0e0209892d447fec334eecfe976d8a368cdd2f92
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / t_items.qc
1 #ifdef CSQC
2 void ItemDraw()
3 {
4     if(self.gravity)
5     {
6         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
7         if(self.move_flags & FL_ONGROUND)
8         { // For some reason move_avelocity gets set to '0 0 0' here ...
9             self.oldorigin = self.origin;
10             self.gravity = 0;
11
12             if(autocvar_cl_animate_items)
13             { // ... so reset it if animations are requested.
14                 if(self.ItemStatus & ITS_ANIMATE1)
15                     self.move_avelocity = '0 180 0';
16
17                 if(self.ItemStatus & ITS_ANIMATE2)
18                     self.move_avelocity = '0 -90 0';
19             }
20         }
21     }
22     else if (autocvar_cl_animate_items)
23     {
24         if(self.ItemStatus & ITS_ANIMATE1)
25         {
26             self.angles += self.move_avelocity * frametime;
27             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
28         }
29
30         if(self.ItemStatus & ITS_ANIMATE2)
31         {
32             self.angles += self.move_avelocity * frametime;
33             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
34         }
35     }
36 }
37
38 void ItemDrawSimple()
39 {
40     if(self.gravity)
41     {
42         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
43
44         if(self.move_flags & FL_ONGROUND)
45             self.gravity = 0;
46     }
47 }
48
49 void ItemRead(float _IsNew)
50 {
51     float sf = ReadByte();
52
53     if(sf & ISF_LOCATION)
54     {
55         self.origin_x = ReadCoord();
56         self.origin_y = ReadCoord();
57         self.origin_z = ReadCoord();
58         setorigin(self, self.origin);
59         self.oldorigin = self.origin;
60     }
61
62     if(sf & ISF_ANGLES)
63     {
64         self.angles_x = ReadCoord();
65         self.angles_y = ReadCoord();
66         self.angles_z = ReadCoord();
67         self.move_angles = self.angles;
68     }
69
70     if(sf & ISF_SIZE)
71     {
72         self.mins_x = ReadCoord();
73         self.mins_y = ReadCoord();
74         self.mins_z = ReadCoord();
75         self.maxs_x = ReadCoord();
76         self.maxs_y = ReadCoord();
77         self.maxs_z = ReadCoord();
78         setsize(self, self.mins, self.maxs);
79     }
80
81     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
82     {
83         self.ItemStatus = ReadByte();
84
85         if(self.ItemStatus & ITS_AVAILABLE)
86         {
87             self.alpha = 1;
88             self.colormod = self.glowmod = '1 1 1';
89         }
90         else
91         {
92             if (autocvar_cl_ghost_items_color)
93             {
94                 self.alpha = autocvar_cl_ghost_items;
95                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
96             }
97             else
98                 self.alpha = -1;
99         }
100
101         if(autocvar_cl_fullbright_items)
102             if(self.ItemStatus & ITS_ALLOWFB)
103                 self.effects |= EF_FULLBRIGHT;
104
105         if(self.ItemStatus & ITS_STAYWEP)
106         {
107             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
108             self.alpha = autocvar_cl_weapon_stay_alpha;
109
110         }
111
112         if(self.ItemStatus & ITS_POWERUP)
113         {
114             if(self.ItemStatus & ITS_AVAILABLE)
115                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
116             else
117                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
118         }
119     }
120
121     if(sf & ISF_MODEL)
122     {
123         self.drawmask  = MASK_NORMAL;
124         self.movetype  = MOVETYPE_TOSS;
125         self.draw       = ItemDraw;
126
127         if(self.mdl)
128             strunzone(self.mdl);
129
130         self.mdl = "";
131         string _fn = ReadString();
132
133         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
134         {
135             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
136             self.draw = ItemDrawSimple;
137
138
139
140             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
141                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
142             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
143                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
144             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
145                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
146             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
147                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
148             else
149             {
150                 self.draw = ItemDraw;
151                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
152             }
153         }
154
155         if(self.draw != ItemDrawSimple)
156             self.mdl = strzone(_fn);
157
158
159         if(self.mdl == "")
160             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
161
162         precache_model(self.mdl);
163         setmodel(self, self.mdl);
164     }
165
166     if(sf & ISF_COLORMAP)
167         self.colormap = ReadShort();
168
169     if(sf & ISF_DROP)
170     {
171         self.gravity = 1;
172         //self.move_angles = '0 0 0';
173         self.move_movetype = MOVETYPE_TOSS;
174         self.move_velocity_x = ReadCoord();
175         self.move_velocity_y = ReadCoord();
176         self.move_velocity_z = ReadCoord();
177         self.velocity = self.move_velocity;
178         self.move_origin = self.oldorigin;
179
180         if(!self.move_time)
181         {
182             self.move_time = time;
183             self.spawntime = time;
184         }
185         else
186             self.move_time = max(self.move_time, time);
187     }
188
189     if(autocvar_cl_animate_items)
190     {
191         if(self.ItemStatus & ITS_ANIMATE1)
192             self.move_avelocity = '0 180 0';
193
194         if(self.ItemStatus & ITS_ANIMATE2)
195             self.move_avelocity = '0 -90 0';
196     }
197 }
198
199 #endif
200
201 #ifdef SVQC
202 float ItemSend(entity to, float sf)
203 {
204     if(self.gravity)
205         sf |= ISF_DROP;
206     else
207         sf &= ~ISF_DROP;
208
209         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
210         WriteByte(MSG_ENTITY, sf);
211
212         //WriteByte(MSG_ENTITY, self.cnt);
213     if(sf & ISF_LOCATION)
214     {
215         WriteCoord(MSG_ENTITY, self.origin_x);
216         WriteCoord(MSG_ENTITY, self.origin_y);
217         WriteCoord(MSG_ENTITY, self.origin_z);
218     }
219
220     if(sf & ISF_ANGLES)
221     {
222         WriteCoord(MSG_ENTITY, self.angles_x);
223         WriteCoord(MSG_ENTITY, self.angles_y);
224         WriteCoord(MSG_ENTITY, self.angles_z);
225     }
226
227     if(sf & ISF_SIZE)
228     {
229         WriteCoord(MSG_ENTITY, self.mins_x);
230         WriteCoord(MSG_ENTITY, self.mins_y);
231         WriteCoord(MSG_ENTITY, self.mins_z);
232         WriteCoord(MSG_ENTITY, self.maxs_x);
233         WriteCoord(MSG_ENTITY, self.maxs_y);
234         WriteCoord(MSG_ENTITY, self.maxs_z);
235     }
236
237     if(sf & ISF_STATUS)
238         WriteByte(MSG_ENTITY, self.ItemStatus);
239
240     if(sf & ISF_MODEL)
241     {
242
243         if(self.mdl == "")
244             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
245
246         WriteString(MSG_ENTITY, self.mdl);
247     }
248
249
250     if(sf & ISF_COLORMAP)
251         WriteShort(MSG_ENTITY, self.colormap);
252
253     if(sf & ISF_DROP)
254     {
255         WriteCoord(MSG_ENTITY, self.velocity_x);
256         WriteCoord(MSG_ENTITY, self.velocity_y);
257         WriteCoord(MSG_ENTITY, self.velocity_z);
258     }
259
260     return TRUE;
261 }
262
263 void ItemUpdate(entity item)
264 {
265         item.SendFlags |= ISF_LOCATION;
266 }
267
268 float have_pickup_item(void)
269 {
270         if(self.flags & FL_POWERUP)
271         {
272                 if(autocvar_g_powerups > 0)
273                         return TRUE;
274                 if(autocvar_g_powerups == 0)
275                         return FALSE;
276         }
277         else
278         {
279                 if(autocvar_g_pickup_items > 0)
280                         return TRUE;
281                 if(autocvar_g_pickup_items == 0)
282                         return FALSE;
283                 if(g_weaponarena)
284                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
285                                 return FALSE;
286         }
287         return TRUE;
288 }
289
290 /*
291 float Item_Customize()
292 {
293         if(self.spawnshieldtime)
294                 return TRUE;
295         if(self.weapons & ~other.weapons)
296         {
297                 self.colormod = '0 0 0';
298                 self.glowmod = self.colormod;
299                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
300                 return TRUE;
301         }
302         else
303         {
304                 if(g_ghost_items)
305                 {
306                         self.colormod = stov(autocvar_g_ghost_items_color);
307                         self.glowmod = self.colormod;
308                         self.alpha = g_ghost_items;
309                         return TRUE;
310                 }
311                 else
312                         return FALSE;
313         }
314 }
315 */
316
317 void Item_Show (entity e, float mode)
318 {
319         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
320         e.ItemStatus &= ~ITS_STAYWEP;
321         if (mode > 0)
322         {
323                 // make the item look normal, and be touchable
324                 e.model = e.mdl;
325                 e.solid = SOLID_TRIGGER;
326                 e.spawnshieldtime = 1;
327                 e.ItemStatus |= ITS_AVAILABLE;
328         }
329         else if (mode < 0)
330         {
331                 // hide the item completely
332                 e.model = string_null;
333                 e.solid = SOLID_NOT;
334                 e.spawnshieldtime = 1;
335                 e.ItemStatus &= ~ITS_AVAILABLE;
336         }
337         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
338         {
339                 // make the item translucent and not touchable
340                 e.model = e.mdl;
341                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
342                 e.effects |= EF_STARDUST;
343                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
344                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
345         }
346         else
347         {
348                 //setmodel(e, "null");
349                 e.solid = SOLID_NOT;
350                 e.colormod = '0 0 0';
351                 e.glowmod = e.colormod;
352                 e.spawnshieldtime = 1;
353                 e.ItemStatus &= ~ITS_AVAILABLE;
354         }
355
356         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
357             e.ItemStatus |= ITS_POWERUP;
358
359         if (autocvar_g_nodepthtestitems)
360                 e.effects |= EF_NODEPTHTEST;
361
362
363     if (autocvar_g_fullbrightitems)
364                 e.ItemStatus |= ITS_ALLOWFB;
365
366         if (autocvar_sv_simple_items)
367         e.ItemStatus |= ITS_ALLOWSI;
368
369         // relink entity (because solid may have changed)
370         setorigin(e, e.origin);
371     e.SendFlags |= ISF_STATUS;
372 }
373
374 void Item_Think()
375 {
376         self.nextthink = time;
377         if(self.origin != self.oldorigin)
378         {
379                 self.oldorigin = self.origin;
380                 ItemUpdate(self);
381         }
382 }
383
384 void Item_Respawn (void)
385 {
386         Item_Show(self, 1);
387         // this is ugly...
388         if(self.items == IT_STRENGTH)
389                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
390         else if(self.items == IT_INVINCIBLE)
391                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
392         else
393                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
394         setorigin (self, self.origin);
395
396         self.think = Item_Think;
397         self.nextthink = time;
398         
399         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
400         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
401 }
402
403 void Item_RespawnCountdown (void)
404 {
405         if(self.count >= ITEM_RESPAWN_TICKS)
406         {
407                 if(self.waypointsprite_attached)
408                         WaypointSprite_Kill(self.waypointsprite_attached);
409                 Item_Respawn();
410         }
411         else
412         {
413                 self.nextthink = time + 1;
414                 self.count += 1;
415                 if(self.count == 1)
416                 {
417                         string name;
418                         vector rgb = '1 0 1';
419                         name = string_null;
420                         switch(self.items)
421                         {
422                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
423                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
424                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
425                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
426                         }
427                         item_name = name;
428                         item_color = rgb;
429                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
430                         name = item_name;
431                         rgb = item_color;
432                         if(self.flags & FL_WEAPON)
433                         {
434                                 entity wi = get_weaponinfo(self.weapon);
435                                 if(wi)
436                                 {
437                                         name = wi.model2;
438                                         rgb = '1 0 0';
439                                 }
440                         }
441                         if(name)
442                         {
443                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
444                                 if(self.waypointsprite_attached)
445                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
446                         }
447                         else
448                         {
449                                 print("Unknown powerup-marked item is wanting to respawn\n");
450                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
451                         }
452                 }
453                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
454                 if(self.waypointsprite_attached)
455                 {
456                         WaypointSprite_Ping(self.waypointsprite_attached);
457                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
458                 }
459         }
460 }
461
462 void Item_RespawnThink()
463 {
464         self.nextthink = time;
465         if(self.origin != self.oldorigin)
466         {
467                 self.oldorigin = self.origin;
468                 ItemUpdate(self);
469         }
470
471         if(time >= self.wait)
472                 Item_Respawn();
473 }
474
475 void Item_ScheduleRespawnIn(entity e, float t)
476 {
477         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS))
478         {
479                 e.think = Item_RespawnCountdown;
480                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
481                 e.count = 0;
482         }
483         else
484         {
485                 e.think = Item_RespawnThink;
486                 e.nextthink = time;
487                 e.wait = time + t;
488         }
489 }
490
491 void Item_ScheduleRespawn(entity e)
492 {
493         if(e.respawntime > 0)
494         {
495                 Item_Show(e, 0);
496                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
497         }
498         else // if respawntime is -1, this item does not respawn
499                 Item_Show(e, -1);
500 }
501
502 void Item_ScheduleInitialRespawn(entity e)
503 {
504         Item_Show(e, 0);
505         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
506 }
507
508 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
509 {
510         if (!item.ammotype)
511                 return FALSE;
512
513         if (item.spawnshieldtime)
514         {
515                 if ((player.ammotype < ammomax) || item.pickup_anyway)
516                 {
517                         player.ammotype = bound(player.ammotype, ammomax, player.ammotype + item.ammotype);
518                         goto YEAH;
519                 }
520         }
521         else if(g_weapon_stay == 2)
522         {
523                 float mi = min(item.ammotype, ammomax);
524                 if (player.ammotype < mi)
525                 {
526                         player.ammotype = mi;
527                         goto YEAH;
528                 }
529         }
530
531         return FALSE;
532
533 :YEAH
534         switch(mode)
535         {
536                 case ITEM_MODE_FUEL:
537                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
538                         break;
539                 case ITEM_MODE_HEALTH:
540                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
541                         break;
542                 case ITEM_MODE_ARMOR:
543                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
544                         break;
545                 default:
546                         break;
547         }
548         return TRUE;
549 }
550
551 float Item_GiveTo(entity item, entity player)
552 {
553         float _switchweapon;
554         float pickedup;
555         float it;
556         float i;
557
558         // if nothing happens to player, just return without taking the item
559         pickedup = FALSE;
560         _switchweapon = FALSE;
561         // in case the player has autoswitch enabled do the following:
562         // if the player is using their best weapon before items are given, they
563         // probably want to switch to an even better weapon after items are given
564         if (player.autoswitch)
565         if (player.switchweapon == w_getbestweapon(player))
566                 _switchweapon = TRUE;
567
568         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
569                 _switchweapon = TRUE;
570
571         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
572         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
573         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
574         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
575         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
576         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
577         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
578         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
579
580         if (item.flags & FL_WEAPON)
581         {
582                 WepSet it;
583                 it = item.weapons;
584                 it &= ~player.weapons;
585
586                 if (it || (item.spawnshieldtime && item.pickup_anyway))
587                 {
588                         pickedup = TRUE;
589                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
590                         if(it & WepSet_FromWeapon(i))
591                                 W_GiveWeapon(player, i);
592                 }
593         }
594
595         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
596         {
597                 pickedup = TRUE;
598                 player.items |= it;
599                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
600         }
601
602         if (item.strength_finished)
603         {
604                 pickedup = TRUE;
605                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
606         }
607         if (item.invincible_finished)
608         {
609                 pickedup = TRUE;
610                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
611         }
612         if (item.superweapons_finished)
613         {
614                 pickedup = TRUE;
615                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
616         }
617
618 :skip
619
620         // always eat teamed entities
621         if(item.team)
622                 pickedup = TRUE;
623
624         if (!pickedup)
625                 return 0;
626
627         if (_switchweapon)
628                 if (player.switchweapon != w_getbestweapon(player))
629                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
630
631         return 1;
632 }
633
634 void Item_Touch (void)
635 {
636         entity e, head;
637
638         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
639         if(self.classname == "droppedweapon")
640         {
641                 if (ITEM_TOUCH_NEEDKILL())
642                 {
643                         remove(self);
644                         return;
645                 }
646         }
647
648         if (!IS_PLAYER(other))
649                 return;
650         if (other.deadflag)
651                 return;
652         if (self.solid != SOLID_TRIGGER)
653                 return;
654         if (self.owner == other)
655                 return;
656         if (time < self.item_spawnshieldtime)
657                 return;
658
659         switch(MUTATOR_CALLHOOK(ItemTouch))
660         {
661                 case MUT_ITEMTOUCH_RETURN: { return; }
662                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
663         }
664
665         if (self.classname == "droppedweapon")
666         {
667                 self.strength_finished = max(0, self.strength_finished - time);
668                 self.invincible_finished = max(0, self.invincible_finished - time);
669                 self.superweapons_finished = max(0, self.superweapons_finished - time);
670         }
671
672         if(!Item_GiveTo(self, other))
673         {
674                 if (self.classname == "droppedweapon")
675                 {
676                         // undo what we did above
677                         self.strength_finished += time;
678                         self.invincible_finished += time;
679                         self.superweapons_finished += time;
680                 }
681                 return;
682         }
683
684         :pickup
685
686         other.last_pickup = time;
687
688         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
689         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
690
691         if (self.classname == "droppedweapon")
692                 remove (self);
693         else if (!self.spawnshieldtime)
694                 return;
695         else
696         {
697                 if(self.team)
698                 {
699                         RandomSelection_Init();
700                         for(head = world; (head = findfloat(head, team, self.team)); )
701                         {
702                                 if(head.flags & FL_ITEM)
703                                 {
704                                         Item_Show(head, -1);
705                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
706                                 }
707                         }
708                         e = RandomSelection_chosen_ent;
709
710                 }
711                 else
712                         e = self;
713                 Item_ScheduleRespawn(e);
714         }
715 }
716
717 void Item_Reset()
718 {
719         Item_Show(self, !self.state);
720         setorigin (self, self.origin);
721
722         if(self.classname != "droppedweapon")
723         {
724                 self.think = Item_Think;
725                 self.nextthink = time;
726
727                 if(self.waypointsprite_attached)
728                         WaypointSprite_Kill(self.waypointsprite_attached);
729
730                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
731                         Item_ScheduleInitialRespawn(self);
732         }
733 }
734
735 void Item_FindTeam()
736 {
737         entity head, e;
738
739         if(self.effects & EF_NODRAW)
740         {
741                 // marker for item team search
742                 dprint("Initializing item team ", ftos(self.team), "\n");
743                 RandomSelection_Init();
744                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
745                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
746                 e = RandomSelection_chosen_ent;
747                 e.state = 0;
748                 Item_Show(e, 1);
749
750                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
751                 {
752                         if(head != e)
753                         {
754                                 // make it a non-spawned item
755                                 Item_Show(head, -1);
756                                 head.state = 1; // state 1 = initially hidden item
757                         }
758                         head.effects &= ~EF_NODRAW;
759                 }
760
761                 Item_Reset();
762         }
763 }
764
765 // Savage: used for item garbage-collection
766 // TODO: perhaps nice special effect?
767 void RemoveItem(void)
768 {
769         remove(self);
770 }
771
772 // pickup evaluation functions
773 // these functions decide how desirable an item is to the bots
774
775 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
776
777 float weapon_pickupevalfunc(entity player, entity item)
778 {
779         float c, j, position;
780
781         // See if I have it already
782         if(item.weapons & ~player.weapons)
783         {
784                 // If I can pick it up
785                 if(!item.spawnshieldtime)
786                         c = 0;
787                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
788                 {
789                         // Skilled bots will grab more
790                         c = bound(0, skill / 10, 1) * 0.5;
791                 }
792                 else
793                         c = 0;
794         }
795         else
796                 c = 1;
797
798         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
799         if( bot_custom_weapon && c )
800         {
801                 // Find the highest position on any range
802                 position = -1;
803                 for(j = 0; j < WEP_LAST ; ++j){
804                         if(
805                                         bot_weapons_far[j] == item.weapon ||
806                                         bot_weapons_mid[j] == item.weapon ||
807                                         bot_weapons_close[j] == item.weapon
808                           )
809                         {
810                                 position = j;
811                                 break;
812                         }
813                 }
814
815                 // Rate it
816                 if (position >= 0 )
817                 {
818                         position = WEP_LAST - position;
819                         // item.bot_pickupbasevalue is overwritten here
820                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
821                 }
822         }
823
824         return item.bot_pickupbasevalue * c;
825 }
826
827 float commodity_pickupevalfunc(entity player, entity item)
828 {
829         float c, i;
830         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_plasma = FALSE, need_fuel = FALSE;
831         entity wi;
832         c = 0;
833
834         // Detect needed ammo
835         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
836         {
837                 wi = get_weaponinfo(i);
838
839                 if (!(player.weapons & WepSet_FromWeapon(i)))
840                         continue;
841
842                 if(wi.items & IT_SHELLS)
843                         need_shells = TRUE;
844                 else if(wi.items & IT_NAILS)
845                         need_nails = TRUE;
846                 else if(wi.items & IT_ROCKETS)
847                         need_rockets = TRUE;
848                 else if(wi.items & IT_CELLS)
849                         need_cells = TRUE;
850                 else if(wi.items & IT_PLASMA)
851                         need_plasma = TRUE;
852                 else if(wi.items & IT_FUEL)
853                         need_cells = TRUE;
854         }
855
856         // TODO: figure out if the player even has the weapon this ammo is for?
857         // may not affect strategy much though...
858         // find out how much more ammo/armor/health the player can hold
859         if (need_shells)
860         if (item.ammo_shells)
861         if (player.ammo_shells < g_pickup_shells_max)
862                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
863         if (need_nails)
864         if (item.ammo_nails)
865         if (player.ammo_nails < g_pickup_nails_max)
866                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
867         if (need_rockets)
868         if (item.ammo_rockets)
869         if (player.ammo_rockets < g_pickup_rockets_max)
870                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
871         if (need_cells)
872         if (item.ammo_cells)
873         if (player.ammo_cells < g_pickup_cells_max)
874                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
875         if (need_plasma)
876         if (item.ammo_plasma)
877         if (player.ammo_plasma < g_pickup_plasma_max)
878                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
879         if (need_fuel)
880         if (item.ammo_fuel)
881         if (player.ammo_fuel < g_pickup_fuel_max)
882                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
883         if (item.armorvalue)
884         if (player.armorvalue < item.max_armorvalue)
885                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
886         if (item.health)
887         if (player.health < item.max_health)
888                 c = c + max(0, 1 - player.health / item.max_health);
889
890         return item.bot_pickupbasevalue * c;
891 }
892
893 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
894 {
895         if(ITEM_DAMAGE_NEEDKILL(deathtype))
896                 RemoveItem();
897 }
898
899 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
900 {
901         startitem_failed = FALSE;
902
903         if(self.model == "")
904                 self.model = itemmodel;
905
906         if(self.model == "")
907     {
908         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
909         return;
910     }
911
912         if(self.item_pickupsound == "")
913                 self.item_pickupsound = pickupsound;
914
915         if(!self.respawntime) // both need to be set
916         {
917                 self.respawntime = defaultrespawntime;
918                 self.respawntimejitter = defaultrespawntimejitter;
919         }
920
921         self.items = itemid;
922         self.weapon = weaponid;
923
924         if(weaponid)
925                 self.weapons = WepSet_FromWeapon(weaponid);
926
927         self.flags = FL_ITEM | itemflags;
928
929         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
930         {
931                 startitem_failed = TRUE;
932                 remove(self);
933                 return;
934         }
935
936         // is it a dropped weapon?
937         if (self.classname == "droppedweapon")
938         {
939                 self.reset = SUB_Remove;
940                 // it's a dropped weapon
941                 self.movetype = MOVETYPE_TOSS;
942
943                 // Savage: remove thrown items after a certain period of time ("garbage collection")
944                 self.think = RemoveItem;
945                 self.nextthink = time + 20;
946
947                 self.takedamage = DAMAGE_YES;
948                 self.event_damage = Item_Damage;
949
950                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
951                 /*
952                 if(self.items == 0)
953                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
954                 if(self.ammo_nails == 0)
955                 if(self.ammo_cells == 0)
956                 if(self.ammo_rockets == 0)
957                 if(self.ammo_shells == 0)
958                 if(self.ammo_fuel == 0)
959                 if(self.health == 0)
960                 if(self.armorvalue == 0)
961                 */
962                 {
963                         // if item is worthless after a timer, have it expire then
964                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
965                 }
966
967                 // don't drop if in a NODROP zone (such as lava)
968                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
969                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
970                 {
971                         startitem_failed = TRUE;
972                         remove(self);
973                         return;
974                 }
975         }
976         else
977         {
978                 if(!have_pickup_item())
979                 {
980                         startitem_failed = TRUE;
981                         remove (self);
982                         return;
983                 }
984
985                 self.reset = Item_Reset;
986                 // it's a level item
987                 if(self.spawnflags & 1)
988                         self.noalign = 1;
989                 if (self.noalign)
990                         self.movetype = MOVETYPE_NONE;
991                 else
992                         self.movetype = MOVETYPE_TOSS;
993                 // do item filtering according to game mode and other things
994                 if (!self.noalign)
995                 {
996                         // first nudge it off the floor a little bit to avoid math errors
997                         setorigin(self, self.origin + '0 0 1');
998                         // set item size before we spawn a spawnfunc_waypoint
999                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1000                                 setsize (self, '-16 -16 0', '16 16 48');
1001                         else
1002                                 setsize (self, '-16 -16 0', '16 16 32');
1003
1004                         // note droptofloor returns FALSE if stuck/or would fall too far
1005                         droptofloor();
1006                         waypoint_spawnforitem(self);
1007                 }
1008
1009                 /*
1010                  * can't do it that way, as it would break maps
1011                  * TODO make a target_give like entity another way, that perhaps has
1012                  * the weapon name in a key
1013                 if(self.targetname)
1014                 {
1015                         // target_give not yet supported; maybe later
1016                         print("removed targeted ", self.classname, "\n");
1017                         startitem_failed = TRUE;
1018                         remove (self);
1019                         return;
1020                 }
1021                 */
1022
1023                 if(autocvar_spawn_debug >= 2)
1024                 {
1025                         entity otheritem;
1026                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1027                         {
1028                             // why not flags & fl_item?
1029                                 if(otheritem.is_item)
1030                                 {
1031                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1032                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1033                                         error("Mapper sucks.");
1034                                 }
1035                         }
1036                         self.is_item = TRUE;
1037                 }
1038
1039                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1040
1041                 precache_model (self.model);
1042                 precache_sound (self.item_pickupsound);
1043
1044                 precache_sound ("misc/itemrespawncountdown.wav");
1045                 if(itemid == IT_STRENGTH)
1046                         precache_sound ("misc/strength_respawn.wav");
1047                 else if(itemid == IT_INVINCIBLE)
1048                         precache_sound ("misc/shield_respawn.wav");
1049                 else
1050                         precache_sound ("misc/itemrespawn.wav");
1051
1052                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1053                         self.target = "###item###"; // for finding the nearest item using find()
1054         }
1055
1056         self.bot_pickup = TRUE;
1057         self.bot_pickupevalfunc = pickupevalfunc;
1058         self.bot_pickupbasevalue = pickupbasevalue;
1059         self.mdl = self.model;
1060         self.netname = itemname;
1061         self.touch = Item_Touch;
1062         setmodel(self, "null"); // precision set below
1063         //self.effects |= EF_LOWPRECISION;
1064
1065         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1066     {
1067         self.pos1 = '-16 -16 0';
1068         self.pos2 = '16 16 48';
1069     }
1070         else
1071     {
1072         self.pos1 = '-16 -16 0';
1073         self.pos2 = '16 16 32';
1074     }
1075     setsize (self, self.pos1, self.pos2);
1076
1077     if(itemflags & FL_POWERUP)
1078         self.ItemStatus |= ITS_ANIMATE1;
1079
1080         if(self.armorvalue || self.health)
1081         self.ItemStatus |= ITS_ANIMATE2;
1082
1083         if(itemflags & FL_WEAPON)
1084         {
1085                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1086             self.colormap = 1024; // color shirt=0 pants=0 grey
1087         else
1088             self.gravity = 1;
1089
1090                 self.ItemStatus |= ITS_ANIMATE1;
1091                 self.ItemStatus |= ISF_COLORMAP;
1092         }
1093
1094         self.state = 0;
1095         if(self.team) // broken, no idea why.
1096         {
1097                 if(!self.cnt)
1098                         self.cnt = 1; // item probability weight
1099
1100                 self.effects |= EF_NODRAW; // marker for item team search
1101                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1102         }
1103         else
1104                 Item_Reset();
1105
1106     Net_LinkEntity(self, FALSE, 0, ItemSend);
1107         
1108         self.SendFlags |= ISF_SIZE;
1109         if(self.angles)
1110                 self.SendFlags |= ISF_ANGLES;
1111
1112         // call this hook after everything else has been done
1113         if(MUTATOR_CALLHOOK(Item_Spawn))
1114         {
1115                 startitem_failed = TRUE;
1116                 remove(self);
1117                 return;
1118         }
1119 }
1120 void spawnfunc_item_rockets (void) {
1121         if(!self.ammo_rockets)
1122                 self.ammo_rockets = g_pickup_rockets;
1123         if(!self.pickup_anyway)
1124                 self.pickup_anyway = g_pickup_ammo_anyway;
1125         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1126 }
1127
1128 void spawnfunc_item_shells (void);
1129 void spawnfunc_item_bullets (void) {
1130         if(!weaponswapping)
1131         if(autocvar_sv_q3acompat_machineshotgunswap)
1132         if(self.classname != "droppedweapon")
1133         {
1134                 weaponswapping = TRUE;
1135                 spawnfunc_item_shells();
1136                 weaponswapping = FALSE;
1137                 return;
1138         }
1139
1140         if(!self.ammo_nails)
1141                 self.ammo_nails = g_pickup_nails;
1142         if(!self.pickup_anyway)
1143                 self.pickup_anyway = g_pickup_ammo_anyway;
1144         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1145 }
1146
1147 void spawnfunc_item_cells (void) {
1148         if(!self.ammo_cells)
1149                 self.ammo_cells = g_pickup_cells;
1150         if(!self.pickup_anyway)
1151                 self.pickup_anyway = g_pickup_ammo_anyway;
1152         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1153 }
1154
1155 void spawnfunc_item_plasma()
1156 {
1157         if(!self.ammo_plasma)
1158                 self.ammo_plasma = g_pickup_plasma;
1159         if(!self.pickup_anyway)
1160                 self.pickup_anyway = g_pickup_ammo_anyway;
1161         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "plasma", IT_PLASMA, 0, 0, commodity_pickupevalfunc, 2000);
1162 }
1163
1164 void spawnfunc_item_shells (void) {
1165         if(!weaponswapping)
1166         if(autocvar_sv_q3acompat_machineshotgunswap)
1167         if(self.classname != "droppedweapon")
1168         {
1169                 weaponswapping = TRUE;
1170                 spawnfunc_item_bullets();
1171                 weaponswapping = FALSE;
1172                 return;
1173         }
1174
1175         if(!self.ammo_shells)
1176                 self.ammo_shells = g_pickup_shells;
1177         if(!self.pickup_anyway)
1178                 self.pickup_anyway = g_pickup_ammo_anyway;
1179         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1180 }
1181
1182 void spawnfunc_item_armor_small (void) {
1183         if(!self.armorvalue)
1184                 self.armorvalue = g_pickup_armorsmall;
1185         if(!self.max_armorvalue)
1186                 self.max_armorvalue = g_pickup_armorsmall_max;
1187         if(!self.pickup_anyway)
1188                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1189         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1190 }
1191
1192 void spawnfunc_item_armor_medium (void) {
1193         if(!self.armorvalue)
1194                 self.armorvalue = g_pickup_armormedium;
1195         if(!self.max_armorvalue)
1196                 self.max_armorvalue = g_pickup_armormedium_max;
1197         if(!self.pickup_anyway)
1198                 self.pickup_anyway = g_pickup_armormedium_anyway;
1199         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1200 }
1201
1202 void spawnfunc_item_armor_big (void) {
1203         if(!self.armorvalue)
1204                 self.armorvalue = g_pickup_armorbig;
1205         if(!self.max_armorvalue)
1206                 self.max_armorvalue = g_pickup_armorbig_max;
1207         if(!self.pickup_anyway)
1208                 self.pickup_anyway = g_pickup_armorbig_anyway;
1209         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1210 }
1211
1212 void spawnfunc_item_armor_large (void) {
1213         if(!self.armorvalue)
1214                 self.armorvalue = g_pickup_armorlarge;
1215         if(!self.max_armorvalue)
1216                 self.max_armorvalue = g_pickup_armorlarge_max;
1217         if(!self.pickup_anyway)
1218                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1219         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1220 }
1221
1222 void spawnfunc_item_health_small (void) {
1223         if(!self.max_health)
1224                 self.max_health = g_pickup_healthsmall_max;
1225         if(!self.health)
1226                 self.health = g_pickup_healthsmall;
1227         if(!self.pickup_anyway)
1228                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1229         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1230 }
1231
1232 void spawnfunc_item_health_medium (void) {
1233         if(!self.max_health)
1234                 self.max_health = g_pickup_healthmedium_max;
1235         if(!self.health)
1236                 self.health = g_pickup_healthmedium;
1237         if(!self.pickup_anyway)
1238                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1239         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1240 }
1241
1242 void spawnfunc_item_health_large (void) {
1243         if(!self.max_health)
1244                 self.max_health = g_pickup_healthlarge_max;
1245         if(!self.health)
1246                 self.health = g_pickup_healthlarge;
1247         if(!self.pickup_anyway)
1248                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1249         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1250 }
1251
1252 void spawnfunc_item_health_mega (void) {
1253                 if(!self.max_health)
1254                         self.max_health = g_pickup_healthmega_max;
1255                 if(!self.health)
1256                         self.health = g_pickup_healthmega;
1257                 if(!self.pickup_anyway)
1258                         self.pickup_anyway = g_pickup_healthmega_anyway;
1259                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1260 }
1261
1262 // support old misnamed entities
1263 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1264 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1265 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1266 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1267 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1268
1269 void spawnfunc_item_strength (void) {
1270                 precache_sound("weapons/strength_fire.wav");
1271                 if(!self.strength_finished)
1272                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1273                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1274 }
1275
1276 void spawnfunc_item_invincible (void) {
1277                 if(!self.invincible_finished)
1278                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1279                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1280 }
1281
1282 // compatibility:
1283 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1284
1285 void target_items_use (void)
1286 {
1287         if(activator.classname == "droppedweapon")
1288         {
1289                 EXACTTRIGGER_TOUCH;
1290                 remove(activator);
1291                 return;
1292         }
1293
1294         if (!IS_PLAYER(activator))
1295                 return;
1296         if(activator.deadflag != DEAD_NO)
1297                 return;
1298         EXACTTRIGGER_TOUCH;
1299
1300         entity e;
1301         for(e = world; (e = find(e, classname, "droppedweapon")); )
1302                 if(e.enemy == activator)
1303                         remove(e);
1304
1305         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1306                 centerprint(activator, self.message);
1307 }
1308
1309 void spawnfunc_target_items (void)
1310 {
1311         float n, i, j;
1312         entity e;
1313
1314         self.use = target_items_use;
1315         if(!self.strength_finished)
1316                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1317         if(!self.invincible_finished)
1318                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1319         if(!self.superweapons_finished)
1320                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1321
1322         precache_sound("misc/itempickup.wav");
1323         precache_sound("misc/megahealth.wav");
1324         precache_sound("misc/armor25.wav");
1325         precache_sound("misc/powerup.wav");
1326         precache_sound("misc/poweroff.wav");
1327         precache_sound("weapons/weaponpickup.wav");
1328
1329         n = tokenize_console(self.netname);
1330         if(argv(0) == "give")
1331         {
1332                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1333         }
1334         else
1335         {
1336                 for(i = 0; i < n; ++i)
1337                 {
1338                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1339                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1340                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1341                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1342                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1343                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1344                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1345                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1346                         else
1347                         {
1348                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1349                                 {
1350                                         e = get_weaponinfo(j);
1351                                         if(argv(i) == e.netname)
1352                                         {
1353                                                 self.weapons |= WepSet_FromWeapon(j);
1354                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1355                                                         WEP_ACTION(e.weapon, WR_INIT);
1356                                                 break;
1357                                         }
1358                                 }
1359                                 if(j > WEP_LAST)
1360                                         print("target_items: invalid item ", argv(i), "\n");
1361                         }
1362                 }
1363
1364                 string itemprefix, valueprefix;
1365                 if(self.spawnflags == 0)
1366                 {
1367                         itemprefix = "";
1368                         valueprefix = "";
1369                 }
1370                 else if(self.spawnflags == 1)
1371                 {
1372                         itemprefix = "max ";
1373                         valueprefix = "max ";
1374                 }
1375                 else if(self.spawnflags == 2)
1376                 {
1377                         itemprefix = "min ";
1378                         valueprefix = "min ";
1379                 }
1380                 else if(self.spawnflags == 4)
1381                 {
1382                         itemprefix = "minus ";
1383                         valueprefix = "max ";
1384                 }
1385                 else
1386                 {
1387                         error("invalid spawnflags");
1388 #ifdef GMQCC
1389                         itemprefix = string_null;
1390                         valueprefix = string_null;
1391 #endif
1392                 }
1393
1394                 self.netname = "";
1395                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1396                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1397                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1398                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1399                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1400                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1401                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1402                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1403                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1404                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1405                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1406                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1407                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1408                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1409                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1410                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1411                 {
1412                         e = get_weaponinfo(j);
1413                         if(e.weapon)
1414                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1415                 }
1416         }
1417         self.netname = strzone(self.netname);
1418         //print(self.netname, "\n");
1419
1420         n = tokenize_console(self.netname);
1421         for(i = 0; i < n; ++i)
1422         {
1423                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1424                 {
1425                         e = get_weaponinfo(j);
1426                         if(argv(i) == e.netname)
1427                         {
1428                                 WEP_ACTION(e.weapon, WR_INIT);
1429                                 break;
1430                         }
1431                 }
1432         }
1433 }
1434
1435 void spawnfunc_item_fuel(void)
1436 {
1437         if(!self.ammo_fuel)
1438                 self.ammo_fuel = g_pickup_fuel;
1439         if(!self.pickup_anyway)
1440                 self.pickup_anyway = g_pickup_ammo_anyway;
1441         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1442 }
1443
1444 void spawnfunc_item_fuel_regen(void)
1445 {
1446         if(start_items & IT_FUEL_REGEN)
1447         {
1448                 spawnfunc_item_fuel();
1449                 return;
1450         }
1451         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1452 }
1453
1454 void spawnfunc_item_jetpack(void)
1455 {
1456         if(g_grappling_hook)
1457                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1458         if(!self.ammo_fuel)
1459                 self.ammo_fuel = g_pickup_fuel_jetpack;
1460         if(start_items & IT_JETPACK)
1461         {
1462                 spawnfunc_item_fuel();
1463                 return;
1464         }
1465         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1466 }
1467
1468 float GiveWeapon(entity e, float wpn, float op, float val)
1469 {
1470         WepSet v0, v1;
1471         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1472         switch(op)
1473         {
1474                 case OP_SET:
1475                         if(val > 0)
1476                                 e.weapons |= WepSet_FromWeapon(wpn);
1477                         else
1478                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1479                         break;
1480                 case OP_MIN:
1481                 case OP_PLUS:
1482                         if(val > 0)
1483                                 e.weapons |= WepSet_FromWeapon(wpn);
1484                         break;
1485                 case OP_MAX:
1486                         if(val <= 0)
1487                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1488                         break;
1489                 case OP_MINUS:
1490                         if(val > 0)
1491                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1492                         break;
1493         }
1494         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1495         return (v0 != v1);
1496 }
1497
1498 float GiveBit(entity e, .float fld, float bit, float op, float val)
1499 {
1500         float v0, v1;
1501         v0 = (e.fld & bit);
1502         switch(op)
1503         {
1504                 case OP_SET:
1505                         if(val > 0)
1506                                 e.fld |= bit;
1507                         else
1508                                 e.fld &= ~bit;
1509                         break;
1510                 case OP_MIN:
1511                 case OP_PLUS:
1512                         if(val > 0)
1513                                 e.fld |= bit;
1514                         break;
1515                 case OP_MAX:
1516                         if(val <= 0)
1517                                 e.fld &= ~bit;
1518                         break;
1519                 case OP_MINUS:
1520                         if(val > 0)
1521                                 e.fld &= ~bit;
1522                         break;
1523         }
1524         v1 = (e.fld & bit);
1525         return (v0 != v1);
1526 }
1527
1528 float GiveValue(entity e, .float fld, float op, float val)
1529 {
1530         float v0, v1;
1531         v0 = e.fld;
1532         switch(op)
1533         {
1534                 case OP_SET:
1535                         e.fld = val;
1536                         break;
1537                 case OP_MIN:
1538                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1539                         break;
1540                 case OP_MAX:
1541                         e.fld = min(e.fld, val);
1542                         break;
1543                 case OP_PLUS:
1544                         e.fld += val;
1545                         break;
1546                 case OP_MINUS:
1547                         e.fld -= val;
1548                         break;
1549         }
1550         v1 = e.fld;
1551         return (v0 != v1);
1552 }
1553
1554 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1555 {
1556         if(v1 == v0)
1557                 return;
1558         if(v1 <= v0 - t)
1559         {
1560                 if(snd_decr != "")
1561                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1562         }
1563         else if(v0 >= v0 + t)
1564         {
1565                 if(snd_incr != "")
1566                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1567         }
1568 }
1569
1570 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1571 {
1572         if(v0 < v1)
1573                 e.rotfield = max(e.rotfield, time + rottime);
1574         else if(v0 > v1)
1575                 e.regenfield = max(e.regenfield, time + regentime);
1576 }
1577 float GiveItems(entity e, float beginarg, float endarg)
1578 {
1579         float got, i, j, val, op;
1580         float _switchweapon;
1581         entity wi;
1582         string cmd;
1583
1584         val = 999;
1585         op = OP_SET;
1586
1587         got = 0;
1588
1589         _switchweapon = FALSE;
1590         if (e.autoswitch)
1591                 if (e.switchweapon == w_getbestweapon(e))
1592                         _switchweapon = TRUE;
1593
1594         e.strength_finished = max(0, e.strength_finished - time);
1595         e.invincible_finished = max(0, e.invincible_finished - time);
1596         e.superweapons_finished = max(0, e.superweapons_finished - time);
1597
1598         PREGIVE(e, items);
1599         PREGIVE_WEAPONS(e);
1600         PREGIVE(e, strength_finished);
1601         PREGIVE(e, invincible_finished);
1602         PREGIVE(e, superweapons_finished);
1603         PREGIVE(e, ammo_nails);
1604         PREGIVE(e, ammo_cells);
1605         PREGIVE(e, ammo_plasma);
1606         PREGIVE(e, ammo_shells);
1607         PREGIVE(e, ammo_rockets);
1608         PREGIVE(e, ammo_fuel);
1609         PREGIVE(e, armorvalue);
1610         PREGIVE(e, health);
1611
1612         for(i = beginarg; i < endarg; ++i)
1613         {
1614                 cmd = argv(i);
1615
1616                 if(cmd == "0" || stof(cmd))
1617                 {
1618                         val = stof(cmd);
1619                         continue;
1620                 }
1621                 switch(cmd)
1622                 {
1623                         case "no":
1624                                 op = OP_MAX;
1625                                 val = 0;
1626                                 continue;
1627                         case "max":
1628                                 op = OP_MAX;
1629                                 continue;
1630                         case "min":
1631                                 op = OP_MIN;
1632                                 continue;
1633                         case "plus":
1634                                 op = OP_PLUS;
1635                                 continue;
1636                         case "minus":
1637                                 op = OP_MINUS;
1638                                 continue;
1639                         case "ALL":
1640                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1641                                 got += GiveValue(e, strength_finished, op, val);
1642                                 got += GiveValue(e, invincible_finished, op, val);
1643                                 got += GiveValue(e, superweapons_finished, op, val);
1644                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1645                         case "all":
1646                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1647                                 got += GiveValue(e, health, op, val);
1648                                 got += GiveValue(e, armorvalue, op, val);
1649                         case "allweapons":
1650                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1651                                 {
1652                                         wi = get_weaponinfo(j);
1653                                         if(wi.weapon)
1654                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1655                                                         got += GiveWeapon(e, j, op, val);
1656                                 }
1657                         case "allammo":
1658                                 got += GiveValue(e, ammo_cells, op, val);
1659                                 got += GiveValue(e, ammo_plasma, op, val);
1660                                 got += GiveValue(e, ammo_shells, op, val);
1661                                 got += GiveValue(e, ammo_nails, op, val);
1662                                 got += GiveValue(e, ammo_rockets, op, val);
1663                                 got += GiveValue(e, ammo_fuel, op, val);
1664                                 break;
1665                         case "unlimited_ammo":
1666                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1667                                 break;
1668                         case "unlimited_weapon_ammo":
1669                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1670                                 break;
1671                         case "unlimited_superweapons":
1672                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1673                                 break;
1674                         case "jetpack":
1675                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1676                                 break;
1677                         case "fuel_regen":
1678                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1679                                 break;
1680                         case "strength":
1681                                 got += GiveValue(e, strength_finished, op, val);
1682                                 break;
1683                         case "invincible":
1684                                 got += GiveValue(e, invincible_finished, op, val);
1685                                 break;
1686                         case "superweapons":
1687                                 got += GiveValue(e, superweapons_finished, op, val);
1688                                 break;
1689                         case "cells":
1690                                 got += GiveValue(e, ammo_cells, op, val);
1691                                 break;
1692                         case "plasma":
1693                                 got += GiveValue(e, ammo_plasma, op, val);
1694                                 break;
1695                         case "shells":
1696                                 got += GiveValue(e, ammo_shells, op, val);
1697                                 break;
1698                         case "nails":
1699                         case "bullets":
1700                                 got += GiveValue(e, ammo_nails, op, val);
1701                                 break;
1702                         case "rockets":
1703                                 got += GiveValue(e, ammo_rockets, op, val);
1704                                 break;
1705                         case "health":
1706                                 got += GiveValue(e, health, op, val);
1707                                 break;
1708                         case "armor":
1709                                 got += GiveValue(e, armorvalue, op, val);
1710                                 break;
1711                         case "fuel":
1712                                 got += GiveValue(e, ammo_fuel, op, val);
1713                                 break;
1714                         default:
1715                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1716                                 {
1717                                         wi = get_weaponinfo(j);
1718                                         if(cmd == wi.netname)
1719                                         {
1720                                                 got += GiveWeapon(e, j, op, val);
1721                                                 break;
1722                                         }
1723                                 }
1724                                 if(j > WEP_LAST)
1725                                         print("give: invalid item ", cmd, "\n");
1726                                 break;
1727                 }
1728                 val = 999;
1729                 op = OP_SET;
1730         }
1731
1732         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1733         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1734         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1735         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1736         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1737         {
1738                 wi = get_weaponinfo(j);
1739                 if(wi.weapon)
1740                 {
1741                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1742                         if (!(save_weapons & WepSet_FromWeapon(j)))
1743                                 if(e.weapons & WepSet_FromWeapon(j))
1744                                         WEP_ACTION(wi.weapon, WR_INIT);
1745                 }
1746         }
1747         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1748         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1749         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1750         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1751         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1752         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1753         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1754         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1755         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1756         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1757
1758         if(e.superweapons_finished <= 0)
1759                 if(self.weapons & WEPSET_SUPERWEAPONS)
1760                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1761
1762         if(e.strength_finished <= 0)
1763                 e.strength_finished = 0;
1764         else
1765                 e.strength_finished += time;
1766         if(e.invincible_finished <= 0)
1767                 e.invincible_finished = 0;
1768         else
1769                 e.invincible_finished += time;
1770         if(e.superweapons_finished <= 0)
1771                 e.superweapons_finished = 0;
1772         else
1773                 e.superweapons_finished += time;
1774
1775         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1776                 _switchweapon = TRUE;
1777         if(_switchweapon)
1778                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1779
1780         return got;
1781 }
1782 #endif