qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/bot.qh"
   8 #include "bot/waypoints.qh"
   9
  10 #include "command/common.qh"
  11
  12 #include "mutators/all.qh"
  13 #include "weapons/csqcprojectile.qh"
  14
  15 #include "../common/constants.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/debug.qh"
  18 #include "../common/mapinfo.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/vehicles/all.qh"
  22 #include "../common/weapons/all.qh"
  23
  24 #include "../lib/csqcmodel/sv_model.qh"
  25
  26 #include "../lib/warpzone/common.qh"
  27 #include "../lib/warpzone/server.qh"
  28
  29 .float lastground;
  30 .int state;
  31
  32 void CreatureFrame_hotliquids(entity this)
  33 {
  34         if (this.dmgtime < time)
  35         {
  36                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  37
  38                 if (this.flags & FL_PROJECTILE)
  39                 {
  40                         if (this.watertype == CONTENT_LAVA)
  41                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  42                         else if (this.watertype == CONTENT_SLIME)
  43                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  44                 }
  45                 else
  46                 {
  47                         if (this.watertype == CONTENT_LAVA)
  48                         {
  49                                 if (this.watersound_finished < time)
  50                                 {
  51                                         this.watersound_finished = time + 0.5;
  52                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  53                                 }
  54                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  55                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  56                                         Fire_AddDamage(this, world, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  57                         }
  58                         else if (this.watertype == CONTENT_SLIME)
  59                         {
  60                                 if (this.watersound_finished < time)
  61                                 {
  62                                         this.watersound_finished = time + 0.5;
  63                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  64                                 }
  65                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  66                         }
  67                 }
  68         }
  69 }
  70
  71 void CreatureFrame_Liquids(entity this)
  72 {
  73         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  74         {
  75                 if (!(this.flags & FL_INWATER))
  76                 {
  77                         this.flags |= FL_INWATER;
  78                         this.dmgtime = 0;
  79                 }
  80
  81                 CreatureFrame_hotliquids(this);
  82         }
  83         else
  84         {
  85                 if (this.flags & FL_INWATER)
  86                 {
  87                         // play leave water sound
  88                         this.flags &= ~FL_INWATER;
  89                         this.dmgtime = 0;
  90                 }
  91                 this.air_finished = time + 12;
  92                 this.dmg = 2;
  93         }
  94 }
  95
  96 void CreatureFrame_FallDamage(entity this)
  97 {
  98         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 if(!this.hook.state)
 103                 {
 104                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 105                         if (IS_DEAD(this))
 106                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 107                         else
 108                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 109                         if (dm > 0)
 110                                 Damage (this, world, world, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 111                 }
 112
 113                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 114                         Damage (this, world, world, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 115         }
 116 }
 117
 118 void CreatureFrame_All()
 119 {
 120         FOREACH_ENTITY_FLOAT(damagedbycontents, true, LAMBDA(
 121                 if(it.movetype == MOVETYPE_NOCLIP) continue;
 122                 CreatureFrame_Liquids(it);
 123                 CreatureFrame_FallDamage(it);
 124                 it.oldvelocity = it.velocity;
 125         ));
 126 }
 127
 128 void Pause_TryPause(bool ispaused)
 129 {
 130         int n = 0;
 131         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 132                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 133                 ++n;
 134         ));
 135         if (!n) return;
 136         setpause(ispaused);
 137 }
 138
 139 void SV_PausedTic(float elapsedtime)
 140 {
 141         if (!server_is_dedicated) Pause_TryPause(false);
 142 }
 143
 144 /*
 145 =============
 146 StartFrame
 147
 148 Called before each frame by the server
 149 =============
 150 */
 151
 152 float game_delay;
 153 float game_delay_last;
 154
 155 bool autocvar_sv_autopause = true;
 156 float RedirectionThink();
 157 void StartFrame()
 158 {
 159         SELFPARAM();
 160         execute_next_frame();
 161         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 162
 163         remove = remove_unsafely; // not during spawning!
 164         serverprevtime = servertime;
 165         servertime = time;
 166         serverframetime = frametime;
 167
 168 #ifdef PROFILING
 169         if(time > client_cefc_accumulatortime + 1)
 170         {
 171                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 172                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 173                 int c_seeing = 0;
 174                 int c_seen = 0;
 175                 FOREACH_CLIENT(true, LAMBDA(
 176                         if(IS_REAL_CLIENT(it))
 177                                 ++c_seeing;
 178                         if(IS_PLAYER(it))
 179                                 ++c_seen;
 180                 ));
 181                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 182                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 183
 184                 client_cefc_accumulatortime = time;
 185                 client_cefc_accumulator = 0;
 186         }
 187 #endif
 188
 189         FOREACH_ENTITY_FLOAT(csqcprojectile_clientanimate, true, LAMBDA(CSQCProjectile_Check(it)));
 190
 191         if(RedirectionThink())
 192                 return;
 193
 194         UncustomizeEntitiesRun();
 195         InitializeEntitiesRun();
 196
 197         WarpZone_StartFrame();
 198
 199         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 200         if(sys_frametime <= 0)
 201                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 202
 203         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 204                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 205
 206         skill = autocvar_skill;
 207
 208         // detect when the pre-game countdown (if any) has ended and the game has started
 209         game_delay = (time < game_starttime);
 210
 211         if(autocvar_sv_eventlog && game_delay_last && !game_delay)
 212                 GameLogEcho(":startdelay_ended");
 213
 214         game_delay_last = game_delay;
 215
 216         CreatureFrame_All();
 217         CheckRules_World();
 218
 219         // if in warmup stage and limit for warmup is hit start match
 220         if(warmup_stage)
 221         if(!gameover)
 222         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 223          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 224         {
 225                 ReadyRestart();
 226                 return;
 227         }
 228
 229         bot_serverframe();
 230         anticheat_startframe();
 231         MUTATOR_CALLHOOK(SV_StartFrame);
 232
 233     FOREACH_CLIENT(true, LAMBDA(GlobalStats_update(it)));
 234 }
 235
 236 .vector originjitter;
 237 .vector anglesjitter;
 238 .float anglejitter;
 239 .string gametypefilter;
 240 .string cvarfilter;
 241 float DoesQ3ARemoveThisEntity();
 242 void SV_OnEntityPreSpawnFunction()
 243 {SELFPARAM();
 244         __spawnfunc_expect = this;
 245         if (self)
 246         if (self.gametypefilter != "")
 247         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 248         {
 249                 remove(self);
 250                 return;
 251         }
 252         if(self.cvarfilter != "")
 253         {
 254                 float n, i, o, inv;
 255                 string s, k, v;
 256                 inv = 0;
 257
 258                 s = self.cvarfilter;
 259                 if(substring(s, 0, 1) == "+")
 260                 {
 261                         s = substring(s, 1, -1);
 262                 }
 263                 else if(substring(s, 0, 1) == "-")
 264                 {
 265                         inv = 1;
 266                         s = substring(s, 1, -1);
 267                 }
 268
 269                 n = tokenize_console(s);
 270                 for(i = 0; i < n; ++i)
 271                 {
 272                         s = argv(i);
 273                         // syntax:
 274                         // var>x
 275                         // var<x
 276                         // var>=x
 277                         // var<=x
 278                         // var==x
 279                         // var!=x
 280                         // var===x
 281                         // var!==x
 282                         if((o = strstrofs(s, ">=", 0)) >= 0)
 283                         {
 284                                 k = substring(s, 0, o);
 285                                 v = substring(s, o+2, -1);
 286                                 if(cvar(k) < stof(v))
 287                                         goto cvar_fail;
 288                         }
 289                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 290                         {
 291                                 k = substring(s, 0, o);
 292                                 v = substring(s, o+2, -1);
 293                                 if(cvar(k) > stof(v))
 294                                         goto cvar_fail;
 295                         }
 296                         else if((o = strstrofs(s, ">", 0)) >= 0)
 297                         {
 298                                 k = substring(s, 0, o);
 299                                 v = substring(s, o+1, -1);
 300                                 if(cvar(k) <= stof(v))
 301                                         goto cvar_fail;
 302                         }
 303                         else if((o = strstrofs(s, "<", 0)) >= 0)
 304                         {
 305                                 k = substring(s, 0, o);
 306                                 v = substring(s, o+1, -1);
 307                                 if(cvar(k) >= stof(v))
 308                                         goto cvar_fail;
 309                         }
 310                         else if((o = strstrofs(s, "==", 0)) >= 0)
 311                         {
 312                                 k = substring(s, 0, o);
 313                                 v = substring(s, o+2, -1);
 314                                 if(cvar(k) != stof(v))
 315                                         goto cvar_fail;
 316                         }
 317                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 318                         {
 319                                 k = substring(s, 0, o);
 320                                 v = substring(s, o+2, -1);
 321                                 if(cvar(k) == stof(v))
 322                                         goto cvar_fail;
 323                         }
 324                         else if((o = strstrofs(s, "===", 0)) >= 0)
 325                         {
 326                                 k = substring(s, 0, o);
 327                                 v = substring(s, o+2, -1);
 328                                 if(cvar_string(k) != v)
 329                                         goto cvar_fail;
 330                         }
 331                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 332                         {
 333                                 k = substring(s, 0, o);
 334                                 v = substring(s, o+2, -1);
 335                                 if(cvar_string(k) == v)
 336                                         goto cvar_fail;
 337                         }
 338                         else if(substring(s, 0, 1) == "!")
 339                         {
 340                                 k = substring(s, 1, -1);
 341                                 if(cvar(k))
 342                                         goto cvar_fail;
 343                         }
 344                         else
 345                         {
 346                                 k = s;
 347                                 if (!cvar(k))
 348                                         goto cvar_fail;
 349                         }
 350                 }
 351                 inv = !inv;
 352 :cvar_fail
 353                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 354                 if (!inv)
 355                 {
 356                         //print("cvarfilter fail\n");
 357                         remove(self);
 358                         return;
 359                 }
 360         }
 361
 362         if(DoesQ3ARemoveThisEntity())
 363         {
 364                 remove(self);
 365                 return;
 366         }
 367
 368         // support special -1 and -2 angle from radiant
 369         if (self.angles == '0 -1 0')
 370                 self.angles = '-90 0 0';
 371         else if (self.angles == '0 -2 0')
 372                 self.angles = '+90 0 0';
 373
 374         if(self.originjitter.x != 0)
 375                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 376         if(self.originjitter.y != 0)
 377                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 378         if(self.originjitter.z != 0)
 379                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 380         if(self.anglesjitter.x != 0)
 381                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 382         if(self.anglesjitter.y != 0)
 383                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 384         if(self.anglesjitter.z != 0)
 385                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 386         if(self.anglejitter != 0)
 387                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 388
 389         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 390         {
 391                 remove(self);
 392                 return;
 393         }
 394 }
 395
 396 void WarpZone_PostInitialize_Callback()
 397 {
 398         // create waypoint links for warpzones
 399         entity e;
 400         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 401         {
 402                 vector src, dst;
 403                 src = (e.absmin + e.absmax) * 0.5;
 404                 makevectors(e.warpzone_angles);
 405                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 406                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 407                 makevectors(e.enemy.warpzone_angles);
 408                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 409                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 410         }
 411 }