qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280         }
 281         else
 282         {
 283                 if(autocvar_g_pickup_items > 0)
 284                         return TRUE;
 285                 if(autocvar_g_pickup_items == 0)
 286                         return FALSE;
 287                 if(g_weaponarena)
 288                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 289                                 return FALSE;
 290         }
 291         return TRUE;
 292 }
 293
 294 #define ITEM_RESPAWN_TICKS 10
 295
 296 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 297         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 298 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 299         // range: 10 .. respawntime + respawntimejitter
 300
 301 floatfield Item_CounterField(float it)
 302 {
 303         switch(it)
 304         {
 305                 case IT_SHELLS:      return ammo_shells;
 306                 case IT_NAILS:       return ammo_nails;
 307                 case IT_ROCKETS:     return ammo_rockets;
 308                 case IT_CELLS:       return ammo_cells;
 309                 case IT_FUEL:        return ammo_fuel;
 310                 case IT_5HP:         return health;
 311                 case IT_25HP:        return health;
 312                 case IT_HEALTH:      return health;
 313                 case IT_ARMOR_SHARD: return armorvalue;
 314                 case IT_ARMOR:       return armorvalue;
 315                 // add more things here (health, armor)
 316                 default:             error("requested item has no counter field");
 317         }
 318 #ifdef GMQCC
 319         // should never happen
 320         return health;
 321 #endif
 322 }
 323
 324 string Item_CounterFieldName(float it)
 325 {
 326         switch(it)
 327         {
 328                 case IT_SHELLS:      return "shells";
 329                 case IT_NAILS:       return "nails";
 330                 case IT_ROCKETS:     return "rockets";
 331                 case IT_CELLS:       return "cells";
 332                 case IT_FUEL:        return "fuel";
 333
 334                 // add more things here (health, armor)
 335                 default:             error("requested item has no counter field name");
 336         }
 337 #ifdef GMQCC
 338         // should never happen
 339         return string_null;
 340 #endif
 341 }
 342
 343 .float max_armorvalue;
 344 .float pickup_anyway;
 345 /*
 346 float Item_Customize()
 347 {
 348         if(self.spawnshieldtime)
 349                 return TRUE;
 350         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 351         {
 352                 self.colormod = '0 0 0';
 353                 self.glowmod = self.colormod;
 354                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 355                 return TRUE;
 356         }
 357         else
 358         {
 359                 if(g_ghost_items)
 360                 {
 361                         self.colormod = stov(autocvar_g_ghost_items_color);
 362                         self.glowmod = self.colormod;
 363                         self.alpha = g_ghost_items;
 364                         return TRUE;
 365                 }
 366                 else
 367                         return FALSE;
 368         }
 369 }
 370 */
 371
 372 void Item_Show (entity e, float mode)
 373 {
 374         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 375         e.ItemStatus &~= ITS_STAYWEP;
 376         if (mode > 0)
 377         {
 378                 // make the item look normal, and be touchable
 379                 e.model = e.mdl;
 380                 e.solid = SOLID_TRIGGER;
 381                 e.spawnshieldtime = 1;
 382                 e.ItemStatus |= ITS_AVAILABLE;
 383         }
 384         else if (mode < 0)
 385         {
 386                 // hide the item completely
 387                 e.model = string_null;
 388                 e.solid = SOLID_NOT;
 389                 e.spawnshieldtime = 1;
 390                 e.ItemStatus &~= ITS_AVAILABLE;
 391         }
 392         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 393         {
 394                 // make the item translucent and not touchable
 395                 e.model = e.mdl;
 396                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 397                 e.effects |= EF_STARDUST;
 398                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 399                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 400         }
 401         else
 402         {
 403                 //setmodel(e, "null");
 404                 e.solid = SOLID_NOT;
 405                 e.colormod = '0 0 0';
 406                 e.glowmod = e.colormod;
 407                 e.spawnshieldtime = 1;
 408                 e.ItemStatus &~= ITS_AVAILABLE;
 409         }
 410
 411         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 412             e.ItemStatus |= ITS_POWERUP;
 413
 414         if (autocvar_g_nodepthtestitems)
 415                 e.effects |= EF_NODEPTHTEST;
 416
 417
 418     if (autocvar_g_fullbrightitems)
 419                 e.ItemStatus |= ITS_ALLOWFB;
 420
 421         if (autocvar_sv_simple_items)
 422         e.ItemStatus |= ITS_ALLOWSI;
 423
 424         // relink entity (because solid may have changed)
 425         setorigin(e, e.origin);
 426     e.SendFlags |= ISF_STATUS;
 427 }
 428
 429 void Item_Respawn (void)
 430 {
 431         Item_Show(self, 1);
 432         // this is ugly...
 433         if(self.items == IT_STRENGTH)
 434                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 435         else if(self.items == IT_INVINCIBLE)
 436                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 437         else
 438                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 439         setorigin (self, self.origin);
 440
 441         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 442         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 443 }
 444
 445 void Item_RespawnCountdown (void)
 446 {
 447         if(self.count >= ITEM_RESPAWN_TICKS)
 448         {
 449                 if(self.waypointsprite_attached)
 450                         WaypointSprite_Kill(self.waypointsprite_attached);
 451                 Item_Respawn();
 452         }
 453         else
 454         {
 455                 self.nextthink = time + 1;
 456                 self.count += 1;
 457                 if(self.count == 1)
 458                 {
 459                         string name;
 460                         vector rgb = '1 0 1';
 461                         name = string_null;
 462                         switch(self.items)
 463                         {
 464                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 465                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 466                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 467                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 468                         }
 469                         item_name = name;
 470                         item_color = rgb;
 471                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 472                         name = item_name;
 473                         rgb = item_color;
 474                         if(self.flags & FL_WEAPON)
 475                         {
 476                                 entity wi = get_weaponinfo(self.weapon);
 477                                 if(wi)
 478                                 {
 479                                         name = wi.model2;
 480                                         rgb = '1 0 0';
 481                                 }
 482                         }
 483                         if(name)
 484                         {
 485                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 486                                 if(self.waypointsprite_attached)
 487                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 488                         }
 489                         else
 490                         {
 491                                 print("Unknown powerup-marked item is wanting to respawn\n");
 492                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 493                         }
 494                 }
 495                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 496                 if(self.waypointsprite_attached)
 497                 {
 498                         WaypointSprite_Ping(self.waypointsprite_attached);
 499                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 500                 }
 501         }
 502 }
 503
 504 void Item_ScheduleRespawnIn(entity e, float t)
 505 {
 506         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 507         {
 508                 e.think = Item_RespawnCountdown;
 509                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 510                 e.count = 0;
 511         }
 512         else
 513         {
 514                 e.think = Item_Respawn;
 515                 e.nextthink = time + t;
 516         }
 517 }
 518
 519 void Item_ScheduleRespawn(entity e)
 520 {
 521         if(e.respawntime > 0)
 522         {
 523                 Item_Show(e, 0);
 524                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 525         }
 526         else // if respawntime is -1, this item does not respawn
 527                 Item_Show(e, -1);
 528 }
 529
 530 void Item_ScheduleInitialRespawn(entity e)
 531 {
 532         Item_Show(e, 0);
 533         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 534 }
 535
 536 float ITEM_MODE_NONE = 0;
 537 float ITEM_MODE_HEALTH = 1;
 538 float ITEM_MODE_ARMOR = 2;
 539 float ITEM_MODE_FUEL = 3;
 540 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 541 {
 542         if (!item.ammofield)
 543                 return FALSE;
 544
 545         if (item.spawnshieldtime)
 546         {
 547                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 548                 {
 549                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 550                         goto YEAH;
 551                 }
 552         }
 553         else if(g_weapon_stay == 2)
 554         {
 555                 float mi = min(item.ammofield, ammomax);
 556                 if (player.ammofield < mi)
 557                 {
 558                         player.ammofield = mi;
 559                         goto YEAH;
 560                 }
 561         }
 562
 563         return FALSE;
 564
 565 :YEAH
 566         switch(mode)
 567         {
 568                 case ITEM_MODE_FUEL:
 569                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 570                         break;
 571                 case ITEM_MODE_HEALTH:
 572                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 573                         break;
 574                 case ITEM_MODE_ARMOR:
 575                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 576                         break;
 577                 default:
 578                         break;
 579         }
 580         return TRUE;
 581 }
 582
 583 float Item_GiveTo(entity item, entity player)
 584 {
 585         float _switchweapon;
 586         float pickedup;
 587         float it;
 588         float i;
 589
 590         // if nothing happens to player, just return without taking the item
 591         pickedup = FALSE;
 592         _switchweapon = FALSE;
 593         // in case the player has autoswitch enabled do the following:
 594         // if the player is using their best weapon before items are given, they
 595         // probably want to switch to an even better weapon after items are given
 596         if (player.autoswitch)
 597         if (player.switchweapon == w_getbestweapon(player))
 598                 _switchweapon = TRUE;
 599
 600         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 601                 _switchweapon = TRUE;
 602
 603         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 604         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 605         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 606         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 607         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 608         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 609         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 610
 611         if (item.flags & FL_WEAPON)
 612         {
 613                 WEPSET_DECLARE_A(it);
 614                 WEPSET_COPY_AE(it, item);
 615                 WEPSET_ANDNOT_AE(it, player);
 616
 617                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && item.pickup_anyway))
 618                 {
 619                         pickedup = TRUE;
 620                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 621                         if(WEPSET_CONTAINS_AW(it, i))
 622                                 W_GiveWeapon(player, i);
 623                 }
 624         }
 625
 626         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 627         {
 628                 pickedup = TRUE;
 629                 player.items |= it;
 630                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 631         }
 632
 633         if (item.strength_finished)
 634         {
 635                 pickedup = TRUE;
 636                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 637         }
 638         if (item.invincible_finished)
 639         {
 640                 pickedup = TRUE;
 641                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 642         }
 643         if (item.superweapons_finished)
 644         {
 645                 pickedup = TRUE;
 646                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 647         }
 648
 649 :skip
 650
 651         // always eat teamed entities
 652         if(item.team)
 653                 pickedup = TRUE;
 654
 655         if (!pickedup)
 656                 return 0;
 657
 658         if (_switchweapon)
 659                 if (player.switchweapon != w_getbestweapon(player))
 660                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 661
 662         return 1;
 663 }
 664
 665 void Item_Touch (void)
 666 {
 667         entity e, head;
 668
 669         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 670         if(self.classname == "droppedweapon")
 671         {
 672                 if (ITEM_TOUCH_NEEDKILL())
 673                 {
 674                         remove(self);
 675                         return;
 676                 }
 677         }
 678
 679         if not(IS_PLAYER(other))
 680                 return;
 681         if (other.frozen)
 682                 return;
 683         if (other.deadflag)
 684                 return;
 685         if (self.solid != SOLID_TRIGGER)
 686                 return;
 687         if (self.owner == other)
 688                 return;
 689
 690         switch(MUTATOR_CALLHOOK(ItemTouch))
 691         {
 692                 case MUT_ITEMTOUCH_RETURN: { return; }
 693                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 694         }
 695
 696         if (self.classname == "droppedweapon")
 697         {
 698                 self.strength_finished = max(0, self.strength_finished - time);
 699                 self.invincible_finished = max(0, self.invincible_finished - time);
 700                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 701         }
 702
 703         if(!Item_GiveTo(self, other))
 704         {
 705                 if (self.classname == "droppedweapon")
 706                 {
 707                         // undo what we did above
 708                         self.strength_finished += time;
 709                         self.invincible_finished += time;
 710                         self.superweapons_finished += time;
 711                 }
 712                 return;
 713         }
 714
 715         :pickup
 716
 717         other.last_pickup = time;
 718
 719         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 720         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 721
 722         if (self.classname == "droppedweapon")
 723                 remove (self);
 724         else if not(self.spawnshieldtime)
 725                 return;
 726         else
 727         {
 728                 if(self.team)
 729                 {
 730                         RandomSelection_Init();
 731                         for(head = world; (head = findfloat(head, team, self.team)); )
 732                         {
 733                                 if(head.flags & FL_ITEM)
 734                                 {
 735                                         Item_Show(head, -1);
 736                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 737                                 }
 738                         }
 739                         e = RandomSelection_chosen_ent;
 740
 741                 }
 742                 else
 743                         e = self;
 744                 Item_ScheduleRespawn(e);
 745         }
 746 }
 747
 748 void Item_Reset()
 749 {
 750         Item_Show(self, !self.state);
 751         setorigin (self, self.origin);
 752
 753         if(self.classname != "droppedweapon")
 754         {
 755                 self.think = func_null;
 756                 self.nextthink = 0;
 757
 758                 if(self.waypointsprite_attached)
 759                         WaypointSprite_Kill(self.waypointsprite_attached);
 760
 761                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 762                         Item_ScheduleInitialRespawn(self);
 763         }
 764 }
 765
 766 void Item_FindTeam()
 767 {
 768         entity head, e;
 769
 770         if(self.effects & EF_NODRAW)
 771         {
 772                 // marker for item team search
 773                 dprint("Initializing item team ", ftos(self.team), "\n");
 774                 RandomSelection_Init();
 775                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 776                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 777                 e = RandomSelection_chosen_ent;
 778                 e.state = 0;
 779                 Item_Show(e, 1);
 780
 781                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 782                 {
 783                         if(head != e)
 784                         {
 785                                 // make it a non-spawned item
 786                                 Item_Show(head, -1);
 787                                 head.state = 1; // state 1 = initially hidden item
 788                         }
 789                         head.effects &~= EF_NODRAW;
 790                 }
 791
 792                 Item_Reset();
 793         }
 794 }
 795
 796 // Savage: used for item garbage-collection
 797 // TODO: perhaps nice special effect?
 798 void RemoveItem(void)
 799 {
 800         remove(self);
 801 }
 802
 803 // pickup evaluation functions
 804 // these functions decide how desirable an item is to the bots
 805
 806 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 807
 808 float weapon_pickupevalfunc(entity player, entity item)
 809 {
 810         float c, j, position;
 811
 812         // See if I have it already
 813         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 814         {
 815                 // If I can pick it up
 816                 if(!item.spawnshieldtime)
 817                         c = 0;
 818                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 819                 {
 820                         // Skilled bots will grab more
 821                         c = bound(0, skill / 10, 1) * 0.5;
 822                 }
 823                 else
 824                         c = 0;
 825         }
 826         else
 827                 c = 1;
 828
 829         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 830         if( bot_custom_weapon && c )
 831         {
 832                 // Find the highest position on any range
 833                 position = -1;
 834                 for(j = 0; j < WEP_LAST ; ++j){
 835                         if(
 836                                         bot_weapons_far[j] == item.weapon ||
 837                                         bot_weapons_mid[j] == item.weapon ||
 838                                         bot_weapons_close[j] == item.weapon
 839                           )
 840                         {
 841                                 position = j;
 842                                 break;
 843                         }
 844                 }
 845
 846                 // Rate it
 847                 if (position >= 0 )
 848                 {
 849                         position = WEP_LAST - position;
 850                         // item.bot_pickupbasevalue is overwritten here
 851                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 852                 }
 853         }
 854
 855         return item.bot_pickupbasevalue * c;
 856 }
 857
 858 float commodity_pickupevalfunc(entity player, entity item)
 859 {
 860         float c, i;
 861         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 862         entity wi;
 863         c = 0;
 864
 865         // Detect needed ammo
 866         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 867         {
 868                 wi = get_weaponinfo(i);
 869
 870                 if not(WEPSET_CONTAINS_EW(player, i))
 871                         continue;
 872
 873                 if(wi.items & IT_SHELLS)
 874                         need_shells = TRUE;
 875                 else if(wi.items & IT_NAILS)
 876                         need_nails = TRUE;
 877                 else if(wi.items & IT_ROCKETS)
 878                         need_rockets = TRUE;
 879                 else if(wi.items & IT_CELLS)
 880                         need_cells = TRUE;
 881                 else if(wi.items & IT_FUEL)
 882                         need_cells = TRUE;
 883         }
 884
 885         // TODO: figure out if the player even has the weapon this ammo is for?
 886         // may not affect strategy much though...
 887         // find out how much more ammo/armor/health the player can hold
 888         if (need_shells)
 889         if (item.ammo_shells)
 890         if (player.ammo_shells < g_pickup_shells_max)
 891                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 892         if (need_nails)
 893         if (item.ammo_nails)
 894         if (player.ammo_nails < g_pickup_nails_max)
 895                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 896         if (need_rockets)
 897         if (item.ammo_rockets)
 898         if (player.ammo_rockets < g_pickup_rockets_max)
 899                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 900         if (need_cells)
 901         if (item.ammo_cells)
 902         if (player.ammo_cells < g_pickup_cells_max)
 903                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 904         if (need_fuel)
 905         if (item.ammo_fuel)
 906         if (player.ammo_fuel < g_pickup_fuel_max)
 907                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 908         if (item.armorvalue)
 909         if (player.armorvalue < item.max_armorvalue)
 910                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 911         if (item.health)
 912         if (player.health < item.max_health)
 913                 c = c + max(0, 1 - player.health / item.max_health);
 914
 915         return item.bot_pickupbasevalue * c;
 916 }
 917
 918 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 919 {
 920         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 921                 RemoveItem();
 922 }
 923
 924 .float is_item;
 925 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 926 {
 927         startitem_failed = FALSE;
 928
 929         if(self.model == "")
 930                 self.model = itemmodel;
 931
 932         if(self.model == "")
 933     {
 934         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 935         return;
 936     }
 937
 938         if(self.item_pickupsound == "")
 939                 self.item_pickupsound = pickupsound;
 940
 941         if(!self.respawntime) // both need to be set
 942         {
 943                 self.respawntime = defaultrespawntime;
 944                 self.respawntimejitter = defaultrespawntimejitter;
 945         }
 946
 947         self.items = itemid;
 948         self.weapon = weaponid;
 949
 950         if(weaponid)
 951                 WEPSET_COPY_EW(self, weaponid);
 952
 953         self.flags = FL_ITEM | itemflags;
 954
 955         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 956         {
 957                 startitem_failed = TRUE;
 958                 remove(self);
 959                 return;
 960         }
 961
 962         // is it a dropped weapon?
 963         if (self.classname == "droppedweapon")
 964         {
 965                 self.reset = SUB_Remove;
 966                 // it's a dropped weapon
 967                 self.movetype = MOVETYPE_TOSS;
 968
 969                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 970                 self.think = RemoveItem;
 971                 self.nextthink = time + 20;
 972
 973                 self.takedamage = DAMAGE_YES;
 974                 self.event_damage = Item_Damage;
 975
 976                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 977                 /*
 978                 if(self.items == 0)
 979                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 980                 if(self.ammo_nails == 0)
 981                 if(self.ammo_cells == 0)
 982                 if(self.ammo_rockets == 0)
 983                 if(self.ammo_shells == 0)
 984                 if(self.ammo_fuel == 0)
 985                 if(self.health == 0)
 986                 if(self.armorvalue == 0)
 987                 */
 988                 {
 989                         // if item is worthless after a timer, have it expire then
 990                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 991                 }
 992
 993                 // don't drop if in a NODROP zone (such as lava)
 994                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 995                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 996                 {
 997                         startitem_failed = TRUE;
 998                         remove(self);
 999                         return;
1000                 }
1001         }
1002         else
1003         {
1004                 if(!have_pickup_item())
1005                 {
1006                         startitem_failed = TRUE;
1007                         remove (self);
1008                         return;
1009                 }
1010
1011                 if(self.angles != '0 0 0')
1012             self.SendFlags |= ISF_ANGLES;
1013
1014                 self.reset = Item_Reset;
1015                 // it's a level item
1016                 if(self.spawnflags & 1)
1017                         self.noalign = 1;
1018                 if (self.noalign)
1019                         self.movetype = MOVETYPE_NONE;
1020                 else
1021                         self.movetype = MOVETYPE_TOSS;
1022                 // do item filtering according to game mode and other things
1023                 if (!self.noalign)
1024                 {
1025                         // first nudge it off the floor a little bit to avoid math errors
1026                         setorigin(self, self.origin + '0 0 1');
1027                         // set item size before we spawn a spawnfunc_waypoint
1028                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1029                                 setsize (self, '-16 -16 0', '16 16 48');
1030                         else
1031                                 setsize (self, '-16 -16 0', '16 16 32');
1032                         // note droptofloor returns FALSE if stuck/or would fall too far
1033                         droptofloor();
1034                         waypoint_spawnforitem(self);
1035                 }
1036
1037                 /*
1038                  * can't do it that way, as it would break maps
1039                  * TODO make a target_give like entity another way, that perhaps has
1040                  * the weapon name in a key
1041                 if(self.targetname)
1042                 {
1043                         // target_give not yet supported; maybe later
1044                         print("removed targeted ", self.classname, "\n");
1045                         startitem_failed = TRUE;
1046                         remove (self);
1047                         return;
1048                 }
1049                 */
1050
1051                 if(autocvar_spawn_debug >= 2)
1052                 {
1053                         entity otheritem;
1054                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1055                         {
1056                             // why not flags & fl_item?
1057                                 if(otheritem.is_item)
1058                                 {
1059                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1060                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1061                                         error("Mapper sucks.");
1062                                 }
1063                         }
1064                         self.is_item = TRUE;
1065                 }
1066
1067                 WEPSET_OR_AW(weaponsInMap, weaponid);
1068
1069                 precache_model (self.model);
1070                 precache_sound (self.item_pickupsound);
1071
1072                 precache_sound ("misc/itemrespawncountdown.wav");
1073                 if(itemid == IT_STRENGTH)
1074                         precache_sound ("misc/strength_respawn.wav");
1075                 else if(itemid == IT_INVINCIBLE)
1076                         precache_sound ("misc/shield_respawn.wav");
1077                 else
1078                         precache_sound ("misc/itemrespawn.wav");
1079
1080                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1081                         self.target = "###item###"; // for finding the nearest item using find()
1082         }
1083
1084         self.bot_pickup = TRUE;
1085         self.bot_pickupevalfunc = pickupevalfunc;
1086         self.bot_pickupbasevalue = pickupbasevalue;
1087         self.mdl = self.model;
1088         self.netname = itemname;
1089         self.touch = Item_Touch;
1090         setmodel(self, "null"); // precision set below
1091         //self.effects |= EF_LOWPRECISION;
1092
1093         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1094     {
1095         self.pos1 = '-16 -16 0';
1096         self.pos2 = '16 16 48';
1097     }
1098         else
1099     {
1100         self.pos1 = '-16 -16 0';
1101         self.pos2 = '16 16 32';
1102     }
1103     setsize (self, self.pos1, self.pos2);
1104
1105     if(itemflags & FL_POWERUP)
1106         self.ItemStatus |= ITS_ANIMATE1;
1107
1108         if(self.armorvalue || self.health)
1109         self.ItemStatus |= ITS_ANIMATE2;
1110
1111         if(itemflags & FL_WEAPON)
1112         {
1113                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1114             self.colormap = 1024; // color shirt=0 pants=0 grey
1115         else
1116             self.gravity = 1;
1117
1118                 self.ItemStatus |= ITS_ANIMATE1;
1119                 self.ItemStatus |= ISF_COLORMAP;
1120         }
1121
1122         self.state = 0;
1123         if(self.team) // broken, no idea why.
1124         {
1125                 if(!self.cnt)
1126                         self.cnt = 1; // item probability weight
1127
1128                 self.effects |= EF_NODRAW; // marker for item team search
1129                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1130         }
1131         else
1132                 Item_Reset();
1133
1134     Net_LinkEntity(self, FALSE, 0, ItemSend);
1135
1136         // call this hook after everything else has been done
1137         if(MUTATOR_CALLHOOK(Item_Spawn))
1138         {
1139                 startitem_failed = TRUE;
1140                 remove(self);
1141                 return;
1142         }
1143 }
1144
1145 float weaponswapping;
1146 float internalteam;
1147
1148 void weapon_defaultspawnfunc(float wpn)
1149 {
1150         entity e;
1151         float t;
1152         var .float ammofield;
1153         string s;
1154         entity oldself;
1155         float i, j;
1156         float f;
1157
1158         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1159         {
1160                 e = get_weaponinfo(wpn);
1161
1162                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1163                 {
1164                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1165                         startitem_failed = TRUE;
1166                         return;
1167                 }
1168
1169                 s = W_Apply_Weaponreplace(e.netname);
1170                 ret_string = s;
1171                 other = e;
1172                 MUTATOR_CALLHOOK(SetWeaponreplace);
1173                 s = ret_string;
1174                 if(s == "")
1175                 {
1176                         remove(self);
1177                         startitem_failed = TRUE;
1178                         return;
1179                 }
1180                 t = tokenize_console(s);
1181                 if(t >= 2)
1182                 {
1183                         self.team = --internalteam;
1184                         oldself = self;
1185                         for(i = 1; i < t; ++i)
1186                         {
1187                                 s = argv(i);
1188                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1189                                 {
1190                                         e = get_weaponinfo(j);
1191                                         if(e.netname == s)
1192                                         {
1193                                                 self = spawn();
1194                                                 copyentity(oldself, self);
1195                                                 self.classname = "replacedweapon";
1196                                                 weapon_defaultspawnfunc(j);
1197                                                 break;
1198                                         }
1199                                 }
1200                                 if(j > WEP_LAST)
1201                                 {
1202                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1203                                 }
1204                         }
1205                         self = oldself;
1206                 }
1207                 if(t >= 1) // always the case!
1208                 {
1209                         s = argv(0);
1210                         wpn = 0;
1211                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1212                         {
1213                                 e = get_weaponinfo(j);
1214                                 if(e.netname == s)
1215                                 {
1216                                         wpn = j;
1217                                         break;
1218                                 }
1219                         }
1220                         if(j > WEP_LAST)
1221                         {
1222                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1223                         }
1224                 }
1225                 if(wpn == 0)
1226                 {
1227                         remove(self);
1228                         startitem_failed = TRUE;
1229                         return;
1230                 }
1231         }
1232
1233         e = get_weaponinfo(wpn);
1234
1235         if(!self.respawntime)
1236         {
1237                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1238                 {
1239                         self.respawntime = g_pickup_respawntime_superweapon;
1240                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1241                 }
1242                 else
1243                 {
1244                         self.respawntime = g_pickup_respawntime_weapon;
1245                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1246                 }
1247         }
1248
1249         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1250                 if(!self.superweapons_finished)
1251                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1252
1253         if(e.items)
1254         {
1255                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1256                 {
1257                         if(e.items & j)
1258                         {
1259                                 ammofield = Item_CounterField(j);
1260                                 if(!self.ammofield)
1261                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1262                         }
1263                 }
1264         }
1265
1266         // pickup anyway
1267         if(g_pickup_weapons_anyway)
1268                 self.pickup_anyway = TRUE;
1269
1270         f = FL_WEAPON;
1271
1272         // no weapon-stay on superweapons
1273         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1274                 f |= FL_NO_WEAPON_STAY;
1275
1276         // weapon stay isn't supported for teamed weapons
1277         if(self.team)
1278                 f |= FL_NO_WEAPON_STAY;
1279
1280         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1281         if (self.modelindex) // don't precache if self was removed
1282                 weapon_action(e.weapon, WR_PRECACHE);
1283 }
1284
1285 void spawnfunc_weapon_shotgun (void);
1286 void spawnfunc_weapon_uzi (void) {
1287         if(autocvar_sv_q3acompat_machineshotgunswap)
1288         if(self.classname != "droppedweapon")
1289         {
1290                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1291                 return;
1292         }
1293         weapon_defaultspawnfunc(WEP_UZI);
1294 }
1295
1296 void spawnfunc_weapon_shotgun (void) {
1297         if(autocvar_sv_q3acompat_machineshotgunswap)
1298         if(self.classname != "droppedweapon")
1299         {
1300                 weapon_defaultspawnfunc(WEP_UZI);
1301                 return;
1302         }
1303         weapon_defaultspawnfunc(WEP_SHOTGUN);
1304 }
1305
1306 void spawnfunc_weapon_nex (void)
1307 {
1308         weapon_defaultspawnfunc(WEP_NEX);
1309 }
1310
1311 void spawnfunc_weapon_minstanex (void)
1312 {
1313         weapon_defaultspawnfunc(WEP_MINSTANEX);
1314 }
1315
1316 void spawnfunc_weapon_rocketlauncher (void)
1317 {
1318         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1319 }
1320
1321 void spawnfunc_item_rockets (void) {
1322         if(!self.ammo_rockets)
1323                 self.ammo_rockets = g_pickup_rockets;
1324         if(!self.pickup_anyway)
1325                 self.pickup_anyway = g_pickup_ammo_anyway;
1326         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1327 }
1328
1329 void spawnfunc_item_shells (void);
1330 void spawnfunc_item_bullets (void) {
1331         if(!weaponswapping)
1332         if(autocvar_sv_q3acompat_machineshotgunswap)
1333         if(self.classname != "droppedweapon")
1334         {
1335                 weaponswapping = TRUE;
1336                 spawnfunc_item_shells();
1337                 weaponswapping = FALSE;
1338                 return;
1339         }
1340
1341         if(!self.ammo_nails)
1342                 self.ammo_nails = g_pickup_nails;
1343         if(!self.pickup_anyway)
1344                 self.pickup_anyway = g_pickup_ammo_anyway;
1345         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1346 }
1347
1348 void spawnfunc_item_cells (void) {
1349         if(!self.ammo_cells)
1350                 self.ammo_cells = g_pickup_cells;
1351         if(!self.pickup_anyway)
1352                 self.pickup_anyway = g_pickup_ammo_anyway;
1353         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1354 }
1355
1356 void spawnfunc_item_shells (void) {
1357         if(!weaponswapping)
1358         if(autocvar_sv_q3acompat_machineshotgunswap)
1359         if(self.classname != "droppedweapon")
1360         {
1361                 weaponswapping = TRUE;
1362                 spawnfunc_item_bullets();
1363                 weaponswapping = FALSE;
1364                 return;
1365         }
1366
1367         if(!self.ammo_shells)
1368                 self.ammo_shells = g_pickup_shells;
1369         if(!self.pickup_anyway)
1370                 self.pickup_anyway = g_pickup_ammo_anyway;
1371         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1372 }
1373
1374 void spawnfunc_item_armor_small (void) {
1375         if(!self.armorvalue)
1376                 self.armorvalue = g_pickup_armorsmall;
1377         if(!self.max_armorvalue)
1378                 self.max_armorvalue = g_pickup_armorsmall_max;
1379         if(!self.pickup_anyway)
1380                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1381         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1382 }
1383
1384 void spawnfunc_item_armor_medium (void) {
1385         if(!self.armorvalue)
1386                 self.armorvalue = g_pickup_armormedium;
1387         if(!self.max_armorvalue)
1388                 self.max_armorvalue = g_pickup_armormedium_max;
1389         if(!self.pickup_anyway)
1390                 self.pickup_anyway = g_pickup_armormedium_anyway;
1391         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1392 }
1393
1394 void spawnfunc_item_armor_big (void) {
1395         if(!self.armorvalue)
1396                 self.armorvalue = g_pickup_armorbig;
1397         if(!self.max_armorvalue)
1398                 self.max_armorvalue = g_pickup_armorbig_max;
1399         if(!self.pickup_anyway)
1400                 self.pickup_anyway = g_pickup_armorbig_anyway;
1401         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1402 }
1403
1404 void spawnfunc_item_armor_large (void) {
1405         if(!self.armorvalue)
1406                 self.armorvalue = g_pickup_armorlarge;
1407         if(!self.max_armorvalue)
1408                 self.max_armorvalue = g_pickup_armorlarge_max;
1409         if(!self.pickup_anyway)
1410                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1411         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1412 }
1413
1414 void spawnfunc_item_health_small (void) {
1415         if(!self.max_health)
1416                 self.max_health = g_pickup_healthsmall_max;
1417         if(!self.health)
1418                 self.health = g_pickup_healthsmall;
1419         if(!self.pickup_anyway)
1420                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1421         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1422 }
1423
1424 void spawnfunc_item_health_medium (void) {
1425         if(!self.max_health)
1426                 self.max_health = g_pickup_healthmedium_max;
1427         if(!self.health)
1428                 self.health = g_pickup_healthmedium;
1429         if(!self.pickup_anyway)
1430                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1431         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1432 }
1433
1434 void spawnfunc_item_health_large (void) {
1435         if(!self.max_health)
1436                 self.max_health = g_pickup_healthlarge_max;
1437         if(!self.health)
1438                 self.health = g_pickup_healthlarge;
1439         if(!self.pickup_anyway)
1440                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1441         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1442 }
1443
1444 void spawnfunc_item_health_mega (void) {
1445                 if(!self.max_health)
1446                         self.max_health = g_pickup_healthmega_max;
1447                 if(!self.health)
1448                         self.health = g_pickup_healthmega;
1449                 if(!self.pickup_anyway)
1450                         self.pickup_anyway = g_pickup_healthmega_anyway;
1451                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1452 }
1453
1454 // support old misnamed entities
1455 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1456 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1457 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1458 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1459 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1460
1461 void spawnfunc_item_strength (void) {
1462                 precache_sound("weapons/strength_fire.wav");
1463                 if(!self.strength_finished)
1464                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1465                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1466 }
1467
1468 void spawnfunc_item_invincible (void) {
1469                 if(!self.invincible_finished)
1470                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1471                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1472 }
1473
1474 // compatibility:
1475 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1476
1477 float GiveItems(entity e, float beginarg, float endarg);
1478 void target_items_use (void)
1479 {
1480         if(activator.classname == "droppedweapon")
1481         {
1482                 EXACTTRIGGER_TOUCH;
1483                 remove(activator);
1484                 return;
1485         }
1486
1487         if not(IS_PLAYER(activator))
1488                 return;
1489         if(activator.deadflag != DEAD_NO)
1490                 return;
1491         EXACTTRIGGER_TOUCH;
1492
1493         entity e;
1494         for(e = world; (e = find(e, classname, "droppedweapon")); )
1495                 if(e.enemy == activator)
1496                         remove(e);
1497
1498         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1499                 centerprint(activator, self.message);
1500 }
1501
1502 void spawnfunc_target_items (void)
1503 {
1504         float n, i, j;
1505         entity e;
1506
1507         self.use = target_items_use;
1508         if(!self.strength_finished)
1509                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1510         if(!self.invincible_finished)
1511                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1512         if(!self.superweapons_finished)
1513                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1514
1515         precache_sound("misc/itempickup.wav");
1516         precache_sound("misc/megahealth.wav");
1517         precache_sound("misc/armor25.wav");
1518         precache_sound("misc/powerup.wav");
1519         precache_sound("misc/poweroff.wav");
1520         precache_sound("weapons/weaponpickup.wav");
1521
1522         n = tokenize_console(self.netname);
1523         if(argv(0) == "give")
1524         {
1525                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1526         }
1527         else
1528         {
1529                 for(i = 0; i < n; ++i)
1530                 {
1531                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1532                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1533                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1534                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1535                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1536                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1537                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1538                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1539                         else
1540                         {
1541                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1542                                 {
1543                                         e = get_weaponinfo(j);
1544                                         if(argv(i) == e.netname)
1545                                         {
1546                                                 WEPSET_OR_EW(self, j);
1547                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1548                                                         weapon_action(e.weapon, WR_PRECACHE);
1549                                                 break;
1550                                         }
1551                                 }
1552                                 if(j > WEP_LAST)
1553                                         print("target_items: invalid item ", argv(i), "\n");
1554                         }
1555                 }
1556
1557                 string itemprefix, valueprefix;
1558                 if(self.spawnflags == 0)
1559                 {
1560                         itemprefix = "";
1561                         valueprefix = "";
1562                 }
1563                 else if(self.spawnflags == 1)
1564                 {
1565                         itemprefix = "max ";
1566                         valueprefix = "max ";
1567                 }
1568                 else if(self.spawnflags == 2)
1569                 {
1570                         itemprefix = "min ";
1571                         valueprefix = "min ";
1572                 }
1573                 else if(self.spawnflags == 4)
1574                 {
1575                         itemprefix = "minus ";
1576                         valueprefix = "max ";
1577                 }
1578                 else
1579                 {
1580                         error("invalid spawnflags");
1581 #ifdef GMQCC
1582                         itemprefix = string_null;
1583                         valueprefix = string_null;
1584 #endif
1585                 }
1586
1587                 self.netname = "";
1588                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1589                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1590                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1591                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1592                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1593                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1594                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1595                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1596                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1597                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1598                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1599                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1600                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1601                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1602                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1603                 {
1604                         e = get_weaponinfo(j);
1605                         if(e.weapon)
1606                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1607                 }
1608         }
1609         self.netname = strzone(self.netname);
1610         //print(self.netname, "\n");
1611
1612         n = tokenize_console(self.netname);
1613         for(i = 0; i < n; ++i)
1614         {
1615                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1616                 {
1617                         e = get_weaponinfo(j);
1618                         if(argv(i) == e.netname)
1619                         {
1620                                 weapon_action(e.weapon, WR_PRECACHE);
1621                                 break;
1622                         }
1623                 }
1624         }
1625 }
1626
1627 void spawnfunc_item_fuel(void)
1628 {
1629         if(!self.ammo_fuel)
1630                 self.ammo_fuel = g_pickup_fuel;
1631         if(!self.pickup_anyway)
1632                 self.pickup_anyway = g_pickup_ammo_anyway;
1633         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1634 }
1635
1636 void spawnfunc_item_fuel_regen(void)
1637 {
1638         if(start_items & IT_FUEL_REGEN)
1639         {
1640                 spawnfunc_item_fuel();
1641                 return;
1642         }
1643         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1644 }
1645
1646 void spawnfunc_item_jetpack(void)
1647 {
1648         if(g_grappling_hook)
1649                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1650         if(!self.ammo_fuel)
1651                 self.ammo_fuel = g_pickup_fuel_jetpack;
1652         if(start_items & IT_JETPACK)
1653         {
1654                 spawnfunc_item_fuel();
1655                 return;
1656         }
1657         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1658 }
1659
1660
1661 #define OP_SET 0
1662 #define OP_MIN 1
1663 #define OP_MAX 2
1664 #define OP_PLUS 3
1665 #define OP_MINUS 4
1666
1667 float GiveWeapon(entity e, float wpn, float op, float val)
1668 {
1669         float v0, v1;
1670         v0 = WEPSET_CONTAINS_EW(e, wpn);
1671         switch(op)
1672         {
1673                 case OP_SET:
1674                         if(val > 0)
1675                                 WEPSET_OR_EW(e, wpn);
1676                         else
1677                                 WEPSET_ANDNOT_EW(e, wpn);
1678                         break;
1679                 case OP_MIN:
1680                 case OP_PLUS:
1681                         if(val > 0)
1682                                 WEPSET_OR_EW(e, wpn);
1683                         break;
1684                 case OP_MAX:
1685                         if(val <= 0)
1686                                 WEPSET_ANDNOT_EW(e, wpn);
1687                         break;
1688                 case OP_MINUS:
1689                         if(val > 0)
1690                                 WEPSET_ANDNOT_EW(e, wpn);
1691                         break;
1692         }
1693         v1 = WEPSET_CONTAINS_EW(e, wpn);
1694         return (v0 != v1);
1695 }
1696
1697 float GiveBit(entity e, .float fld, float bit, float op, float val)
1698 {
1699         float v0, v1;
1700         v0 = (e.fld & bit);
1701         switch(op)
1702         {
1703                 case OP_SET:
1704                         if(val > 0)
1705                                 e.fld |= bit;
1706                         else
1707                                 e.fld &~= bit;
1708                         break;
1709                 case OP_MIN:
1710                 case OP_PLUS:
1711                         if(val > 0)
1712                                 e.fld |= bit;
1713                         break;
1714                 case OP_MAX:
1715                         if(val <= 0)
1716                                 e.fld &~= bit;
1717                         break;
1718                 case OP_MINUS:
1719                         if(val > 0)
1720                                 e.fld &~= bit;
1721                         break;
1722         }
1723         v1 = (e.fld & bit);
1724         return (v0 != v1);
1725 }
1726
1727 float GiveValue(entity e, .float fld, float op, float val)
1728 {
1729         float v0, v1;
1730         v0 = e.fld;
1731         switch(op)
1732         {
1733                 case OP_SET:
1734                         e.fld = val;
1735                         break;
1736                 case OP_MIN:
1737                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1738                         break;
1739                 case OP_MAX:
1740                         e.fld = min(e.fld, val);
1741                         break;
1742                 case OP_PLUS:
1743                         e.fld += val;
1744                         break;
1745                 case OP_MINUS:
1746                         e.fld -= val;
1747                         break;
1748         }
1749         v1 = e.fld;
1750         return (v0 != v1);
1751 }
1752
1753 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1754 {
1755         if(v1 == v0)
1756                 return;
1757         if(v1 <= v0 - t)
1758         {
1759                 if(snd_decr != "")
1760                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1761         }
1762         else if(v0 >= v0 + t)
1763         {
1764                 if(snd_incr != "")
1765                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1766         }
1767 }
1768
1769 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1770 {
1771         if(v0 < v1)
1772                 e.rotfield = max(e.rotfield, time + rottime);
1773         else if(v0 > v1)
1774                 e.regenfield = max(e.regenfield, time + regentime);
1775 }
1776
1777 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1778 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1779 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1780 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1781 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1782 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1783
1784 float GiveItems(entity e, float beginarg, float endarg)
1785 {
1786         float got, i, j, val, op;
1787         float _switchweapon;
1788         entity wi;
1789         string cmd;
1790
1791         val = 999;
1792         op = OP_SET;
1793
1794         got = 0;
1795
1796         _switchweapon = FALSE;
1797         if (e.autoswitch)
1798                 if (e.switchweapon == w_getbestweapon(e))
1799                         _switchweapon = TRUE;
1800
1801         e.strength_finished = max(0, e.strength_finished - time);
1802         e.invincible_finished = max(0, e.invincible_finished - time);
1803         e.superweapons_finished = max(0, e.superweapons_finished - time);
1804
1805         PREGIVE(e, items);
1806         PREGIVE_WEAPONS(e);
1807         PREGIVE(e, strength_finished);
1808         PREGIVE(e, invincible_finished);
1809         PREGIVE(e, superweapons_finished);
1810         PREGIVE(e, ammo_nails);
1811         PREGIVE(e, ammo_cells);
1812         PREGIVE(e, ammo_shells);
1813         PREGIVE(e, ammo_rockets);
1814         PREGIVE(e, ammo_fuel);
1815         PREGIVE(e, armorvalue);
1816         PREGIVE(e, health);
1817
1818         for(i = beginarg; i < endarg; ++i)
1819         {
1820                 cmd = argv(i);
1821
1822                 if(cmd == "0" || stof(cmd))
1823                 {
1824                         val = stof(cmd);
1825                         continue;
1826                 }
1827                 switch(cmd)
1828                 {
1829                         case "no":
1830                                 op = OP_MAX;
1831                                 val = 0;
1832                                 continue;
1833                         case "max":
1834                                 op = OP_MAX;
1835                                 continue;
1836                         case "min":
1837                                 op = OP_MIN;
1838                                 continue;
1839                         case "plus":
1840                                 op = OP_PLUS;
1841                                 continue;
1842                         case "minus":
1843                                 op = OP_MINUS;
1844                                 continue;
1845                         case "ALL":
1846                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1847                                 got += GiveValue(e, strength_finished, op, val);
1848                                 got += GiveValue(e, invincible_finished, op, val);
1849                                 got += GiveValue(e, superweapons_finished, op, val);
1850                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1851                         case "all":
1852                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1853                                 got += GiveValue(e, health, op, val);
1854                                 got += GiveValue(e, armorvalue, op, val);
1855                         case "allweapons":
1856                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1857                                 {
1858                                         wi = get_weaponinfo(j);
1859                                         if(wi.weapon)
1860                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1861                                                         got += GiveWeapon(e, j, op, val);
1862                                 }
1863                         case "allammo":
1864                                 got += GiveValue(e, ammo_cells, op, val);
1865                                 got += GiveValue(e, ammo_shells, op, val);
1866                                 got += GiveValue(e, ammo_nails, op, val);
1867                                 got += GiveValue(e, ammo_rockets, op, val);
1868                                 got += GiveValue(e, ammo_fuel, op, val);
1869                                 break;
1870                         case "unlimited_ammo":
1871                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1872                                 break;
1873                         case "unlimited_weapon_ammo":
1874                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1875                                 break;
1876                         case "unlimited_superweapons":
1877                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1878                                 break;
1879                         case "jetpack":
1880                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1881                                 break;
1882                         case "fuel_regen":
1883                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1884                                 break;
1885                         case "strength":
1886                                 got += GiveValue(e, strength_finished, op, val);
1887                                 break;
1888                         case "invincible":
1889                                 got += GiveValue(e, invincible_finished, op, val);
1890                                 break;
1891                         case "superweapons":
1892                                 got += GiveValue(e, superweapons_finished, op, val);
1893                                 break;
1894                         case "cells":
1895                                 got += GiveValue(e, ammo_cells, op, val);
1896                                 break;
1897                         case "shells":
1898                                 got += GiveValue(e, ammo_shells, op, val);
1899                                 break;
1900                         case "nails":
1901                         case "bullets":
1902                                 got += GiveValue(e, ammo_nails, op, val);
1903                                 break;
1904                         case "rockets":
1905                                 got += GiveValue(e, ammo_rockets, op, val);
1906                                 break;
1907                         case "health":
1908                                 got += GiveValue(e, health, op, val);
1909                                 break;
1910                         case "armor":
1911                                 got += GiveValue(e, armorvalue, op, val);
1912                                 break;
1913                         case "fuel":
1914                                 got += GiveValue(e, ammo_fuel, op, val);
1915                                 break;
1916                         default:
1917                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1918                                 {
1919                                         wi = get_weaponinfo(j);
1920                                         if(cmd == wi.netname)
1921                                         {
1922                                                 got += GiveWeapon(e, j, op, val);
1923                                                 break;
1924                                         }
1925                                 }
1926                                 if(j > WEP_LAST)
1927                                         print("give: invalid item ", cmd, "\n");
1928                                 break;
1929                 }
1930                 val = 999;
1931                 op = OP_SET;
1932         }
1933
1934         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1935         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1936         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1937         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1938         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1939         {
1940                 wi = get_weaponinfo(j);
1941                 if(wi.weapon)
1942                 {
1943                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1944                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1945                                 if(WEPSET_CONTAINS_EW(e, j))
1946                                         weapon_action(wi.weapon, WR_PRECACHE);
1947                 }
1948         }
1949         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1950         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1951         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1952         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1953         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1954         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1955         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1956         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1957         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1958
1959         if(e.superweapons_finished <= 0)
1960                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1961                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1962
1963         if(e.strength_finished <= 0)
1964                 e.strength_finished = 0;
1965         else
1966                 e.strength_finished += time;
1967         if(e.invincible_finished <= 0)
1968                 e.invincible_finished = 0;
1969         else
1970                 e.invincible_finished += time;
1971         if(e.superweapons_finished <= 0)
1972                 e.superweapons_finished = 0;
1973         else
1974                 e.superweapons_finished += time;
1975
1976         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1977                 _switchweapon = TRUE;
1978         if(_switchweapon)
1979                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1980
1981         return got;
1982 }
1983 #endif