qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_damage.qh"
   6 #include "g_world.qh"
   7
   8 #include "bot/api.qh"
   9
  10 #include "command/common.qh"
  11
  12 #include <server/mutators/_mod.qh>
  13 #include "weapons/csqcprojectile.qh"
  14 #include <server/compat/quake3.qh>
  15
  16 #include "../common/constants.qh"
  17 #include "../common/deathtypes/all.qh"
  18 #include "../common/debug.qh"
  19 #include "../common/mapinfo.qh"
  20 #include "../common/util.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/weapons/_all.qh>
  25
  26 #include "../lib/csqcmodel/sv_model.qh"
  27
  28 #include "../lib/warpzone/common.qh"
  29 #include "../lib/warpzone/server.qh"
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime >= time)
  34         {
  35                 return;
  36         }
  37
  38         this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  39
  40         if (this.flags & FL_PROJECTILE)
  41         {
  42                 if (this.watertype == CONTENT_LAVA)
  43                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  44                 else if (this.watertype == CONTENT_SLIME)
  45                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  46         }
  47         else
  48         {
  49                 if (this.watertype == CONTENT_LAVA)
  50                 {
  51                         if (this.watersound_finished < time)
  52                         {
  53                                 this.watersound_finished = time + 0.5;
  54                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  55                         }
  56                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  57                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  58                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  59                 }
  60                 else if (this.watertype == CONTENT_SLIME)
  61                 {
  62                         if (this.watersound_finished < time)
  63                         {
  64                                 this.watersound_finished = time + 0.5;
  65                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  66                         }
  67                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  68                 }
  69         }
  70 }
  71
  72 void CreatureFrame_Liquids(entity this)
  73 {
  74         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  75         {
  76                 if (!(this.flags & FL_INWATER))
  77                 {
  78                         this.flags |= FL_INWATER;
  79                         this.dmgtime = 0;
  80                 }
  81
  82                 CreatureFrame_hotliquids(this);
  83                 if (!this.air_finished)
  84                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
  85         }
  86         else
  87         {
  88                 if (this.flags & FL_INWATER)
  89                 {
  90                         // play leave water sound
  91                         this.flags &= ~FL_INWATER;
  92                         this.dmgtime = 0;
  93                 }
  94                 this.air_finished = 0;
  95         }
  96 }
  97
  98 void CreatureFrame_FallDamage(entity this)
  99 {
 100         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 101                 return; // vehicles and projectiles don't receive fall damage
 102         if(!(this.velocity || this.oldvelocity))
 103                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 104
 105         // check for falling damage
 106         bool have_hook = false;
 107         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 108         {
 109             .entity weaponentity = weaponentities[slot];
 110             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 111             {
 112                 have_hook = true;
 113                 break;
 114             }
 115         }
 116         if(!have_hook)
 117         {
 118                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 119                 if(autocvar_g_balance_falldamage_onlyvertical)
 120                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 121                 else
 122                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 123                 if (IS_DEAD(this))
 124                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 125                 else
 126                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 127                 if (dm > 0)
 128                 {
 129                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 130                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 131                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 132                 }
 133         }
 134
 135         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 136                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 137 }
 138
 139 void CreatureFrame_All()
 140 {
 141         if(game_stopped || time < game_starttime)
 142                 return;
 143
 144         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 145         {
 146                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 147                 CreatureFrame_Liquids(it);
 148                 CreatureFrame_FallDamage(it);
 149                 it.oldvelocity = it.velocity;
 150         });
 151 }
 152
 153 void Pause_TryPause(bool ispaused)
 154 {
 155         int n = 0;
 156         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 157                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 158                 ++n;
 159         });
 160         if (!n) return;
 161         setpause(ispaused);
 162 }
 163
 164 void SV_PausedTic(float elapsedtime)
 165 {
 166         if (!server_is_dedicated) Pause_TryPause(false);
 167 }
 168
 169 /*
 170 =============
 171 StartFrame
 172
 173 Called before each frame by the server
 174 =============
 175 */
 176
 177 bool game_delay_last;
 178
 179 bool autocvar_sv_autopause = false;
 180 void systems_update();
 181 void sys_phys_update(entity this, float dt);
 182 void StartFrame()
 183 {
 184     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 185     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 186     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 187
 188         execute_next_frame();
 189         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 190
 191         delete_fn = remove_unsafely; // not during spawning!
 192         serverprevtime = servertime;
 193         servertime = time;
 194         serverframetime = frametime;
 195
 196 #ifdef PROFILING
 197         if(time > client_cefc_accumulatortime + 1)
 198         {
 199                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 200                 int c_seeing = 0;
 201                 int c_seen = 0;
 202                 FOREACH_CLIENT(true, {
 203                         if(IS_REAL_CLIENT(it))
 204                                 ++c_seeing;
 205                         if(IS_PLAYER(it))
 206                                 ++c_seen;
 207                 });
 208                 LOG_INFO(
 209                     "CEFC time: ", ftos(t * 1000), "ms; ",
 210             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 211             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 212         );
 213                 client_cefc_accumulatortime = time;
 214                 client_cefc_accumulator = 0;
 215         }
 216 #endif
 217
 218         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 219
 220         if (RedirectionThink()) return;
 221
 222         UncustomizeEntitiesRun();
 223         InitializeEntitiesRun();
 224
 225         WarpZone_StartFrame();
 226
 227         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 228         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 229
 230         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 231                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 232
 233         // detect when the pre-game countdown (if any) has ended and the game has started
 234         bool game_delay = (time < game_starttime);
 235         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 236                 GameLogEcho(":startdelay_ended");
 237         game_delay_last = game_delay;
 238
 239         CreatureFrame_All();
 240         CheckRules_World();
 241
 242         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 243                 ReadyRestart();
 244                 return;
 245         }
 246
 247         bot_serverframe();
 248         anticheat_startframe();
 249         MUTATOR_CALLHOOK(SV_StartFrame);
 250
 251         GlobalStats_updateglobal();
 252     FOREACH_CLIENT(true, GlobalStats_update(it));
 253     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 254 }
 255
 256 .vector originjitter;
 257 .vector anglesjitter;
 258 .float anglejitter;
 259 .string gametypefilter;
 260 .string cvarfilter;
 261
 262 /**
 263  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 264  * +: all must match. this is the default
 265  * -: one must NOT match
 266  *
 267  * var>x
 268  * var<x
 269  * var>=x
 270  * var<=x
 271  * var==x
 272  * var!=x
 273  * var===x
 274  * var!==x
 275  */
 276 bool expr_evaluate(string s)
 277 {
 278     bool ret = false;
 279     if (str2chr(s, 0) == '+') {
 280         s = substring(s, 1, -1);
 281     } else if (str2chr(s, 0) == '-') {
 282         ret = true;
 283         s = substring(s, 1, -1);
 284     }
 285     bool expr_fail = false;
 286     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 287         int o;
 288         string k, v;
 289         s = argv(i);
 290         #define X(expr) \
 291             if (expr) \
 292                 continue; \
 293             expr_fail = true; \
 294             break;
 295
 296         #define BINOP(op, len, expr) \
 297             if ((o = strstrofs(s, op, 0)) >= 0) { \
 298                 k = substring(s, 0, o); \
 299                 v = substring(s, o + len, -1); \
 300                 X(expr); \
 301             }
 302         BINOP(">=", 2, cvar(k) >= stof(v));
 303         BINOP("<=", 2, cvar(k) <= stof(v));
 304         BINOP(">",  1, cvar(k) >  stof(v));
 305         BINOP("<",  1, cvar(k) <  stof(v));
 306         BINOP("==", 2, cvar(k) == stof(v));
 307         BINOP("!=", 2, cvar(k) != stof(v));
 308         BINOP("===", 3, cvar_string(k) == v);
 309         BINOP("!==", 3, cvar_string(k) != v);
 310         {
 311             k = s;
 312             bool b = true;
 313             if (str2chr(k, 0) == '!') {
 314                 k = substring(s, 1, -1);
 315                 b = false;
 316             }
 317             float f = stof(k);
 318             bool isnum = ftos(f) == k;
 319             X(boolean(isnum ? f : cvar(k)) == b);
 320         }
 321         #undef BINOP
 322         #undef X
 323     }
 324     if (!expr_fail) {
 325         ret = !ret;
 326     }
 327     // now ret is true if we want to keep the item, and false if we want to get rid of it
 328     return ret;
 329 }
 330
 331 void SV_OnEntityPreSpawnFunction(entity this)
 332 {
 333         if (this)
 334         if (this.gametypefilter != "")
 335         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 336         {
 337                 delete(this);
 338                 return;
 339         }
 340         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 341                 delete(this);
 342                 return;
 343         }
 344
 345         if (DoesQ3ARemoveThisEntity(this)) {
 346                 delete(this);
 347                 return;
 348         }
 349
 350         set_movetype(this, this.movetype);
 351
 352         if (this.monster_attack) {
 353                 IL_PUSH(g_monster_targets, this);
 354     }
 355
 356         // support special -1 and -2 angle from radiant
 357         if (this.angles == '0 -1 0') {
 358                 this.angles = '-90 0 0';
 359         } else if (this.angles == '0 -2 0') {
 360                 this.angles = '+90 0 0';
 361     }
 362
 363     #define X(out, in) MACRO_BEGIN \
 364         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 365     MACRO_END
 366     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 367     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 368     X(this.angles.y, this.anglejitter);
 369     #undef X
 370
 371         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 372                 delete(this);
 373                 return;
 374         }
 375 }
 376
 377 void WarpZone_PostInitialize_Callback()
 378 {
 379         // create waypoint links for warpzones
 380         entity tracetest_ent = spawn();
 381         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 382         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 383         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 384         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 385                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 386         delete(tracetest_ent);
 387 }
 388
 389 /*
 390 ==================
 391 main
 392
 393 unused but required by the engine
 394 ==================
 395 */
 396 void main ()
 397 {
 398
 399 }