qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(autocvar_g_ghost_items_color);
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(autocvar_g_ghost_items_color);
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = '0 0 0';
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (autocvar_g_nodepthtestitems)
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (autocvar_g_fullbrightitems)
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 152         else
 153                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 202                                 if(self.waypointsprite_attached)
 203                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 204                         }
 205                 }
 206                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 207                 if(self.waypointsprite_attached)
 208                 {
 209                         WaypointSprite_Ping(self.waypointsprite_attached);
 210                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 211                 }
 212         }
 213 }
 214
 215 void Item_ScheduleRespawnIn(entity e, float t)
 216 {
 217         if(e.flags & FL_POWERUP)
 218         {
 219                 e.think = Item_RespawnCountdown;
 220                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 221                 e.count = 0;
 222         }
 223         else
 224         {
 225                 e.think = Item_Respawn;
 226                 e.nextthink = time + t;
 227         }
 228 }
 229
 230 void Item_ScheduleRespawn(entity e)
 231 {
 232         if(e.respawntime > 0)
 233         {
 234                 Item_Show(e, 0);
 235                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 236         }
 237         else // if respawntime is -1, this item does not respawn
 238                 Item_Show(e, -1);
 239 }
 240
 241 void Item_ScheduleInitialRespawn(entity e)
 242 {
 243         Item_Show(e, 0);
 244         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 245 }
 246
 247 float Item_GiveTo(entity item, entity player)
 248 {
 249         float _switchweapon;
 250         float pickedup;
 251         float it;
 252         float i;
 253         entity e;
 254
 255         // if nothing happens to player, just return without taking the item
 256         pickedup = FALSE;
 257         _switchweapon = FALSE;
 258
 259         if (g_minstagib)
 260         {
 261                 if(item.spawnshieldtime)
 262                 {
 263                         if (item.ammo_fuel)
 264                         if (player.ammo_fuel < g_pickup_fuel_max)
 265                         {
 266                                 pickedup = TRUE;
 267                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 268                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 269                         }
 270                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 271                         {
 272                                 pickedup = TRUE;
 273                                 player.items |= it;
 274                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 275                         }
 276
 277                         _switchweapon = TRUE;
 278                         if (item.ammo_cells)
 279                         {
 280                                 pickedup = TRUE;
 281                                 // play some cool sounds ;)
 282                                 if (clienttype(player) == CLIENTTYPE_REAL)
 283                                 {
 284                                         if(player.health <= 5)
 285                                                 AnnounceTo(player, "lastsecond");
 286                                         else if(player.health < 50)
 287                                                 AnnounceTo(player, "narrowly");
 288                                 }
 289                                 // sound not available
 290                                 // else if(item.items == IT_CELLS)
 291                                 //      AnnounceTo(player, "ammo");
 292
 293                                 if (item.weapons & WEPBIT_MINSTANEX)
 294                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 295                                 if (item.ammo_cells)
 296                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 297                                 player.health = 100;
 298                         }
 299
 300                         // extralife powerup
 301                         if (item.max_health)
 302                         {
 303                                 pickedup = TRUE;
 304                                 // sound not available
 305                                 // AnnounceTo(player, "_lives");
 306                                 player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 307                                 sprint(player, "^3You picked up some extra lives\n");
 308                         }
 309
 310                         // invis powerup
 311                         if (item.strength_finished)
 312                         {
 313                                 pickedup = TRUE;
 314                                 // sound not available
 315                                 // AnnounceTo(player, "invisible");
 316                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 317                         }
 318
 319                         // speed powerup
 320                         if (item.invincible_finished)
 321                         {
 322                                 pickedup = TRUE;
 323                                 // sound not available
 324                                 // AnnounceTo(player, "speed");
 325                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 326                         }
 327                 }
 328         }
 329         else
 330         {
 331                 if (g_weapon_stay == 1)
 332                 if not(item.flags & FL_NO_WEAPON_STAY)
 333                 if (item.flags & FL_WEAPON)
 334                 {
 335                         if(item.classname == "droppedweapon")
 336                         {
 337                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 338                                         goto skip;
 339                         }
 340                         else
 341                         {
 342                                 if (player.weapons & item.weapons)
 343                                         goto skip;
 344                         }
 345                 }
 346
 347                 // in case the player has autoswitch enabled do the following:
 348                 // if the player is using their best weapon before items are given, they
 349                 // probably want to switch to an even better weapon after items are given
 350                 if (player.autoswitch)
 351                 if (player.switchweapon == w_getbestweapon(player))
 352                         _switchweapon = TRUE;
 353
 354                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 355                         _switchweapon = TRUE;
 356
 357                 if(item.spawnshieldtime)
 358                 {
 359                         if (item.ammo_shells)
 360                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 361                         {
 362                                 pickedup = TRUE;
 363                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 364                         }
 365                         if (item.ammo_nails)
 366                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 367                         {
 368                                 pickedup = TRUE;
 369                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 370                         }
 371                         if (item.ammo_rockets)
 372                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 373                         {
 374                                 pickedup = TRUE;
 375                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 376                         }
 377                         if (item.ammo_cells)
 378                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 379                         {
 380                                 pickedup = TRUE;
 381                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 382                         }
 383                         if (item.ammo_fuel)
 384                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 385                         {
 386                                 pickedup = TRUE;
 387                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 388                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 389                         }
 390                 }
 391
 392                 if (item.flags & FL_WEAPON)
 393                         if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway && g_weapon_stay == 0))
 394                 {
 395                         pickedup = TRUE;
 396                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 397                         {
 398                                 e = get_weaponinfo(i);
 399                                 if(it & e.weapons)
 400                                         W_GiveWeapon (player, e.weapon, item.netname);
 401                         }
 402                 }
 403
 404                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 405                 {
 406                         pickedup = TRUE;
 407                         player.items |= it;
 408                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 409                 }
 410
 411                 if(item.spawnshieldtime)
 412                 {
 413                         if (item.strength_finished)
 414                         {
 415                                 pickedup = TRUE;
 416                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 417                         }
 418                         if (item.invincible_finished)
 419                         {
 420                                 pickedup = TRUE;
 421                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 422                         }
 423
 424                         if (item.health)
 425                         if ((player.health < item.max_health) || item.pickup_anyway)
 426                         {
 427                                 pickedup = TRUE;
 428                                 player.health = bound(player.health, item.max_health, player.health + item.health);
 429                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 430                         }
 431                         if (item.armorvalue)
 432                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 433                         {
 434                                 pickedup = TRUE;
 435                                 player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 436                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 437                         }
 438                 }
 439         }
 440
 441 :skip
 442         // always eat teamed entities
 443         if(item.team)
 444                 pickedup = TRUE;
 445
 446         if (!pickedup)
 447                 return 0;
 448
 449         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 450         if (_switchweapon)
 451                 if (player.switchweapon != w_getbestweapon(player))
 452                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 453
 454         return 1;
 455 }
 456
 457 void Item_Touch (void)
 458 {
 459         entity e, head;
 460
 461         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 462         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 463         {
 464                 remove(self);
 465                 return;
 466         }
 467         if (other.classname != "player")
 468                 return;
 469         if (other.deadflag)
 470                 return;
 471         if (self.solid != SOLID_TRIGGER)
 472                 return;
 473         if (self.owner == other)
 474                 return;
 475
 476         if(!Item_GiveTo(self, other))
 477                 return;
 478
 479         other.last_pickup = time;
 480
 481         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 482
 483         if (self.classname == "droppedweapon")
 484                 remove (self);
 485         else if not(self.spawnshieldtime)
 486                 return;
 487         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 488                 return;
 489         else
 490         {
 491                 if(self.team)
 492                 {
 493                         RandomSelection_Init();
 494                         for(head = world; (head = findfloat(head, team, self.team)); )
 495                         {
 496                                 if(head.flags & FL_ITEM)
 497                                 {
 498                                         Item_Show(head, -1);
 499                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 500                                 }
 501                         }
 502                         e = RandomSelection_chosen_ent;
 503                 }
 504                 else
 505                         e = self;
 506                 Item_ScheduleRespawn(e);
 507         }
 508 }
 509
 510 void Item_FindTeam()
 511 {
 512         entity head, e;
 513
 514         if(self.effects & EF_NODRAW)
 515         {
 516                 // marker for item team search
 517                 dprint("Initializing item team ", ftos(self.team), "\n");
 518                 RandomSelection_Init();
 519                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 520                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 521                 e = RandomSelection_chosen_ent;
 522                 e.state = 0;
 523                 Item_Show(e, 1);
 524
 525                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 526                 {
 527                         if(head != e)
 528                         {
 529                                 // make it a non-spawned item
 530                                 Item_Show(head, -1);
 531                                 head.state = 1; // state 1 = initially hidden item
 532                         }
 533                         head.effects &~= EF_NODRAW;
 534                 }
 535
 536                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 537                         Item_ScheduleInitialRespawn(e);
 538         }
 539 }
 540
 541 void Item_Reset()
 542 {
 543         Item_Show(self, !self.state);
 544         setorigin (self, self.origin);
 545         self.think = SUB_Null;
 546         self.nextthink = 0;
 547
 548         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 549                 Item_ScheduleInitialRespawn(self);
 550 }
 551
 552 // Savage: used for item garbage-collection
 553 // TODO: perhaps nice special effect?
 554 void RemoveItem(void)
 555 {
 556         remove(self);
 557 }
 558
 559 // pickup evaluation functions
 560 // these functions decide how desirable an item is to the bots
 561
 562 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 563
 564 float weapon_pickupevalfunc(entity player, entity item)
 565 {
 566         float c, i, j, position;
 567
 568         // See if I have it already
 569         if(player.weapons & item.weapons == item.weapons)
 570         {
 571                 // If I can pick it up
 572                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 573                         c = 0;
 574                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 575                 {
 576                         // Skilled bots will grab more
 577                         c = bound(0, skill / 10, 1) * 0.5;
 578                 }
 579                 else
 580                         c = 0;
 581         }
 582         else
 583                 c = 1;
 584
 585         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 586         if( bot_custom_weapon && c )
 587         {
 588                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 589                 {
 590                         // Find weapon
 591                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 592                                 continue;
 593
 594                         // Find the highest position on any range
 595                         position = -1;
 596                         for(j = 0; j < WEP_LAST ; ++j){
 597                                 if(
 598                                                 bot_weapons_far[j] == i ||
 599                                                 bot_weapons_mid[j] == i ||
 600                                                 bot_weapons_close[j] == i
 601                                   )
 602                                 {
 603                                         position = j;
 604                                         break;
 605                                 }
 606                         }
 607
 608                         // Rate it
 609                         if (position >= 0 )
 610                         {
 611                                 position = WEP_LAST - position;
 612                                 // item.bot_pickupbasevalue is overwritten here
 613                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 614                         }
 615                 }
 616         }
 617
 618         return item.bot_pickupbasevalue * c;
 619 }
 620
 621 float commodity_pickupevalfunc(entity player, entity item)
 622 {
 623         float c, i, need_shells, need_nails, need_rockets, need_cells;
 624         entity wi;
 625         c = 0;
 626
 627         // Detect needed ammo
 628         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 629         {
 630                 wi = get_weaponinfo(i);
 631
 632                 if not(wi.weapons & player.weapons)
 633                         continue;
 634
 635                 if(wi.items & IT_SHELLS)
 636                         need_shells = TRUE;
 637                 else if(wi.items & IT_NAILS)
 638                         need_nails = TRUE;
 639                 else if(wi.items & IT_ROCKETS)
 640                         need_rockets = TRUE;
 641                 else if(wi.items & IT_CELLS)
 642                         need_cells = TRUE;
 643         }
 644
 645         // TODO: figure out if the player even has the weapon this ammo is for?
 646         // may not affect strategy much though...
 647         // find out how much more ammo/armor/health the player can hold
 648         if (need_shells)
 649         if (item.ammo_shells)
 650         if (player.ammo_shells < g_pickup_shells_max)
 651                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 652         if (need_nails)
 653         if (item.ammo_nails)
 654         if (player.ammo_nails < g_pickup_nails_max)
 655                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 656         if (need_rockets)
 657         if (item.ammo_rockets)
 658         if (player.ammo_rockets < g_pickup_rockets_max)
 659                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 660         if (need_cells)
 661         if (item.ammo_cells)
 662         if (player.ammo_cells < g_pickup_cells_max)
 663                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 664         if (item.armorvalue)
 665         if (player.armorvalue < item.max_armorvalue)
 666                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 667         if (item.health)
 668         if (player.health < item.max_health)
 669                 c = c + max(0, 1 - player.health / item.max_health);
 670
 671         return item.bot_pickupbasevalue * c;
 672 }
 673
 674
 675 .float is_item;
 676 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 677 {
 678         startitem_failed = FALSE;
 679
 680         self.items = itemid;
 681         self.weapons = weaponid;
 682
 683         // is it a dropped weapon?
 684         if (self.classname == "droppedweapon")
 685         {
 686                 self.reset = SUB_Remove;
 687                 // it's a dropped weapon
 688                 self.movetype = MOVETYPE_TOSS;
 689                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 690                 self.think = RemoveItem;
 691                 self.nextthink = time + 60;
 692                 // don't drop if in a NODROP zone (such as lava)
 693                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 694                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 695                 {
 696                         startitem_failed = TRUE;
 697                         remove(self);
 698                         return;
 699                 }
 700         }
 701         else
 702         {
 703                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 704                 {
 705                         startitem_failed = TRUE;
 706                         remove(self);
 707                         return;
 708                 }
 709
 710                 self.reset = Item_Reset;
 711                 // it's a level item
 712                 if(self.spawnflags & 1)
 713                         self.noalign = 1;
 714                 if (self.noalign)
 715                         self.movetype = MOVETYPE_NONE;
 716                 else
 717                         self.movetype = MOVETYPE_TOSS;
 718                 // do item filtering according to game mode and other things
 719                 if (!self.noalign)
 720                 {
 721                         // first nudge it off the floor a little bit to avoid math errors
 722                         setorigin(self, self.origin + '0 0 1');
 723                         // set item size before we spawn a spawnfunc_waypoint
 724                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 725                                 setsize (self, '-16 -16 0', '16 16 48');
 726                         else
 727                                 setsize (self, '-16 -16 0', '16 16 32');
 728                         // note droptofloor returns FALSE if stuck/or would fall too far
 729                         droptofloor();
 730                         waypoint_spawnforitem(self);
 731                 }
 732
 733                 /*
 734                  * can't do it that way, as it would break maps
 735                  * TODO make a target_give like entity another way, that perhaps has
 736                  * the weapon name in a key
 737                 if(self.targetname)
 738                 {
 739                         // target_give not yet supported; maybe later
 740                         print("removed targeted ", self.classname, "\n");
 741                         startitem_failed = TRUE;
 742                         remove (self);
 743                         return;
 744                 }
 745                 */
 746
 747                 if(autocvar_spawn_debug >= 2)
 748                 {
 749                         entity otheritem;
 750                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 751                         {
 752                                 if(otheritem.is_item)
 753                                 {
 754                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 755                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 756                                         error("Mapper sucks.");
 757                                 }
 758                         }
 759                         self.is_item = TRUE;
 760                 }
 761
 762                 if(g_lms || g_ca)
 763                 {
 764                         startitem_failed = TRUE;
 765                         remove(self);
 766                         return;
 767                 }
 768                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 769                 {
 770                         startitem_failed = TRUE;
 771                         remove(self);
 772                         return;
 773                 }
 774                 else if (g_minstagib)
 775                 {
 776                         // don't remove dropped items and powerups
 777                         if (self.classname != "minstagib")
 778                         {
 779                                 startitem_failed = TRUE;
 780                                 remove (self);
 781                                 return;
 782                         }
 783                 }
 784                 else if (!autocvar_g_pickup_items && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 785                 {
 786                         startitem_failed = TRUE;
 787                         remove (self);
 788                         return;
 789                 }
 790
 791                 weaponsInMap |= weaponid;
 792
 793                 precache_model (itemmodel);
 794                 precache_sound (pickupsound);
 795
 796                 precache_sound ("misc/itemrespawncountdown.wav");
 797                 if(!g_minstagib && itemid == IT_STRENGTH)
 798                         precache_sound ("misc/strength_respawn.wav");
 799                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 800                         precache_sound ("misc/shield_respawn.wav");
 801                 else
 802                         precache_sound ("misc/itemrespawn.wav");
 803
 804                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 805                         self.target = "###item###"; // for finding the nearest item using find()
 806         }
 807
 808         self.bot_pickup = TRUE;
 809         self.bot_pickupevalfunc = pickupevalfunc;
 810         self.bot_pickupbasevalue = pickupbasevalue;
 811         self.mdl = itemmodel;
 812         self.item_pickupsound = pickupsound;
 813         // let mappers override respawntime
 814         if(!self.respawntime) // both set
 815         {
 816                 self.respawntime = defaultrespawntime;
 817                 self.respawntimejitter = defaultrespawntimejitter;
 818         }
 819         self.netname = itemname;
 820         self.flags = FL_ITEM | itemflags;
 821         self.touch = Item_Touch;
 822         setmodel (self, self.mdl); // precision set below
 823         self.effects |= EF_LOWPRECISION;
 824         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 825                 setsize (self, '-16 -16 0', '16 16 48');
 826         else
 827                 setsize (self, '-16 -16 0', '16 16 32');
 828         if(itemflags & FL_WEAPON)
 829                 self.modelflags |= MF_ROTATE;
 830
 831         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 832         if (itemflags & FL_WEAPON)
 833         {
 834                 // neutral team color for pickup weapons
 835                 self.colormap = 1024; // color shirt=0 pants=0 grey
 836         }
 837
 838         Item_Show(self, 1);
 839         self.state = 0;
 840         if(self.team)
 841         {
 842                 if(!self.cnt)
 843                         self.cnt = 1; // item probability weight
 844                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 845                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 846         }
 847         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 848                 Item_ScheduleInitialRespawn(self);
 849 }
 850
 851 /* replace items in minstagib
 852  * IT_STRENGTH   = invisibility
 853  * IT_NAILS      = extra lives
 854  * IT_INVINCIBLE = speed
 855  */
 856 void minstagib_items (float itemid)
 857 {
 858         float rnd;
 859         self.classname = "minstagib";
 860
 861         // replace rocket launchers and nex guns with ammo cells
 862         if (itemid == IT_CELLS)
 863         {
 864                 self.ammo_cells = 1;
 865                 StartItem ("models/items/a_cells.md3",
 866                         "misc/itempickup.wav", 45, 0,
 867                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 868                 return;
 869         }
 870
 871         // randomize
 872         rnd = random() * 3;
 873         if (rnd <= 1)
 874                 itemid = IT_STRENGTH;
 875         else if (rnd <= 2)
 876                 itemid = IT_NAILS;
 877         else
 878                 itemid = IT_INVINCIBLE;
 879
 880         // replace with invis
 881         if (itemid == IT_STRENGTH)
 882         {
 883                 self.strength_finished = 30;
 884                 StartItem ("models/items/g_strength.md3",
 885                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 886                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 887         }
 888         // replace with extra lives
 889         if (itemid == IT_NAILS)
 890         {
 891                 self.max_health = 1;
 892                 StartItem ("models/items/g_h100.md3",
 893                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 894                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 895         }
 896         // replace with speed
 897         if (itemid == IT_INVINCIBLE)
 898         {
 899                 self.invincible_finished = 30;
 900                 StartItem ("models/items/g_invincible.md3",
 901                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 902                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 903         }
 904 }
 905
 906 float minst_no_auto_cells;
 907 void minst_remove_item (void) {
 908         if(minst_no_auto_cells)
 909                 remove(self);
 910 }
 911
 912 float weaponswapping;
 913 float internalteam;
 914
 915 void weapon_defaultspawnfunc(float wpn)
 916 {
 917         entity e;
 918         float t;
 919         var .float ammofield;
 920         string s;
 921         entity oldself;
 922         float i, j;
 923
 924         // set the respawntime in advance (so replaced weapons can copy it)
 925
 926         if(!self.respawntime)
 927         {
 928                 e = get_weaponinfo(wpn);
 929                 if(e.items == IT_SUPERWEAPON)
 930                 {
 931                         self.respawntime = g_pickup_respawntime_powerup;
 932                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 933                 }
 934                 else
 935                 {
 936                         self.respawntime = g_pickup_respawntime_weapon;
 937                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 938                 }
 939         }
 940
 941         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 942         {
 943                 e = get_weaponinfo(wpn);
 944                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 945                 if(s == "0")
 946                 {
 947                         remove(self);
 948                         startitem_failed = TRUE;
 949                         return;
 950                 }
 951                 t = tokenize_console(s);
 952                 if(t >= 2)
 953                 {
 954                         self.team = --internalteam;
 955                         oldself = self;
 956                         for(i = 1; i < t; ++i)
 957                         {
 958                                 s = argv(i);
 959                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 960                                 {
 961                                         e = get_weaponinfo(j);
 962                                         if(e.netname == s)
 963                                         {
 964                                                 self = spawn();
 965                                                 copyentity(oldself, self);
 966                                                 self.classname = "replacedweapon";
 967                                                 weapon_defaultspawnfunc(j);
 968                                                 break;
 969                                         }
 970                                 }
 971                                 if(j > WEP_LAST)
 972                                 {
 973                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 974                                 }
 975                         }
 976                         self = oldself;
 977                 }
 978                 if(t >= 1)
 979                 {
 980                         s = argv(0);
 981                         wpn = 0;
 982                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 983                         {
 984                                 e = get_weaponinfo(j);
 985                                 if(e.netname == s)
 986                                 {
 987                                         wpn = j;
 988                                         break;
 989                                 }
 990                         }
 991                         if(j > WEP_LAST)
 992                         {
 993                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 994                         }
 995                 }
 996                 if(wpn == 0)
 997                 {
 998                         remove(self);
 999                         startitem_failed = TRUE;
1000                         return;
1001                 }
1002         }
1003
1004         e = get_weaponinfo(wpn);
1005
1006         if(e.items && e.items != IT_SUPERWEAPON)
1007         {
1008                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1009                 {
1010                         if(e.items & j)
1011                         {
1012                                 ammofield = Item_CounterField(j);
1013                                 if(!self.ammofield)
1014                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1015                         }
1016                 }
1017         }
1018         else
1019         {
1020                 self.flags |= FL_NO_WEAPON_STAY;
1021         }
1022
1023         // weapon stay isn't supported for teamed weapons
1024         if(self.team)
1025                 self.flags |= FL_NO_WEAPON_STAY;
1026
1027         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1028         {
1029                 self.ammo_shells = 0;
1030                 self.ammo_nails = 0;
1031                 self.ammo_cells = 0;
1032                 self.ammo_rockets = 0;
1033                 // weapon stay 2: don't use ammo on weapon pickups; instead
1034                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1035         }
1036
1037         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1038         if (self.modelindex) // don't precache if self was removed
1039                 weapon_action(e.weapon, WR_PRECACHE);
1040 }
1041
1042 void spawnfunc_weapon_shotgun (void);
1043 void spawnfunc_weapon_uzi (void) {
1044         if(autocvar_sv_q3acompat_machineshotgunswap)
1045         if(self.classname != "droppedweapon")
1046         {
1047                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1048                 return;
1049         }
1050         weapon_defaultspawnfunc(WEP_UZI);
1051 }
1052
1053 void spawnfunc_weapon_shotgun (void) {
1054         if(autocvar_sv_q3acompat_machineshotgunswap)
1055         if(self.classname != "droppedweapon")
1056         {
1057                 weapon_defaultspawnfunc(WEP_UZI);
1058                 return;
1059         }
1060         weapon_defaultspawnfunc(WEP_SHOTGUN);
1061 }
1062
1063 void spawnfunc_weapon_nex (void)
1064 {
1065         if (g_minstagib)
1066         {
1067                 minstagib_items(IT_CELLS);
1068                 self.think = minst_remove_item;
1069                 self.nextthink = time;
1070                 return;
1071         }
1072         weapon_defaultspawnfunc(WEP_NEX);
1073 }
1074
1075 void spawnfunc_weapon_minstanex (void)
1076 {
1077         if (g_minstagib)
1078         {
1079                 minstagib_items(IT_CELLS);
1080                 self.think = minst_remove_item;
1081                 self.nextthink = time;
1082                 return;
1083         }
1084         weapon_defaultspawnfunc(WEP_MINSTANEX);
1085 }
1086
1087 void spawnfunc_weapon_rocketlauncher (void)
1088 {
1089         if (g_minstagib)
1090         {
1091                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1092                 self.think = minst_remove_item;
1093                 self.nextthink = time;
1094                 return;
1095         }
1096         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1097 }
1098
1099 void spawnfunc_item_rockets (void) {
1100         if(!self.ammo_rockets)
1101                 self.ammo_rockets = g_pickup_rockets;
1102         if(!self.pickup_anyway)
1103                 self.pickup_anyway = g_pickup_ammo_anyway;
1104         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1105 }
1106
1107 void spawnfunc_item_shells (void);
1108 void spawnfunc_item_bullets (void) {
1109         if(!weaponswapping)
1110         if(autocvar_sv_q3acompat_machineshotgunswap)
1111         if(self.classname != "droppedweapon")
1112         {
1113                 weaponswapping = TRUE;
1114                 spawnfunc_item_shells();
1115                 weaponswapping = FALSE;
1116                 return;
1117         }
1118
1119         if(!self.ammo_nails)
1120                 self.ammo_nails = g_pickup_nails;
1121         if(!self.pickup_anyway)
1122                 self.pickup_anyway = g_pickup_ammo_anyway;
1123         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1124 }
1125
1126 void spawnfunc_item_cells (void) {
1127         if(!self.ammo_cells)
1128                 self.ammo_cells = g_pickup_cells;
1129         if(!self.pickup_anyway)
1130                 self.pickup_anyway = g_pickup_ammo_anyway;
1131         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1132 }
1133
1134 void spawnfunc_item_shells (void) {
1135         if(!weaponswapping)
1136         if(autocvar_sv_q3acompat_machineshotgunswap)
1137         if(self.classname != "droppedweapon")
1138         {
1139                 weaponswapping = TRUE;
1140                 spawnfunc_item_bullets();
1141                 weaponswapping = FALSE;
1142                 return;
1143         }
1144
1145         if(!self.ammo_shells)
1146                 self.ammo_shells = g_pickup_shells;
1147         if(!self.pickup_anyway)
1148                 self.pickup_anyway = g_pickup_ammo_anyway;
1149         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1150 }
1151
1152 void spawnfunc_item_armor_small (void) {
1153         if(!self.armorvalue)
1154                 self.armorvalue = g_pickup_armorsmall;
1155         if(!self.max_armorvalue)
1156                 self.max_armorvalue = g_pickup_armorsmall_max;
1157         if(!self.pickup_anyway)
1158                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1159         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1160 }
1161
1162 void spawnfunc_item_armor_medium (void) {
1163         if(!self.armorvalue)
1164                 self.armorvalue = g_pickup_armormedium;
1165         if(!self.max_armorvalue)
1166                 self.max_armorvalue = g_pickup_armormedium_max;
1167         if(!self.pickup_anyway)
1168                 self.pickup_anyway = g_pickup_armormedium_anyway;
1169         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1170 }
1171
1172 void spawnfunc_item_armor_big (void) {
1173         if(!self.armorvalue)
1174                 self.armorvalue = g_pickup_armorbig;
1175         if(!self.max_armorvalue)
1176                 self.max_armorvalue = g_pickup_armorbig_max;
1177         if(!self.pickup_anyway)
1178                 self.pickup_anyway = g_pickup_armorbig_anyway;
1179         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1180 }
1181
1182 void spawnfunc_item_armor_large (void) {
1183         if(!self.armorvalue)
1184                 self.armorvalue = g_pickup_armorlarge;
1185         if(!self.max_armorvalue)
1186                 self.max_armorvalue = g_pickup_armorlarge_max;
1187         if(!self.pickup_anyway)
1188                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1189         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1190 }
1191
1192 void spawnfunc_item_health_small (void) {
1193         if(!self.max_health)
1194                 self.max_health = g_pickup_healthsmall_max;
1195         if(!self.health)
1196                 self.health = g_pickup_healthsmall;
1197         if(!self.pickup_anyway)
1198                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1199         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1200 }
1201
1202 void spawnfunc_item_health_medium (void) {
1203         if(!self.max_health)
1204                 self.max_health = g_pickup_healthmedium_max;
1205         if(!self.health)
1206                 self.health = g_pickup_healthmedium;
1207         if(!self.pickup_anyway)
1208                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1209         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1210 }
1211
1212 void spawnfunc_item_health_large (void) {
1213         if(!self.max_health)
1214                 self.max_health = g_pickup_healthlarge_max;
1215         if(!self.health)
1216                 self.health = g_pickup_healthlarge;
1217         if(!self.pickup_anyway)
1218                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1219         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1220 }
1221
1222 void spawnfunc_item_health_mega (void) {
1223         if(!autocvar_g_powerup_superhealth)
1224                 return;
1225
1226         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1227                 return;
1228
1229         if(g_minstagib) {
1230                 minstagib_items(IT_NAILS);
1231         } else {
1232                 if(!self.max_health)
1233                         self.max_health = g_pickup_healthmega_max;
1234                 if(!self.health)
1235                         self.health = g_pickup_healthmega;
1236                 if(!self.pickup_anyway)
1237                         self.pickup_anyway = g_pickup_healthmega_anyway;
1238                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1239         }
1240 }
1241
1242 // support old misnamed entities
1243 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1244 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1245 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1246 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1247 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1248
1249 void spawnfunc_item_strength (void) {
1250         if(!autocvar_g_powerup_strength)
1251                 return;
1252
1253         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1254                 return;
1255
1256         if(g_minstagib) {
1257                 minstagib_items(IT_STRENGTH);
1258         } else {
1259                 precache_sound("weapons/strength_fire.wav");
1260                 self.strength_finished = 30;
1261                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1262         }
1263 }
1264
1265 void spawnfunc_item_invincible (void) {
1266         if(!autocvar_g_powerup_shield)
1267                 return;
1268
1269         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1270                 return;
1271
1272         if(g_minstagib) {
1273                 minstagib_items(IT_INVINCIBLE);
1274         } else {
1275                 self.invincible_finished = 30;
1276                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1277         }
1278 }
1279
1280 void spawnfunc_item_minst_cells (void) {
1281         if (g_minstagib)
1282         {
1283                 minst_no_auto_cells = 1;
1284                 minstagib_items(IT_CELLS);
1285         }
1286         else
1287                 remove(self);
1288 }
1289
1290 // compatibility:
1291 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1292
1293 float GiveItems(entity e, float beginarg, float endarg);
1294 void target_items_use (void)
1295 {
1296         if(activator.classname == "droppedweapon")
1297         {
1298                 EXACTTRIGGER_TOUCH;
1299                 remove(activator);
1300                 return;
1301         }
1302
1303         if(activator.classname != "player")
1304                 return;
1305         if(activator.deadflag != DEAD_NO)
1306                 return;
1307         EXACTTRIGGER_TOUCH;
1308
1309         entity e;
1310         for(e = world; (e = find(e, classname, "droppedweapon")); )
1311                 if(e.enemy == activator)
1312                         remove(e);
1313
1314         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1315                 centerprint(activator, self.message);
1316 }
1317
1318 void spawnfunc_target_items (void)
1319 {
1320         float n, i, j;
1321         entity e;
1322
1323         self.use = target_items_use;
1324         if(!self.strength_finished)
1325                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1326         if(!self.invincible_finished)
1327                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1328
1329         precache_sound("misc/itempickup.wav");
1330         precache_sound("misc/megahealth.wav");
1331         precache_sound("misc/armor25.wav");
1332         precache_sound("misc/powerup.wav");
1333         precache_sound("misc/poweroff.wav");
1334         precache_sound("weapons/weaponpickup.wav");
1335
1336         n = tokenize_console(self.netname);
1337         if(argv(0) == "give")
1338         {
1339                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1340         }
1341         else
1342         {
1343                 for(i = 0; i < n; ++i)
1344                 {
1345                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1346                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1347                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1348                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1349                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1350                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1351                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1352                         else
1353                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1354                         {
1355                                 e = get_weaponinfo(j);
1356                                 if(argv(i) == e.netname)
1357                                 {
1358                                         self.weapons |= e.weapons;
1359                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1360                                                 weapon_action(e.weapon, WR_PRECACHE);
1361                                         break;
1362                                 }
1363                         }
1364                         if(j > WEP_LAST)
1365                                 print("target_items: invalid item ", argv(i), "\n");
1366                 }
1367
1368                 string itemprefix, valueprefix;
1369                 if(self.spawnflags == 0)
1370                 {
1371                         itemprefix = "";
1372                         valueprefix = "";
1373                 }
1374                 else if(self.spawnflags == 1)
1375                 {
1376                         itemprefix = "max ";
1377                         valueprefix = "max ";
1378                 }
1379                 else if(self.spawnflags == 2)
1380                 {
1381                         itemprefix = "min ";
1382                         valueprefix = "min ";
1383                 }
1384                 else if(self.spawnflags == 4)
1385                 {
1386                         itemprefix = "minus ";
1387                         valueprefix = "max ";
1388                 }
1389                 else
1390                         error("invalid spawnflags");
1391
1392                 self.netname = "";
1393                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1394                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1395                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1396                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1397                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1398                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1399                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1400                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1401                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1402                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1403                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1404                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1405                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1406                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1407                 {
1408                         e = get_weaponinfo(j);
1409                         if(e.weapons)
1410                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1411                 }
1412         }
1413         self.netname = strzone(self.netname);
1414         //print(self.netname, "\n");
1415
1416         n = tokenize_console(self.netname);
1417         for(i = 0; i < n; ++i)
1418         {
1419                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1420                 {
1421                         e = get_weaponinfo(j);
1422                         if(argv(i) == e.netname)
1423                         {
1424                                 weapon_action(e.weapon, WR_PRECACHE);
1425                                 break;
1426                         }
1427                 }
1428         }
1429 }
1430
1431 void spawnfunc_item_fuel(void)
1432 {
1433         if(!self.ammo_fuel)
1434                 self.ammo_fuel = g_pickup_fuel;
1435         if(!self.pickup_anyway)
1436                 self.pickup_anyway = g_pickup_ammo_anyway;
1437         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1438 }
1439
1440 void spawnfunc_item_fuel_regen(void)
1441 {
1442         if(start_items & IT_FUEL_REGEN)
1443         {
1444                 spawnfunc_item_fuel();
1445                 return;
1446         }
1447         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1448 }
1449
1450 void spawnfunc_item_jetpack(void)
1451 {
1452         if(g_grappling_hook)
1453                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1454         if(!self.ammo_fuel)
1455                 self.ammo_fuel = g_pickup_fuel_jetpack;
1456         if(start_items & IT_JETPACK)
1457         {
1458                 spawnfunc_item_fuel();
1459                 return;
1460         }
1461         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1462 }
1463
1464
1465 #define OP_SET 0
1466 #define OP_MIN 1
1467 #define OP_MAX 2
1468 #define OP_PLUS 3
1469 #define OP_MINUS 4
1470
1471 float GiveBit(entity e, .float fld, float bit, float op, float val)
1472 {
1473         float v0, v1;
1474         v0 = (e.fld & bit);
1475         switch(op)
1476         {
1477                 case OP_SET:
1478                         if(val > 0)
1479                                 e.fld |= bit;
1480                         else
1481                                 e.fld &~= bit;
1482                         break;
1483                 case OP_MIN:
1484                 case OP_PLUS:
1485                         if(val > 0)
1486                                 e.fld |= bit;
1487                         break;
1488                 case OP_MAX:
1489                         if(val <= 0)
1490                                 e.fld &~= bit;
1491                         break;
1492                 case OP_MINUS:
1493                         if(val > 0)
1494                                 e.fld &~= bit;
1495                         break;
1496         }
1497         v1 = (e.fld & bit);
1498         return (v0 != v1);
1499 }
1500
1501 float GiveValue(entity e, .float fld, float op, float val)
1502 {
1503         float v0, v1;
1504         v0 = e.fld;
1505         switch(op)
1506         {
1507                 case OP_SET:
1508                         e.fld = val;
1509                         break;
1510                 case OP_MIN:
1511                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1512                         break;
1513                 case OP_MAX:
1514                         e.fld = min(e.fld, val);
1515                         break;
1516                 case OP_PLUS:
1517                         e.fld += val;
1518                         break;
1519                 case OP_MINUS:
1520                         e.fld -= val;
1521                         break;
1522         }
1523         v1 = e.fld;
1524         return (v0 != v1);
1525 }
1526
1527 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1528 {
1529         if(v1 == v0)
1530                 return;
1531         if(v1 <= v0 - t)
1532         {
1533                 if(snd_decr != "")
1534                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1535         }
1536         else if(v0 >= v0 + t)
1537         {
1538                 if(snd_incr != "")
1539                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1540         }
1541 }
1542
1543 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1544 {
1545         if(v0 < v1)
1546                 e.rotfield = max(e.rotfield, time + rottime);
1547         else if(v0 > v1)
1548                 e.regenfield = max(e.regenfield, time + regentime);
1549 }
1550
1551 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1552 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1553 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1554 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1555
1556 float GiveItems(entity e, float beginarg, float endarg)
1557 {
1558         float got, i, j, val, op;
1559         float _switchweapon;
1560         entity wi;
1561         string cmd;
1562
1563         val = 999;
1564         op = OP_SET;
1565
1566         got = 0;
1567
1568         _switchweapon = FALSE;
1569         if (e.autoswitch)
1570                 if (e.switchweapon == w_getbestweapon(e))
1571                         _switchweapon = TRUE;
1572
1573         e.strength_finished = max(0, e.strength_finished - time);
1574         e.invincible_finished = max(0, e.invincible_finished - time);
1575
1576         PREGIVE(e, items);
1577         PREGIVE(e, weapons);
1578         PREGIVE(e, strength_finished);
1579         PREGIVE(e, invincible_finished);
1580         PREGIVE(e, ammo_nails);
1581         PREGIVE(e, ammo_cells);
1582         PREGIVE(e, ammo_shells);
1583         PREGIVE(e, ammo_rockets);
1584         PREGIVE(e, ammo_fuel);
1585         PREGIVE(e, armorvalue);
1586         PREGIVE(e, health);
1587
1588         for(i = beginarg; i < endarg; ++i)
1589         {
1590                 cmd = argv(i);
1591
1592                 if(cmd == "0" || stof(cmd))
1593                 {
1594                         val = stof(cmd);
1595                         continue;
1596                 }
1597                 switch(cmd)
1598                 {
1599                         case "no":
1600                                 op = OP_MAX;
1601                                 val = 0;
1602                                 continue;
1603                         case "max":
1604                                 op = OP_MAX;
1605                                 continue;
1606                         case "min":
1607                                 op = OP_MIN;
1608                                 continue;
1609                         case "plus":
1610                                 op = OP_PLUS;
1611                                 continue;
1612                         case "minus":
1613                                 op = OP_MINUS;
1614                                 continue;
1615                         case "ALL":
1616                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1617                                 got += GiveValue(e, strength_finished, op, time);
1618                                 got += GiveValue(e, invincible_finished, op, time);
1619                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1620                         case "all":
1621                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1622                                 got += GiveValue(e, health, op, val);
1623                                 got += GiveValue(e, armorvalue, op, val);
1624                         case "allweapons":
1625                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1626                                 {
1627                                         wi = get_weaponinfo(j);
1628                                         if(wi.weapons)
1629                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1630                                 }
1631                         case "allammo":
1632                                 got += GiveValue(e, ammo_cells, op, val);
1633                                 got += GiveValue(e, ammo_shells, op, val);
1634                                 got += GiveValue(e, ammo_nails, op, val);
1635                                 got += GiveValue(e, ammo_rockets, op, val);
1636                                 got += GiveValue(e, ammo_fuel, op, val);
1637                                 break;
1638                         case "unlimited_ammo":
1639                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1640                                 break;
1641                         case "unlimited_weapon_ammo":
1642                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1643                                 break;
1644                         case "unlimited_superweapons":
1645                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1646                                 break;
1647                         case "jetpack":
1648                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1649                                 break;
1650                         case "fuel_regen":
1651                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1652                                 break;
1653                         case "strength":
1654                                 got += GiveValue(e, strength_finished, op, val);
1655                                 break;
1656                         case "invincible":
1657                                 got += GiveValue(e, invincible_finished, op, val);
1658                                 break;
1659                         case "cells":
1660                                 got += GiveValue(e, ammo_cells, op, val);
1661                                 break;
1662                         case "shells":
1663                                 got += GiveValue(e, ammo_shells, op, val);
1664                                 break;
1665                         case "nails":
1666                         case "bullets":
1667                                 got += GiveValue(e, ammo_nails, op, val);
1668                                 break;
1669                         case "rockets":
1670                                 got += GiveValue(e, ammo_rockets, op, val);
1671                                 break;
1672                         case "health":
1673                                 got += GiveValue(e, health, op, val);
1674                                 break;
1675                         case "armor":
1676                                 got += GiveValue(e, armorvalue, op, val);
1677                                 break;
1678                         case "fuel":
1679                                 got += GiveValue(e, ammo_fuel, op, val);
1680                                 break;
1681                         default:
1682                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1683                                 {
1684                                         wi = get_weaponinfo(j);
1685                                         if(cmd == wi.netname)
1686                                         {
1687                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1688                                                 break;
1689                                         }
1690                                 }
1691                                 if(j > WEP_LAST)
1692                                         print("give: invalid item ", cmd, "\n");
1693                                 break;
1694                 }
1695                 val = 999;
1696                 op = OP_SET;
1697         }
1698
1699         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1700         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1701         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1702         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1703         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1704         {
1705                 wi = get_weaponinfo(j);
1706                 if(wi.weapons)
1707                 {
1708                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1709                         if not(save_weapons & wi.weapons)
1710                                 if(e.weapons & wi.weapons)
1711                                         weapon_action(wi.weapon, WR_PRECACHE);
1712                 }
1713         }
1714         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1715         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1716         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1717         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1718         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1719         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1720         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1721         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1722         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1723
1724         if (g_minstagib)
1725         {
1726                 e.health = bound(0, e.health, 100);
1727                 e.armorvalue = bound(0, e.armorvalue, 999);
1728         }
1729
1730         if(e.strength_finished <= 0)
1731                 e.strength_finished = 0;
1732         else
1733                 e.strength_finished += time;
1734         if(e.invincible_finished <= 0)
1735                 e.invincible_finished = 0;
1736         else
1737                 e.invincible_finished += time;
1738
1739         if not(e.weapons & W_WeaponBit(e.switchweapon))
1740                 _switchweapon = TRUE;
1741         if(_switchweapon)
1742                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1743
1744         return got;
1745 }