qcsrc/server/sv_main.qc

   1 void CreatureFrame (void)
   2 {
   3         entity oldself;
   4         float dm;
   5
   6         oldself = self;
   7         for(self = world; (self = findfloat(self, damagedbycontents, true)); )
   8         {
   9                 if (self.movetype == MOVETYPE_NOCLIP) { continue; }
  10
  11                 float vehic = (self.vehicle_flags & VHF_ISVEHICLE);
  12                 float projectile = (self.flags & FL_PROJECTILE);
  13                 float monster = (self.flags & FL_MONSTER);
  14
  15                 if (self.watertype <= CONTENT_WATER && self.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  16                 {
  17                         if (!(self.flags & FL_INWATER))
  18                         {
  19                                 self.flags |= FL_INWATER;
  20                                 self.dmgtime = 0;
  21                         }
  22
  23                         if(!vehic && !projectile && !monster) // vehicles, monsters and projectiles don't drown
  24                         {
  25                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  26                                 {
  27                                         if(self.air_finished < time)
  28                                                 PlayerSound(playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
  29                                         self.air_finished = time + autocvar_g_balance_contents_drowndelay;
  30                                         self.dmg = 2;
  31                                 }
  32                                 else if (self.air_finished < time)
  33                                 {       // drown!
  34                                         if (!self.deadflag)
  35                                         if (self.pain_finished < time)
  36                                         {
  37                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN, self.origin, '0 0 0');
  38                                                 self.pain_finished = time + 0.5;
  39                                         }
  40                                 }
  41                         }
  42
  43                         if (self.dmgtime < time)
  44                         {
  45                                 self.dmgtime = time + autocvar_g_balance_contents_damagerate;
  46
  47                                 if (projectile)
  48                                 {
  49                                         if (self.watertype == CONTENT_LAVA)
  50                                         {
  51                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  52                                         }
  53                                         else if (self.watertype == CONTENT_SLIME)
  54                                         {
  55                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  56                                         }
  57                                 }
  58                                 else
  59                                 {
  60                                         if (self.watertype == CONTENT_LAVA)
  61                                         {
  62                                                 if (self.watersound_finished < time)
  63                                                 {
  64                                                         self.watersound_finished = time + 0.5;
  65                                                         sound (self, CH_PLAYER_SINGLE, "player/lava.wav", VOL_BASE, ATTEN_NORM);
  66                                                 }
  67                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  68                                         }
  69                                         else if (self.watertype == CONTENT_SLIME)
  70                                         {
  71                                                 if (self.watersound_finished < time)
  72                                                 {
  73                                                         self.watersound_finished = time + 0.5;
  74                                                         sound (self, CH_PLAYER_SINGLE, "player/slime.wav", VOL_BASE, ATTEN_NORM);
  75                                                 }
  76                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  77                                         }
  78                                 }
  79                         }
  80                 }
  81                 else
  82                 {
  83                         if (self.flags & FL_INWATER)
  84                         {
  85                                 // play leave water sound
  86                                 self.flags &= ~FL_INWATER;
  87                                 self.dmgtime = 0;
  88                         }
  89                         self.air_finished = time + 12;
  90                         self.dmg = 2;
  91                 }
  92
  93                 if(!vehic && !projectile) // vehicles don't get falling damage
  94                 {
  95                         // check for falling damage
  96                         float velocity_len = vlen(self.velocity);
  97                         if(!self.hook.state)
  98                         {
  99                                 dm = vlen(self.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 100                                 if (self.deadflag)
 101                                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 102                                 else
 103                                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 104                                 if (dm > 0)
 105                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
 106                         }
 107
 108                         if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 109                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
 110                         // play stupid sounds
 111                         if (g_footsteps)
 112                         if (!gameover)
 113                         if (self.flags & FL_ONGROUND)
 114                         if (velocity_len > autocvar_sv_maxspeed * 0.6)
 115                         if (!self.deadflag)
 116                         if (time < self.lastground + 0.2)
 117                         {
 118                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
 119                                 {
 120                                         self.nextstep = time + 0.3 + random() * 0.1;
 121                                         trace_dphitq3surfaceflags = 0;
 122                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 123                                         /*
 124                                         if(trace_fraction == 1)
 125                                                 dprint("nohit\n");
 126                                         else
 127                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 128                                         */
 129                                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS))
 130                                         {
 131                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 132                                                         GlobalSound(globalsound_metalstep, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 133                                                 else
 134                                                         GlobalSound(globalsound_step, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 135                                         }
 136                                 }
 137                         }
 138                 }
 139
 140         self.oldvelocity = self.velocity;
 141         }
 142         self = oldself;
 143 }
 144
 145
 146 /*
 147 =============
 148 StartFrame
 149
 150 Called before each frame by the server
 151 =============
 152 */
 153
 154 float game_delay;
 155 float game_delay_last;
 156
 157 float RedirectionThink();
 158 void StartFrame (void)
 159 {
 160         execute_next_frame();
 161
 162         remove = remove_unsafely; // not during spawning!
 163         serverprevtime = servertime;
 164         servertime = time;
 165         serverframetime = frametime;
 166
 167 #ifdef PROFILING
 168         if(time > client_cefc_accumulatortime + 1)
 169         {
 170                 float t, pp, c_seeing, c_seen;
 171                 entity cl;
 172                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 173                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 174                 c_seeing = 0;
 175                 c_seen = 0;
 176                 FOR_EACH_CLIENT(cl)
 177                 {
 178                         if(IS_REAL_CLIENT(cl))
 179                                 ++c_seeing;
 180                         if(IS_PLAYER(cl))
 181                                 ++c_seen;
 182                 }
 183                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 184                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 185
 186                 client_cefc_accumulatortime = time;
 187                 client_cefc_accumulator = 0;
 188         }
 189 #endif
 190
 191         entity e;
 192         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 193                 CSQCProjectile_Check(e);
 194
 195         if(RedirectionThink())
 196                 return;
 197
 198         UncustomizeEntitiesRun();
 199         InitializeEntitiesRun();
 200
 201         WarpZone_StartFrame();
 202
 203         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 204         if(sys_frametime <= 0)
 205                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 206
 207         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 208                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 209
 210         skill = autocvar_skill;
 211
 212         // detect when the pre-game countdown (if any) has ended and the game has started
 213         game_delay = (time < game_starttime) ? true : false;
 214
 215         if(game_delay_last == true)
 216         if(game_delay == false)
 217         if(autocvar_sv_eventlog)
 218                 GameLogEcho(":startdelay_ended");
 219
 220         game_delay_last = game_delay;
 221
 222         CreatureFrame ();
 223         CheckRules_World ();
 224
 225         // if in warmup stage and limit for warmup is hit start match
 226         if(warmup_stage)
 227         if(!gameover)
 228         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 229          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 230         {
 231                 ReadyRestart();
 232                 return;
 233         }
 234
 235         bot_serverframe();
 236
 237         FOR_EACH_PLAYER(self)
 238                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 239
 240         anticheat_startframe();
 241
 242         MUTATOR_CALLHOOK(SV_StartFrame);
 243 }
 244
 245 .vector originjitter;
 246 .vector anglesjitter;
 247 .float anglejitter;
 248 .string gametypefilter;
 249 .string cvarfilter;
 250 float DoesQ3ARemoveThisEntity();
 251 void SV_OnEntityPreSpawnFunction()
 252 {
 253         if (self)
 254         if (self.gametypefilter != "")
 255         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 256         {
 257                 remove(self);
 258                 return;
 259         }
 260         if(self.cvarfilter != "")
 261         {
 262                 float n, i, o, inv;
 263                 string s, k, v;
 264                 inv = 0;
 265
 266                 s = self.cvarfilter;
 267                 if(substring(s, 0, 1) == "+")
 268                 {
 269                         s = substring(s, 1, -1);
 270                 }
 271                 else if(substring(s, 0, 1) == "-")
 272                 {
 273                         inv = 1;
 274                         s = substring(s, 1, -1);
 275                 }
 276
 277                 n = tokenize_console(s);
 278                 for(i = 0; i < n; ++i)
 279                 {
 280                         s = argv(i);
 281                         // syntax:
 282                         // var>x
 283                         // var<x
 284                         // var>=x
 285                         // var<=x
 286                         // var==x
 287                         // var!=x
 288                         // var===x
 289                         // var!==x
 290                         if((o = strstrofs(s, ">=", 0)) >= 0)
 291                         {
 292                                 k = substring(s, 0, o);
 293                                 v = substring(s, o+2, -1);
 294                                 if(cvar(k) < stof(v))
 295                                         goto cvar_fail;
 296                         }
 297                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 298                         {
 299                                 k = substring(s, 0, o);
 300                                 v = substring(s, o+2, -1);
 301                                 if(cvar(k) > stof(v))
 302                                         goto cvar_fail;
 303                         }
 304                         else if((o = strstrofs(s, ">", 0)) >= 0)
 305                         {
 306                                 k = substring(s, 0, o);
 307                                 v = substring(s, o+1, -1);
 308                                 if(cvar(k) <= stof(v))
 309                                         goto cvar_fail;
 310                         }
 311                         else if((o = strstrofs(s, "<", 0)) >= 0)
 312                         {
 313                                 k = substring(s, 0, o);
 314                                 v = substring(s, o+1, -1);
 315                                 if(cvar(k) >= stof(v))
 316                                         goto cvar_fail;
 317                         }
 318                         else if((o = strstrofs(s, "==", 0)) >= 0)
 319                         {
 320                                 k = substring(s, 0, o);
 321                                 v = substring(s, o+2, -1);
 322                                 if(cvar(k) != stof(v))
 323                                         goto cvar_fail;
 324                         }
 325                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 326                         {
 327                                 k = substring(s, 0, o);
 328                                 v = substring(s, o+2, -1);
 329                                 if(cvar(k) == stof(v))
 330                                         goto cvar_fail;
 331                         }
 332                         else if((o = strstrofs(s, "===", 0)) >= 0)
 333                         {
 334                                 k = substring(s, 0, o);
 335                                 v = substring(s, o+2, -1);
 336                                 if(cvar_string(k) != v)
 337                                         goto cvar_fail;
 338                         }
 339                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 340                         {
 341                                 k = substring(s, 0, o);
 342                                 v = substring(s, o+2, -1);
 343                                 if(cvar_string(k) == v)
 344                                         goto cvar_fail;
 345                         }
 346                         else if(substring(s, 0, 1) == "!")
 347                         {
 348                                 k = substring(s, 1, -1);
 349                                 if(cvar(k))
 350                                         goto cvar_fail;
 351                         }
 352                         else
 353                         {
 354                                 k = s;
 355                                 if (!cvar(k))
 356                                         goto cvar_fail;
 357                         }
 358                 }
 359                 inv = !inv;
 360 :cvar_fail
 361                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 362                 if (!inv)
 363                 {
 364                         //print("cvarfilter fail\n");
 365                         remove(self);
 366                         return;
 367                 }
 368         }
 369
 370         if(DoesQ3ARemoveThisEntity())
 371         {
 372                 remove(self);
 373                 return;
 374         }
 375
 376         // support special -1 and -2 angle from radiant
 377         if (self.angles == '0 -1 0')
 378                 self.angles = '-90 0 0';
 379         else if (self.angles == '0 -2 0')
 380                 self.angles = '+90 0 0';
 381
 382         if(self.originjitter.x != 0)
 383                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 384         if(self.originjitter.y != 0)
 385                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 386         if(self.originjitter.z != 0)
 387                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 388         if(self.anglesjitter.x != 0)
 389                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 390         if(self.anglesjitter.y != 0)
 391                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 392         if(self.anglesjitter.z != 0)
 393                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 394         if(self.anglejitter != 0)
 395                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 396
 397         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 398         {
 399                 remove(self);
 400                 return;
 401         }
 402 }
 403
 404 void WarpZone_PostInitialize_Callback(void)
 405 {
 406         // create waypoint links for warpzones
 407         entity e;
 408         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 409         {
 410                 vector src, dst;
 411                 src = (e.absmin + e.absmax) * 0.5;
 412                 makevectors(e.warpzone_angles);
 413                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 414                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 415                 makevectors(e.enemy.warpzone_angles);
 416                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 417                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 418         }
 419 }