qcsrc/server/sv_main.qc

   1 #include "_all.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "command/common.qh"
   8
   9 #include "mutators/mutators_include.qh"
  10 #include "weapons/csqcprojectile.qh"
  11
  12 #include "../common/constants.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/util.qh"
  16
  17 #include "../common/vehicles/all.qh"
  18 #include "../common/weapons/all.qh"
  19
  20 #include "../csqcmodellib/sv_model.qh"
  21
  22 #include "../warpzonelib/common.qh"
  23 #include "../warpzonelib/server.qh"
  24
  25 .float lastground;
  26
  27 void CreatureFrame (void)
  28 {SELFPARAM();
  29         float dm;
  30
  31         for(entity e = world; (e = findfloat(e, damagedbycontents, true)); )
  32         {
  33                 setself(e);
  34                 if (self.movetype == MOVETYPE_NOCLIP) { continue; }
  35
  36                 float vehic = IS_VEHICLE(self);
  37                 float projectile = (self.flags & FL_PROJECTILE);
  38                 float monster = IS_MONSTER(self);
  39
  40                 if (self.watertype <= CONTENT_WATER && self.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  41                 {
  42                         if (!(self.flags & FL_INWATER))
  43                         {
  44                                 self.flags |= FL_INWATER;
  45                                 self.dmgtime = 0;
  46                         }
  47
  48                         if(!vehic && !projectile && !monster) // vehicles, monsters and projectiles don't drown
  49                         {
  50                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  51                                 {
  52                                         if(self.air_finished < time)
  53                                                 PlayerSound(playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
  54                                         self.air_finished = time + autocvar_g_balance_contents_drowndelay;
  55                                         self.dmg = 2;
  56                                 }
  57                                 else if (self.air_finished < time)
  58                                 {       // drown!
  59                                         if (!self.deadflag)
  60                                         if (self.pain_finished < time)
  61                                         {
  62                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN, self.origin, '0 0 0');
  63                                                 self.pain_finished = time + 0.5;
  64                                         }
  65                                 }
  66                         }
  67
  68                         if (self.dmgtime < time)
  69                         {
  70                                 self.dmgtime = time + autocvar_g_balance_contents_damagerate;
  71
  72                                 if (projectile)
  73                                 {
  74                                         if (self.watertype == CONTENT_LAVA)
  75                                         {
  76                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  77                                         }
  78                                         else if (self.watertype == CONTENT_SLIME)
  79                                         {
  80                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  81                                         }
  82                                 }
  83                                 else
  84                                 {
  85                                         if (self.watertype == CONTENT_LAVA)
  86                                         {
  87                                                 if (self.watersound_finished < time)
  88                                                 {
  89                                                         self.watersound_finished = time + 0.5;
  90                                                         sound (self, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  91                                                 }
  92                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  93                                         }
  94                                         else if (self.watertype == CONTENT_SLIME)
  95                                         {
  96                                                 if (self.watersound_finished < time)
  97                                                 {
  98                                                         self.watersound_finished = time + 0.5;
  99                                                         sound (self, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
 100                                                 }
 101                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
 102                                         }
 103                                 }
 104                         }
 105                 }
 106                 else
 107                 {
 108                         if (self.flags & FL_INWATER)
 109                         {
 110                                 // play leave water sound
 111                                 self.flags &= ~FL_INWATER;
 112                                 self.dmgtime = 0;
 113                         }
 114                         self.air_finished = time + 12;
 115                         self.dmg = 2;
 116                 }
 117
 118                 if(!vehic && !projectile) // vehicles don't get falling damage
 119                 {
 120                         // check for falling damage
 121                         float velocity_len = vlen(self.velocity);
 122                         if(!self.hook.state)
 123                         {
 124                                 dm = vlen(self.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 125                                 if (self.deadflag)
 126                                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 127                                 else
 128                                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 129                                 if (dm > 0)
 130                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
 131                         }
 132
 133                         if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 134                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
 135                         // play stupid sounds
 136                         if (g_footsteps)
 137                         if (!gameover)
 138                         if (self.flags & FL_ONGROUND)
 139                         if (!self.crouch)
 140                         if (velocity_len > autocvar_sv_maxspeed * 0.6)
 141                         if (!self.deadflag)
 142                         if (time < self.lastground + 0.2)
 143                         {
 144                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
 145                                 {
 146                                         self.nextstep = time + 0.3 + random() * 0.1;
 147                                         trace_dphitq3surfaceflags = 0;
 148                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 149                                         /*
 150                                         if(trace_fraction == 1)
 151                                                 dprint("nohit\n");
 152                                         else
 153                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 154                                         */
 155                                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS))
 156                                         {
 157                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 158                                                         GlobalSound(globalsound_metalstep, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 159                                                 else
 160                                                         GlobalSound(globalsound_step, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 161                                         }
 162                                 }
 163                         }
 164                 }
 165
 166         self.oldvelocity = self.velocity;
 167         }
 168         setself(this);
 169 }
 170
 171
 172 /*
 173 =============
 174 StartFrame
 175
 176 Called before each frame by the server
 177 =============
 178 */
 179
 180 float game_delay;
 181 float game_delay_last;
 182
 183 float RedirectionThink();
 184 void StartFrame (void)
 185 {SELFPARAM();
 186         execute_next_frame();
 187
 188         remove = remove_unsafely; // not during spawning!
 189         serverprevtime = servertime;
 190         servertime = time;
 191         serverframetime = frametime;
 192
 193 #ifdef PROFILING
 194         if(time > client_cefc_accumulatortime + 1)
 195         {
 196                 float t, pp, c_seeing, c_seen;
 197                 entity cl;
 198                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 199                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 200                 c_seeing = 0;
 201                 c_seen = 0;
 202                 FOR_EACH_CLIENT(cl)
 203                 {
 204                         if(IS_REAL_CLIENT(cl))
 205                                 ++c_seeing;
 206                         if(IS_PLAYER(cl))
 207                                 ++c_seen;
 208                 }
 209                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 210                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 211
 212                 client_cefc_accumulatortime = time;
 213                 client_cefc_accumulator = 0;
 214         }
 215 #endif
 216
 217         for(entity e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 218                 CSQCProjectile_Check(e);
 219
 220         if(RedirectionThink())
 221                 return;
 222
 223         UncustomizeEntitiesRun();
 224         InitializeEntitiesRun();
 225
 226         WarpZone_StartFrame();
 227
 228         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 229         if(sys_frametime <= 0)
 230                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 231
 232         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 233                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 234
 235         skill = autocvar_skill;
 236
 237         // detect when the pre-game countdown (if any) has ended and the game has started
 238         game_delay = (time < game_starttime) ? true : false;
 239
 240         if(game_delay_last == true)
 241         if(game_delay == false)
 242         if(autocvar_sv_eventlog)
 243                 GameLogEcho(":startdelay_ended");
 244
 245         game_delay_last = game_delay;
 246
 247         CreatureFrame ();
 248         CheckRules_World ();
 249
 250         // if in warmup stage and limit for warmup is hit start match
 251         if(warmup_stage)
 252         if(!gameover)
 253         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 254          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 255         {
 256                 ReadyRestart();
 257                 return;
 258         }
 259
 260         bot_serverframe();
 261
 262         entity e;
 263         FOR_EACH_PLAYER(e)
 264                 e.porto_forbidden = max(0, e.porto_forbidden - 1);
 265
 266         anticheat_startframe();
 267
 268         MUTATOR_CALLHOOK(SV_StartFrame);
 269 }
 270
 271 .vector originjitter;
 272 .vector anglesjitter;
 273 .float anglejitter;
 274 .string gametypefilter;
 275 .string cvarfilter;
 276 float DoesQ3ARemoveThisEntity();
 277 void SV_OnEntityPreSpawnFunction()
 278 {SELFPARAM();
 279         if (self)
 280         if (self.gametypefilter != "")
 281         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 282         {
 283                 remove(self);
 284                 return;
 285         }
 286         if(self.cvarfilter != "")
 287         {
 288                 float n, i, o, inv;
 289                 string s, k, v;
 290                 inv = 0;
 291
 292                 s = self.cvarfilter;
 293                 if(substring(s, 0, 1) == "+")
 294                 {
 295                         s = substring(s, 1, -1);
 296                 }
 297                 else if(substring(s, 0, 1) == "-")
 298                 {
 299                         inv = 1;
 300                         s = substring(s, 1, -1);
 301                 }
 302
 303                 n = tokenize_console(s);
 304                 for(i = 0; i < n; ++i)
 305                 {
 306                         s = argv(i);
 307                         // syntax:
 308                         // var>x
 309                         // var<x
 310                         // var>=x
 311                         // var<=x
 312                         // var==x
 313                         // var!=x
 314                         // var===x
 315                         // var!==x
 316                         if((o = strstrofs(s, ">=", 0)) >= 0)
 317                         {
 318                                 k = substring(s, 0, o);
 319                                 v = substring(s, o+2, -1);
 320                                 if(cvar(k) < stof(v))
 321                                         goto cvar_fail;
 322                         }
 323                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 324                         {
 325                                 k = substring(s, 0, o);
 326                                 v = substring(s, o+2, -1);
 327                                 if(cvar(k) > stof(v))
 328                                         goto cvar_fail;
 329                         }
 330                         else if((o = strstrofs(s, ">", 0)) >= 0)
 331                         {
 332                                 k = substring(s, 0, o);
 333                                 v = substring(s, o+1, -1);
 334                                 if(cvar(k) <= stof(v))
 335                                         goto cvar_fail;
 336                         }
 337                         else if((o = strstrofs(s, "<", 0)) >= 0)
 338                         {
 339                                 k = substring(s, 0, o);
 340                                 v = substring(s, o+1, -1);
 341                                 if(cvar(k) >= stof(v))
 342                                         goto cvar_fail;
 343                         }
 344                         else if((o = strstrofs(s, "==", 0)) >= 0)
 345                         {
 346                                 k = substring(s, 0, o);
 347                                 v = substring(s, o+2, -1);
 348                                 if(cvar(k) != stof(v))
 349                                         goto cvar_fail;
 350                         }
 351                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 352                         {
 353                                 k = substring(s, 0, o);
 354                                 v = substring(s, o+2, -1);
 355                                 if(cvar(k) == stof(v))
 356                                         goto cvar_fail;
 357                         }
 358                         else if((o = strstrofs(s, "===", 0)) >= 0)
 359                         {
 360                                 k = substring(s, 0, o);
 361                                 v = substring(s, o+2, -1);
 362                                 if(cvar_string(k) != v)
 363                                         goto cvar_fail;
 364                         }
 365                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 366                         {
 367                                 k = substring(s, 0, o);
 368                                 v = substring(s, o+2, -1);
 369                                 if(cvar_string(k) == v)
 370                                         goto cvar_fail;
 371                         }
 372                         else if(substring(s, 0, 1) == "!")
 373                         {
 374                                 k = substring(s, 1, -1);
 375                                 if(cvar(k))
 376                                         goto cvar_fail;
 377                         }
 378                         else
 379                         {
 380                                 k = s;
 381                                 if (!cvar(k))
 382                                         goto cvar_fail;
 383                         }
 384                 }
 385                 inv = !inv;
 386 :cvar_fail
 387                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 388                 if (!inv)
 389                 {
 390                         //print("cvarfilter fail\n");
 391                         remove(self);
 392                         return;
 393                 }
 394         }
 395
 396         if(DoesQ3ARemoveThisEntity())
 397         {
 398                 remove(self);
 399                 return;
 400         }
 401
 402         // support special -1 and -2 angle from radiant
 403         if (self.angles == '0 -1 0')
 404                 self.angles = '-90 0 0';
 405         else if (self.angles == '0 -2 0')
 406                 self.angles = '+90 0 0';
 407
 408         if(self.originjitter.x != 0)
 409                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 410         if(self.originjitter.y != 0)
 411                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 412         if(self.originjitter.z != 0)
 413                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 414         if(self.anglesjitter.x != 0)
 415                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 416         if(self.anglesjitter.y != 0)
 417                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 418         if(self.anglesjitter.z != 0)
 419                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 420         if(self.anglejitter != 0)
 421                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 422
 423         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 424         {
 425                 remove(self);
 426                 return;
 427         }
 428 }
 429
 430 void WarpZone_PostInitialize_Callback(void)
 431 {
 432         // create waypoint links for warpzones
 433         entity e;
 434         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 435         {
 436                 vector src, dst;
 437                 src = (e.absmin + e.absmax) * 0.5;
 438                 makevectors(e.warpzone_angles);
 439                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 440                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 441                 makevectors(e.enemy.warpzone_angles);
 442                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 443                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 444         }
 445 }