qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 float it_armor_large_time;
 183 float it_health_mega_time;
 184 float it_invisible_time;
 185 float it_speed_time;
 186 float it_extralife_time;
 187 float it_strength_time;
 188 float it_shield_time;
 189 float it_fuelregen_time;
 190 float it_jetpack_time;
 191
 192 void Item_ItemsTime_Init()
 193 {
 194         it_armor_large_time = -1;
 195         it_health_mega_time = -1;
 196         it_invisible_time = -1;
 197         it_speed_time = -1;
 198         it_extralife_time = -1;
 199         it_strength_time = -1;
 200         it_shield_time = -1;
 201         it_fuelregen_time = -1;
 202         it_jetpack_time = -1;
 203 }
 204 void Item_ItemsTime_Clear()
 205 {
 206         self.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 207         self.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 208         self.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 209         self.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 210         self.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 211         self.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 212         self.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 213         self.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 214         self.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 215 }
 216 void Item_ItemsTime_Get(entity e)
 217 {
 218         e.item_armor_large_time = it_armor_large_time;
 219         e.item_health_mega_time = it_health_mega_time;
 220         e.item_invisible_time = it_invisible_time;
 221         e.item_speed_time = it_speed_time;
 222         e.item_extralife_time = it_extralife_time;
 223         e.item_strength_time = it_strength_time;
 224         e.item_shield_time = it_shield_time;
 225         e.item_fuelregen_time = it_fuelregen_time;
 226         e.item_jetpack_time = it_jetpack_time;
 227 }
 228 float Item_ItemsTime_UpdateTime_Check(float item_time, float t)
 229 {
 230         if(t == 0 && item_time == -1)
 231                 return TRUE;
 232         if(time < t && (item_time <= time || t < item_time))
 233                 return TRUE;
 234         return FALSE;
 235 }
 236 void Item_ItemsTime_UpdateTime(entity e, float t)
 237 {
 238         if(g_minstagib)
 239         {
 240                 switch(e.items)
 241                 {
 242                         case IT_STRENGTH://"item-invis"
 243                                 if(Item_ItemsTime_UpdateTime_Check(it_invisible_time, t))
 244                                         it_invisible_time = t;
 245                                 break;
 246                         case IT_NAILS://"item-extralife"
 247                                 if(Item_ItemsTime_UpdateTime_Check(it_extralife_time, t))
 248                                         it_extralife_time = t;
 249                                 break;
 250                         case IT_INVINCIBLE://"item-speed"
 251                                 if(Item_ItemsTime_UpdateTime_Check(it_speed_time, t))
 252                                         it_speed_time = t;
 253                                 break;
 254                 }
 255         }
 256         else
 257         {
 258                 switch(e.items)
 259                 {
 260                         case IT_HEALTH:
 261                                 //if (e.classname == "item_health_mega")
 262                                         if(Item_ItemsTime_UpdateTime_Check(it_health_mega_time, t))
 263                                                 it_health_mega_time = t;
 264                                 break;
 265                         case IT_ARMOR:
 266                                 if (e.classname == "item_armor_large")
 267                                         if(Item_ItemsTime_UpdateTime_Check(it_armor_large_time, t))
 268                                                 it_armor_large_time = t;
 269                                 break;
 270                         case IT_STRENGTH://"item-strength"
 271                                 if(Item_ItemsTime_UpdateTime_Check(it_strength_time, t))
 272                                         it_strength_time = t;
 273                                 break;
 274                         case IT_INVINCIBLE://"item-shield"
 275                                 if(Item_ItemsTime_UpdateTime_Check(it_shield_time, t))
 276                                         it_shield_time = t;
 277                                 break;
 278                 }
 279         }
 280         switch(e.items)
 281         {
 282                 case IT_FUEL_REGEN://"item-fuelregen"
 283                         if(Item_ItemsTime_UpdateTime_Check(it_fuelregen_time, t))
 284                                 it_fuelregen_time = t;
 285                         break;
 286                 case IT_JETPACK://"item-jetpack"
 287                         if(Item_ItemsTime_UpdateTime_Check(it_jetpack_time, t))
 288                                 it_jetpack_time = t;
 289                         break;
 290         }
 291 }
 292
 293 void Item_Respawn (void)
 294 {
 295         float t;
 296         entity head;
 297         Item_Show(self, 1);
 298         if(!g_minstagib && self.items == IT_STRENGTH)
 299                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 300         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 301                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 302         else
 303                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 304         setorigin (self, self.origin);
 305
 306         if (self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH)
 307         {
 308                 for(t = 0, head = world; (head = find(head, classname, self.classname)); )
 309                 {
 310                         // in minstagib .classname is "minstagib" for every item
 311                         if (g_minstagib && self.items != head.items)
 312                                 continue;
 313                         if (head.scheduledrespawntime > time)
 314                                 if (t == 0 || head.scheduledrespawntime < t)
 315                                         t = head.scheduledrespawntime;
 316                 }
 317                 Item_ItemsTime_UpdateTime(self, t);
 318                 FOR_EACH_REALCLIENT(head)
 319                 {
 320                         if (head.classname != "player")
 321                                 Item_ItemsTime_Get(head);
 322                 }
 323         }
 324
 325         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 326         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 327 }
 328
 329 void Item_RespawnCountdown (void)
 330 {
 331         if(self.count >= ITEM_RESPAWN_TICKS)
 332         {
 333                 if(self.waypointsprite_attached)
 334                         WaypointSprite_Kill(self.waypointsprite_attached);
 335                 Item_Respawn();
 336         }
 337         else
 338         {
 339                 self.nextthink = time + 1;
 340                 self.count += 1;
 341                 if(self.count == 1)
 342                 {
 343                         string name;
 344                         vector rgb;
 345                         name = string_null;
 346                         if(g_minstagib)
 347                         {
 348                                 switch(self.items)
 349                                 {
 350                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 351                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 352                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 353                                 }
 354                         }
 355                         else
 356                         {
 357                                 switch(self.items)
 358                                 {
 359                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 360                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 361                                         case IT_HEALTH:
 362                                                 //if (self.classname == "item_health_mega")
 363                                                         {name = "item_health_mega"; rgb = '1 0 0';}
 364                                                 break;
 365                                         case IT_ARMOR:
 366                                                 if (self.classname == "item_armor_large")
 367                                                         {name = "item_armor_large"; rgb = '0 1 0';}
 368                                                 break;
 369                                 }
 370                         }
 371                         switch(self.items)
 372                         {
 373                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 374                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 375                         }
 376                         if(!name)
 377                         {
 378                                 print("Unknown powerup-marked item is wanting to respawn\n");
 379                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 380                         }
 381                         if(name)
 382                         {
 383                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 384                                 if(self.waypointsprite_attached)
 385                                 {
 386                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 387                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 388                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 389                                 }
 390                         }
 391                 }
 392                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 393                 if(self.waypointsprite_attached)
 394                 {
 395                         WaypointSprite_Ping(self.waypointsprite_attached);
 396                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 397                 }
 398         }
 399 }
 400
 401 void Item_ScheduleRespawnIn(entity e, float t)
 402 {
 403         if(e.flags & FL_POWERUP || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 404         {
 405                 e.think = Item_RespawnCountdown;
 406                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 407                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 408                 e.count = 0;
 409         }
 410         else
 411         {
 412                 e.think = Item_Respawn;
 413                 e.nextthink = time + t;
 414                 e.scheduledrespawntime = e.nextthink;
 415         }
 416         Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 417         FOR_EACH_REALCLIENT(e)
 418         {
 419                 if (e.classname != "player")
 420                         Item_ItemsTime_Get(e);
 421         }
 422 }
 423
 424 void Item_ScheduleRespawn(entity e)
 425 {
 426         if(e.respawntime > 0)
 427         {
 428                 Item_Show(e, 0);
 429                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 430         }
 431         else // if respawntime is -1, this item does not respawn
 432                 Item_Show(e, -1);
 433 }
 434
 435 void Item_ScheduleInitialRespawn(entity e)
 436 {
 437         Item_Show(e, 0);
 438         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 439 }
 440
 441 float ITEM_MODE_NONE = 0;
 442 float ITEM_MODE_HEALTH = 1;
 443 float ITEM_MODE_ARMOR = 2;
 444 float ITEM_MODE_FUEL = 3;
 445 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 446 {
 447         if (!item.ammofield)
 448                 return FALSE;
 449
 450         if (item.spawnshieldtime)
 451         {
 452                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 453                 {
 454                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 455                         goto YEAH;
 456                 }
 457         }
 458         else if(g_weapon_stay == 2)
 459         {
 460                 float mi = min(item.ammofield, ammomax);
 461                 if (player.ammofield < mi)
 462                 {
 463                         player.ammofield = mi;
 464                         goto YEAH;
 465                 }
 466         }
 467
 468         return FALSE;
 469
 470 :YEAH
 471         switch(mode)
 472         {
 473                 case ITEM_MODE_FUEL:
 474                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 475                         break;
 476                 case ITEM_MODE_HEALTH:
 477                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 478                         break;
 479                 case ITEM_MODE_ARMOR:
 480                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 481                         break;
 482                 default:
 483                         break;
 484         }
 485         return TRUE;
 486 }
 487
 488 float Item_GiveTo(entity item, entity player)
 489 {
 490         float _switchweapon;
 491         float pickedup;
 492         float it;
 493         float i;
 494         entity e;
 495
 496         // if nothing happens to player, just return without taking the item
 497         pickedup = FALSE;
 498         _switchweapon = FALSE;
 499
 500         if (g_minstagib)
 501         {
 502                 float prevcells = player.ammo_cells;
 503
 504                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 505                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 506
 507                 if(player.ammo_cells > prevcells)
 508                 {
 509                         _switchweapon = TRUE;
 510
 511                         // play some cool sounds ;)
 512                         if (clienttype(player) == CLIENTTYPE_REAL)
 513                         {
 514                                 if(player.health <= 5)
 515                                         AnnounceTo(player, "lastsecond");
 516                                 else if(player.health < 50)
 517                                         AnnounceTo(player, "narrowly");
 518                         }
 519                         // sound not available
 520                         // else if(item.items == IT_CELLS)
 521                         //      AnnounceTo(player, "ammo");
 522
 523                         if (item.weapons & WEPBIT_MINSTANEX)
 524                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 525                         if (item.ammo_cells)
 526                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 527                         player.health = 100;
 528                 }
 529
 530                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 531                 {
 532                         pickedup = TRUE;
 533                         player.items |= it;
 534                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 535                 }
 536
 537                 // extralife powerup
 538                 if (item.max_health)
 539                 {
 540                         pickedup = TRUE;
 541                         // sound not available
 542                         // AnnounceTo(player, "_lives");
 543                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 544                         sprint(player, "^3You picked up some extra lives\n");
 545                 }
 546
 547                 // invis powerup
 548                 if (item.strength_finished)
 549                 {
 550                         pickedup = TRUE;
 551                         // sound not available
 552                         // AnnounceTo(player, "invisible");
 553                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 554                 }
 555
 556                 // speed powerup
 557                 if (item.invincible_finished)
 558                 {
 559                         pickedup = TRUE;
 560                         // sound not available
 561                         // AnnounceTo(player, "speed");
 562                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 563                 }
 564         }
 565         else
 566         {
 567                 // in case the player has autoswitch enabled do the following:
 568                 // if the player is using their best weapon before items are given, they
 569                 // probably want to switch to an even better weapon after items are given
 570                 if (player.autoswitch)
 571                 if (player.switchweapon == w_getbestweapon(player))
 572                         _switchweapon = TRUE;
 573
 574                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 575                         _switchweapon = TRUE;
 576
 577                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 578                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 579                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 580                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 581                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 582                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 583                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 584
 585                 if (item.flags & FL_WEAPON)
 586                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && g_pickup_weapons_anyway))
 587                 {
 588                         pickedup = TRUE;
 589                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 590                         {
 591                                 e = get_weaponinfo(i);
 592                                 if(it & e.weapons)
 593                                         W_GiveWeapon (player, e.weapon, item.netname);
 594                         }
 595                 }
 596
 597                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 598                 {
 599                         pickedup = TRUE;
 600                         player.items |= it;
 601                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 602                 }
 603
 604                 if (item.strength_finished)
 605                 {
 606                         pickedup = TRUE;
 607                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 608                 }
 609                 if (item.invincible_finished)
 610                 {
 611                         pickedup = TRUE;
 612                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 613                 }
 614         }
 615
 616 :skip
 617         // always eat teamed entities
 618         if(item.team)
 619                 pickedup = TRUE;
 620
 621         if (!pickedup)
 622                 return 0;
 623
 624         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 625         if (_switchweapon)
 626                 if (player.switchweapon != w_getbestweapon(player))
 627                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 628
 629         return 1;
 630 }
 631
 632 void Item_Touch (void)
 633 {
 634         entity e, head;
 635
 636         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 637         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 638         {
 639                 remove(self);
 640                 return;
 641         }
 642         if (other.classname != "player")
 643                 return;
 644         if (other.deadflag)
 645                 return;
 646         if (self.solid != SOLID_TRIGGER)
 647                 return;
 648         if (self.owner == other)
 649                 return;
 650
 651         if(!Item_GiveTo(self, other))
 652                 return;
 653
 654         other.last_pickup = time;
 655
 656         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 657
 658         if (self.classname == "droppedweapon")
 659                 remove (self);
 660         else if not(self.spawnshieldtime)
 661                 return;
 662         else
 663         {
 664                 if(self.team)
 665                 {
 666                         RandomSelection_Init();
 667                         for(head = world; (head = findfloat(head, team, self.team)); )
 668                         {
 669                                 if(head.flags & FL_ITEM)
 670                                 {
 671                                         Item_Show(head, -1);
 672                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 673                                 }
 674                         }
 675                         e = RandomSelection_chosen_ent;
 676                 }
 677                 else
 678                         e = self;
 679                 Item_ScheduleRespawn(e);
 680         }
 681 }
 682
 683 void Item_FindTeam()
 684 {
 685         entity head, e;
 686
 687         if(self.effects & EF_NODRAW)
 688         {
 689                 // marker for item team search
 690                 dprint("Initializing item team ", ftos(self.team), "\n");
 691                 RandomSelection_Init();
 692                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 693                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 694                 e = RandomSelection_chosen_ent;
 695                 e.state = 0;
 696                 Item_Show(e, 1);
 697
 698                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 699                 {
 700                         if(head != e)
 701                         {
 702                                 // make it a non-spawned item
 703                                 Item_Show(head, -1);
 704                                 head.state = 1; // state 1 = initially hidden item
 705                         }
 706                         head.effects &~= EF_NODRAW;
 707                 }
 708
 709                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 710                         Item_ScheduleInitialRespawn(e);
 711         }
 712 }
 713
 714 void Item_Reset()
 715 {
 716         Item_Show(self, !self.state);
 717         setorigin (self, self.origin);
 718         self.think = SUB_Null;
 719         self.nextthink = 0;
 720
 721         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 722                 Item_ScheduleInitialRespawn(self);
 723 }
 724
 725 // Savage: used for item garbage-collection
 726 // TODO: perhaps nice special effect?
 727 void RemoveItem(void)
 728 {
 729         remove(self);
 730 }
 731
 732 // pickup evaluation functions
 733 // these functions decide how desirable an item is to the bots
 734
 735 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 736
 737 float weapon_pickupevalfunc(entity player, entity item)
 738 {
 739         float c, i, j, position;
 740
 741         // See if I have it already
 742         if(player.weapons & item.weapons == item.weapons)
 743         {
 744                 // If I can pick it up
 745                 if(!item.spawnshieldtime)
 746                         c = 0;
 747                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 748                 {
 749                         // Skilled bots will grab more
 750                         c = bound(0, skill / 10, 1) * 0.5;
 751                 }
 752                 else
 753                         c = 0;
 754         }
 755         else
 756                 c = 1;
 757
 758         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 759         if( bot_custom_weapon && c )
 760         {
 761                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 762                 {
 763                         // Find weapon
 764                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 765                                 continue;
 766
 767                         // Find the highest position on any range
 768                         position = -1;
 769                         for(j = 0; j < WEP_LAST ; ++j){
 770                                 if(
 771                                                 bot_weapons_far[j] == i ||
 772                                                 bot_weapons_mid[j] == i ||
 773                                                 bot_weapons_close[j] == i
 774                                   )
 775                                 {
 776                                         position = j;
 777                                         break;
 778                                 }
 779                         }
 780
 781                         // Rate it
 782                         if (position >= 0 )
 783                         {
 784                                 position = WEP_LAST - position;
 785                                 // item.bot_pickupbasevalue is overwritten here
 786                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 787                         }
 788                 }
 789         }
 790
 791         return item.bot_pickupbasevalue * c;
 792 }
 793
 794 float commodity_pickupevalfunc(entity player, entity item)
 795 {
 796         float c, i, need_shells, need_nails, need_rockets, need_cells;
 797         entity wi;
 798         c = 0;
 799
 800         // Detect needed ammo
 801         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 802         {
 803                 wi = get_weaponinfo(i);
 804
 805                 if not(wi.weapons & player.weapons)
 806                         continue;
 807
 808                 if(wi.items & IT_SHELLS)
 809                         need_shells = TRUE;
 810                 else if(wi.items & IT_NAILS)
 811                         need_nails = TRUE;
 812                 else if(wi.items & IT_ROCKETS)
 813                         need_rockets = TRUE;
 814                 else if(wi.items & IT_CELLS)
 815                         need_cells = TRUE;
 816         }
 817
 818         // TODO: figure out if the player even has the weapon this ammo is for?
 819         // may not affect strategy much though...
 820         // find out how much more ammo/armor/health the player can hold
 821         if (need_shells)
 822         if (item.ammo_shells)
 823         if (player.ammo_shells < g_pickup_shells_max)
 824                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 825         if (need_nails)
 826         if (item.ammo_nails)
 827         if (player.ammo_nails < g_pickup_nails_max)
 828                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 829         if (need_rockets)
 830         if (item.ammo_rockets)
 831         if (player.ammo_rockets < g_pickup_rockets_max)
 832                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 833         if (need_cells)
 834         if (item.ammo_cells)
 835         if (player.ammo_cells < g_pickup_cells_max)
 836                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 837         if (item.armorvalue)
 838         if (player.armorvalue < item.max_armorvalue)
 839                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 840         if (item.health)
 841         if (player.health < item.max_health)
 842                 c = c + max(0, 1 - player.health / item.max_health);
 843
 844         return item.bot_pickupbasevalue * c;
 845 }
 846
 847
 848 .float is_item;
 849 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 850 {
 851         startitem_failed = FALSE;
 852
 853         self.items = itemid;
 854         self.weapons = weaponid;
 855         self.flags = FL_ITEM | itemflags;
 856
 857         // is it a dropped weapon?
 858         if (self.classname == "droppedweapon")
 859         {
 860                 self.reset = SUB_Remove;
 861                 // it's a dropped weapon
 862                 self.movetype = MOVETYPE_TOSS;
 863                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 864                 self.think = RemoveItem;
 865                 self.nextthink = time + 60;
 866                 // don't drop if in a NODROP zone (such as lava)
 867                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 868                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 869                 {
 870                         startitem_failed = TRUE;
 871                         remove(self);
 872                         return;
 873                 }
 874         }
 875         else
 876         {
 877                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 878                 {
 879                         startitem_failed = TRUE;
 880                         remove(self);
 881                         return;
 882                 }
 883
 884                 if(!have_pickup_item())
 885                 {
 886                         startitem_failed = TRUE;
 887                         remove (self);
 888                         return;
 889                 }
 890
 891                 self.reset = Item_Reset;
 892                 // it's a level item
 893                 if(self.spawnflags & 1)
 894                         self.noalign = 1;
 895                 if (self.noalign)
 896                         self.movetype = MOVETYPE_NONE;
 897                 else
 898                         self.movetype = MOVETYPE_TOSS;
 899                 // do item filtering according to game mode and other things
 900                 if (!self.noalign)
 901                 {
 902                         // first nudge it off the floor a little bit to avoid math errors
 903                         setorigin(self, self.origin + '0 0 1');
 904                         // set item size before we spawn a spawnfunc_waypoint
 905                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 906                                 setsize (self, '-16 -16 0', '16 16 48');
 907                         else
 908                                 setsize (self, '-16 -16 0', '16 16 32');
 909                         // note droptofloor returns FALSE if stuck/or would fall too far
 910                         droptofloor();
 911                         waypoint_spawnforitem(self);
 912                 }
 913
 914                 /*
 915                  * can't do it that way, as it would break maps
 916                  * TODO make a target_give like entity another way, that perhaps has
 917                  * the weapon name in a key
 918                 if(self.targetname)
 919                 {
 920                         // target_give not yet supported; maybe later
 921                         print("removed targeted ", self.classname, "\n");
 922                         startitem_failed = TRUE;
 923                         remove (self);
 924                         return;
 925                 }
 926                 */
 927
 928                 if(autocvar_spawn_debug >= 2)
 929                 {
 930                         entity otheritem;
 931                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 932                         {
 933                                 if(otheritem.is_item)
 934                                 {
 935                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 936                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 937                                         error("Mapper sucks.");
 938                                 }
 939                         }
 940                         self.is_item = TRUE;
 941                 }
 942
 943                 weaponsInMap |= weaponid;
 944
 945                 precache_model (itemmodel);
 946                 precache_sound (pickupsound);
 947
 948                 precache_sound ("misc/itemrespawncountdown.wav");
 949                 if(!g_minstagib && itemid == IT_STRENGTH)
 950                         precache_sound ("misc/strength_respawn.wav");
 951                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 952                         precache_sound ("misc/shield_respawn.wav");
 953                 else
 954                         precache_sound ("misc/itemrespawn.wav");
 955
 956                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 957                         self.target = "###item###"; // for finding the nearest item using find()
 958
 959                 Item_ItemsTime_UpdateTime(self, 0);
 960         }
 961
 962         self.bot_pickup = TRUE;
 963         self.bot_pickupevalfunc = pickupevalfunc;
 964         self.bot_pickupbasevalue = pickupbasevalue;
 965         self.mdl = itemmodel;
 966         self.item_pickupsound = pickupsound;
 967         // let mappers override respawntime
 968         if(!self.respawntime) // both set
 969         {
 970                 self.respawntime = defaultrespawntime;
 971                 self.respawntimejitter = defaultrespawntimejitter;
 972         }
 973         self.netname = itemname;
 974         self.touch = Item_Touch;
 975         setmodel (self, self.mdl); // precision set below
 976         self.effects |= EF_LOWPRECISION;
 977         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 978                 setsize (self, '-16 -16 0', '16 16 48');
 979         else
 980                 setsize (self, '-16 -16 0', '16 16 32');
 981         if(itemflags & FL_WEAPON)
 982                 self.modelflags |= MF_ROTATE;
 983
 984         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 985         if (itemflags & FL_WEAPON)
 986         {
 987                 // neutral team color for pickup weapons
 988                 self.colormap = 1024; // color shirt=0 pants=0 grey
 989         }
 990
 991         Item_Show(self, 1);
 992         self.state = 0;
 993         if(self.team)
 994         {
 995                 if(!self.cnt)
 996                         self.cnt = 1; // item probability weight
 997                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 998                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 999         }
1000         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
1001                 Item_ScheduleInitialRespawn(self);
1002 }
1003
1004 /* replace items in minstagib
1005  * IT_STRENGTH   = invisibility
1006  * IT_NAILS      = extra lives
1007  * IT_INVINCIBLE = speed
1008  */
1009 void minstagib_items (float itemid)
1010 {
1011         float rnd;
1012         self.classname = "minstagib";
1013
1014         // replace rocket launchers and nex guns with ammo cells
1015         if (itemid == IT_CELLS)
1016         {
1017                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1018                 StartItem ("models/items/a_cells.md3",
1019                         "misc/itempickup.wav", 45, 0,
1020                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
1021                 return;
1022         }
1023
1024         // randomize
1025         rnd = random() * 3;
1026         if (rnd <= 1)
1027                 itemid = IT_STRENGTH;
1028         else if (rnd <= 2)
1029                 itemid = IT_NAILS;
1030         else
1031                 itemid = IT_INVINCIBLE;
1032
1033         // replace with invis
1034         if (itemid == IT_STRENGTH)
1035         {
1036                 self.strength_finished = 30;
1037                 StartItem ("models/items/g_strength.md3",
1038                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1039                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1040         }
1041         // replace with extra lives
1042         if (itemid == IT_NAILS)
1043         {
1044                 self.max_health = 1;
1045                 StartItem ("models/items/g_h100.md3",
1046                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1047                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1048         }
1049         // replace with speed
1050         if (itemid == IT_INVINCIBLE)
1051         {
1052                 self.invincible_finished = 30;
1053                 StartItem ("models/items/g_invincible.md3",
1054                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1055                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1056         }
1057 }
1058
1059 float minst_no_auto_cells;
1060 void minst_remove_item (void) {
1061         if(minst_no_auto_cells)
1062                 remove(self);
1063 }
1064
1065 float weaponswapping;
1066 float internalteam;
1067
1068 void weapon_defaultspawnfunc(float wpn)
1069 {
1070         entity e;
1071         float t;
1072         var .float ammofield;
1073         string s;
1074         entity oldself;
1075         float i, j;
1076
1077         // set the respawntime in advance (so replaced weapons can copy it)
1078
1079         if(!self.respawntime)
1080         {
1081                 e = get_weaponinfo(wpn);
1082                 if(e.items == IT_SUPERWEAPON)
1083                 {
1084                         self.respawntime = g_pickup_respawntime_powerup;
1085                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
1086                 }
1087                 else
1088                 {
1089                         self.respawntime = g_pickup_respawntime_weapon;
1090                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1091                 }
1092         }
1093
1094         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1095         {
1096                 e = get_weaponinfo(wpn);
1097                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1098                 if(s == "0")
1099                 {
1100                         remove(self);
1101                         startitem_failed = TRUE;
1102                         return;
1103                 }
1104                 t = tokenize_console(s);
1105                 if(t >= 2)
1106                 {
1107                         self.team = --internalteam;
1108                         oldself = self;
1109                         for(i = 1; i < t; ++i)
1110                         {
1111                                 s = argv(i);
1112                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1113                                 {
1114                                         e = get_weaponinfo(j);
1115                                         if(e.netname == s)
1116                                         {
1117                                                 self = spawn();
1118                                                 copyentity(oldself, self);
1119                                                 self.classname = "replacedweapon";
1120                                                 weapon_defaultspawnfunc(j);
1121                                                 break;
1122                                         }
1123                                 }
1124                                 if(j > WEP_LAST)
1125                                 {
1126                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1127                                 }
1128                         }
1129                         self = oldself;
1130                 }
1131                 if(t >= 1)
1132                 {
1133                         s = argv(0);
1134                         wpn = 0;
1135                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1136                         {
1137                                 e = get_weaponinfo(j);
1138                                 if(e.netname == s)
1139                                 {
1140                                         wpn = j;
1141                                         break;
1142                                 }
1143                         }
1144                         if(j > WEP_LAST)
1145                         {
1146                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1147                         }
1148                 }
1149                 if(wpn == 0)
1150                 {
1151                         remove(self);
1152                         startitem_failed = TRUE;
1153                         return;
1154                 }
1155         }
1156
1157         e = get_weaponinfo(wpn);
1158
1159         if(e.items && e.items != IT_SUPERWEAPON)
1160         {
1161                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1162                 {
1163                         if(e.items & j)
1164                         {
1165                                 ammofield = Item_CounterField(j);
1166                                 if(!self.ammofield)
1167                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1168                         }
1169                 }
1170         }
1171         else
1172         {
1173                 self.flags |= FL_NO_WEAPON_STAY;
1174         }
1175
1176         // weapon stay isn't supported for teamed weapons
1177         if(self.team)
1178                 self.flags |= FL_NO_WEAPON_STAY;
1179
1180         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1181         if (self.modelindex) // don't precache if self was removed
1182                 weapon_action(e.weapon, WR_PRECACHE);
1183 }
1184
1185 void spawnfunc_weapon_shotgun (void);
1186 void spawnfunc_weapon_uzi (void) {
1187         if(autocvar_sv_q3acompat_machineshotgunswap)
1188         if(self.classname != "droppedweapon")
1189         {
1190                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1191                 return;
1192         }
1193         weapon_defaultspawnfunc(WEP_UZI);
1194 }
1195
1196 void spawnfunc_weapon_shotgun (void) {
1197         if(autocvar_sv_q3acompat_machineshotgunswap)
1198         if(self.classname != "droppedweapon")
1199         {
1200                 weapon_defaultspawnfunc(WEP_UZI);
1201                 return;
1202         }
1203         weapon_defaultspawnfunc(WEP_SHOTGUN);
1204 }
1205
1206 void spawnfunc_weapon_nex (void)
1207 {
1208         if (g_minstagib)
1209         {
1210                 minstagib_items(IT_CELLS);
1211                 self.think = minst_remove_item;
1212                 self.nextthink = time;
1213                 return;
1214         }
1215         weapon_defaultspawnfunc(WEP_NEX);
1216 }
1217
1218 void spawnfunc_weapon_minstanex (void)
1219 {
1220         if (g_minstagib)
1221         {
1222                 minstagib_items(IT_CELLS);
1223                 self.think = minst_remove_item;
1224                 self.nextthink = time;
1225                 return;
1226         }
1227         weapon_defaultspawnfunc(WEP_MINSTANEX);
1228 }
1229
1230 void spawnfunc_weapon_rocketlauncher (void)
1231 {
1232         if (g_minstagib)
1233         {
1234                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1235                 self.think = minst_remove_item;
1236                 self.nextthink = time;
1237                 return;
1238         }
1239         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1240 }
1241
1242 void spawnfunc_item_rockets (void) {
1243         if(!self.ammo_rockets)
1244                 self.ammo_rockets = g_pickup_rockets;
1245         if(!self.pickup_anyway)
1246                 self.pickup_anyway = g_pickup_ammo_anyway;
1247         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1248 }
1249
1250 void spawnfunc_item_shells (void);
1251 void spawnfunc_item_bullets (void) {
1252         if(!weaponswapping)
1253         if(autocvar_sv_q3acompat_machineshotgunswap)
1254         if(self.classname != "droppedweapon")
1255         {
1256                 weaponswapping = TRUE;
1257                 spawnfunc_item_shells();
1258                 weaponswapping = FALSE;
1259                 return;
1260         }
1261
1262         if(!self.ammo_nails)
1263                 self.ammo_nails = g_pickup_nails;
1264         if(!self.pickup_anyway)
1265                 self.pickup_anyway = g_pickup_ammo_anyway;
1266         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1267 }
1268
1269 void spawnfunc_item_cells (void) {
1270         if(!self.ammo_cells)
1271                 self.ammo_cells = g_pickup_cells;
1272         if(!self.pickup_anyway)
1273                 self.pickup_anyway = g_pickup_ammo_anyway;
1274         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1275 }
1276
1277 void spawnfunc_item_shells (void) {
1278         if(!weaponswapping)
1279         if(autocvar_sv_q3acompat_machineshotgunswap)
1280         if(self.classname != "droppedweapon")
1281         {
1282                 weaponswapping = TRUE;
1283                 spawnfunc_item_bullets();
1284                 weaponswapping = FALSE;
1285                 return;
1286         }
1287
1288         if(!self.ammo_shells)
1289                 self.ammo_shells = g_pickup_shells;
1290         if(!self.pickup_anyway)
1291                 self.pickup_anyway = g_pickup_ammo_anyway;
1292         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1293 }
1294
1295 void spawnfunc_item_armor_small (void) {
1296         if(!self.armorvalue)
1297                 self.armorvalue = g_pickup_armorsmall;
1298         if(!self.max_armorvalue)
1299                 self.max_armorvalue = g_pickup_armorsmall_max;
1300         if(!self.pickup_anyway)
1301                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1302         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1303 }
1304
1305 void spawnfunc_item_armor_medium (void) {
1306         if(!self.armorvalue)
1307                 self.armorvalue = g_pickup_armormedium;
1308         if(!self.max_armorvalue)
1309                 self.max_armorvalue = g_pickup_armormedium_max;
1310         if(!self.pickup_anyway)
1311                 self.pickup_anyway = g_pickup_armormedium_anyway;
1312         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1313 }
1314
1315 void spawnfunc_item_armor_big (void) {
1316         if(!self.armorvalue)
1317                 self.armorvalue = g_pickup_armorbig;
1318         if(!self.max_armorvalue)
1319                 self.max_armorvalue = g_pickup_armorbig_max;
1320         if(!self.pickup_anyway)
1321                 self.pickup_anyway = g_pickup_armorbig_anyway;
1322         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1323 }
1324
1325 void spawnfunc_item_armor_large (void) {
1326         if(!self.armorvalue)
1327                 self.armorvalue = g_pickup_armorlarge;
1328         if(!self.max_armorvalue)
1329                 self.max_armorvalue = g_pickup_armorlarge_max;
1330         if(!self.pickup_anyway)
1331                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1332         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1333 }
1334
1335 void spawnfunc_item_health_small (void) {
1336         if(!self.max_health)
1337                 self.max_health = g_pickup_healthsmall_max;
1338         if(!self.health)
1339                 self.health = g_pickup_healthsmall;
1340         if(!self.pickup_anyway)
1341                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1342         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1343 }
1344
1345 void spawnfunc_item_health_medium (void) {
1346         if(!self.max_health)
1347                 self.max_health = g_pickup_healthmedium_max;
1348         if(!self.health)
1349                 self.health = g_pickup_healthmedium;
1350         if(!self.pickup_anyway)
1351                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1352         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1353 }
1354
1355 void spawnfunc_item_health_large (void) {
1356         if(!self.max_health)
1357                 self.max_health = g_pickup_healthlarge_max;
1358         if(!self.health)
1359                 self.health = g_pickup_healthlarge;
1360         if(!self.pickup_anyway)
1361                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1362         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1363 }
1364
1365 void spawnfunc_item_health_mega (void) {
1366         if(g_minstagib) {
1367                 minstagib_items(IT_NAILS);
1368         } else {
1369                 if(!self.max_health)
1370                         self.max_health = g_pickup_healthmega_max;
1371                 if(!self.health)
1372                         self.health = g_pickup_healthmega;
1373                 if(!self.pickup_anyway)
1374                         self.pickup_anyway = g_pickup_healthmega_anyway;
1375                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1376         }
1377 }
1378
1379 // support old misnamed entities
1380 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1381 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1382 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1383 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1384 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1385
1386 void spawnfunc_item_strength (void) {
1387         if(g_minstagib) {
1388                 minstagib_items(IT_STRENGTH);
1389         } else {
1390                 precache_sound("weapons/strength_fire.wav");
1391                 self.strength_finished = 30;
1392                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1393         }
1394 }
1395
1396 void spawnfunc_item_invincible (void) {
1397         if(g_minstagib) {
1398                 minstagib_items(IT_INVINCIBLE);
1399         } else {
1400                 self.invincible_finished = 30;
1401                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1402         }
1403 }
1404
1405 void spawnfunc_item_minst_cells (void) {
1406         if (g_minstagib)
1407         {
1408                 minst_no_auto_cells = 1;
1409                 minstagib_items(IT_CELLS);
1410         }
1411         else
1412                 remove(self);
1413 }
1414
1415 // compatibility:
1416 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1417
1418 float GiveItems(entity e, float beginarg, float endarg);
1419 void target_items_use (void)
1420 {
1421         if(activator.classname == "droppedweapon")
1422         {
1423                 EXACTTRIGGER_TOUCH;
1424                 remove(activator);
1425                 return;
1426         }
1427
1428         if(activator.classname != "player")
1429                 return;
1430         if(activator.deadflag != DEAD_NO)
1431                 return;
1432         EXACTTRIGGER_TOUCH;
1433
1434         entity e;
1435         for(e = world; (e = find(e, classname, "droppedweapon")); )
1436                 if(e.enemy == activator)
1437                         remove(e);
1438
1439         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1440                 centerprint(activator, self.message);
1441 }
1442
1443 void spawnfunc_target_items (void)
1444 {
1445         float n, i, j;
1446         entity e;
1447
1448         self.use = target_items_use;
1449         if(!self.strength_finished)
1450                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1451         if(!self.invincible_finished)
1452                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1453
1454         precache_sound("misc/itempickup.wav");
1455         precache_sound("misc/megahealth.wav");
1456         precache_sound("misc/armor25.wav");
1457         precache_sound("misc/powerup.wav");
1458         precache_sound("misc/poweroff.wav");
1459         precache_sound("weapons/weaponpickup.wav");
1460
1461         n = tokenize_console(self.netname);
1462         if(argv(0) == "give")
1463         {
1464                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1465         }
1466         else
1467         {
1468                 for(i = 0; i < n; ++i)
1469                 {
1470                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1471                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1472                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1473                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1474                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1475                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1476                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1477                         else
1478                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1479                         {
1480                                 e = get_weaponinfo(j);
1481                                 if(argv(i) == e.netname)
1482                                 {
1483                                         self.weapons |= e.weapons;
1484                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1485                                                 weapon_action(e.weapon, WR_PRECACHE);
1486                                         break;
1487                                 }
1488                         }
1489                         if(j > WEP_LAST)
1490                                 print("target_items: invalid item ", argv(i), "\n");
1491                 }
1492
1493                 string itemprefix, valueprefix;
1494                 if(self.spawnflags == 0)
1495                 {
1496                         itemprefix = "";
1497                         valueprefix = "";
1498                 }
1499                 else if(self.spawnflags == 1)
1500                 {
1501                         itemprefix = "max ";
1502                         valueprefix = "max ";
1503                 }
1504                 else if(self.spawnflags == 2)
1505                 {
1506                         itemprefix = "min ";
1507                         valueprefix = "min ";
1508                 }
1509                 else if(self.spawnflags == 4)
1510                 {
1511                         itemprefix = "minus ";
1512                         valueprefix = "max ";
1513                 }
1514                 else
1515                         error("invalid spawnflags");
1516
1517                 self.netname = "";
1518                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1519                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1520                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1521                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1522                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1523                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1524                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1525                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1526                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1527                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1528                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1529                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1530                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1531                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1532                 {
1533                         e = get_weaponinfo(j);
1534                         if(e.weapons)
1535                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1536                 }
1537         }
1538         self.netname = strzone(self.netname);
1539         //print(self.netname, "\n");
1540
1541         n = tokenize_console(self.netname);
1542         for(i = 0; i < n; ++i)
1543         {
1544                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1545                 {
1546                         e = get_weaponinfo(j);
1547                         if(argv(i) == e.netname)
1548                         {
1549                                 weapon_action(e.weapon, WR_PRECACHE);
1550                                 break;
1551                         }
1552                 }
1553         }
1554 }
1555
1556 void spawnfunc_item_fuel(void)
1557 {
1558         if(!self.ammo_fuel)
1559                 self.ammo_fuel = g_pickup_fuel;
1560         if(!self.pickup_anyway)
1561                 self.pickup_anyway = g_pickup_ammo_anyway;
1562         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1563 }
1564
1565 void spawnfunc_item_fuel_regen(void)
1566 {
1567         if(start_items & IT_FUEL_REGEN)
1568         {
1569                 spawnfunc_item_fuel();
1570                 return;
1571         }
1572         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1573 }
1574
1575 void spawnfunc_item_jetpack(void)
1576 {
1577         if(g_grappling_hook)
1578                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1579         if(!self.ammo_fuel)
1580                 self.ammo_fuel = g_pickup_fuel_jetpack;
1581         if(start_items & IT_JETPACK)
1582         {
1583                 spawnfunc_item_fuel();
1584                 return;
1585         }
1586         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1587 }
1588
1589
1590 #define OP_SET 0
1591 #define OP_MIN 1
1592 #define OP_MAX 2
1593 #define OP_PLUS 3
1594 #define OP_MINUS 4
1595
1596 float GiveBit(entity e, .float fld, float bit, float op, float val)
1597 {
1598         float v0, v1;
1599         v0 = (e.fld & bit);
1600         switch(op)
1601         {
1602                 case OP_SET:
1603                         if(val > 0)
1604                                 e.fld |= bit;
1605                         else
1606                                 e.fld &~= bit;
1607                         break;
1608                 case OP_MIN:
1609                 case OP_PLUS:
1610                         if(val > 0)
1611                                 e.fld |= bit;
1612                         break;
1613                 case OP_MAX:
1614                         if(val <= 0)
1615                                 e.fld &~= bit;
1616                         break;
1617                 case OP_MINUS:
1618                         if(val > 0)
1619                                 e.fld &~= bit;
1620                         break;
1621         }
1622         v1 = (e.fld & bit);
1623         return (v0 != v1);
1624 }
1625
1626 float GiveValue(entity e, .float fld, float op, float val)
1627 {
1628         float v0, v1;
1629         v0 = e.fld;
1630         switch(op)
1631         {
1632                 case OP_SET:
1633                         e.fld = val;
1634                         break;
1635                 case OP_MIN:
1636                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1637                         break;
1638                 case OP_MAX:
1639                         e.fld = min(e.fld, val);
1640                         break;
1641                 case OP_PLUS:
1642                         e.fld += val;
1643                         break;
1644                 case OP_MINUS:
1645                         e.fld -= val;
1646                         break;
1647         }
1648         v1 = e.fld;
1649         return (v0 != v1);
1650 }
1651
1652 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1653 {
1654         if(v1 == v0)
1655                 return;
1656         if(v1 <= v0 - t)
1657         {
1658                 if(snd_decr != "")
1659                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1660         }
1661         else if(v0 >= v0 + t)
1662         {
1663                 if(snd_incr != "")
1664                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1665         }
1666 }
1667
1668 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1669 {
1670         if(v0 < v1)
1671                 e.rotfield = max(e.rotfield, time + rottime);
1672         else if(v0 > v1)
1673                 e.regenfield = max(e.regenfield, time + regentime);
1674 }
1675
1676 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1677 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1678 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1679 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1680
1681 float GiveItems(entity e, float beginarg, float endarg)
1682 {
1683         float got, i, j, val, op;
1684         float _switchweapon;
1685         entity wi;
1686         string cmd;
1687
1688         val = 999;
1689         op = OP_SET;
1690
1691         got = 0;
1692
1693         _switchweapon = FALSE;
1694         if (e.autoswitch)
1695                 if (e.switchweapon == w_getbestweapon(e))
1696                         _switchweapon = TRUE;
1697
1698         e.strength_finished = max(0, e.strength_finished - time);
1699         e.invincible_finished = max(0, e.invincible_finished - time);
1700
1701         PREGIVE(e, items);
1702         PREGIVE(e, weapons);
1703         PREGIVE(e, strength_finished);
1704         PREGIVE(e, invincible_finished);
1705         PREGIVE(e, ammo_nails);
1706         PREGIVE(e, ammo_cells);
1707         PREGIVE(e, ammo_shells);
1708         PREGIVE(e, ammo_rockets);
1709         PREGIVE(e, ammo_fuel);
1710         PREGIVE(e, armorvalue);
1711         PREGIVE(e, health);
1712
1713         for(i = beginarg; i < endarg; ++i)
1714         {
1715                 cmd = argv(i);
1716
1717                 if(cmd == "0" || stof(cmd))
1718                 {
1719                         val = stof(cmd);
1720                         continue;
1721                 }
1722                 switch(cmd)
1723                 {
1724                         case "no":
1725                                 op = OP_MAX;
1726                                 val = 0;
1727                                 continue;
1728                         case "max":
1729                                 op = OP_MAX;
1730                                 continue;
1731                         case "min":
1732                                 op = OP_MIN;
1733                                 continue;
1734                         case "plus":
1735                                 op = OP_PLUS;
1736                                 continue;
1737                         case "minus":
1738                                 op = OP_MINUS;
1739                                 continue;
1740                         case "ALL":
1741                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1742                                 got += GiveValue(e, strength_finished, op, time);
1743                                 got += GiveValue(e, invincible_finished, op, time);
1744                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1745                         case "all":
1746                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1747                                 got += GiveValue(e, health, op, val);
1748                                 got += GiveValue(e, armorvalue, op, val);
1749                         case "allweapons":
1750                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1751                                 {
1752                                         wi = get_weaponinfo(j);
1753                                         if(wi.weapons)
1754                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1755                                 }
1756                         case "allammo":
1757                                 got += GiveValue(e, ammo_cells, op, val);
1758                                 got += GiveValue(e, ammo_shells, op, val);
1759                                 got += GiveValue(e, ammo_nails, op, val);
1760                                 got += GiveValue(e, ammo_rockets, op, val);
1761                                 got += GiveValue(e, ammo_fuel, op, val);
1762                                 break;
1763                         case "unlimited_ammo":
1764                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1765                                 break;
1766                         case "unlimited_weapon_ammo":
1767                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1768                                 break;
1769                         case "unlimited_superweapons":
1770                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1771                                 break;
1772                         case "jetpack":
1773                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1774                                 break;
1775                         case "fuel_regen":
1776                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1777                                 break;
1778                         case "strength":
1779                                 got += GiveValue(e, strength_finished, op, val);
1780                                 break;
1781                         case "invincible":
1782                                 got += GiveValue(e, invincible_finished, op, val);
1783                                 break;
1784                         case "cells":
1785                                 got += GiveValue(e, ammo_cells, op, val);
1786                                 break;
1787                         case "shells":
1788                                 got += GiveValue(e, ammo_shells, op, val);
1789                                 break;
1790                         case "nails":
1791                         case "bullets":
1792                                 got += GiveValue(e, ammo_nails, op, val);
1793                                 break;
1794                         case "rockets":
1795                                 got += GiveValue(e, ammo_rockets, op, val);
1796                                 break;
1797                         case "health":
1798                                 got += GiveValue(e, health, op, val);
1799                                 break;
1800                         case "armor":
1801                                 got += GiveValue(e, armorvalue, op, val);
1802                                 break;
1803                         case "fuel":
1804                                 got += GiveValue(e, ammo_fuel, op, val);
1805                                 break;
1806                         default:
1807                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1808                                 {
1809                                         wi = get_weaponinfo(j);
1810                                         if(cmd == wi.netname)
1811                                         {
1812                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1813                                                 break;
1814                                         }
1815                                 }
1816                                 if(j > WEP_LAST)
1817                                         print("give: invalid item ", cmd, "\n");
1818                                 break;
1819                 }
1820                 val = 999;
1821                 op = OP_SET;
1822         }
1823
1824         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1825         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1826         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1827         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1828         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1829         {
1830                 wi = get_weaponinfo(j);
1831                 if(wi.weapons)
1832                 {
1833                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1834                         if not(save_weapons & wi.weapons)
1835                                 if(e.weapons & wi.weapons)
1836                                         weapon_action(wi.weapon, WR_PRECACHE);
1837                 }
1838         }
1839         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1840         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1841         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1842         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1843         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1844         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1845         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1846         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1847         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1848
1849         if (g_minstagib)
1850         {
1851                 e.health = bound(0, e.health, 100);
1852                 e.armorvalue = bound(0, e.armorvalue, 999);
1853         }
1854
1855         if(e.strength_finished <= 0)
1856                 e.strength_finished = 0;
1857         else
1858                 e.strength_finished += time;
1859         if(e.invincible_finished <= 0)
1860                 e.invincible_finished = 0;
1861         else
1862                 e.invincible_finished += time;
1863
1864         if not(e.weapons & W_WeaponBit(e.switchweapon))
1865                 _switchweapon = TRUE;
1866         if(_switchweapon)
1867                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1868
1869         return got;
1870 }