qcsrc/server/sv_main.qc

   1
   2 void CreatureFrame (void)
   3 {
   4         local entity oldself;
   5         local float dm, maxspeed;
   6         oldself = self;
   7         self = findfloat(world, iscreature, TRUE);
   8         while (self)
   9         {
  10                 if (self.movetype != MOVETYPE_NOCLIP)
  11                 {
  12                         if (self.waterlevel)
  13                         {
  14                                 if (!(self.flags & FL_INWATER))
  15                                 {
  16                                         self.flags |= FL_INWATER;
  17                                         self.dmgtime = 0;
  18                                 }
  19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  20                                 {
  21                                         if(self.air_finished < time + 9)
  22                                                 PlayerSound(playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  23                                         self.air_finished = time + 12;
  24                                         self.dmg = 2;
  25                                 }
  26                                 else if (self.air_finished < time)
  27                                 {       // drown!
  28                                         if (!self.deadflag)
  29                                         if (self.pain_finished < time)
  30                                         {
  31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
  32                                                 self.pain_finished = time + 0.5;
  33                                         }
  34                                 }
  35                                 if (self.dmgtime < time)
  36                                 {
  37                                         self.dmgtime = time + 0.2;
  38                                         if (self.watertype == CONTENT_LAVA)
  39                                         {
  40                                                 if (self.watersound_finished < time)
  41                                                 {
  42                                                         self.watersound_finished = time + 0.5;
  43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  44                                                 }
  45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  46                                         }
  47                                         else if (self.watertype == CONTENT_SLIME)
  48                                         {
  49                                                 if (self.watersound_finished < time)
  50                                                 {
  51                                                         self.watersound_finished = time + 0.5;
  52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  53                                                 }
  54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  55                                         }
  56                                 }
  57                         }
  58                         else
  59                         {
  60                                 if (self.flags & FL_INWATER)
  61                                 {
  62                                         // play leave water sound
  63                                         self.flags &~= FL_INWATER;
  64                                         self.dmgtime = 0;
  65                                 }
  66                                 self.air_finished = time + 12;
  67                                 self.dmg = 2;
  68                         }
  69                         // check for falling damage
  70                         if(!self.hook.state && !g_ca && !(g_cts && !cvar("g_cts_selfdamage")))
  71                         {
  72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
  73                                 if (self.deadflag)
  74                                         dm = (dm - cvar("g_balance_falldamage_deadminspeed")) * cvar("g_balance_falldamage_factor");
  75                                 else
  76                                         dm = min((dm - cvar("g_balance_falldamage_minspeed")) * cvar("g_balance_falldamage_factor"), cvar("g_balance_falldamage_maxdamage"));
  77                                 if (dm > 0)
  78                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
  79                         }
  80
  81                         maxspeed = cvar("g_maxspeed");
  82                         if(maxspeed > 0 && vlen(self.velocity) > maxspeed)
  83                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
  84
  85                         // play stupid sounds
  86                         if (g_footsteps)
  87                         if (!gameover)
  88                         if (self.flags & FL_ONGROUND)
  89                         if (vlen(self.velocity) > autocvar_sv_maxspeed * 0.6)
  90                         if (!self.deadflag)
  91                         if (time < self.lastground + 0.2)
  92                         {
  93                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
  94                                 {
  95                                         self.nextstep = time + 0.3 + random() * 0.1;
  96                                         trace_dphitq3surfaceflags = 0;
  97                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
  98                                         /*
  99                                         if(trace_fraction == 1)
 100                                                 dprint("nohit\n");
 101                                         else
 102                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 103                                         */
 104                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 105                                         {
 106                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 107                                                         GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 108                                                 else
 109                                                         GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 110                                         }
 111                                 }
 112                         }
 113                         self.oldvelocity = self.velocity;
 114                 }
 115                 self = findfloat(self, iscreature, TRUE);
 116         }
 117         self = oldself;
 118 }
 119
 120
 121 /*
 122 =============
 123 StartFrame
 124
 125 Called before each frame by the server
 126 =============
 127 */
 128
 129 float game_delay;
 130 float game_delay_last;
 131
 132 void RuneMatchGivePoints();
 133 float RedirectionThink();
 134 entity SelectSpawnPoint (float anypoint);
 135 void StartFrame (void)
 136 {
 137         remove = remove_unsafely; // not during spawning!
 138         serverprevtime = servertime;
 139         servertime = time;
 140         serverframetime = frametime;
 141
 142 #ifdef PROFILING
 143         if(time > client_cefc_accumulatortime + 1)
 144         {
 145                 float t, pp, c_seeing, c_seen;
 146                 entity cl;
 147                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 148                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 149                 c_seeing = 0;
 150                 c_seen = 0;
 151                 FOR_EACH_CLIENT(cl)
 152                 {
 153                         if(clienttype(cl) == CLIENTTYPE_REAL)
 154                                 ++c_seeing;
 155                         if(cl.classname == "player")
 156                                 ++c_seen;
 157                 }
 158                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 159                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 160
 161                 client_cefc_accumulatortime = time;
 162                 client_cefc_accumulator = 0;
 163         }
 164 #endif
 165
 166         entity e;
 167         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 168                 CSQCProjectile_Check(e);
 169
 170         if(RedirectionThink())
 171                 return;
 172
 173         UncustomizeEntitiesRun();
 174         InitializeEntitiesRun();
 175
 176         WarpZone_StartFrame();
 177
 178         sys_frametime = cvar("sys_ticrate") * cvar("slowmo");
 179         if(sys_frametime <= 0)
 180                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 181
 182         if (timeoutStatus == 1) // just before the timeout (when timeoutStatus will be 2)
 183                 orig_slowmo = cvar("slowmo"); // slowmo will be restored after the timeout
 184
 185         if(teams_matter && !autocvar_teamplay)
 186                 cvar_set("teamplay", "3"); // this also updates the autocvar
 187         if(!teams_matter && autocvar_teamplay)
 188                 cvar_set("teamplay", "0"); // this also updates the autocvar
 189
 190         skill = cvar("skill");
 191
 192         Spawnqueue_Check();
 193
 194
 195         // detect when the pre-game countdown (if any) has ended and the game has started
 196         game_delay = (time < game_starttime) ? TRUE : FALSE;
 197
 198         if(game_delay_last == TRUE)
 199         if(game_delay == FALSE)
 200         if(cvar("sv_eventlog"))
 201                         GameLogEcho(":startdelay_ended");
 202
 203         game_delay_last = game_delay;
 204
 205         // if in warmup stage and limit for warmup is hit start match
 206         if (inWarmupStage)
 207         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
 208          || (g_warmup_limit == 0 && cvar("timelimit") != 0 && time >= cvar("timelimit") * 60))
 209         {
 210                 ReadyRestart();
 211                 return;
 212         }
 213
 214         CreatureFrame ();
 215         CheckRules_World ();
 216
 217         AuditTeams();
 218
 219         RuneMatchGivePoints();
 220         bot_serverframe();
 221
 222         if(cvar("spawn_debugview"))
 223         {
 224                 RandomSelection_Init();
 225                 for(self = world; (self = find(self, classname, "player")); )
 226                         RandomSelection_Add(self, 0, string_null, 1, 0);
 227                 self = RandomSelection_chosen_ent;
 228                 SelectSpawnPoint(0);
 229         }
 230
 231         FOR_EACH_PLAYER(self)
 232                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 233 }
 234
 235 .vector originjitter;
 236 .vector anglesjitter;
 237 .float anglejitter;
 238 .string gametypefilter;
 239 .string cvarfilter;
 240 void SV_OnEntityPreSpawnFunction()
 241 {
 242         if(self.gametypefilter != "")
 243         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))
 244         {
 245                 remove(self);
 246                 return;
 247         }
 248         if(self.cvarfilter != "")
 249         {
 250                 float n, i, o, inv;
 251                 string s, k, v;
 252                 inv = 0;
 253
 254                 s = self.cvarfilter;
 255                 if(substring(s, 0, 1) == "+")
 256                 {
 257                         s = substring(s, 1, -1);
 258                 }
 259                 else if(substring(s, 0, 1) == "-")
 260                 {
 261                         inv = 1;
 262                         s = substring(s, 1, -1);
 263                 }
 264
 265                 n = tokenize(s);
 266                 for(i = 0; i < n; ++i)
 267                 {
 268                         s = argv(i);
 269                         // syntax:
 270                         // var>x
 271                         // var<x
 272                         // var>=x
 273                         // var<=x
 274                         // var==x
 275                         // var!=x
 276                         // var===x
 277                         // var!==x
 278                         if((o = strstrofs(s, ">=", 0)) >= 0)
 279                         {
 280                                 k = substring(s, 0, o);
 281                                 v = substring(s, o+2, -1);
 282                                 if(cvar(k) < stof(v))
 283                                         goto cvar_fail;
 284                         }
 285                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 286                         {
 287                                 k = substring(s, 0, o);
 288                                 v = substring(s, o+2, -1);
 289                                 if(cvar(k) > stof(v))
 290                                         goto cvar_fail;
 291                         }
 292                         else if((o = strstrofs(s, ">", 0)) >= 0)
 293                         {
 294                                 k = substring(s, 0, o);
 295                                 v = substring(s, o+1, -1);
 296                                 if(cvar(k) <= stof(v))
 297                                         goto cvar_fail;
 298                         }
 299                         else if((o = strstrofs(s, "<", 0)) >= 0)
 300                         {
 301                                 k = substring(s, 0, o);
 302                                 v = substring(s, o+1, -1);
 303                                 if(cvar(k) >= stof(v))
 304                                         goto cvar_fail;
 305                         }
 306                         else if((o = strstrofs(s, "==", 0)) >= 0)
 307                         {
 308                                 k = substring(s, 0, o);
 309                                 v = substring(s, o+2, -1);
 310                                 if(cvar(k) != stof(v))
 311                                         goto cvar_fail;
 312                         }
 313                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 314                         {
 315                                 k = substring(s, 0, o);
 316                                 v = substring(s, o+2, -1);
 317                                 if(cvar(k) == stof(v))
 318                                         goto cvar_fail;
 319                         }
 320                         else if((o = strstrofs(s, "===", 0)) >= 0)
 321                         {
 322                                 k = substring(s, 0, o);
 323                                 v = substring(s, o+2, -1);
 324                                 if(cvar_string(k) != v)
 325                                         goto cvar_fail;
 326                         }
 327                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 328                         {
 329                                 k = substring(s, 0, o);
 330                                 v = substring(s, o+2, -1);
 331                                 if(cvar_string(k) == v)
 332                                         goto cvar_fail;
 333                         }
 334                         else if(substring(s, 0, 1) == "!")
 335                         {
 336                                 k = substring(s, 1, -1);
 337                                 if(cvar(k))
 338                                         goto cvar_fail;
 339                         }
 340                         else
 341                         {
 342                                 k = s;
 343                                 if not(cvar(k))
 344                                         goto cvar_fail;
 345                         }
 346                 }
 347                 inv = !inv;
 348 :cvar_fail
 349                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 350                 if not(inv)
 351                 {
 352                         //print("cvarfilter fail\n");
 353                         remove(self);
 354                         return;
 355                 }
 356         }
 357
 358         // support special -1 and -2 angle from radiant
 359         if (self.angles == '0 -1 0')
 360                 self.angles = '-90 0 0';
 361         else if (self.angles == '0 -2 0')
 362                 self.angles = '+90 0 0';
 363
 364         if(self.originjitter_x != 0)
 365                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 366         if(self.originjitter_y != 0)
 367                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 368         if(self.originjitter_z != 0)
 369                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 370         if(self.anglesjitter_x != 0)
 371                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 372         if(self.anglesjitter_y != 0)
 373                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 374         if(self.anglesjitter_z != 0)
 375                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 376         if(self.anglejitter != 0)
 377                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 378
 379         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 380         {
 381                 remove(self);
 382                 return;
 383         }
 384 }