Don't enable the oxygen bar when frozen or in lava/slime; also fix the oxygen bar...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / sv_main.qc
1 #include "sv_main.qh"
2
3 #include "anticheat.qh"
4 #include "g_hook.qh"
5 #include "g_damage.qh"
6 #include "g_world.qh"
7
8 #include "bot/api.qh"
9
10 #include "command/common.qh"
11
12 #include <server/mutators/_mod.qh>
13 #include "weapons/csqcprojectile.qh"
14 #include <server/compat/quake3.qh>
15
16 #include "../common/constants.qh"
17 #include "../common/deathtypes/all.qh"
18 #include "../common/debug.qh"
19 #include "../common/mapinfo.qh"
20 #include "../common/util.qh"
21
22 #include "../common/vehicles/all.qh"
23 #include <common/monsters/sv_monsters.qh>
24 #include <common/weapons/_all.qh>
25
26 #include "../lib/csqcmodel/sv_model.qh"
27
28 #include "../lib/warpzone/common.qh"
29 #include "../lib/warpzone/server.qh"
30
31 void CreatureFrame_hotliquids(entity this)
32 {
33         if (this.dmgtime >= time)
34         {
35                 return;
36         }
37
38         this.dmgtime = time + autocvar_g_balance_contents_damagerate;
39
40         if (this.flags & FL_PROJECTILE)
41         {
42                 if (this.watertype == CONTENT_LAVA)
43                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
44                 else if (this.watertype == CONTENT_SLIME)
45                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
46         }
47         else
48         {
49                 if (this.watertype == CONTENT_LAVA)
50                 {
51                         if (this.watersound_finished < time)
52                         {
53                                 this.watersound_finished = time + 0.5;
54                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
55                         }
56                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
57                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
58                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
59                 }
60                 else if (this.watertype == CONTENT_SLIME)
61                 {
62                         if (this.watersound_finished < time)
63                         {
64                                 this.watersound_finished = time + 0.5;
65                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
66                         }
67                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
68                 }
69         }
70 }
71
72 void CreatureFrame_Liquids(entity this)
73 {
74         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
75         {
76                 if (!(this.flags & FL_INWATER))
77                 {
78                         this.flags |= FL_INWATER;
79                         this.dmgtime = 0;
80                 }
81
82                 CreatureFrame_hotliquids(this);
83         }
84         else
85         {
86                 if (this.flags & FL_INWATER)
87                 {
88                         // play leave water sound
89                         this.flags &= ~FL_INWATER;
90                         this.dmgtime = 0;
91                 }
92         }
93 }
94
95 void CreatureFrame_FallDamage(entity this)
96 {
97         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
98                 return; // vehicles and projectiles don't receive fall damage
99         if(!(this.velocity || this.oldvelocity))
100                 return; // if the entity hasn't moved and isn't moving, then don't do anything
101
102         // check for falling damage
103         bool have_hook = false;
104         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
105         {
106             .entity weaponentity = weaponentities[slot];
107             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
108             {
109                 have_hook = true;
110                 break;
111             }
112         }
113         if(!have_hook)
114         {
115                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
116                 if(autocvar_g_balance_falldamage_onlyvertical)
117                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
118                 else
119                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
120                 if (IS_DEAD(this))
121                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
122                 else
123                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
124                 if (dm > 0)
125                 {
126                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
127                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
128                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
129                 }
130         }
131
132         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
133                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
134 }
135
136 void CreatureFrame_All()
137 {
138         if(game_stopped || time < game_starttime)
139                 return;
140
141         IL_EACH(g_damagedbycontents, it.damagedbycontents,
142         {
143                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
144                 CreatureFrame_Liquids(it);
145                 CreatureFrame_FallDamage(it);
146                 it.oldvelocity = it.velocity;
147         });
148 }
149
150 void Pause_TryPause(bool ispaused)
151 {
152         int n = 0;
153         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
154                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
155                 ++n;
156         });
157         if (!n) return;
158         setpause(ispaused);
159 }
160
161 void SV_PausedTic(float elapsedtime)
162 {
163         if (!server_is_dedicated) Pause_TryPause(false);
164 }
165
166 /*
167 =============
168 StartFrame
169
170 Called before each frame by the server
171 =============
172 */
173
174 bool game_delay_last;
175
176 bool autocvar_sv_autopause = false;
177 void systems_update();
178 void sys_phys_update(entity this, float dt);
179 void StartFrame()
180 {
181     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
182     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
183     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
184
185         execute_next_frame();
186         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
187
188         delete_fn = remove_unsafely; // not during spawning!
189         serverprevtime = servertime;
190         servertime = time;
191         serverframetime = frametime;
192
193 #ifdef PROFILING
194         if(time > client_cefc_accumulatortime + 1)
195         {
196                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
197                 int c_seeing = 0;
198                 int c_seen = 0;
199                 FOREACH_CLIENT(true, {
200                         if(IS_REAL_CLIENT(it))
201                                 ++c_seeing;
202                         if(IS_PLAYER(it))
203                                 ++c_seen;
204                 });
205                 LOG_INFO(
206                     "CEFC time: ", ftos(t * 1000), "ms; ",
207             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
208             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
209         );
210                 client_cefc_accumulatortime = time;
211                 client_cefc_accumulator = 0;
212         }
213 #endif
214
215         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
216
217         if (RedirectionThink()) return;
218
219         UncustomizeEntitiesRun();
220         InitializeEntitiesRun();
221
222         WarpZone_StartFrame();
223
224         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
225         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
226
227         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
228                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
229
230         // detect when the pre-game countdown (if any) has ended and the game has started
231         bool game_delay = (time < game_starttime);
232         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
233                 GameLogEcho(":startdelay_ended");
234         game_delay_last = game_delay;
235
236         CreatureFrame_All();
237         CheckRules_World();
238
239         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
240                 ReadyRestart();
241                 return;
242         }
243
244         bot_serverframe();
245         anticheat_startframe();
246         MUTATOR_CALLHOOK(SV_StartFrame);
247
248         GlobalStats_updateglobal();
249     FOREACH_CLIENT(true, GlobalStats_update(it));
250     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
251 }
252
253 .vector originjitter;
254 .vector anglesjitter;
255 .float anglejitter;
256 .string gametypefilter;
257 .string cvarfilter;
258
259 /**
260  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
261  * +: all must match. this is the default
262  * -: one must NOT match
263  *
264  * var>x
265  * var<x
266  * var>=x
267  * var<=x
268  * var==x
269  * var!=x
270  * var===x
271  * var!==x
272  */
273 bool expr_evaluate(string s)
274 {
275     bool ret = false;
276     if (str2chr(s, 0) == '+') {
277         s = substring(s, 1, -1);
278     } else if (str2chr(s, 0) == '-') {
279         ret = true;
280         s = substring(s, 1, -1);
281     }
282     bool expr_fail = false;
283     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
284         int o;
285         string k, v;
286         s = argv(i);
287         #define X(expr) \
288             if (expr) \
289                 continue; \
290             expr_fail = true; \
291             break;
292
293         #define BINOP(op, len, expr) \
294             if ((o = strstrofs(s, op, 0)) >= 0) { \
295                 k = substring(s, 0, o); \
296                 v = substring(s, o + len, -1); \
297                 X(expr); \
298             }
299         BINOP(">=", 2, cvar(k) >= stof(v));
300         BINOP("<=", 2, cvar(k) <= stof(v));
301         BINOP(">",  1, cvar(k) >  stof(v));
302         BINOP("<",  1, cvar(k) <  stof(v));
303         BINOP("==", 2, cvar(k) == stof(v));
304         BINOP("!=", 2, cvar(k) != stof(v));
305         BINOP("===", 3, cvar_string(k) == v);
306         BINOP("!==", 3, cvar_string(k) != v);
307         {
308             k = s;
309             bool b = true;
310             if (str2chr(k, 0) == '!') {
311                 k = substring(s, 1, -1);
312                 b = false;
313             }
314             float f = stof(k);
315             bool isnum = ftos(f) == k;
316             X(boolean(isnum ? f : cvar(k)) == b);
317         }
318         #undef BINOP
319         #undef X
320     }
321     if (!expr_fail) {
322         ret = !ret;
323     }
324     // now ret is true if we want to keep the item, and false if we want to get rid of it
325     return ret;
326 }
327
328 void SV_OnEntityPreSpawnFunction(entity this)
329 {
330         if (this)
331         if (this.gametypefilter != "")
332         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
333         {
334                 delete(this);
335                 return;
336         }
337         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
338                 delete(this);
339                 return;
340         }
341
342         if (DoesQ3ARemoveThisEntity(this)) {
343                 delete(this);
344                 return;
345         }
346
347         set_movetype(this, this.movetype);
348
349         if (this.monster_attack) {
350                 IL_PUSH(g_monster_targets, this);
351     }
352
353         // support special -1 and -2 angle from radiant
354         if (this.angles == '0 -1 0') {
355                 this.angles = '-90 0 0';
356         } else if (this.angles == '0 -2 0') {
357                 this.angles = '+90 0 0';
358     }
359
360     #define X(out, in) MACRO_BEGIN \
361         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
362     MACRO_END
363     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
364     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
365     X(this.angles.y, this.anglejitter);
366     #undef X
367
368         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
369                 delete(this);
370                 return;
371         }
372 }
373
374 void WarpZone_PostInitialize_Callback()
375 {
376         // create waypoint links for warpzones
377         entity tracetest_ent = spawn();
378         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
379         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
380         //for(entity e = warpzone_first; e; e = e.warpzone_next)
381         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
382                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
383         delete(tracetest_ent);
384 }
385
386 /*
387 ==================
388 main
389
390 unused but required by the engine
391 ==================
392 */
393 void main ()
394 {
395
396 }