qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/api.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/_mod.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include <common/weapons/_all.qh>
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         if(this.velocity || this.oldvelocity) // moving or has moved
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 bool have_hook = false;
 103                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 104             {
 105                 .entity weaponentity = weaponentities[slot];
 106                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 107                 {
 108                         have_hook = true;
 109                         break;
 110                 }
 111             }
 112                 if(!have_hook)
 113                 {
 114                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 115                         if (IS_DEAD(this))
 116                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 117                         else
 118                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 119                         if (dm > 0)
 120                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 121                 }
 122
 123                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 124                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 125         }
 126 }
 127
 128 void CreatureFrame_All()
 129 {
 130         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 131         {
 132                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 133                 CreatureFrame_Liquids(it);
 134                 CreatureFrame_FallDamage(it);
 135                 it.oldvelocity = it.velocity;
 136         });
 137 }
 138
 139 void Pause_TryPause(bool ispaused)
 140 {
 141         int n = 0;
 142         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 143                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 144                 ++n;
 145         ));
 146         if (!n) return;
 147         setpause(ispaused);
 148 }
 149
 150 void SV_PausedTic(float elapsedtime)
 151 {
 152         if (!server_is_dedicated) Pause_TryPause(false);
 153 }
 154
 155 /*
 156 =============
 157 StartFrame
 158
 159 Called before each frame by the server
 160 =============
 161 */
 162
 163 bool game_delay_last;
 164
 165 bool autocvar_sv_autopause = false;
 166 float RedirectionThink();
 167 void systems_update();
 168 void sys_phys_update(entity this, float dt);
 169 void StartFrame()
 170 {
 171     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 172     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 173     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 174
 175         execute_next_frame();
 176         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 177
 178         delete_fn = remove_unsafely; // not during spawning!
 179         serverprevtime = servertime;
 180         servertime = time;
 181         serverframetime = frametime;
 182
 183 #ifdef PROFILING
 184         if(time > client_cefc_accumulatortime + 1)
 185         {
 186                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 187                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 188                 int c_seeing = 0;
 189                 int c_seen = 0;
 190                 FOREACH_CLIENT(true, LAMBDA(
 191                         if(IS_REAL_CLIENT(it))
 192                                 ++c_seeing;
 193                         if(IS_PLAYER(it))
 194                                 ++c_seen;
 195                 ));
 196                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 197                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 198
 199                 client_cefc_accumulatortime = time;
 200                 client_cefc_accumulator = 0;
 201         }
 202 #endif
 203
 204         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 205
 206         if (RedirectionThink()) return;
 207
 208         UncustomizeEntitiesRun();
 209         InitializeEntitiesRun();
 210
 211         WarpZone_StartFrame();
 212
 213         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 214         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 215
 216         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 217                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 218
 219         // detect when the pre-game countdown (if any) has ended and the game has started
 220         bool game_delay = (time < game_starttime);
 221         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 222                 GameLogEcho(":startdelay_ended");
 223         game_delay_last = game_delay;
 224
 225         CreatureFrame_All();
 226         CheckRules_World();
 227
 228         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 229                 ReadyRestart();
 230                 return;
 231         }
 232
 233         bot_serverframe();
 234         anticheat_startframe();
 235         MUTATOR_CALLHOOK(SV_StartFrame);
 236
 237     FOREACH_CLIENT(true, GlobalStats_update(it));
 238     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 239 }
 240
 241 .vector originjitter;
 242 .vector anglesjitter;
 243 .float anglejitter;
 244 .string gametypefilter;
 245 .string cvarfilter;
 246 bool DoesQ3ARemoveThisEntity(entity this);
 247 void SV_OnEntityPreSpawnFunction(entity this)
 248 {
 249         __spawnfunc_expecting = true;
 250         __spawnfunc_expect = this;
 251         if (this)
 252         if (this.gametypefilter != "")
 253         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 254         {
 255                 delete(this);
 256                 __spawnfunc_expecting = false;
 257                 return;
 258         }
 259         if(this.cvarfilter != "")
 260         {
 261                 float n, i, o, inv;
 262                 string s, k, v;
 263                 inv = 0;
 264
 265                 s = this.cvarfilter;
 266                 if(substring(s, 0, 1) == "+")
 267                 {
 268                         s = substring(s, 1, -1);
 269                 }
 270                 else if(substring(s, 0, 1) == "-")
 271                 {
 272                         inv = 1;
 273                         s = substring(s, 1, -1);
 274                 }
 275
 276                 n = tokenize_console(s);
 277                 for(i = 0; i < n; ++i)
 278                 {
 279                         s = argv(i);
 280                         // syntax:
 281                         // var>x
 282                         // var<x
 283                         // var>=x
 284                         // var<=x
 285                         // var==x
 286                         // var!=x
 287                         // var===x
 288                         // var!==x
 289                         if((o = strstrofs(s, ">=", 0)) >= 0)
 290                         {
 291                                 k = substring(s, 0, o);
 292                                 v = substring(s, o+2, -1);
 293                                 if(cvar(k) < stof(v))
 294                                         goto cvar_fail;
 295                         }
 296                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 297                         {
 298                                 k = substring(s, 0, o);
 299                                 v = substring(s, o+2, -1);
 300                                 if(cvar(k) > stof(v))
 301                                         goto cvar_fail;
 302                         }
 303                         else if((o = strstrofs(s, ">", 0)) >= 0)
 304                         {
 305                                 k = substring(s, 0, o);
 306                                 v = substring(s, o+1, -1);
 307                                 if(cvar(k) <= stof(v))
 308                                         goto cvar_fail;
 309                         }
 310                         else if((o = strstrofs(s, "<", 0)) >= 0)
 311                         {
 312                                 k = substring(s, 0, o);
 313                                 v = substring(s, o+1, -1);
 314                                 if(cvar(k) >= stof(v))
 315                                         goto cvar_fail;
 316                         }
 317                         else if((o = strstrofs(s, "==", 0)) >= 0)
 318                         {
 319                                 k = substring(s, 0, o);
 320                                 v = substring(s, o+2, -1);
 321                                 if(cvar(k) != stof(v))
 322                                         goto cvar_fail;
 323                         }
 324                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 325                         {
 326                                 k = substring(s, 0, o);
 327                                 v = substring(s, o+2, -1);
 328                                 if(cvar(k) == stof(v))
 329                                         goto cvar_fail;
 330                         }
 331                         else if((o = strstrofs(s, "===", 0)) >= 0)
 332                         {
 333                                 k = substring(s, 0, o);
 334                                 v = substring(s, o+2, -1);
 335                                 if(cvar_string(k) != v)
 336                                         goto cvar_fail;
 337                         }
 338                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 339                         {
 340                                 k = substring(s, 0, o);
 341                                 v = substring(s, o+2, -1);
 342                                 if(cvar_string(k) == v)
 343                                         goto cvar_fail;
 344                         }
 345                         else if(substring(s, 0, 1) == "!")
 346                         {
 347                                 k = substring(s, 1, -1);
 348                                 if(cvar(k))
 349                                         goto cvar_fail;
 350                         }
 351                         else
 352                         {
 353                                 k = s;
 354                                 if (!cvar(k))
 355                                         goto cvar_fail;
 356                         }
 357                 }
 358                 inv = !inv;
 359 LABEL(cvar_fail)
 360                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 361                 if (!inv)
 362                 {
 363                         //print("cvarfilter fail\n");
 364                         delete(this);
 365                         __spawnfunc_expecting = false;
 366                         return;
 367                 }
 368         }
 369
 370         if(DoesQ3ARemoveThisEntity(this))
 371         {
 372                 delete(this);
 373                 __spawnfunc_expecting = false;
 374                 return;
 375         }
 376
 377         set_movetype(this, this.movetype);
 378
 379         // support special -1 and -2 angle from radiant
 380         if (this.angles == '0 -1 0')
 381                 this.angles = '-90 0 0';
 382         else if (this.angles == '0 -2 0')
 383                 this.angles = '+90 0 0';
 384
 385         if(this.originjitter.x != 0)
 386                 this.origin_x = this.origin.x + (random() * 2 - 1) * this.originjitter.x;
 387         if(this.originjitter.y != 0)
 388                 this.origin_y = this.origin.y + (random() * 2 - 1) * this.originjitter.y;
 389         if(this.originjitter.z != 0)
 390                 this.origin_z = this.origin.z + (random() * 2 - 1) * this.originjitter.z;
 391         if(this.anglesjitter.x != 0)
 392                 this.angles_x = this.angles.x + (random() * 2 - 1) * this.anglesjitter.x;
 393         if(this.anglesjitter.y != 0)
 394                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglesjitter.y;
 395         if(this.anglesjitter.z != 0)
 396                 this.angles_z = this.angles.z + (random() * 2 - 1) * this.anglesjitter.z;
 397         if(this.anglejitter != 0)
 398                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglejitter;
 399
 400         if(MUTATOR_CALLHOOK(OnEntityPreSpawn, this))
 401         {
 402                 delete(this);
 403                 __spawnfunc_expecting = false;
 404                 return;
 405         }
 406 }
 407
 408 void WarpZone_PostInitialize_Callback()
 409 {
 410         // create waypoint links for warpzones
 411         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 412         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 413         {
 414                 vector src, dst;
 415                 src = (e.absmin + e.absmax) * 0.5;
 416                 makevectors(e.warpzone_angles);
 417                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 418                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 419                 makevectors(e.enemy.warpzone_angles);
 420                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 421                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 422         }
 423 }