turn NIX into a mutator; fix keyhunt
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / t_items.qc
1 #define ITEM_RESPAWN_TICKS 10
2
3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
6         // range: 10 .. respawntime + respawntimejitter
7
8 floatfield Item_CounterField(float it)
9 {
10         switch(it)
11         {
12                 case IT_SHELLS:      return ammo_shells;
13                 case IT_NAILS:       return ammo_nails;
14                 case IT_ROCKETS:     return ammo_rockets;
15                 case IT_CELLS:       return ammo_cells;
16                 case IT_FUEL:        return ammo_fuel;
17                 case IT_5HP:         return health;
18                 case IT_25HP:        return health;
19                 case IT_HEALTH:      return health;
20                 case IT_ARMOR_SHARD: return armorvalue;
21                 case IT_ARMOR:       return armorvalue;
22                 // add more things here (health, armor)
23                 default:             error("requested item has no counter field");
24         }
25 }
26
27 string Item_CounterFieldName(float it)
28 {
29         switch(it)
30         {
31                 case IT_SHELLS:      return "shells";
32                 case IT_NAILS:       return "nails";
33                 case IT_ROCKETS:     return "rockets";
34                 case IT_CELLS:       return "cells";
35                 case IT_FUEL:        return "fuel";
36
37                 // add more things here (health, armor)
38                 default:             error("requested item has no counter field name");
39         }
40 }
41
42 .float max_armorvalue;
43
44 float Item_Customize()
45 {
46         if(self.spawnshieldtime)
47                 return TRUE;
48         if(self.weapons != (self.weapons & other.weapons))
49         {
50                 self.colormod = '0 0 0';
51                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
52                         self.glowmod = self.colormod;
53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
54                 return TRUE;
55         }
56         else
57         {
58                 if(g_ghost_items)
59                 {
60                         self.colormod = stov(cvar_string("g_ghost_items_color"));
61                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
62                                 self.glowmod = self.colormod;
63                         self.alpha = g_ghost_items;
64                         return TRUE;
65                 }
66                 else
67                         return FALSE;
68         }
69 }
70
71 void Item_Show (entity e, float mode)
72 {
73         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
74         if (mode > 0)
75         {
76                 // make the item look normal, and be touchable
77                 e.model = e.mdl;
78                 e.solid = SOLID_TRIGGER;
79                 e.colormod = '0 0 0';
80                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
81                         self.glowmod = self.colormod;
82                 e.alpha = 0;
83                 e.customizeentityforclient = func_null;
84
85                 e.spawnshieldtime = 1;
86         }
87         else if (mode < 0)
88         {
89                 // hide the item completely
90                 e.model = string_null;
91                 e.solid = SOLID_NOT;
92                 e.colormod = '0 0 0';
93                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
94                         self.glowmod = self.colormod;
95                 e.alpha = 0;
96                 e.customizeentityforclient = func_null;
97
98                 e.spawnshieldtime = 1;
99         }
100         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
101         {
102                 // make the item translucent green and not touchable
103                 e.model = e.mdl;
104                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
105                 e.colormod = '0 0 0';
106                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
107                         self.glowmod = self.colormod;
108                 e.effects |= EF_STARDUST;
109                 e.customizeentityforclient = Item_Customize;
110
111                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
112         }
113         else if(g_ghost_items)
114         {
115                 // make the item translucent green and not touchable
116                 e.model = e.mdl;
117                 e.solid = SOLID_NOT;
118                 e.colormod = stov(cvar_string("g_ghost_items_color"));
119                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
120                         self.glowmod = self.colormod;
121                 e.alpha = g_ghost_items;
122                 e.customizeentityforclient = func_null;
123
124                 e.spawnshieldtime = 1;
125         }
126         else
127         {
128                 // hide the item completely
129                 e.model = string_null;
130                 e.solid = SOLID_NOT;
131                 e.colormod = stov(cvar_string("g_ghost_items_color"));
132                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
133                         self.glowmod = self.colormod;
134                 e.alpha = 0;
135                 e.customizeentityforclient = func_null;
136
137                 e.spawnshieldtime = 1;
138         }
139
140         if (e.strength_finished || e.invincible_finished)
141                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
142         if (cvar("g_nodepthtestitems"))
143                 e.effects |= EF_NODEPTHTEST;
144         if (cvar("g_fullbrightitems"))
145                 e.effects |= EF_FULLBRIGHT;
146
147         // relink entity (because solid may have changed)
148         setorigin(e, e.origin);
149 }
150
151 void Item_Respawn (void)
152 {
153         Item_Show(self, 1);
154         if(!g_minstagib && self.items == IT_STRENGTH)
155                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
156         else if(!g_minstagib && self.items == IT_INVINCIBLE)
157                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
158         else
159                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
160         setorigin (self, self.origin);
161
162         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
163         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
164 }
165
166 void Item_RespawnCountdown (void)
167 {
168         if(self.count >= ITEM_RESPAWN_TICKS)
169         {
170                 if(self.waypointsprite_attached)
171                         WaypointSprite_Kill(self.waypointsprite_attached);
172                 Item_Respawn();
173         }
174         else
175         {
176                 self.nextthink = time + 1;
177                 self.count += 1;
178                 if(self.count == 1)
179                 {
180                         string name;
181                         vector rgb;
182                         name = string_null;
183                         if(g_minstagib)
184                         {
185                                 switch(self.items)
186                                 {
187                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
188                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
189                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
190                                 }
191                         }
192                         else
193                         {
194                                 switch(self.items)
195                                 {
196                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
197                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
198                                 }
199                         }
200                         switch(self.items)
201                         {
202                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
203                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
204                         }
205                         if(name)
206                         {
207                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
208                                 if(self.waypointsprite_attached)
209                                 {
210                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
211                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
212                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
213                                 }
214                         }
215                 }
216                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
217                 if(self.waypointsprite_attached)
218                 {
219                         WaypointSprite_Ping(self.waypointsprite_attached);
220                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
221                 }
222         }
223 }
224
225 void Item_ScheduleRespawnIn(entity e, float t)
226 {
227         if(e.flags & FL_POWERUP)
228         {
229                 e.think = Item_RespawnCountdown;
230                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
231                 e.count = 0;
232         }
233         else
234         {
235                 e.think = Item_Respawn;
236                 e.nextthink = time + t;
237         }
238 }
239
240 void Item_ScheduleRespawn(entity e)
241 {
242         Item_Show(e, 0);
243         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
244 }
245
246 void Item_ScheduleInitialRespawn(entity e)
247 {
248         Item_Show(e, 0);
249         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
250 }
251
252 float Item_GiveTo(entity item, entity player)
253 {
254         float _switchweapon;
255         float pickedup;
256         float it;
257         float i;
258         entity e;
259
260         // if nothing happens to player, just return without taking the item
261         pickedup = FALSE;
262         _switchweapon = FALSE;
263
264         if (g_minstagib)
265         {
266                 if(item.spawnshieldtime)
267                 {
268                         if (item.ammo_fuel)
269                         if (player.ammo_fuel < g_pickup_fuel_max)
270                         {
271                                 pickedup = TRUE;
272                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
273                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
274                         }
275                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
276                         {
277                                 pickedup = TRUE;
278                                 player.items |= it;
279                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
280                         }
281
282                         _switchweapon = TRUE;
283                         if (item.ammo_cells)
284                         {
285                                 pickedup = TRUE;
286                                 // play some cool sounds ;)
287                                 centerprint(player, "\n");
288                                 if (clienttype(player) == CLIENTTYPE_REAL)
289                                 {
290                                         if(player.health <= 5)
291                                                 AnnounceTo(player, "lastsecond");
292                                         else if(player.health < 50)
293                                                 AnnounceTo(player, "narrowly");
294                                 }
295                                 // sound not available
296                                 // else if(item.items == IT_CELLS)
297                                 //      AnnounceTo(player, "ammo");
298
299                                 if (item.weapons & WEPBIT_MINSTANEX)
300                                         W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
301                                 if (item.ammo_cells)
302                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
303                                 player.health = 100;
304                         }
305
306                         // extralife powerup
307                         if (item.max_health)
308                         {
309                                 pickedup = TRUE;
310                                 // sound not available
311                                 // AnnounceTo(player, "_lives");
312                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
313                                 sprint(player, "^3You picked up some extra lives\n");
314                         }
315
316                         // invis powerup
317                         if (item.strength_finished)
318                         {
319                                 pickedup = TRUE;
320                                 // sound not available
321                                 // AnnounceTo(player, "invisible");
322                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
323                         }
324
325                         // speed powerup
326                         if (item.invincible_finished)
327                         {
328                                 pickedup = TRUE;
329                                 // sound not available
330                                 // AnnounceTo(player, "speed");
331                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
332                         }
333
334                         if (item.ammo_fuel)
335                         if (player.ammo_fuel < g_pickup_fuel_max)
336                         {
337                                 pickedup = TRUE;
338                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
339                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
340                         }
341                 }
342         }
343         else
344         {
345                 if (g_weapon_stay == 1)
346                 if not(item.flags & FL_NO_WEAPON_STAY)
347                 if (item.flags & FL_WEAPON)
348                 {
349                         if(item.classname == "droppedweapon")
350                         {
351                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
352                                         goto skip;
353                         }
354                         else
355                         {
356                                 if (player.weapons & item.weapons)
357                                         goto skip;
358                         }
359                 }
360
361                 // in case the player has autoswitch enabled do the following:
362                 // if the player is using their best weapon before items are given, they
363                 // probably want to switch to an even better weapon after items are given
364                 if (player.autoswitch)
365                 if (player.switchweapon == w_getbestweapon(player))
366                         _switchweapon = TRUE;
367
368                 if not(player.weapons & W_WeaponBit(player.switchweapon))
369                         _switchweapon = TRUE;
370
371                 if(item.spawnshieldtime)
372                 {
373                         if (item.ammo_shells)
374                         if (player.ammo_shells < g_pickup_shells_max)
375                         {
376                                 pickedup = TRUE;
377                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
378                         }
379                         if (item.ammo_nails)
380                         if (player.ammo_nails < g_pickup_nails_max)
381                         {
382                                 pickedup = TRUE;
383                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
384                         }
385                         if (item.ammo_rockets)
386                         if (player.ammo_rockets < g_pickup_rockets_max)
387                         {
388                                 pickedup = TRUE;
389                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
390                         }
391                         if (item.ammo_cells)
392                         if (player.ammo_cells < g_pickup_cells_max)
393                         {
394                                 pickedup = TRUE;
395                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
396                         }
397                         if (item.ammo_fuel)
398                         if (player.ammo_fuel < g_pickup_fuel_max)
399                         {
400                                 pickedup = TRUE;
401                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
402                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
403                         }
404                 }
405
406                 if (item.flags & FL_WEAPON)
407                 if ((it = item.weapons - (item.weapons & player.weapons)))
408                 {
409                         pickedup = TRUE;
410                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
411                         {
412                                 e = get_weaponinfo(i);
413                                 if(it & e.weapons)
414                                         W_GiveWeapon (player, e.weapon, item.netname);
415                         }
416                 }
417
418                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
419                 {
420                         pickedup = TRUE;
421                         player.items |= it;
422                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
423                 }
424
425                 if(item.spawnshieldtime)
426                 {
427                         if (item.strength_finished)
428                         {
429                                 pickedup = TRUE;
430                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
431                         }
432                         if (item.invincible_finished)
433                         {
434                                 pickedup = TRUE;
435                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
436                         }
437
438                         if (item.health)
439                         if (player.health < item.max_health)
440                         {
441                                 pickedup = TRUE;
442                                 player.health = min(player.health + item.health, item.max_health);
443                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
444                         }
445                         if (item.armorvalue)
446                         if (player.armorvalue < item.max_armorvalue)
447                         {
448                                 pickedup = TRUE;
449                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
450                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
451                         }
452                 }
453         }
454
455 :skip
456         // always eat teamed entities
457         if(item.team)
458                 pickedup = TRUE;
459
460         if (!pickedup)
461                 return 0;
462
463         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
464         if (_switchweapon)
465                 if (player.switchweapon != w_getbestweapon(player))
466                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
467
468         return 1;
469 }
470
471 void Item_Touch (void)
472 {
473         entity e, head;
474
475         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
476         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
477         {
478                 remove(self);
479                 return;
480         }
481         if (other.classname != "player")
482                 return;
483         if (other.deadflag)
484                 return;
485         if (self.solid != SOLID_TRIGGER)
486                 return;
487         if (self.owner == other)
488                 return;
489
490         if(!Item_GiveTo(self, other))
491                 return;
492
493         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
494
495         if (self.classname == "droppedweapon")
496                 remove (self);
497         else if not(self.spawnshieldtime)
498                 return;
499         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
500                 return;
501         else
502         {
503                 if(self.team)
504                 {
505                         RandomSelection_Init();
506                         for(head = world; (head = findfloat(head, team, self.team)); )
507                         {
508                                 if(head.flags & FL_ITEM)
509                                 {
510                                         Item_Show(head, -1);
511                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
512                                 }
513                         }
514                         e = RandomSelection_chosen_ent;
515                 }
516                 else
517                         e = self;
518                 Item_ScheduleRespawn(e);
519         }
520 }
521
522 void Item_FindTeam()
523 {
524         entity head, e;
525
526         if(self.effects & EF_NODRAW)
527         {
528                 // marker for item team search
529                 dprint("Initializing item team ", ftos(self.team), "\n");
530                 RandomSelection_Init();
531                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
532                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
533                 e = RandomSelection_chosen_ent;
534                 e.state = 0;
535                 Item_Show(e, 1);
536
537                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
538                 {
539                         if(head != e)
540                         {
541                                 // make it a non-spawned item
542                                 Item_Show(head, -1);
543                                 head.state = 1; // state 1 = initially hidden item
544                         }
545                         head.effects &~= EF_NODRAW;
546                 }
547
548                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
549                         Item_ScheduleInitialRespawn(e);
550         }
551 }
552
553 void Item_Reset()
554 {
555         Item_Show(self, !self.state);
556         setorigin (self, self.origin);
557         self.think = SUB_Null;
558         self.nextthink = 0;
559
560         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
561                 Item_ScheduleInitialRespawn(self);
562 }
563
564 // Savage: used for item garbage-collection
565 // TODO: perhaps nice special effect?
566 void RemoveItem(void)
567 {
568         remove(self);
569 }
570
571 // pickup evaluation functions
572 // these functions decide how desirable an item is to the bots
573
574 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
575
576 float weapon_pickupevalfunc(entity player, entity item)
577 {
578         float c, i, j, position;
579
580         // See if I have it already
581         if(player.weapons & item.weapons == item.weapons)
582         {
583                 // If I can pick it up
584                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
585                         c = 0;
586                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
587                 {
588                         // Skilled bots will grab more
589                         c = bound(0, skill / 10, 1) * 0.5;
590                 }
591                 else
592                         c = 0;
593         }
594         else
595                 c = 1;
596
597         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
598         if( bot_custom_weapon && c )
599         {
600                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
601                 {
602                         // Find weapon
603                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
604                                 continue;
605
606                         // Find the highest position on any range
607                         position = -1;
608                         for(j = 0; j < WEP_LAST ; ++j){
609                                 if(
610                                                 bot_weapons_far[j] == i ||
611                                                 bot_weapons_mid[j] == i ||
612                                                 bot_weapons_close[j] == i
613                                   )
614                                 {
615                                         position = j;
616                                         break;
617                                 }
618                         }
619
620                         // Rate it
621                         if (position >= 0 )
622                         {
623                                 position = WEP_LAST - position;
624                                 // item.bot_pickupbasevalue is overwritten here
625                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
626                         }
627                 }
628         }
629
630         return item.bot_pickupbasevalue * c;
631 };
632
633 float commodity_pickupevalfunc(entity player, entity item)
634 {
635         float c, i, need_shells, need_nails, need_rockets, need_cells;
636         entity wi;
637         c = 0;
638
639         // Detect needed ammo
640         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
641         {
642                 wi = get_weaponinfo(i);
643
644                 if not(wi.weapons & player.weapons)
645                         continue;
646
647                 if(wi.items & IT_SHELLS)
648                         need_shells = TRUE;
649                 else if(wi.items & IT_NAILS)
650                         need_nails = TRUE;
651                 else if(wi.items & IT_ROCKETS)
652                         need_rockets = TRUE;
653                 else if(wi.items & IT_CELLS)
654                         need_cells = TRUE;
655         }
656
657         // TODO: figure out if the player even has the weapon this ammo is for?
658         // may not affect strategy much though...
659         // find out how much more ammo/armor/health the player can hold
660         if (need_shells)
661         if (item.ammo_shells)
662         if (player.ammo_shells < g_pickup_shells_max)
663                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
664         if (need_nails)
665         if (item.ammo_nails)
666         if (player.ammo_nails < g_pickup_nails_max)
667                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
668         if (need_rockets)
669         if (item.ammo_rockets)
670         if (player.ammo_rockets < g_pickup_rockets_max)
671                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
672         if (need_cells)
673         if (item.ammo_cells)
674         if (player.ammo_cells < g_pickup_cells_max)
675                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
676         if (item.armorvalue)
677         if (player.armorvalue < item.max_armorvalue)
678                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
679         if (item.health)
680         if (player.health < item.max_health)
681                 c = c + max(0, 1 - player.health / item.max_health);
682
683         return item.bot_pickupbasevalue * c;
684 };
685
686
687 .float is_item;
688 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
689 {
690         startitem_failed = FALSE;
691
692         // is it a dropped weapon?
693         if (self.classname == "droppedweapon")
694         {
695                 self.reset = SUB_Remove;
696                 // it's a dropped weapon
697                 self.movetype = MOVETYPE_TOSS;
698                 // Savage: remove thrown items after a certain period of time ("garbage collection")
699                 self.think = RemoveItem;
700                 self.nextthink = time + 60;
701                 // don't drop if in a NODROP zone (such as lava)
702                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
703                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
704                 {
705                         startitem_failed = TRUE;
706                         remove(self);
707                         return;
708                 }
709         }
710         else
711         {
712                 self.items = itemid;
713                 self.weapons = weaponid;
714
715                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
716                 {
717                         startitem_failed = TRUE;
718                         remove(self);
719                         return;
720                 }
721
722                 itemid = self.items;
723                 weaponid = self.weapons;
724
725                 self.reset = Item_Reset;
726                 // it's a level item
727                 if(self.spawnflags & 1)
728                         self.noalign = 1;
729                 if (self.noalign)
730                         self.movetype = MOVETYPE_NONE;
731                 else
732                         self.movetype = MOVETYPE_TOSS;
733                 // do item filtering according to game mode and other things
734                 if (!self.noalign)
735                 {
736                         // first nudge it off the floor a little bit to avoid math errors
737                         setorigin(self, self.origin + '0 0 1');
738                         // set item size before we spawn a spawnfunc_waypoint
739                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
740                                 setsize (self, '-16 -16 0', '16 16 48');
741                         else
742                                 setsize (self, '-16 -16 0', '16 16 32');
743                         // note droptofloor returns FALSE if stuck/or would fall too far
744                         droptofloor();
745                         waypoint_spawnforitem(self);
746                 }
747
748                 if(teams_matter)
749                 {
750                         if(self.notteam)
751                         {
752                                 print("removed non-teamplay ", self.classname, "\n");
753                                 startitem_failed = TRUE;
754                                 remove (self);
755                                 return;
756                         }
757                 }
758                 else
759                 {
760                         if(self.notfree)
761                         {
762                                 print("removed non-FFA ", self.classname, "\n");
763                                 startitem_failed = TRUE;
764                                 remove (self);
765                                 return;
766                         }
767                 }
768
769                 if(self.notq3a)
770                 {
771                         // We aren't TA or something like that, so we keep the Q3A entities
772                         print("removed non-Q3A ", self.classname, "\n");
773                         startitem_failed = TRUE;
774                         remove (self);
775                         return;
776                 }
777
778                 /*
779                  * can't do it that way, as it would break maps
780                  * TODO make a target_give like entity another way, that perhaps has
781                  * the weapon name in a key
782                 if(self.targetname)
783                 {
784                         // target_give not yet supported; maybe later
785                         print("removed targeted ", self.classname, "\n");
786                         startitem_failed = TRUE;
787                         remove (self);
788                         return;
789                 }
790                 */
791
792                 if(cvar("spawn_debug") >= 2)
793                 {
794                         entity otheritem;
795                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
796                         {
797                                 if(otheritem.is_item)
798                                 {
799                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
800                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
801                                         error("Mapper sucks.");
802                                 }
803                         }
804                         self.is_item = TRUE;
805                 }
806
807                 weaponsInMap |= weaponid;
808
809                 if(g_lms || g_ca)
810                 {
811                         startitem_failed = TRUE;
812                         remove(self);
813                         return;
814                 }
815                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
816                 {
817                         startitem_failed = TRUE;
818                         remove(self);
819                         return;
820                 }
821                 else if (g_minstagib)
822                 {
823                         // don't remove dropped items and powerups
824                         if (self.classname != "minstagib")
825                         {
826                                 startitem_failed = TRUE;
827                                 remove (self);
828                                 return;
829                         }
830                 }
831                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
832                 {
833                         startitem_failed = TRUE;
834                         remove (self);
835                         return;
836                 }
837
838                 precache_model (itemmodel);
839                 precache_sound (pickupsound);
840                 precache_sound ("misc/itemrespawn.wav");
841                 precache_sound ("misc/itemrespawncountdown.wav");
842
843                 if(itemid == IT_STRENGTH)
844                         precache_sound ("misc/strength_respawn.wav");
845                 if(itemid == IT_INVINCIBLE)
846                         precache_sound ("misc/shield_respawn.wav");
847
848                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
849                         self.target = "###item###"; // for finding the nearest item using find()
850         }
851
852         self.bot_pickup = TRUE;
853         self.bot_pickupevalfunc = pickupevalfunc;
854         self.bot_pickupbasevalue = pickupbasevalue;
855         self.mdl = itemmodel;
856         self.item_pickupsound = pickupsound;
857         // let mappers override respawntime
858         if(!self.respawntime) // both set
859         {
860                 self.respawntime = defaultrespawntime;
861                 self.respawntimejitter = defaultrespawntimejitter;
862         }
863         self.netname = itemname;
864         self.flags = FL_ITEM | itemflags;
865         self.touch = Item_Touch;
866         setmodel (self, self.mdl); // precision set below
867         self.effects |= EF_LOWPRECISION;
868         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
869                 setsize (self, '-16 -16 0', '16 16 48');
870         else
871                 setsize (self, '-16 -16 0', '16 16 32');
872         if(itemflags & FL_WEAPON)
873                 self.modelflags |= MF_ROTATE;
874
875         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
876         if (itemflags & FL_WEAPON)
877         {
878                 // neutral team color for pickup weapons
879                 self.colormap = 1024; // color shirt=0 pants=0 grey
880         }
881
882         Item_Show(self, 1);
883         self.state = 0;
884         if(self.team)
885         {
886                 if(!self.cnt)
887                         self.cnt = 1; // item probability weight
888                 self.effects = self.effects | EF_NODRAW; // marker for item team search
889                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
890         }
891         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
892                 Item_ScheduleInitialRespawn(self);
893 }
894
895 /* replace items in minstagib
896  * IT_STRENGTH   = invisibility
897  * IT_NAILS      = extra lives
898  * IT_INVINCIBLE = speed
899  */
900 void minstagib_items (float itemid)
901 {
902         // we don't want to replace dropped weapons ;)
903         if (self.classname == "droppedweapon")
904         {
905                 self.ammo_cells = 25;
906                 StartItem ("models/weapons/g_nex.md3",
907                         "weapons/weaponpickup.wav", 15, 0,
908                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
909                 return;
910         }
911
912         local float rnd;
913         self.classname = "minstagib";
914
915         // replace rocket launchers and nex guns with ammo cells
916         if (itemid == IT_CELLS)
917         {
918                 self.ammo_cells = 1;
919                 StartItem ("models/items/a_cells.md3",
920                         "misc/itempickup.wav", 45, 0,
921                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
922                 return;
923         }
924
925         // randomize
926         rnd = random() * 3;
927         if (rnd <= 1)
928                 itemid = IT_STRENGTH;
929         else if (rnd <= 2)
930                 itemid = IT_NAILS;
931         else
932                 itemid = IT_INVINCIBLE;
933
934         // replace with invis
935         if (itemid == IT_STRENGTH)
936         {
937                 self.strength_finished = 30;
938                 StartItem ("models/items/g_strength.md3",
939                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
940                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
941         }
942         // replace with extra lives
943         if (itemid == IT_NAILS)
944         {
945                 self.max_health = 1;
946                 StartItem ("models/items/g_h100.md3",
947                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
948                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
949
950         }
951         // replace with speed
952         if (itemid == IT_INVINCIBLE)
953         {
954                 self.invincible_finished = 30;
955                 StartItem ("models/items/g_invincible.md3",
956                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
957                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
958         }
959
960 }
961
962 float minst_no_auto_cells;
963 void minst_remove_item (void) {
964         if(minst_no_auto_cells)
965                 remove(self);
966 }
967
968 float weaponswapping;
969 float internalteam;
970
971 void weapon_defaultspawnfunc(float wpn)
972 {
973         entity e;
974         float t;
975         var .float ammofield;
976         string s;
977         entity oldself;
978         float i, j;
979
980         // set the respawntime in advance (so replaced weapons can copy it)
981
982         if(!self.respawntime)
983         {
984                 e = get_weaponinfo(wpn);
985                 if(e.items == IT_SUPERWEAPON)
986                 {
987                         self.respawntime = g_pickup_respawntime_powerup;
988                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
989                 }
990                 else
991                 {
992                         self.respawntime = g_pickup_respawntime_weapon;
993                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
994                 }
995         }
996
997         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
998         {
999                 e = get_weaponinfo(wpn);
1000                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1001                 if(s == "0")
1002                 {
1003                         remove(self);
1004                         startitem_failed = TRUE;
1005                         return;
1006                 }
1007                 t = tokenize_console(s);
1008                 if(t >= 2)
1009                 {
1010                         self.team = --internalteam;
1011                         oldself = self;
1012                         for(i = 1; i < t; ++i)
1013                         {
1014                                 s = argv(i);
1015                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1016                                 {
1017                                         e = get_weaponinfo(j);
1018                                         if(e.netname == s)
1019                                         {
1020                                                 self = spawn();
1021                                                 copyentity(oldself, self);
1022                                                 self.classname = "replacedweapon";
1023                                                 weapon_defaultspawnfunc(j);
1024                                                 break;
1025                                         }
1026                                 }
1027                                 if(j > WEP_LAST)
1028                                 {
1029                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1030                                 }
1031                         }
1032                         self = oldself;
1033                 }
1034                 if(t >= 1)
1035                 {
1036                         s = argv(0);
1037                         wpn = 0;
1038                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1039                         {
1040                                 e = get_weaponinfo(j);
1041                                 if(e.netname == s)
1042                                 {
1043                                         wpn = j;
1044                                         break;
1045                                 }
1046                         }
1047                         if(j > WEP_LAST)
1048                         {
1049                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1050                         }
1051                 }
1052                 if(wpn == 0)
1053                 {
1054                         remove(self);
1055                         startitem_failed = TRUE;
1056                         return;
1057                 }
1058         }
1059
1060         e = get_weaponinfo(wpn);
1061
1062         if(e.items && e.items != IT_SUPERWEAPON)
1063         {
1064                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1065                 {
1066                         if(e.items & j)
1067                         {
1068                                 ammofield = Item_CounterField(j);
1069                                 if(!self.ammofield)
1070                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1071                         }
1072                 }
1073         }
1074         else
1075         {
1076                 self.flags |= FL_NO_WEAPON_STAY;
1077         }
1078
1079         // weapon stay isn't supported for teamed weapons
1080         if(self.team)
1081                 self.flags |= FL_NO_WEAPON_STAY;
1082
1083         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1084         {
1085                 self.ammo_shells = 0;
1086                 self.ammo_nails = 0;
1087                 self.ammo_cells = 0;
1088                 self.ammo_rockets = 0;
1089                 // weapon stay 2: don't use ammo on weapon pickups; instead
1090                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1091         }
1092
1093         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1094         if (self.modelindex) // don't precache if self was removed
1095                 weapon_action(e.weapon, WR_PRECACHE);
1096 }
1097
1098 void spawnfunc_weapon_shotgun (void);
1099 void spawnfunc_weapon_uzi (void) {
1100         if(q3acompat_machineshotgunswap)
1101         if(self.classname != "droppedweapon")
1102         {
1103                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1104                 return;
1105         }
1106         weapon_defaultspawnfunc(WEP_UZI);
1107 }
1108
1109 void spawnfunc_weapon_shotgun (void) {
1110         if(q3acompat_machineshotgunswap)
1111         if(self.classname != "droppedweapon")
1112         {
1113                 weapon_defaultspawnfunc(WEP_UZI);
1114                 return;
1115         }
1116         weapon_defaultspawnfunc(WEP_SHOTGUN);
1117 }
1118
1119 void spawnfunc_weapon_nex (void)
1120 {
1121         if (g_minstagib)
1122         {
1123                 minstagib_items(IT_CELLS);
1124                 self.think = minst_remove_item;
1125                 self.nextthink = time;
1126                 return;
1127         }
1128         weapon_defaultspawnfunc(WEP_NEX);
1129 }
1130
1131 void spawnfunc_weapon_minstanex (void)
1132 {
1133         if (g_minstagib)
1134         {
1135                 minstagib_items(IT_CELLS);
1136                 self.think = minst_remove_item;
1137                 self.nextthink = time;
1138                 return;
1139         }
1140         weapon_defaultspawnfunc(WEP_MINSTANEX);
1141 }
1142
1143 void spawnfunc_weapon_rocketlauncher (void)
1144 {
1145         if (g_minstagib)
1146         {
1147                 minstagib_items(IT_CELLS);
1148                 self.think = minst_remove_item;
1149                 self.nextthink = time;
1150                 return;
1151         }
1152         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1153 }
1154
1155 void spawnfunc_item_rockets (void) {
1156         if(!self.ammo_rockets)
1157                 self.ammo_rockets = g_pickup_rockets;
1158         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1159 }
1160
1161 void spawnfunc_item_shells (void);
1162 void spawnfunc_item_bullets (void) {
1163         if(!weaponswapping)
1164         if(q3acompat_machineshotgunswap)
1165         if(self.classname != "droppedweapon")
1166         {
1167                 weaponswapping = TRUE;
1168                 spawnfunc_item_shells();
1169                 weaponswapping = FALSE;
1170                 return;
1171         }
1172
1173         if(!self.ammo_nails)
1174                 self.ammo_nails = g_pickup_nails;
1175         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1176 }
1177
1178 void spawnfunc_item_cells (void) {
1179         if(!self.ammo_cells)
1180                 self.ammo_cells = g_pickup_cells;
1181         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1182 }
1183
1184 void spawnfunc_item_shells (void) {
1185         if(!weaponswapping)
1186         if(q3acompat_machineshotgunswap)
1187         if(self.classname != "droppedweapon")
1188         {
1189                 weaponswapping = TRUE;
1190                 spawnfunc_item_bullets();
1191                 weaponswapping = FALSE;
1192                 return;
1193         }
1194
1195         if(!self.ammo_shells)
1196                 self.ammo_shells = g_pickup_shells;
1197         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1198 }
1199
1200 void spawnfunc_item_armor_small (void) {
1201         if(!self.armorvalue)
1202                 self.armorvalue = g_pickup_armorsmall;
1203         if(!self.max_armorvalue)
1204                 self.max_armorvalue = g_pickup_armorsmall_max;
1205         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1206 }
1207
1208 void spawnfunc_item_armor_medium (void) {
1209         if(!self.armorvalue)
1210                 self.armorvalue = g_pickup_armormedium;
1211         if(!self.max_armorvalue)
1212                 self.max_armorvalue = g_pickup_armormedium_max;
1213         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1214 }
1215
1216 void spawnfunc_item_armor_big (void) {
1217         if(!self.armorvalue)
1218                 self.armorvalue = g_pickup_armorbig;
1219         if(!self.max_armorvalue)
1220                 self.max_armorvalue = g_pickup_armorbig_max;
1221         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1222 }
1223
1224 void spawnfunc_item_armor_large (void) {
1225         if(!self.armorvalue)
1226                 self.armorvalue = g_pickup_armorlarge;
1227         if(!self.max_armorvalue)
1228                 self.max_armorvalue = g_pickup_armorlarge_max;
1229         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1230 }
1231
1232 void spawnfunc_item_health_small (void) {
1233         if(!self.max_health)
1234                 self.max_health = g_pickup_healthsmall_max;
1235         if(!self.health)
1236                 self.health = g_pickup_healthsmall;
1237         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1238 }
1239
1240 void spawnfunc_item_health_medium (void) {
1241         if(!self.max_health)
1242                 self.max_health = g_pickup_healthmedium_max;
1243         if(!self.health)
1244                 self.health = g_pickup_healthmedium;
1245         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1246 }
1247
1248 void spawnfunc_item_health_large (void) {
1249         if(!self.max_health)
1250                 self.max_health = g_pickup_healthlarge_max;
1251         if(!self.health)
1252                 self.health = g_pickup_healthlarge;
1253         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1254 }
1255
1256 void spawnfunc_item_health_mega (void) {
1257         if(!cvar("g_powerup_superhealth"))
1258                 return;
1259
1260         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1261                 return;
1262
1263         if(g_minstagib) {
1264                 minstagib_items(IT_NAILS);
1265         } else {
1266                 if(!self.max_health)
1267                         self.max_health = g_pickup_healthmega_max;
1268                 if(!self.health)
1269                         self.health = g_pickup_healthmega;
1270                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1271         }
1272 }
1273
1274 // support old misnamed entities
1275 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1276 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1277 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1278 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1279 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1280
1281 void spawnfunc_item_strength (void) {
1282         if(!cvar("g_powerup_strength"))
1283                 return;
1284
1285         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1286                 return;
1287
1288         if(g_minstagib) {
1289                 minstagib_items(IT_STRENGTH);
1290         } else {
1291                 precache_sound("weapons/strength_fire.wav");
1292                 self.strength_finished = 30;
1293                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1294         }
1295 }
1296
1297 void spawnfunc_item_invincible (void) {
1298         if(!cvar("g_powerup_shield"))
1299                 return;
1300
1301         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1302                 return;
1303
1304         if(g_minstagib) {
1305                 minstagib_items(IT_INVINCIBLE);
1306         } else {
1307                 self.invincible_finished = 30;
1308                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1309         }
1310 }
1311
1312 void spawnfunc_item_minst_cells (void) {
1313         if (g_minstagib)
1314         {
1315                 minst_no_auto_cells = 1;
1316                 minstagib_items(IT_CELLS);
1317         }
1318         else
1319                 remove(self);
1320 }
1321
1322 // compatibility:
1323 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1324
1325 float GiveItems(entity e, float beginarg, float endarg);
1326 void target_items_use (void)
1327 {
1328         if(activator.classname == "droppedweapon")
1329         {
1330                 EXACTTRIGGER_TOUCH;
1331                 remove(activator);
1332                 return;
1333         }
1334
1335         if(activator.classname != "player")
1336                 return;
1337         if(activator.deadflag != DEAD_NO)
1338                 return;
1339         EXACTTRIGGER_TOUCH;
1340
1341         entity e;
1342         for(e = world; (e = find(e, classname, "droppedweapon")); )
1343                 if(e.enemy == activator)
1344                         remove(e);
1345
1346         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1347                 centerprint(activator, self.message);
1348 }
1349
1350 void spawnfunc_target_items (void)
1351 {
1352         float n, i, j;
1353         entity e;
1354
1355         self.use = target_items_use;
1356         if(!self.strength_finished)
1357                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1358         if(!self.invincible_finished)
1359                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1360
1361         precache_sound("misc/itempickup.wav");
1362         precache_sound("misc/itempickup.wav");
1363         precache_sound("misc/itempickup.wav");
1364         precache_sound("misc/itempickup.wav");
1365         precache_sound("misc/megahealth.wav");
1366         precache_sound("misc/armor25.wav");
1367         precache_sound("misc/powerup.wav");
1368         precache_sound("misc/poweroff.wav");
1369         precache_sound("weapons/weaponpickup.wav");
1370
1371         n = tokenize_console(self.netname);
1372         if(argv(0) == "give")
1373         {
1374                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1375         }
1376         else
1377         {
1378                 for(i = 0; i < n; ++i)
1379                 {
1380                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1381                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1382                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1383                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1384                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1385                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1386                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1387                         else
1388                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1389                         {
1390                                 e = get_weaponinfo(j);
1391                                 if(argv(i) == e.netname)
1392                                 {
1393                                         self.weapons |= e.weapons;
1394                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1395                                                 weapon_action(e.weapon, WR_PRECACHE);
1396                                         break;
1397                                 }
1398                         }
1399                         if(j > WEP_LAST)
1400                                 print("target_items: invalid item ", argv(i), "\n");
1401                 }
1402
1403                 string itemprefix, valueprefix;
1404                 if(self.spawnflags == 0)
1405                 {
1406                         itemprefix = "";
1407                         valueprefix = "";
1408                 }
1409                 else if(self.spawnflags == 1)
1410                 {
1411                         itemprefix = "max ";
1412                         valueprefix = "max ";
1413                 }
1414                 else if(self.spawnflags == 2)
1415                 {
1416                         itemprefix = "min ";
1417                         valueprefix = "min ";
1418                 }
1419                 else if(self.spawnflags == 4)
1420                 {
1421                         itemprefix = "minus ";
1422                         valueprefix = "max ";
1423                 }
1424                 else
1425                         error("invalid spawnflags");
1426
1427                 self.netname = "";
1428                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1429                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1430                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1431                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1432                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1433                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1434                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1435                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1436                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1437                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1438                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1439                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1440                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1441                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1442                 {
1443                         e = get_weaponinfo(j);
1444                         if(e.weapons)
1445                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1446                 }
1447         }
1448         self.netname = strzone(self.netname);
1449         //print(self.netname, "\n");
1450
1451         n = tokenize_console(self.netname);
1452         for(i = 0; i < n; ++i)
1453         {
1454                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1455                 {
1456                         e = get_weaponinfo(j);
1457                         if(argv(i) == e.netname)
1458                         {
1459                                 weapon_action(e.weapon, WR_PRECACHE);
1460                                 break;
1461                         }
1462                 }
1463         }
1464 }
1465
1466 void spawnfunc_item_fuel(void)
1467 {
1468         if(!self.ammo_fuel)
1469                 self.ammo_fuel = g_pickup_fuel;
1470         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1471 }
1472
1473 void spawnfunc_item_fuel_regen(void)
1474 {
1475         if(start_items & IT_FUEL_REGEN)
1476         {
1477                 spawnfunc_item_fuel();
1478                 return;
1479         }
1480         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1481 }
1482
1483 void spawnfunc_item_jetpack(void)
1484 {
1485         if(g_grappling_hook)
1486                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1487         if(!self.ammo_fuel)
1488                 self.ammo_fuel = g_pickup_fuel_jetpack;
1489         if(start_items & IT_JETPACK)
1490         {
1491                 spawnfunc_item_fuel();
1492                 return;
1493         }
1494         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1495 }
1496
1497 // we no longer have the seeker
1498 void spawnfunc_weapon_seeker()
1499 {
1500         spawnfunc_weapon_fireball();
1501 }
1502
1503
1504 #define OP_SET 0
1505 #define OP_MIN 1
1506 #define OP_MAX 2
1507 #define OP_PLUS 3
1508 #define OP_MINUS 4
1509
1510 float GiveBit(entity e, .float fld, float bit, float op, float val)
1511 {
1512         float v0, v1;
1513         v0 = (e.fld & bit);
1514         switch(op)
1515         {
1516                 case OP_SET:
1517                         if(val > 0)
1518                                 e.fld |= bit;
1519                         else
1520                                 e.fld &~= bit;
1521                         break;
1522                 case OP_MIN:
1523                 case OP_PLUS:
1524                         if(val > 0)
1525                                 e.fld |= bit;
1526                         break;
1527                 case OP_MAX:
1528                         if(val <= 0)
1529                                 e.fld &~= bit;
1530                         break;
1531                 case OP_MINUS:
1532                         if(val > 0)
1533                                 e.fld &~= bit;
1534                         break;
1535         }
1536         v1 = (e.fld & bit);
1537         return (v0 != v1);
1538 }
1539
1540 float GiveValue(entity e, .float fld, float op, float val)
1541 {
1542         float v0, v1;
1543         v0 = e.fld;
1544         switch(op)
1545         {
1546                 case OP_SET:
1547                         e.fld = val;
1548                         break;
1549                 case OP_MIN:
1550                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1551                         break;
1552                 case OP_MAX:
1553                         e.fld = min(e.fld, val);
1554                         break;
1555                 case OP_PLUS:
1556                         e.fld += val;
1557                         break;
1558                 case OP_MINUS:
1559                         e.fld -= val;
1560                         break;
1561         }
1562         v1 = e.fld;
1563         return (v0 != v1);
1564 }
1565
1566 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1567 {
1568         if(v1 == v0)
1569                 return;
1570         if(v1 <= v0 - t)
1571         {
1572                 if(snd_decr != "")
1573                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1574         }
1575         else if(v0 >= v0 + t)
1576         {
1577                 if(snd_incr != "")
1578                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1579         }
1580 }
1581
1582 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1583 {
1584         if(v0 < v1)
1585                 e.rotfield = max(e.rotfield, time + rottime);
1586         else if(v0 > v1)
1587                 e.regenfield = max(e.regenfield, time + regentime);
1588 }
1589
1590 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1591 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1592 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1593 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1594
1595 float GiveItems(entity e, float beginarg, float endarg)
1596 {
1597         float got, i, j, val, op;
1598         float _switchweapon;
1599         entity wi;
1600         string cmd;
1601
1602         val = 999;
1603         op = OP_SET;
1604
1605         got = 0;
1606
1607         _switchweapon = FALSE;
1608         if (e.autoswitch)
1609                 if (e.switchweapon == w_getbestweapon(e))
1610                         _switchweapon = TRUE;
1611
1612         e.strength_finished = max(0, e.strength_finished - time);
1613         e.invincible_finished = max(0, e.invincible_finished - time);
1614         
1615         PREGIVE(e, items);
1616         PREGIVE(e, weapons);
1617         PREGIVE(e, strength_finished);
1618         PREGIVE(e, invincible_finished);
1619         PREGIVE(e, ammo_nails);
1620         PREGIVE(e, ammo_cells);
1621         PREGIVE(e, ammo_shells);
1622         PREGIVE(e, ammo_rockets);
1623         PREGIVE(e, ammo_fuel);
1624         PREGIVE(e, armorvalue);
1625         PREGIVE(e, health);
1626
1627         for(i = beginarg; i < endarg; ++i)
1628         {
1629                 cmd = argv(i);
1630
1631                 if(cmd == "0" || stof(cmd))
1632                 {
1633                         val = stof(cmd);
1634                         continue;
1635                 }
1636                 switch(cmd)
1637                 {
1638                         case "no":
1639                                 op = OP_MAX;
1640                                 val = 0;
1641                                 continue;
1642                         case "max":
1643                                 op = OP_MAX;
1644                                 continue;
1645                         case "min":
1646                                 op = OP_MIN;
1647                                 continue;
1648                         case "plus":
1649                                 op = OP_PLUS;
1650                                 continue;
1651                         case "minus":
1652                                 op = OP_MINUS;
1653                                 continue;
1654                         case "ALL":
1655                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1656                                 got += GiveValue(e, strength_finished, op, time + val);
1657                                 got += GiveValue(e, invincible_finished, op, time + val);
1658                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1659                         case "all":
1660                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1661                                 got += GiveValue(e, health, op, val);
1662                                 got += GiveValue(e, armorvalue, op, val);
1663                         case "allweapons":
1664                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1665                                 {
1666                                         wi = get_weaponinfo(j);
1667                                         if(wi.weapons)
1668                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1669                                 }
1670                         case "allammo":
1671                                 got += GiveValue(e, ammo_cells, op, val);
1672                                 got += GiveValue(e, ammo_shells, op, val);
1673                                 got += GiveValue(e, ammo_nails, op, val);
1674                                 got += GiveValue(e, ammo_rockets, op, val);
1675                                 got += GiveValue(e, ammo_fuel, op, val);
1676                                 break;
1677                         case "unlimited_ammo":
1678                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1679                                 break;
1680                         case "unlimited_weapon_ammo":
1681                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1682                                 break;
1683                         case "unlimited_superweapons":
1684                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1685                                 break;
1686                         case "jetpack":
1687                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1688                                 break;
1689                         case "fuel_regen":
1690                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1691                                 break;
1692                         case "strength":
1693                                 got += GiveValue(e, strength_finished, op, val);
1694                                 break;
1695                         case "invincible":
1696                                 got += GiveValue(e, invincible_finished, op, val);
1697                                 break;
1698                         case "cells":
1699                                 got += GiveValue(e, ammo_cells, op, val);
1700                                 break;
1701                         case "shells":
1702                                 got += GiveValue(e, ammo_shells, op, val);
1703                                 break;
1704                         case "nails":
1705                         case "bullets":
1706                                 got += GiveValue(e, ammo_nails, op, val);
1707                                 break;
1708                         case "rockets":
1709                                 got += GiveValue(e, ammo_rockets, op, val);
1710                                 break;
1711                         case "health":
1712                                 got += GiveValue(e, health, op, val);
1713                                 break;
1714                         case "armor":
1715                                 got += GiveValue(e, armorvalue, op, val);
1716                                 break;
1717                         case "fuel":
1718                                 got += GiveValue(e, ammo_fuel, op, val);
1719                                 break;
1720                         default:
1721                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1722                                 {
1723                                         wi = get_weaponinfo(j);
1724                                         if(cmd == wi.netname)
1725                                         {
1726                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1727                                                 break;
1728                                         }
1729                                 }
1730                                 if(j > WEP_LAST)
1731                                         print("give: invalid item ", cmd, "\n");
1732                                 break;
1733                 }
1734                 val = 999;
1735                 op = OP_SET;
1736         }
1737
1738         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1739         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1740         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1741         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1742         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1743         {
1744                 wi = get_weaponinfo(j);
1745                 if(wi.weapons)
1746                 {
1747                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1748                         if not(save_weapons & wi.weapons)
1749                                 if(e.weapons & wi.weapons)
1750                                         weapon_action(wi.weapon, WR_PRECACHE);
1751                 }
1752         }
1753         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1754         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1755         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1756         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1757         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1758         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1759         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1760         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1761         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1762
1763         if(e.strength_finished <= 0)
1764                 e.strength_finished = 0;
1765         else
1766                 e.strength_finished += time;
1767         if(e.invincible_finished <= 0)
1768                 e.invincible_finished = 0;
1769         else
1770                 e.invincible_finished += time;
1771
1772         if not(e.weapons & W_WeaponBit(e.switchweapon))
1773                 _switchweapon = TRUE;
1774         if(_switchweapon)
1775                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1776
1777         return got;
1778 }