just slightly more RL start speed...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / sv_main.qc
1
2 void CreatureFrame (void)
3 {
4         local entity oldself;
5         local float dm, maxspeed;
6         oldself = self;
7         self = findfloat(world, iscreature, TRUE);
8         while (self)
9         {
10                 if (self.movetype != MOVETYPE_NOCLIP)
11                 {
12                         if (self.waterlevel)
13                         {
14                                 if (!(self.flags & FL_INWATER))
15                                 {
16                                         self.flags |= FL_INWATER;
17                                         self.dmgtime = 0;
18                                 }
19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
20                                 {
21                                         if(self.air_finished < time + 9)
22                                                 PlayerSound(playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
23                                         self.air_finished = time + 12;
24                                         self.dmg = 2;
25                                 }
26                                 else if (self.air_finished < time)
27                                 {       // drown!
28                                         if (!self.deadflag)
29                                         if (self.pain_finished < time)
30                                         {
31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
32                                                 self.pain_finished = time + 0.5;
33                                         }
34                                 }
35                                 if (self.dmgtime < time)
36                                 {
37                                         self.dmgtime = time + 0.1;
38                                         if (self.watertype == CONTENT_LAVA)
39                                         {
40                                                 if (self.watersound_finished < time)
41                                                 {
42                                                         self.watersound_finished = time + 0.5;
43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
44                                                 }
45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
46                                         }
47                                         else if (self.watertype == CONTENT_SLIME)
48                                         {
49                                                 if (self.watersound_finished < time)
50                                                 {
51                                                         self.watersound_finished = time + 0.5;
52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
53                                                 }
54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
55                                         }
56                                 }
57                         }
58                         else
59                         {
60                                 if (self.flags & FL_INWATER)
61                                 {
62                                         // play leave water sound
63                                         self.flags &~= FL_INWATER;
64                                         self.dmgtime = 0;
65                                 }
66                                 self.air_finished = time + 12;
67                                 self.dmg = 2;
68                         }
69                         // check for falling damage
70                         if(!self.hook.state && !g_ca && !(g_cts && !cvar("g_cts_selfdamage")))
71                         {
72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
73                                 if (self.deadflag)
74                                         dm = (dm - cvar("g_balance_falldamage_deadminspeed")) * cvar("g_balance_falldamage_factor");
75                                 else
76                                         dm = min((dm - cvar("g_balance_falldamage_minspeed")) * cvar("g_balance_falldamage_factor"), cvar("g_balance_falldamage_maxdamage"));
77                                 if (dm > 0)
78                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
79                         }
80
81                         maxspeed = cvar("g_maxspeed");
82                         if(maxspeed > 0 && vlen(self.velocity) > maxspeed)
83                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
84
85                         // play stupid sounds
86                         if (g_footsteps)
87                         if (!gameover)
88                         if (self.flags & FL_ONGROUND)
89                         if (vlen(self.velocity) > sv_maxspeed * 0.6)
90                         if (!self.deadflag)
91                         if (time < self.lastground + 0.2)
92                         {
93                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
94                                 {
95                                         self.nextstep = time + 0.3 + random() * 0.1;
96                                         trace_dphitq3surfaceflags = 0;
97                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
98                                         /*
99                                         if(trace_fraction == 1)
100                                                 dprint("nohit\n");
101                                         else
102                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
103                                         */
104                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
105                                         {
106                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
107                                                         GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
108                                                 else
109                                                         GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
110                                         }
111                                 }
112                         }
113                         self.oldvelocity = self.velocity;
114                 }
115                 self = findfloat(self, iscreature, TRUE);
116         }
117         self = oldself;
118 }
119
120
121 /*
122 =============
123 StartFrame
124
125 Called before each frame by the server
126 =============
127 */
128
129 float game_delay;
130 float game_delay_last;
131
132 void RuneMatchGivePoints();
133 float RedirectionThink();
134 entity SelectSpawnPoint (float anypoint);
135 void StartFrame (void)
136 {
137         remove = remove_unsafely; // not during spawning!
138         serverprevtime = servertime;
139         servertime = time;
140         serverframetime = frametime;
141
142 #ifdef PROFILING
143         if(time > client_cefc_accumulatortime + 1)
144         {
145                 float t, pp, c_seeing, c_seen;
146                 entity cl;
147                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
148                 print("CEFC time: ", ftos(t * 1000), "ms; ");
149                 c_seeing = 0;
150                 c_seen = 0;
151                 FOR_EACH_CLIENT(cl)
152                 {
153                         if(clienttype(cl) == CLIENTTYPE_REAL)
154                                 ++c_seeing;
155                         if(cl.classname == "player")
156                                 ++c_seen;
157                 }
158                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
159                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
160
161                 client_cefc_accumulatortime = time;
162                 client_cefc_accumulator = 0;
163         }
164 #endif
165
166         entity e;
167         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
168                 CSQCProjectile_Check(e);
169
170         if(RedirectionThink())
171                 return;
172
173         UncustomizeEntitiesRun();
174         InitializeEntitiesRun();
175
176         WarpZone_StartFrame();
177
178         sv_gravity = cvar("sv_gravity");
179         sv_maxairspeed = cvar("sv_maxairspeed");
180         sv_maxspeed = cvar ("sv_maxspeed");
181         sv_friction = cvar ("sv_friction");
182         sv_accelerate = cvar ("sv_accelerate");
183         sv_airaccelerate = cvar("sv_airaccelerate");
184         sv_airaccel_sideways_friction = cvar("sv_airaccel_sideways_friction");
185         sv_airaccel_qw = cvar("sv_airaccel_qw");
186         sv_stopspeed = cvar ("sv_stopspeed");
187         sv_airstopaccelerate = cvar("sv_airstopaccelerate");
188         sv_airstrafeaccelerate = cvar("sv_airstrafeaccelerate");
189         sv_maxairstrafespeed = cvar("sv_maxairstrafespeed");
190         sv_airstrafeaccel_qw = cvar("sv_airstrafeaccel_qw");
191         sv_aircontrol = cvar("sv_aircontrol");
192         sv_aircontrol_penalty = cvar("sv_aircontrol_penalty");
193         sv_aircontrol_power = cvar("sv_aircontrol_power");
194         sv_warsowbunny_airforwardaccel = cvar("sv_warsowbunny_airforwardaccel");
195         sv_warsowbunny_accel = cvar("sv_warsowbunny_accel");
196         sv_warsowbunny_topspeed = cvar("sv_warsowbunny_topspeed");
197         sv_warsowbunny_turnaccel = cvar("sv_warsowbunny_turnaccel");
198         sv_warsowbunny_backtosideratio = cvar("sv_warsowbunny_backtosideratio");
199         sv_airspeedlimit_nonqw = cvar("sv_airspeedlimit_nonqw");
200         teamplay = cvar ("teamplay");
201         sys_frametime = cvar("sys_ticrate") * cvar("slowmo");
202         sv_doublejump = cvar("sv_doublejump");
203
204         if (timeoutStatus == 1) // just before the timeout (when timeoutStatus will be 2)
205                 orig_slowmo = cvar("slowmo"); // slowmo will be restored after the timeout
206
207         if(teams_matter && !teamplay)
208                 teamplay = 3;
209         if(!teams_matter && teamplay)
210                 teamplay = 0;
211
212         skill = cvar("skill");
213
214         Spawnqueue_Check();
215
216
217         // detect when the pre-game countdown (if any) has ended and the game has started
218         game_delay = (time < game_starttime) ? TRUE : FALSE;
219
220         if(game_delay_last == TRUE)
221         if(game_delay == FALSE)
222         if(cvar("sv_eventlog"))
223                         GameLogEcho(":startdelay_ended");
224
225         game_delay_last = game_delay;
226
227         // if in warmup stage and limit for warmup is hit start match
228         if (inWarmupStage)
229         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
230          || (g_warmup_limit == 0 && cvar("timelimit") != 0 && time >= cvar("timelimit") * 60))
231         {
232                 ReadyRestart();
233                 return;
234         }
235
236         CreatureFrame ();
237         CheckRules_World ();
238
239         AuditTeams();
240
241         RuneMatchGivePoints();
242         bot_serverframe();
243
244         if(cvar("spawn_debugview"))
245         {
246                 RandomSelection_Init();
247                 for(self = world; (self = find(self, classname, "player")); )
248                         RandomSelection_Add(self, 0, string_null, 1, 0);
249                 self = RandomSelection_chosen_ent;
250                 SelectSpawnPoint(0);
251         }
252
253         FOR_EACH_PLAYER(self)
254                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
255 }
256
257 .vector originjitter;
258 .vector anglesjitter;
259 .float anglejitter;
260 .string gametypefilter;
261 .string cvarfilter;
262 void SV_OnEntityPreSpawnFunction()
263 {
264         if(self.gametypefilter != "")
265         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))
266         {
267                 remove(self);
268                 return;
269         }
270         if(self.cvarfilter != "")
271         {
272                 float n, i, o, inv;
273                 string s, k, v;
274                 inv = 0;
275
276                 s = self.cvarfilter;
277                 if(substring(s, 0, 1) == "+")
278                 {
279                         s = substring(s, 1, -1);
280                 }
281                 else if(substring(s, 0, 1) == "-")
282                 {
283                         inv = 1;
284                         s = substring(s, 1, -1);
285                 }
286
287                 n = tokenize(s);
288                 for(i = 0; i < n; ++i)
289                 {
290                         s = argv(i);
291                         // syntax:
292                         // var>x
293                         // var<x
294                         // var>=x
295                         // var<=x
296                         // var==x
297                         // var!=x
298                         // var===x
299                         // var!==x
300                         if((o = strstrofs(s, ">=", 0)) >= 0)
301                         {
302                                 k = substring(s, 0, o);
303                                 v = substring(s, o+2, -1);
304                                 if(cvar(k) < stof(v))
305                                         goto cvar_fail;
306                         }
307                         else if((o = strstrofs(s, "<=", 0)) >= 0)
308                         {
309                                 k = substring(s, 0, o);
310                                 v = substring(s, o+2, -1);
311                                 if(cvar(k) > stof(v))
312                                         goto cvar_fail;
313                         }
314                         else if((o = strstrofs(s, ">", 0)) >= 0)
315                         {
316                                 k = substring(s, 0, o);
317                                 v = substring(s, o+1, -1);
318                                 if(cvar(k) <= stof(v))
319                                         goto cvar_fail;
320                         }
321                         else if((o = strstrofs(s, "<", 0)) >= 0)
322                         {
323                                 k = substring(s, 0, o);
324                                 v = substring(s, o+1, -1);
325                                 if(cvar(k) >= stof(v))
326                                         goto cvar_fail;
327                         }
328                         else if((o = strstrofs(s, "==", 0)) >= 0)
329                         {
330                                 k = substring(s, 0, o);
331                                 v = substring(s, o+2, -1);
332                                 if(cvar(k) != stof(v))
333                                         goto cvar_fail;
334                         }
335                         else if((o = strstrofs(s, "!=", 0)) >= 0)
336                         {
337                                 k = substring(s, 0, o);
338                                 v = substring(s, o+2, -1);
339                                 if(cvar(k) == stof(v))
340                                         goto cvar_fail;
341                         }
342                         else if((o = strstrofs(s, "===", 0)) >= 0)
343                         {
344                                 k = substring(s, 0, o);
345                                 v = substring(s, o+2, -1);
346                                 if(cvar_string(k) != v)
347                                         goto cvar_fail;
348                         }
349                         else if((o = strstrofs(s, "!==", 0)) >= 0)
350                         {
351                                 k = substring(s, 0, o);
352                                 v = substring(s, o+2, -1);
353                                 if(cvar_string(k) == v)
354                                         goto cvar_fail;
355                         }
356                         else if(substring(s, 0, 1) == "!")
357                         {
358                                 k = substring(s, 1, -1);
359                                 if(cvar(k))
360                                         goto cvar_fail;
361                         }
362                         else
363                         {
364                                 k = s;
365                                 if not(cvar(k))
366                                         goto cvar_fail;
367                         }
368                 }
369                 inv = !inv;
370 :cvar_fail
371                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
372                 if not(inv)
373                 {
374                         //print("cvarfilter fail\n");
375                         remove(self);
376                         return;
377                 }
378         }
379
380         // support special -1 and -2 angle from radiant
381         if (self.angles == '0 -1 0')
382                 self.angles = '-90 0 0';
383         else if (self.angles == '0 -2 0')
384                 self.angles = '+90 0 0';
385
386         if(self.originjitter_x != 0)
387                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
388         if(self.originjitter_y != 0)
389                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
390         if(self.originjitter_z != 0)
391                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
392         if(self.anglesjitter_x != 0)
393                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
394         if(self.anglesjitter_y != 0)
395                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
396         if(self.anglesjitter_z != 0)
397                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
398         if(self.anglejitter != 0)
399                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
400
401         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
402         {
403                 remove(self);
404                 return;
405         }
406 }