qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(cvar_string("g_ghost_items_color"));
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent green and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent green and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 115                 self.glowmod = self.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 127                 self.glowmod = self.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (cvar("g_nodepthtestitems"))
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (cvar("g_fullbrightitems"))
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 152         else
 153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 202                                 if(self.waypointsprite_attached)
 203                                 {
 204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 207                                 }
 208                         }
 209                 }
 210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 211                 if(self.waypointsprite_attached)
 212                 {
 213                         WaypointSprite_Ping(self.waypointsprite_attached);
 214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 215                 }
 216         }
 217 }
 218
 219 void Item_ScheduleRespawnIn(entity e, float t)
 220 {
 221         if(e.flags & FL_POWERUP)
 222         {
 223                 e.think = Item_RespawnCountdown;
 224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 225                 e.count = 0;
 226         }
 227         else
 228         {
 229                 e.think = Item_Respawn;
 230                 e.nextthink = time + t;
 231         }
 232 }
 233
 234 void Item_ScheduleRespawn(entity e)
 235 {
 236         Item_Show(e, 0);
 237         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 238 }
 239
 240 void Item_ScheduleInitialRespawn(entity e)
 241 {
 242         Item_Show(e, 0);
 243         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 244 }
 245
 246 float Item_GiveTo(entity item, entity player)
 247 {
 248         float _switchweapon;
 249         float pickedup;
 250         float it;
 251         float i;
 252         entity e;
 253
 254         // if nothing happens to player, just return without taking the item
 255         pickedup = FALSE;
 256         _switchweapon = FALSE;
 257
 258         if (g_minstagib)
 259         {
 260                 if(item.spawnshieldtime)
 261                 {
 262                         if (item.ammo_fuel)
 263                         if (player.ammo_fuel < g_pickup_fuel_max)
 264                         {
 265                                 pickedup = TRUE;
 266                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 267                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 268                         }
 269                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 270                         {
 271                                 pickedup = TRUE;
 272                                 player.items |= it;
 273                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 274                         }
 275
 276                         _switchweapon = TRUE;
 277                         if (item.ammo_cells)
 278                         {
 279                                 pickedup = TRUE;
 280                                 // play some cool sounds ;)
 281                                 centerprint(player, "\n");
 282                                 if (clienttype(player) == CLIENTTYPE_REAL)
 283                                 {
 284                                         if(player.health <= 5)
 285                                                 AnnounceTo(player, "lastsecond");
 286                                         else if(player.health < 50)
 287                                                 AnnounceTo(player, "narrowly");
 288                                 }
 289                                 // sound not available
 290                                 // else if(item.items == IT_CELLS)
 291                                 //      AnnounceTo(player, "ammo");
 292
 293                                 if (item.weapons & WEPBIT_MINSTANEX)
 294                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 295                                 if (item.ammo_cells)
 296                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 297                                 player.health = 100;
 298                         }
 299
 300                         // extralife powerup
 301                         if (item.max_health)
 302                         {
 303                                 pickedup = TRUE;
 304                                 // sound not available
 305                                 // AnnounceTo(player, "_lives");
 306                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 307                                 sprint(player, "^3You picked up some extra lives\n");
 308                         }
 309
 310                         // invis powerup
 311                         if (item.strength_finished)
 312                         {
 313                                 pickedup = TRUE;
 314                                 // sound not available
 315                                 // AnnounceTo(player, "invisible");
 316                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 317                         }
 318
 319                         // speed powerup
 320                         if (item.invincible_finished)
 321                         {
 322                                 pickedup = TRUE;
 323                                 // sound not available
 324                                 // AnnounceTo(player, "speed");
 325                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 326                         }
 327
 328                         if (item.ammo_fuel)
 329                         if (player.ammo_fuel < g_pickup_fuel_max)
 330                         {
 331                                 pickedup = TRUE;
 332                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 333                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 334                         }
 335                 }
 336         }
 337         else
 338         {
 339                 if (g_weapon_stay == 1)
 340                 if not(item.flags & FL_NO_WEAPON_STAY)
 341                 if (item.flags & FL_WEAPON)
 342                 {
 343                         if(item.classname == "droppedweapon")
 344                         {
 345                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 346                                         goto skip;
 347                         }
 348                         else
 349                         {
 350                                 if (player.weapons & item.weapons)
 351                                         goto skip;
 352                         }
 353                 }
 354
 355                 // in case the player has autoswitch enabled do the following:
 356                 // if the player is using their best weapon before items are given, they
 357                 // probably want to switch to an even better weapon after items are given
 358                 if (player.autoswitch)
 359                 if (player.switchweapon == w_getbestweapon(player))
 360                         _switchweapon = TRUE;
 361
 362                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 363                         _switchweapon = TRUE;
 364
 365                 if(item.spawnshieldtime)
 366                 {
 367                         if (item.ammo_shells)
 368                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 369                         {
 370                                 pickedup = TRUE;
 371                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 372                         }
 373                         if (item.ammo_nails)
 374                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 375                         {
 376                                 pickedup = TRUE;
 377                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 378                         }
 379                         if (item.ammo_rockets)
 380                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 381                         {
 382                                 pickedup = TRUE;
 383                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 384                         }
 385                         if (item.ammo_cells)
 386                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 387                         {
 388                                 pickedup = TRUE;
 389                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 390                         }
 391                         if (item.ammo_fuel)
 392                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 393                         {
 394                                 pickedup = TRUE;
 395                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 396                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 397                         }
 398                 }
 399
 400                 if (item.flags & FL_WEAPON)
 401                 if ((it = item.weapons - (item.weapons & player.weapons)) || g_pickup_weapons_anyway)
 402                 {
 403                         pickedup = TRUE;
 404                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 405                         {
 406                                 e = get_weaponinfo(i);
 407                                 if(it & e.weapons)
 408                                         W_GiveWeapon (player, e.weapon, item.netname);
 409                         }
 410                 }
 411
 412                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 413                 {
 414                         pickedup = TRUE;
 415                         player.items |= it;
 416                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 417                 }
 418
 419                 if(item.spawnshieldtime)
 420                 {
 421                         if (item.strength_finished)
 422                         {
 423                                 pickedup = TRUE;
 424                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 425                         }
 426                         if (item.invincible_finished)
 427                         {
 428                                 pickedup = TRUE;
 429                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 430                         }
 431
 432                         if (item.health)
 433                         if ((player.health < item.max_health) || item.pickup_anyway)
 434                         {
 435                                 pickedup = TRUE;
 436                                 player.health = min(player.health + item.health, item.max_health);
 437                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 438                         }
 439                         if (item.armorvalue)
 440                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 441                         {
 442                                 pickedup = TRUE;
 443                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 444                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 445                         }
 446                 }
 447         }
 448
 449 :skip
 450         // always eat teamed entities
 451         if(item.team)
 452                 pickedup = TRUE;
 453
 454         if (!pickedup)
 455                 return 0;
 456
 457         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 458         if (_switchweapon)
 459                 if (player.switchweapon != w_getbestweapon(player))
 460                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 461
 462         return 1;
 463 }
 464
 465 void Item_Touch (void)
 466 {
 467         entity e, head;
 468
 469         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 470         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 471         {
 472                 remove(self);
 473                 return;
 474         }
 475         if (other.classname != "player")
 476                 return;
 477         if (other.deadflag)
 478                 return;
 479         if (self.solid != SOLID_TRIGGER)
 480                 return;
 481         if (self.owner == other)
 482                 return;
 483
 484         if(!Item_GiveTo(self, other))
 485                 return;
 486
 487         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 488
 489         if (self.classname == "droppedweapon")
 490                 remove (self);
 491         else if not(self.spawnshieldtime)
 492                 return;
 493         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 494                 return;
 495         else
 496         {
 497                 if(self.team)
 498                 {
 499                         RandomSelection_Init();
 500                         for(head = world; (head = findfloat(head, team, self.team)); )
 501                         {
 502                                 if(head.flags & FL_ITEM)
 503                                 {
 504                                         Item_Show(head, -1);
 505                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 506                                 }
 507                         }
 508                         e = RandomSelection_chosen_ent;
 509                 }
 510                 else
 511                         e = self;
 512                 Item_ScheduleRespawn(e);
 513         }
 514 }
 515
 516 void Item_FindTeam()
 517 {
 518         entity head, e;
 519
 520         if(self.effects & EF_NODRAW)
 521         {
 522                 // marker for item team search
 523                 dprint("Initializing item team ", ftos(self.team), "\n");
 524                 RandomSelection_Init();
 525                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 526                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 527                 e = RandomSelection_chosen_ent;
 528                 e.state = 0;
 529                 Item_Show(e, 1);
 530
 531                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 532                 {
 533                         if(head != e)
 534                         {
 535                                 // make it a non-spawned item
 536                                 Item_Show(head, -1);
 537                                 head.state = 1; // state 1 = initially hidden item
 538                         }
 539                         head.effects &~= EF_NODRAW;
 540                 }
 541
 542                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 543                         Item_ScheduleInitialRespawn(e);
 544         }
 545 }
 546
 547 void Item_Reset()
 548 {
 549         Item_Show(self, !self.state);
 550         setorigin (self, self.origin);
 551         self.think = SUB_Null;
 552         self.nextthink = 0;
 553
 554         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 555                 Item_ScheduleInitialRespawn(self);
 556 }
 557
 558 // Savage: used for item garbage-collection
 559 // TODO: perhaps nice special effect?
 560 void RemoveItem(void)
 561 {
 562         remove(self);
 563 }
 564
 565 // pickup evaluation functions
 566 // these functions decide how desirable an item is to the bots
 567
 568 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 569
 570 float weapon_pickupevalfunc(entity player, entity item)
 571 {
 572         float c, i, j, position;
 573
 574         // See if I have it already
 575         if(player.weapons & item.weapons == item.weapons)
 576         {
 577                 // If I can pick it up
 578                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 579                         c = 0;
 580                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 581                 {
 582                         // Skilled bots will grab more
 583                         c = bound(0, skill / 10, 1) * 0.5;
 584                 }
 585                 else
 586                         c = 0;
 587         }
 588         else
 589                 c = 1;
 590
 591         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 592         if( bot_custom_weapon && c )
 593         {
 594                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 595                 {
 596                         // Find weapon
 597                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 598                                 continue;
 599
 600                         // Find the highest position on any range
 601                         position = -1;
 602                         for(j = 0; j < WEP_LAST ; ++j){
 603                                 if(
 604                                                 bot_weapons_far[j] == i ||
 605                                                 bot_weapons_mid[j] == i ||
 606                                                 bot_weapons_close[j] == i
 607                                   )
 608                                 {
 609                                         position = j;
 610                                         break;
 611                                 }
 612                         }
 613
 614                         // Rate it
 615                         if (position >= 0 )
 616                         {
 617                                 position = WEP_LAST - position;
 618                                 // item.bot_pickupbasevalue is overwritten here
 619                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 620                         }
 621                 }
 622         }
 623
 624         return item.bot_pickupbasevalue * c;
 625 };
 626
 627 float commodity_pickupevalfunc(entity player, entity item)
 628 {
 629         float c, i, need_shells, need_nails, need_rockets, need_cells;
 630         entity wi;
 631         c = 0;
 632
 633         // Detect needed ammo
 634         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 635         {
 636                 wi = get_weaponinfo(i);
 637
 638                 if not(wi.weapons & player.weapons)
 639                         continue;
 640
 641                 if(wi.items & IT_SHELLS)
 642                         need_shells = TRUE;
 643                 else if(wi.items & IT_NAILS)
 644                         need_nails = TRUE;
 645                 else if(wi.items & IT_ROCKETS)
 646                         need_rockets = TRUE;
 647                 else if(wi.items & IT_CELLS)
 648                         need_cells = TRUE;
 649         }
 650
 651         // TODO: figure out if the player even has the weapon this ammo is for?
 652         // may not affect strategy much though...
 653         // find out how much more ammo/armor/health the player can hold
 654         if (need_shells)
 655         if (item.ammo_shells)
 656         if (player.ammo_shells < g_pickup_shells_max)
 657                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 658         if (need_nails)
 659         if (item.ammo_nails)
 660         if (player.ammo_nails < g_pickup_nails_max)
 661                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 662         if (need_rockets)
 663         if (item.ammo_rockets)
 664         if (player.ammo_rockets < g_pickup_rockets_max)
 665                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 666         if (need_cells)
 667         if (item.ammo_cells)
 668         if (player.ammo_cells < g_pickup_cells_max)
 669                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 670         if (item.armorvalue)
 671         if (player.armorvalue < item.max_armorvalue)
 672                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 673         if (item.health)
 674         if (player.health < item.max_health)
 675                 c = c + max(0, 1 - player.health / item.max_health);
 676
 677         return item.bot_pickupbasevalue * c;
 678 };
 679
 680
 681 .float is_item;
 682 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 683 {
 684         startitem_failed = FALSE;
 685
 686         self.items = itemid;
 687         self.weapons = weaponid;
 688
 689         // is it a dropped weapon?
 690         if (self.classname == "droppedweapon")
 691         {
 692                 self.reset = SUB_Remove;
 693                 // it's a dropped weapon
 694                 self.movetype = MOVETYPE_TOSS;
 695                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 696                 self.think = RemoveItem;
 697                 self.nextthink = time + 60;
 698                 // don't drop if in a NODROP zone (such as lava)
 699                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 700                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 701                 {
 702                         startitem_failed = TRUE;
 703                         remove(self);
 704                         return;
 705                 }
 706         }
 707         else
 708         {
 709                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 710                 {
 711                         startitem_failed = TRUE;
 712                         remove(self);
 713                         return;
 714                 }
 715
 716                 self.reset = Item_Reset;
 717                 // it's a level item
 718                 if(self.spawnflags & 1)
 719                         self.noalign = 1;
 720                 if (self.noalign)
 721                         self.movetype = MOVETYPE_NONE;
 722                 else
 723                         self.movetype = MOVETYPE_TOSS;
 724                 // do item filtering according to game mode and other things
 725                 if (!self.noalign)
 726                 {
 727                         // first nudge it off the floor a little bit to avoid math errors
 728                         setorigin(self, self.origin + '0 0 1');
 729                         // set item size before we spawn a spawnfunc_waypoint
 730                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 731                                 setsize (self, '-16 -16 0', '16 16 48');
 732                         else
 733                                 setsize (self, '-16 -16 0', '16 16 32');
 734                         // note droptofloor returns FALSE if stuck/or would fall too far
 735                         droptofloor();
 736                         waypoint_spawnforitem(self);
 737                 }
 738
 739                 if(teams_matter)
 740                 {
 741                         if(self.notteam)
 742                         {
 743                                 print("removed non-teamplay ", self.classname, "\n");
 744                                 startitem_failed = TRUE;
 745                                 remove (self);
 746                                 return;
 747                         }
 748                 }
 749                 else
 750                 {
 751                         if(self.notfree)
 752                         {
 753                                 print("removed non-FFA ", self.classname, "\n");
 754                                 startitem_failed = TRUE;
 755                                 remove (self);
 756                                 return;
 757                         }
 758                 }
 759
 760                 if(self.notq3a)
 761                 {
 762                         // We aren't TA or something like that, so we keep the Q3A entities
 763                         print("removed non-Q3A ", self.classname, "\n");
 764                         startitem_failed = TRUE;
 765                         remove (self);
 766                         return;
 767                 }
 768
 769                 /*
 770                  * can't do it that way, as it would break maps
 771                  * TODO make a target_give like entity another way, that perhaps has
 772                  * the weapon name in a key
 773                 if(self.targetname)
 774                 {
 775                         // target_give not yet supported; maybe later
 776                         print("removed targeted ", self.classname, "\n");
 777                         startitem_failed = TRUE;
 778                         remove (self);
 779                         return;
 780                 }
 781                 */
 782
 783                 if(cvar("spawn_debug") >= 2)
 784                 {
 785                         entity otheritem;
 786                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 787                         {
 788                                 if(otheritem.is_item)
 789                                 {
 790                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 791                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 792                                         error("Mapper sucks.");
 793                                 }
 794                         }
 795                         self.is_item = TRUE;
 796                 }
 797
 798                 if(g_lms || g_ca)
 799                 {
 800                         startitem_failed = TRUE;
 801                         remove(self);
 802                         return;
 803                 }
 804                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 805                 {
 806                         startitem_failed = TRUE;
 807                         remove(self);
 808                         return;
 809                 }
 810                 else if (g_minstagib)
 811                 {
 812                         // don't remove dropped items and powerups
 813                         if (self.classname != "minstagib")
 814                         {
 815                                 startitem_failed = TRUE;
 816                                 remove (self);
 817                                 return;
 818                         }
 819                 }
 820                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 821                 {
 822                         startitem_failed = TRUE;
 823                         remove (self);
 824                         return;
 825                 }
 826
 827                 weaponsInMap |= weaponid;
 828
 829                 precache_model (itemmodel);
 830                 precache_sound (pickupsound);
 831                 precache_sound ("misc/itemrespawn.wav");
 832                 precache_sound ("misc/itemrespawncountdown.wav");
 833
 834                 if(itemid == IT_STRENGTH)
 835                         precache_sound ("misc/strength_respawn.wav");
 836                 if(itemid == IT_INVINCIBLE)
 837                         precache_sound ("misc/shield_respawn.wav");
 838
 839                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 840                         self.target = "###item###"; // for finding the nearest item using find()
 841         }
 842
 843         self.bot_pickup = TRUE;
 844         self.bot_pickupevalfunc = pickupevalfunc;
 845         self.bot_pickupbasevalue = pickupbasevalue;
 846         self.mdl = itemmodel;
 847         self.item_pickupsound = pickupsound;
 848         // let mappers override respawntime
 849         if(!self.respawntime) // both set
 850         {
 851                 self.respawntime = defaultrespawntime;
 852                 self.respawntimejitter = defaultrespawntimejitter;
 853         }
 854         self.netname = itemname;
 855         self.flags = FL_ITEM | itemflags;
 856         self.touch = Item_Touch;
 857         setmodel (self, self.mdl); // precision set below
 858         self.effects |= EF_LOWPRECISION;
 859         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 860                 setsize (self, '-16 -16 0', '16 16 48');
 861         else
 862                 setsize (self, '-16 -16 0', '16 16 32');
 863         if(itemflags & FL_WEAPON)
 864                 self.modelflags |= MF_ROTATE;
 865
 866         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 867         if (itemflags & FL_WEAPON)
 868         {
 869                 // neutral team color for pickup weapons
 870                 self.colormap = 1024; // color shirt=0 pants=0 grey
 871         }
 872
 873         Item_Show(self, 1);
 874         self.state = 0;
 875         if(self.team)
 876         {
 877                 if(!self.cnt)
 878                         self.cnt = 1; // item probability weight
 879                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 880                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 881         }
 882         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 883                 Item_ScheduleInitialRespawn(self);
 884 }
 885
 886 /* replace items in minstagib
 887  * IT_STRENGTH   = invisibility
 888  * IT_NAILS      = extra lives
 889  * IT_INVINCIBLE = speed
 890  */
 891 void minstagib_items (float itemid)
 892 {
 893         // we don't want to replace dropped weapons ;)
 894         if (self.classname == "droppedweapon")
 895         {
 896                 self.ammo_cells = 25;
 897                 StartItem ("models/weapons/g_nex.md3",
 898                         "weapons/weaponpickup.wav", 15, 0,
 899                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 900                 return;
 901         }
 902
 903         local float rnd;
 904         self.classname = "minstagib";
 905
 906         // replace rocket launchers and nex guns with ammo cells
 907         if (itemid == IT_CELLS)
 908         {
 909                 self.ammo_cells = 1;
 910                 StartItem ("models/items/a_cells.md3",
 911                         "misc/itempickup.wav", 45, 0,
 912                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 913                 return;
 914         }
 915
 916         // randomize
 917         rnd = random() * 3;
 918         if (rnd <= 1)
 919                 itemid = IT_STRENGTH;
 920         else if (rnd <= 2)
 921                 itemid = IT_NAILS;
 922         else
 923                 itemid = IT_INVINCIBLE;
 924
 925         // replace with invis
 926         if (itemid == IT_STRENGTH)
 927         {
 928                 self.strength_finished = 30;
 929                 StartItem ("models/items/g_strength.md3",
 930                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 931                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 932         }
 933         // replace with extra lives
 934         if (itemid == IT_NAILS)
 935         {
 936                 self.max_health = 1;
 937                 StartItem ("models/items/g_h100.md3",
 938                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 939                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 940         }
 941         // replace with speed
 942         if (itemid == IT_INVINCIBLE)
 943         {
 944                 self.invincible_finished = 30;
 945                 StartItem ("models/items/g_invincible.md3",
 946                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 947                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 948         }
 949 }
 950
 951 float minst_no_auto_cells;
 952 void minst_remove_item (void) {
 953         if(minst_no_auto_cells)
 954                 remove(self);
 955 }
 956
 957 float weaponswapping;
 958 float internalteam;
 959
 960 void weapon_defaultspawnfunc(float wpn)
 961 {
 962         entity e;
 963         float t;
 964         var .float ammofield;
 965         string s;
 966         entity oldself;
 967         float i, j;
 968
 969         // set the respawntime in advance (so replaced weapons can copy it)
 970
 971         if(!self.respawntime)
 972         {
 973                 e = get_weaponinfo(wpn);
 974                 if(e.items == IT_SUPERWEAPON)
 975                 {
 976                         self.respawntime = g_pickup_respawntime_powerup;
 977                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 978                 }
 979                 else
 980                 {
 981                         self.respawntime = g_pickup_respawntime_weapon;
 982                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 983                 }
 984         }
 985
 986         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 987         {
 988                 e = get_weaponinfo(wpn);
 989                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 990                 if(s == "0")
 991                 {
 992                         remove(self);
 993                         startitem_failed = TRUE;
 994                         return;
 995                 }
 996                 t = tokenize_console(s);
 997                 if(t >= 2)
 998                 {
 999                         self.team = --internalteam;
1000                         oldself = self;
1001                         for(i = 1; i < t; ++i)
1002                         {
1003                                 s = argv(i);
1004                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1005                                 {
1006                                         e = get_weaponinfo(j);
1007                                         if(e.netname == s)
1008                                         {
1009                                                 self = spawn();
1010                                                 copyentity(oldself, self);
1011                                                 self.classname = "replacedweapon";
1012                                                 weapon_defaultspawnfunc(j);
1013                                                 break;
1014                                         }
1015                                 }
1016                                 if(j > WEP_LAST)
1017                                 {
1018                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1019                                 }
1020                         }
1021                         self = oldself;
1022                 }
1023                 if(t >= 1)
1024                 {
1025                         s = argv(0);
1026                         wpn = 0;
1027                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1028                         {
1029                                 e = get_weaponinfo(j);
1030                                 if(e.netname == s)
1031                                 {
1032                                         wpn = j;
1033                                         break;
1034                                 }
1035                         }
1036                         if(j > WEP_LAST)
1037                         {
1038                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1039                         }
1040                 }
1041                 if(wpn == 0)
1042                 {
1043                         remove(self);
1044                         startitem_failed = TRUE;
1045                         return;
1046                 }
1047         }
1048
1049         e = get_weaponinfo(wpn);
1050
1051         if(e.items && e.items != IT_SUPERWEAPON)
1052         {
1053                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1054                 {
1055                         if(e.items & j)
1056                         {
1057                                 ammofield = Item_CounterField(j);
1058                                 if(!self.ammofield)
1059                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1060                         }
1061                 }
1062         }
1063         else
1064         {
1065                 self.flags |= FL_NO_WEAPON_STAY;
1066         }
1067
1068         // weapon stay isn't supported for teamed weapons
1069         if(self.team)
1070                 self.flags |= FL_NO_WEAPON_STAY;
1071
1072         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1073         {
1074                 self.ammo_shells = 0;
1075                 self.ammo_nails = 0;
1076                 self.ammo_cells = 0;
1077                 self.ammo_rockets = 0;
1078                 // weapon stay 2: don't use ammo on weapon pickups; instead
1079                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1080         }
1081
1082         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1083         if (self.modelindex) // don't precache if self was removed
1084                 weapon_action(e.weapon, WR_PRECACHE);
1085 }
1086
1087 void spawnfunc_weapon_shotgun (void);
1088 void spawnfunc_weapon_uzi (void) {
1089         if(q3acompat_machineshotgunswap)
1090         if(self.classname != "droppedweapon")
1091         {
1092                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1093                 return;
1094         }
1095         weapon_defaultspawnfunc(WEP_UZI);
1096 }
1097
1098 void spawnfunc_weapon_shotgun (void) {
1099         if(q3acompat_machineshotgunswap)
1100         if(self.classname != "droppedweapon")
1101         {
1102                 weapon_defaultspawnfunc(WEP_UZI);
1103                 return;
1104         }
1105         weapon_defaultspawnfunc(WEP_SHOTGUN);
1106 }
1107
1108 void spawnfunc_weapon_nex (void)
1109 {
1110         if (g_minstagib)
1111         {
1112                 minstagib_items(IT_CELLS);
1113                 self.think = minst_remove_item;
1114                 self.nextthink = time;
1115                 return;
1116         }
1117         weapon_defaultspawnfunc(WEP_NEX);
1118 }
1119
1120 void spawnfunc_weapon_minstanex (void)
1121 {
1122         if (g_minstagib)
1123         {
1124                 minstagib_items(IT_CELLS);
1125                 self.think = minst_remove_item;
1126                 self.nextthink = time;
1127                 return;
1128         }
1129         weapon_defaultspawnfunc(WEP_MINSTANEX);
1130 }
1131
1132 void spawnfunc_weapon_rocketlauncher (void)
1133 {
1134         if (g_minstagib)
1135         {
1136                 minstagib_items(IT_CELLS);
1137                 self.think = minst_remove_item;
1138                 self.nextthink = time;
1139                 return;
1140         }
1141         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1142 }
1143
1144 void spawnfunc_item_rockets (void) {
1145         if(!self.ammo_rockets)
1146                 self.ammo_rockets = g_pickup_rockets;
1147         if(!self.pickup_anyway)
1148                 self.pickup_anyway = g_pickup_ammo_anyway;
1149         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1150 }
1151
1152 void spawnfunc_item_shells (void);
1153 void spawnfunc_item_bullets (void) {
1154         if(!weaponswapping)
1155         if(q3acompat_machineshotgunswap)
1156         if(self.classname != "droppedweapon")
1157         {
1158                 weaponswapping = TRUE;
1159                 spawnfunc_item_shells();
1160                 weaponswapping = FALSE;
1161                 return;
1162         }
1163
1164         if(!self.ammo_nails)
1165                 self.ammo_nails = g_pickup_nails;
1166         if(!self.pickup_anyway)
1167                 self.pickup_anyway = g_pickup_ammo_anyway;
1168         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1169 }
1170
1171 void spawnfunc_item_cells (void) {
1172         if(!self.ammo_cells)
1173                 self.ammo_cells = g_pickup_cells;
1174         if(!self.pickup_anyway)
1175                 self.pickup_anyway = g_pickup_ammo_anyway;
1176         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1177 }
1178
1179 void spawnfunc_item_shells (void) {
1180         if(!weaponswapping)
1181         if(q3acompat_machineshotgunswap)
1182         if(self.classname != "droppedweapon")
1183         {
1184                 weaponswapping = TRUE;
1185                 spawnfunc_item_bullets();
1186                 weaponswapping = FALSE;
1187                 return;
1188         }
1189
1190         if(!self.ammo_shells)
1191                 self.ammo_shells = g_pickup_shells;
1192         if(!self.pickup_anyway)
1193                 self.pickup_anyway = g_pickup_ammo_anyway;
1194         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1195 }
1196
1197 void spawnfunc_item_armor_small (void) {
1198         if(!self.armorvalue)
1199                 self.armorvalue = g_pickup_armorsmall;
1200         if(!self.max_armorvalue)
1201                 self.max_armorvalue = g_pickup_armorsmall_max;
1202         if(!self.pickup_anyway)
1203                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1204         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1205 }
1206
1207 void spawnfunc_item_armor_medium (void) {
1208         if(!self.armorvalue)
1209                 self.armorvalue = g_pickup_armormedium;
1210         if(!self.max_armorvalue)
1211                 self.max_armorvalue = g_pickup_armormedium_max;
1212         if(!self.pickup_anyway)
1213                 self.pickup_anyway = g_pickup_armormedium_anyway;
1214         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1215 }
1216
1217 void spawnfunc_item_armor_big (void) {
1218         if(!self.armorvalue)
1219                 self.armorvalue = g_pickup_armorbig;
1220         if(!self.max_armorvalue)
1221                 self.max_armorvalue = g_pickup_armorbig_max;
1222         if(!self.pickup_anyway)
1223                 self.pickup_anyway = g_pickup_armorbig_anyway;
1224         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1225 }
1226
1227 void spawnfunc_item_armor_large (void) {
1228         if(!self.armorvalue)
1229                 self.armorvalue = g_pickup_armorlarge;
1230         if(!self.max_armorvalue)
1231                 self.max_armorvalue = g_pickup_armorlarge_max;
1232         if(!self.pickup_anyway)
1233                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1234         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1235 }
1236
1237 void spawnfunc_item_health_small (void) {
1238         if(!self.max_health)
1239                 self.max_health = g_pickup_healthsmall_max;
1240         if(!self.health)
1241                 self.health = g_pickup_healthsmall;
1242         if(!self.pickup_anyway)
1243                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1244         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1245 }
1246
1247 void spawnfunc_item_health_medium (void) {
1248         if(!self.max_health)
1249                 self.max_health = g_pickup_healthmedium_max;
1250         if(!self.health)
1251                 self.health = g_pickup_healthmedium;
1252         if(!self.pickup_anyway)
1253                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1254         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1255 }
1256
1257 void spawnfunc_item_health_large (void) {
1258         if(!self.max_health)
1259                 self.max_health = g_pickup_healthlarge_max;
1260         if(!self.health)
1261                 self.health = g_pickup_healthlarge;
1262         if(!self.pickup_anyway)
1263                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1264         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1265 }
1266
1267 void spawnfunc_item_health_mega (void) {
1268         if(!cvar("g_powerup_superhealth"))
1269                 return;
1270
1271         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1272                 return;
1273
1274         if(g_minstagib) {
1275                 minstagib_items(IT_NAILS);
1276         } else {
1277                 if(!self.max_health)
1278                         self.max_health = g_pickup_healthmega_max;
1279                 if(!self.health)
1280                         self.health = g_pickup_healthmega;
1281                 if(!self.pickup_anyway)
1282                         self.pickup_anyway = g_pickup_healthmega_anyway;
1283                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1284         }
1285 }
1286
1287 // support old misnamed entities
1288 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1289 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1290 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1291 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1292 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1293
1294 void spawnfunc_item_strength (void) {
1295         if(!cvar("g_powerup_strength"))
1296                 return;
1297
1298         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1299                 return;
1300
1301         if(g_minstagib) {
1302                 minstagib_items(IT_STRENGTH);
1303         } else {
1304                 precache_sound("weapons/strength_fire.wav");
1305                 self.strength_finished = 30;
1306                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1307         }
1308 }
1309
1310 void spawnfunc_item_invincible (void) {
1311         if(!cvar("g_powerup_shield"))
1312                 return;
1313
1314         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1315                 return;
1316
1317         if(g_minstagib) {
1318                 minstagib_items(IT_INVINCIBLE);
1319         } else {
1320                 self.invincible_finished = 30;
1321                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1322         }
1323 }
1324
1325 void spawnfunc_item_minst_cells (void) {
1326         if (g_minstagib)
1327         {
1328                 minst_no_auto_cells = 1;
1329                 minstagib_items(IT_CELLS);
1330         }
1331         else
1332                 remove(self);
1333 }
1334
1335 // compatibility:
1336 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1337
1338 float GiveItems(entity e, float beginarg, float endarg);
1339 void target_items_use (void)
1340 {
1341         if(activator.classname == "droppedweapon")
1342         {
1343                 EXACTTRIGGER_TOUCH;
1344                 remove(activator);
1345                 return;
1346         }
1347
1348         if(activator.classname != "player")
1349                 return;
1350         if(activator.deadflag != DEAD_NO)
1351                 return;
1352         EXACTTRIGGER_TOUCH;
1353
1354         entity e;
1355         for(e = world; (e = find(e, classname, "droppedweapon")); )
1356                 if(e.enemy == activator)
1357                         remove(e);
1358
1359         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1360                 centerprint(activator, self.message);
1361 }
1362
1363 void spawnfunc_target_items (void)
1364 {
1365         float n, i, j;
1366         entity e;
1367
1368         self.use = target_items_use;
1369         if(!self.strength_finished)
1370                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1371         if(!self.invincible_finished)
1372                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1373
1374         precache_sound("misc/itempickup.wav");
1375         precache_sound("misc/megahealth.wav");
1376         precache_sound("misc/armor25.wav");
1377         precache_sound("misc/powerup.wav");
1378         precache_sound("misc/poweroff.wav");
1379         precache_sound("weapons/weaponpickup.wav");
1380
1381         n = tokenize_console(self.netname);
1382         if(argv(0) == "give")
1383         {
1384                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1385         }
1386         else
1387         {
1388                 for(i = 0; i < n; ++i)
1389                 {
1390                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1391                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1392                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1393                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1394                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1395                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1396                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1397                         else
1398                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1399                         {
1400                                 e = get_weaponinfo(j);
1401                                 if(argv(i) == e.netname)
1402                                 {
1403                                         self.weapons |= e.weapons;
1404                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1405                                                 weapon_action(e.weapon, WR_PRECACHE);
1406                                         break;
1407                                 }
1408                         }
1409                         if(j > WEP_LAST)
1410                                 print("target_items: invalid item ", argv(i), "\n");
1411                 }
1412
1413                 string itemprefix, valueprefix;
1414                 if(self.spawnflags == 0)
1415                 {
1416                         itemprefix = "";
1417                         valueprefix = "";
1418                 }
1419                 else if(self.spawnflags == 1)
1420                 {
1421                         itemprefix = "max ";
1422                         valueprefix = "max ";
1423                 }
1424                 else if(self.spawnflags == 2)
1425                 {
1426                         itemprefix = "min ";
1427                         valueprefix = "min ";
1428                 }
1429                 else if(self.spawnflags == 4)
1430                 {
1431                         itemprefix = "minus ";
1432                         valueprefix = "max ";
1433                 }
1434                 else
1435                         error("invalid spawnflags");
1436
1437                 self.netname = "";
1438                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1439                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1440                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1441                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1442                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1443                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1444                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1445                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1446                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1447                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1448                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1449                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1450                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1451                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1452                 {
1453                         e = get_weaponinfo(j);
1454                         if(e.weapons)
1455                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1456                 }
1457         }
1458         self.netname = strzone(self.netname);
1459         //print(self.netname, "\n");
1460
1461         n = tokenize_console(self.netname);
1462         for(i = 0; i < n; ++i)
1463         {
1464                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1465                 {
1466                         e = get_weaponinfo(j);
1467                         if(argv(i) == e.netname)
1468                         {
1469                                 weapon_action(e.weapon, WR_PRECACHE);
1470                                 break;
1471                         }
1472                 }
1473         }
1474 }
1475
1476 void spawnfunc_item_fuel(void)
1477 {
1478         if(!self.ammo_fuel)
1479                 self.ammo_fuel = g_pickup_fuel;
1480         if(!self.pickup_anyway)
1481                 self.pickup_anyway = g_pickup_ammo_anyway;
1482         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1483 }
1484
1485 void spawnfunc_item_fuel_regen(void)
1486 {
1487         if(start_items & IT_FUEL_REGEN)
1488         {
1489                 spawnfunc_item_fuel();
1490                 return;
1491         }
1492         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1493 }
1494
1495 void spawnfunc_item_jetpack(void)
1496 {
1497         if(g_grappling_hook)
1498                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1499         if(!self.ammo_fuel)
1500                 self.ammo_fuel = g_pickup_fuel_jetpack;
1501         if(start_items & IT_JETPACK)
1502         {
1503                 spawnfunc_item_fuel();
1504                 return;
1505         }
1506         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1507 }
1508
1509
1510 #define OP_SET 0
1511 #define OP_MIN 1
1512 #define OP_MAX 2
1513 #define OP_PLUS 3
1514 #define OP_MINUS 4
1515
1516 float GiveBit(entity e, .float fld, float bit, float op, float val)
1517 {
1518         float v0, v1;
1519         v0 = (e.fld & bit);
1520         switch(op)
1521         {
1522                 case OP_SET:
1523                         if(val > 0)
1524                                 e.fld |= bit;
1525                         else
1526                                 e.fld &~= bit;
1527                         break;
1528                 case OP_MIN:
1529                 case OP_PLUS:
1530                         if(val > 0)
1531                                 e.fld |= bit;
1532                         break;
1533                 case OP_MAX:
1534                         if(val <= 0)
1535                                 e.fld &~= bit;
1536                         break;
1537                 case OP_MINUS:
1538                         if(val > 0)
1539                                 e.fld &~= bit;
1540                         break;
1541         }
1542         v1 = (e.fld & bit);
1543         return (v0 != v1);
1544 }
1545
1546 float GiveValue(entity e, .float fld, float op, float val)
1547 {
1548         float v0, v1;
1549         v0 = e.fld;
1550         switch(op)
1551         {
1552                 case OP_SET:
1553                         e.fld = val;
1554                         break;
1555                 case OP_MIN:
1556                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1557                         break;
1558                 case OP_MAX:
1559                         e.fld = min(e.fld, val);
1560                         break;
1561                 case OP_PLUS:
1562                         e.fld += val;
1563                         break;
1564                 case OP_MINUS:
1565                         e.fld -= val;
1566                         break;
1567         }
1568         v1 = e.fld;
1569         return (v0 != v1);
1570 }
1571
1572 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1573 {
1574         if(v1 == v0)
1575                 return;
1576         if(v1 <= v0 - t)
1577         {
1578                 if(snd_decr != "")
1579                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1580         }
1581         else if(v0 >= v0 + t)
1582         {
1583                 if(snd_incr != "")
1584                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1585         }
1586 }
1587
1588 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1589 {
1590         if(v0 < v1)
1591                 e.rotfield = max(e.rotfield, time + rottime);
1592         else if(v0 > v1)
1593                 e.regenfield = max(e.regenfield, time + regentime);
1594 }
1595
1596 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1597 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1598 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1599 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1600
1601 float GiveItems(entity e, float beginarg, float endarg)
1602 {
1603         float got, i, j, val, op;
1604         float _switchweapon;
1605         entity wi;
1606         string cmd;
1607
1608         val = 999;
1609         op = OP_SET;
1610
1611         got = 0;
1612
1613         _switchweapon = FALSE;
1614         if (e.autoswitch)
1615                 if (e.switchweapon == w_getbestweapon(e))
1616                         _switchweapon = TRUE;
1617
1618         e.strength_finished = max(0, e.strength_finished - time);
1619         e.invincible_finished = max(0, e.invincible_finished - time);
1620
1621         PREGIVE(e, items);
1622         PREGIVE(e, weapons);
1623         PREGIVE(e, strength_finished);
1624         PREGIVE(e, invincible_finished);
1625         PREGIVE(e, ammo_nails);
1626         PREGIVE(e, ammo_cells);
1627         PREGIVE(e, ammo_shells);
1628         PREGIVE(e, ammo_rockets);
1629         PREGIVE(e, ammo_fuel);
1630         PREGIVE(e, armorvalue);
1631         PREGIVE(e, health);
1632
1633         for(i = beginarg; i < endarg; ++i)
1634         {
1635                 cmd = argv(i);
1636
1637                 if(cmd == "0" || stof(cmd))
1638                 {
1639                         val = stof(cmd);
1640                         continue;
1641                 }
1642                 switch(cmd)
1643                 {
1644                         case "no":
1645                                 op = OP_MAX;
1646                                 val = 0;
1647                                 continue;
1648                         case "max":
1649                                 op = OP_MAX;
1650                                 continue;
1651                         case "min":
1652                                 op = OP_MIN;
1653                                 continue;
1654                         case "plus":
1655                                 op = OP_PLUS;
1656                                 continue;
1657                         case "minus":
1658                                 op = OP_MINUS;
1659                                 continue;
1660                         case "ALL":
1661                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1662                                 got += GiveValue(e, strength_finished, op, time);
1663                                 got += GiveValue(e, invincible_finished, op, time);
1664                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1665                         case "all":
1666                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1667                                 got += GiveValue(e, health, op, val);
1668                                 got += GiveValue(e, armorvalue, op, val);
1669                         case "allweapons":
1670                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1671                                 {
1672                                         wi = get_weaponinfo(j);
1673                                         if(wi.weapons)
1674                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1675                                 }
1676                         case "allammo":
1677                                 got += GiveValue(e, ammo_cells, op, val);
1678                                 got += GiveValue(e, ammo_shells, op, val);
1679                                 got += GiveValue(e, ammo_nails, op, val);
1680                                 got += GiveValue(e, ammo_rockets, op, val);
1681                                 got += GiveValue(e, ammo_fuel, op, val);
1682                                 break;
1683                         case "unlimited_ammo":
1684                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1685                                 break;
1686                         case "unlimited_weapon_ammo":
1687                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1688                                 break;
1689                         case "unlimited_superweapons":
1690                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1691                                 break;
1692                         case "jetpack":
1693                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1694                                 break;
1695                         case "fuel_regen":
1696                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1697                                 break;
1698                         case "strength":
1699                                 got += GiveValue(e, strength_finished, op, val);
1700                                 break;
1701                         case "invincible":
1702                                 got += GiveValue(e, invincible_finished, op, val);
1703                                 break;
1704                         case "cells":
1705                                 got += GiveValue(e, ammo_cells, op, val);
1706                                 break;
1707                         case "shells":
1708                                 got += GiveValue(e, ammo_shells, op, val);
1709                                 break;
1710                         case "nails":
1711                         case "bullets":
1712                                 got += GiveValue(e, ammo_nails, op, val);
1713                                 break;
1714                         case "rockets":
1715                                 got += GiveValue(e, ammo_rockets, op, val);
1716                                 break;
1717                         case "health":
1718                                 got += GiveValue(e, health, op, val);
1719                                 break;
1720                         case "armor":
1721                                 got += GiveValue(e, armorvalue, op, val);
1722                                 break;
1723                         case "fuel":
1724                                 got += GiveValue(e, ammo_fuel, op, val);
1725                                 break;
1726                         default:
1727                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1728                                 {
1729                                         wi = get_weaponinfo(j);
1730                                         if(cmd == wi.netname)
1731                                         {
1732                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1733                                                 break;
1734                                         }
1735                                 }
1736                                 if(j > WEP_LAST)
1737                                         print("give: invalid item ", cmd, "\n");
1738                                 break;
1739                 }
1740                 val = 999;
1741                 op = OP_SET;
1742         }
1743
1744         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1745         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1746         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1747         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1748         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1749         {
1750                 wi = get_weaponinfo(j);
1751                 if(wi.weapons)
1752                 {
1753                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1754                         if not(save_weapons & wi.weapons)
1755                                 if(e.weapons & wi.weapons)
1756                                         weapon_action(wi.weapon, WR_PRECACHE);
1757                 }
1758         }
1759         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1760         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1761         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1762         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1763         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1764         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1765         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1766         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1767         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1768
1769         if(e.strength_finished <= 0)
1770                 e.strength_finished = 0;
1771         else
1772                 e.strength_finished += time;
1773         if(e.invincible_finished <= 0)
1774                 e.invincible_finished = 0;
1775         else
1776                 e.invincible_finished += time;
1777
1778         if not(e.weapons & W_WeaponBit(e.switchweapon))
1779                 _switchweapon = TRUE;
1780         if(_switchweapon)
1781                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1782
1783         return got;
1784 }