d9c3240603852704483caeea7b341d8195221120
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / t_items.qc
1 #define ITEM_RESPAWN_TICKS 10
2
3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
6         // range: 10 .. respawntime + respawntimejitter
7
8 floatfield Item_CounterField(float it)
9 {
10         switch(it)
11         {
12                 case IT_SHELLS:      return ammo_shells;
13                 case IT_NAILS:       return ammo_nails;
14                 case IT_ROCKETS:     return ammo_rockets;
15                 case IT_CELLS:       return ammo_cells;
16                 case IT_FUEL:        return ammo_fuel;
17                 case IT_5HP:         return health;
18                 case IT_25HP:        return health;
19                 case IT_HEALTH:      return health;
20                 case IT_ARMOR_SHARD: return armorvalue;
21                 case IT_ARMOR:       return armorvalue;
22                 // add more things here (health, armor)
23                 default:             error("requested item has no counter field");
24         }
25 }
26
27 string Item_CounterFieldName(float it)
28 {
29         switch(it)
30         {
31                 case IT_SHELLS:      return "shells";
32                 case IT_NAILS:       return "nails";
33                 case IT_ROCKETS:     return "rockets";
34                 case IT_CELLS:       return "cells";
35                 case IT_FUEL:        return "fuel";
36
37                 // add more things here (health, armor)
38                 default:             error("requested item has no counter field name");
39         }
40 }
41
42 .float max_armorvalue;
43
44 float Item_Customize()
45 {
46         if(self.spawnshieldtime)
47                 return TRUE;
48         if(self.weapons != (self.weapons & other.weapons))
49         {
50                 self.colormod = '0 0 0';
51                 self.glowmod = self.colormod;
52                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
53                 return TRUE;
54         }
55         else
56         {
57                 if(g_ghost_items)
58                 {
59                         self.colormod = stov(cvar_string("g_ghost_items_color"));
60                         self.glowmod = self.colormod;
61                         self.alpha = g_ghost_items;
62                         return TRUE;
63                 }
64                 else
65                         return FALSE;
66         }
67 }
68
69 void Item_Show (entity e, float mode)
70 {
71         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
72         if (mode > 0)
73         {
74                 // make the item look normal, and be touchable
75                 e.model = e.mdl;
76                 e.solid = SOLID_TRIGGER;
77                 e.colormod = '0 0 0';
78                 self.glowmod = self.colormod;
79                 e.alpha = 0;
80                 e.customizeentityforclient = func_null;
81
82                 e.spawnshieldtime = 1;
83         }
84         else if (mode < 0)
85         {
86                 // hide the item completely
87                 e.model = string_null;
88                 e.solid = SOLID_NOT;
89                 e.colormod = '0 0 0';
90                 self.glowmod = self.colormod;
91                 e.alpha = 0;
92                 e.customizeentityforclient = func_null;
93
94                 e.spawnshieldtime = 1;
95         }
96         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
97         {
98                 // make the item translucent green and not touchable
99                 e.model = e.mdl;
100                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
101                 e.colormod = '0 0 0';
102                 self.glowmod = self.colormod;
103                 e.effects |= EF_STARDUST;
104                 e.customizeentityforclient = Item_Customize;
105
106                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
107         }
108         else if(g_ghost_items)
109         {
110                 // make the item translucent green and not touchable
111                 e.model = e.mdl;
112                 e.solid = SOLID_NOT;
113                 e.colormod = stov(cvar_string("g_ghost_items_color"));
114                 self.glowmod = self.colormod;
115                 e.alpha = g_ghost_items;
116                 e.customizeentityforclient = func_null;
117
118                 e.spawnshieldtime = 1;
119         }
120         else
121         {
122                 // hide the item completely
123                 e.model = string_null;
124                 e.solid = SOLID_NOT;
125                 e.colormod = stov(cvar_string("g_ghost_items_color"));
126                 self.glowmod = self.colormod;
127                 e.alpha = 0;
128                 e.customizeentityforclient = func_null;
129
130                 e.spawnshieldtime = 1;
131         }
132
133         if (e.strength_finished || e.invincible_finished)
134                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
135         if (cvar("g_nodepthtestitems"))
136                 e.effects |= EF_NODEPTHTEST;
137         if (cvar("g_fullbrightitems"))
138                 e.effects |= EF_FULLBRIGHT;
139
140         // relink entity (because solid may have changed)
141         setorigin(e, e.origin);
142 }
143
144 void Item_Respawn (void)
145 {
146         Item_Show(self, 1);
147         if(!g_minstagib && self.items == IT_STRENGTH)
148                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
149         else if(!g_minstagib && self.items == IT_INVINCIBLE)
150                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
151         else
152                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
153         setorigin (self, self.origin);
154
155         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
156         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
157 }
158
159 void Item_RespawnCountdown (void)
160 {
161         if(self.count >= ITEM_RESPAWN_TICKS)
162         {
163                 if(self.waypointsprite_attached)
164                         WaypointSprite_Kill(self.waypointsprite_attached);
165                 Item_Respawn();
166         }
167         else
168         {
169                 self.nextthink = time + 1;
170                 self.count += 1;
171                 if(self.count == 1)
172                 {
173                         string name;
174                         vector rgb;
175                         name = string_null;
176                         if(g_minstagib)
177                         {
178                                 switch(self.items)
179                                 {
180                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
181                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
182                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
183                                 }
184                         }
185                         else
186                         {
187                                 switch(self.items)
188                                 {
189                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
190                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
191                                 }
192                         }
193                         switch(self.items)
194                         {
195                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
196                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
197                         }
198                         if(name)
199                         {
200                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
201                                 if(self.waypointsprite_attached)
202                                 {
203                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
204                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
205                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
206                                 }
207                         }
208                 }
209                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
210                 if(self.waypointsprite_attached)
211                 {
212                         WaypointSprite_Ping(self.waypointsprite_attached);
213                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
214                 }
215         }
216 }
217
218 void Item_ScheduleRespawnIn(entity e, float t)
219 {
220         if(e.flags & FL_POWERUP)
221         {
222                 e.think = Item_RespawnCountdown;
223                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
224                 e.count = 0;
225         }
226         else
227         {
228                 e.think = Item_Respawn;
229                 e.nextthink = time + t;
230         }
231 }
232
233 void Item_ScheduleRespawn(entity e)
234 {
235         Item_Show(e, 0);
236         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
237 }
238
239 void Item_ScheduleInitialRespawn(entity e)
240 {
241         Item_Show(e, 0);
242         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
243 }
244
245 float Item_GiveTo(entity item, entity player)
246 {
247         float _switchweapon;
248         float pickedup;
249         float it;
250         float i;
251         entity e;
252
253         // if nothing happens to player, just return without taking the item
254         pickedup = FALSE;
255         _switchweapon = FALSE;
256
257         if (g_minstagib)
258         {
259                 if(item.spawnshieldtime)
260                 {
261                         if (item.ammo_fuel)
262                         if (player.ammo_fuel < g_pickup_fuel_max)
263                         {
264                                 pickedup = TRUE;
265                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
266                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
267                         }
268                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
269                         {
270                                 pickedup = TRUE;
271                                 player.items |= it;
272                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
273                         }
274
275                         _switchweapon = TRUE;
276                         if (item.ammo_cells)
277                         {
278                                 pickedup = TRUE;
279                                 // play some cool sounds ;)
280                                 centerprint(player, "\n");
281                                 if (clienttype(player) == CLIENTTYPE_REAL)
282                                 {
283                                         if(player.health <= 5)
284                                                 AnnounceTo(player, "lastsecond");
285                                         else if(player.health < 50)
286                                                 AnnounceTo(player, "narrowly");
287                                 }
288                                 // sound not available
289                                 // else if(item.items == IT_CELLS)
290                                 //      AnnounceTo(player, "ammo");
291
292                                 if (item.weapons & WEPBIT_MINSTANEX)
293                                         W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
294                                 if (item.ammo_cells)
295                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
296                                 player.health = 100;
297                         }
298
299                         // extralife powerup
300                         if (item.max_health)
301                         {
302                                 pickedup = TRUE;
303                                 // sound not available
304                                 // AnnounceTo(player, "_lives");
305                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
306                                 sprint(player, "^3You picked up some extra lives\n");
307                         }
308
309                         // invis powerup
310                         if (item.strength_finished)
311                         {
312                                 pickedup = TRUE;
313                                 // sound not available
314                                 // AnnounceTo(player, "invisible");
315                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
316                         }
317
318                         // speed powerup
319                         if (item.invincible_finished)
320                         {
321                                 pickedup = TRUE;
322                                 // sound not available
323                                 // AnnounceTo(player, "speed");
324                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
325                         }
326
327                         if (item.ammo_fuel)
328                         if (player.ammo_fuel < g_pickup_fuel_max)
329                         {
330                                 pickedup = TRUE;
331                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
332                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
333                         }
334                 }
335         }
336         else
337         {
338                 if (g_weapon_stay == 1)
339                 if not(item.flags & FL_NO_WEAPON_STAY)
340                 if (item.flags & FL_WEAPON)
341                 {
342                         if(item.classname == "droppedweapon")
343                         {
344                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
345                                         goto skip;
346                         }
347                         else
348                         {
349                                 if (player.weapons & item.weapons)
350                                         goto skip;
351                         }
352                 }
353
354                 // in case the player has autoswitch enabled do the following:
355                 // if the player is using their best weapon before items are given, they
356                 // probably want to switch to an even better weapon after items are given
357                 if (player.autoswitch)
358                 if (player.switchweapon == w_getbestweapon(player))
359                         _switchweapon = TRUE;
360
361                 if not(player.weapons & W_WeaponBit(player.switchweapon))
362                         _switchweapon = TRUE;
363
364                 if(item.spawnshieldtime)
365                 {
366                         if (item.ammo_shells)
367                         if (player.ammo_shells < g_pickup_shells_max)
368                         {
369                                 pickedup = TRUE;
370                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
371                         }
372                         if (item.ammo_nails)
373                         if (player.ammo_nails < g_pickup_nails_max)
374                         {
375                                 pickedup = TRUE;
376                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
377                         }
378                         if (item.ammo_rockets)
379                         if (player.ammo_rockets < g_pickup_rockets_max)
380                         {
381                                 pickedup = TRUE;
382                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
383                         }
384                         if (item.ammo_cells)
385                         if (player.ammo_cells < g_pickup_cells_max)
386                         {
387                                 pickedup = TRUE;
388                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
389                         }
390                         if (item.ammo_fuel)
391                         if (player.ammo_fuel < g_pickup_fuel_max)
392                         {
393                                 pickedup = TRUE;
394                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
395                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
396                         }
397                 }
398
399                 if (item.flags & FL_WEAPON)
400                 if ((it = item.weapons - (item.weapons & player.weapons)))
401                 {
402                         pickedup = TRUE;
403                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
404                         {
405                                 e = get_weaponinfo(i);
406                                 if(it & e.weapons)
407                                         W_GiveWeapon (player, e.weapon, item.netname);
408                         }
409                 }
410
411                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
412                 {
413                         pickedup = TRUE;
414                         player.items |= it;
415                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
416                 }
417
418                 if(item.spawnshieldtime)
419                 {
420                         if (item.strength_finished)
421                         {
422                                 pickedup = TRUE;
423                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
424                         }
425                         if (item.invincible_finished)
426                         {
427                                 pickedup = TRUE;
428                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
429                         }
430
431                         if (item.health)
432                         if (player.health < item.max_health)
433                         {
434                                 pickedup = TRUE;
435                                 player.health = min(player.health + item.health, item.max_health);
436                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
437                         }
438                         if (item.armorvalue)
439                         if (player.armorvalue < item.max_armorvalue)
440                         {
441                                 pickedup = TRUE;
442                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
443                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
444                         }
445                 }
446         }
447
448 :skip
449         // always eat teamed entities
450         if(item.team)
451                 pickedup = TRUE;
452
453         if (!pickedup)
454                 return 0;
455
456         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
457         if (_switchweapon)
458                 if (player.switchweapon != w_getbestweapon(player))
459                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
460
461         return 1;
462 }
463
464 void Item_Touch (void)
465 {
466         entity e, head;
467
468         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
469         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
470         {
471                 remove(self);
472                 return;
473         }
474         if (other.classname != "player")
475                 return;
476         if (other.deadflag)
477                 return;
478         if (self.solid != SOLID_TRIGGER)
479                 return;
480         if (self.owner == other)
481                 return;
482
483         if(!Item_GiveTo(self, other))
484                 return;
485
486         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
487
488         if (self.classname == "droppedweapon")
489                 remove (self);
490         else if not(self.spawnshieldtime)
491                 return;
492         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
493                 return;
494         else
495         {
496                 if(self.team)
497                 {
498                         RandomSelection_Init();
499                         for(head = world; (head = findfloat(head, team, self.team)); )
500                         {
501                                 if(head.flags & FL_ITEM)
502                                 {
503                                         Item_Show(head, -1);
504                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
505                                 }
506                         }
507                         e = RandomSelection_chosen_ent;
508                 }
509                 else
510                         e = self;
511                 Item_ScheduleRespawn(e);
512         }
513 }
514
515 void Item_FindTeam()
516 {
517         entity head, e;
518
519         if(self.effects & EF_NODRAW)
520         {
521                 // marker for item team search
522                 dprint("Initializing item team ", ftos(self.team), "\n");
523                 RandomSelection_Init();
524                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
525                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
526                 e = RandomSelection_chosen_ent;
527                 e.state = 0;
528                 Item_Show(e, 1);
529
530                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
531                 {
532                         if(head != e)
533                         {
534                                 // make it a non-spawned item
535                                 Item_Show(head, -1);
536                                 head.state = 1; // state 1 = initially hidden item
537                         }
538                         head.effects &~= EF_NODRAW;
539                 }
540
541                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
542                         Item_ScheduleInitialRespawn(e);
543         }
544 }
545
546 void Item_Reset()
547 {
548         Item_Show(self, !self.state);
549         setorigin (self, self.origin);
550         self.think = SUB_Null;
551         self.nextthink = 0;
552
553         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
554                 Item_ScheduleInitialRespawn(self);
555 }
556
557 // Savage: used for item garbage-collection
558 // TODO: perhaps nice special effect?
559 void RemoveItem(void)
560 {
561         remove(self);
562 }
563
564 // pickup evaluation functions
565 // these functions decide how desirable an item is to the bots
566
567 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
568
569 float weapon_pickupevalfunc(entity player, entity item)
570 {
571         float c, i, j, position;
572
573         // See if I have it already
574         if(player.weapons & item.weapons == item.weapons)
575         {
576                 // If I can pick it up
577                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
578                         c = 0;
579                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
580                 {
581                         // Skilled bots will grab more
582                         c = bound(0, skill / 10, 1) * 0.5;
583                 }
584                 else
585                         c = 0;
586         }
587         else
588                 c = 1;
589
590         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
591         if( bot_custom_weapon && c )
592         {
593                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
594                 {
595                         // Find weapon
596                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
597                                 continue;
598
599                         // Find the highest position on any range
600                         position = -1;
601                         for(j = 0; j < WEP_LAST ; ++j){
602                                 if(
603                                                 bot_weapons_far[j] == i ||
604                                                 bot_weapons_mid[j] == i ||
605                                                 bot_weapons_close[j] == i
606                                   )
607                                 {
608                                         position = j;
609                                         break;
610                                 }
611                         }
612
613                         // Rate it
614                         if (position >= 0 )
615                         {
616                                 position = WEP_LAST - position;
617                                 // item.bot_pickupbasevalue is overwritten here
618                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
619                         }
620                 }
621         }
622
623         return item.bot_pickupbasevalue * c;
624 };
625
626 float commodity_pickupevalfunc(entity player, entity item)
627 {
628         float c, i, need_shells, need_nails, need_rockets, need_cells;
629         entity wi;
630         c = 0;
631
632         // Detect needed ammo
633         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
634         {
635                 wi = get_weaponinfo(i);
636
637                 if not(wi.weapons & player.weapons)
638                         continue;
639
640                 if(wi.items & IT_SHELLS)
641                         need_shells = TRUE;
642                 else if(wi.items & IT_NAILS)
643                         need_nails = TRUE;
644                 else if(wi.items & IT_ROCKETS)
645                         need_rockets = TRUE;
646                 else if(wi.items & IT_CELLS)
647                         need_cells = TRUE;
648         }
649
650         // TODO: figure out if the player even has the weapon this ammo is for?
651         // may not affect strategy much though...
652         // find out how much more ammo/armor/health the player can hold
653         if (need_shells)
654         if (item.ammo_shells)
655         if (player.ammo_shells < g_pickup_shells_max)
656                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
657         if (need_nails)
658         if (item.ammo_nails)
659         if (player.ammo_nails < g_pickup_nails_max)
660                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
661         if (need_rockets)
662         if (item.ammo_rockets)
663         if (player.ammo_rockets < g_pickup_rockets_max)
664                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
665         if (need_cells)
666         if (item.ammo_cells)
667         if (player.ammo_cells < g_pickup_cells_max)
668                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
669         if (item.armorvalue)
670         if (player.armorvalue < item.max_armorvalue)
671                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
672         if (item.health)
673         if (player.health < item.max_health)
674                 c = c + max(0, 1 - player.health / item.max_health);
675
676         return item.bot_pickupbasevalue * c;
677 };
678
679
680 .float is_item;
681 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
682 {
683         startitem_failed = FALSE;
684
685         self.items = itemid;
686         self.weapons = weaponid;
687
688         // is it a dropped weapon?
689         if (self.classname == "droppedweapon")
690         {
691                 self.reset = SUB_Remove;
692                 // it's a dropped weapon
693                 self.movetype = MOVETYPE_TOSS;
694                 // Savage: remove thrown items after a certain period of time ("garbage collection")
695                 self.think = RemoveItem;
696                 self.nextthink = time + 60;
697                 // don't drop if in a NODROP zone (such as lava)
698                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
699                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
700                 {
701                         startitem_failed = TRUE;
702                         remove(self);
703                         return;
704                 }
705         }
706         else
707         {
708                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
709                 {
710                         startitem_failed = TRUE;
711                         remove(self);
712                         return;
713                 }
714
715                 itemid = self.items;
716                 weaponid = self.weapons;
717
718                 self.reset = Item_Reset;
719                 // it's a level item
720                 if(self.spawnflags & 1)
721                         self.noalign = 1;
722                 if (self.noalign)
723                         self.movetype = MOVETYPE_NONE;
724                 else
725                         self.movetype = MOVETYPE_TOSS;
726                 // do item filtering according to game mode and other things
727                 if (!self.noalign)
728                 {
729                         // first nudge it off the floor a little bit to avoid math errors
730                         setorigin(self, self.origin + '0 0 1');
731                         // set item size before we spawn a spawnfunc_waypoint
732                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
733                                 setsize (self, '-16 -16 0', '16 16 48');
734                         else
735                                 setsize (self, '-16 -16 0', '16 16 32');
736                         // note droptofloor returns FALSE if stuck/or would fall too far
737                         droptofloor();
738                         waypoint_spawnforitem(self);
739                 }
740
741                 if(teams_matter)
742                 {
743                         if(self.notteam)
744                         {
745                                 print("removed non-teamplay ", self.classname, "\n");
746                                 startitem_failed = TRUE;
747                                 remove (self);
748                                 return;
749                         }
750                 }
751                 else
752                 {
753                         if(self.notfree)
754                         {
755                                 print("removed non-FFA ", self.classname, "\n");
756                                 startitem_failed = TRUE;
757                                 remove (self);
758                                 return;
759                         }
760                 }
761
762                 if(self.notq3a)
763                 {
764                         // We aren't TA or something like that, so we keep the Q3A entities
765                         print("removed non-Q3A ", self.classname, "\n");
766                         startitem_failed = TRUE;
767                         remove (self);
768                         return;
769                 }
770
771                 /*
772                  * can't do it that way, as it would break maps
773                  * TODO make a target_give like entity another way, that perhaps has
774                  * the weapon name in a key
775                 if(self.targetname)
776                 {
777                         // target_give not yet supported; maybe later
778                         print("removed targeted ", self.classname, "\n");
779                         startitem_failed = TRUE;
780                         remove (self);
781                         return;
782                 }
783                 */
784
785                 if(cvar("spawn_debug") >= 2)
786                 {
787                         entity otheritem;
788                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
789                         {
790                                 if(otheritem.is_item)
791                                 {
792                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
793                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
794                                         error("Mapper sucks.");
795                                 }
796                         }
797                         self.is_item = TRUE;
798                 }
799
800                 weaponsInMap |= weaponid;
801
802                 if(g_lms || g_ca)
803                 {
804                         startitem_failed = TRUE;
805                         remove(self);
806                         return;
807                 }
808                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
809                 {
810                         startitem_failed = TRUE;
811                         remove(self);
812                         return;
813                 }
814                 else if (g_minstagib)
815                 {
816                         // don't remove dropped items and powerups
817                         if (self.classname != "minstagib")
818                         {
819                                 startitem_failed = TRUE;
820                                 remove (self);
821                                 return;
822                         }
823                 }
824                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
825                 {
826                         startitem_failed = TRUE;
827                         remove (self);
828                         return;
829                 }
830
831                 precache_model (itemmodel);
832                 precache_sound (pickupsound);
833                 precache_sound ("misc/itemrespawn.wav");
834                 precache_sound ("misc/itemrespawncountdown.wav");
835
836                 if(itemid == IT_STRENGTH)
837                         precache_sound ("misc/strength_respawn.wav");
838                 if(itemid == IT_INVINCIBLE)
839                         precache_sound ("misc/shield_respawn.wav");
840
841                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
842                         self.target = "###item###"; // for finding the nearest item using find()
843         }
844
845         self.bot_pickup = TRUE;
846         self.bot_pickupevalfunc = pickupevalfunc;
847         self.bot_pickupbasevalue = pickupbasevalue;
848         self.mdl = itemmodel;
849         self.item_pickupsound = pickupsound;
850         // let mappers override respawntime
851         if(!self.respawntime) // both set
852         {
853                 self.respawntime = defaultrespawntime;
854                 self.respawntimejitter = defaultrespawntimejitter;
855         }
856         self.netname = itemname;
857         self.flags = FL_ITEM | itemflags;
858         self.touch = Item_Touch;
859         setmodel (self, self.mdl); // precision set below
860         self.effects |= EF_LOWPRECISION;
861         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
862                 setsize (self, '-16 -16 0', '16 16 48');
863         else
864                 setsize (self, '-16 -16 0', '16 16 32');
865         if(itemflags & FL_WEAPON)
866                 self.modelflags |= MF_ROTATE;
867
868         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
869         if (itemflags & FL_WEAPON)
870         {
871                 // neutral team color for pickup weapons
872                 self.colormap = 1024; // color shirt=0 pants=0 grey
873         }
874
875         Item_Show(self, 1);
876         self.state = 0;
877         if(self.team)
878         {
879                 if(!self.cnt)
880                         self.cnt = 1; // item probability weight
881                 self.effects = self.effects | EF_NODRAW; // marker for item team search
882                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
883         }
884         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
885                 Item_ScheduleInitialRespawn(self);
886 }
887
888 /* replace items in minstagib
889  * IT_STRENGTH   = invisibility
890  * IT_NAILS      = extra lives
891  * IT_INVINCIBLE = speed
892  */
893 void minstagib_items (float itemid)
894 {
895         // we don't want to replace dropped weapons ;)
896         if (self.classname == "droppedweapon")
897         {
898                 self.ammo_cells = 25;
899                 StartItem ("models/weapons/g_nex.md3",
900                         "weapons/weaponpickup.wav", 15, 0,
901                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
902                 return;
903         }
904
905         local float rnd;
906         self.classname = "minstagib";
907
908         // replace rocket launchers and nex guns with ammo cells
909         if (itemid == IT_CELLS)
910         {
911                 self.ammo_cells = 1;
912                 StartItem ("models/items/a_cells.md3",
913                         "misc/itempickup.wav", 45, 0,
914                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
915                 return;
916         }
917
918         // randomize
919         rnd = random() * 3;
920         if (rnd <= 1)
921                 itemid = IT_STRENGTH;
922         else if (rnd <= 2)
923                 itemid = IT_NAILS;
924         else
925                 itemid = IT_INVINCIBLE;
926
927         // replace with invis
928         if (itemid == IT_STRENGTH)
929         {
930                 self.strength_finished = 30;
931                 StartItem ("models/items/g_strength.md3",
932                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
933                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
934         }
935         // replace with extra lives
936         if (itemid == IT_NAILS)
937         {
938                 self.max_health = 1;
939                 StartItem ("models/items/g_h100.md3",
940                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
941                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
942
943         }
944         // replace with speed
945         if (itemid == IT_INVINCIBLE)
946         {
947                 self.invincible_finished = 30;
948                 StartItem ("models/items/g_invincible.md3",
949                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
950                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
951         }
952
953 }
954
955 float minst_no_auto_cells;
956 void minst_remove_item (void) {
957         if(minst_no_auto_cells)
958                 remove(self);
959 }
960
961 float weaponswapping;
962 float internalteam;
963
964 void weapon_defaultspawnfunc(float wpn)
965 {
966         entity e;
967         float t;
968         var .float ammofield;
969         string s;
970         entity oldself;
971         float i, j;
972
973         // set the respawntime in advance (so replaced weapons can copy it)
974
975         if(!self.respawntime)
976         {
977                 e = get_weaponinfo(wpn);
978                 if(e.items == IT_SUPERWEAPON)
979                 {
980                         self.respawntime = g_pickup_respawntime_powerup;
981                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
982                 }
983                 else
984                 {
985                         self.respawntime = g_pickup_respawntime_weapon;
986                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
987                 }
988         }
989
990         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
991         {
992                 e = get_weaponinfo(wpn);
993                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
994                 if(s == "0")
995                 {
996                         remove(self);
997                         startitem_failed = TRUE;
998                         return;
999                 }
1000                 t = tokenize_console(s);
1001                 if(t >= 2)
1002                 {
1003                         self.team = --internalteam;
1004                         oldself = self;
1005                         for(i = 1; i < t; ++i)
1006                         {
1007                                 s = argv(i);
1008                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1009                                 {
1010                                         e = get_weaponinfo(j);
1011                                         if(e.netname == s)
1012                                         {
1013                                                 self = spawn();
1014                                                 copyentity(oldself, self);
1015                                                 self.classname = "replacedweapon";
1016                                                 weapon_defaultspawnfunc(j);
1017                                                 break;
1018                                         }
1019                                 }
1020                                 if(j > WEP_LAST)
1021                                 {
1022                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1023                                 }
1024                         }
1025                         self = oldself;
1026                 }
1027                 if(t >= 1)
1028                 {
1029                         s = argv(0);
1030                         wpn = 0;
1031                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1032                         {
1033                                 e = get_weaponinfo(j);
1034                                 if(e.netname == s)
1035                                 {
1036                                         wpn = j;
1037                                         break;
1038                                 }
1039                         }
1040                         if(j > WEP_LAST)
1041                         {
1042                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1043                         }
1044                 }
1045                 if(wpn == 0)
1046                 {
1047                         remove(self);
1048                         startitem_failed = TRUE;
1049                         return;
1050                 }
1051         }
1052
1053         e = get_weaponinfo(wpn);
1054
1055         if(e.items && e.items != IT_SUPERWEAPON)
1056         {
1057                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1058                 {
1059                         if(e.items & j)
1060                         {
1061                                 ammofield = Item_CounterField(j);
1062                                 if(!self.ammofield)
1063                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1064                         }
1065                 }
1066         }
1067         else
1068         {
1069                 self.flags |= FL_NO_WEAPON_STAY;
1070         }
1071
1072         // weapon stay isn't supported for teamed weapons
1073         if(self.team)
1074                 self.flags |= FL_NO_WEAPON_STAY;
1075
1076         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1077         {
1078                 self.ammo_shells = 0;
1079                 self.ammo_nails = 0;
1080                 self.ammo_cells = 0;
1081                 self.ammo_rockets = 0;
1082                 // weapon stay 2: don't use ammo on weapon pickups; instead
1083                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1084         }
1085
1086         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1087         if (self.modelindex) // don't precache if self was removed
1088                 weapon_action(e.weapon, WR_PRECACHE);
1089 }
1090
1091 void spawnfunc_weapon_shotgun (void);
1092 void spawnfunc_weapon_uzi (void) {
1093         if(q3acompat_machineshotgunswap)
1094         if(self.classname != "droppedweapon")
1095         {
1096                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1097                 return;
1098         }
1099         weapon_defaultspawnfunc(WEP_UZI);
1100 }
1101
1102 void spawnfunc_weapon_shotgun (void) {
1103         if(q3acompat_machineshotgunswap)
1104         if(self.classname != "droppedweapon")
1105         {
1106                 weapon_defaultspawnfunc(WEP_UZI);
1107                 return;
1108         }
1109         weapon_defaultspawnfunc(WEP_SHOTGUN);
1110 }
1111
1112 void spawnfunc_weapon_nex (void)
1113 {
1114         if (g_minstagib)
1115         {
1116                 minstagib_items(IT_CELLS);
1117                 self.think = minst_remove_item;
1118                 self.nextthink = time;
1119                 return;
1120         }
1121         weapon_defaultspawnfunc(WEP_NEX);
1122 }
1123
1124 void spawnfunc_weapon_minstanex (void)
1125 {
1126         if (g_minstagib)
1127         {
1128                 minstagib_items(IT_CELLS);
1129                 self.think = minst_remove_item;
1130                 self.nextthink = time;
1131                 return;
1132         }
1133         weapon_defaultspawnfunc(WEP_MINSTANEX);
1134 }
1135
1136 void spawnfunc_weapon_rocketlauncher (void)
1137 {
1138         if (g_minstagib)
1139         {
1140                 minstagib_items(IT_CELLS);
1141                 self.think = minst_remove_item;
1142                 self.nextthink = time;
1143                 return;
1144         }
1145         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1146 }
1147
1148 void spawnfunc_item_rockets (void) {
1149         if(!self.ammo_rockets)
1150                 self.ammo_rockets = g_pickup_rockets;
1151         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1152 }
1153
1154 void spawnfunc_item_shells (void);
1155 void spawnfunc_item_bullets (void) {
1156         if(!weaponswapping)
1157         if(q3acompat_machineshotgunswap)
1158         if(self.classname != "droppedweapon")
1159         {
1160                 weaponswapping = TRUE;
1161                 spawnfunc_item_shells();
1162                 weaponswapping = FALSE;
1163                 return;
1164         }
1165
1166         if(!self.ammo_nails)
1167                 self.ammo_nails = g_pickup_nails;
1168         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1169 }
1170
1171 void spawnfunc_item_cells (void) {
1172         if(!self.ammo_cells)
1173                 self.ammo_cells = g_pickup_cells;
1174         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1175 }
1176
1177 void spawnfunc_item_shells (void) {
1178         if(!weaponswapping)
1179         if(q3acompat_machineshotgunswap)
1180         if(self.classname != "droppedweapon")
1181         {
1182                 weaponswapping = TRUE;
1183                 spawnfunc_item_bullets();
1184                 weaponswapping = FALSE;
1185                 return;
1186         }
1187
1188         if(!self.ammo_shells)
1189                 self.ammo_shells = g_pickup_shells;
1190         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1191 }
1192
1193 void spawnfunc_item_armor_small (void) {
1194         if(!self.armorvalue)
1195                 self.armorvalue = g_pickup_armorsmall;
1196         if(!self.max_armorvalue)
1197                 self.max_armorvalue = g_pickup_armorsmall_max;
1198         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1199 }
1200
1201 void spawnfunc_item_armor_medium (void) {
1202         if(!self.armorvalue)
1203                 self.armorvalue = g_pickup_armormedium;
1204         if(!self.max_armorvalue)
1205                 self.max_armorvalue = g_pickup_armormedium_max;
1206         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1207 }
1208
1209 void spawnfunc_item_armor_big (void) {
1210         if(!self.armorvalue)
1211                 self.armorvalue = g_pickup_armorbig;
1212         if(!self.max_armorvalue)
1213                 self.max_armorvalue = g_pickup_armorbig_max;
1214         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1215 }
1216
1217 void spawnfunc_item_armor_large (void) {
1218         if(!self.armorvalue)
1219                 self.armorvalue = g_pickup_armorlarge;
1220         if(!self.max_armorvalue)
1221                 self.max_armorvalue = g_pickup_armorlarge_max;
1222         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1223 }
1224
1225 void spawnfunc_item_health_small (void) {
1226         if(!self.max_health)
1227                 self.max_health = g_pickup_healthsmall_max;
1228         if(!self.health)
1229                 self.health = g_pickup_healthsmall;
1230         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1231 }
1232
1233 void spawnfunc_item_health_medium (void) {
1234         if(!self.max_health)
1235                 self.max_health = g_pickup_healthmedium_max;
1236         if(!self.health)
1237                 self.health = g_pickup_healthmedium;
1238         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1239 }
1240
1241 void spawnfunc_item_health_large (void) {
1242         if(!self.max_health)
1243                 self.max_health = g_pickup_healthlarge_max;
1244         if(!self.health)
1245                 self.health = g_pickup_healthlarge;
1246         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1247 }
1248
1249 void spawnfunc_item_health_mega (void) {
1250         if(!cvar("g_powerup_superhealth"))
1251                 return;
1252
1253         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1254                 return;
1255
1256         if(g_minstagib) {
1257                 minstagib_items(IT_NAILS);
1258         } else {
1259                 if(!self.max_health)
1260                         self.max_health = g_pickup_healthmega_max;
1261                 if(!self.health)
1262                         self.health = g_pickup_healthmega;
1263                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1264         }
1265 }
1266
1267 // support old misnamed entities
1268 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1269 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1270 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1271 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1272 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1273
1274 void spawnfunc_item_strength (void) {
1275         if(!cvar("g_powerup_strength"))
1276                 return;
1277
1278         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1279                 return;
1280
1281         if(g_minstagib) {
1282                 minstagib_items(IT_STRENGTH);
1283         } else {
1284                 precache_sound("weapons/strength_fire.wav");
1285                 self.strength_finished = 30;
1286                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1287         }
1288 }
1289
1290 void spawnfunc_item_invincible (void) {
1291         if(!cvar("g_powerup_shield"))
1292                 return;
1293
1294         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1295                 return;
1296
1297         if(g_minstagib) {
1298                 minstagib_items(IT_INVINCIBLE);
1299         } else {
1300                 self.invincible_finished = 30;
1301                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1302         }
1303 }
1304
1305 void spawnfunc_item_minst_cells (void) {
1306         if (g_minstagib)
1307         {
1308                 minst_no_auto_cells = 1;
1309                 minstagib_items(IT_CELLS);
1310         }
1311         else
1312                 remove(self);
1313 }
1314
1315 // compatibility:
1316 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1317
1318 float GiveItems(entity e, float beginarg, float endarg);
1319 void target_items_use (void)
1320 {
1321         if(activator.classname == "droppedweapon")
1322         {
1323                 EXACTTRIGGER_TOUCH;
1324                 remove(activator);
1325                 return;
1326         }
1327
1328         if(activator.classname != "player")
1329                 return;
1330         if(activator.deadflag != DEAD_NO)
1331                 return;
1332         EXACTTRIGGER_TOUCH;
1333
1334         entity e;
1335         for(e = world; (e = find(e, classname, "droppedweapon")); )
1336                 if(e.enemy == activator)
1337                         remove(e);
1338
1339         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1340                 centerprint(activator, self.message);
1341 }
1342
1343 void spawnfunc_target_items (void)
1344 {
1345         float n, i, j;
1346         entity e;
1347
1348         self.use = target_items_use;
1349         if(!self.strength_finished)
1350                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1351         if(!self.invincible_finished)
1352                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1353
1354         precache_sound("misc/itempickup.wav");
1355         precache_sound("misc/itempickup.wav");
1356         precache_sound("misc/itempickup.wav");
1357         precache_sound("misc/itempickup.wav");
1358         precache_sound("misc/megahealth.wav");
1359         precache_sound("misc/armor25.wav");
1360         precache_sound("misc/powerup.wav");
1361         precache_sound("misc/poweroff.wav");
1362         precache_sound("weapons/weaponpickup.wav");
1363
1364         n = tokenize_console(self.netname);
1365         if(argv(0) == "give")
1366         {
1367                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1368         }
1369         else
1370         {
1371                 for(i = 0; i < n; ++i)
1372                 {
1373                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1374                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1375                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1376                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1377                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1378                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1379                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1380                         else
1381                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1382                         {
1383                                 e = get_weaponinfo(j);
1384                                 if(argv(i) == e.netname)
1385                                 {
1386                                         self.weapons |= e.weapons;
1387                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1388                                                 weapon_action(e.weapon, WR_PRECACHE);
1389                                         break;
1390                                 }
1391                         }
1392                         if(j > WEP_LAST)
1393                                 print("target_items: invalid item ", argv(i), "\n");
1394                 }
1395
1396                 string itemprefix, valueprefix;
1397                 if(self.spawnflags == 0)
1398                 {
1399                         itemprefix = "";
1400                         valueprefix = "";
1401                 }
1402                 else if(self.spawnflags == 1)
1403                 {
1404                         itemprefix = "max ";
1405                         valueprefix = "max ";
1406                 }
1407                 else if(self.spawnflags == 2)
1408                 {
1409                         itemprefix = "min ";
1410                         valueprefix = "min ";
1411                 }
1412                 else if(self.spawnflags == 4)
1413                 {
1414                         itemprefix = "minus ";
1415                         valueprefix = "max ";
1416                 }
1417                 else
1418                         error("invalid spawnflags");
1419
1420                 self.netname = "";
1421                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1422                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1423                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1424                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1425                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1426                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1427                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1428                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1429                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1430                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1431                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1432                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1433                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1434                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1435                 {
1436                         e = get_weaponinfo(j);
1437                         if(e.weapons)
1438                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1439                 }
1440         }
1441         self.netname = strzone(self.netname);
1442         //print(self.netname, "\n");
1443
1444         n = tokenize_console(self.netname);
1445         for(i = 0; i < n; ++i)
1446         {
1447                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1448                 {
1449                         e = get_weaponinfo(j);
1450                         if(argv(i) == e.netname)
1451                         {
1452                                 weapon_action(e.weapon, WR_PRECACHE);
1453                                 break;
1454                         }
1455                 }
1456         }
1457 }
1458
1459 void spawnfunc_item_fuel(void)
1460 {
1461         if(!self.ammo_fuel)
1462                 self.ammo_fuel = g_pickup_fuel;
1463         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1464 }
1465
1466 void spawnfunc_item_fuel_regen(void)
1467 {
1468         if(start_items & IT_FUEL_REGEN)
1469         {
1470                 spawnfunc_item_fuel();
1471                 return;
1472         }
1473         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1474 }
1475
1476 void spawnfunc_item_jetpack(void)
1477 {
1478         if(g_grappling_hook)
1479                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1480         if(!self.ammo_fuel)
1481                 self.ammo_fuel = g_pickup_fuel_jetpack;
1482         if(start_items & IT_JETPACK)
1483         {
1484                 spawnfunc_item_fuel();
1485                 return;
1486         }
1487         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1488 }
1489
1490 // we no longer have the seeker
1491 void spawnfunc_weapon_seeker()
1492 {
1493         spawnfunc_weapon_fireball();
1494 }
1495
1496
1497 #define OP_SET 0
1498 #define OP_MIN 1
1499 #define OP_MAX 2
1500 #define OP_PLUS 3
1501 #define OP_MINUS 4
1502
1503 float GiveBit(entity e, .float fld, float bit, float op, float val)
1504 {
1505         float v0, v1;
1506         v0 = (e.fld & bit);
1507         switch(op)
1508         {
1509                 case OP_SET:
1510                         if(val > 0)
1511                                 e.fld |= bit;
1512                         else
1513                                 e.fld &~= bit;
1514                         break;
1515                 case OP_MIN:
1516                 case OP_PLUS:
1517                         if(val > 0)
1518                                 e.fld |= bit;
1519                         break;
1520                 case OP_MAX:
1521                         if(val <= 0)
1522                                 e.fld &~= bit;
1523                         break;
1524                 case OP_MINUS:
1525                         if(val > 0)
1526                                 e.fld &~= bit;
1527                         break;
1528         }
1529         v1 = (e.fld & bit);
1530         return (v0 != v1);
1531 }
1532
1533 float GiveValue(entity e, .float fld, float op, float val)
1534 {
1535         float v0, v1;
1536         v0 = e.fld;
1537         switch(op)
1538         {
1539                 case OP_SET:
1540                         e.fld = val;
1541                         break;
1542                 case OP_MIN:
1543                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1544                         break;
1545                 case OP_MAX:
1546                         e.fld = min(e.fld, val);
1547                         break;
1548                 case OP_PLUS:
1549                         e.fld += val;
1550                         break;
1551                 case OP_MINUS:
1552                         e.fld -= val;
1553                         break;
1554         }
1555         v1 = e.fld;
1556         return (v0 != v1);
1557 }
1558
1559 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1560 {
1561         if(v1 == v0)
1562                 return;
1563         if(v1 <= v0 - t)
1564         {
1565                 if(snd_decr != "")
1566                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1567         }
1568         else if(v0 >= v0 + t)
1569         {
1570                 if(snd_incr != "")
1571                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1572         }
1573 }
1574
1575 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1576 {
1577         if(v0 < v1)
1578                 e.rotfield = max(e.rotfield, time + rottime);
1579         else if(v0 > v1)
1580                 e.regenfield = max(e.regenfield, time + regentime);
1581 }
1582
1583 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1584 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1585 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1586 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1587
1588 float GiveItems(entity e, float beginarg, float endarg)
1589 {
1590         float got, i, j, val, op;
1591         float _switchweapon;
1592         entity wi;
1593         string cmd;
1594
1595         val = 999;
1596         op = OP_SET;
1597
1598         got = 0;
1599
1600         _switchweapon = FALSE;
1601         if (e.autoswitch)
1602                 if (e.switchweapon == w_getbestweapon(e))
1603                         _switchweapon = TRUE;
1604
1605         e.strength_finished = max(0, e.strength_finished - time);
1606         e.invincible_finished = max(0, e.invincible_finished - time);
1607         
1608         PREGIVE(e, items);
1609         PREGIVE(e, weapons);
1610         PREGIVE(e, strength_finished);
1611         PREGIVE(e, invincible_finished);
1612         PREGIVE(e, ammo_nails);
1613         PREGIVE(e, ammo_cells);
1614         PREGIVE(e, ammo_shells);
1615         PREGIVE(e, ammo_rockets);
1616         PREGIVE(e, ammo_fuel);
1617         PREGIVE(e, armorvalue);
1618         PREGIVE(e, health);
1619
1620         for(i = beginarg; i < endarg; ++i)
1621         {
1622                 cmd = argv(i);
1623
1624                 if(cmd == "0" || stof(cmd))
1625                 {
1626                         val = stof(cmd);
1627                         continue;
1628                 }
1629                 switch(cmd)
1630                 {
1631                         case "no":
1632                                 op = OP_MAX;
1633                                 val = 0;
1634                                 continue;
1635                         case "max":
1636                                 op = OP_MAX;
1637                                 continue;
1638                         case "min":
1639                                 op = OP_MIN;
1640                                 continue;
1641                         case "plus":
1642                                 op = OP_PLUS;
1643                                 continue;
1644                         case "minus":
1645                                 op = OP_MINUS;
1646                                 continue;
1647                         case "ALL":
1648                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1649                                 got += GiveValue(e, strength_finished, op, time + val);
1650                                 got += GiveValue(e, invincible_finished, op, time + val);
1651                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1652                         case "all":
1653                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1654                                 got += GiveValue(e, health, op, val);
1655                                 got += GiveValue(e, armorvalue, op, val);
1656                         case "allweapons":
1657                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1658                                 {
1659                                         wi = get_weaponinfo(j);
1660                                         if(wi.weapons)
1661                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1662                                 }
1663                         case "allammo":
1664                                 got += GiveValue(e, ammo_cells, op, val);
1665                                 got += GiveValue(e, ammo_shells, op, val);
1666                                 got += GiveValue(e, ammo_nails, op, val);
1667                                 got += GiveValue(e, ammo_rockets, op, val);
1668                                 got += GiveValue(e, ammo_fuel, op, val);
1669                                 break;
1670                         case "unlimited_ammo":
1671                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1672                                 break;
1673                         case "unlimited_weapon_ammo":
1674                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1675                                 break;
1676                         case "unlimited_superweapons":
1677                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1678                                 break;
1679                         case "jetpack":
1680                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1681                                 break;
1682                         case "fuel_regen":
1683                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1684                                 break;
1685                         case "strength":
1686                                 got += GiveValue(e, strength_finished, op, val);
1687                                 break;
1688                         case "invincible":
1689                                 got += GiveValue(e, invincible_finished, op, val);
1690                                 break;
1691                         case "cells":
1692                                 got += GiveValue(e, ammo_cells, op, val);
1693                                 break;
1694                         case "shells":
1695                                 got += GiveValue(e, ammo_shells, op, val);
1696                                 break;
1697                         case "nails":
1698                         case "bullets":
1699                                 got += GiveValue(e, ammo_nails, op, val);
1700                                 break;
1701                         case "rockets":
1702                                 got += GiveValue(e, ammo_rockets, op, val);
1703                                 break;
1704                         case "health":
1705                                 got += GiveValue(e, health, op, val);
1706                                 break;
1707                         case "armor":
1708                                 got += GiveValue(e, armorvalue, op, val);
1709                                 break;
1710                         case "fuel":
1711                                 got += GiveValue(e, ammo_fuel, op, val);
1712                                 break;
1713                         default:
1714                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1715                                 {
1716                                         wi = get_weaponinfo(j);
1717                                         if(cmd == wi.netname)
1718                                         {
1719                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1720                                                 break;
1721                                         }
1722                                 }
1723                                 if(j > WEP_LAST)
1724                                         print("give: invalid item ", cmd, "\n");
1725                                 break;
1726                 }
1727                 val = 999;
1728                 op = OP_SET;
1729         }
1730
1731         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1732         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1733         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1734         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1735         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1736         {
1737                 wi = get_weaponinfo(j);
1738                 if(wi.weapons)
1739                 {
1740                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1741                         if not(save_weapons & wi.weapons)
1742                                 if(e.weapons & wi.weapons)
1743                                         weapon_action(wi.weapon, WR_PRECACHE);
1744                 }
1745         }
1746         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1747         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1748         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1749         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1750         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1751         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1752         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1753         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1754         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1755
1756         if(e.strength_finished <= 0)
1757                 e.strength_finished = 0;
1758         else
1759                 e.strength_finished += time;
1760         if(e.invincible_finished <= 0)
1761                 e.invincible_finished = 0;
1762         else
1763                 e.invincible_finished += time;
1764
1765         if not(e.weapons & W_WeaponBit(e.switchweapon))
1766                 _switchweapon = TRUE;
1767         if(_switchweapon)
1768                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1769
1770         return got;
1771 }