qcsrc/server/sv_main.qc

   1 void CreatureFrame (void)
   2 {
   3         entity oldself;
   4         float dm;
   5
   6         oldself = self;
   7         for(self = world; (self = findfloat(self, damagedbycontents, TRUE)); )
   8         {
   9                 if (self.movetype == MOVETYPE_NOCLIP) { continue; }
  10
  11                 float vehic = (self.vehicle_flags & VHF_ISVEHICLE);
  12                 float projectile = (self.flags & FL_PROJECTILE);
  13
  14                 if (self.watertype <= CONTENT_WATER && self.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  15                 {
  16                         if (!(self.flags & FL_INWATER))
  17                         {
  18                                 self.flags |= FL_INWATER;
  19                                 self.dmgtime = 0;
  20                         }
  21
  22                         if(!vehic && !projectile) // vehicles and projectiles don't drown
  23                         {
  24                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  25                                 {
  26                                         if(self.air_finished < time)
  27                                                 PlayerSound(playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
  28                                         self.air_finished = time + autocvar_g_balance_contents_drowndelay;
  29                                         self.dmg = 2;
  30                                 }
  31                                 else if (self.air_finished < time)
  32                                 {       // drown!
  33                                         if (!self.deadflag)
  34                                         if (self.pain_finished < time)
  35                                         {
  36                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN, self.origin, '0 0 0');
  37                                                 self.pain_finished = time + 0.5;
  38                                         }
  39                                 }
  40                         }
  41
  42                         if (self.dmgtime < time)
  43                         {
  44                                 self.dmgtime = time + autocvar_g_balance_contents_damagerate;
  45
  46                                 if (projectile)
  47                                 {
  48                                         if (self.watertype == CONTENT_LAVA)
  49                                         {
  50                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  51                                         }
  52                                         else if (self.watertype == CONTENT_SLIME)
  53                                         {
  54                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  55                                         }
  56                                 }
  57                                 else
  58                                 {
  59                                         if (self.watertype == CONTENT_LAVA)
  60                                         {
  61                                                 if (self.watersound_finished < time)
  62                                                 {
  63                                                         self.watersound_finished = time + 0.5;
  64                                                         sound (self, CH_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  65                                                 }
  66                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  67                                         }
  68                                         else if (self.watertype == CONTENT_SLIME)
  69                                         {
  70                                                 if (self.watersound_finished < time)
  71                                                 {
  72                                                         self.watersound_finished = time + 0.5;
  73                                                         sound (self, CH_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  74                                                 }
  75                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  76                                         }
  77                                 }
  78                         }
  79                 }
  80                 else
  81                 {
  82                         if (self.flags & FL_INWATER)
  83                         {
  84                                 // play leave water sound
  85                                 self.flags &~= FL_INWATER;
  86                                 self.dmgtime = 0;
  87                         }
  88                         self.air_finished = time + 12;
  89                         self.dmg = 2;
  90                 }
  91
  92                 if(!vehic && !projectile) // vehicles don't get falling damage
  93                 {
  94                         // check for falling damage
  95                         float velocity_len = vlen(self.velocity);
  96                         if(!self.hook.state && !g_ca && !(g_cts && !autocvar_g_cts_selfdamage))
  97                         {
  98                                 dm = vlen(self.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
  99                                 if (self.deadflag)
 100                                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 101                                 else
 102                                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 103                                 if (dm > 0)
 104                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
 105                         }
 106
 107                         if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 108                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
 109                         // play stupid sounds
 110                         if (g_footsteps)
 111                         if (!gameover)
 112                         if (self.flags & FL_ONGROUND)
 113                         if (velocity_len > autocvar_sv_maxspeed * 0.6)
 114                         if (!self.deadflag)
 115                         if (time < self.lastground + 0.2)
 116                         {
 117                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
 118                                 {
 119                                         self.nextstep = time + 0.3 + random() * 0.1;
 120                                         trace_dphitq3surfaceflags = 0;
 121                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 122                                         /*
 123                                         if(trace_fraction == 1)
 124                                                 dprint("nohit\n");
 125                                         else
 126                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 127                                         */
 128                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 129                                         {
 130                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 131                                                         GlobalSound(globalsound_metalstep, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 132                                                 else
 133                                                         GlobalSound(globalsound_step, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 134                                         }
 135                                 }
 136                         }
 137                 }
 138
 139         self.oldvelocity = self.velocity;
 140         }
 141         self = oldself;
 142 }
 143
 144
 145 /*
 146 =============
 147 StartFrame
 148
 149 Called before each frame by the server
 150 =============
 151 */
 152
 153 float game_delay;
 154 float game_delay_last;
 155
 156 float RedirectionThink();
 157 entity SelectSpawnPoint (float anypoint);
 158 void StartFrame (void)
 159 {
 160         execute_next_frame();
 161
 162         remove = remove_unsafely; // not during spawning!
 163         serverprevtime = servertime;
 164         servertime = time;
 165         serverframetime = frametime;
 166
 167 #ifdef PROFILING
 168         if(time > client_cefc_accumulatortime + 1)
 169         {
 170                 float t, pp, c_seeing, c_seen;
 171                 entity cl;
 172                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 173                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 174                 c_seeing = 0;
 175                 c_seen = 0;
 176                 FOR_EACH_CLIENT(cl)
 177                 {
 178                         if(clienttype(cl) == CLIENTTYPE_REAL)
 179                                 ++c_seeing;
 180                         if(cl.classname == "player")
 181                                 ++c_seen;
 182                 }
 183                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 184                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 185
 186                 client_cefc_accumulatortime = time;
 187                 client_cefc_accumulator = 0;
 188         }
 189 #endif
 190
 191         entity e;
 192         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 193                 CSQCProjectile_Check(e);
 194
 195         if(RedirectionThink())
 196                 return;
 197
 198         UncustomizeEntitiesRun();
 199         InitializeEntitiesRun();
 200
 201         WarpZone_StartFrame();
 202
 203         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 204         if(sys_frametime <= 0)
 205                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 206
 207         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 208                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 209
 210         skill = autocvar_skill;
 211
 212         count_players();
 213         if(g_ca || g_freezetag)
 214                 count_alive_players();
 215         Arena_Warmup();
 216         Spawnqueue_Check();
 217
 218         // detect when the pre-game countdown (if any) has ended and the game has started
 219         game_delay = (time < game_starttime) ? TRUE : FALSE;
 220
 221         if(game_delay_last == TRUE)
 222         if(game_delay == FALSE)
 223         if(autocvar_sv_eventlog)
 224                         GameLogEcho(":startdelay_ended");
 225
 226         game_delay_last = game_delay;
 227
 228         // if in warmup stage and limit for warmup is hit start match
 229         if (inWarmupStage)
 230         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
 231          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 232         {
 233                 ReadyRestart();
 234                 return;
 235         }
 236
 237         CreatureFrame ();
 238         CheckRules_World ();
 239
 240         bot_serverframe();
 241
 242         FOR_EACH_PLAYER(self)
 243                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 244
 245         MUTATOR_CALLHOOK(SV_StartFrame);
 246 }
 247
 248 .vector originjitter;
 249 .vector anglesjitter;
 250 .float anglejitter;
 251 .string gametypefilter;
 252 .string cvarfilter;
 253 float DoesQ3ARemoveThisEntity();
 254 void SV_OnEntityPreSpawnFunction()
 255 {
 256         if (self)
 257         if (self.gametypefilter != "")
 258         if not(isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 259         {
 260                 remove(self);
 261                 return;
 262         }
 263         if(self.cvarfilter != "")
 264         {
 265                 float n, i, o, inv;
 266                 string s, k, v;
 267                 inv = 0;
 268
 269                 s = self.cvarfilter;
 270                 if(substring(s, 0, 1) == "+")
 271                 {
 272                         s = substring(s, 1, -1);
 273                 }
 274                 else if(substring(s, 0, 1) == "-")
 275                 {
 276                         inv = 1;
 277                         s = substring(s, 1, -1);
 278                 }
 279
 280                 n = tokenize_console(s);
 281                 for(i = 0; i < n; ++i)
 282                 {
 283                         s = argv(i);
 284                         // syntax:
 285                         // var>x
 286                         // var<x
 287                         // var>=x
 288                         // var<=x
 289                         // var==x
 290                         // var!=x
 291                         // var===x
 292                         // var!==x
 293                         if((o = strstrofs(s, ">=", 0)) >= 0)
 294                         {
 295                                 k = substring(s, 0, o);
 296                                 v = substring(s, o+2, -1);
 297                                 if(cvar(k) < stof(v))
 298                                         goto cvar_fail;
 299                         }
 300                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 301                         {
 302                                 k = substring(s, 0, o);
 303                                 v = substring(s, o+2, -1);
 304                                 if(cvar(k) > stof(v))
 305                                         goto cvar_fail;
 306                         }
 307                         else if((o = strstrofs(s, ">", 0)) >= 0)
 308                         {
 309                                 k = substring(s, 0, o);
 310                                 v = substring(s, o+1, -1);
 311                                 if(cvar(k) <= stof(v))
 312                                         goto cvar_fail;
 313                         }
 314                         else if((o = strstrofs(s, "<", 0)) >= 0)
 315                         {
 316                                 k = substring(s, 0, o);
 317                                 v = substring(s, o+1, -1);
 318                                 if(cvar(k) >= stof(v))
 319                                         goto cvar_fail;
 320                         }
 321                         else if((o = strstrofs(s, "==", 0)) >= 0)
 322                         {
 323                                 k = substring(s, 0, o);
 324                                 v = substring(s, o+2, -1);
 325                                 if(cvar(k) != stof(v))
 326                                         goto cvar_fail;
 327                         }
 328                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 329                         {
 330                                 k = substring(s, 0, o);
 331                                 v = substring(s, o+2, -1);
 332                                 if(cvar(k) == stof(v))
 333                                         goto cvar_fail;
 334                         }
 335                         else if((o = strstrofs(s, "===", 0)) >= 0)
 336                         {
 337                                 k = substring(s, 0, o);
 338                                 v = substring(s, o+2, -1);
 339                                 if(cvar_string(k) != v)
 340                                         goto cvar_fail;
 341                         }
 342                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 343                         {
 344                                 k = substring(s, 0, o);
 345                                 v = substring(s, o+2, -1);
 346                                 if(cvar_string(k) == v)
 347                                         goto cvar_fail;
 348                         }
 349                         else if(substring(s, 0, 1) == "!")
 350                         {
 351                                 k = substring(s, 1, -1);
 352                                 if(cvar(k))
 353                                         goto cvar_fail;
 354                         }
 355                         else
 356                         {
 357                                 k = s;
 358                                 if not(cvar(k))
 359                                         goto cvar_fail;
 360                         }
 361                 }
 362                 inv = !inv;
 363 :cvar_fail
 364                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 365                 if not(inv)
 366                 {
 367                         //print("cvarfilter fail\n");
 368                         remove(self);
 369                         return;
 370                 }
 371         }
 372
 373         if(DoesQ3ARemoveThisEntity())
 374         {
 375                 remove(self);
 376                 return;
 377         }
 378
 379         // support special -1 and -2 angle from radiant
 380         if (self.angles == '0 -1 0')
 381                 self.angles = '-90 0 0';
 382         else if (self.angles == '0 -2 0')
 383                 self.angles = '+90 0 0';
 384
 385         if(self.originjitter_x != 0)
 386                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 387         if(self.originjitter_y != 0)
 388                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 389         if(self.originjitter_z != 0)
 390                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 391         if(self.anglesjitter_x != 0)
 392                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 393         if(self.anglesjitter_y != 0)
 394                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 395         if(self.anglesjitter_z != 0)
 396                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 397         if(self.anglejitter != 0)
 398                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 399
 400         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 401         {
 402                 remove(self);
 403                 return;
 404         }
 405 }
 406
 407 void WarpZone_PostInitialize_Callback(void)
 408 {
 409         // create waypoint links for warpzones
 410         entity e;
 411         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 412         {
 413                 vector src, dst;
 414                 src = (e.absmin + e.absmax) * 0.5;
 415                 makevectors(e.warpzone_angles);
 416                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 417                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 418                 makevectors(e.enemy.warpzone_angles);
 419                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 420                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 421         }
 422 }