Merge branch 'master' into martin-t/limit
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / sv_main.qc
1 #include "sv_main.qh"
2
3 #include "anticheat.qh"
4 #include "g_hook.qh"
5 #include "g_damage.qh"
6 #include "g_world.qh"
7
8 #include "bot/api.qh"
9
10 #include "command/common.qh"
11
12 #include <server/mutators/_mod.qh>
13 #include "weapons/csqcprojectile.qh"
14 #include <server/compat/quake3.qh>
15
16 #include "../common/constants.qh"
17 #include "../common/deathtypes/all.qh"
18 #include "../common/debug.qh"
19 #include "../common/mapinfo.qh"
20 #include "../common/util.qh"
21
22 #include "../common/vehicles/all.qh"
23 #include <common/monsters/sv_monsters.qh>
24 #include <common/weapons/_all.qh>
25
26 #include "../lib/csqcmodel/sv_model.qh"
27
28 #include "../lib/warpzone/common.qh"
29 #include "../lib/warpzone/server.qh"
30
31 void CreatureFrame_hotliquids(entity this)
32 {
33         if (this.dmgtime >= time)
34         {
35                 return;
36         }
37
38         this.dmgtime = time + autocvar_g_balance_contents_damagerate;
39
40         if (this.flags & FL_PROJECTILE)
41         {
42                 if (this.watertype == CONTENT_LAVA)
43                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
44                 else if (this.watertype == CONTENT_SLIME)
45                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
46         }
47         else
48         {
49                 if (this.watertype == CONTENT_LAVA)
50                 {
51                         if (this.watersound_finished < time)
52                         {
53                                 this.watersound_finished = time + 0.5;
54                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
55                         }
56                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
57                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
58                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
59                 }
60                 else if (this.watertype == CONTENT_SLIME)
61                 {
62                         if (this.watersound_finished < time)
63                         {
64                                 this.watersound_finished = time + 0.5;
65                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
66                         }
67                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
68                 }
69         }
70 }
71
72 void CreatureFrame_Liquids(entity this)
73 {
74         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
75         {
76                 if (!(this.flags & FL_INWATER))
77                 {
78                         this.flags |= FL_INWATER;
79                         this.dmgtime = 0;
80                 }
81
82                 CreatureFrame_hotliquids(this);
83         }
84         else
85         {
86                 if (this.flags & FL_INWATER)
87                 {
88                         // play leave water sound
89                         this.flags &= ~FL_INWATER;
90                         this.dmgtime = 0;
91                 }
92                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
93         }
94 }
95
96 void CreatureFrame_FallDamage(entity this)
97 {
98         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
99                 return; // vehicles and projectiles don't receive fall damage
100         if(!(this.velocity || this.oldvelocity))
101                 return; // if the entity hasn't moved and isn't moving, then don't do anything
102
103         // check for falling damage
104         bool have_hook = false;
105         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
106         {
107             .entity weaponentity = weaponentities[slot];
108             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
109             {
110                 have_hook = true;
111                 break;
112             }
113         }
114         if(!have_hook)
115         {
116                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
117                 if(autocvar_g_balance_falldamage_onlyvertical)
118                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
119                 else
120                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
121                 if (IS_DEAD(this))
122                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
123                 else
124                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
125                 if (dm > 0)
126                 {
127                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
128                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
129                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
130                 }
131         }
132
133         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
134                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
135 }
136
137 void CreatureFrame_All()
138 {
139         if(game_stopped || time < game_starttime)
140                 return;
141
142         IL_EACH(g_damagedbycontents, it.damagedbycontents,
143         {
144                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
145                 CreatureFrame_Liquids(it);
146                 CreatureFrame_FallDamage(it);
147                 it.oldvelocity = it.velocity;
148         });
149 }
150
151 void Pause_TryPause(bool ispaused)
152 {
153         int n = 0;
154         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
155                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
156                 ++n;
157         });
158         if (!n) return;
159         setpause(ispaused);
160 }
161
162 void SV_PausedTic(float elapsedtime)
163 {
164         if (!server_is_dedicated) Pause_TryPause(false);
165 }
166
167 /*
168 =============
169 StartFrame
170
171 Called before each frame by the server
172 =============
173 */
174
175 bool game_delay_last;
176
177 bool autocvar_sv_autopause = false;
178 void systems_update();
179 void sys_phys_update(entity this, float dt);
180 void StartFrame()
181 {
182     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
183     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
184     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
185
186         execute_next_frame();
187         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
188
189         delete_fn = remove_unsafely; // not during spawning!
190         serverprevtime = servertime;
191         servertime = time;
192         serverframetime = frametime;
193
194 #ifdef PROFILING
195         if(time > client_cefc_accumulatortime + 1)
196         {
197                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
198                 int c_seeing = 0;
199                 int c_seen = 0;
200                 FOREACH_CLIENT(true, {
201                         if(IS_REAL_CLIENT(it))
202                                 ++c_seeing;
203                         if(IS_PLAYER(it))
204                                 ++c_seen;
205                 });
206                 LOG_INFO(
207                     "CEFC time: ", ftos(t * 1000), "ms; ",
208             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
209             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
210         );
211                 client_cefc_accumulatortime = time;
212                 client_cefc_accumulator = 0;
213         }
214 #endif
215
216         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
217
218         if (RedirectionThink()) return;
219
220         UncustomizeEntitiesRun();
221         InitializeEntitiesRun();
222
223         WarpZone_StartFrame();
224
225         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
226         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
227
228         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
229                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
230
231         // detect when the pre-game countdown (if any) has ended and the game has started
232         bool game_delay = (time < game_starttime);
233         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
234                 GameLogEcho(":startdelay_ended");
235         game_delay_last = game_delay;
236
237         CreatureFrame_All();
238         CheckRules_World();
239
240         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
241                 ReadyRestart();
242                 return;
243         }
244
245         bot_serverframe();
246         anticheat_startframe();
247         MUTATOR_CALLHOOK(SV_StartFrame);
248
249         GlobalStats_updateglobal();
250     FOREACH_CLIENT(true, GlobalStats_update(it));
251     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
252 }
253
254 .vector originjitter;
255 .vector anglesjitter;
256 .float anglejitter;
257 .string gametypefilter;
258 .string cvarfilter;
259
260 /**
261  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
262  * +: all must match. this is the default
263  * -: one must NOT match
264  *
265  * var>x
266  * var<x
267  * var>=x
268  * var<=x
269  * var==x
270  * var!=x
271  * var===x
272  * var!==x
273  */
274 bool expr_evaluate(string s)
275 {
276     bool ret = false;
277     if (str2chr(s, 0) == '+') {
278         s = substring(s, 1, -1);
279     } else if (str2chr(s, 0) == '-') {
280         ret = true;
281         s = substring(s, 1, -1);
282     }
283     bool expr_fail = false;
284     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
285         int o;
286         string k, v;
287         s = argv(i);
288         #define X(expr) \
289             if (expr) \
290                 continue; \
291             expr_fail = true; \
292             break;
293
294         #define BINOP(op, len, expr) \
295             if ((o = strstrofs(s, op, 0)) >= 0) { \
296                 k = substring(s, 0, o); \
297                 v = substring(s, o + len, -1); \
298                 X(expr); \
299             }
300         BINOP(">=", 2, cvar(k) >= stof(v));
301         BINOP("<=", 2, cvar(k) <= stof(v));
302         BINOP(">",  1, cvar(k) >  stof(v));
303         BINOP("<",  1, cvar(k) <  stof(v));
304         BINOP("==", 2, cvar(k) == stof(v));
305         BINOP("!=", 2, cvar(k) != stof(v));
306         BINOP("===", 3, cvar_string(k) == v);
307         BINOP("!==", 3, cvar_string(k) != v);
308         {
309             k = s;
310             bool b = true;
311             if (str2chr(k, 0) == '!') {
312                 k = substring(s, 1, -1);
313                 b = false;
314             }
315             float f = stof(k);
316             bool isnum = ftos(f) == k;
317             X(boolean(isnum ? f : cvar(k)) == b);
318         }
319         #undef BINOP
320         #undef X
321     }
322     if (!expr_fail) {
323         ret = !ret;
324     }
325     // now ret is true if we want to keep the item, and false if we want to get rid of it
326     return ret;
327 }
328
329 void SV_OnEntityPreSpawnFunction(entity this)
330 {
331         if (this)
332         if (this.gametypefilter != "")
333         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
334         {
335                 delete(this);
336                 return;
337         }
338         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
339                 delete(this);
340                 return;
341         }
342
343         if (DoesQ3ARemoveThisEntity(this)) {
344                 delete(this);
345                 return;
346         }
347
348         set_movetype(this, this.movetype);
349
350         if (this.monster_attack) {
351                 IL_PUSH(g_monster_targets, this);
352     }
353
354         // support special -1 and -2 angle from radiant
355         if (this.angles == '0 -1 0') {
356                 this.angles = '-90 0 0';
357         } else if (this.angles == '0 -2 0') {
358                 this.angles = '+90 0 0';
359     }
360
361     #define X(out, in) MACRO_BEGIN \
362         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
363     MACRO_END
364     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
365     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
366     X(this.angles.y, this.anglejitter);
367     #undef X
368
369         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
370                 delete(this);
371                 return;
372         }
373 }
374
375 void WarpZone_PostInitialize_Callback()
376 {
377         // create waypoint links for warpzones
378         entity tracetest_ent = spawn();
379         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
380         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
381         //for(entity e = warpzone_first; e; e = e.warpzone_next)
382         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
383                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
384         delete(tracetest_ent);
385 }
386
387 /*
388 ==================
389 main
390
391 unused but required by the engine
392 ==================
393 */
394 void main ()
395 {
396
397 }