qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280         }
 281         else
 282         {
 283                 if(autocvar_g_pickup_items > 0)
 284                         return TRUE;
 285                 if(autocvar_g_pickup_items == 0)
 286                         return FALSE;
 287                 if(g_weaponarena)
 288                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 289                                 return FALSE;
 290         }
 291         return TRUE;
 292 }
 293
 294 #define ITEM_RESPAWN_TICKS 10
 295
 296 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 297         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 298 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 299         // range: 10 .. respawntime + respawntimejitter
 300
 301 floatfield Item_CounterField(float it)
 302 {
 303         switch(it)
 304         {
 305                 case IT_SHELLS:      return ammo_shells;
 306                 case IT_NAILS:       return ammo_nails;
 307                 case IT_ROCKETS:     return ammo_rockets;
 308                 case IT_CELLS:       return ammo_cells;
 309                 case IT_FUEL:        return ammo_fuel;
 310                 case IT_5HP:         return health;
 311                 case IT_25HP:        return health;
 312                 case IT_HEALTH:      return health;
 313                 case IT_ARMOR_SHARD: return armorvalue;
 314                 case IT_ARMOR:       return armorvalue;
 315                 // add more things here (health, armor)
 316                 default:             error("requested item has no counter field");
 317         }
 318 #ifdef GMQCC
 319         // should never happen
 320         return health;
 321 #endif
 322 }
 323
 324 string Item_CounterFieldName(float it)
 325 {
 326         switch(it)
 327         {
 328                 case IT_SHELLS:      return "shells";
 329                 case IT_NAILS:       return "nails";
 330                 case IT_ROCKETS:     return "rockets";
 331                 case IT_CELLS:       return "cells";
 332                 case IT_FUEL:        return "fuel";
 333
 334                 // add more things here (health, armor)
 335                 default:             error("requested item has no counter field name");
 336         }
 337 #ifdef GMQCC
 338         // should never happen
 339         return string_null;
 340 #endif
 341 }
 342
 343 .float max_armorvalue;
 344 .float pickup_anyway;
 345 /*
 346 float Item_Customize()
 347 {
 348         if(self.spawnshieldtime)
 349                 return TRUE;
 350         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 351         {
 352                 self.colormod = '0 0 0';
 353                 self.glowmod = self.colormod;
 354                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 355                 return TRUE;
 356         }
 357         else
 358         {
 359                 if(g_ghost_items)
 360                 {
 361                         self.colormod = stov(autocvar_g_ghost_items_color);
 362                         self.glowmod = self.colormod;
 363                         self.alpha = g_ghost_items;
 364                         return TRUE;
 365                 }
 366                 else
 367                         return FALSE;
 368         }
 369 }
 370 */
 371
 372 void Item_Show (entity e, float mode)
 373 {
 374         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 375         e.ItemStatus &~= ITS_STAYWEP;
 376         if (mode > 0)
 377         {
 378                 // make the item look normal, and be touchable
 379                 e.model = e.mdl;
 380                 e.solid = SOLID_TRIGGER;
 381                 e.spawnshieldtime = 1;
 382                 e.ItemStatus |= ITS_AVAILABLE;
 383         }
 384         else if (mode < 0)
 385         {
 386                 // hide the item completely
 387                 e.model = string_null;
 388                 e.solid = SOLID_NOT;
 389                 e.spawnshieldtime = 1;
 390                 e.ItemStatus &~= ITS_AVAILABLE;
 391         }
 392         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 393         {
 394                 // make the item translucent and not touchable
 395                 e.model = e.mdl;
 396                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 397                 e.effects |= EF_STARDUST;
 398                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 399                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 400         }
 401         else
 402         {
 403                 //setmodel(e, "null");
 404                 e.solid = SOLID_NOT;
 405                 e.colormod = '0 0 0';
 406                 e.glowmod = e.colormod;
 407                 e.spawnshieldtime = 1;
 408                 e.ItemStatus &~= ITS_AVAILABLE;
 409         }
 410
 411         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 412             e.ItemStatus |= ITS_POWERUP;
 413
 414         if (autocvar_g_nodepthtestitems)
 415                 e.effects |= EF_NODEPTHTEST;
 416
 417
 418     if (autocvar_g_fullbrightitems)
 419                 e.ItemStatus |= ITS_ALLOWFB;
 420
 421         if (autocvar_sv_simple_items)
 422         e.ItemStatus |= ITS_ALLOWSI;
 423
 424         // relink entity (because solid may have changed)
 425         setorigin(e, e.origin);
 426     e.SendFlags |= ISF_STATUS;
 427 }
 428
 429 void Item_Respawn (void)
 430 {
 431         Item_Show(self, 1);
 432         // this is ugly...
 433         if(self.items == IT_STRENGTH)
 434                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 435         else if(self.items == IT_INVINCIBLE)
 436                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 437         else
 438                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 439         setorigin (self, self.origin);
 440
 441         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 442         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 443 }
 444
 445 void Item_RespawnCountdown (void)
 446 {
 447         if(self.count >= ITEM_RESPAWN_TICKS)
 448         {
 449                 if(self.waypointsprite_attached)
 450                         WaypointSprite_Kill(self.waypointsprite_attached);
 451                 Item_Respawn();
 452         }
 453         else
 454         {
 455                 self.nextthink = time + 1;
 456                 self.count += 1;
 457                 if(self.count == 1)
 458                 {
 459                         string name;
 460                         vector rgb = '1 0 1';
 461                         name = string_null;
 462                         switch(self.items)
 463                         {
 464                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 465                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 466                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 467                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 468                         }
 469                         item_name = name;
 470                         item_color = rgb;
 471                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 472                         name = item_name;
 473                         rgb = item_color;
 474                         if(self.flags & FL_WEAPON)
 475                         {
 476                                 entity wi = get_weaponinfo(self.weapon);
 477                                 if(wi)
 478                                 {
 479                                         name = wi.model2;
 480                                         rgb = '1 0 0';
 481                                 }
 482                         }
 483                         if(name)
 484                         {
 485                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 486                                 if(self.waypointsprite_attached)
 487                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 488                         }
 489                         else
 490                         {
 491                                 print("Unknown powerup-marked item is wanting to respawn\n");
 492                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 493                         }
 494                 }
 495                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 496                 if(self.waypointsprite_attached)
 497                 {
 498                         WaypointSprite_Ping(self.waypointsprite_attached);
 499                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 500                 }
 501         }
 502 }
 503
 504 void Item_ScheduleRespawnIn(entity e, float t)
 505 {
 506         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 507         {
 508                 e.think = Item_RespawnCountdown;
 509                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 510                 e.count = 0;
 511         }
 512         else
 513         {
 514                 e.think = Item_Respawn;
 515                 e.nextthink = time + t;
 516         }
 517 }
 518
 519 void Item_ScheduleRespawn(entity e)
 520 {
 521         if(e.respawntime > 0)
 522         {
 523                 Item_Show(e, 0);
 524                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 525         }
 526         else // if respawntime is -1, this item does not respawn
 527                 Item_Show(e, -1);
 528 }
 529
 530 void Item_ScheduleInitialRespawn(entity e)
 531 {
 532         Item_Show(e, 0);
 533         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 534 }
 535
 536 float ITEM_MODE_NONE = 0;
 537 float ITEM_MODE_HEALTH = 1;
 538 float ITEM_MODE_ARMOR = 2;
 539 float ITEM_MODE_FUEL = 3;
 540 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 541 {
 542         if (!item.ammofield)
 543                 return FALSE;
 544
 545         if (item.spawnshieldtime)
 546         {
 547                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 548                 {
 549                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 550                         goto YEAH;
 551                 }
 552         }
 553         else if(g_weapon_stay == 2)
 554         {
 555                 float mi = min(item.ammofield, ammomax);
 556                 if (player.ammofield < mi)
 557                 {
 558                         player.ammofield = mi;
 559                         goto YEAH;
 560                 }
 561         }
 562
 563         return FALSE;
 564
 565 :YEAH
 566         switch(mode)
 567         {
 568                 case ITEM_MODE_FUEL:
 569                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 570                         break;
 571                 case ITEM_MODE_HEALTH:
 572                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 573                         break;
 574                 case ITEM_MODE_ARMOR:
 575                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 576                         break;
 577                 default:
 578                         break;
 579         }
 580         return TRUE;
 581 }
 582
 583 float Item_GiveTo(entity item, entity player)
 584 {
 585         float _switchweapon;
 586         float pickedup;
 587         float it;
 588         float i;
 589
 590         // if nothing happens to player, just return without taking the item
 591         pickedup = FALSE;
 592         _switchweapon = FALSE;
 593         // in case the player has autoswitch enabled do the following:
 594         // if the player is using their best weapon before items are given, they
 595         // probably want to switch to an even better weapon after items are given
 596         if (player.autoswitch)
 597         if (player.switchweapon == w_getbestweapon(player))
 598                 _switchweapon = TRUE;
 599
 600         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 601                 _switchweapon = TRUE;
 602
 603         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 604         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 605         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 606         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 607         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 608         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 609         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 610
 611         if (item.flags & FL_WEAPON)
 612         {
 613                 WEPSET_DECLARE_A(it);
 614                 WEPSET_COPY_AE(it, item);
 615                 WEPSET_ANDNOT_AE(it, player);
 616
 617                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && item.pickup_anyway))
 618                 {
 619                         pickedup = TRUE;
 620                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 621                         if(WEPSET_CONTAINS_AW(it, i))
 622                                 W_GiveWeapon(player, i);
 623                 }
 624         }
 625
 626         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 627         {
 628                 pickedup = TRUE;
 629                 player.items |= it;
 630                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 631         }
 632
 633         if (item.strength_finished)
 634         {
 635                 pickedup = TRUE;
 636                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 637         }
 638         if (item.invincible_finished)
 639         {
 640                 pickedup = TRUE;
 641                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 642         }
 643         if (item.superweapons_finished)
 644         {
 645                 pickedup = TRUE;
 646                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 647         }
 648
 649 :skip
 650
 651         // always eat teamed entities
 652         if(item.team)
 653                 pickedup = TRUE;
 654
 655         if (!pickedup)
 656                 return 0;
 657
 658         if (_switchweapon)
 659                 if (player.switchweapon != w_getbestweapon(player))
 660                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 661
 662         return 1;
 663 }
 664
 665 void Item_Touch (void)
 666 {
 667         entity e, head;
 668
 669         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 670         if(self.classname == "droppedweapon")
 671         {
 672                 if (ITEM_TOUCH_NEEDKILL())
 673                 {
 674                         remove(self);
 675                         return;
 676                 }
 677         }
 678
 679         if not(IS_PLAYER(other))
 680                 return;
 681         if (other.deadflag)
 682                 return;
 683         if (self.solid != SOLID_TRIGGER)
 684                 return;
 685         if (self.owner == other)
 686                 return;
 687
 688         switch(MUTATOR_CALLHOOK(ItemTouch))
 689         {
 690                 case MUT_ITEMTOUCH_RETURN: { return; }
 691                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 692         }
 693
 694         if (self.classname == "droppedweapon")
 695         {
 696                 self.strength_finished = max(0, self.strength_finished - time);
 697                 self.invincible_finished = max(0, self.invincible_finished - time);
 698                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 699         }
 700
 701         if(!Item_GiveTo(self, other))
 702         {
 703                 if (self.classname == "droppedweapon")
 704                 {
 705                         // undo what we did above
 706                         self.strength_finished += time;
 707                         self.invincible_finished += time;
 708                         self.superweapons_finished += time;
 709                 }
 710                 return;
 711         }
 712
 713         :pickup
 714
 715         other.last_pickup = time;
 716
 717         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 718         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 719
 720         if (self.classname == "droppedweapon")
 721                 remove (self);
 722         else if not(self.spawnshieldtime)
 723                 return;
 724         else
 725         {
 726                 if(self.team)
 727                 {
 728                         RandomSelection_Init();
 729                         for(head = world; (head = findfloat(head, team, self.team)); )
 730                         {
 731                                 if(head.flags & FL_ITEM)
 732                                 {
 733                                         Item_Show(head, -1);
 734                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 735                                 }
 736                         }
 737                         e = RandomSelection_chosen_ent;
 738
 739                 }
 740                 else
 741                         e = self;
 742                 Item_ScheduleRespawn(e);
 743         }
 744 }
 745
 746 void Item_Reset()
 747 {
 748         Item_Show(self, !self.state);
 749         setorigin (self, self.origin);
 750
 751         if(self.classname != "droppedweapon")
 752         {
 753                 self.think = func_null;
 754                 self.nextthink = 0;
 755
 756                 if(self.waypointsprite_attached)
 757                         WaypointSprite_Kill(self.waypointsprite_attached);
 758
 759                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 760                         Item_ScheduleInitialRespawn(self);
 761         }
 762 }
 763
 764 void Item_FindTeam()
 765 {
 766         entity head, e;
 767
 768         if(self.effects & EF_NODRAW)
 769         {
 770                 // marker for item team search
 771                 dprint("Initializing item team ", ftos(self.team), "\n");
 772                 RandomSelection_Init();
 773                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 774                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 775                 e = RandomSelection_chosen_ent;
 776                 e.state = 0;
 777                 Item_Show(e, 1);
 778
 779                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 780                 {
 781                         if(head != e)
 782                         {
 783                                 // make it a non-spawned item
 784                                 Item_Show(head, -1);
 785                                 head.state = 1; // state 1 = initially hidden item
 786                         }
 787                         head.effects &~= EF_NODRAW;
 788                 }
 789
 790                 Item_Reset();
 791         }
 792 }
 793
 794 // Savage: used for item garbage-collection
 795 // TODO: perhaps nice special effect?
 796 void RemoveItem(void)
 797 {
 798         remove(self);
 799 }
 800
 801 // pickup evaluation functions
 802 // these functions decide how desirable an item is to the bots
 803
 804 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 805
 806 float weapon_pickupevalfunc(entity player, entity item)
 807 {
 808         float c, j, position;
 809
 810         // See if I have it already
 811         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 812         {
 813                 // If I can pick it up
 814                 if(!item.spawnshieldtime)
 815                         c = 0;
 816                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 817                 {
 818                         // Skilled bots will grab more
 819                         c = bound(0, skill / 10, 1) * 0.5;
 820                 }
 821                 else
 822                         c = 0;
 823         }
 824         else
 825                 c = 1;
 826
 827         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 828         if( bot_custom_weapon && c )
 829         {
 830                 // Find the highest position on any range
 831                 position = -1;
 832                 for(j = 0; j < WEP_LAST ; ++j){
 833                         if(
 834                                         bot_weapons_far[j] == item.weapon ||
 835                                         bot_weapons_mid[j] == item.weapon ||
 836                                         bot_weapons_close[j] == item.weapon
 837                           )
 838                         {
 839                                 position = j;
 840                                 break;
 841                         }
 842                 }
 843
 844                 // Rate it
 845                 if (position >= 0 )
 846                 {
 847                         position = WEP_LAST - position;
 848                         // item.bot_pickupbasevalue is overwritten here
 849                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 850                 }
 851         }
 852
 853         return item.bot_pickupbasevalue * c;
 854 }
 855
 856 float commodity_pickupevalfunc(entity player, entity item)
 857 {
 858         float c, i;
 859         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 860         entity wi;
 861         c = 0;
 862
 863         // Detect needed ammo
 864         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 865         {
 866                 wi = get_weaponinfo(i);
 867
 868                 if not(WEPSET_CONTAINS_EW(player, i))
 869                         continue;
 870
 871                 if(wi.items & IT_SHELLS)
 872                         need_shells = TRUE;
 873                 else if(wi.items & IT_NAILS)
 874                         need_nails = TRUE;
 875                 else if(wi.items & IT_ROCKETS)
 876                         need_rockets = TRUE;
 877                 else if(wi.items & IT_CELLS)
 878                         need_cells = TRUE;
 879                 else if(wi.items & IT_FUEL)
 880                         need_cells = TRUE;
 881         }
 882
 883         // TODO: figure out if the player even has the weapon this ammo is for?
 884         // may not affect strategy much though...
 885         // find out how much more ammo/armor/health the player can hold
 886         if (need_shells)
 887         if (item.ammo_shells)
 888         if (player.ammo_shells < g_pickup_shells_max)
 889                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 890         if (need_nails)
 891         if (item.ammo_nails)
 892         if (player.ammo_nails < g_pickup_nails_max)
 893                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 894         if (need_rockets)
 895         if (item.ammo_rockets)
 896         if (player.ammo_rockets < g_pickup_rockets_max)
 897                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 898         if (need_cells)
 899         if (item.ammo_cells)
 900         if (player.ammo_cells < g_pickup_cells_max)
 901                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 902         if (need_fuel)
 903         if (item.ammo_fuel)
 904         if (player.ammo_fuel < g_pickup_fuel_max)
 905                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 906         if (item.armorvalue)
 907         if (player.armorvalue < item.max_armorvalue)
 908                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 909         if (item.health)
 910         if (player.health < item.max_health)
 911                 c = c + max(0, 1 - player.health / item.max_health);
 912
 913         return item.bot_pickupbasevalue * c;
 914 }
 915
 916 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 917 {
 918         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 919                 RemoveItem();
 920 }
 921
 922 .float is_item;
 923 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 924 {
 925         startitem_failed = FALSE;
 926
 927         if(self.model == "")
 928                 self.model = itemmodel;
 929
 930         if(self.model == "")
 931     {
 932         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 933         return;
 934     }
 935
 936         if(self.item_pickupsound == "")
 937                 self.item_pickupsound = pickupsound;
 938
 939         if(!self.respawntime) // both need to be set
 940         {
 941                 self.respawntime = defaultrespawntime;
 942                 self.respawntimejitter = defaultrespawntimejitter;
 943         }
 944
 945         self.items = itemid;
 946         self.weapon = weaponid;
 947
 948         if(weaponid)
 949                 WEPSET_COPY_EW(self, weaponid);
 950
 951         self.flags = FL_ITEM | itemflags;
 952
 953         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 954         {
 955                 startitem_failed = TRUE;
 956                 remove(self);
 957                 return;
 958         }
 959
 960         // is it a dropped weapon?
 961         if (self.classname == "droppedweapon")
 962         {
 963                 self.reset = SUB_Remove;
 964                 // it's a dropped weapon
 965                 self.movetype = MOVETYPE_TOSS;
 966
 967                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 968                 self.think = RemoveItem;
 969                 self.nextthink = time + 20;
 970
 971                 self.takedamage = DAMAGE_YES;
 972                 self.event_damage = Item_Damage;
 973
 974                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 975                 /*
 976                 if(self.items == 0)
 977                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 978                 if(self.ammo_nails == 0)
 979                 if(self.ammo_cells == 0)
 980                 if(self.ammo_rockets == 0)
 981                 if(self.ammo_shells == 0)
 982                 if(self.ammo_fuel == 0)
 983                 if(self.health == 0)
 984                 if(self.armorvalue == 0)
 985                 */
 986                 {
 987                         // if item is worthless after a timer, have it expire then
 988                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 989                 }
 990
 991                 // don't drop if in a NODROP zone (such as lava)
 992                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 993                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 994                 {
 995                         startitem_failed = TRUE;
 996                         remove(self);
 997                         return;
 998                 }
 999         }
1000         else
1001         {
1002                 if(!have_pickup_item())
1003                 {
1004                         startitem_failed = TRUE;
1005                         remove (self);
1006                         return;
1007                 }
1008
1009                 if(self.angles != '0 0 0')
1010             self.SendFlags |= ISF_ANGLES;
1011
1012                 self.reset = Item_Reset;
1013                 // it's a level item
1014                 if(self.spawnflags & 1)
1015                         self.noalign = 1;
1016                 if (self.noalign)
1017                         self.movetype = MOVETYPE_NONE;
1018                 else
1019                         self.movetype = MOVETYPE_TOSS;
1020                 // do item filtering according to game mode and other things
1021                 if (!self.noalign)
1022                 {
1023                         // first nudge it off the floor a little bit to avoid math errors
1024                         setorigin(self, self.origin + '0 0 1');
1025                         // set item size before we spawn a spawnfunc_waypoint
1026                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1027                                 setsize (self, '-16 -16 0', '16 16 48');
1028                         else
1029                                 setsize (self, '-16 -16 0', '16 16 32');
1030                         // note droptofloor returns FALSE if stuck/or would fall too far
1031                         droptofloor();
1032                         waypoint_spawnforitem(self);
1033                 }
1034
1035                 /*
1036                  * can't do it that way, as it would break maps
1037                  * TODO make a target_give like entity another way, that perhaps has
1038                  * the weapon name in a key
1039                 if(self.targetname)
1040                 {
1041                         // target_give not yet supported; maybe later
1042                         print("removed targeted ", self.classname, "\n");
1043                         startitem_failed = TRUE;
1044                         remove (self);
1045                         return;
1046                 }
1047                 */
1048
1049                 if(autocvar_spawn_debug >= 2)
1050                 {
1051                         entity otheritem;
1052                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1053                         {
1054                             // why not flags & fl_item?
1055                                 if(otheritem.is_item)
1056                                 {
1057                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1058                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1059                                         error("Mapper sucks.");
1060                                 }
1061                         }
1062                         self.is_item = TRUE;
1063                 }
1064
1065                 WEPSET_OR_AW(weaponsInMap, weaponid);
1066
1067                 precache_model (self.model);
1068                 precache_sound (self.item_pickupsound);
1069
1070                 precache_sound ("misc/itemrespawncountdown.wav");
1071                 if(itemid == IT_STRENGTH)
1072                         precache_sound ("misc/strength_respawn.wav");
1073                 else if(itemid == IT_INVINCIBLE)
1074                         precache_sound ("misc/shield_respawn.wav");
1075                 else
1076                         precache_sound ("misc/itemrespawn.wav");
1077
1078                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1079                         self.target = "###item###"; // for finding the nearest item using find()
1080         }
1081
1082         self.bot_pickup = TRUE;
1083         self.bot_pickupevalfunc = pickupevalfunc;
1084         self.bot_pickupbasevalue = pickupbasevalue;
1085         self.mdl = self.model;
1086         self.netname = itemname;
1087         self.touch = Item_Touch;
1088         setmodel(self, "null"); // precision set below
1089         //self.effects |= EF_LOWPRECISION;
1090
1091         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1092     {
1093         self.pos1 = '-16 -16 0';
1094         self.pos2 = '16 16 48';
1095     }
1096         else
1097     {
1098         self.pos1 = '-16 -16 0';
1099         self.pos2 = '16 16 32';
1100     }
1101     setsize (self, self.pos1, self.pos2);
1102
1103     if(itemflags & FL_POWERUP)
1104         self.ItemStatus |= ITS_ANIMATE1;
1105
1106         if(self.armorvalue || self.health)
1107         self.ItemStatus |= ITS_ANIMATE2;
1108
1109         if(itemflags & FL_WEAPON)
1110         {
1111                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1112             self.colormap = 1024; // color shirt=0 pants=0 grey
1113         else
1114             self.gravity = 1;
1115
1116                 self.ItemStatus |= ITS_ANIMATE1;
1117                 self.ItemStatus |= ISF_COLORMAP;
1118         }
1119
1120         self.state = 0;
1121         if(self.team) // broken, no idea why.
1122         {
1123                 if(!self.cnt)
1124                         self.cnt = 1; // item probability weight
1125
1126                 self.effects |= EF_NODRAW; // marker for item team search
1127                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1128         }
1129         else
1130                 Item_Reset();
1131
1132     Net_LinkEntity(self, FALSE, 0, ItemSend);
1133
1134         // call this hook after everything else has been done
1135         if(MUTATOR_CALLHOOK(Item_Spawn))
1136         {
1137                 startitem_failed = TRUE;
1138                 remove(self);
1139                 return;
1140         }
1141 }
1142
1143 float weaponswapping;
1144 float internalteam;
1145
1146 void weapon_defaultspawnfunc(float wpn)
1147 {
1148         entity e;
1149         float t;
1150         var .float ammofield;
1151         string s;
1152         entity oldself;
1153         float i, j;
1154         float f;
1155
1156         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1157         {
1158                 e = get_weaponinfo(wpn);
1159
1160                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1161                 {
1162                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1163                         startitem_failed = TRUE;
1164                         return;
1165                 }
1166
1167                 s = W_Apply_Weaponreplace(e.netname);
1168                 ret_string = s;
1169                 other = e;
1170                 MUTATOR_CALLHOOK(SetWeaponreplace);
1171                 s = ret_string;
1172                 if(s == "")
1173                 {
1174                         remove(self);
1175                         startitem_failed = TRUE;
1176                         return;
1177                 }
1178                 t = tokenize_console(s);
1179                 if(t >= 2)
1180                 {
1181                         self.team = --internalteam;
1182                         oldself = self;
1183                         for(i = 1; i < t; ++i)
1184                         {
1185                                 s = argv(i);
1186                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1187                                 {
1188                                         e = get_weaponinfo(j);
1189                                         if(e.netname == s)
1190                                         {
1191                                                 self = spawn();
1192                                                 copyentity(oldself, self);
1193                                                 self.classname = "replacedweapon";
1194                                                 weapon_defaultspawnfunc(j);
1195                                                 break;
1196                                         }
1197                                 }
1198                                 if(j > WEP_LAST)
1199                                 {
1200                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1201                                 }
1202                         }
1203                         self = oldself;
1204                 }
1205                 if(t >= 1) // always the case!
1206                 {
1207                         s = argv(0);
1208                         wpn = 0;
1209                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1210                         {
1211                                 e = get_weaponinfo(j);
1212                                 if(e.netname == s)
1213                                 {
1214                                         wpn = j;
1215                                         break;
1216                                 }
1217                         }
1218                         if(j > WEP_LAST)
1219                         {
1220                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1221                         }
1222                 }
1223                 if(wpn == 0)
1224                 {
1225                         remove(self);
1226                         startitem_failed = TRUE;
1227                         return;
1228                 }
1229         }
1230
1231         e = get_weaponinfo(wpn);
1232
1233         if(!self.respawntime)
1234         {
1235                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1236                 {
1237                         self.respawntime = g_pickup_respawntime_superweapon;
1238                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1239                 }
1240                 else
1241                 {
1242                         self.respawntime = g_pickup_respawntime_weapon;
1243                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1244                 }
1245         }
1246
1247         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1248                 if(!self.superweapons_finished)
1249                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1250
1251         if(e.items)
1252         {
1253                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1254                 {
1255                         if(e.items & j)
1256                         {
1257                                 ammofield = Item_CounterField(j);
1258                                 if(!self.ammofield)
1259                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1260                         }
1261                 }
1262         }
1263
1264         // pickup anyway
1265         if(g_pickup_weapons_anyway)
1266                 self.pickup_anyway = TRUE;
1267
1268         f = FL_WEAPON;
1269
1270         // no weapon-stay on superweapons
1271         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1272                 f |= FL_NO_WEAPON_STAY;
1273
1274         // weapon stay isn't supported for teamed weapons
1275         if(self.team)
1276                 f |= FL_NO_WEAPON_STAY;
1277
1278         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1279         if (self.modelindex) // don't precache if self was removed
1280                 weapon_action(e.weapon, WR_PRECACHE);
1281 }
1282
1283 void spawnfunc_weapon_shotgun (void);
1284 void spawnfunc_weapon_uzi (void) {
1285         if(autocvar_sv_q3acompat_machineshotgunswap)
1286         if(self.classname != "droppedweapon")
1287         {
1288                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1289                 return;
1290         }
1291         weapon_defaultspawnfunc(WEP_UZI);
1292 }
1293
1294 void spawnfunc_weapon_shotgun (void) {
1295         if(autocvar_sv_q3acompat_machineshotgunswap)
1296         if(self.classname != "droppedweapon")
1297         {
1298                 weapon_defaultspawnfunc(WEP_UZI);
1299                 return;
1300         }
1301         weapon_defaultspawnfunc(WEP_SHOTGUN);
1302 }
1303
1304 void spawnfunc_weapon_nex (void)
1305 {
1306         weapon_defaultspawnfunc(WEP_NEX);
1307 }
1308
1309 void spawnfunc_weapon_minstanex (void)
1310 {
1311         weapon_defaultspawnfunc(WEP_MINSTANEX);
1312 }
1313
1314 void spawnfunc_weapon_rocketlauncher (void)
1315 {
1316         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1317 }
1318
1319 void spawnfunc_item_rockets (void) {
1320         if(!self.ammo_rockets)
1321                 self.ammo_rockets = g_pickup_rockets;
1322         if(!self.pickup_anyway)
1323                 self.pickup_anyway = g_pickup_ammo_anyway;
1324         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1325 }
1326
1327 void spawnfunc_item_shells (void);
1328 void spawnfunc_item_bullets (void) {
1329         if(!weaponswapping)
1330         if(autocvar_sv_q3acompat_machineshotgunswap)
1331         if(self.classname != "droppedweapon")
1332         {
1333                 weaponswapping = TRUE;
1334                 spawnfunc_item_shells();
1335                 weaponswapping = FALSE;
1336                 return;
1337         }
1338
1339         if(!self.ammo_nails)
1340                 self.ammo_nails = g_pickup_nails;
1341         if(!self.pickup_anyway)
1342                 self.pickup_anyway = g_pickup_ammo_anyway;
1343         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1344 }
1345
1346 void spawnfunc_item_cells (void) {
1347         if(!self.ammo_cells)
1348                 self.ammo_cells = g_pickup_cells;
1349         if(!self.pickup_anyway)
1350                 self.pickup_anyway = g_pickup_ammo_anyway;
1351         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1352 }
1353
1354 void spawnfunc_item_shells (void) {
1355         if(!weaponswapping)
1356         if(autocvar_sv_q3acompat_machineshotgunswap)
1357         if(self.classname != "droppedweapon")
1358         {
1359                 weaponswapping = TRUE;
1360                 spawnfunc_item_bullets();
1361                 weaponswapping = FALSE;
1362                 return;
1363         }
1364
1365         if(!self.ammo_shells)
1366                 self.ammo_shells = g_pickup_shells;
1367         if(!self.pickup_anyway)
1368                 self.pickup_anyway = g_pickup_ammo_anyway;
1369         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1370 }
1371
1372 void spawnfunc_item_armor_small (void) {
1373         if(!self.armorvalue)
1374                 self.armorvalue = g_pickup_armorsmall;
1375         if(!self.max_armorvalue)
1376                 self.max_armorvalue = g_pickup_armorsmall_max;
1377         if(!self.pickup_anyway)
1378                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1379         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1380 }
1381
1382 void spawnfunc_item_armor_medium (void) {
1383         if(!self.armorvalue)
1384                 self.armorvalue = g_pickup_armormedium;
1385         if(!self.max_armorvalue)
1386                 self.max_armorvalue = g_pickup_armormedium_max;
1387         if(!self.pickup_anyway)
1388                 self.pickup_anyway = g_pickup_armormedium_anyway;
1389         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1390 }
1391
1392 void spawnfunc_item_armor_big (void) {
1393         if(!self.armorvalue)
1394                 self.armorvalue = g_pickup_armorbig;
1395         if(!self.max_armorvalue)
1396                 self.max_armorvalue = g_pickup_armorbig_max;
1397         if(!self.pickup_anyway)
1398                 self.pickup_anyway = g_pickup_armorbig_anyway;
1399         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1400 }
1401
1402 void spawnfunc_item_armor_large (void) {
1403         if(!self.armorvalue)
1404                 self.armorvalue = g_pickup_armorlarge;
1405         if(!self.max_armorvalue)
1406                 self.max_armorvalue = g_pickup_armorlarge_max;
1407         if(!self.pickup_anyway)
1408                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1409         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1410 }
1411
1412 void spawnfunc_item_health_small (void) {
1413         if(!self.max_health)
1414                 self.max_health = g_pickup_healthsmall_max;
1415         if(!self.health)
1416                 self.health = g_pickup_healthsmall;
1417         if(!self.pickup_anyway)
1418                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1419         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1420 }
1421
1422 void spawnfunc_item_health_medium (void) {
1423         if(!self.max_health)
1424                 self.max_health = g_pickup_healthmedium_max;
1425         if(!self.health)
1426                 self.health = g_pickup_healthmedium;
1427         if(!self.pickup_anyway)
1428                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1429         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1430 }
1431
1432 void spawnfunc_item_health_large (void) {
1433         if(!self.max_health)
1434                 self.max_health = g_pickup_healthlarge_max;
1435         if(!self.health)
1436                 self.health = g_pickup_healthlarge;
1437         if(!self.pickup_anyway)
1438                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1439         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1440 }
1441
1442 void spawnfunc_item_health_mega (void) {
1443                 if(!self.max_health)
1444                         self.max_health = g_pickup_healthmega_max;
1445                 if(!self.health)
1446                         self.health = g_pickup_healthmega;
1447                 if(!self.pickup_anyway)
1448                         self.pickup_anyway = g_pickup_healthmega_anyway;
1449                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1450 }
1451
1452 // support old misnamed entities
1453 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1454 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1455 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1456 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1457 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1458
1459 void spawnfunc_item_strength (void) {
1460                 precache_sound("weapons/strength_fire.wav");
1461                 if(!self.strength_finished)
1462                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1463                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1464 }
1465
1466 void spawnfunc_item_invincible (void) {
1467                 if(!self.invincible_finished)
1468                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1469                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1470 }
1471
1472 // compatibility:
1473 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1474
1475 float GiveItems(entity e, float beginarg, float endarg);
1476 void target_items_use (void)
1477 {
1478         if(activator.classname == "droppedweapon")
1479         {
1480                 EXACTTRIGGER_TOUCH;
1481                 remove(activator);
1482                 return;
1483         }
1484
1485         if not(IS_PLAYER(activator))
1486                 return;
1487         if(activator.deadflag != DEAD_NO)
1488                 return;
1489         EXACTTRIGGER_TOUCH;
1490
1491         entity e;
1492         for(e = world; (e = find(e, classname, "droppedweapon")); )
1493                 if(e.enemy == activator)
1494                         remove(e);
1495
1496         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1497                 centerprint(activator, self.message);
1498 }
1499
1500 void spawnfunc_target_items (void)
1501 {
1502         float n, i, j;
1503         entity e;
1504
1505         self.use = target_items_use;
1506         if(!self.strength_finished)
1507                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1508         if(!self.invincible_finished)
1509                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1510         if(!self.superweapons_finished)
1511                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1512
1513         precache_sound("misc/itempickup.wav");
1514         precache_sound("misc/megahealth.wav");
1515         precache_sound("misc/armor25.wav");
1516         precache_sound("misc/powerup.wav");
1517         precache_sound("misc/poweroff.wav");
1518         precache_sound("weapons/weaponpickup.wav");
1519
1520         n = tokenize_console(self.netname);
1521         if(argv(0) == "give")
1522         {
1523                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1524         }
1525         else
1526         {
1527                 for(i = 0; i < n; ++i)
1528                 {
1529                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1530                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1531                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1532                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1533                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1534                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1535                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1536                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1537                         else
1538                         {
1539                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1540                                 {
1541                                         e = get_weaponinfo(j);
1542                                         if(argv(i) == e.netname)
1543                                         {
1544                                                 WEPSET_OR_EW(self, j);
1545                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1546                                                         weapon_action(e.weapon, WR_PRECACHE);
1547                                                 break;
1548                                         }
1549                                 }
1550                                 if(j > WEP_LAST)
1551                                         print("target_items: invalid item ", argv(i), "\n");
1552                         }
1553                 }
1554
1555                 string itemprefix, valueprefix;
1556                 if(self.spawnflags == 0)
1557                 {
1558                         itemprefix = "";
1559                         valueprefix = "";
1560                 }
1561                 else if(self.spawnflags == 1)
1562                 {
1563                         itemprefix = "max ";
1564                         valueprefix = "max ";
1565                 }
1566                 else if(self.spawnflags == 2)
1567                 {
1568                         itemprefix = "min ";
1569                         valueprefix = "min ";
1570                 }
1571                 else if(self.spawnflags == 4)
1572                 {
1573                         itemprefix = "minus ";
1574                         valueprefix = "max ";
1575                 }
1576                 else
1577                 {
1578                         error("invalid spawnflags");
1579 #ifdef GMQCC
1580                         itemprefix = string_null;
1581                         valueprefix = string_null;
1582 #endif
1583                 }
1584
1585                 self.netname = "";
1586                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1587                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1588                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1589                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1590                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1591                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1592                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1593                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1594                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1595                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1596                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1597                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1598                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1599                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1600                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1601                 {
1602                         e = get_weaponinfo(j);
1603                         if(e.weapon)
1604                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1605                 }
1606         }
1607         self.netname = strzone(self.netname);
1608         //print(self.netname, "\n");
1609
1610         n = tokenize_console(self.netname);
1611         for(i = 0; i < n; ++i)
1612         {
1613                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1614                 {
1615                         e = get_weaponinfo(j);
1616                         if(argv(i) == e.netname)
1617                         {
1618                                 weapon_action(e.weapon, WR_PRECACHE);
1619                                 break;
1620                         }
1621                 }
1622         }
1623 }
1624
1625 void spawnfunc_item_fuel(void)
1626 {
1627         if(!self.ammo_fuel)
1628                 self.ammo_fuel = g_pickup_fuel;
1629         if(!self.pickup_anyway)
1630                 self.pickup_anyway = g_pickup_ammo_anyway;
1631         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1632 }
1633
1634 void spawnfunc_item_fuel_regen(void)
1635 {
1636         if(start_items & IT_FUEL_REGEN)
1637         {
1638                 spawnfunc_item_fuel();
1639                 return;
1640         }
1641         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1642 }
1643
1644 void spawnfunc_item_jetpack(void)
1645 {
1646         if(g_grappling_hook)
1647                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1648         if(!self.ammo_fuel)
1649                 self.ammo_fuel = g_pickup_fuel_jetpack;
1650         if(start_items & IT_JETPACK)
1651         {
1652                 spawnfunc_item_fuel();
1653                 return;
1654         }
1655         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1656 }
1657
1658
1659 #define OP_SET 0
1660 #define OP_MIN 1
1661 #define OP_MAX 2
1662 #define OP_PLUS 3
1663 #define OP_MINUS 4
1664
1665 float GiveWeapon(entity e, float wpn, float op, float val)
1666 {
1667         float v0, v1;
1668         v0 = WEPSET_CONTAINS_EW(e, wpn);
1669         switch(op)
1670         {
1671                 case OP_SET:
1672                         if(val > 0)
1673                                 WEPSET_OR_EW(e, wpn);
1674                         else
1675                                 WEPSET_ANDNOT_EW(e, wpn);
1676                         break;
1677                 case OP_MIN:
1678                 case OP_PLUS:
1679                         if(val > 0)
1680                                 WEPSET_OR_EW(e, wpn);
1681                         break;
1682                 case OP_MAX:
1683                         if(val <= 0)
1684                                 WEPSET_ANDNOT_EW(e, wpn);
1685                         break;
1686                 case OP_MINUS:
1687                         if(val > 0)
1688                                 WEPSET_ANDNOT_EW(e, wpn);
1689                         break;
1690         }
1691         v1 = WEPSET_CONTAINS_EW(e, wpn);
1692         return (v0 != v1);
1693 }
1694
1695 float GiveBit(entity e, .float fld, float bit, float op, float val)
1696 {
1697         float v0, v1;
1698         v0 = (e.fld & bit);
1699         switch(op)
1700         {
1701                 case OP_SET:
1702                         if(val > 0)
1703                                 e.fld |= bit;
1704                         else
1705                                 e.fld &~= bit;
1706                         break;
1707                 case OP_MIN:
1708                 case OP_PLUS:
1709                         if(val > 0)
1710                                 e.fld |= bit;
1711                         break;
1712                 case OP_MAX:
1713                         if(val <= 0)
1714                                 e.fld &~= bit;
1715                         break;
1716                 case OP_MINUS:
1717                         if(val > 0)
1718                                 e.fld &~= bit;
1719                         break;
1720         }
1721         v1 = (e.fld & bit);
1722         return (v0 != v1);
1723 }
1724
1725 float GiveValue(entity e, .float fld, float op, float val)
1726 {
1727         float v0, v1;
1728         v0 = e.fld;
1729         switch(op)
1730         {
1731                 case OP_SET:
1732                         e.fld = val;
1733                         break;
1734                 case OP_MIN:
1735                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1736                         break;
1737                 case OP_MAX:
1738                         e.fld = min(e.fld, val);
1739                         break;
1740                 case OP_PLUS:
1741                         e.fld += val;
1742                         break;
1743                 case OP_MINUS:
1744                         e.fld -= val;
1745                         break;
1746         }
1747         v1 = e.fld;
1748         return (v0 != v1);
1749 }
1750
1751 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1752 {
1753         if(v1 == v0)
1754                 return;
1755         if(v1 <= v0 - t)
1756         {
1757                 if(snd_decr != "")
1758                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1759         }
1760         else if(v0 >= v0 + t)
1761         {
1762                 if(snd_incr != "")
1763                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1764         }
1765 }
1766
1767 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1768 {
1769         if(v0 < v1)
1770                 e.rotfield = max(e.rotfield, time + rottime);
1771         else if(v0 > v1)
1772                 e.regenfield = max(e.regenfield, time + regentime);
1773 }
1774
1775 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1776 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1777 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1778 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1779 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1780 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1781
1782 float GiveItems(entity e, float beginarg, float endarg)
1783 {
1784         float got, i, j, val, op;
1785         float _switchweapon;
1786         entity wi;
1787         string cmd;
1788
1789         val = 999;
1790         op = OP_SET;
1791
1792         got = 0;
1793
1794         _switchweapon = FALSE;
1795         if (e.autoswitch)
1796                 if (e.switchweapon == w_getbestweapon(e))
1797                         _switchweapon = TRUE;
1798
1799         e.strength_finished = max(0, e.strength_finished - time);
1800         e.invincible_finished = max(0, e.invincible_finished - time);
1801         e.superweapons_finished = max(0, e.superweapons_finished - time);
1802
1803         PREGIVE(e, items);
1804         PREGIVE_WEAPONS(e);
1805         PREGIVE(e, strength_finished);
1806         PREGIVE(e, invincible_finished);
1807         PREGIVE(e, superweapons_finished);
1808         PREGIVE(e, ammo_nails);
1809         PREGIVE(e, ammo_cells);
1810         PREGIVE(e, ammo_shells);
1811         PREGIVE(e, ammo_rockets);
1812         PREGIVE(e, ammo_fuel);
1813         PREGIVE(e, armorvalue);
1814         PREGIVE(e, health);
1815
1816         for(i = beginarg; i < endarg; ++i)
1817         {
1818                 cmd = argv(i);
1819
1820                 if(cmd == "0" || stof(cmd))
1821                 {
1822                         val = stof(cmd);
1823                         continue;
1824                 }
1825                 switch(cmd)
1826                 {
1827                         case "no":
1828                                 op = OP_MAX;
1829                                 val = 0;
1830                                 continue;
1831                         case "max":
1832                                 op = OP_MAX;
1833                                 continue;
1834                         case "min":
1835                                 op = OP_MIN;
1836                                 continue;
1837                         case "plus":
1838                                 op = OP_PLUS;
1839                                 continue;
1840                         case "minus":
1841                                 op = OP_MINUS;
1842                                 continue;
1843                         case "ALL":
1844                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1845                                 got += GiveValue(e, strength_finished, op, val);
1846                                 got += GiveValue(e, invincible_finished, op, val);
1847                                 got += GiveValue(e, superweapons_finished, op, val);
1848                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1849                         case "all":
1850                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1851                                 got += GiveValue(e, health, op, val);
1852                                 got += GiveValue(e, armorvalue, op, val);
1853                         case "allweapons":
1854                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1855                                 {
1856                                         wi = get_weaponinfo(j);
1857                                         if(wi.weapon)
1858                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1859                                                         got += GiveWeapon(e, j, op, val);
1860                                 }
1861                         case "allammo":
1862                                 got += GiveValue(e, ammo_cells, op, val);
1863                                 got += GiveValue(e, ammo_shells, op, val);
1864                                 got += GiveValue(e, ammo_nails, op, val);
1865                                 got += GiveValue(e, ammo_rockets, op, val);
1866                                 got += GiveValue(e, ammo_fuel, op, val);
1867                                 break;
1868                         case "unlimited_ammo":
1869                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1870                                 break;
1871                         case "unlimited_weapon_ammo":
1872                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1873                                 break;
1874                         case "unlimited_superweapons":
1875                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1876                                 break;
1877                         case "jetpack":
1878                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1879                                 break;
1880                         case "fuel_regen":
1881                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1882                                 break;
1883                         case "strength":
1884                                 got += GiveValue(e, strength_finished, op, val);
1885                                 break;
1886                         case "invincible":
1887                                 got += GiveValue(e, invincible_finished, op, val);
1888                                 break;
1889                         case "superweapons":
1890                                 got += GiveValue(e, superweapons_finished, op, val);
1891                                 break;
1892                         case "cells":
1893                                 got += GiveValue(e, ammo_cells, op, val);
1894                                 break;
1895                         case "shells":
1896                                 got += GiveValue(e, ammo_shells, op, val);
1897                                 break;
1898                         case "nails":
1899                         case "bullets":
1900                                 got += GiveValue(e, ammo_nails, op, val);
1901                                 break;
1902                         case "rockets":
1903                                 got += GiveValue(e, ammo_rockets, op, val);
1904                                 break;
1905                         case "health":
1906                                 got += GiveValue(e, health, op, val);
1907                                 break;
1908                         case "armor":
1909                                 got += GiveValue(e, armorvalue, op, val);
1910                                 break;
1911                         case "fuel":
1912                                 got += GiveValue(e, ammo_fuel, op, val);
1913                                 break;
1914                         default:
1915                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1916                                 {
1917                                         wi = get_weaponinfo(j);
1918                                         if(cmd == wi.netname)
1919                                         {
1920                                                 got += GiveWeapon(e, j, op, val);
1921                                                 break;
1922                                         }
1923                                 }
1924                                 if(j > WEP_LAST)
1925                                         print("give: invalid item ", cmd, "\n");
1926                                 break;
1927                 }
1928                 val = 999;
1929                 op = OP_SET;
1930         }
1931
1932         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1933         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1934         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1935         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1936         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1937         {
1938                 wi = get_weaponinfo(j);
1939                 if(wi.weapon)
1940                 {
1941                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1942                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1943                                 if(WEPSET_CONTAINS_EW(e, j))
1944                                         weapon_action(wi.weapon, WR_PRECACHE);
1945                 }
1946         }
1947         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1948         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1949         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1950         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1951         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1952         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1953         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1954         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1955         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1956
1957         if(e.superweapons_finished <= 0)
1958                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1959                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1960
1961         if(e.strength_finished <= 0)
1962                 e.strength_finished = 0;
1963         else
1964                 e.strength_finished += time;
1965         if(e.invincible_finished <= 0)
1966                 e.invincible_finished = 0;
1967         else
1968                 e.invincible_finished += time;
1969         if(e.superweapons_finished <= 0)
1970                 e.superweapons_finished = 0;
1971         else
1972                 e.superweapons_finished += time;
1973
1974         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1975                 _switchweapon = TRUE;
1976         if(_switchweapon)
1977                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1978
1979         return got;
1980 }
1981 #endif