qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/api.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/all.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         if(this.velocity || this.oldvelocity) // moving or has moved
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 if(!this.hook.state)
 103                 {
 104                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 105                         if (IS_DEAD(this))
 106                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 107                         else
 108                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 109                         if (dm > 0)
 110                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 111                 }
 112
 113                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 114                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 115         }
 116 }
 117
 118 void CreatureFrame_All()
 119 {
 120         FOREACH_ENTITY_FLOAT(damagedbycontents, true, {
 121                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 122                 CreatureFrame_Liquids(it);
 123                 CreatureFrame_FallDamage(it);
 124                 it.oldvelocity = it.velocity;
 125         });
 126 }
 127
 128 void Pause_TryPause(bool ispaused)
 129 {
 130         int n = 0;
 131         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 132                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 133                 ++n;
 134         ));
 135         if (!n) return;
 136         setpause(ispaused);
 137 }
 138
 139 void SV_PausedTic(float elapsedtime)
 140 {
 141         if (!server_is_dedicated) Pause_TryPause(false);
 142 }
 143
 144 /*
 145 =============
 146 StartFrame
 147
 148 Called before each frame by the server
 149 =============
 150 */
 151
 152 float game_delay;
 153 float game_delay_last;
 154
 155 bool autocvar_sv_autopause = false;
 156 float RedirectionThink();
 157 void systems_update();
 158 void sys_phys_update(entity this, float dt);
 159 void StartFrame()
 160 {
 161     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 162     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 163     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 164
 165         execute_next_frame();
 166         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 167
 168         delete_fn = remove_unsafely; // not during spawning!
 169         serverprevtime = servertime;
 170         servertime = time;
 171         serverframetime = frametime;
 172
 173 #ifdef PROFILING
 174         if(time > client_cefc_accumulatortime + 1)
 175         {
 176                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 177                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 178                 int c_seeing = 0;
 179                 int c_seen = 0;
 180                 FOREACH_CLIENT(true, LAMBDA(
 181                         if(IS_REAL_CLIENT(it))
 182                                 ++c_seeing;
 183                         if(IS_PLAYER(it))
 184                                 ++c_seen;
 185                 ));
 186                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 187                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 188
 189                 client_cefc_accumulatortime = time;
 190                 client_cefc_accumulator = 0;
 191         }
 192 #endif
 193
 194         FOREACH_ENTITY_FLOAT(csqcprojectile_clientanimate, true, CSQCProjectile_Check(it));
 195
 196         if (RedirectionThink()) return;
 197
 198         UncustomizeEntitiesRun();
 199         InitializeEntitiesRun();
 200
 201         WarpZone_StartFrame();
 202
 203         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 204         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 205
 206         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 207                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 208
 209         skill = autocvar_skill;
 210
 211         // detect when the pre-game countdown (if any) has ended and the game has started
 212         game_delay = (time < game_starttime);
 213
 214         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 215                 GameLogEcho(":startdelay_ended");
 216
 217         game_delay_last = game_delay;
 218
 219         CreatureFrame_All();
 220         CheckRules_World();
 221
 222         if (warmup_stage && !gameover && warmup_limit > 0 && time >= warmup_limit) {
 223                 ReadyRestart();
 224                 return;
 225         }
 226
 227         bot_serverframe();
 228         anticheat_startframe();
 229         MUTATOR_CALLHOOK(SV_StartFrame);
 230
 231     FOREACH_CLIENT(true, GlobalStats_update(it));
 232     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 233 }
 234
 235 .vector originjitter;
 236 .vector anglesjitter;
 237 .float anglejitter;
 238 .string gametypefilter;
 239 .string cvarfilter;
 240 bool DoesQ3ARemoveThisEntity(entity this);
 241 void SV_OnEntityPreSpawnFunction(entity this)
 242 {
 243         __spawnfunc_expecting = true;
 244         __spawnfunc_expect = this;
 245         if (this)
 246         if (this.gametypefilter != "")
 247         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 248         {
 249                 delete(this);
 250                 __spawnfunc_expecting = false;
 251                 return;
 252         }
 253         if(this.cvarfilter != "")
 254         {
 255                 float n, i, o, inv;
 256                 string s, k, v;
 257                 inv = 0;
 258
 259                 s = this.cvarfilter;
 260                 if(substring(s, 0, 1) == "+")
 261                 {
 262                         s = substring(s, 1, -1);
 263                 }
 264                 else if(substring(s, 0, 1) == "-")
 265                 {
 266                         inv = 1;
 267                         s = substring(s, 1, -1);
 268                 }
 269
 270                 n = tokenize_console(s);
 271                 for(i = 0; i < n; ++i)
 272                 {
 273                         s = argv(i);
 274                         // syntax:
 275                         // var>x
 276                         // var<x
 277                         // var>=x
 278                         // var<=x
 279                         // var==x
 280                         // var!=x
 281                         // var===x
 282                         // var!==x
 283                         if((o = strstrofs(s, ">=", 0)) >= 0)
 284                         {
 285                                 k = substring(s, 0, o);
 286                                 v = substring(s, o+2, -1);
 287                                 if(cvar(k) < stof(v))
 288                                         goto cvar_fail;
 289                         }
 290                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 291                         {
 292                                 k = substring(s, 0, o);
 293                                 v = substring(s, o+2, -1);
 294                                 if(cvar(k) > stof(v))
 295                                         goto cvar_fail;
 296                         }
 297                         else if((o = strstrofs(s, ">", 0)) >= 0)
 298                         {
 299                                 k = substring(s, 0, o);
 300                                 v = substring(s, o+1, -1);
 301                                 if(cvar(k) <= stof(v))
 302                                         goto cvar_fail;
 303                         }
 304                         else if((o = strstrofs(s, "<", 0)) >= 0)
 305                         {
 306                                 k = substring(s, 0, o);
 307                                 v = substring(s, o+1, -1);
 308                                 if(cvar(k) >= stof(v))
 309                                         goto cvar_fail;
 310                         }
 311                         else if((o = strstrofs(s, "==", 0)) >= 0)
 312                         {
 313                                 k = substring(s, 0, o);
 314                                 v = substring(s, o+2, -1);
 315                                 if(cvar(k) != stof(v))
 316                                         goto cvar_fail;
 317                         }
 318                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 319                         {
 320                                 k = substring(s, 0, o);
 321                                 v = substring(s, o+2, -1);
 322                                 if(cvar(k) == stof(v))
 323                                         goto cvar_fail;
 324                         }
 325                         else if((o = strstrofs(s, "===", 0)) >= 0)
 326                         {
 327                                 k = substring(s, 0, o);
 328                                 v = substring(s, o+2, -1);
 329                                 if(cvar_string(k) != v)
 330                                         goto cvar_fail;
 331                         }
 332                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 333                         {
 334                                 k = substring(s, 0, o);
 335                                 v = substring(s, o+2, -1);
 336                                 if(cvar_string(k) == v)
 337                                         goto cvar_fail;
 338                         }
 339                         else if(substring(s, 0, 1) == "!")
 340                         {
 341                                 k = substring(s, 1, -1);
 342                                 if(cvar(k))
 343                                         goto cvar_fail;
 344                         }
 345                         else
 346                         {
 347                                 k = s;
 348                                 if (!cvar(k))
 349                                         goto cvar_fail;
 350                         }
 351                 }
 352                 inv = !inv;
 353 LABEL(cvar_fail)
 354                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 355                 if (!inv)
 356                 {
 357                         //print("cvarfilter fail\n");
 358                         delete(this);
 359                         __spawnfunc_expecting = false;
 360                         return;
 361                 }
 362         }
 363
 364         if(DoesQ3ARemoveThisEntity(this))
 365         {
 366                 delete(this);
 367                 __spawnfunc_expecting = false;
 368                 return;
 369         }
 370
 371         set_movetype(this, this.movetype);
 372
 373         // support special -1 and -2 angle from radiant
 374         if (this.angles == '0 -1 0')
 375                 this.angles = '-90 0 0';
 376         else if (this.angles == '0 -2 0')
 377                 this.angles = '+90 0 0';
 378
 379         if(this.originjitter.x != 0)
 380                 this.origin_x = this.origin.x + (random() * 2 - 1) * this.originjitter.x;
 381         if(this.originjitter.y != 0)
 382                 this.origin_y = this.origin.y + (random() * 2 - 1) * this.originjitter.y;
 383         if(this.originjitter.z != 0)
 384                 this.origin_z = this.origin.z + (random() * 2 - 1) * this.originjitter.z;
 385         if(this.anglesjitter.x != 0)
 386                 this.angles_x = this.angles.x + (random() * 2 - 1) * this.anglesjitter.x;
 387         if(this.anglesjitter.y != 0)
 388                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglesjitter.y;
 389         if(this.anglesjitter.z != 0)
 390                 this.angles_z = this.angles.z + (random() * 2 - 1) * this.anglesjitter.z;
 391         if(this.anglejitter != 0)
 392                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglejitter;
 393
 394         if(MUTATOR_CALLHOOK(OnEntityPreSpawn, this))
 395         {
 396                 delete(this);
 397                 __spawnfunc_expecting = false;
 398                 return;
 399         }
 400 }
 401
 402 void WarpZone_PostInitialize_Callback()
 403 {
 404         // create waypoint links for warpzones
 405         entity e;
 406         for(e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 407         {
 408                 vector src, dst;
 409                 src = (e.absmin + e.absmax) * 0.5;
 410                 makevectors(e.warpzone_angles);
 411                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 412                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 413                 makevectors(e.enemy.warpzone_angles);
 414                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 415                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 416         }
 417 }