qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "waypointsprites.qh"
   9
  10     #include "bot/bot.qh"
  11     #include "bot/waypoints.qh"
  12
  13     #include "mutators/mutators_include.qh"
  14
  15     #include "weapons/common.qh"
  16     #include "weapons/selection.qh"
  17     #include "weapons/weaponsystem.qh"
  18
  19     #include "../common/constants.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "../common/notifications.qh"
  22         #include "../common/triggers/subs.qh"
  23     #include "../common/util.qh"
  24
  25     #include "../common/monsters/all.qh"
  26
  27     #include "../common/weapons/all.qh"
  28
  29     #include "../warpzonelib/util_server.qh"
  30 #endif
  31
  32 #ifdef CSQC
  33 void ItemDraw()
  34 {
  35     if(self.gravity)
  36     {
  37         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  38         if(self.move_flags & FL_ONGROUND)
  39         { // For some reason move_avelocity gets set to '0 0 0' here ...
  40             self.oldorigin = self.origin;
  41             self.gravity = 0;
  42
  43             if(autocvar_cl_animate_items)
  44             { // ... so reset it if animations are requested.
  45                 if(self.ItemStatus & ITS_ANIMATE1)
  46                     self.move_avelocity = '0 180 0';
  47
  48                 if(self.ItemStatus & ITS_ANIMATE2)
  49                     self.move_avelocity = '0 -90 0';
  50             }
  51         }
  52     }
  53     else if (autocvar_cl_animate_items)
  54     {
  55         if(self.ItemStatus & ITS_ANIMATE1)
  56         {
  57             self.angles += self.move_avelocity * frametime;
  58             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  59         }
  60
  61         if(self.ItemStatus & ITS_ANIMATE2)
  62         {
  63             self.angles += self.move_avelocity * frametime;
  64             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  65         }
  66     }
  67 }
  68
  69 void ItemDrawSimple()
  70 {
  71     if(self.gravity)
  72     {
  73         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74
  75         if(self.move_flags & FL_ONGROUND)
  76             self.gravity = 0;
  77     }
  78 }
  79
  80 void ItemRead(float _IsNew)
  81 {
  82     int sf = ReadByte();
  83
  84     if(sf & ISF_LOCATION)
  85     {
  86         self.origin_x = ReadCoord();
  87         self.origin_y = ReadCoord();
  88         self.origin_z = ReadCoord();
  89         setorigin(self, self.origin);
  90         self.oldorigin = self.origin;
  91     }
  92
  93     if(sf & ISF_ANGLES)
  94     {
  95         self.angles_x = ReadCoord();
  96         self.angles_y = ReadCoord();
  97         self.angles_z = ReadCoord();
  98         self.move_angles = self.angles;
  99     }
 100
 101     if(sf & ISF_SIZE)
 102     {
 103         self.mins_x = ReadCoord();
 104         self.mins_y = ReadCoord();
 105         self.mins_z = ReadCoord();
 106         self.maxs_x = ReadCoord();
 107         self.maxs_y = ReadCoord();
 108         self.maxs_z = ReadCoord();
 109         setsize(self, self.mins, self.maxs);
 110     }
 111
 112     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 113     {
 114         self.ItemStatus = ReadByte();
 115
 116         if(self.ItemStatus & ITS_AVAILABLE)
 117         {
 118             self.alpha = 1;
 119             self.colormod = self.glowmod = '1 1 1';
 120         }
 121         else
 122         {
 123             if (autocvar_cl_ghost_items_color)
 124             {
 125                 self.alpha = autocvar_cl_ghost_items;
 126                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 127             }
 128             else
 129                 self.alpha = -1;
 130         }
 131
 132         if(autocvar_cl_fullbright_items)
 133             if(self.ItemStatus & ITS_ALLOWFB)
 134                 self.effects |= EF_FULLBRIGHT;
 135
 136         if(self.ItemStatus & ITS_STAYWEP)
 137         {
 138             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 139             self.alpha = autocvar_cl_weapon_stay_alpha;
 140
 141         }
 142
 143         if(self.ItemStatus & ITS_POWERUP)
 144         {
 145             if(self.ItemStatus & ITS_AVAILABLE)
 146                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 147             else
 148                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 149         }
 150     }
 151
 152     if(sf & ISF_MODEL)
 153     {
 154         self.drawmask  = MASK_NORMAL;
 155         self.movetype  = MOVETYPE_TOSS;
 156         self.draw       = ItemDraw;
 157
 158         if(self.mdl)
 159             strunzone(self.mdl);
 160
 161         self.mdl = "";
 162         string _fn = ReadString();
 163
 164         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 165         {
 166             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 167             self.draw = ItemDrawSimple;
 168
 169
 170
 171             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 177             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 178                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 179             else
 180             {
 181                 self.draw = ItemDraw;
 182                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 183             }
 184         }
 185
 186         if(self.draw != ItemDrawSimple)
 187             self.mdl = strzone(_fn);
 188
 189
 190         if(self.mdl == "")
 191             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 192
 193         precache_model(self.mdl);
 194         setmodel(self, self.mdl);
 195     }
 196
 197     if(sf & ISF_COLORMAP)
 198         self.colormap = ReadShort();
 199
 200     if(sf & ISF_DROP)
 201     {
 202         self.gravity = 1;
 203         //self.move_angles = '0 0 0';
 204         self.move_movetype = MOVETYPE_TOSS;
 205         self.move_velocity_x = ReadCoord();
 206         self.move_velocity_y = ReadCoord();
 207         self.move_velocity_z = ReadCoord();
 208         self.velocity = self.move_velocity;
 209         self.move_origin = self.oldorigin;
 210
 211         if(!self.move_time)
 212         {
 213             self.move_time = time;
 214             self.spawntime = time;
 215         }
 216         else
 217             self.move_time = max(self.move_time, time);
 218     }
 219
 220     if(autocvar_cl_animate_items)
 221     {
 222         if(self.ItemStatus & ITS_ANIMATE1)
 223             self.move_avelocity = '0 180 0';
 224
 225         if(self.ItemStatus & ITS_ANIMATE2)
 226             self.move_avelocity = '0 -90 0';
 227     }
 228 }
 229
 230 #endif
 231
 232 #ifdef SVQC
 233 bool ItemSend(entity to, int sf)
 234 {
 235     if(self.gravity)
 236         sf |= ISF_DROP;
 237     else
 238         sf &= ~ISF_DROP;
 239
 240         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 241         WriteByte(MSG_ENTITY, sf);
 242
 243         //WriteByte(MSG_ENTITY, self.cnt);
 244     if(sf & ISF_LOCATION)
 245     {
 246         WriteCoord(MSG_ENTITY, self.origin.x);
 247         WriteCoord(MSG_ENTITY, self.origin.y);
 248         WriteCoord(MSG_ENTITY, self.origin.z);
 249     }
 250
 251     if(sf & ISF_ANGLES)
 252     {
 253         WriteCoord(MSG_ENTITY, self.angles.x);
 254         WriteCoord(MSG_ENTITY, self.angles.y);
 255         WriteCoord(MSG_ENTITY, self.angles.z);
 256     }
 257
 258     if(sf & ISF_SIZE)
 259     {
 260         WriteCoord(MSG_ENTITY, self.mins.x);
 261         WriteCoord(MSG_ENTITY, self.mins.y);
 262         WriteCoord(MSG_ENTITY, self.mins.z);
 263         WriteCoord(MSG_ENTITY, self.maxs.x);
 264         WriteCoord(MSG_ENTITY, self.maxs.y);
 265         WriteCoord(MSG_ENTITY, self.maxs.z);
 266     }
 267
 268     if(sf & ISF_STATUS)
 269         WriteByte(MSG_ENTITY, self.ItemStatus);
 270
 271     if(sf & ISF_MODEL)
 272     {
 273
 274         if(self.mdl == "")
 275             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 276
 277         WriteString(MSG_ENTITY, self.mdl);
 278     }
 279
 280
 281     if(sf & ISF_COLORMAP)
 282         WriteShort(MSG_ENTITY, self.colormap);
 283
 284     if(sf & ISF_DROP)
 285     {
 286         WriteCoord(MSG_ENTITY, self.velocity.x);
 287         WriteCoord(MSG_ENTITY, self.velocity.y);
 288         WriteCoord(MSG_ENTITY, self.velocity.z);
 289     }
 290
 291     return true;
 292 }
 293
 294 void ItemUpdate(entity item)
 295 {
 296         item.SendFlags |= ISF_LOCATION;
 297 }
 298
 299 float have_pickup_item(void)
 300 {
 301         if(self.flags & FL_POWERUP)
 302         {
 303                 if(autocvar_g_powerups > 0)
 304                         return true;
 305                 if(autocvar_g_powerups == 0)
 306                         return false;
 307         }
 308         else
 309         {
 310                 if(autocvar_g_pickup_items > 0)
 311                         return true;
 312                 if(autocvar_g_pickup_items == 0)
 313                         return false;
 314                 if(g_weaponarena)
 315                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 316                                 return false;
 317         }
 318         return true;
 319 }
 320
 321 /*
 322 float Item_Customize()
 323 {
 324         if(self.spawnshieldtime)
 325                 return true;
 326         if(self.weapons & ~other.weapons)
 327         {
 328                 self.colormod = '0 0 0';
 329                 self.glowmod = self.colormod;
 330                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 331                 return true;
 332         }
 333         else
 334         {
 335                 if(g_ghost_items)
 336                 {
 337                         self.colormod = stov(autocvar_g_ghost_items_color);
 338                         self.glowmod = self.colormod;
 339                         self.alpha = g_ghost_items;
 340                         return true;
 341                 }
 342                 else
 343                         return false;
 344         }
 345 }
 346 */
 347
 348 void Item_Show (entity e, float mode)
 349 {
 350         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 351         e.ItemStatus &= ~ITS_STAYWEP;
 352         if (mode > 0)
 353         {
 354                 // make the item look normal, and be touchable
 355                 e.model = e.mdl;
 356                 e.solid = SOLID_TRIGGER;
 357                 e.spawnshieldtime = 1;
 358                 e.ItemStatus |= ITS_AVAILABLE;
 359         }
 360         else if (mode < 0)
 361         {
 362                 // hide the item completely
 363                 e.model = string_null;
 364                 e.solid = SOLID_NOT;
 365                 e.spawnshieldtime = 1;
 366                 e.ItemStatus &= ~ITS_AVAILABLE;
 367         }
 368         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 369         {
 370                 // make the item translucent and not touchable
 371                 e.model = e.mdl;
 372                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 373                 e.effects |= EF_STARDUST;
 374                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 375                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 376         }
 377         else
 378         {
 379                 //setmodel(e, "null");
 380                 e.solid = SOLID_NOT;
 381                 e.colormod = '0 0 0';
 382                 e.glowmod = e.colormod;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus &= ~ITS_AVAILABLE;
 385         }
 386
 387         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 388             e.ItemStatus |= ITS_POWERUP;
 389
 390         if (autocvar_g_nodepthtestitems)
 391                 e.effects |= EF_NODEPTHTEST;
 392
 393
 394     if (autocvar_g_fullbrightitems)
 395                 e.ItemStatus |= ITS_ALLOWFB;
 396
 397         if (autocvar_sv_simple_items)
 398         e.ItemStatus |= ITS_ALLOWSI;
 399
 400         // relink entity (because solid may have changed)
 401         setorigin(e, e.origin);
 402     e.SendFlags |= ISF_STATUS;
 403 }
 404
 405 void Item_Think()
 406 {
 407         self.nextthink = time;
 408         if(self.origin != self.oldorigin)
 409         {
 410                 self.oldorigin = self.origin;
 411                 ItemUpdate(self);
 412         }
 413 }
 414
 415 float it_armor_large_time;
 416 float it_health_mega_time;
 417 float it_invisible_time;
 418 float it_speed_time;
 419 float it_extralife_time;
 420 float it_strength_time;
 421 float it_shield_time;
 422 float it_fuelregen_time;
 423 float it_jetpack_time;
 424 float it_superweapons_time;
 425
 426 void Item_ItemsTime_Init()
 427 {
 428         it_armor_large_time = -1;
 429         it_health_mega_time = -1;
 430         it_invisible_time = -1;
 431         it_speed_time = -1;
 432         it_extralife_time = -1;
 433         it_strength_time = -1;
 434         it_shield_time = -1;
 435         it_fuelregen_time = -1;
 436         it_jetpack_time = -1;
 437         it_superweapons_time = -1;
 438 }
 439 void Item_ItemsTime_ResetTimes()
 440 {
 441         it_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 442         it_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 443         it_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 444         it_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 445         it_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 446         it_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 447         it_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 448         it_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 449         it_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 450         it_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 451 }
 452 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 453 {
 454         e.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 455         e.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 456         e.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 457         e.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 458         e.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 459         e.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 460         e.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 461         e.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 462         e.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 463         e.item_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 464 }
 465 void Item_ItemsTime_SetTimesForPlayer(entity e)
 466 {
 467         e.item_armor_large_time = it_armor_large_time;
 468         e.item_health_mega_time = it_health_mega_time;
 469         e.item_invisible_time = it_invisible_time;
 470         e.item_speed_time = it_speed_time;
 471         e.item_extralife_time = it_extralife_time;
 472         e.item_strength_time = it_strength_time;
 473         e.item_shield_time = it_shield_time;
 474         e.item_fuelregen_time = it_fuelregen_time;
 475         e.item_jetpack_time = it_jetpack_time;
 476         e.item_superweapons_time = it_superweapons_time;
 477 }
 478 bool Item_ItemsTime_UpdateTime_Check(float item_time, float t)
 479 {
 480         if(t == 0 && item_time == -1)
 481                 return true;
 482         if(t < 0) // negative means there's another available item of the same kind
 483                 t = -t;
 484         if(time < t && (item_time <= time || t < item_time))
 485                 return true;
 486         return false;
 487 }
 488 void Item_ItemsTime_UpdateTime(entity e, float t)
 489 {
 490         if(!autocvar_sv_itemstime)
 491                 return;
 492
 493         if(g_instagib)
 494         {
 495                 switch(e.items)
 496                 {
 497                         case IT_STRENGTH://"item-invis"
 498                                 if(Item_ItemsTime_UpdateTime_Check(it_invisible_time, t))
 499                                         it_invisible_time = t;
 500                                 break;
 501                         case IT_NAILS://"item-extralife"
 502                                 if(Item_ItemsTime_UpdateTime_Check(it_extralife_time, t))
 503                                         it_extralife_time = t;
 504                                 break;
 505                         case IT_INVINCIBLE://"item-speed"
 506                                 if(Item_ItemsTime_UpdateTime_Check(it_speed_time, t))
 507                                         it_speed_time = t;
 508                                 break;
 509                 }
 510         }
 511         else
 512         {
 513                 switch(e.items)
 514                 {
 515                         case IT_HEALTH:
 516                                 // if(e.classname == "item_health_mega") // IT_HEALTH unequivocally identifies it
 517                                         if(Item_ItemsTime_UpdateTime_Check(it_health_mega_time, t))
 518                                                 it_health_mega_time = t;
 519                                 break;
 520                         case IT_ARMOR:
 521                                 if(e.classname == "item_armor_large") // IT_ARMOR doesn't unequivocally identifies it
 522                                         if(Item_ItemsTime_UpdateTime_Check(it_armor_large_time, t))
 523                                                 it_armor_large_time = t;
 524                                 break;
 525                         case IT_STRENGTH://"item-strength"
 526                                 if(Item_ItemsTime_UpdateTime_Check(it_strength_time, t))
 527                                         it_strength_time = t;
 528                                 break;
 529                         case IT_INVINCIBLE://"item-shield"
 530                                 if(Item_ItemsTime_UpdateTime_Check(it_shield_time, t))
 531                                         it_shield_time = t;
 532                                 break;
 533                         default:
 534                                 if(e.weapons & WEPSET_SUPERWEAPONS)
 535                                         if(Item_ItemsTime_UpdateTime_Check(it_superweapons_time, t))
 536                                                 it_superweapons_time = t;
 537                 }
 538         }
 539         switch(e.items)
 540         {
 541                 case IT_FUEL_REGEN://"item-fuelregen"
 542                         if(Item_ItemsTime_UpdateTime_Check(it_fuelregen_time, t))
 543                                 it_fuelregen_time = t;
 544                         break;
 545                 case IT_JETPACK://"item-jetpack"
 546                         if(Item_ItemsTime_UpdateTime_Check(it_jetpack_time, t))
 547                                 it_jetpack_time = t;
 548                         break;
 549         }
 550 }
 551 void Item_ItemsTime_SetTimesForAllPlayers()
 552 {
 553         entity e;
 554         if(warmup_stage)
 555         {
 556                 FOR_EACH_REALCLIENT(e)
 557                         Item_ItemsTime_SetTimesForPlayer(e);
 558         }
 559         else
 560         {
 561                 FOR_EACH_REALCLIENT(e)
 562                 {
 563                         if(!IS_PLAYER(e))
 564                                 Item_ItemsTime_SetTimesForPlayer(e);
 565                 }
 566         }
 567 }
 568
 569 float Item_ItemsTime_GetTime(entity e, float t)
 570 {
 571         entity head;
 572         bool isavailable = (t == 0);
 573         if(e.weapons & WEPSET_SUPERWEAPONS)
 574         {
 575                 for(head = world; (head = nextent(head)); )
 576                 {
 577                         if(clienttype(head) != CLIENTTYPE_NOTACLIENT || !(head.weapons & WEPSET_SUPERWEAPONS) || head.classname == "weapon_info")
 578                                 continue;
 579                         if(e == head)
 580                                 continue;
 581
 582                         if(head.scheduledrespawntime <= time)
 583                                 isavailable = true;
 584                         else if(t == 0 || head.scheduledrespawntime < t)
 585                                 t = head.scheduledrespawntime;
 586                 }
 587         }
 588         else
 589         {
 590                 for(head = world; (head = nextent(head)); )
 591                 {
 592                         if(head.itemdef != e.itemdef)
 593                                 continue;
 594                         if(e == head)
 595                                 continue;
 596
 597                         if(head.scheduledrespawntime <= time)
 598                                 isavailable = true;
 599                         else if(t == 0 || head.scheduledrespawntime < t)
 600                                 t = head.scheduledrespawntime;
 601                 }
 602         }
 603         if(isavailable)
 604                 t = -t; // let know the client there's another available item
 605         return t;
 606 }
 607
 608 void Item_Respawn (void)
 609 {
 610         Item_Show(self, 1);
 611         // this is ugly...
 612         if(self.items == IT_STRENGTH)
 613                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 614         else if(self.items == IT_INVINCIBLE)
 615                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 616         else
 617                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 618         setorigin (self, self.origin);
 619
 620         if(self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 621         {
 622                 float t = Item_ItemsTime_GetTime(self, 0);
 623                 Item_ItemsTime_UpdateTime(self, t);
 624                 Item_ItemsTime_SetTimesForAllPlayers();
 625         }
 626
 627         self.think = Item_Think;
 628         self.nextthink = time;
 629
 630         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 631         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 632 }
 633
 634 void Item_RespawnCountdown (void)
 635 {
 636         if(self.count >= ITEM_RESPAWN_TICKS)
 637         {
 638                 if(self.waypointsprite_attached)
 639                         WaypointSprite_Kill(self.waypointsprite_attached);
 640                 Item_Respawn();
 641         }
 642         else
 643         {
 644                 self.nextthink = time + 1;
 645                 self.count += 1;
 646                 if(self.count == 1)
 647                 {
 648                         string name;
 649                         vector rgb = '1 0 1';
 650                         name = string_null;
 651                         switch(self.items)
 652                         {
 653                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 654                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 655                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 656                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 657                                 case IT_HEALTH:
 658                                         //if (self.classname == "item_health_mega")
 659                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 660                                         break;
 661                                 case IT_ARMOR:
 662                                         if (self.classname == "item_armor_large")
 663                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 664                                         break;
 665                         }
 666                         item_name = name;
 667                         item_color = rgb;
 668                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 669                         name = item_name;
 670                         rgb = item_color;
 671                         if(self.flags & FL_WEAPON)
 672                         {
 673                                 entity wi = get_weaponinfo(self.weapon);
 674                                 if(wi)
 675                                 {
 676                                         name = wi.wpmodel;
 677                                         rgb = '1 0 0';
 678                                 }
 679                         }
 680                         if(name)
 681                         {
 682                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 683                                 if(self.waypointsprite_attached)
 684                                 {
 685                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 686                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 687                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 688                                 }
 689                         }
 690                         else
 691                         {
 692                                 print("Unknown powerup-marked item is wanting to respawn\n");
 693                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 694                         }
 695                 }
 696
 697                 if(self.waypointsprite_attached)
 698                 {
 699                         entity e;
 700                         entity it = self;
 701                         self = self.waypointsprite_attached;
 702                         FOR_EACH_REALCLIENT(e)
 703                                 if(self.waypointsprite_visible_for_player(e))
 704                                 {
 705                                         msg_entity = e;
 706                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 707                                 }
 708                         self = it;
 709
 710                         WaypointSprite_Ping(self.waypointsprite_attached);
 711                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 712                 }
 713                 else
 714                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 715         }
 716 }
 717
 718 void Item_RespawnThink()
 719 {
 720         self.nextthink = time;
 721         if(self.origin != self.oldorigin)
 722         {
 723                 self.oldorigin = self.origin;
 724                 ItemUpdate(self);
 725         }
 726
 727         if(time >= self.wait)
 728                 Item_Respawn();
 729 }
 730
 731 void Item_ScheduleRespawnIn(entity e, float t)
 732 {
 733         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 734         {
 735                 e.think = Item_RespawnCountdown;
 736                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 737                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 738                 e.count = 0;
 739                 t = Item_ItemsTime_GetTime(e, e.scheduledrespawntime);
 740                 Item_ItemsTime_UpdateTime(e, t);
 741                 Item_ItemsTime_SetTimesForAllPlayers();
 742         }
 743         else
 744         {
 745                 e.think = Item_RespawnThink;
 746                 e.nextthink = time;
 747                 e.scheduledrespawntime = time + t;
 748                 e.wait = time + t;
 749         }
 750 }
 751
 752 void Item_ScheduleRespawn(entity e)
 753 {
 754         if(e.respawntime > 0)
 755         {
 756                 Item_Show(e, 0);
 757                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 758         }
 759         else // if respawntime is -1, this item does not respawn
 760                 Item_Show(e, -1);
 761 }
 762
 763 void Item_ScheduleInitialRespawn(entity e)
 764 {
 765         Item_Show(e, 0);
 766         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 767 }
 768
 769 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 770 {
 771         if (!item.(ammotype))
 772                 return false;
 773
 774         if (item.spawnshieldtime)
 775         {
 776                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 777                 {
 778                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 779                         goto YEAH;
 780                 }
 781         }
 782         else if(g_weapon_stay == 2)
 783         {
 784                 float mi = min(item.(ammotype), ammomax);
 785                 if (player.(ammotype) < mi)
 786                 {
 787                         player.(ammotype) = mi;
 788                         goto YEAH;
 789                 }
 790         }
 791
 792         return false;
 793
 794 :YEAH
 795         switch(mode)
 796         {
 797                 case ITEM_MODE_FUEL:
 798                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 799                         break;
 800                 case ITEM_MODE_HEALTH:
 801                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 802                         break;
 803                 case ITEM_MODE_ARMOR:
 804                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 805                         break;
 806                 default:
 807                         break;
 808         }
 809         return true;
 810 }
 811
 812 float Item_GiveTo(entity item, entity player)
 813 {
 814         float _switchweapon;
 815         float pickedup;
 816         float it;
 817         float i;
 818
 819         // if nothing happens to player, just return without taking the item
 820         pickedup = false;
 821         _switchweapon = false;
 822         // in case the player has autoswitch enabled do the following:
 823         // if the player is using their best weapon before items are given, they
 824         // probably want to switch to an even better weapon after items are given
 825         if (player.autoswitch)
 826         if (player.switchweapon == w_getbestweapon(player))
 827                 _switchweapon = true;
 828
 829         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 830                 _switchweapon = true;
 831
 832         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 833         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 834         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 835         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 836         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 837         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 838         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 839         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 840
 841         if (item.flags & FL_WEAPON)
 842         {
 843                 WepSet it;
 844                 it = item.weapons;
 845                 it &= ~player.weapons;
 846
 847                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 848                 {
 849                         pickedup = true;
 850                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 851                         if(it & WepSet_FromWeapon(i))
 852                         {
 853                                 W_DropEvent(WR_PICKUP, player, i, item);
 854                                 W_GiveWeapon(player, i);
 855                         }
 856                 }
 857         }
 858
 859         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 860         {
 861                 pickedup = true;
 862                 player.items |= it;
 863                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 864         }
 865
 866         if (item.strength_finished)
 867         {
 868                 pickedup = true;
 869                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 870         }
 871         if (item.invincible_finished)
 872         {
 873                 pickedup = true;
 874                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 875         }
 876         if (item.superweapons_finished)
 877         {
 878                 pickedup = true;
 879                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 880         }
 881
 882 :skip
 883
 884         // always eat teamed entities
 885         if(item.team)
 886                 pickedup = true;
 887
 888         if (!pickedup)
 889                 return 0;
 890
 891         if (_switchweapon)
 892                 if (player.switchweapon != w_getbestweapon(player))
 893                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 894
 895         return 1;
 896 }
 897
 898 void Item_Touch (void)
 899 {
 900         entity e, head;
 901
 902         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 903         if(self.classname == "droppedweapon")
 904         {
 905                 if (ITEM_TOUCH_NEEDKILL())
 906                 {
 907                         remove(self);
 908                         return;
 909                 }
 910         }
 911
 912         if (!IS_PLAYER(other))
 913                 return;
 914         if (other.frozen)
 915                 return;
 916         if (other.deadflag)
 917                 return;
 918         if (self.solid != SOLID_TRIGGER)
 919                 return;
 920         if (self.owner == other)
 921                 return;
 922         if (time < self.item_spawnshieldtime)
 923                 return;
 924
 925         switch(MUTATOR_CALLHOOK(ItemTouch))
 926         {
 927                 case MUT_ITEMTOUCH_RETURN: { return; }
 928                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 929         }
 930
 931         if (self.classname == "droppedweapon")
 932         {
 933                 self.strength_finished = max(0, self.strength_finished - time);
 934                 self.invincible_finished = max(0, self.invincible_finished - time);
 935                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 936         }
 937         entity it = self.itemdef;
 938         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 939         if (!gave)
 940         {
 941                 if (self.classname == "droppedweapon")
 942                 {
 943                         // undo what we did above
 944                         self.strength_finished += time;
 945                         self.invincible_finished += time;
 946                         self.superweapons_finished += time;
 947                 }
 948                 return;
 949         }
 950
 951         :pickup
 952
 953         other.last_pickup = time;
 954
 955         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 956         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 957
 958         if (self.classname == "droppedweapon")
 959                 remove (self);
 960         else if (self.spawnshieldtime)
 961         {
 962                 if(self.team)
 963                 {
 964                         RandomSelection_Init();
 965                         for(head = world; (head = findfloat(head, team, self.team)); )
 966                         {
 967                                 if(head.flags & FL_ITEM)
 968                                 {
 969                                         Item_Show(head, -1);
 970                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 971                                 }
 972                         }
 973                         e = RandomSelection_chosen_ent;
 974
 975                 }
 976                 else
 977                         e = self;
 978                 Item_ScheduleRespawn(e);
 979         }
 980 }
 981
 982 void Item_Reset()
 983 {
 984         Item_Show(self, !self.state);
 985         setorigin (self, self.origin);
 986
 987         if(self.classname != "droppedweapon")
 988         {
 989                 self.think = Item_Think;
 990                 self.nextthink = time;
 991
 992                 if(self.waypointsprite_attached)
 993                         WaypointSprite_Kill(self.waypointsprite_attached);
 994
 995                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 996                         Item_ScheduleInitialRespawn(self);
 997         }
 998 }
 999
1000 void Item_FindTeam()
1001 {
1002         entity head, e;
1003
1004         if(self.effects & EF_NODRAW)
1005         {
1006                 // marker for item team search
1007                 dprint("Initializing item team ", ftos(self.team), "\n");
1008                 RandomSelection_Init();
1009                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
1010                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
1011                 e = RandomSelection_chosen_ent;
1012                 e.state = 0;
1013                 Item_Show(e, 1);
1014
1015                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
1016                 {
1017                         if(head != e)
1018                         {
1019                                 // make it a non-spawned item
1020                                 Item_Show(head, -1);
1021                                 head.state = 1; // state 1 = initially hidden item
1022                         }
1023                         head.effects &= ~EF_NODRAW;
1024                 }
1025
1026                 Item_Reset();
1027         }
1028 }
1029
1030 // Savage: used for item garbage-collection
1031 // TODO: perhaps nice special effect?
1032 void RemoveItem(void)
1033 {
1034         remove(self);
1035 }
1036
1037 // pickup evaluation functions
1038 // these functions decide how desirable an item is to the bots
1039
1040 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1041
1042 float weapon_pickupevalfunc(entity player, entity item)
1043 {
1044         float c;
1045
1046         // See if I have it already
1047         if(item.weapons & ~player.weapons)
1048         {
1049                 // If I can pick it up
1050                 if(!item.spawnshieldtime)
1051                         c = 0;
1052                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
1053                 {
1054                         // Skilled bots will grab more
1055                         c = bound(0, skill / 10, 1) * 0.5;
1056                 }
1057                 else
1058                         c = 0;
1059         }
1060         else
1061                 c = 1;
1062
1063         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
1064         if( bot_custom_weapon && c )
1065         {
1066                 // Find the highest position on any range
1067                 int position = -1;
1068                 for (int j = 0; j < WEP_LAST ; ++j){
1069                         if(
1070                                         bot_weapons_far[j] == item.weapon ||
1071                                         bot_weapons_mid[j] == item.weapon ||
1072                                         bot_weapons_close[j] == item.weapon
1073                           )
1074                         {
1075                                 position = j;
1076                                 break;
1077                         }
1078                 }
1079
1080                 // Rate it
1081                 if (position >= 0 )
1082                 {
1083                         position = WEP_LAST - position;
1084                         // item.bot_pickupbasevalue is overwritten here
1085                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
1086                 }
1087         }
1088
1089         return item.bot_pickupbasevalue * c;
1090 }
1091
1092 float commodity_pickupevalfunc(entity player, entity item)
1093 {
1094         float c, i;
1095         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1096         entity wi;
1097         c = 0;
1098
1099         // Detect needed ammo
1100         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
1101         {
1102                 wi = get_weaponinfo(i);
1103
1104                 if (!(player.weapons & WepSet_FromWeapon(i)))
1105                         continue;
1106
1107                 if(wi.items & IT_SHELLS)
1108                         need_shells = true;
1109                 else if(wi.items & IT_NAILS)
1110                         need_nails = true;
1111                 else if(wi.items & IT_ROCKETS)
1112                         need_rockets = true;
1113                 else if(wi.items & IT_CELLS)
1114                         need_cells = true;
1115                 else if(wi.items & IT_PLASMA)
1116                         need_plasma = true;
1117                 else if(wi.items & IT_FUEL)
1118                         need_fuel = true;
1119         }
1120
1121         // TODO: figure out if the player even has the weapon this ammo is for?
1122         // may not affect strategy much though...
1123         // find out how much more ammo/armor/health the player can hold
1124         if (need_shells)
1125         if (item.ammo_shells)
1126         if (player.ammo_shells < g_pickup_shells_max)
1127                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1128         if (need_nails)
1129         if (item.ammo_nails)
1130         if (player.ammo_nails < g_pickup_nails_max)
1131                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1132         if (need_rockets)
1133         if (item.ammo_rockets)
1134         if (player.ammo_rockets < g_pickup_rockets_max)
1135                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1136         if (need_cells)
1137         if (item.ammo_cells)
1138         if (player.ammo_cells < g_pickup_cells_max)
1139                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1140         if (need_plasma)
1141         if (item.ammo_plasma)
1142         if (player.ammo_plasma < g_pickup_plasma_max)
1143                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1144         if (need_fuel)
1145         if (item.ammo_fuel)
1146         if (player.ammo_fuel < g_pickup_fuel_max)
1147                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1148         if (item.armorvalue)
1149         if (player.armorvalue < item.max_armorvalue)
1150                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1151         if (item.health)
1152         if (player.health < item.max_health)
1153                 c = c + max(0, 1 - player.health / item.max_health);
1154
1155         return item.bot_pickupbasevalue * c;
1156 }
1157
1158 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1159 {
1160         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1161                 RemoveItem();
1162 }
1163
1164 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1165 {
1166         startitem_failed = false;
1167
1168         if(self.model == "")
1169                 self.model = itemmodel;
1170
1171         if(self.model == "")
1172     {
1173         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1174         return;
1175     }
1176
1177         if(self.item_pickupsound == "")
1178                 self.item_pickupsound = pickupsound;
1179
1180         if(!self.respawntime) // both need to be set
1181         {
1182                 self.respawntime = defaultrespawntime;
1183                 self.respawntimejitter = defaultrespawntimejitter;
1184         }
1185
1186         self.items = itemid;
1187         self.weapon = weaponid;
1188
1189         if(weaponid)
1190                 self.weapons = WepSet_FromWeapon(weaponid);
1191
1192         self.flags = FL_ITEM | itemflags;
1193
1194         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1195         {
1196                 startitem_failed = true;
1197                 remove(self);
1198                 return;
1199         }
1200
1201         // is it a dropped weapon?
1202         if (self.classname == "droppedweapon")
1203         {
1204                 self.reset = SUB_Remove;
1205                 // it's a dropped weapon
1206                 self.movetype = MOVETYPE_TOSS;
1207
1208                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1209                 self.think = RemoveItem;
1210                 self.nextthink = time + 20;
1211
1212                 self.takedamage = DAMAGE_YES;
1213                 self.event_damage = Item_Damage;
1214
1215                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1216                 /*
1217                 if(self.items == 0)
1218                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1219                 if(self.ammo_nails == 0)
1220                 if(self.ammo_cells == 0)
1221                 if(self.ammo_rockets == 0)
1222                 if(self.ammo_shells == 0)
1223                 if(self.ammo_fuel == 0)
1224                 if(self.health == 0)
1225                 if(self.armorvalue == 0)
1226                 */
1227                 {
1228                         // if item is worthless after a timer, have it expire then
1229                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1230                 }
1231
1232                 // don't drop if in a NODROP zone (such as lava)
1233                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1234                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1235                 {
1236                         startitem_failed = true;
1237                         remove(self);
1238                         return;
1239                 }
1240         }
1241         else
1242         {
1243                 if(!have_pickup_item())
1244                 {
1245                         startitem_failed = true;
1246                         remove (self);
1247                         return;
1248                 }
1249
1250                 self.reset = Item_Reset;
1251                 // it's a level item
1252                 if(self.spawnflags & 1)
1253                         self.noalign = 1;
1254                 if (self.noalign)
1255                         self.movetype = MOVETYPE_NONE;
1256                 else
1257                         self.movetype = MOVETYPE_TOSS;
1258                 // do item filtering according to game mode and other things
1259                 if (!self.noalign)
1260                 {
1261                         // first nudge it off the floor a little bit to avoid math errors
1262                         setorigin(self, self.origin + '0 0 1');
1263                         // set item size before we spawn a spawnfunc_waypoint
1264                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1265                                 setsize (self, '-16 -16 0', '16 16 48');
1266                         else
1267                                 setsize (self, '-16 -16 0', '16 16 32');
1268
1269                         // note droptofloor returns false if stuck/or would fall too far
1270                         droptofloor();
1271                         waypoint_spawnforitem(self);
1272                 }
1273
1274                 /*
1275                  * can't do it that way, as it would break maps
1276                  * TODO make a target_give like entity another way, that perhaps has
1277                  * the weapon name in a key
1278                 if(self.targetname)
1279                 {
1280                         // target_give not yet supported; maybe later
1281                         print("removed targeted ", self.classname, "\n");
1282                         startitem_failed = true;
1283                         remove (self);
1284                         return;
1285                 }
1286                 */
1287
1288                 if(autocvar_spawn_debug >= 2)
1289                 {
1290                         entity otheritem;
1291                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1292                         {
1293                             // why not flags & fl_item?
1294                                 if(otheritem.is_item)
1295                                 {
1296                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1297                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1298                                         error("Mapper sucks.");
1299                                 }
1300                         }
1301                         self.is_item = true;
1302                 }
1303
1304                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1305
1306                 precache_model (self.model);
1307                 precache_sound (self.item_pickupsound);
1308
1309                 precache_sound ("misc/itemrespawncountdown.wav");
1310                 if(itemid == IT_STRENGTH)
1311                         precache_sound ("misc/strength_respawn.wav");
1312                 else if(itemid == IT_INVINCIBLE)
1313                         precache_sound ("misc/shield_respawn.wav");
1314                 else
1315                         precache_sound ("misc/itemrespawn.wav");
1316
1317                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1318                         self.target = "###item###"; // for finding the nearest item using find()
1319
1320                 Item_ItemsTime_UpdateTime(self, 0);
1321         }
1322
1323         self.bot_pickup = true;
1324         self.bot_pickupevalfunc = pickupevalfunc;
1325         self.bot_pickupbasevalue = pickupbasevalue;
1326         self.mdl = self.model;
1327         self.netname = itemname;
1328         self.touch = Item_Touch;
1329         setmodel(self, "null"); // precision set below
1330         //self.effects |= EF_LOWPRECISION;
1331
1332         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1333     {
1334         self.pos1 = '-16 -16 0';
1335         self.pos2 = '16 16 48';
1336     }
1337         else
1338     {
1339         self.pos1 = '-16 -16 0';
1340         self.pos2 = '16 16 32';
1341     }
1342     setsize (self, self.pos1, self.pos2);
1343
1344     if(itemflags & FL_POWERUP)
1345         self.ItemStatus |= ITS_ANIMATE1;
1346
1347         if(self.armorvalue || self.health)
1348         self.ItemStatus |= ITS_ANIMATE2;
1349
1350         if(itemflags & FL_WEAPON)
1351         {
1352                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1353             self.colormap = 1024; // color shirt=0 pants=0 grey
1354         else
1355             self.gravity = 1;
1356
1357                 self.ItemStatus |= ITS_ANIMATE1;
1358                 self.ItemStatus |= ISF_COLORMAP;
1359         }
1360
1361         self.state = 0;
1362         if(self.team) // broken, no idea why.
1363         {
1364                 if(!self.cnt)
1365                         self.cnt = 1; // item probability weight
1366
1367                 self.effects |= EF_NODRAW; // marker for item team search
1368                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1369         }
1370         else
1371                 Item_Reset();
1372
1373     Net_LinkEntity(self, false, 0, ItemSend);
1374
1375         self.SendFlags |= ISF_SIZE;
1376         if(self.angles)
1377                 self.SendFlags |= ISF_ANGLES;
1378
1379         // call this hook after everything else has been done
1380         if(MUTATOR_CALLHOOK(Item_Spawn))
1381         {
1382                 startitem_failed = true;
1383                 remove(self);
1384                 return;
1385         }
1386 }
1387
1388 void StartItemA (entity a)
1389 {
1390     self.itemdef = a;
1391     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1392 }
1393
1394 void spawnfunc_item_rockets (void) {
1395         if(!self.ammo_rockets)
1396                 self.ammo_rockets = g_pickup_rockets;
1397         if(!self.pickup_anyway)
1398                 self.pickup_anyway = g_pickup_ammo_anyway;
1399     StartItemA (ITEM_Rockets);
1400 }
1401
1402 void spawnfunc_item_bullets (void) {
1403         if(!weaponswapping)
1404         if(autocvar_sv_q3acompat_machineshotgunswap)
1405         if(self.classname != "droppedweapon")
1406         {
1407                 weaponswapping = true;
1408                 spawnfunc_item_shells();
1409                 weaponswapping = false;
1410                 return;
1411         }
1412
1413         if(!self.ammo_nails)
1414                 self.ammo_nails = g_pickup_nails;
1415         if(!self.pickup_anyway)
1416                 self.pickup_anyway = g_pickup_ammo_anyway;
1417     StartItemA (ITEM_Bullets);
1418 }
1419
1420 void spawnfunc_item_cells (void) {
1421         if(!self.ammo_cells)
1422                 self.ammo_cells = g_pickup_cells;
1423         if(!self.pickup_anyway)
1424                 self.pickup_anyway = g_pickup_ammo_anyway;
1425         StartItemA (ITEM_Cells);
1426 }
1427
1428 void spawnfunc_item_plasma()
1429 {
1430         if(!self.ammo_plasma)
1431                 self.ammo_plasma = g_pickup_plasma;
1432         if(!self.pickup_anyway)
1433                 self.pickup_anyway = g_pickup_ammo_anyway;
1434         StartItemA (ITEM_Plasma);
1435 }
1436
1437 void spawnfunc_item_shells (void) {
1438         if(!weaponswapping)
1439         if(autocvar_sv_q3acompat_machineshotgunswap)
1440         if(self.classname != "droppedweapon")
1441         {
1442                 weaponswapping = true;
1443                 spawnfunc_item_bullets();
1444                 weaponswapping = false;
1445                 return;
1446         }
1447
1448         if(!self.ammo_shells)
1449                 self.ammo_shells = g_pickup_shells;
1450         if(!self.pickup_anyway)
1451                 self.pickup_anyway = g_pickup_ammo_anyway;
1452         StartItemA (ITEM_Shells);
1453 }
1454
1455 void spawnfunc_item_armor_small (void) {
1456         if(!self.armorvalue)
1457                 self.armorvalue = g_pickup_armorsmall;
1458         if(!self.max_armorvalue)
1459                 self.max_armorvalue = g_pickup_armorsmall_max;
1460         if(!self.pickup_anyway)
1461                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1462         StartItemA (ITEM_ArmorSmall);
1463 }
1464
1465 void spawnfunc_item_armor_medium (void) {
1466         if(!self.armorvalue)
1467                 self.armorvalue = g_pickup_armormedium;
1468         if(!self.max_armorvalue)
1469                 self.max_armorvalue = g_pickup_armormedium_max;
1470         if(!self.pickup_anyway)
1471                 self.pickup_anyway = g_pickup_armormedium_anyway;
1472         StartItemA (ITEM_ArmorMedium);
1473 }
1474
1475 void spawnfunc_item_armor_big (void) {
1476         if(!self.armorvalue)
1477                 self.armorvalue = g_pickup_armorbig;
1478         if(!self.max_armorvalue)
1479                 self.max_armorvalue = g_pickup_armorbig_max;
1480         if(!self.pickup_anyway)
1481                 self.pickup_anyway = g_pickup_armorbig_anyway;
1482         StartItemA (ITEM_ArmorBig);
1483 }
1484
1485 void spawnfunc_item_armor_large (void) {
1486         if(!self.armorvalue)
1487                 self.armorvalue = g_pickup_armorlarge;
1488         if(!self.max_armorvalue)
1489                 self.max_armorvalue = g_pickup_armorlarge_max;
1490         if(!self.pickup_anyway)
1491                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1492         StartItemA (ITEM_ArmorLarge);
1493 }
1494
1495 void spawnfunc_item_health_small (void) {
1496         if(!self.max_health)
1497                 self.max_health = g_pickup_healthsmall_max;
1498         if(!self.health)
1499                 self.health = g_pickup_healthsmall;
1500         if(!self.pickup_anyway)
1501                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1502         StartItemA (ITEM_HealthSmall);
1503 }
1504
1505 void spawnfunc_item_health_medium (void) {
1506         if(!self.max_health)
1507                 self.max_health = g_pickup_healthmedium_max;
1508         if(!self.health)
1509                 self.health = g_pickup_healthmedium;
1510         if(!self.pickup_anyway)
1511                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1512     StartItemA (ITEM_HealthMedium);
1513 }
1514
1515 void spawnfunc_item_health_large (void) {
1516         if(!self.max_health)
1517                 self.max_health = g_pickup_healthlarge_max;
1518         if(!self.health)
1519                 self.health = g_pickup_healthlarge;
1520         if(!self.pickup_anyway)
1521                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1522         StartItemA (ITEM_HealthLarge);
1523 }
1524
1525 void spawnfunc_item_health_mega (void) {
1526     if(!self.max_health)
1527         self.max_health = g_pickup_healthmega_max;
1528     if(!self.health)
1529         self.health = g_pickup_healthmega;
1530     if(!self.pickup_anyway)
1531         self.pickup_anyway = g_pickup_healthmega_anyway;
1532     StartItemA (ITEM_HealthMega);
1533 }
1534
1535 // support old misnamed entities
1536 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1537 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1538 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1539 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1540 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1541
1542 void spawnfunc_item_strength (void) {
1543                 precache_sound("weapons/strength_fire.wav");
1544                 if(!self.strength_finished)
1545                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1546                 StartItemA (ITEM_Strength);
1547 }
1548
1549 void spawnfunc_item_invincible (void) {
1550                 if(!self.invincible_finished)
1551                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1552                 StartItemA (ITEM_Shield);
1553 }
1554
1555 // compatibility:
1556 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1557
1558 void target_items_use (void)
1559 {
1560         if(activator.classname == "droppedweapon")
1561         {
1562                 EXACTTRIGGER_TOUCH;
1563                 remove(activator);
1564                 return;
1565         }
1566
1567         if (!IS_PLAYER(activator))
1568                 return;
1569         if(activator.deadflag != DEAD_NO)
1570                 return;
1571         EXACTTRIGGER_TOUCH;
1572
1573         entity e;
1574         for(e = world; (e = find(e, classname, "droppedweapon")); )
1575                 if(e.enemy == activator)
1576                         remove(e);
1577
1578         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1579                 centerprint(activator, self.message);
1580 }
1581
1582 void spawnfunc_target_items (void)
1583 {
1584         float n, i, j;
1585         entity e;
1586         string s;
1587
1588         self.use = target_items_use;
1589         if(!self.strength_finished)
1590                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1591         if(!self.invincible_finished)
1592                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1593         if(!self.superweapons_finished)
1594                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1595
1596         precache_sound("misc/itempickup.wav");
1597         precache_sound("misc/megahealth.wav");
1598         precache_sound("misc/armor25.wav");
1599         precache_sound("misc/powerup.wav");
1600         precache_sound("misc/poweroff.wav");
1601         precache_sound("weapons/weaponpickup.wav");
1602
1603         n = tokenize_console(self.netname);
1604         if(argv(0) == "give")
1605         {
1606                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1607         }
1608         else
1609         {
1610                 for(i = 0; i < n; ++i)
1611                 {
1612                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1613                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1614                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1615                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1616                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1617                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1618                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1619                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1620                         else
1621                         {
1622                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1623                                 {
1624                                         e = get_weaponinfo(j);
1625                                         s = W_UndeprecateName(argv(i));
1626                                         if(s == e.netname)
1627                                         {
1628                                                 self.weapons |= WepSet_FromWeapon(j);
1629                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1630                                                         WEP_ACTION(e.weapon, WR_INIT);
1631                                                 break;
1632                                         }
1633                                 }
1634                                 if(j > WEP_LAST)
1635                                         print("target_items: invalid item ", argv(i), "\n");
1636                         }
1637                 }
1638
1639                 string itemprefix, valueprefix;
1640                 if(self.spawnflags == 0)
1641                 {
1642                         itemprefix = "";
1643                         valueprefix = "";
1644                 }
1645                 else if(self.spawnflags == 1)
1646                 {
1647                         itemprefix = "max ";
1648                         valueprefix = "max ";
1649                 }
1650                 else if(self.spawnflags == 2)
1651                 {
1652                         itemprefix = "min ";
1653                         valueprefix = "min ";
1654                 }
1655                 else if(self.spawnflags == 4)
1656                 {
1657                         itemprefix = "minus ";
1658                         valueprefix = "max ";
1659                 }
1660                 else
1661                 {
1662                         error("invalid spawnflags");
1663                         itemprefix = valueprefix = string_null;
1664                 }
1665
1666                 self.netname = "";
1667                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1668                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1669                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1670                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1671                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1672                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1673                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1674                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1675                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1676                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1677                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1678                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1679                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1680                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1681                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1682                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1683                 {
1684                         e = get_weaponinfo(j);
1685                         if(e.weapon)
1686                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1687                 }
1688         }
1689         self.netname = strzone(self.netname);
1690         //print(self.netname, "\n");
1691
1692         n = tokenize_console(self.netname);
1693         for(i = 0; i < n; ++i)
1694         {
1695                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1696                 {
1697                         e = get_weaponinfo(j);
1698                         if(argv(i) == e.netname)
1699                         {
1700                                 WEP_ACTION(e.weapon, WR_INIT);
1701                                 break;
1702                         }
1703                 }
1704         }
1705 }
1706
1707 void spawnfunc_item_fuel(void)
1708 {
1709         if(!self.ammo_fuel)
1710                 self.ammo_fuel = g_pickup_fuel;
1711         if(!self.pickup_anyway)
1712                 self.pickup_anyway = g_pickup_ammo_anyway;
1713         StartItemA (ITEM_JetpackFuel);
1714 }
1715
1716 void spawnfunc_item_fuel_regen(void)
1717 {
1718         if(start_items & IT_FUEL_REGEN)
1719         {
1720                 spawnfunc_item_fuel();
1721                 return;
1722         }
1723         StartItemA (ITEM_JetpackRegen);
1724 }
1725
1726 void spawnfunc_item_jetpack(void)
1727 {
1728         if(!self.ammo_fuel)
1729                 self.ammo_fuel = g_pickup_fuel_jetpack;
1730         if(start_items & IT_JETPACK)
1731         {
1732                 spawnfunc_item_fuel();
1733                 return;
1734         }
1735         StartItemA (ITEM_Jetpack);
1736 }
1737
1738 float GiveWeapon(entity e, float wpn, float op, float val)
1739 {
1740         WepSet v0, v1;
1741         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1742         switch(op)
1743         {
1744                 case OP_SET:
1745                         if(val > 0)
1746                                 e.weapons |= WepSet_FromWeapon(wpn);
1747                         else
1748                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1749                         break;
1750                 case OP_MIN:
1751                 case OP_PLUS:
1752                         if(val > 0)
1753                                 e.weapons |= WepSet_FromWeapon(wpn);
1754                         break;
1755                 case OP_MAX:
1756                         if(val <= 0)
1757                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1758                         break;
1759                 case OP_MINUS:
1760                         if(val > 0)
1761                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1762                         break;
1763         }
1764         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1765         return (v0 != v1);
1766 }
1767
1768 float GiveBit(entity e, .float fld, float bit, float op, float val)
1769 {
1770         float v0, v1;
1771         v0 = (e.(fld) & bit);
1772         switch(op)
1773         {
1774                 case OP_SET:
1775                         if(val > 0)
1776                                 e.(fld) |= bit;
1777                         else
1778                                 e.(fld) &= ~bit;
1779                         break;
1780                 case OP_MIN:
1781                 case OP_PLUS:
1782                         if(val > 0)
1783                                 e.(fld) |= bit;
1784                         break;
1785                 case OP_MAX:
1786                         if(val <= 0)
1787                                 e.(fld) &= ~bit;
1788                         break;
1789                 case OP_MINUS:
1790                         if(val > 0)
1791                                 e.(fld) &= ~bit;
1792                         break;
1793         }
1794         v1 = (e.(fld) & bit);
1795         return (v0 != v1);
1796 }
1797
1798 float GiveValue(entity e, .float fld, float op, float val)
1799 {
1800         float v0, v1;
1801         v0 = e.(fld);
1802         switch(op)
1803         {
1804                 case OP_SET:
1805                         e.(fld) = val;
1806                         break;
1807                 case OP_MIN:
1808                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1809                         break;
1810                 case OP_MAX:
1811                         e.(fld) = min(e.(fld), val);
1812                         break;
1813                 case OP_PLUS:
1814                         e.(fld) += val;
1815                         break;
1816                 case OP_MINUS:
1817                         e.(fld) -= val;
1818                         break;
1819         }
1820         v1 = e.(fld);
1821         return (v0 != v1);
1822 }
1823
1824 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1825 {
1826         if(v1 == v0)
1827                 return;
1828         if(v1 <= v0 - t)
1829         {
1830                 if(snd_decr != "")
1831                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1832         }
1833         else if(v0 >= v0 + t)
1834         {
1835                 if(snd_incr != "")
1836                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1837         }
1838 }
1839
1840 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1841 {
1842         if(v0 < v1)
1843                 e.(rotfield) = max(e.(rotfield), time + rottime);
1844         else if(v0 > v1)
1845                 e.(regenfield) = max(e.(regenfield), time + regentime);
1846 }
1847 float GiveItems(entity e, float beginarg, float endarg)
1848 {
1849         float got, i, j, val, op;
1850         float _switchweapon;
1851         entity wi;
1852         string cmd;
1853
1854         val = 999;
1855         op = OP_SET;
1856
1857         got = 0;
1858
1859         _switchweapon = false;
1860         if (e.autoswitch)
1861                 if (e.switchweapon == w_getbestweapon(e))
1862                         _switchweapon = true;
1863
1864         e.strength_finished = max(0, e.strength_finished - time);
1865         e.invincible_finished = max(0, e.invincible_finished - time);
1866         e.superweapons_finished = max(0, e.superweapons_finished - time);
1867
1868         PREGIVE(e, items);
1869         PREGIVE_WEAPONS(e);
1870         PREGIVE(e, strength_finished);
1871         PREGIVE(e, invincible_finished);
1872         PREGIVE(e, superweapons_finished);
1873         PREGIVE(e, ammo_nails);
1874         PREGIVE(e, ammo_cells);
1875         PREGIVE(e, ammo_plasma);
1876         PREGIVE(e, ammo_shells);
1877         PREGIVE(e, ammo_rockets);
1878         PREGIVE(e, ammo_fuel);
1879         PREGIVE(e, armorvalue);
1880         PREGIVE(e, health);
1881
1882         for(i = beginarg; i < endarg; ++i)
1883         {
1884                 cmd = argv(i);
1885
1886                 if(cmd == "0" || stof(cmd))
1887                 {
1888                         val = stof(cmd);
1889                         continue;
1890                 }
1891                 switch(cmd)
1892                 {
1893                         case "no":
1894                                 op = OP_MAX;
1895                                 val = 0;
1896                                 continue;
1897                         case "max":
1898                                 op = OP_MAX;
1899                                 continue;
1900                         case "min":
1901                                 op = OP_MIN;
1902                                 continue;
1903                         case "plus":
1904                                 op = OP_PLUS;
1905                                 continue;
1906                         case "minus":
1907                                 op = OP_MINUS;
1908                                 continue;
1909                         case "ALL":
1910                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1911                                 got += GiveValue(e, strength_finished, op, val);
1912                                 got += GiveValue(e, invincible_finished, op, val);
1913                                 got += GiveValue(e, superweapons_finished, op, val);
1914                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1915                         case "all":
1916                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1917                                 got += GiveValue(e, health, op, val);
1918                                 got += GiveValue(e, armorvalue, op, val);
1919                         case "allweapons":
1920                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1921                                 {
1922                                         wi = get_weaponinfo(j);
1923                                         if(wi.weapon)
1924                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1925                                                         got += GiveWeapon(e, j, op, val);
1926                                 }
1927                         case "allammo":
1928                                 got += GiveValue(e, ammo_cells, op, val);
1929                                 got += GiveValue(e, ammo_plasma, op, val);
1930                                 got += GiveValue(e, ammo_shells, op, val);
1931                                 got += GiveValue(e, ammo_nails, op, val);
1932                                 got += GiveValue(e, ammo_rockets, op, val);
1933                                 got += GiveValue(e, ammo_fuel, op, val);
1934                                 break;
1935                         case "unlimited_ammo":
1936                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1937                                 break;
1938                         case "unlimited_weapon_ammo":
1939                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1940                                 break;
1941                         case "unlimited_superweapons":
1942                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1943                                 break;
1944                         case "jetpack":
1945                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1946                                 break;
1947                         case "fuel_regen":
1948                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1949                                 break;
1950                         case "strength":
1951                                 got += GiveValue(e, strength_finished, op, val);
1952                                 break;
1953                         case "invincible":
1954                                 got += GiveValue(e, invincible_finished, op, val);
1955                                 break;
1956                         case "superweapons":
1957                                 got += GiveValue(e, superweapons_finished, op, val);
1958                                 break;
1959                         case "cells":
1960                                 got += GiveValue(e, ammo_cells, op, val);
1961                                 break;
1962                         case "plasma":
1963                                 got += GiveValue(e, ammo_plasma, op, val);
1964                                 break;
1965                         case "shells":
1966                                 got += GiveValue(e, ammo_shells, op, val);
1967                                 break;
1968                         case "nails":
1969                         case "bullets":
1970                                 got += GiveValue(e, ammo_nails, op, val);
1971                                 break;
1972                         case "rockets":
1973                                 got += GiveValue(e, ammo_rockets, op, val);
1974                                 break;
1975                         case "health":
1976                                 got += GiveValue(e, health, op, val);
1977                                 break;
1978                         case "armor":
1979                                 got += GiveValue(e, armorvalue, op, val);
1980                                 break;
1981                         case "fuel":
1982                                 got += GiveValue(e, ammo_fuel, op, val);
1983                                 break;
1984                         default:
1985                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1986                                 {
1987                                         wi = get_weaponinfo(j);
1988                                         if(cmd == wi.netname)
1989                                         {
1990                                                 got += GiveWeapon(e, j, op, val);
1991                                                 break;
1992                                         }
1993                                 }
1994                                 if(j > WEP_LAST)
1995                                         print("give: invalid item ", cmd, "\n");
1996                                 break;
1997                 }
1998                 val = 999;
1999                 op = OP_SET;
2000         }
2001
2002         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
2003         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
2004         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
2005         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
2006         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2007         {
2008                 wi = get_weaponinfo(j);
2009                 if(wi.weapon)
2010                 {
2011                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
2012                         if (!(save_weapons & WepSet_FromWeapon(j)))
2013                                 if(e.weapons & WepSet_FromWeapon(j))
2014                                         WEP_ACTION(wi.weapon, WR_INIT);
2015                 }
2016         }
2017         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2018         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2019         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2020         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2021         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
2022         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2023         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2024         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2025         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2026         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2027
2028         if(e.superweapons_finished <= 0)
2029                 if(self.weapons & WEPSET_SUPERWEAPONS)
2030                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2031
2032         if(e.strength_finished <= 0)
2033                 e.strength_finished = 0;
2034         else
2035                 e.strength_finished += time;
2036         if(e.invincible_finished <= 0)
2037                 e.invincible_finished = 0;
2038         else
2039                 e.invincible_finished += time;
2040         if(e.superweapons_finished <= 0)
2041                 e.superweapons_finished = 0;
2042         else
2043                 e.superweapons_finished += time;
2044
2045         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
2046                 _switchweapon = true;
2047         if(_switchweapon)
2048                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2049
2050         return got;
2051 }
2052 #endif