2cc9e1f4355200847756cd0bd9e5b948281a8138
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / t_items.qc
1 #define ISF_LOCATION 2
2 #define ISF_MODEL    4
3 #define ISF_STATUS   8
4     #define ITS_STAYWEP   1
5     #define ITS_ANIMATE1  2
6     #define ITS_ANIMATE2  4
7     #define ITS_AVAILABLE 8
8     #define ITS_ALLOWFB   16
9     #define ITS_ALLOWSI   32
10     #define ITS_POWERUP   64
11 #define ISF_COLORMAP 16
12 #define ISF_DROP 32
13 #define ISF_ANGLES 64
14
15 .float ItemStatus;
16
17 #ifdef CSQC
18
19 var float  autocvar_cl_animate_items = 1;
20 var float  autocvar_cl_ghost_items = 0.45;
21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
22 var float  autocvar_cl_fullbright_items = 0;
23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
25 var float  autocvar_cl_simple_items = 0;
26 var string autocvr_cl_simpleitems_postfix = "_simple";
27 .float  spawntime;
28 .float  gravity;
29 .vector colormod;
30 void ItemDraw()
31 {    
32     if(self.gravity)
33     {        
34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
35         if(self.move_flags & FL_ONGROUND) 
36         { // For some reason move_avelocity gets set to '0 0 0' here ...
37             self.oldorigin = self.origin;
38             self.gravity = 0;
39
40             if(autocvar_cl_animate_items)   
41             { // ... so reset it if animations are requested. 
42                 if(self.ItemStatus & ITS_ANIMATE1)
43                     self.move_avelocity = '0 180 0';
44                 
45                 if(self.ItemStatus & ITS_ANIMATE2)
46                     self.move_avelocity = '0 -90 0';
47             }
48         }
49     }
50     else if (autocvar_cl_animate_items)
51     {        
52         if(self.ItemStatus & ITS_ANIMATE1)
53         {
54             self.angles += self.move_avelocity * frametime;
55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));        
56         }    
57         
58         if(self.ItemStatus & ITS_ANIMATE2)
59         {
60             self.angles += self.move_avelocity * frametime;
61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));        
62         }
63     }
64 }
65
66 void ItemDrawSimple()
67 {
68     if(self.gravity)
69     {        
70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);    
71         
72         if(self.move_flags & FL_ONGROUND)
73             self.gravity = 0;
74     }
75 }
76
77 void ItemRead(float _IsNew)
78 {
79     float sf = ReadByte();
80
81     if(sf & ISF_LOCATION)
82     {
83         self.origin_x = ReadCoord();
84         self.origin_y = ReadCoord();
85         self.origin_z = ReadCoord();
86         setorigin(self, self.origin);
87         self.oldorigin = self.origin;
88     }
89     
90     if(sf & ISF_ANGLES) 
91     {
92         self.angles_x = ReadCoord();
93         self.angles_y = ReadCoord();
94         self.angles_z = ReadCoord();        
95         self.move_angles = self.angles;
96     }
97     
98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
99     {
100         self.ItemStatus = ReadByte();    
101         
102         if(self.ItemStatus & ITS_AVAILABLE)
103         {
104             self.alpha = 1;
105             self.colormod = self.glowmod = '1 1 1';
106         }
107         else
108         {
109             if (autocvar_cl_ghost_items_color)
110             {
111                 self.alpha = autocvar_cl_ghost_items;
112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
113             }
114             else
115                 self.alpha = -1;
116         }    
117         
118         if(autocvar_cl_fullbright_items)
119             if(self.ItemStatus & ITS_ALLOWFB)
120                 self.effects |= EF_FULLBRIGHT;
121             
122         if(self.ItemStatus & ITS_STAYWEP)
123         {
124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
125             self.alpha = autocvar_cl_weapon_stay_alpha;
126             
127         }
128         
129         if(self.ItemStatus & ITS_POWERUP)
130         {
131             if(self.ItemStatus & ITS_AVAILABLE)
132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
133             else
134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
135         }
136     }
137     
138     if(sf & ISF_MODEL)
139     {
140         self.drawmask  = MASK_NORMAL;
141         self.movetype  = MOVETYPE_NOCLIP;
142         self.draw       = ItemDraw;
143         
144         if(self.mdl)
145             strunzone(self.mdl);
146         
147         self.mdl = "";
148         string _fn = ReadString();
149         
150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
151         {
152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
153             self.draw = ItemDrawSimple;
154                     
155             
156             
157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
165             else
166             {
167                 self.draw = ItemDraw;
168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
169             }
170         }
171         
172         if(self.draw != ItemDrawSimple)        
173             self.mdl = strzone(_fn);                
174         
175         
176         if(self.mdl == "")
177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
178         
179         precache_model(self.mdl);
180         setmodel(self, self.mdl);
181     }
182     
183     if(sf & ISF_COLORMAP)
184         self.colormap = ReadShort();
185     
186     if(sf & ISF_DROP)
187     {
188         self.gravity = 1;
189         self.move_angles = '0 0 0';
190         self.move_movetype = MOVETYPE_TOSS;
191         self.move_velocity_x = ReadCoord();
192         self.move_velocity_y = ReadCoord();
193         self.move_velocity_z = ReadCoord();
194         self.velocity = self.move_velocity;
195         self.move_origin = self.oldorigin;
196         
197         if(!self.move_time)
198         {
199             self.move_time = time;
200             self.spawntime = time;
201         }
202         else
203             self.move_time = max(self.move_time, time);
204     }
205         
206     if(autocvar_cl_animate_items)
207     {        
208         if(self.ItemStatus & ITS_ANIMATE1)
209             self.move_avelocity = '0 180 0';
210                 
211         if(self.ItemStatus & ITS_ANIMATE2)
212             self.move_avelocity = '0 -90 0';
213     }
214 }
215
216 #endif
217
218 #ifdef SVQC
219 float autocvar_sv_simple_items;
220 float ItemSend(entity to, float sf)
221 {
222     if(self.gravity)
223         sf |= ISF_DROP;
224     else
225         sf &~= ISF_DROP;
226         
227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM); 
228         WriteByte(MSG_ENTITY, sf);
229
230         //WriteByte(MSG_ENTITY, self.cnt);
231     if(sf & ISF_LOCATION)
232     {
233         WriteCoord(MSG_ENTITY, self.origin_x);
234         WriteCoord(MSG_ENTITY, self.origin_y);
235         WriteCoord(MSG_ENTITY, self.origin_z);
236     }
237     
238     if(sf & ISF_ANGLES)
239     {
240         WriteCoord(MSG_ENTITY, self.angles_x);
241         WriteCoord(MSG_ENTITY, self.angles_y);
242         WriteCoord(MSG_ENTITY, self.angles_z);
243     }
244
245     if(sf & ISF_STATUS)
246         WriteByte(MSG_ENTITY, self.ItemStatus);
247
248     if(sf & ISF_MODEL)
249     {
250         
251         if(self.mdl == "")
252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
253         
254         WriteString(MSG_ENTITY, self.mdl);
255     }
256         
257         
258     if(sf & ISF_COLORMAP)
259         WriteShort(MSG_ENTITY, self.colormap);
260
261     if(sf & ISF_DROP)
262     {
263         WriteCoord(MSG_ENTITY, self.velocity_x);
264         WriteCoord(MSG_ENTITY, self.velocity_y);
265         WriteCoord(MSG_ENTITY, self.velocity_z);
266     }
267         
268     return TRUE;
269 }
270
271
272 float have_pickup_item(void)
273 {
274         if(self.flags & FL_POWERUP)
275         {
276                 if(autocvar_g_powerups > 0)
277                         return TRUE;
278                 if(autocvar_g_powerups == 0)
279                         return FALSE;
280                 if(g_ca)
281                         return FALSE;
282                 if(g_arena)
283                         return FALSE;
284         }
285         else
286         {
287                 if(autocvar_g_pickup_items > 0)
288                         return TRUE;
289                 if(autocvar_g_pickup_items == 0)
290                         return FALSE;
291                 if(g_ca)
292                         return FALSE;
293                 if(g_weaponarena)
294                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
295                                 return FALSE;
296         }
297         return TRUE;
298 }
299
300 #define ITEM_RESPAWN_TICKS 10
301
302 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
303         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
304 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
305         // range: 10 .. respawntime + respawntimejitter
306
307 floatfield Item_CounterField(float it)
308 {
309         switch(it)
310         {
311                 case IT_SHELLS:      return ammo_shells;
312                 case IT_NAILS:       return ammo_nails;
313                 case IT_ROCKETS:     return ammo_rockets;
314                 case IT_CELLS:       return ammo_cells;
315                 case IT_FUEL:        return ammo_fuel;
316                 case IT_5HP:         return health;
317                 case IT_25HP:        return health;
318                 case IT_HEALTH:      return health;
319                 case IT_ARMOR_SHARD: return armorvalue;
320                 case IT_ARMOR:       return armorvalue;
321                 // add more things here (health, armor)
322                 default:             error("requested item has no counter field");
323         }
324 #ifdef GMQCC
325         // should never happen
326         return health;
327 #endif
328 }
329
330 string Item_CounterFieldName(float it)
331 {
332         switch(it)
333         {
334                 case IT_SHELLS:      return "shells";
335                 case IT_NAILS:       return "nails";
336                 case IT_ROCKETS:     return "rockets";
337                 case IT_CELLS:       return "cells";
338                 case IT_FUEL:        return "fuel";
339
340                 // add more things here (health, armor)
341                 default:             error("requested item has no counter field name");
342         }
343 #ifdef GMQCC
344         // should never happen
345         return string_null;
346 #endif
347 }
348
349 .float max_armorvalue;
350 .float pickup_anyway;
351 /*
352 float Item_Customize()
353 {
354         if(self.spawnshieldtime)
355                 return TRUE;
356         if(!WEPSET_CONTAINS_ALL_EE(other, self))
357         {
358                 self.colormod = '0 0 0';
359                 self.glowmod = self.colormod;
360                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
361                 return TRUE;
362         }
363         else
364         {
365                 if(g_ghost_items)
366                 {
367                         self.colormod = stov(autocvar_g_ghost_items_color);
368                         self.glowmod = self.colormod;
369                         self.alpha = g_ghost_items;
370                         return TRUE;
371                 }
372                 else
373                         return FALSE;
374         }
375 }
376 */
377
378 void Item_Show (entity e, float mode)
379 {    
380         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
381         e.ItemStatus &~= ITS_STAYWEP;
382         if (mode > 0)
383         {
384                 // make the item look normal, and be touchable
385                 e.model = e.mdl;
386                 e.solid = SOLID_TRIGGER;
387                 e.spawnshieldtime = 1;
388                 e.ItemStatus |= ITS_AVAILABLE;
389         }
390         else if (mode < 0)
391         {
392                 // hide the item completely
393                 e.model = string_null;
394                 e.solid = SOLID_NOT;
395                 e.spawnshieldtime = 1;
396                 e.ItemStatus &~= ITS_AVAILABLE;
397         }
398         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
399         {
400                 // make the item translucent and not touchable
401                 e.model = e.mdl;
402                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
403                 e.effects |= EF_STARDUST;
404                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
405                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
406         }
407         else
408         {
409                 //setmodel(e, "null");
410                 e.solid = SOLID_NOT;
411                 e.colormod = '0 0 0';
412                 e.glowmod = e.colormod;
413                 e.spawnshieldtime = 1;
414                 e.ItemStatus &~= ITS_AVAILABLE;
415         }
416         
417         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
418             e.ItemStatus |= ITS_POWERUP;                
419         
420         if (autocvar_g_nodepthtestitems)
421                 e.effects |= EF_NODEPTHTEST;
422                 
423     
424     if (autocvar_g_fullbrightitems)
425                 e.ItemStatus |= ITS_ALLOWFB;
426         
427         if (autocvar_sv_simple_items)
428         e.ItemStatus |= ITS_ALLOWSI;
429
430         // relink entity (because solid may have changed)
431         setorigin(e, e.origin);
432     e.SendFlags |= ISF_STATUS;
433 }
434
435 void Item_Respawn (void)
436 {
437         Item_Show(self, 1);
438         // this is ugly...
439         if(self.items == IT_STRENGTH)
440                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
441         else if(self.items == IT_INVINCIBLE)
442                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
443         else
444                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
445         setorigin (self, self.origin);
446
447         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
448         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
449 }
450
451 void Item_RespawnCountdown (void)
452 {
453         if(self.count >= ITEM_RESPAWN_TICKS)
454         {
455                 if(self.waypointsprite_attached)
456                         WaypointSprite_Kill(self.waypointsprite_attached);
457                 Item_Respawn();
458         }
459         else
460         {
461                 self.nextthink = time + 1;
462                 self.count += 1;
463                 if(self.count == 1)
464                 {
465                         string name;
466                         vector rgb = '1 0 1';
467                         name = string_null;
468                         switch(self.items)
469                         {
470                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
471                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
472                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
473                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
474                         }
475                         item_name = name;
476                         item_color = rgb;
477                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
478                         name = item_name;
479                         rgb = item_color;
480                         if(self.flags & FL_WEAPON)
481                         {
482                                 entity wi = get_weaponinfo(self.weapon);
483                                 if(wi)
484                                 {
485                                         name = wi.model2;
486                                         rgb = '1 0 0';
487                                 }
488                         }
489                         if(name)
490                         {
491                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
492                                 if(self.waypointsprite_attached)
493                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
494                         }
495                         else
496                         {
497                                 print("Unknown powerup-marked item is wanting to respawn\n");
498                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
499                         }
500                 }
501                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
502                 if(self.waypointsprite_attached)
503                 {
504                         WaypointSprite_Ping(self.waypointsprite_attached);
505                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
506                 }
507         }
508 }
509
510 void Item_ScheduleRespawnIn(entity e, float t)
511 {
512         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
513         {
514                 e.think = Item_RespawnCountdown;
515                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
516                 e.count = 0;
517         }
518         else
519         {
520                 e.think = Item_Respawn;
521                 e.nextthink = time + t;
522         }
523 }
524
525 void Item_ScheduleRespawn(entity e)
526 {
527         if(e.respawntime > 0)
528         {
529                 Item_Show(e, 0);
530                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
531         }
532         else // if respawntime is -1, this item does not respawn
533                 Item_Show(e, -1);
534 }
535
536 void Item_ScheduleInitialRespawn(entity e)
537 {
538         Item_Show(e, 0);
539         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
540 }
541
542 float ITEM_MODE_NONE = 0;
543 float ITEM_MODE_HEALTH = 1;
544 float ITEM_MODE_ARMOR = 2;
545 float ITEM_MODE_FUEL = 3;
546 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
547 {
548         if (!item.ammofield)
549                 return FALSE;
550
551         if (item.spawnshieldtime)
552         {
553                 if ((player.ammofield < ammomax) || item.pickup_anyway)
554                 {
555                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
556                         goto YEAH;
557                 }
558         }
559         else if(g_weapon_stay == 2)
560         {
561                 float mi = min(item.ammofield, ammomax);
562                 if (player.ammofield < mi)
563                 {
564                         player.ammofield = mi;
565                         goto YEAH;
566                 }
567         }
568
569         return FALSE;
570
571 :YEAH
572         switch(mode)
573         {
574                 case ITEM_MODE_FUEL:
575                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
576                         break;
577                 case ITEM_MODE_HEALTH:
578                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
579                         break;
580                 case ITEM_MODE_ARMOR:
581                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
582                         break;
583                 default:
584                         break;
585         }
586         return TRUE;
587 }
588
589 float Item_GiveTo(entity item, entity player)
590 {
591         float _switchweapon;
592         float pickedup;
593         float it;
594         float i;
595
596         // if nothing happens to player, just return without taking the item
597         pickedup = FALSE;
598         _switchweapon = FALSE;
599         // in case the player has autoswitch enabled do the following:
600         // if the player is using their best weapon before items are given, they
601         // probably want to switch to an even better weapon after items are given
602         if (player.autoswitch)
603         if (player.switchweapon == w_getbestweapon(player))
604                 _switchweapon = TRUE;
605
606         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
607                 _switchweapon = TRUE;
608
609         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
610         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
611         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
612         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
613         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
614         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
615         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
616
617         if (item.flags & FL_WEAPON)
618         {
619                 WEPSET_DECLARE_A(it);
620                 WEPSET_COPY_AE(it, item);
621                 WEPSET_ANDNOT_AE(it, player);
622
623                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && item.pickup_anyway))
624                 {
625                         pickedup = TRUE;
626                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
627                         if(WEPSET_CONTAINS_AW(it, i))
628                                 W_GiveWeapon(player, i);
629                 }
630         }
631
632         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
633         {
634                 pickedup = TRUE;
635                 player.items |= it;
636                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
637         }
638
639         if (item.strength_finished)
640         {
641                 pickedup = TRUE;
642                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
643         }
644         if (item.invincible_finished)
645         {
646                 pickedup = TRUE;
647                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
648         }
649         if (item.superweapons_finished)
650         {
651                 pickedup = TRUE;
652                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
653         }
654
655 :skip
656         
657         // always eat teamed entities
658         if(item.team)
659                 pickedup = TRUE;
660
661         if (!pickedup)
662                 return 0;
663
664         if (_switchweapon)
665                 if (player.switchweapon != w_getbestweapon(player))
666                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
667
668         return 1;
669 }
670
671 void Item_Touch (void)
672 {
673         entity e, head;
674         
675         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
676         if(self.classname == "droppedweapon")
677         {
678                 if (ITEM_TOUCH_NEEDKILL())
679                 {
680                         remove(self);
681                         return;
682                 }
683         }
684
685         if not(IS_PLAYER(other))
686                 return;
687         if (other.deadflag)
688                 return;
689         if (self.solid != SOLID_TRIGGER)
690                 return;
691         if (self.owner == other)
692                 return;
693         if(MUTATOR_CALLHOOK(ItemTouch))
694                 return;
695
696         if (self.classname == "droppedweapon")
697         {
698                 self.strength_finished = max(0, self.strength_finished - time);
699                 self.invincible_finished = max(0, self.invincible_finished - time);
700                 self.superweapons_finished = max(0, self.superweapons_finished - time);
701         }
702
703         if(!Item_GiveTo(self, other))
704         {
705                 if (self.classname == "droppedweapon")
706                 {
707                         // undo what we did above
708                         self.strength_finished += time;
709                         self.invincible_finished += time;
710                         self.superweapons_finished += time;
711                 }
712                 return;
713         }
714
715         other.last_pickup = time;
716
717         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
718         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
719
720         if (self.classname == "droppedweapon")
721                 remove (self);
722         else if not(self.spawnshieldtime)
723                 return;
724         else
725         {
726                 if(self.team)
727                 {
728                         RandomSelection_Init();
729                         for(head = world; (head = findfloat(head, team, self.team)); )
730                         {
731                                 if(head.flags & FL_ITEM)
732                                 {
733                                         Item_Show(head, -1);
734                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
735                                 }
736                         }
737                         e = RandomSelection_chosen_ent;
738
739                 }
740                 else
741                         e = self;
742                 Item_ScheduleRespawn(e);
743         }
744 }
745
746 void Item_Reset()
747 {
748         Item_Show(self, !self.state);
749         setorigin (self, self.origin);
750
751         if(self.classname != "droppedweapon")
752         {
753                 self.think = func_null;
754                 self.nextthink = 0;
755
756                 if(self.waypointsprite_attached)
757                         WaypointSprite_Kill(self.waypointsprite_attached);
758
759                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
760                         Item_ScheduleInitialRespawn(self);
761         }
762 }
763
764 void Item_FindTeam()
765 {
766         entity head, e;
767
768         if(self.effects & EF_NODRAW)
769         {
770                 // marker for item team search
771                 dprint("Initializing item team ", ftos(self.team), "\n");
772                 RandomSelection_Init();
773                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
774                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
775                 e = RandomSelection_chosen_ent;
776                 e.state = 0;
777                 Item_Show(e, 1);
778
779                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
780                 {
781                         if(head != e)
782                         {
783                                 // make it a non-spawned item
784                                 Item_Show(head, -1);
785                                 head.state = 1; // state 1 = initially hidden item
786                         }
787                         head.effects &~= EF_NODRAW;
788                 }
789
790                 Item_Reset();
791         }
792 }
793
794 // Savage: used for item garbage-collection
795 // TODO: perhaps nice special effect?
796 void RemoveItem(void)
797 {
798         remove(self);
799 }
800
801 // pickup evaluation functions
802 // these functions decide how desirable an item is to the bots
803
804 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
805
806 float weapon_pickupevalfunc(entity player, entity item)
807 {
808         float c, j, position;
809
810         // See if I have it already
811         if(!WEPSET_CONTAINS_ALL_EE(player, item))
812         {
813                 // If I can pick it up
814                 if(!item.spawnshieldtime)
815                         c = 0;
816                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
817                 {
818                         // Skilled bots will grab more
819                         c = bound(0, skill / 10, 1) * 0.5;
820                 }
821                 else
822                         c = 0;
823         }
824         else
825                 c = 1;
826
827         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
828         if( bot_custom_weapon && c )
829         {
830                 // Find the highest position on any range
831                 position = -1;
832                 for(j = 0; j < WEP_LAST ; ++j){
833                         if(
834                                         bot_weapons_far[j] == item.weapon ||
835                                         bot_weapons_mid[j] == item.weapon ||
836                                         bot_weapons_close[j] == item.weapon
837                           )
838                         {
839                                 position = j;
840                                 break;
841                         }
842                 }
843
844                 // Rate it
845                 if (position >= 0 )
846                 {
847                         position = WEP_LAST - position;
848                         // item.bot_pickupbasevalue is overwritten here
849                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
850                 }
851         }
852
853         return item.bot_pickupbasevalue * c;
854 }
855
856 float commodity_pickupevalfunc(entity player, entity item)
857 {
858         float c, i;
859         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
860         entity wi;
861         c = 0;
862
863         // Detect needed ammo
864         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
865         {
866                 wi = get_weaponinfo(i);
867
868                 if not(WEPSET_CONTAINS_EW(player, i))
869                         continue;
870
871                 if(wi.items & IT_SHELLS)
872                         need_shells = TRUE;
873                 else if(wi.items & IT_NAILS)
874                         need_nails = TRUE;
875                 else if(wi.items & IT_ROCKETS)
876                         need_rockets = TRUE;
877                 else if(wi.items & IT_CELLS)
878                         need_cells = TRUE;
879                 else if(wi.items & IT_FUEL)
880                         need_cells = TRUE;
881         }
882
883         // TODO: figure out if the player even has the weapon this ammo is for?
884         // may not affect strategy much though...
885         // find out how much more ammo/armor/health the player can hold
886         if (need_shells)
887         if (item.ammo_shells)
888         if (player.ammo_shells < g_pickup_shells_max)
889                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
890         if (need_nails)
891         if (item.ammo_nails)
892         if (player.ammo_nails < g_pickup_nails_max)
893                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
894         if (need_rockets)
895         if (item.ammo_rockets)
896         if (player.ammo_rockets < g_pickup_rockets_max)
897                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
898         if (need_cells)
899         if (item.ammo_cells)
900         if (player.ammo_cells < g_pickup_cells_max)
901                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
902         if (need_fuel)
903         if (item.ammo_fuel)
904         if (player.ammo_fuel < g_pickup_fuel_max)
905                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
906         if (item.armorvalue)
907         if (player.armorvalue < item.max_armorvalue)
908                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
909         if (item.health)
910         if (player.health < item.max_health)
911                 c = c + max(0, 1 - player.health / item.max_health);
912
913         return item.bot_pickupbasevalue * c;
914 }
915
916 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
917 {
918         if(ITEM_DAMAGE_NEEDKILL(deathtype))
919                 RemoveItem();
920 }
921
922 .float is_item;
923 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
924 {
925         startitem_failed = FALSE;
926
927         if(self.model == "")
928                 self.model = itemmodel;
929         
930         if(self.model == "")
931     {
932         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
933         return;
934     }
935         
936         if(self.item_pickupsound == "")
937                 self.item_pickupsound = pickupsound;
938         
939         if(!self.respawntime) // both need to be set
940         {
941                 self.respawntime = defaultrespawntime;
942                 self.respawntimejitter = defaultrespawntimejitter;
943         }
944
945         self.items = itemid;
946         self.weapon = weaponid;
947
948         if(weaponid)
949                 WEPSET_COPY_EW(self, weaponid);
950         
951         self.flags = FL_ITEM | itemflags;
952
953         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
954         {
955                 startitem_failed = TRUE;
956                 remove(self);
957                 return;
958         }
959
960         // is it a dropped weapon?
961         if (self.classname == "droppedweapon")
962         {
963                 self.reset = SUB_Remove;
964                 // it's a dropped weapon
965                 self.movetype = MOVETYPE_TOSS;
966
967                 // Savage: remove thrown items after a certain period of time ("garbage collection")
968                 self.think = RemoveItem;
969                 self.nextthink = time + 20;
970
971                 self.takedamage = DAMAGE_YES;
972                 self.event_damage = Item_Damage;
973
974                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
975                 /*
976                 if(self.items == 0)
977                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
978                 if(self.ammo_nails == 0)
979                 if(self.ammo_cells == 0)
980                 if(self.ammo_rockets == 0)
981                 if(self.ammo_shells == 0)
982                 if(self.ammo_fuel == 0)
983                 if(self.health == 0)
984                 if(self.armorvalue == 0)
985                 */
986                 {
987                         // if item is worthless after a timer, have it expire then
988                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
989                 }
990
991                 // don't drop if in a NODROP zone (such as lava)
992                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
993                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
994                 {
995                         startitem_failed = TRUE;
996                         remove(self);
997                         return;
998                 }
999         }
1000         else
1001         {
1002                 if(!have_pickup_item())
1003                 {
1004                         startitem_failed = TRUE;
1005                         remove (self);
1006                         return;
1007                 }
1008                 
1009                 if(self.angles != '0 0 0')
1010             self.SendFlags |= ISF_ANGLES;
1011
1012                 self.reset = Item_Reset;
1013                 // it's a level item
1014                 if(self.spawnflags & 1)
1015                         self.noalign = 1;
1016                 if (self.noalign)
1017                         self.movetype = MOVETYPE_NONE;
1018                 else
1019                         self.movetype = MOVETYPE_TOSS;
1020                 // do item filtering according to game mode and other things
1021                 if (!self.noalign)
1022                 {
1023                         // first nudge it off the floor a little bit to avoid math errors
1024                         setorigin(self, self.origin + '0 0 1');
1025                         // set item size before we spawn a spawnfunc_waypoint
1026                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1027                                 setsize (self, '-16 -16 0', '16 16 48');
1028                         else
1029                                 setsize (self, '-16 -16 0', '16 16 32');
1030                         // note droptofloor returns FALSE if stuck/or would fall too far
1031                         droptofloor();
1032                         waypoint_spawnforitem(self);
1033                 }
1034
1035                 /*
1036                  * can't do it that way, as it would break maps
1037                  * TODO make a target_give like entity another way, that perhaps has
1038                  * the weapon name in a key
1039                 if(self.targetname)
1040                 {
1041                         // target_give not yet supported; maybe later
1042                         print("removed targeted ", self.classname, "\n");
1043                         startitem_failed = TRUE;
1044                         remove (self);
1045                         return;
1046                 }
1047                 */
1048
1049                 if(autocvar_spawn_debug >= 2)
1050                 {
1051                         entity otheritem;
1052                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1053                         {
1054                             // why not flags & fl_item?
1055                                 if(otheritem.is_item)
1056                                 {
1057                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1058                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1059                                         error("Mapper sucks.");
1060                                 }
1061                         }
1062                         self.is_item = TRUE;
1063                 }
1064
1065                 WEPSET_OR_AW(weaponsInMap, weaponid);
1066
1067                 precache_model (self.model);
1068                 precache_sound (self.item_pickupsound);
1069
1070                 precache_sound ("misc/itemrespawncountdown.wav");
1071                 if(itemid == IT_STRENGTH)
1072                         precache_sound ("misc/strength_respawn.wav");
1073                 else if(itemid == IT_INVINCIBLE)
1074                         precache_sound ("misc/shield_respawn.wav");
1075                 else
1076                         precache_sound ("misc/itemrespawn.wav");
1077
1078                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1079                         self.target = "###item###"; // for finding the nearest item using find()
1080         }
1081
1082         self.bot_pickup = TRUE;
1083         self.bot_pickupevalfunc = pickupevalfunc;
1084         self.bot_pickupbasevalue = pickupbasevalue;
1085         self.mdl = self.model;
1086         self.netname = itemname;
1087         self.touch = Item_Touch;
1088         setmodel(self, "null"); // precision set below
1089         //self.effects |= EF_LOWPRECISION; 
1090         
1091         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1092     {
1093         self.pos1 = '-16 -16 0';
1094         self.pos2 = '16 16 48';
1095     }
1096         else
1097     {
1098         self.pos1 = '-16 -16 0';
1099         self.pos2 = '16 16 32';
1100     }
1101     setsize (self, self.pos1, self.pos2);
1102     
1103     if(itemflags & FL_POWERUP) 
1104         self.ItemStatus |= ITS_ANIMATE1;
1105         
1106         if(self.armorvalue || self.health)
1107         self.ItemStatus |= ITS_ANIMATE2;
1108         
1109         if(itemflags & FL_WEAPON)
1110         {
1111                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1112             self.colormap = 1024; // color shirt=0 pants=0 grey
1113         else
1114             self.gravity = 1;
1115             
1116                 self.ItemStatus |= ITS_ANIMATE1;
1117                 self.ItemStatus |= ISF_COLORMAP;
1118         }
1119
1120         self.state = 0;
1121         if(self.team) // broken, no idea why.
1122         {
1123                 if(!self.cnt)
1124                         self.cnt = 1; // item probability weight
1125                         
1126                 self.effects |= EF_NODRAW; // marker for item team search
1127                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1128         }
1129         else
1130                 Item_Reset();
1131         
1132     Net_LinkEntity(self, FALSE, 0, ItemSend);
1133
1134         // call this hook after everything else has been done
1135         if(MUTATOR_CALLHOOK(Item_Spawn))
1136         {
1137                 startitem_failed = TRUE;
1138                 remove(self);
1139                 return;
1140         }
1141 }
1142
1143 float weaponswapping;
1144 float internalteam;
1145
1146 void weapon_defaultspawnfunc(float wpn)
1147 {
1148         entity e;
1149         float t;
1150         var .float ammofield;
1151         string s;
1152         entity oldself;
1153         float i, j;
1154         float f;
1155
1156         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1157         {
1158                 e = get_weaponinfo(wpn);
1159
1160                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1161                 {
1162                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1163                         /*
1164                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1165                         startitem_failed = TRUE;
1166                         return;
1167                         */
1168                 }
1169
1170                 s = W_Apply_Weaponreplace(e.netname);
1171                 ret_string = s;
1172                 other = e;
1173                 MUTATOR_CALLHOOK(SetWeaponreplace);
1174                 s = ret_string;
1175                 if(s == "")
1176                 {
1177                         remove(self);
1178                         startitem_failed = TRUE;
1179                         return;
1180                 }
1181                 t = tokenize_console(s);
1182                 if(t >= 2)
1183                 {
1184                         self.team = --internalteam;
1185                         oldself = self;
1186                         for(i = 1; i < t; ++i)
1187                         {
1188                                 s = argv(i);
1189                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1190                                 {
1191                                         e = get_weaponinfo(j);
1192                                         if(e.netname == s)
1193                                         {
1194                                                 self = spawn();
1195                                                 copyentity(oldself, self);
1196                                                 self.classname = "replacedweapon";
1197                                                 weapon_defaultspawnfunc(j);
1198                                                 break;
1199                                         }
1200                                 }
1201                                 if(j > WEP_LAST)
1202                                 {
1203                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1204                                 }
1205                         }
1206                         self = oldself;
1207                 }
1208                 if(t >= 1) // always the case!
1209                 {
1210                         s = argv(0);
1211                         wpn = 0;
1212                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1213                         {
1214                                 e = get_weaponinfo(j);
1215                                 if(e.netname == s)
1216                                 {
1217                                         wpn = j;
1218                                         break;
1219                                 }
1220                         }
1221                         if(j > WEP_LAST)
1222                         {
1223                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1224                         }
1225                 }
1226                 if(wpn == 0)
1227                 {
1228                         remove(self);
1229                         startitem_failed = TRUE;
1230                         return;
1231                 }
1232         }
1233
1234         e = get_weaponinfo(wpn);
1235
1236         if(!self.respawntime)
1237         {
1238                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1239                 {
1240                         self.respawntime = g_pickup_respawntime_superweapon;
1241                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1242                 }
1243                 else
1244                 {
1245                         self.respawntime = g_pickup_respawntime_weapon;
1246                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1247                 }
1248         }
1249
1250         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1251                 if(!self.superweapons_finished)
1252                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1253
1254         if(e.items)
1255         {
1256                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1257                 {
1258                         if(e.items & j)
1259                         {
1260                                 ammofield = Item_CounterField(j);
1261                                 if(!self.ammofield)
1262                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1263                         }
1264                 }
1265         }
1266
1267         // pickup anyway
1268         if(g_pickup_weapons_anyway)
1269                 self.pickup_anyway = TRUE;
1270
1271         f = FL_WEAPON;
1272
1273         // no weapon-stay on superweapons
1274         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1275                 f |= FL_NO_WEAPON_STAY;
1276
1277         // weapon stay isn't supported for teamed weapons
1278         if(self.team)
1279                 f |= FL_NO_WEAPON_STAY;
1280
1281         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1282         if (self.modelindex) // don't precache if self was removed
1283                 weapon_action(e.weapon, WR_PRECACHE);
1284 }
1285
1286 void spawnfunc_weapon_shotgun (void);
1287 void spawnfunc_weapon_uzi (void) {
1288         if(autocvar_sv_q3acompat_machineshotgunswap)
1289         if(self.classname != "droppedweapon")
1290         {
1291                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1292                 return;
1293         }
1294         weapon_defaultspawnfunc(WEP_UZI);
1295 }
1296
1297 void spawnfunc_weapon_shotgun (void) {
1298         if(autocvar_sv_q3acompat_machineshotgunswap)
1299         if(self.classname != "droppedweapon")
1300         {
1301                 weapon_defaultspawnfunc(WEP_UZI);
1302                 return;
1303         }
1304         weapon_defaultspawnfunc(WEP_SHOTGUN);
1305 }
1306
1307 void spawnfunc_weapon_nex (void)
1308 {
1309         weapon_defaultspawnfunc(WEP_NEX);
1310 }
1311
1312 void spawnfunc_weapon_minstanex (void)
1313 {
1314         weapon_defaultspawnfunc(WEP_MINSTANEX);
1315 }
1316
1317 void spawnfunc_weapon_rocketlauncher (void)
1318 {
1319         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1320 }
1321
1322 void spawnfunc_item_rockets (void) {
1323         if(!self.ammo_rockets)
1324                 self.ammo_rockets = g_pickup_rockets;
1325         if(!self.pickup_anyway)
1326                 self.pickup_anyway = g_pickup_ammo_anyway;
1327         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1328 }
1329
1330 void spawnfunc_item_shells (void);
1331 void spawnfunc_item_bullets (void) {
1332         if(!weaponswapping)
1333         if(autocvar_sv_q3acompat_machineshotgunswap)
1334         if(self.classname != "droppedweapon")
1335         {
1336                 weaponswapping = TRUE;
1337                 spawnfunc_item_shells();
1338                 weaponswapping = FALSE;
1339                 return;
1340         }
1341
1342         if(!self.ammo_nails)
1343                 self.ammo_nails = g_pickup_nails;
1344         if(!self.pickup_anyway)
1345                 self.pickup_anyway = g_pickup_ammo_anyway;
1346         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1347 }
1348
1349 void spawnfunc_item_cells (void) {
1350         if(!self.ammo_cells)
1351                 self.ammo_cells = g_pickup_cells;
1352         if(!self.pickup_anyway)
1353                 self.pickup_anyway = g_pickup_ammo_anyway;
1354         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1355 }
1356
1357 void spawnfunc_item_shells (void) {
1358         if(!weaponswapping)
1359         if(autocvar_sv_q3acompat_machineshotgunswap)
1360         if(self.classname != "droppedweapon")
1361         {
1362                 weaponswapping = TRUE;
1363                 spawnfunc_item_bullets();
1364                 weaponswapping = FALSE;
1365                 return;
1366         }
1367
1368         if(!self.ammo_shells)
1369                 self.ammo_shells = g_pickup_shells;
1370         if(!self.pickup_anyway)
1371                 self.pickup_anyway = g_pickup_ammo_anyway;
1372         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1373 }
1374
1375 void spawnfunc_item_armor_small (void) {
1376         if(!self.armorvalue)
1377                 self.armorvalue = g_pickup_armorsmall;
1378         if(!self.max_armorvalue)
1379                 self.max_armorvalue = g_pickup_armorsmall_max;
1380         if(!self.pickup_anyway)
1381                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1382         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1383 }
1384
1385 void spawnfunc_item_armor_medium (void) {
1386         if(!self.armorvalue)
1387                 self.armorvalue = g_pickup_armormedium;
1388         if(!self.max_armorvalue)
1389                 self.max_armorvalue = g_pickup_armormedium_max;
1390         if(!self.pickup_anyway)
1391                 self.pickup_anyway = g_pickup_armormedium_anyway;
1392         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1393 }
1394
1395 void spawnfunc_item_armor_big (void) {
1396         if(!self.armorvalue)
1397                 self.armorvalue = g_pickup_armorbig;
1398         if(!self.max_armorvalue)
1399                 self.max_armorvalue = g_pickup_armorbig_max;
1400         if(!self.pickup_anyway)
1401                 self.pickup_anyway = g_pickup_armorbig_anyway;
1402         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1403 }
1404
1405 void spawnfunc_item_armor_large (void) {
1406         if(!self.armorvalue)
1407                 self.armorvalue = g_pickup_armorlarge;
1408         if(!self.max_armorvalue)
1409                 self.max_armorvalue = g_pickup_armorlarge_max;
1410         if(!self.pickup_anyway)
1411                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1412         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1413 }
1414
1415 void spawnfunc_item_health_small (void) {
1416         if(!self.max_health)
1417                 self.max_health = g_pickup_healthsmall_max;
1418         if(!self.health)
1419                 self.health = g_pickup_healthsmall;
1420         if(!self.pickup_anyway)
1421                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1422         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1423 }
1424
1425 void spawnfunc_item_health_medium (void) {
1426         if(!self.max_health)
1427                 self.max_health = g_pickup_healthmedium_max;
1428         if(!self.health)
1429                 self.health = g_pickup_healthmedium;
1430         if(!self.pickup_anyway)
1431                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1432         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1433 }
1434
1435 void spawnfunc_item_health_large (void) {
1436         if(!self.max_health)
1437                 self.max_health = g_pickup_healthlarge_max;
1438         if(!self.health)
1439                 self.health = g_pickup_healthlarge;
1440         if(!self.pickup_anyway)
1441                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1442         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1443 }
1444
1445 void spawnfunc_item_health_mega (void) {
1446                 if(!self.max_health)
1447                         self.max_health = g_pickup_healthmega_max;
1448                 if(!self.health)
1449                         self.health = g_pickup_healthmega;
1450                 if(!self.pickup_anyway)
1451                         self.pickup_anyway = g_pickup_healthmega_anyway;
1452                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1453 }
1454
1455 // support old misnamed entities
1456 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1457 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1458 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1459 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1460 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1461
1462 void spawnfunc_item_strength (void) {
1463                 precache_sound("weapons/strength_fire.wav");
1464                 if(!self.strength_finished)
1465                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1466                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1467 }
1468
1469 void spawnfunc_item_invincible (void) {
1470                 if(!self.invincible_finished)
1471                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1472                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1473 }
1474
1475 // compatibility:
1476 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1477
1478 float GiveItems(entity e, float beginarg, float endarg);
1479 void target_items_use (void)
1480 {
1481         if(activator.classname == "droppedweapon")
1482         {
1483                 EXACTTRIGGER_TOUCH;
1484                 remove(activator);
1485                 return;
1486         }
1487
1488         if not(IS_PLAYER(activator))
1489                 return;
1490         if(activator.deadflag != DEAD_NO)
1491                 return;
1492         EXACTTRIGGER_TOUCH;
1493
1494         entity e;
1495         for(e = world; (e = find(e, classname, "droppedweapon")); )
1496                 if(e.enemy == activator)
1497                         remove(e);
1498
1499         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1500                 centerprint(activator, self.message);
1501 }
1502
1503 void spawnfunc_target_items (void)
1504 {
1505         float n, i, j;
1506         entity e;
1507
1508         self.use = target_items_use;
1509         if(!self.strength_finished)
1510                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1511         if(!self.invincible_finished)
1512                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1513         if(!self.superweapons_finished)
1514                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1515
1516         precache_sound("misc/itempickup.wav");
1517         precache_sound("misc/megahealth.wav");
1518         precache_sound("misc/armor25.wav");
1519         precache_sound("misc/powerup.wav");
1520         precache_sound("misc/poweroff.wav");
1521         precache_sound("weapons/weaponpickup.wav");
1522
1523         n = tokenize_console(self.netname);
1524         if(argv(0) == "give")
1525         {
1526                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1527         }
1528         else
1529         {
1530                 for(i = 0; i < n; ++i)
1531                 {
1532                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1533                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1534                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1535                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1536                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1537                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1538                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1539                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1540                         else
1541                         {
1542                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1543                                 {
1544                                         e = get_weaponinfo(j);
1545                                         if(argv(i) == e.netname)
1546                                         {
1547                                                 WEPSET_OR_EW(self, j);
1548                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1549                                                         weapon_action(e.weapon, WR_PRECACHE);
1550                                                 break;
1551                                         }
1552                                 }
1553                                 if(j > WEP_LAST)
1554                                         print("target_items: invalid item ", argv(i), "\n");
1555                         }
1556                 }
1557
1558                 string itemprefix, valueprefix;
1559                 if(self.spawnflags == 0)
1560                 {
1561                         itemprefix = "";
1562                         valueprefix = "";
1563                 }
1564                 else if(self.spawnflags == 1)
1565                 {
1566                         itemprefix = "max ";
1567                         valueprefix = "max ";
1568                 }
1569                 else if(self.spawnflags == 2)
1570                 {
1571                         itemprefix = "min ";
1572                         valueprefix = "min ";
1573                 }
1574                 else if(self.spawnflags == 4)
1575                 {
1576                         itemprefix = "minus ";
1577                         valueprefix = "max ";
1578                 }
1579                 else
1580                 {
1581                         error("invalid spawnflags");
1582 #ifdef GMQCC
1583                         itemprefix = string_null;
1584                         valueprefix = string_null;
1585 #endif
1586                 }
1587
1588                 self.netname = "";
1589                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1590                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1591                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1592                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1593                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1594                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1595                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1596                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1597                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1598                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1599                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1600                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1601                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1602                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1603                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1604                 {
1605                         e = get_weaponinfo(j);
1606                         if(e.weapon)
1607                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1608                 }
1609         }
1610         self.netname = strzone(self.netname);
1611         //print(self.netname, "\n");
1612
1613         n = tokenize_console(self.netname);
1614         for(i = 0; i < n; ++i)
1615         {
1616                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1617                 {
1618                         e = get_weaponinfo(j);
1619                         if(argv(i) == e.netname)
1620                         {
1621                                 weapon_action(e.weapon, WR_PRECACHE);
1622                                 break;
1623                         }
1624                 }
1625         }
1626 }
1627
1628 void spawnfunc_item_fuel(void)
1629 {
1630         if(!self.ammo_fuel)
1631                 self.ammo_fuel = g_pickup_fuel;
1632         if(!self.pickup_anyway)
1633                 self.pickup_anyway = g_pickup_ammo_anyway;
1634         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1635 }
1636
1637 void spawnfunc_item_fuel_regen(void)
1638 {
1639         if(start_items & IT_FUEL_REGEN)
1640         {
1641                 spawnfunc_item_fuel();
1642                 return;
1643         }
1644         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1645 }
1646
1647 void spawnfunc_item_jetpack(void)
1648 {
1649         if(g_grappling_hook)
1650                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1651         if(!self.ammo_fuel)
1652                 self.ammo_fuel = g_pickup_fuel_jetpack;
1653         if(start_items & IT_JETPACK)
1654         {
1655                 spawnfunc_item_fuel();
1656                 return;
1657         }
1658         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1659 }
1660
1661
1662 #define OP_SET 0
1663 #define OP_MIN 1
1664 #define OP_MAX 2
1665 #define OP_PLUS 3
1666 #define OP_MINUS 4
1667
1668 float GiveWeapon(entity e, float wpn, float op, float val)
1669 {
1670         float v0, v1;
1671         v0 = WEPSET_CONTAINS_EW(e, wpn);
1672         switch(op)
1673         {
1674                 case OP_SET:
1675                         if(val > 0)
1676                                 WEPSET_OR_EW(e, wpn);
1677                         else
1678                                 WEPSET_ANDNOT_EW(e, wpn);
1679                         break;
1680                 case OP_MIN:
1681                 case OP_PLUS:
1682                         if(val > 0)
1683                                 WEPSET_OR_EW(e, wpn);
1684                         break;
1685                 case OP_MAX:
1686                         if(val <= 0)
1687                                 WEPSET_ANDNOT_EW(e, wpn);
1688                         break;
1689                 case OP_MINUS:
1690                         if(val > 0)
1691                                 WEPSET_ANDNOT_EW(e, wpn);
1692                         break;
1693         }
1694         v1 = WEPSET_CONTAINS_EW(e, wpn);
1695         return (v0 != v1);
1696 }
1697
1698 float GiveBit(entity e, .float fld, float bit, float op, float val)
1699 {
1700         float v0, v1;
1701         v0 = (e.fld & bit);
1702         switch(op)
1703         {
1704                 case OP_SET:
1705                         if(val > 0)
1706                                 e.fld |= bit;
1707                         else
1708                                 e.fld &~= bit;
1709                         break;
1710                 case OP_MIN:
1711                 case OP_PLUS:
1712                         if(val > 0)
1713                                 e.fld |= bit;
1714                         break;
1715                 case OP_MAX:
1716                         if(val <= 0)
1717                                 e.fld &~= bit;
1718                         break;
1719                 case OP_MINUS:
1720                         if(val > 0)
1721                                 e.fld &~= bit;
1722                         break;
1723         }
1724         v1 = (e.fld & bit);
1725         return (v0 != v1);
1726 }
1727
1728 float GiveValue(entity e, .float fld, float op, float val)
1729 {
1730         float v0, v1;
1731         v0 = e.fld;
1732         switch(op)
1733         {
1734                 case OP_SET:
1735                         e.fld = val;
1736                         break;
1737                 case OP_MIN:
1738                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1739                         break;
1740                 case OP_MAX:
1741                         e.fld = min(e.fld, val);
1742                         break;
1743                 case OP_PLUS:
1744                         e.fld += val;
1745                         break;
1746                 case OP_MINUS:
1747                         e.fld -= val;
1748                         break;
1749         }
1750         v1 = e.fld;
1751         return (v0 != v1);
1752 }
1753
1754 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1755 {
1756         if(v1 == v0)
1757                 return;
1758         if(v1 <= v0 - t)
1759         {
1760                 if(snd_decr != "")
1761                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1762         }
1763         else if(v0 >= v0 + t)
1764         {
1765                 if(snd_incr != "")
1766                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1767         }
1768 }
1769
1770 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1771 {
1772         if(v0 < v1)
1773                 e.rotfield = max(e.rotfield, time + rottime);
1774         else if(v0 > v1)
1775                 e.regenfield = max(e.regenfield, time + regentime);
1776 }
1777
1778 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1779 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1780 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1781 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1782 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1783 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1784
1785 float GiveItems(entity e, float beginarg, float endarg)
1786 {
1787         float got, i, j, val, op;
1788         float _switchweapon;
1789         entity wi;
1790         string cmd;
1791
1792         val = 999;
1793         op = OP_SET;
1794
1795         got = 0;
1796
1797         _switchweapon = FALSE;
1798         if (e.autoswitch)
1799                 if (e.switchweapon == w_getbestweapon(e))
1800                         _switchweapon = TRUE;
1801
1802         e.strength_finished = max(0, e.strength_finished - time);
1803         e.invincible_finished = max(0, e.invincible_finished - time);
1804         e.superweapons_finished = max(0, e.superweapons_finished - time);
1805         
1806         PREGIVE(e, items);
1807         PREGIVE_WEAPONS(e);
1808         PREGIVE(e, strength_finished);
1809         PREGIVE(e, invincible_finished);
1810         PREGIVE(e, superweapons_finished);
1811         PREGIVE(e, ammo_nails);
1812         PREGIVE(e, ammo_cells);
1813         PREGIVE(e, ammo_shells);
1814         PREGIVE(e, ammo_rockets);
1815         PREGIVE(e, ammo_fuel);
1816         PREGIVE(e, armorvalue);
1817         PREGIVE(e, health);
1818
1819         for(i = beginarg; i < endarg; ++i)
1820         {
1821                 cmd = argv(i);
1822
1823                 if(cmd == "0" || stof(cmd))
1824                 {
1825                         val = stof(cmd);
1826                         continue;
1827                 }
1828                 switch(cmd)
1829                 {
1830                         case "no":
1831                                 op = OP_MAX;
1832                                 val = 0;
1833                                 continue;
1834                         case "max":
1835                                 op = OP_MAX;
1836                                 continue;
1837                         case "min":
1838                                 op = OP_MIN;
1839                                 continue;
1840                         case "plus":
1841                                 op = OP_PLUS;
1842                                 continue;
1843                         case "minus":
1844                                 op = OP_MINUS;
1845                                 continue;
1846                         case "ALL":
1847                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1848                                 got += GiveValue(e, strength_finished, op, val);
1849                                 got += GiveValue(e, invincible_finished, op, val);
1850                                 got += GiveValue(e, superweapons_finished, op, val);
1851                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1852                         case "all":
1853                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1854                                 got += GiveValue(e, health, op, val);
1855                                 got += GiveValue(e, armorvalue, op, val);
1856                         case "allweapons":
1857                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1858                                 {
1859                                         wi = get_weaponinfo(j);
1860                                         if(wi.weapon)
1861                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1862                                                         got += GiveWeapon(e, j, op, val);
1863                                 }
1864                         case "allammo":
1865                                 got += GiveValue(e, ammo_cells, op, val);
1866                                 got += GiveValue(e, ammo_shells, op, val);
1867                                 got += GiveValue(e, ammo_nails, op, val);
1868                                 got += GiveValue(e, ammo_rockets, op, val);
1869                                 got += GiveValue(e, ammo_fuel, op, val);
1870                                 break;
1871                         case "unlimited_ammo":
1872                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1873                                 break;
1874                         case "unlimited_weapon_ammo":
1875                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1876                                 break;
1877                         case "unlimited_superweapons":
1878                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1879                                 break;
1880                         case "jetpack":
1881                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1882                                 break;
1883                         case "fuel_regen":
1884                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1885                                 break;
1886                         case "strength":
1887                                 got += GiveValue(e, strength_finished, op, val);
1888                                 break;
1889                         case "invincible":
1890                                 got += GiveValue(e, invincible_finished, op, val);
1891                                 break;
1892                         case "superweapons":
1893                                 got += GiveValue(e, superweapons_finished, op, val);
1894                                 break;
1895                         case "cells":
1896                                 got += GiveValue(e, ammo_cells, op, val);
1897                                 break;
1898                         case "shells":
1899                                 got += GiveValue(e, ammo_shells, op, val);
1900                                 break;
1901                         case "nails":
1902                         case "bullets":
1903                                 got += GiveValue(e, ammo_nails, op, val);
1904                                 break;
1905                         case "rockets":
1906                                 got += GiveValue(e, ammo_rockets, op, val);
1907                                 break;
1908                         case "health":
1909                                 got += GiveValue(e, health, op, val);
1910                                 break;
1911                         case "armor":
1912                                 got += GiveValue(e, armorvalue, op, val);
1913                                 break;
1914                         case "fuel":
1915                                 got += GiveValue(e, ammo_fuel, op, val);
1916                                 break;
1917                         default:
1918                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1919                                 {
1920                                         wi = get_weaponinfo(j);
1921                                         if(cmd == wi.netname)
1922                                         {
1923                                                 got += GiveWeapon(e, j, op, val);
1924                                                 break;
1925                                         }
1926                                 }
1927                                 if(j > WEP_LAST)
1928                                         print("give: invalid item ", cmd, "\n");
1929                                 break;
1930                 }
1931                 val = 999;
1932                 op = OP_SET;
1933         }
1934
1935         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1936         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1937         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1938         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1939         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1940         {
1941                 wi = get_weaponinfo(j);
1942                 if(wi.weapon)
1943                 {
1944                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1945                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1946                                 if(WEPSET_CONTAINS_EW(e, j))
1947                                         weapon_action(wi.weapon, WR_PRECACHE);
1948                 }
1949         }
1950         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1951         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1952         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1953         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1954         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1955         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1956         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1957         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1958         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1959
1960         if(e.superweapons_finished <= 0)
1961                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1962                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1963
1964         if(e.strength_finished <= 0)
1965                 e.strength_finished = 0;
1966         else
1967                 e.strength_finished += time;
1968         if(e.invincible_finished <= 0)
1969                 e.invincible_finished = 0;
1970         else
1971                 e.invincible_finished += time;
1972         if(e.superweapons_finished <= 0)
1973                 e.superweapons_finished = 0;
1974         else
1975                 e.superweapons_finished += time;
1976
1977         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1978                 _switchweapon = TRUE;
1979         if(_switchweapon)
1980                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1981
1982         return got;
1983 }
1984 #endif