qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_damage.qh"
   6 #include "g_world.qh"
   7 #include "spawnpoints.qh"
   8 #include <server/gamelog.qh>
   9
  10 #include "bot/api.qh"
  11
  12 #include "command/common.qh"
  13
  14 #include <server/mutators/_mod.qh>
  15 #include "weapons/csqcprojectile.qh"
  16 #include <server/compat/quake3.qh>
  17
  18 #include "../common/constants.qh"
  19 #include "../common/deathtypes/all.qh"
  20 #include "../common/debug.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/util.qh"
  23
  24 #include "../common/vehicles/all.qh"
  25 #include <common/monsters/sv_monsters.qh>
  26 #include <common/weapons/_all.qh>
  27
  28 #include "../lib/csqcmodel/sv_model.qh"
  29
  30 #include "../lib/warpzone/common.qh"
  31 #include "../lib/warpzone/server.qh"
  32
  33 void CreatureFrame_hotliquids(entity this)
  34 {
  35         if (this.contents_damagetime >= time)
  36         {
  37                 return;
  38         }
  39
  40         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  41
  42         if (this.flags & FL_PROJECTILE)
  43         {
  44                 if (this.watertype == CONTENT_LAVA)
  45                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  46                 else if (this.watertype == CONTENT_SLIME)
  47                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  48         }
  49         else
  50         {
  51                 if (STAT(FROZEN, this))
  52                 {
  53                         if (this.watertype == CONTENT_LAVA)
  54                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  55                         else if (this.watertype == CONTENT_SLIME)
  56                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  57                 }
  58                 else if (this.watertype == CONTENT_LAVA)
  59                 {
  60                         if (this.watersound_finished < time)
  61                         {
  62                                 this.watersound_finished = time + 0.5;
  63                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  64                         }
  65                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  66                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  67                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  68                 }
  69                 else if (this.watertype == CONTENT_SLIME)
  70                 {
  71                         if (this.watersound_finished < time)
  72                         {
  73                                 this.watersound_finished = time + 0.5;
  74                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  75                         }
  76                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  77                 }
  78         }
  79 }
  80
  81 void CreatureFrame_Liquids(entity this)
  82 {
  83         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  84         {
  85                 if (!(this.flags & FL_INWATER))
  86                 {
  87                         this.flags |= FL_INWATER;
  88                         this.contents_damagetime = 0;
  89                 }
  90
  91                 CreatureFrame_hotliquids(this);
  92         }
  93         else
  94         {
  95                 if (this.flags & FL_INWATER)
  96                 {
  97                         // play leave water sound
  98                         this.flags &= ~FL_INWATER;
  99                         this.contents_damagetime = 0;
 100                 }
 101         }
 102 }
 103
 104 void CreatureFrame_FallDamage(entity this)
 105 {
 106         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 107                 return; // vehicles and projectiles don't receive fall damage
 108         if(!(this.velocity || this.oldvelocity))
 109                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 110
 111         // check for falling damage
 112         bool have_hook = false;
 113         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 114         {
 115             .entity weaponentity = weaponentities[slot];
 116             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 117             {
 118                 have_hook = true;
 119                 break;
 120             }
 121         }
 122         if(!have_hook)
 123         {
 124                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 125                 if(autocvar_g_balance_falldamage_onlyvertical)
 126                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 127                 else
 128                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 129                 if (IS_DEAD(this))
 130                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 131                 else
 132                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 133                 if (dm > 0)
 134                 {
 135                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 136                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 137                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 138                 }
 139         }
 140
 141         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 142                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 143 }
 144
 145 void CreatureFrame_All()
 146 {
 147         if(game_stopped || time < game_starttime)
 148                 return;
 149
 150         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 151         {
 152                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 153                 CreatureFrame_Liquids(it);
 154                 CreatureFrame_FallDamage(it);
 155                 it.oldvelocity = it.velocity;
 156         });
 157 }
 158
 159 void Pause_TryPause(bool ispaused)
 160 {
 161         int n = 0;
 162         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 163                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 164                 ++n;
 165         });
 166         if (!n) return;
 167         setpause(ispaused);
 168 }
 169
 170 void SV_PausedTic(float elapsedtime)
 171 {
 172         if (!server_is_dedicated) Pause_TryPause(false);
 173 }
 174
 175 /*
 176 =============
 177 StartFrame
 178
 179 Called before each frame by the server
 180 =============
 181 */
 182
 183 bool game_delay_last;
 184
 185 bool autocvar_sv_autopause = false;
 186 void systems_update();
 187 void sys_phys_update(entity this, float dt);
 188 void StartFrame()
 189 {
 190     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 191     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 192     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 193
 194         execute_next_frame();
 195         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 196
 197         delete_fn = remove_unsafely; // not during spawning!
 198         serverprevtime = servertime;
 199         servertime = time;
 200         serverframetime = frametime;
 201
 202 #ifdef PROFILING
 203         if(time > client_cefc_accumulatortime + 1)
 204         {
 205                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 206                 int c_seeing = 0;
 207                 int c_seen = 0;
 208                 FOREACH_CLIENT(true, {
 209                         if(IS_REAL_CLIENT(it))
 210                                 ++c_seeing;
 211                         if(IS_PLAYER(it))
 212                                 ++c_seen;
 213                 });
 214                 LOG_INFO(
 215                     "CEFC time: ", ftos(t * 1000), "ms; ",
 216             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 217             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 218         );
 219                 client_cefc_accumulatortime = time;
 220                 client_cefc_accumulator = 0;
 221         }
 222 #endif
 223
 224         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 225
 226         if (RedirectionThink()) return;
 227
 228         UncustomizeEntitiesRun();
 229         InitializeEntitiesRun();
 230
 231         WarpZone_StartFrame();
 232
 233         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 234         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 235
 236         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 237                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 238
 239         // detect when the pre-game countdown (if any) has ended and the game has started
 240         bool game_delay = (time < game_starttime);
 241         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 242                 GameLogEcho(":startdelay_ended");
 243         game_delay_last = game_delay;
 244
 245         CreatureFrame_All();
 246         CheckRules_World();
 247
 248         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 249                 ReadyRestart();
 250                 return;
 251         }
 252
 253         bot_serverframe();
 254         anticheat_startframe();
 255         MUTATOR_CALLHOOK(SV_StartFrame);
 256
 257         GlobalStats_updateglobal();
 258     FOREACH_CLIENT(true, GlobalStats_update(it));
 259     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 260 }
 261
 262 .vector originjitter;
 263 .vector anglesjitter;
 264 .float anglejitter;
 265 .string gametypefilter;
 266 .string cvarfilter;
 267
 268 /**
 269  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 270  * +: all must match. this is the default
 271  * -: one must NOT match
 272  *
 273  * var>x
 274  * var<x
 275  * var>=x
 276  * var<=x
 277  * var==x
 278  * var!=x
 279  * var===x
 280  * var!==x
 281  */
 282 bool expr_evaluate(string s)
 283 {
 284     bool ret = false;
 285     if (str2chr(s, 0) == '+') {
 286         s = substring(s, 1, -1);
 287     } else if (str2chr(s, 0) == '-') {
 288         ret = true;
 289         s = substring(s, 1, -1);
 290     }
 291     bool expr_fail = false;
 292     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 293         int o;
 294         string k, v;
 295         s = argv(i);
 296         #define X(expr) \
 297             if (expr) \
 298                 continue; \
 299             expr_fail = true; \
 300             break;
 301
 302         #define BINOP(op, len, expr) \
 303             if ((o = strstrofs(s, op, 0)) >= 0) { \
 304                 k = substring(s, 0, o); \
 305                 v = substring(s, o + len, -1); \
 306                 X(expr); \
 307             }
 308         BINOP(">=", 2, cvar(k) >= stof(v));
 309         BINOP("<=", 2, cvar(k) <= stof(v));
 310         BINOP(">",  1, cvar(k) >  stof(v));
 311         BINOP("<",  1, cvar(k) <  stof(v));
 312         BINOP("==", 2, cvar(k) == stof(v));
 313         BINOP("!=", 2, cvar(k) != stof(v));
 314         BINOP("===", 3, cvar_string(k) == v);
 315         BINOP("!==", 3, cvar_string(k) != v);
 316         {
 317             k = s;
 318             bool b = true;
 319             if (str2chr(k, 0) == '!') {
 320                 k = substring(s, 1, -1);
 321                 b = false;
 322             }
 323             float f = stof(k);
 324             bool isnum = ftos(f) == k;
 325             X(boolean(isnum ? f : cvar(k)) == b);
 326         }
 327         #undef BINOP
 328         #undef X
 329     }
 330     if (!expr_fail) {
 331         ret = !ret;
 332     }
 333     // now ret is true if we want to keep the item, and false if we want to get rid of it
 334     return ret;
 335 }
 336
 337 void SV_OnEntityPreSpawnFunction(entity this)
 338 {
 339         if (this)
 340         if (this.gametypefilter != "")
 341         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 342         {
 343                 delete(this);
 344                 return;
 345         }
 346         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 347                 delete(this);
 348                 return;
 349         }
 350
 351         if (DoesQ3ARemoveThisEntity(this)) {
 352                 delete(this);
 353                 return;
 354         }
 355
 356         set_movetype(this, this.movetype);
 357
 358         if (this.monster_attack) {
 359                 IL_PUSH(g_monster_targets, this);
 360     }
 361
 362         // support special -1 and -2 angle from radiant
 363         if (this.angles == '0 -1 0') {
 364                 this.angles = '-90 0 0';
 365         } else if (this.angles == '0 -2 0') {
 366                 this.angles = '+90 0 0';
 367     }
 368
 369     #define X(out, in) MACRO_BEGIN \
 370         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 371     MACRO_END
 372     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 373     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 374     X(this.angles.y, this.anglejitter);
 375     #undef X
 376
 377         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 378                 delete(this);
 379                 return;
 380         }
 381 }
 382
 383 void WarpZone_PostInitialize_Callback()
 384 {
 385         // create waypoint links for warpzones
 386         entity tracetest_ent = spawn();
 387         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 388         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 389         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 390         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 391                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 392         delete(tracetest_ent);
 393 }
 394
 395 /*
 396 ==================
 397 main
 398
 399 unused but required by the engine
 400 ==================
 401 */
 402 void main ()
 403 {
 404
 405 }