qcsrc/server/sv_main.qc

   1
   2 void CreatureFrame (void)
   3 {
   4         local entity oldself;
   5         local float dm, maxspeed;
   6         oldself = self;
   7         self = findfloat(world, iscreature, TRUE);
   8         while (self)
   9         {
  10                 if (self.movetype != MOVETYPE_NOCLIP)
  11                 {
  12                         if (self.waterlevel)
  13                         {
  14                                 if (!(self.flags & FL_INWATER))
  15                                 {
  16                                         self.flags |= FL_INWATER;
  17                                         self.dmgtime = 0;
  18                                 }
  19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  20                                 {
  21                                         if(self.air_finished < time + 9)
  22                                                 PlayerSound(playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  23                                         self.air_finished = time + 12;
  24                                         self.dmg = 2;
  25                                 }
  26                                 else if (self.air_finished < time)
  27                                 {       // drown!
  28                                         if (!self.deadflag)
  29                                         if (self.pain_finished < time)
  30                                         {
  31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
  32                                                 self.pain_finished = time + 0.5;
  33                                         }
  34                                 }
  35                                 if (self.dmgtime < time)
  36                                 {
  37                                         self.dmgtime = time + 0.2;
  38                                         if (self.watertype == CONTENT_LAVA)
  39                                         {
  40                                                 if (self.watersound_finished < time)
  41                                                 {
  42                                                         self.watersound_finished = time + 0.5;
  43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  44                                                 }
  45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  46                                         }
  47                                         else if (self.watertype == CONTENT_SLIME)
  48                                         {
  49                                                 if (self.watersound_finished < time)
  50                                                 {
  51                                                         self.watersound_finished = time + 0.5;
  52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  53                                                 }
  54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  55                                         }
  56                                 }
  57                         }
  58                         else
  59                         {
  60                                 if (self.flags & FL_INWATER)
  61                                 {
  62                                         // play leave water sound
  63                                         self.flags &~= FL_INWATER;
  64                                         self.dmgtime = 0;
  65                                 }
  66                                 self.air_finished = time + 12;
  67                                 self.dmg = 2;
  68                         }
  69                         // check for falling damage
  70                         if(!self.hook.state && !g_ca && !(g_cts && !cvar("g_cts_selfdamage")))
  71                         {
  72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
  73                                 if (self.deadflag)
  74                                         dm = (dm - cvar("g_balance_falldamage_deadminspeed")) * cvar("g_balance_falldamage_factor");
  75                                 else
  76                                         dm = min((dm - cvar("g_balance_falldamage_minspeed")) * cvar("g_balance_falldamage_factor"), cvar("g_balance_falldamage_maxdamage"));
  77                                 if (dm > 0)
  78                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
  79                         }
  80
  81                         maxspeed = cvar("g_maxspeed");
  82                         if(maxspeed > 0 && vlen(self.velocity) > maxspeed)
  83                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
  84
  85                         // play stupid sounds
  86                         if (g_footsteps)
  87                         if (!gameover)
  88                         if (self.flags & FL_ONGROUND)
  89                         if (vlen(self.velocity) > sv_maxspeed * 0.6)
  90                         if (!self.deadflag)
  91                         if (time < self.lastground + 0.2)
  92                         {
  93                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
  94                                 {
  95                                         self.nextstep = time + 0.3 + random() * 0.1;
  96                                         trace_dphitq3surfaceflags = 0;
  97                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
  98                                         /*
  99                                         if(trace_fraction == 1)
 100                                                 dprint("nohit\n");
 101                                         else
 102                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 103                                         */
 104                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 105                                         {
 106                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 107                                                         GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 108                                                 else
 109                                                         GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 110                                         }
 111                                 }
 112                         }
 113                         self.oldvelocity = self.velocity;
 114                 }
 115                 self = findfloat(self, iscreature, TRUE);
 116         }
 117         self = oldself;
 118 }
 119
 120
 121 /*
 122 =============
 123 StartFrame
 124
 125 Called before each frame by the server
 126 =============
 127 */
 128
 129 float game_delay;
 130 float game_delay_last;
 131
 132 void RuneMatchGivePoints();
 133 float RedirectionThink();
 134 entity SelectSpawnPoint (float anypoint);
 135 void StartFrame (void)
 136 {
 137         remove = remove_unsafely; // not during spawning!
 138         serverprevtime = servertime;
 139         servertime = time;
 140         serverframetime = frametime;
 141
 142 #ifdef PROFILING
 143         if(time > client_cefc_accumulatortime + 1)
 144         {
 145                 float t, pp, c_seeing, c_seen;
 146                 entity cl;
 147                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 148                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 149                 c_seeing = 0;
 150                 c_seen = 0;
 151                 FOR_EACH_CLIENT(cl)
 152                 {
 153                         if(clienttype(cl) == CLIENTTYPE_REAL)
 154                                 ++c_seeing;
 155                         if(cl.classname == "player")
 156                                 ++c_seen;
 157                 }
 158                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 159                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 160
 161                 client_cefc_accumulatortime = time;
 162                 client_cefc_accumulator = 0;
 163         }
 164 #endif
 165
 166         entity e;
 167         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 168                 CSQCProjectile_Check(e);
 169
 170         if(RedirectionThink())
 171                 return;
 172
 173         UncustomizeEntitiesRun();
 174         InitializeEntitiesRun();
 175
 176         WarpZone_StartFrame();
 177
 178         sv_gravity = cvar("sv_gravity");
 179         sv_maxairspeed = cvar("sv_maxairspeed");
 180         sv_maxspeed = cvar ("sv_maxspeed");
 181         sv_friction = cvar ("sv_friction");
 182         sv_accelerate = cvar ("sv_accelerate");
 183         sv_airaccelerate = cvar("sv_airaccelerate");
 184         sv_airaccel_sideways_friction = cvar("sv_airaccel_sideways_friction");
 185         sv_airaccel_qw = cvar("sv_airaccel_qw");
 186         sv_stopspeed = cvar ("sv_stopspeed");
 187         sv_airstopaccelerate = cvar("sv_airstopaccelerate");
 188         sv_airstrafeaccelerate = cvar("sv_airstrafeaccelerate");
 189         sv_maxairstrafespeed = cvar("sv_maxairstrafespeed");
 190         sv_airstrafeaccel_qw = cvar("sv_airstrafeaccel_qw");
 191         sv_aircontrol = cvar("sv_aircontrol");
 192         sv_aircontrol_penalty = cvar("sv_aircontrol_penalty");
 193         sv_aircontrol_power = cvar("sv_aircontrol_power");
 194         sv_warsowbunny_airforwardaccel = cvar("sv_warsowbunny_airforwardaccel");
 195         sv_warsowbunny_accel = cvar("sv_warsowbunny_accel");
 196         sv_warsowbunny_topspeed = cvar("sv_warsowbunny_topspeed");
 197         sv_warsowbunny_turnaccel = cvar("sv_warsowbunny_turnaccel");
 198         sv_warsowbunny_backtosideratio = cvar("sv_warsowbunny_backtosideratio");
 199         sv_airspeedlimit_nonqw = cvar("sv_airspeedlimit_nonqw");
 200         sv_doublejump = cvar("sv_doublejump");
 201         teamplay = cvar ("teamplay");
 202
 203         sys_frametime = cvar("sys_ticrate") * cvar("slowmo");
 204         if(sys_frametime <= 0)
 205                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 206
 207         if (timeoutStatus == 1) // just before the timeout (when timeoutStatus will be 2)
 208                 orig_slowmo = cvar("slowmo"); // slowmo will be restored after the timeout
 209
 210         if(teams_matter && !teamplay)
 211                 teamplay = 3;
 212         if(!teams_matter && teamplay)
 213                 teamplay = 0;
 214
 215         skill = cvar("skill");
 216
 217         Spawnqueue_Check();
 218
 219
 220         // detect when the pre-game countdown (if any) has ended and the game has started
 221         game_delay = (time < game_starttime) ? TRUE : FALSE;
 222
 223         if(game_delay_last == TRUE)
 224         if(game_delay == FALSE)
 225         if(cvar("sv_eventlog"))
 226                         GameLogEcho(":startdelay_ended");
 227
 228         game_delay_last = game_delay;
 229
 230         // if in warmup stage and limit for warmup is hit start match
 231         if (inWarmupStage)
 232         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
 233          || (g_warmup_limit == 0 && cvar("timelimit") != 0 && time >= cvar("timelimit") * 60))
 234         {
 235                 ReadyRestart();
 236                 return;
 237         }
 238
 239         CreatureFrame ();
 240         CheckRules_World ();
 241
 242         AuditTeams();
 243
 244         RuneMatchGivePoints();
 245         bot_serverframe();
 246
 247         if(cvar("spawn_debugview"))
 248         {
 249                 RandomSelection_Init();
 250                 for(self = world; (self = find(self, classname, "player")); )
 251                         RandomSelection_Add(self, 0, string_null, 1, 0);
 252                 self = RandomSelection_chosen_ent;
 253                 SelectSpawnPoint(0);
 254         }
 255
 256         FOR_EACH_PLAYER(self)
 257                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 258 }
 259
 260 .vector originjitter;
 261 .vector anglesjitter;
 262 .float anglejitter;
 263 .string gametypefilter;
 264 .string cvarfilter;
 265 void SV_OnEntityPreSpawnFunction()
 266 {
 267         if(self.gametypefilter != "")
 268         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))
 269         {
 270                 remove(self);
 271                 return;
 272         }
 273         if(self.cvarfilter != "")
 274         {
 275                 float n, i, o, inv;
 276                 string s, k, v;
 277                 inv = 0;
 278
 279                 s = self.cvarfilter;
 280                 if(substring(s, 0, 1) == "+")
 281                 {
 282                         s = substring(s, 1, -1);
 283                 }
 284                 else if(substring(s, 0, 1) == "-")
 285                 {
 286                         inv = 1;
 287                         s = substring(s, 1, -1);
 288                 }
 289
 290                 n = tokenize(s);
 291                 for(i = 0; i < n; ++i)
 292                 {
 293                         s = argv(i);
 294                         // syntax:
 295                         // var>x
 296                         // var<x
 297                         // var>=x
 298                         // var<=x
 299                         // var==x
 300                         // var!=x
 301                         // var===x
 302                         // var!==x
 303                         if((o = strstrofs(s, ">=", 0)) >= 0)
 304                         {
 305                                 k = substring(s, 0, o);
 306                                 v = substring(s, o+2, -1);
 307                                 if(cvar(k) < stof(v))
 308                                         goto cvar_fail;
 309                         }
 310                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 311                         {
 312                                 k = substring(s, 0, o);
 313                                 v = substring(s, o+2, -1);
 314                                 if(cvar(k) > stof(v))
 315                                         goto cvar_fail;
 316                         }
 317                         else if((o = strstrofs(s, ">", 0)) >= 0)
 318                         {
 319                                 k = substring(s, 0, o);
 320                                 v = substring(s, o+1, -1);
 321                                 if(cvar(k) <= stof(v))
 322                                         goto cvar_fail;
 323                         }
 324                         else if((o = strstrofs(s, "<", 0)) >= 0)
 325                         {
 326                                 k = substring(s, 0, o);
 327                                 v = substring(s, o+1, -1);
 328                                 if(cvar(k) >= stof(v))
 329                                         goto cvar_fail;
 330                         }
 331                         else if((o = strstrofs(s, "==", 0)) >= 0)
 332                         {
 333                                 k = substring(s, 0, o);
 334                                 v = substring(s, o+2, -1);
 335                                 if(cvar(k) != stof(v))
 336                                         goto cvar_fail;
 337                         }
 338                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 339                         {
 340                                 k = substring(s, 0, o);
 341                                 v = substring(s, o+2, -1);
 342                                 if(cvar(k) == stof(v))
 343                                         goto cvar_fail;
 344                         }
 345                         else if((o = strstrofs(s, "===", 0)) >= 0)
 346                         {
 347                                 k = substring(s, 0, o);
 348                                 v = substring(s, o+2, -1);
 349                                 if(cvar_string(k) != v)
 350                                         goto cvar_fail;
 351                         }
 352                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 353                         {
 354                                 k = substring(s, 0, o);
 355                                 v = substring(s, o+2, -1);
 356                                 if(cvar_string(k) == v)
 357                                         goto cvar_fail;
 358                         }
 359                         else if(substring(s, 0, 1) == "!")
 360                         {
 361                                 k = substring(s, 1, -1);
 362                                 if(cvar(k))
 363                                         goto cvar_fail;
 364                         }
 365                         else
 366                         {
 367                                 k = s;
 368                                 if not(cvar(k))
 369                                         goto cvar_fail;
 370                         }
 371                 }
 372                 inv = !inv;
 373 :cvar_fail
 374                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 375                 if not(inv)
 376                 {
 377                         //print("cvarfilter fail\n");
 378                         remove(self);
 379                         return;
 380                 }
 381         }
 382
 383         // support special -1 and -2 angle from radiant
 384         if (self.angles == '0 -1 0')
 385                 self.angles = '-90 0 0';
 386         else if (self.angles == '0 -2 0')
 387                 self.angles = '+90 0 0';
 388
 389         if(self.originjitter_x != 0)
 390                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 391         if(self.originjitter_y != 0)
 392                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 393         if(self.originjitter_z != 0)
 394                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 395         if(self.anglesjitter_x != 0)
 396                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 397         if(self.anglesjitter_y != 0)
 398                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 399         if(self.anglesjitter_z != 0)
 400                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 401         if(self.anglejitter != 0)
 402                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 403
 404         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 405         {
 406                 remove(self);
 407                 return;
 408         }
 409 }