Oops, update one cvar because I forgot to change it
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / sv_main.qc
1
2 void CreatureFrame (void)
3 {
4         local entity oldself;
5         local float dm, maxspeed;
6         oldself = self;
7         self = findfloat(world, iscreature, TRUE);
8         while (self)
9         {
10                 if (self.movetype != MOVETYPE_NOCLIP)
11                 {
12                         if (self.waterlevel)
13                         {
14                                 if (!(self.flags & FL_INWATER))
15                                 {
16                                         self.flags |= FL_INWATER;
17                                         self.dmgtime = 0;
18                                 }
19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
20                                 {
21                                         if(self.air_finished < time + 9)
22                                                 PlayerSound(playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
23                                         self.air_finished = time + 12;
24                                         self.dmg = 2;
25                                 }
26                                 else if (self.air_finished < time)
27                                 {       // drown!
28                                         if (!self.deadflag)
29                                         if (self.pain_finished < time)
30                                         {
31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
32                                                 self.pain_finished = time + 0.5;
33                                         }
34                                 }
35                                 if (self.dmgtime < time)
36                                 {
37                                         self.dmgtime = time + 0.2;
38                                         if (self.watertype == CONTENT_LAVA)
39                                         {
40                                                 if (self.watersound_finished < time)
41                                                 {
42                                                         self.watersound_finished = time + 0.5;
43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
44                                                 }
45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
46                                         }
47                                         else if (self.watertype == CONTENT_SLIME)
48                                         {
49                                                 if (self.watersound_finished < time)
50                                                 {
51                                                         self.watersound_finished = time + 0.5;
52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
53                                                 }
54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
55                                         }
56                                 }
57                         }
58                         else
59                         {
60                                 if (self.flags & FL_INWATER)
61                                 {
62                                         // play leave water sound
63                                         self.flags &~= FL_INWATER;
64                                         self.dmgtime = 0;
65                                 }
66                                 self.air_finished = time + 12;
67                                 self.dmg = 2;
68                         }
69                         // check for falling damage
70                         if(!self.hook.state && !g_ca && !(g_cts && !autocvar_g_cts_selfdamage))
71                         {
72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
73                                 if (self.deadflag)
74                                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
75                                 else
76                                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
77                                 if (dm > 0)
78                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
79                         }
80
81                         maxspeed = autocvar_g_maxspeed;
82                         if(maxspeed > 0 && vlen(self.velocity) > maxspeed)
83                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
84
85                         // play stupid sounds
86                         if (g_footsteps)
87                         if (!gameover)
88                         if (self.flags & FL_ONGROUND)
89                         if (vlen(self.velocity) > autocvar_sv_maxspeed * 0.6)
90                         if (!self.deadflag)
91                         if (time < self.lastground + 0.2)
92                         {
93                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
94                                 {
95                                         self.nextstep = time + 0.3 + random() * 0.1;
96                                         trace_dphitq3surfaceflags = 0;
97                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
98                                         /*
99                                         if(trace_fraction == 1)
100                                                 dprint("nohit\n");
101                                         else
102                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
103                                         */
104                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
105                                         {
106                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
107                                                         GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
108                                                 else
109                                                         GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
110                                         }
111                                 }
112                         }
113                         self.oldvelocity = self.velocity;
114                 }
115                 self = findfloat(self, iscreature, TRUE);
116         }
117         self = oldself;
118 }
119
120
121 /*
122 =============
123 StartFrame
124
125 Called before each frame by the server
126 =============
127 */
128
129 float game_delay;
130 float game_delay_last;
131
132 void RuneMatchGivePoints();
133 float RedirectionThink();
134 entity SelectSpawnPoint (float anypoint);
135 void StartFrame (void)
136 {
137         remove = remove_unsafely; // not during spawning!
138         serverprevtime = servertime;
139         servertime = time;
140         serverframetime = frametime;
141
142 #ifdef PROFILING
143         if(time > client_cefc_accumulatortime + 1)
144         {
145                 float t, pp, c_seeing, c_seen;
146                 entity cl;
147                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
148                 print("CEFC time: ", ftos(t * 1000), "ms; ");
149                 c_seeing = 0;
150                 c_seen = 0;
151                 FOR_EACH_CLIENT(cl)
152                 {
153                         if(clienttype(cl) == CLIENTTYPE_REAL)
154                                 ++c_seeing;
155                         if(cl.classname == "player")
156                                 ++c_seen;
157                 }
158                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
159                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
160
161                 client_cefc_accumulatortime = time;
162                 client_cefc_accumulator = 0;
163         }
164 #endif
165
166         entity e;
167         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
168                 CSQCProjectile_Check(e);
169
170         if(RedirectionThink())
171                 return;
172
173         UncustomizeEntitiesRun();
174         InitializeEntitiesRun();
175
176         WarpZone_StartFrame();
177
178         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
179         if(sys_frametime <= 0)
180                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
181
182         if (timeoutStatus == 1) // just before the timeout (when timeoutStatus will be 2)
183                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
184
185         skill = autocvar_skill;
186
187         Spawnqueue_Check();
188
189
190         // detect when the pre-game countdown (if any) has ended and the game has started
191         game_delay = (time < game_starttime) ? TRUE : FALSE;
192
193         if(game_delay_last == TRUE)
194         if(game_delay == FALSE)
195         if(autocvar_sv_eventlog)
196                         GameLogEcho(":startdelay_ended");
197
198         game_delay_last = game_delay;
199
200         // if in warmup stage and limit for warmup is hit start match
201         if (inWarmupStage)
202         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
203          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
204         {
205                 ReadyRestart();
206                 return;
207         }
208
209         CreatureFrame ();
210         CheckRules_World ();
211
212         AuditTeams();
213
214         RuneMatchGivePoints();
215         bot_serverframe();
216
217         if(autocvar_spawn_debugview)
218         {
219                 RandomSelection_Init();
220                 for(self = world; (self = find(self, classname, "player")); )
221                         RandomSelection_Add(self, 0, string_null, 1, 0);
222                 self = RandomSelection_chosen_ent;
223                 SelectSpawnPoint(0);
224         }
225
226         FOR_EACH_PLAYER(self)
227                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
228 }
229
230 .vector originjitter;
231 .vector anglesjitter;
232 .float anglejitter;
233 .string gametypefilter;
234 .string cvarfilter;
235 void SV_OnEntityPreSpawnFunction()
236 {
237         if(self.gametypefilter != "")
238         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))
239         {
240                 remove(self);
241                 return;
242         }
243         if(self.cvarfilter != "")
244         {
245                 float n, i, o, inv;
246                 string s, k, v;
247                 inv = 0;
248
249                 s = self.cvarfilter;
250                 if(substring(s, 0, 1) == "+")
251                 {
252                         s = substring(s, 1, -1);
253                 }
254                 else if(substring(s, 0, 1) == "-")
255                 {
256                         inv = 1;
257                         s = substring(s, 1, -1);
258                 }
259
260                 n = tokenize(s);
261                 for(i = 0; i < n; ++i)
262                 {
263                         s = argv(i);
264                         // syntax:
265                         // var>x
266                         // var<x
267                         // var>=x
268                         // var<=x
269                         // var==x
270                         // var!=x
271                         // var===x
272                         // var!==x
273                         if((o = strstrofs(s, ">=", 0)) >= 0)
274                         {
275                                 k = substring(s, 0, o);
276                                 v = substring(s, o+2, -1);
277                                 if(cvar(k) < stof(v))
278                                         goto cvar_fail;
279                         }
280                         else if((o = strstrofs(s, "<=", 0)) >= 0)
281                         {
282                                 k = substring(s, 0, o);
283                                 v = substring(s, o+2, -1);
284                                 if(cvar(k) > stof(v))
285                                         goto cvar_fail;
286                         }
287                         else if((o = strstrofs(s, ">", 0)) >= 0)
288                         {
289                                 k = substring(s, 0, o);
290                                 v = substring(s, o+1, -1);
291                                 if(cvar(k) <= stof(v))
292                                         goto cvar_fail;
293                         }
294                         else if((o = strstrofs(s, "<", 0)) >= 0)
295                         {
296                                 k = substring(s, 0, o);
297                                 v = substring(s, o+1, -1);
298                                 if(cvar(k) >= stof(v))
299                                         goto cvar_fail;
300                         }
301                         else if((o = strstrofs(s, "==", 0)) >= 0)
302                         {
303                                 k = substring(s, 0, o);
304                                 v = substring(s, o+2, -1);
305                                 if(cvar(k) != stof(v))
306                                         goto cvar_fail;
307                         }
308                         else if((o = strstrofs(s, "!=", 0)) >= 0)
309                         {
310                                 k = substring(s, 0, o);
311                                 v = substring(s, o+2, -1);
312                                 if(cvar(k) == stof(v))
313                                         goto cvar_fail;
314                         }
315                         else if((o = strstrofs(s, "===", 0)) >= 0)
316                         {
317                                 k = substring(s, 0, o);
318                                 v = substring(s, o+2, -1);
319                                 if(cvar_string(k) != v)
320                                         goto cvar_fail;
321                         }
322                         else if((o = strstrofs(s, "!==", 0)) >= 0)
323                         {
324                                 k = substring(s, 0, o);
325                                 v = substring(s, o+2, -1);
326                                 if(cvar_string(k) == v)
327                                         goto cvar_fail;
328                         }
329                         else if(substring(s, 0, 1) == "!")
330                         {
331                                 k = substring(s, 1, -1);
332                                 if(cvar(k))
333                                         goto cvar_fail;
334                         }
335                         else
336                         {
337                                 k = s;
338                                 if not(cvar(k))
339                                         goto cvar_fail;
340                         }
341                 }
342                 inv = !inv;
343 :cvar_fail
344                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
345                 if not(inv)
346                 {
347                         //print("cvarfilter fail\n");
348                         remove(self);
349                         return;
350                 }
351         }
352
353         // support special -1 and -2 angle from radiant
354         if (self.angles == '0 -1 0')
355                 self.angles = '-90 0 0';
356         else if (self.angles == '0 -2 0')
357                 self.angles = '+90 0 0';
358
359         if(self.originjitter_x != 0)
360                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
361         if(self.originjitter_y != 0)
362                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
363         if(self.originjitter_z != 0)
364                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
365         if(self.anglesjitter_x != 0)
366                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
367         if(self.anglesjitter_y != 0)
368                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
369         if(self.anglesjitter_z != 0)
370                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
371         if(self.anglejitter != 0)
372                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
373
374         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
375         {
376                 remove(self);
377                 return;
378         }
379 }