qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_damage.qh"
   6 #include "g_world.qh"
   7 #include "spawnpoints.qh"
   8 #include <server/gamelog.qh>
   9
  10 #include "bot/api.qh"
  11
  12 #include "command/common.qh"
  13
  14 #include <server/mutators/_mod.qh>
  15 #include "weapons/csqcprojectile.qh"
  16 #include <server/weapons/common.qh>
  17 #include <server/compat/quake3.qh>
  18
  19 #include "../common/constants.qh"
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/debug.qh"
  22 #include "../common/mapinfo.qh"
  23 #include "../common/util.qh"
  24
  25 #include "../common/vehicles/all.qh"
  26 #include <common/monsters/sv_monsters.qh>
  27 #include <common/weapons/_all.qh>
  28
  29 #include "../lib/csqcmodel/sv_model.qh"
  30
  31 #include "../lib/warpzone/common.qh"
  32 #include "../lib/warpzone/server.qh"
  33
  34 void CreatureFrame_hotliquids(entity this)
  35 {
  36         if (this.contents_damagetime >= time)
  37         {
  38                 return;
  39         }
  40
  41         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  42
  43         if (this.flags & FL_PROJECTILE)
  44         {
  45                 if (this.watertype == CONTENT_LAVA)
  46                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  47                 else if (this.watertype == CONTENT_SLIME)
  48                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  49         }
  50         else
  51         {
  52                 if (STAT(FROZEN, this))
  53                 {
  54                         if (this.watertype == CONTENT_LAVA)
  55                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  56                         else if (this.watertype == CONTENT_SLIME)
  57                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  58                 }
  59                 else if (this.watertype == CONTENT_LAVA)
  60                 {
  61                         if (this.watersound_finished < time)
  62                         {
  63                                 this.watersound_finished = time + 0.5;
  64                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  65                         }
  66                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  67                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  68                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  69                 }
  70                 else if (this.watertype == CONTENT_SLIME)
  71                 {
  72                         if (this.watersound_finished < time)
  73                         {
  74                                 this.watersound_finished = time + 0.5;
  75                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  76                         }
  77                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  78                 }
  79         }
  80 }
  81
  82 void CreatureFrame_Liquids(entity this)
  83 {
  84         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  85         {
  86                 if (!(this.flags & FL_INWATER))
  87                 {
  88                         this.flags |= FL_INWATER;
  89                         this.contents_damagetime = 0;
  90                 }
  91
  92                 CreatureFrame_hotliquids(this);
  93         }
  94         else
  95         {
  96                 if (this.flags & FL_INWATER)
  97                 {
  98                         // play leave water sound
  99                         this.flags &= ~FL_INWATER;
 100                         this.contents_damagetime = 0;
 101                 }
 102         }
 103 }
 104
 105 void CreatureFrame_FallDamage(entity this)
 106 {
 107         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 108                 return; // vehicles and projectiles don't receive fall damage
 109         if(!(this.velocity || this.oldvelocity))
 110                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 111
 112         // check for falling damage
 113         bool have_hook = false;
 114         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 115         {
 116             .entity weaponentity = weaponentities[slot];
 117             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 118             {
 119                 have_hook = true;
 120                 break;
 121             }
 122         }
 123         if(!have_hook)
 124         {
 125                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 126                 if(autocvar_g_balance_falldamage_onlyvertical)
 127                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 128                 else
 129                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 130                 if (IS_DEAD(this))
 131                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 132                 else
 133                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 134                 if (dm > 0)
 135                 {
 136                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 137                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 138                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 139                 }
 140         }
 141
 142         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 143                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 144 }
 145
 146 void CreatureFrame_All()
 147 {
 148         if(game_stopped || time < game_starttime)
 149                 return;
 150
 151         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 152         {
 153                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 154                 CreatureFrame_Liquids(it);
 155                 CreatureFrame_FallDamage(it);
 156                 it.oldvelocity = it.velocity;
 157         });
 158 }
 159
 160 void Pause_TryPause(bool ispaused)
 161 {
 162         int n = 0;
 163         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 164                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 165                 ++n;
 166         });
 167         if (!n) return;
 168         setpause(ispaused);
 169 }
 170
 171 void SV_PausedTic(float elapsedtime)
 172 {
 173         if (!server_is_dedicated) Pause_TryPause(false);
 174 }
 175
 176 /*
 177 =============
 178 StartFrame
 179
 180 Called before each frame by the server
 181 =============
 182 */
 183
 184 bool game_delay_last;
 185
 186 bool autocvar_sv_autopause = false;
 187 void systems_update();
 188 void sys_phys_update(entity this, float dt);
 189 void StartFrame()
 190 {
 191     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 192     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 193     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 194
 195         execute_next_frame();
 196         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 197
 198         delete_fn = remove_unsafely; // not during spawning!
 199         serverprevtime = servertime;
 200         servertime = time;
 201         serverframetime = frametime;
 202
 203 #ifdef PROFILING
 204         if(time > client_cefc_accumulatortime + 1)
 205         {
 206                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 207                 int c_seeing = 0;
 208                 int c_seen = 0;
 209                 FOREACH_CLIENT(true, {
 210                         if(IS_REAL_CLIENT(it))
 211                                 ++c_seeing;
 212                         if(IS_PLAYER(it))
 213                                 ++c_seen;
 214                 });
 215                 LOG_INFO(
 216                     "CEFC time: ", ftos(t * 1000), "ms; ",
 217             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 218             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 219         );
 220                 client_cefc_accumulatortime = time;
 221                 client_cefc_accumulator = 0;
 222         }
 223 #endif
 224
 225         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 226
 227         if (RedirectionThink()) return;
 228
 229         UncustomizeEntitiesRun();
 230         InitializeEntitiesRun();
 231
 232         WarpZone_StartFrame();
 233
 234         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 235         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 236
 237         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 238                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 239
 240         // detect when the pre-game countdown (if any) has ended and the game has started
 241         bool game_delay = (time < game_starttime);
 242         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 243                 GameLogEcho(":startdelay_ended");
 244         game_delay_last = game_delay;
 245
 246         CreatureFrame_All();
 247         CheckRules_World();
 248
 249         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 250                 ReadyRestart();
 251                 return;
 252         }
 253
 254         bot_serverframe();
 255         anticheat_startframe();
 256         MUTATOR_CALLHOOK(SV_StartFrame);
 257
 258         GlobalStats_updateglobal();
 259     FOREACH_CLIENT(true, GlobalStats_update(it));
 260     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 261 }
 262
 263 .vector originjitter;
 264 .vector anglesjitter;
 265 .float anglejitter;
 266 .string gametypefilter;
 267 .string cvarfilter;
 268
 269 /**
 270  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 271  * +: all must match. this is the default
 272  * -: one must NOT match
 273  *
 274  * var>x
 275  * var<x
 276  * var>=x
 277  * var<=x
 278  * var==x
 279  * var!=x
 280  * var===x
 281  * var!==x
 282  */
 283 bool expr_evaluate(string s)
 284 {
 285     bool ret = false;
 286     if (str2chr(s, 0) == '+') {
 287         s = substring(s, 1, -1);
 288     } else if (str2chr(s, 0) == '-') {
 289         ret = true;
 290         s = substring(s, 1, -1);
 291     }
 292     bool expr_fail = false;
 293     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 294         int o;
 295         string k, v;
 296         s = argv(i);
 297         #define X(expr) \
 298             if (expr) \
 299                 continue; \
 300             expr_fail = true; \
 301             break;
 302
 303         #define BINOP(op, len, expr) \
 304             if ((o = strstrofs(s, op, 0)) >= 0) { \
 305                 k = substring(s, 0, o); \
 306                 v = substring(s, o + len, -1); \
 307                 X(expr); \
 308             }
 309         BINOP(">=", 2, cvar(k) >= stof(v));
 310         BINOP("<=", 2, cvar(k) <= stof(v));
 311         BINOP(">",  1, cvar(k) >  stof(v));
 312         BINOP("<",  1, cvar(k) <  stof(v));
 313         BINOP("==", 2, cvar(k) == stof(v));
 314         BINOP("!=", 2, cvar(k) != stof(v));
 315         BINOP("===", 3, cvar_string(k) == v);
 316         BINOP("!==", 3, cvar_string(k) != v);
 317         {
 318             k = s;
 319             bool b = true;
 320             if (str2chr(k, 0) == '!') {
 321                 k = substring(s, 1, -1);
 322                 b = false;
 323             }
 324             float f = stof(k);
 325             bool isnum = ftos(f) == k;
 326             X(boolean(isnum ? f : cvar(k)) == b);
 327         }
 328         #undef BINOP
 329         #undef X
 330     }
 331     if (!expr_fail) {
 332         ret = !ret;
 333     }
 334     // now ret is true if we want to keep the item, and false if we want to get rid of it
 335     return ret;
 336 }
 337
 338 void SV_OnEntityPreSpawnFunction(entity this)
 339 {
 340         if (this)
 341         if (this.gametypefilter != "")
 342         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 343         {
 344                 delete(this);
 345                 return;
 346         }
 347         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 348                 delete(this);
 349                 return;
 350         }
 351
 352         if (DoesQ3ARemoveThisEntity(this)) {
 353                 delete(this);
 354                 return;
 355         }
 356
 357         set_movetype(this, this.movetype);
 358
 359         if (this.monster_attack) {
 360                 IL_PUSH(g_monster_targets, this);
 361     }
 362
 363         // support special -1 and -2 angle from radiant
 364         if (this.angles == '0 -1 0') {
 365                 this.angles = '-90 0 0';
 366         } else if (this.angles == '0 -2 0') {
 367                 this.angles = '+90 0 0';
 368     }
 369
 370     #define X(out, in) MACRO_BEGIN \
 371         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 372     MACRO_END
 373     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 374     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 375     X(this.angles.y, this.anglejitter);
 376     #undef X
 377
 378         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 379                 delete(this);
 380                 return;
 381         }
 382 }
 383
 384 void WarpZone_PostInitialize_Callback()
 385 {
 386         // create waypoint links for warpzones
 387         entity tracetest_ent = spawn();
 388         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 389         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 390         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 391         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 392                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 393         delete(tracetest_ent);
 394 }
 395
 396 /*
 397 ==================
 398 main
 399
 400 unused but required by the engine
 401 ==================
 402 */
 403 void main ()
 404 {
 405
 406 }