qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &= ~ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271 void ItemUpdate(entity item)
 272 {
 273         item.SendFlags |= ISF_LOCATION;
 274 }
 275
 276 float have_pickup_item(void)
 277 {
 278         if(self.flags & FL_POWERUP)
 279         {
 280                 if(autocvar_g_powerups > 0)
 281                         return TRUE;
 282                 if(autocvar_g_powerups == 0)
 283                         return FALSE;
 284         }
 285         else
 286         {
 287                 if(autocvar_g_pickup_items > 0)
 288                         return TRUE;
 289                 if(autocvar_g_pickup_items == 0)
 290                         return FALSE;
 291                 if(g_weaponarena)
 292                         if(self.weapons || (self.items & IT_AMMO))
 293                                 return FALSE;
 294         }
 295         return TRUE;
 296 }
 297
 298 #define ITEM_RESPAWN_TICKS 10
 299
 300 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 301         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 302 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 303         // range: 10 .. respawntime + respawntimejitter
 304
 305 floatfield Item_CounterField(float it)
 306 {
 307         switch(it)
 308         {
 309                 case IT_SHELLS:      return ammo_shells;
 310                 case IT_NAILS:       return ammo_nails;
 311                 case IT_ROCKETS:     return ammo_rockets;
 312                 case IT_CELLS:       return ammo_cells;
 313                 case IT_FUEL:        return ammo_fuel;
 314                 case IT_5HP:         return health;
 315                 case IT_25HP:        return health;
 316                 case IT_HEALTH:      return health;
 317                 case IT_ARMOR_SHARD: return armorvalue;
 318                 case IT_ARMOR:       return armorvalue;
 319                 // add more things here (health, armor)
 320                 default:             error("requested item has no counter field");
 321         }
 322 #ifdef GMQCC
 323         // should never happen
 324         return health;
 325 #endif
 326 }
 327
 328 string Item_CounterFieldName(float it)
 329 {
 330         switch(it)
 331         {
 332                 case IT_SHELLS:      return "shells";
 333                 case IT_NAILS:       return "nails";
 334                 case IT_ROCKETS:     return "rockets";
 335                 case IT_CELLS:       return "cells";
 336                 case IT_FUEL:        return "fuel";
 337
 338                 // add more things here (health, armor)
 339                 default:             error("requested item has no counter field name");
 340         }
 341 #ifdef GMQCC
 342         // should never happen
 343         return string_null;
 344 #endif
 345 }
 346
 347 .float max_armorvalue;
 348 .float pickup_anyway;
 349 /*
 350 float Item_Customize()
 351 {
 352         if(self.spawnshieldtime)
 353                 return TRUE;
 354         if(self.weapons & ~other.weapons)
 355         {
 356                 self.colormod = '0 0 0';
 357                 self.glowmod = self.colormod;
 358                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 359                 return TRUE;
 360         }
 361         else
 362         {
 363                 if(g_ghost_items)
 364                 {
 365                         self.colormod = stov(autocvar_g_ghost_items_color);
 366                         self.glowmod = self.colormod;
 367                         self.alpha = g_ghost_items;
 368                         return TRUE;
 369                 }
 370                 else
 371                         return FALSE;
 372         }
 373 }
 374 */
 375
 376 void Item_Show (entity e, float mode)
 377 {
 378         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 379         e.ItemStatus &= ~ITS_STAYWEP;
 380         if (mode > 0)
 381         {
 382                 // make the item look normal, and be touchable
 383                 e.model = e.mdl;
 384                 e.solid = SOLID_TRIGGER;
 385                 e.spawnshieldtime = 1;
 386                 e.ItemStatus |= ITS_AVAILABLE;
 387         }
 388         else if (mode < 0)
 389         {
 390                 // hide the item completely
 391                 e.model = string_null;
 392                 e.solid = SOLID_NOT;
 393                 e.spawnshieldtime = 1;
 394                 e.ItemStatus &= ~ITS_AVAILABLE;
 395         }
 396         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 397         {
 398                 // make the item translucent and not touchable
 399                 e.model = e.mdl;
 400                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 401                 e.effects |= EF_STARDUST;
 402                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 403                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 404         }
 405         else
 406         {
 407                 //setmodel(e, "null");
 408                 e.solid = SOLID_NOT;
 409                 e.colormod = '0 0 0';
 410                 e.glowmod = e.colormod;
 411                 e.spawnshieldtime = 1;
 412                 e.ItemStatus &= ~ITS_AVAILABLE;
 413         }
 414
 415         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 416             e.ItemStatus |= ITS_POWERUP;
 417
 418         if (autocvar_g_nodepthtestitems)
 419                 e.effects |= EF_NODEPTHTEST;
 420
 421
 422     if (autocvar_g_fullbrightitems)
 423                 e.ItemStatus |= ITS_ALLOWFB;
 424
 425         if (autocvar_sv_simple_items)
 426         e.ItemStatus |= ITS_ALLOWSI;
 427
 428         // relink entity (because solid may have changed)
 429         setorigin(e, e.origin);
 430     e.SendFlags |= ISF_STATUS;
 431 }
 432
 433 void Item_Respawn (void)
 434 {
 435         Item_Show(self, 1);
 436         // this is ugly...
 437         if(self.items == IT_STRENGTH)
 438                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 439         else if(self.items == IT_INVINCIBLE)
 440                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 441         else
 442                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 443         setorigin (self, self.origin);
 444
 445         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 446         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 447 }
 448
 449 void Item_RespawnCountdown (void)
 450 {
 451         if(self.count >= ITEM_RESPAWN_TICKS)
 452         {
 453                 if(self.waypointsprite_attached)
 454                         WaypointSprite_Kill(self.waypointsprite_attached);
 455                 Item_Respawn();
 456         }
 457         else
 458         {
 459                 self.nextthink = time + 1;
 460                 self.count += 1;
 461                 if(self.count == 1)
 462                 {
 463                         string name;
 464                         vector rgb = '1 0 1';
 465                         name = string_null;
 466                         switch(self.items)
 467                         {
 468                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 469                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 470                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 471                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 472                         }
 473                         item_name = name;
 474                         item_color = rgb;
 475                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 476                         name = item_name;
 477                         rgb = item_color;
 478                         if(self.flags & FL_WEAPON)
 479                         {
 480                                 entity wi = get_weaponinfo(self.weapon);
 481                                 if(wi)
 482                                 {
 483                                         name = wi.model2;
 484                                         rgb = '1 0 0';
 485                                 }
 486                         }
 487                         if(name)
 488                         {
 489                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 490                                 if(self.waypointsprite_attached)
 491                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 492                         }
 493                         else
 494                         {
 495                                 print("Unknown powerup-marked item is wanting to respawn\n");
 496                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 497                         }
 498                 }
 499                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 500                 if(self.waypointsprite_attached)
 501                 {
 502                         WaypointSprite_Ping(self.waypointsprite_attached);
 503                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 504                 }
 505         }
 506 }
 507
 508 void Item_ScheduleRespawnIn(entity e, float t)
 509 {
 510         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS))
 511         {
 512                 e.think = Item_RespawnCountdown;
 513                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 514                 e.count = 0;
 515         }
 516         else
 517         {
 518                 e.think = Item_Respawn;
 519                 e.nextthink = time + t;
 520         }
 521 }
 522
 523 void Item_ScheduleRespawn(entity e)
 524 {
 525         if(e.respawntime > 0)
 526         {
 527                 Item_Show(e, 0);
 528                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 529         }
 530         else // if respawntime is -1, this item does not respawn
 531                 Item_Show(e, -1);
 532 }
 533
 534 void Item_ScheduleInitialRespawn(entity e)
 535 {
 536         Item_Show(e, 0);
 537         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 538 }
 539
 540 const float ITEM_MODE_NONE = 0;
 541 const float ITEM_MODE_HEALTH = 1;
 542 const float ITEM_MODE_ARMOR = 2;
 543 const float ITEM_MODE_FUEL = 3;
 544 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 545 {
 546         if (!item.ammofield)
 547                 return FALSE;
 548
 549         if (item.spawnshieldtime)
 550         {
 551                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 552                 {
 553                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 554                         goto YEAH;
 555                 }
 556         }
 557         else if(g_weapon_stay == 2)
 558         {
 559                 float mi = min(item.ammofield, ammomax);
 560                 if (player.ammofield < mi)
 561                 {
 562                         player.ammofield = mi;
 563                         goto YEAH;
 564                 }
 565         }
 566
 567         return FALSE;
 568
 569 :YEAH
 570         switch(mode)
 571         {
 572                 case ITEM_MODE_FUEL:
 573                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 574                         break;
 575                 case ITEM_MODE_HEALTH:
 576                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 577                         break;
 578                 case ITEM_MODE_ARMOR:
 579                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 580                         break;
 581                 default:
 582                         break;
 583         }
 584         return TRUE;
 585 }
 586
 587 float Item_GiveTo(entity item, entity player)
 588 {
 589         float _switchweapon;
 590         float pickedup;
 591         float it;
 592         float i;
 593
 594         // if nothing happens to player, just return without taking the item
 595         pickedup = FALSE;
 596         _switchweapon = FALSE;
 597         // in case the player has autoswitch enabled do the following:
 598         // if the player is using their best weapon before items are given, they
 599         // probably want to switch to an even better weapon after items are given
 600         if (player.autoswitch)
 601         if (player.switchweapon == w_getbestweapon(player))
 602                 _switchweapon = TRUE;
 603
 604         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 605                 _switchweapon = TRUE;
 606
 607         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 608         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 609         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 610         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 611         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 612         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 613         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 614
 615         if (item.flags & FL_WEAPON)
 616         {
 617                 WepSet it;
 618                 it = item.weapons;
 619                 it &= ~player.weapons;
 620
 621                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 622                 {
 623                         pickedup = TRUE;
 624                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 625                         if(it & WepSet_FromWeapon(i))
 626                                 W_GiveWeapon(player, i);
 627                 }
 628         }
 629
 630         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 631         {
 632                 pickedup = TRUE;
 633                 player.items |= it;
 634                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 635         }
 636
 637         if (item.strength_finished)
 638         {
 639                 pickedup = TRUE;
 640                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 641         }
 642         if (item.invincible_finished)
 643         {
 644                 pickedup = TRUE;
 645                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 646         }
 647         if (item.superweapons_finished)
 648         {
 649                 pickedup = TRUE;
 650                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 651         }
 652
 653 :skip
 654
 655         // always eat teamed entities
 656         if(item.team)
 657                 pickedup = TRUE;
 658
 659         if (!pickedup)
 660                 return 0;
 661
 662         if (_switchweapon)
 663                 if (player.switchweapon != w_getbestweapon(player))
 664                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 665
 666         return 1;
 667 }
 668
 669 void Item_Touch (void)
 670 {
 671         entity e, head;
 672
 673         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 674         if(self.classname == "droppedweapon")
 675         {
 676                 if (ITEM_TOUCH_NEEDKILL())
 677                 {
 678                         remove(self);
 679                         return;
 680                 }
 681         }
 682
 683         if (!IS_PLAYER(other))
 684                 return;
 685         if (other.frozen)
 686                 return;
 687         if (other.deadflag)
 688                 return;
 689         if (self.solid != SOLID_TRIGGER)
 690                 return;
 691         if (self.owner == other)
 692                 return;
 693         if (time < self.item_spawnshieldtime)
 694                 return;
 695
 696         switch(MUTATOR_CALLHOOK(ItemTouch))
 697         {
 698                 case MUT_ITEMTOUCH_RETURN: { return; }
 699                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 700         }
 701
 702         if (self.classname == "droppedweapon")
 703         {
 704                 self.strength_finished = max(0, self.strength_finished - time);
 705                 self.invincible_finished = max(0, self.invincible_finished - time);
 706                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 707         }
 708
 709         if(!Item_GiveTo(self, other))
 710         {
 711                 if (self.classname == "droppedweapon")
 712                 {
 713                         // undo what we did above
 714                         self.strength_finished += time;
 715                         self.invincible_finished += time;
 716                         self.superweapons_finished += time;
 717                 }
 718                 return;
 719         }
 720
 721         :pickup
 722
 723         other.last_pickup = time;
 724
 725         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 726         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 727
 728         if (self.classname == "droppedweapon")
 729                 remove (self);
 730         else if (!self.spawnshieldtime)
 731                 return;
 732         else
 733         {
 734                 if(self.team)
 735                 {
 736                         RandomSelection_Init();
 737                         for(head = world; (head = findfloat(head, team, self.team)); )
 738                         {
 739                                 if(head.flags & FL_ITEM)
 740                                 {
 741                                         Item_Show(head, -1);
 742                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 743                                 }
 744                         }
 745                         e = RandomSelection_chosen_ent;
 746
 747                 }
 748                 else
 749                         e = self;
 750                 Item_ScheduleRespawn(e);
 751         }
 752 }
 753
 754 void Item_Reset()
 755 {
 756         Item_Show(self, !self.state);
 757         setorigin (self, self.origin);
 758
 759         if(self.classname != "droppedweapon")
 760         {
 761                 self.think = func_null;
 762                 self.nextthink = 0;
 763
 764                 if(self.waypointsprite_attached)
 765                         WaypointSprite_Kill(self.waypointsprite_attached);
 766
 767                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 768                         Item_ScheduleInitialRespawn(self);
 769         }
 770 }
 771
 772 void Item_FindTeam()
 773 {
 774         entity head, e;
 775
 776         if(self.effects & EF_NODRAW)
 777         {
 778                 // marker for item team search
 779                 dprint("Initializing item team ", ftos(self.team), "\n");
 780                 RandomSelection_Init();
 781                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 782                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 783                 e = RandomSelection_chosen_ent;
 784                 e.state = 0;
 785                 Item_Show(e, 1);
 786
 787                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 788                 {
 789                         if(head != e)
 790                         {
 791                                 // make it a non-spawned item
 792                                 Item_Show(head, -1);
 793                                 head.state = 1; // state 1 = initially hidden item
 794                         }
 795                         head.effects &= ~EF_NODRAW;
 796                 }
 797
 798                 Item_Reset();
 799         }
 800 }
 801
 802 // Savage: used for item garbage-collection
 803 // TODO: perhaps nice special effect?
 804 void RemoveItem(void)
 805 {
 806         remove(self);
 807 }
 808
 809 // pickup evaluation functions
 810 // these functions decide how desirable an item is to the bots
 811
 812 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 813
 814 float weapon_pickupevalfunc(entity player, entity item)
 815 {
 816         float c, j, position;
 817
 818         // See if I have it already
 819         if(item.weapons & ~player.weapons)
 820         {
 821                 // If I can pick it up
 822                 if(!item.spawnshieldtime)
 823                         c = 0;
 824                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 825                 {
 826                         // Skilled bots will grab more
 827                         c = bound(0, skill / 10, 1) * 0.5;
 828                 }
 829                 else
 830                         c = 0;
 831         }
 832         else
 833                 c = 1;
 834
 835         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 836         if( bot_custom_weapon && c )
 837         {
 838                 // Find the highest position on any range
 839                 position = -1;
 840                 for(j = 0; j < WEP_LAST ; ++j){
 841                         if(
 842                                         bot_weapons_far[j] == item.weapon ||
 843                                         bot_weapons_mid[j] == item.weapon ||
 844                                         bot_weapons_close[j] == item.weapon
 845                           )
 846                         {
 847                                 position = j;
 848                                 break;
 849                         }
 850                 }
 851
 852                 // Rate it
 853                 if (position >= 0 )
 854                 {
 855                         position = WEP_LAST - position;
 856                         // item.bot_pickupbasevalue is overwritten here
 857                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 858                 }
 859         }
 860
 861         return item.bot_pickupbasevalue * c;
 862 }
 863
 864 float commodity_pickupevalfunc(entity player, entity item)
 865 {
 866         float c, i;
 867         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 868         entity wi;
 869         c = 0;
 870
 871         // Detect needed ammo
 872         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 873         {
 874                 wi = get_weaponinfo(i);
 875
 876                 if (!(player.weapons & WepSet_FromWeapon(i)))
 877                         continue;
 878
 879                 if(wi.items & IT_SHELLS)
 880                         need_shells = TRUE;
 881                 else if(wi.items & IT_NAILS)
 882                         need_nails = TRUE;
 883                 else if(wi.items & IT_ROCKETS)
 884                         need_rockets = TRUE;
 885                 else if(wi.items & IT_CELLS)
 886                         need_cells = TRUE;
 887                 else if(wi.items & IT_FUEL)
 888                         need_cells = TRUE;
 889         }
 890
 891         // TODO: figure out if the player even has the weapon this ammo is for?
 892         // may not affect strategy much though...
 893         // find out how much more ammo/armor/health the player can hold
 894         if (need_shells)
 895         if (item.ammo_shells)
 896         if (player.ammo_shells < g_pickup_shells_max)
 897                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 898         if (need_nails)
 899         if (item.ammo_nails)
 900         if (player.ammo_nails < g_pickup_nails_max)
 901                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 902         if (need_rockets)
 903         if (item.ammo_rockets)
 904         if (player.ammo_rockets < g_pickup_rockets_max)
 905                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 906         if (need_cells)
 907         if (item.ammo_cells)
 908         if (player.ammo_cells < g_pickup_cells_max)
 909                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 910         if (need_fuel)
 911         if (item.ammo_fuel)
 912         if (player.ammo_fuel < g_pickup_fuel_max)
 913                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 914         if (item.armorvalue)
 915         if (player.armorvalue < item.max_armorvalue)
 916                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 917         if (item.health)
 918         if (player.health < item.max_health)
 919                 c = c + max(0, 1 - player.health / item.max_health);
 920
 921         return item.bot_pickupbasevalue * c;
 922 }
 923
 924 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 925 {
 926         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 927                 RemoveItem();
 928 }
 929
 930 .float is_item;
 931 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 932 {
 933         startitem_failed = FALSE;
 934
 935         if(self.model == "")
 936                 self.model = itemmodel;
 937
 938         if(self.model == "")
 939     {
 940         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 941         return;
 942     }
 943
 944         if(self.item_pickupsound == "")
 945                 self.item_pickupsound = pickupsound;
 946
 947         if(!self.respawntime) // both need to be set
 948         {
 949                 self.respawntime = defaultrespawntime;
 950                 self.respawntimejitter = defaultrespawntimejitter;
 951         }
 952
 953         self.items = itemid;
 954         self.weapon = weaponid;
 955
 956         if(weaponid)
 957                 self.weapons = WepSet_FromWeapon(weaponid);
 958
 959         self.flags = FL_ITEM | itemflags;
 960
 961         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 962         {
 963                 startitem_failed = TRUE;
 964                 remove(self);
 965                 return;
 966         }
 967
 968         // is it a dropped weapon?
 969         if (self.classname == "droppedweapon")
 970         {
 971                 self.reset = SUB_Remove;
 972                 // it's a dropped weapon
 973                 self.movetype = MOVETYPE_TOSS;
 974
 975                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 976                 self.think = RemoveItem;
 977                 self.nextthink = time + 20;
 978
 979                 self.takedamage = DAMAGE_YES;
 980                 self.event_damage = Item_Damage;
 981
 982                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 983                 /*
 984                 if(self.items == 0)
 985                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
 986                 if(self.ammo_nails == 0)
 987                 if(self.ammo_cells == 0)
 988                 if(self.ammo_rockets == 0)
 989                 if(self.ammo_shells == 0)
 990                 if(self.ammo_fuel == 0)
 991                 if(self.health == 0)
 992                 if(self.armorvalue == 0)
 993                 */
 994                 {
 995                         // if item is worthless after a timer, have it expire then
 996                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 997                 }
 998
 999                 // don't drop if in a NODROP zone (such as lava)
1000                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1001                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1002                 {
1003                         startitem_failed = TRUE;
1004                         remove(self);
1005                         return;
1006                 }
1007         }
1008         else
1009         {
1010                 if(!have_pickup_item())
1011                 {
1012                         startitem_failed = TRUE;
1013                         remove (self);
1014                         return;
1015                 }
1016
1017                 if(self.angles != '0 0 0')
1018             self.SendFlags |= ISF_ANGLES;
1019
1020                 self.reset = Item_Reset;
1021                 // it's a level item
1022                 if(self.spawnflags & 1)
1023                         self.noalign = 1;
1024                 if (self.noalign)
1025                         self.movetype = MOVETYPE_NONE;
1026                 else
1027                         self.movetype = MOVETYPE_TOSS;
1028                 // do item filtering according to game mode and other things
1029                 if (!self.noalign)
1030                 {
1031                         // first nudge it off the floor a little bit to avoid math errors
1032                         setorigin(self, self.origin + '0 0 1');
1033                         // set item size before we spawn a spawnfunc_waypoint
1034                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1035                                 setsize (self, '-16 -16 0', '16 16 48');
1036                         else
1037                                 setsize (self, '-16 -16 0', '16 16 32');
1038                         // note droptofloor returns FALSE if stuck/or would fall too far
1039                         droptofloor();
1040                         waypoint_spawnforitem(self);
1041                 }
1042
1043                 /*
1044                  * can't do it that way, as it would break maps
1045                  * TODO make a target_give like entity another way, that perhaps has
1046                  * the weapon name in a key
1047                 if(self.targetname)
1048                 {
1049                         // target_give not yet supported; maybe later
1050                         print("removed targeted ", self.classname, "\n");
1051                         startitem_failed = TRUE;
1052                         remove (self);
1053                         return;
1054                 }
1055                 */
1056
1057                 if(autocvar_spawn_debug >= 2)
1058                 {
1059                         entity otheritem;
1060                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1061                         {
1062                             // why not flags & fl_item?
1063                                 if(otheritem.is_item)
1064                                 {
1065                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1066                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1067                                         error("Mapper sucks.");
1068                                 }
1069                         }
1070                         self.is_item = TRUE;
1071                 }
1072
1073                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1074
1075                 precache_model (self.model);
1076                 precache_sound (self.item_pickupsound);
1077
1078                 precache_sound ("misc/itemrespawncountdown.wav");
1079                 if(itemid == IT_STRENGTH)
1080                         precache_sound ("misc/strength_respawn.wav");
1081                 else if(itemid == IT_INVINCIBLE)
1082                         precache_sound ("misc/shield_respawn.wav");
1083                 else
1084                         precache_sound ("misc/itemrespawn.wav");
1085
1086                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1087                         self.target = "###item###"; // for finding the nearest item using find()
1088         }
1089
1090         self.bot_pickup = TRUE;
1091         self.bot_pickupevalfunc = pickupevalfunc;
1092         self.bot_pickupbasevalue = pickupbasevalue;
1093         self.mdl = self.model;
1094         self.netname = itemname;
1095         self.touch = Item_Touch;
1096         setmodel(self, "null"); // precision set below
1097         //self.effects |= EF_LOWPRECISION;
1098
1099         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1100     {
1101         self.pos1 = '-16 -16 0';
1102         self.pos2 = '16 16 48';
1103     }
1104         else
1105     {
1106         self.pos1 = '-16 -16 0';
1107         self.pos2 = '16 16 32';
1108     }
1109     setsize (self, self.pos1, self.pos2);
1110
1111     if(itemflags & FL_POWERUP)
1112         self.ItemStatus |= ITS_ANIMATE1;
1113
1114         if(self.armorvalue || self.health)
1115         self.ItemStatus |= ITS_ANIMATE2;
1116
1117         if(itemflags & FL_WEAPON)
1118         {
1119                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1120             self.colormap = 1024; // color shirt=0 pants=0 grey
1121         else
1122             self.gravity = 1;
1123
1124                 self.ItemStatus |= ITS_ANIMATE1;
1125                 self.ItemStatus |= ISF_COLORMAP;
1126         }
1127
1128         self.state = 0;
1129         if(self.team) // broken, no idea why.
1130         {
1131                 if(!self.cnt)
1132                         self.cnt = 1; // item probability weight
1133
1134                 self.effects |= EF_NODRAW; // marker for item team search
1135                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1136         }
1137         else
1138                 Item_Reset();
1139
1140     Net_LinkEntity(self, FALSE, 0, ItemSend);
1141
1142         // call this hook after everything else has been done
1143         if(MUTATOR_CALLHOOK(Item_Spawn))
1144         {
1145                 startitem_failed = TRUE;
1146                 remove(self);
1147                 return;
1148         }
1149 }
1150
1151 float weaponswapping;
1152 float internalteam;
1153
1154 void weapon_defaultspawnfunc(float wpn)
1155 {
1156         entity e;
1157         float t;
1158         var .float ammofield;
1159         string s;
1160         entity oldself;
1161         float i, j;
1162         float f;
1163
1164         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1165         {
1166                 e = get_weaponinfo(wpn);
1167
1168                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1169                 {
1170                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1171                         startitem_failed = TRUE;
1172                         return;
1173                 }
1174
1175                 s = W_Apply_Weaponreplace(e.netname);
1176                 ret_string = s;
1177                 other = e;
1178                 MUTATOR_CALLHOOK(SetWeaponreplace);
1179                 s = ret_string;
1180                 if(s == "")
1181                 {
1182                         remove(self);
1183                         startitem_failed = TRUE;
1184                         return;
1185                 }
1186                 t = tokenize_console(s);
1187                 if(t >= 2)
1188                 {
1189                         self.team = --internalteam;
1190                         oldself = self;
1191                         for(i = 1; i < t; ++i)
1192                         {
1193                                 s = argv(i);
1194                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1195                                 {
1196                                         e = get_weaponinfo(j);
1197                                         if(e.netname == s)
1198                                         {
1199                                                 self = spawn();
1200                                                 copyentity(oldself, self);
1201                                                 self.classname = "replacedweapon";
1202                                                 weapon_defaultspawnfunc(j);
1203                                                 break;
1204                                         }
1205                                 }
1206                                 if(j > WEP_LAST)
1207                                 {
1208                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1209                                 }
1210                         }
1211                         self = oldself;
1212                 }
1213                 if(t >= 1) // always the case!
1214                 {
1215                         s = argv(0);
1216                         wpn = 0;
1217                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1218                         {
1219                                 e = get_weaponinfo(j);
1220                                 if(e.netname == s)
1221                                 {
1222                                         wpn = j;
1223                                         break;
1224                                 }
1225                         }
1226                         if(j > WEP_LAST)
1227                         {
1228                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1229                         }
1230                 }
1231                 if(wpn == 0)
1232                 {
1233                         remove(self);
1234                         startitem_failed = TRUE;
1235                         return;
1236                 }
1237         }
1238
1239         e = get_weaponinfo(wpn);
1240
1241         if(!self.respawntime)
1242         {
1243                 if(e.weapons & WEPSET_SUPERWEAPONS)
1244                 {
1245                         self.respawntime = g_pickup_respawntime_superweapon;
1246                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1247                 }
1248                 else
1249                 {
1250                         self.respawntime = g_pickup_respawntime_weapon;
1251                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1252                 }
1253         }
1254
1255         if(e.weapons & WEPSET_SUPERWEAPONS)
1256                 if(!self.superweapons_finished)
1257                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1258
1259         if(e.items)
1260         {
1261                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1262                 {
1263                         if(e.items & j)
1264                         {
1265                                 ammofield = Item_CounterField(j);
1266                                 if(!self.ammofield)
1267                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1268                         }
1269                 }
1270         }
1271
1272         // pickup anyway
1273         if(g_pickup_weapons_anyway)
1274                 self.pickup_anyway = TRUE;
1275
1276         f = FL_WEAPON;
1277
1278         // no weapon-stay on superweapons
1279         if(e.weapons & WEPSET_SUPERWEAPONS)
1280                 f |= FL_NO_WEAPON_STAY;
1281
1282         // weapon stay isn't supported for teamed weapons
1283         if(self.team)
1284                 f |= FL_NO_WEAPON_STAY;
1285
1286         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1287         if (self.modelindex) // don't precache if self was removed
1288                 weapon_action(e.weapon, WR_PRECACHE);
1289 }
1290
1291 void spawnfunc_weapon_shotgun (void);
1292 void spawnfunc_weapon_uzi (void) {
1293         if(autocvar_sv_q3acompat_machineshotgunswap)
1294         if(self.classname != "droppedweapon")
1295         {
1296                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1297                 return;
1298         }
1299         weapon_defaultspawnfunc(WEP_UZI);
1300 }
1301
1302 void spawnfunc_weapon_shotgun (void) {
1303         if(autocvar_sv_q3acompat_machineshotgunswap)
1304         if(self.classname != "droppedweapon")
1305         {
1306                 weapon_defaultspawnfunc(WEP_UZI);
1307                 return;
1308         }
1309         weapon_defaultspawnfunc(WEP_SHOTGUN);
1310 }
1311
1312 void spawnfunc_weapon_nex (void)
1313 {
1314         weapon_defaultspawnfunc(WEP_NEX);
1315 }
1316
1317 void spawnfunc_weapon_minstanex (void)
1318 {
1319         weapon_defaultspawnfunc(WEP_MINSTANEX);
1320 }
1321
1322 void spawnfunc_weapon_rocketlauncher (void)
1323 {
1324         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1325 }
1326
1327 void spawnfunc_item_rockets (void) {
1328         if(!self.ammo_rockets)
1329                 self.ammo_rockets = g_pickup_rockets;
1330         if(!self.pickup_anyway)
1331                 self.pickup_anyway = g_pickup_ammo_anyway;
1332         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1333 }
1334
1335 void spawnfunc_item_shells (void);
1336 void spawnfunc_item_bullets (void) {
1337         if(!weaponswapping)
1338         if(autocvar_sv_q3acompat_machineshotgunswap)
1339         if(self.classname != "droppedweapon")
1340         {
1341                 weaponswapping = TRUE;
1342                 spawnfunc_item_shells();
1343                 weaponswapping = FALSE;
1344                 return;
1345         }
1346
1347         if(!self.ammo_nails)
1348                 self.ammo_nails = g_pickup_nails;
1349         if(!self.pickup_anyway)
1350                 self.pickup_anyway = g_pickup_ammo_anyway;
1351         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1352 }
1353
1354 void spawnfunc_item_cells (void) {
1355         if(!self.ammo_cells)
1356                 self.ammo_cells = g_pickup_cells;
1357         if(!self.pickup_anyway)
1358                 self.pickup_anyway = g_pickup_ammo_anyway;
1359         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1360 }
1361
1362 void spawnfunc_item_shells (void) {
1363         if(!weaponswapping)
1364         if(autocvar_sv_q3acompat_machineshotgunswap)
1365         if(self.classname != "droppedweapon")
1366         {
1367                 weaponswapping = TRUE;
1368                 spawnfunc_item_bullets();
1369                 weaponswapping = FALSE;
1370                 return;
1371         }
1372
1373         if(!self.ammo_shells)
1374                 self.ammo_shells = g_pickup_shells;
1375         if(!self.pickup_anyway)
1376                 self.pickup_anyway = g_pickup_ammo_anyway;
1377         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1378 }
1379
1380 void spawnfunc_item_armor_small (void) {
1381         if(!self.armorvalue)
1382                 self.armorvalue = g_pickup_armorsmall;
1383         if(!self.max_armorvalue)
1384                 self.max_armorvalue = g_pickup_armorsmall_max;
1385         if(!self.pickup_anyway)
1386                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1387         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1388 }
1389
1390 void spawnfunc_item_armor_medium (void) {
1391         if(!self.armorvalue)
1392                 self.armorvalue = g_pickup_armormedium;
1393         if(!self.max_armorvalue)
1394                 self.max_armorvalue = g_pickup_armormedium_max;
1395         if(!self.pickup_anyway)
1396                 self.pickup_anyway = g_pickup_armormedium_anyway;
1397         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1398 }
1399
1400 void spawnfunc_item_armor_big (void) {
1401         if(!self.armorvalue)
1402                 self.armorvalue = g_pickup_armorbig;
1403         if(!self.max_armorvalue)
1404                 self.max_armorvalue = g_pickup_armorbig_max;
1405         if(!self.pickup_anyway)
1406                 self.pickup_anyway = g_pickup_armorbig_anyway;
1407         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1408 }
1409
1410 void spawnfunc_item_armor_large (void) {
1411         if(!self.armorvalue)
1412                 self.armorvalue = g_pickup_armorlarge;
1413         if(!self.max_armorvalue)
1414                 self.max_armorvalue = g_pickup_armorlarge_max;
1415         if(!self.pickup_anyway)
1416                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1417         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1418 }
1419
1420 void spawnfunc_item_health_small (void) {
1421         if(!self.max_health)
1422                 self.max_health = g_pickup_healthsmall_max;
1423         if(!self.health)
1424                 self.health = g_pickup_healthsmall;
1425         if(!self.pickup_anyway)
1426                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1427         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1428 }
1429
1430 void spawnfunc_item_health_medium (void) {
1431         if(!self.max_health)
1432                 self.max_health = g_pickup_healthmedium_max;
1433         if(!self.health)
1434                 self.health = g_pickup_healthmedium;
1435         if(!self.pickup_anyway)
1436                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1437         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1438 }
1439
1440 void spawnfunc_item_health_large (void) {
1441         if(!self.max_health)
1442                 self.max_health = g_pickup_healthlarge_max;
1443         if(!self.health)
1444                 self.health = g_pickup_healthlarge;
1445         if(!self.pickup_anyway)
1446                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1447         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1448 }
1449
1450 void spawnfunc_item_health_mega (void) {
1451                 if(!self.max_health)
1452                         self.max_health = g_pickup_healthmega_max;
1453                 if(!self.health)
1454                         self.health = g_pickup_healthmega;
1455                 if(!self.pickup_anyway)
1456                         self.pickup_anyway = g_pickup_healthmega_anyway;
1457                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1458 }
1459
1460 // support old misnamed entities
1461 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1462 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1463 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1464 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1465 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1466
1467 void spawnfunc_item_strength (void) {
1468                 precache_sound("weapons/strength_fire.wav");
1469                 if(!self.strength_finished)
1470                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1471                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1472 }
1473
1474 void spawnfunc_item_invincible (void) {
1475                 if(!self.invincible_finished)
1476                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1477                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1478 }
1479
1480 // compatibility:
1481 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1482
1483 float GiveItems(entity e, float beginarg, float endarg);
1484 void target_items_use (void)
1485 {
1486         if(activator.classname == "droppedweapon")
1487         {
1488                 EXACTTRIGGER_TOUCH;
1489                 remove(activator);
1490                 return;
1491         }
1492
1493         if (!IS_PLAYER(activator))
1494                 return;
1495         if(activator.deadflag != DEAD_NO)
1496                 return;
1497         EXACTTRIGGER_TOUCH;
1498
1499         entity e;
1500         for(e = world; (e = find(e, classname, "droppedweapon")); )
1501                 if(e.enemy == activator)
1502                         remove(e);
1503
1504         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1505                 centerprint(activator, self.message);
1506 }
1507
1508 void spawnfunc_target_items (void)
1509 {
1510         float n, i, j;
1511         entity e;
1512
1513         self.use = target_items_use;
1514         if(!self.strength_finished)
1515                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1516         if(!self.invincible_finished)
1517                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1518         if(!self.superweapons_finished)
1519                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1520
1521         precache_sound("misc/itempickup.wav");
1522         precache_sound("misc/megahealth.wav");
1523         precache_sound("misc/armor25.wav");
1524         precache_sound("misc/powerup.wav");
1525         precache_sound("misc/poweroff.wav");
1526         precache_sound("weapons/weaponpickup.wav");
1527
1528         n = tokenize_console(self.netname);
1529         if(argv(0) == "give")
1530         {
1531                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1532         }
1533         else
1534         {
1535                 for(i = 0; i < n; ++i)
1536                 {
1537                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1538                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1539                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1540                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1541                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1542                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1543                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1544                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1545                         else
1546                         {
1547                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1548                                 {
1549                                         e = get_weaponinfo(j);
1550                                         if(argv(i) == e.netname)
1551                                         {
1552                                                 self.weapons |= WepSet_FromWeapon(j);
1553                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1554                                                         weapon_action(e.weapon, WR_PRECACHE);
1555                                                 break;
1556                                         }
1557                                 }
1558                                 if(j > WEP_LAST)
1559                                         print("target_items: invalid item ", argv(i), "\n");
1560                         }
1561                 }
1562
1563                 string itemprefix, valueprefix;
1564                 if(self.spawnflags == 0)
1565                 {
1566                         itemprefix = "";
1567                         valueprefix = "";
1568                 }
1569                 else if(self.spawnflags == 1)
1570                 {
1571                         itemprefix = "max ";
1572                         valueprefix = "max ";
1573                 }
1574                 else if(self.spawnflags == 2)
1575                 {
1576                         itemprefix = "min ";
1577                         valueprefix = "min ";
1578                 }
1579                 else if(self.spawnflags == 4)
1580                 {
1581                         itemprefix = "minus ";
1582                         valueprefix = "max ";
1583                 }
1584                 else
1585                 {
1586                         error("invalid spawnflags");
1587 #ifdef GMQCC
1588                         itemprefix = string_null;
1589                         valueprefix = string_null;
1590 #endif
1591                 }
1592
1593                 self.netname = "";
1594                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1595                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1596                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1597                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1598                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1599                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1600                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1601                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1602                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1603                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1604                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1605                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1606                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1607                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1608                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1609                 {
1610                         e = get_weaponinfo(j);
1611                         if(e.weapon)
1612                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1613                 }
1614         }
1615         self.netname = strzone(self.netname);
1616         //print(self.netname, "\n");
1617
1618         n = tokenize_console(self.netname);
1619         for(i = 0; i < n; ++i)
1620         {
1621                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1622                 {
1623                         e = get_weaponinfo(j);
1624                         if(argv(i) == e.netname)
1625                         {
1626                                 weapon_action(e.weapon, WR_PRECACHE);
1627                                 break;
1628                         }
1629                 }
1630         }
1631 }
1632
1633 void spawnfunc_item_fuel(void)
1634 {
1635         if(!self.ammo_fuel)
1636                 self.ammo_fuel = g_pickup_fuel;
1637         if(!self.pickup_anyway)
1638                 self.pickup_anyway = g_pickup_ammo_anyway;
1639         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1640 }
1641
1642 void spawnfunc_item_fuel_regen(void)
1643 {
1644         if(start_items & IT_FUEL_REGEN)
1645         {
1646                 spawnfunc_item_fuel();
1647                 return;
1648         }
1649         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1650 }
1651
1652 void spawnfunc_item_jetpack(void)
1653 {
1654         if(g_grappling_hook)
1655                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1656         if(!self.ammo_fuel)
1657                 self.ammo_fuel = g_pickup_fuel_jetpack;
1658         if(start_items & IT_JETPACK)
1659         {
1660                 spawnfunc_item_fuel();
1661                 return;
1662         }
1663         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1664 }
1665
1666
1667 #define OP_SET 0
1668 #define OP_MIN 1
1669 #define OP_MAX 2
1670 #define OP_PLUS 3
1671 #define OP_MINUS 4
1672
1673 float GiveWeapon(entity e, float wpn, float op, float val)
1674 {
1675         WepSet v0, v1;
1676         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1677         switch(op)
1678         {
1679                 case OP_SET:
1680                         if(val > 0)
1681                                 e.weapons |= WepSet_FromWeapon(wpn);
1682                         else
1683                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1684                         break;
1685                 case OP_MIN:
1686                 case OP_PLUS:
1687                         if(val > 0)
1688                                 e.weapons |= WepSet_FromWeapon(wpn);
1689                         break;
1690                 case OP_MAX:
1691                         if(val <= 0)
1692                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1693                         break;
1694                 case OP_MINUS:
1695                         if(val > 0)
1696                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1697                         break;
1698         }
1699         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1700         return (v0 != v1);
1701 }
1702
1703 float GiveBit(entity e, .float fld, float bit, float op, float val)
1704 {
1705         float v0, v1;
1706         v0 = (e.fld & bit);
1707         switch(op)
1708         {
1709                 case OP_SET:
1710                         if(val > 0)
1711                                 e.fld |= bit;
1712                         else
1713                                 e.fld &= ~bit;
1714                         break;
1715                 case OP_MIN:
1716                 case OP_PLUS:
1717                         if(val > 0)
1718                                 e.fld |= bit;
1719                         break;
1720                 case OP_MAX:
1721                         if(val <= 0)
1722                                 e.fld &= ~bit;
1723                         break;
1724                 case OP_MINUS:
1725                         if(val > 0)
1726                                 e.fld &= ~bit;
1727                         break;
1728         }
1729         v1 = (e.fld & bit);
1730         return (v0 != v1);
1731 }
1732
1733 float GiveValue(entity e, .float fld, float op, float val)
1734 {
1735         float v0, v1;
1736         v0 = e.fld;
1737         switch(op)
1738         {
1739                 case OP_SET:
1740                         e.fld = val;
1741                         break;
1742                 case OP_MIN:
1743                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1744                         break;
1745                 case OP_MAX:
1746                         e.fld = min(e.fld, val);
1747                         break;
1748                 case OP_PLUS:
1749                         e.fld += val;
1750                         break;
1751                 case OP_MINUS:
1752                         e.fld -= val;
1753                         break;
1754         }
1755         v1 = e.fld;
1756         return (v0 != v1);
1757 }
1758
1759 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1760 {
1761         if(v1 == v0)
1762                 return;
1763         if(v1 <= v0 - t)
1764         {
1765                 if(snd_decr != "")
1766                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1767         }
1768         else if(v0 >= v0 + t)
1769         {
1770                 if(snd_incr != "")
1771                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1772         }
1773 }
1774
1775 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1776 {
1777         if(v0 < v1)
1778                 e.rotfield = max(e.rotfield, time + rottime);
1779         else if(v0 > v1)
1780                 e.regenfield = max(e.regenfield, time + regentime);
1781 }
1782
1783 #define PREGIVE_WEAPONS(e) WepSet save_weapons; save_weapons = e.weapons
1784 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1785 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), !!(save_weapons & WepSet_FromWeapon(b)), !!(e.weapons & WepSet_FromWeapon(b)), 0, snd_incr, snd_decr)
1786 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1787 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1788 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1789
1790 float GiveItems(entity e, float beginarg, float endarg)
1791 {
1792         float got, i, j, val, op;
1793         float _switchweapon;
1794         entity wi;
1795         string cmd;
1796
1797         val = 999;
1798         op = OP_SET;
1799
1800         got = 0;
1801
1802         _switchweapon = FALSE;
1803         if (e.autoswitch)
1804                 if (e.switchweapon == w_getbestweapon(e))
1805                         _switchweapon = TRUE;
1806
1807         e.strength_finished = max(0, e.strength_finished - time);
1808         e.invincible_finished = max(0, e.invincible_finished - time);
1809         e.superweapons_finished = max(0, e.superweapons_finished - time);
1810
1811         PREGIVE(e, items);
1812         PREGIVE_WEAPONS(e);
1813         PREGIVE(e, strength_finished);
1814         PREGIVE(e, invincible_finished);
1815         PREGIVE(e, superweapons_finished);
1816         PREGIVE(e, ammo_nails);
1817         PREGIVE(e, ammo_cells);
1818         PREGIVE(e, ammo_shells);
1819         PREGIVE(e, ammo_rockets);
1820         PREGIVE(e, ammo_fuel);
1821         PREGIVE(e, armorvalue);
1822         PREGIVE(e, health);
1823
1824         for(i = beginarg; i < endarg; ++i)
1825         {
1826                 cmd = argv(i);
1827
1828                 if(cmd == "0" || stof(cmd))
1829                 {
1830                         val = stof(cmd);
1831                         continue;
1832                 }
1833                 switch(cmd)
1834                 {
1835                         case "no":
1836                                 op = OP_MAX;
1837                                 val = 0;
1838                                 continue;
1839                         case "max":
1840                                 op = OP_MAX;
1841                                 continue;
1842                         case "min":
1843                                 op = OP_MIN;
1844                                 continue;
1845                         case "plus":
1846                                 op = OP_PLUS;
1847                                 continue;
1848                         case "minus":
1849                                 op = OP_MINUS;
1850                                 continue;
1851                         case "ALL":
1852                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1853                                 got += GiveValue(e, strength_finished, op, val);
1854                                 got += GiveValue(e, invincible_finished, op, val);
1855                                 got += GiveValue(e, superweapons_finished, op, val);
1856                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1857                         case "all":
1858                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1859                                 got += GiveValue(e, health, op, val);
1860                                 got += GiveValue(e, armorvalue, op, val);
1861                         case "allweapons":
1862                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1863                                 {
1864                                         wi = get_weaponinfo(j);
1865                                         if(wi.weapon)
1866                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1867                                                         got += GiveWeapon(e, j, op, val);
1868                                 }
1869                         case "allammo":
1870                                 got += GiveValue(e, ammo_cells, op, val);
1871                                 got += GiveValue(e, ammo_shells, op, val);
1872                                 got += GiveValue(e, ammo_nails, op, val);
1873                                 got += GiveValue(e, ammo_rockets, op, val);
1874                                 got += GiveValue(e, ammo_fuel, op, val);
1875                                 break;
1876                         case "unlimited_ammo":
1877                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1878                                 break;
1879                         case "unlimited_weapon_ammo":
1880                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1881                                 break;
1882                         case "unlimited_superweapons":
1883                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1884                                 break;
1885                         case "jetpack":
1886                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1887                                 break;
1888                         case "fuel_regen":
1889                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1890                                 break;
1891                         case "strength":
1892                                 got += GiveValue(e, strength_finished, op, val);
1893                                 break;
1894                         case "invincible":
1895                                 got += GiveValue(e, invincible_finished, op, val);
1896                                 break;
1897                         case "superweapons":
1898                                 got += GiveValue(e, superweapons_finished, op, val);
1899                                 break;
1900                         case "cells":
1901                                 got += GiveValue(e, ammo_cells, op, val);
1902                                 break;
1903                         case "shells":
1904                                 got += GiveValue(e, ammo_shells, op, val);
1905                                 break;
1906                         case "nails":
1907                         case "bullets":
1908                                 got += GiveValue(e, ammo_nails, op, val);
1909                                 break;
1910                         case "rockets":
1911                                 got += GiveValue(e, ammo_rockets, op, val);
1912                                 break;
1913                         case "health":
1914                                 got += GiveValue(e, health, op, val);
1915                                 break;
1916                         case "armor":
1917                                 got += GiveValue(e, armorvalue, op, val);
1918                                 break;
1919                         case "fuel":
1920                                 got += GiveValue(e, ammo_fuel, op, val);
1921                                 break;
1922                         default:
1923                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1924                                 {
1925                                         wi = get_weaponinfo(j);
1926                                         if(cmd == wi.netname)
1927                                         {
1928                                                 got += GiveWeapon(e, j, op, val);
1929                                                 break;
1930                                         }
1931                                 }
1932                                 if(j > WEP_LAST)
1933                                         print("give: invalid item ", cmd, "\n");
1934                                 break;
1935                 }
1936                 val = 999;
1937                 op = OP_SET;
1938         }
1939
1940         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1941         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1942         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1943         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1944         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1945         {
1946                 wi = get_weaponinfo(j);
1947                 if(wi.weapon)
1948                 {
1949                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1950                         if (!(save_weapons & WepSet_FromWeapon(j)))
1951                                 if(e.weapons & WepSet_FromWeapon(j))
1952                                         weapon_action(wi.weapon, WR_PRECACHE);
1953                 }
1954         }
1955         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1956         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1957         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1958         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1959         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1960         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1961         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1962         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1963         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1964
1965         if(e.superweapons_finished <= 0)
1966                 if(self.weapons & WEPSET_SUPERWEAPONS)
1967                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1968
1969         if(e.strength_finished <= 0)
1970                 e.strength_finished = 0;
1971         else
1972                 e.strength_finished += time;
1973         if(e.invincible_finished <= 0)
1974                 e.invincible_finished = 0;
1975         else
1976                 e.invincible_finished += time;
1977         if(e.superweapons_finished <= 0)
1978                 e.superweapons_finished = 0;
1979         else
1980                 e.superweapons_finished += time;
1981
1982         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1983                 _switchweapon = TRUE;
1984         if(_switchweapon)
1985                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1986
1987         return got;
1988 }
1989 #endif