qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "waypointsprites.qh"
   9
  10     #include "bot/bot.qh"
  11     #include "bot/waypoints.qh"
  12
  13     #include "mutators/mutators_include.qh"
  14
  15     #include "weapons/common.qh"
  16     #include "weapons/selection.qh"
  17     #include "weapons/weaponsystem.qh"
  18
  19     #include "../common/constants.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "../common/notifications.qh"
  22         #include "../common/triggers/subs.qh"
  23     #include "../common/util.qh"
  24
  25     #include "../common/monsters/all.qh"
  26
  27     #include "../common/weapons/all.qh"
  28
  29     #include "../warpzonelib/util_server.qh"
  30 #endif
  31
  32 #ifdef CSQC
  33 void ItemDraw()
  34 {
  35     if(self.gravity)
  36     {
  37         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  38         if(self.move_flags & FL_ONGROUND)
  39         { // For some reason move_avelocity gets set to '0 0 0' here ...
  40             self.oldorigin = self.origin;
  41             self.gravity = 0;
  42
  43             if(autocvar_cl_animate_items)
  44             { // ... so reset it if animations are requested.
  45                 if(self.ItemStatus & ITS_ANIMATE1)
  46                     self.move_avelocity = '0 180 0';
  47
  48                 if(self.ItemStatus & ITS_ANIMATE2)
  49                     self.move_avelocity = '0 -90 0';
  50             }
  51         }
  52     }
  53     else if (autocvar_cl_animate_items)
  54     {
  55         if(self.ItemStatus & ITS_ANIMATE1)
  56         {
  57             self.angles += self.move_avelocity * frametime;
  58             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  59         }
  60
  61         if(self.ItemStatus & ITS_ANIMATE2)
  62         {
  63             self.angles += self.move_avelocity * frametime;
  64             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  65         }
  66     }
  67 }
  68
  69 void ItemDrawSimple()
  70 {
  71     if(self.gravity)
  72     {
  73         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74
  75         if(self.move_flags & FL_ONGROUND)
  76             self.gravity = 0;
  77     }
  78 }
  79
  80 void ItemRead(float _IsNew)
  81 {
  82     int sf = ReadByte();
  83
  84     if(sf & ISF_LOCATION)
  85     {
  86         self.origin_x = ReadCoord();
  87         self.origin_y = ReadCoord();
  88         self.origin_z = ReadCoord();
  89         setorigin(self, self.origin);
  90         self.oldorigin = self.origin;
  91     }
  92
  93     if(sf & ISF_ANGLES)
  94     {
  95         self.angles_x = ReadCoord();
  96         self.angles_y = ReadCoord();
  97         self.angles_z = ReadCoord();
  98         self.move_angles = self.angles;
  99     }
 100
 101     if(sf & ISF_SIZE)
 102     {
 103         self.mins_x = ReadCoord();
 104         self.mins_y = ReadCoord();
 105         self.mins_z = ReadCoord();
 106         self.maxs_x = ReadCoord();
 107         self.maxs_y = ReadCoord();
 108         self.maxs_z = ReadCoord();
 109         setsize(self, self.mins, self.maxs);
 110     }
 111
 112     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 113     {
 114         self.ItemStatus = ReadByte();
 115
 116         if(self.ItemStatus & ITS_AVAILABLE)
 117         {
 118             self.alpha = 1;
 119             self.colormod = self.glowmod = '1 1 1';
 120         }
 121         else
 122         {
 123             if (autocvar_cl_ghost_items_color)
 124             {
 125                 self.alpha = autocvar_cl_ghost_items;
 126                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 127             }
 128             else
 129                 self.alpha = -1;
 130         }
 131
 132         if(autocvar_cl_fullbright_items)
 133             if(self.ItemStatus & ITS_ALLOWFB)
 134                 self.effects |= EF_FULLBRIGHT;
 135
 136         if(self.ItemStatus & ITS_STAYWEP)
 137         {
 138             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 139             self.alpha = autocvar_cl_weapon_stay_alpha;
 140
 141         }
 142
 143         if(self.ItemStatus & ITS_POWERUP)
 144         {
 145             if(self.ItemStatus & ITS_AVAILABLE)
 146                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 147             else
 148                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 149         }
 150     }
 151
 152     if(sf & ISF_MODEL)
 153     {
 154         self.drawmask  = MASK_NORMAL;
 155         self.movetype  = MOVETYPE_TOSS;
 156         self.draw       = ItemDraw;
 157
 158         if(self.mdl)
 159             strunzone(self.mdl);
 160
 161         self.mdl = "";
 162         string _fn = ReadString();
 163
 164         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 165         {
 166             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 167             self.draw = ItemDrawSimple;
 168
 169
 170
 171             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 177             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 178                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 179             else
 180             {
 181                 self.draw = ItemDraw;
 182                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 183             }
 184         }
 185
 186         if(self.draw != ItemDrawSimple)
 187             self.mdl = strzone(_fn);
 188
 189
 190         if(self.mdl == "")
 191             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 192
 193         precache_model(self.mdl);
 194         setmodel(self, self.mdl);
 195     }
 196
 197     if(sf & ISF_COLORMAP)
 198         self.colormap = ReadShort();
 199
 200     if(sf & ISF_DROP)
 201     {
 202         self.gravity = 1;
 203         //self.move_angles = '0 0 0';
 204         self.move_movetype = MOVETYPE_TOSS;
 205         self.move_velocity_x = ReadCoord();
 206         self.move_velocity_y = ReadCoord();
 207         self.move_velocity_z = ReadCoord();
 208         self.velocity = self.move_velocity;
 209         self.move_origin = self.oldorigin;
 210
 211         if(!self.move_time)
 212         {
 213             self.move_time = time;
 214             self.spawntime = time;
 215         }
 216         else
 217             self.move_time = max(self.move_time, time);
 218     }
 219
 220     if(autocvar_cl_animate_items)
 221     {
 222         if(self.ItemStatus & ITS_ANIMATE1)
 223             self.move_avelocity = '0 180 0';
 224
 225         if(self.ItemStatus & ITS_ANIMATE2)
 226             self.move_avelocity = '0 -90 0';
 227     }
 228 }
 229
 230 #endif
 231
 232 #ifdef SVQC
 233 bool ItemSend(entity to, int sf)
 234 {
 235     if(self.gravity)
 236         sf |= ISF_DROP;
 237     else
 238         sf &= ~ISF_DROP;
 239
 240         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 241         WriteByte(MSG_ENTITY, sf);
 242
 243         //WriteByte(MSG_ENTITY, self.cnt);
 244     if(sf & ISF_LOCATION)
 245     {
 246         WriteCoord(MSG_ENTITY, self.origin.x);
 247         WriteCoord(MSG_ENTITY, self.origin.y);
 248         WriteCoord(MSG_ENTITY, self.origin.z);
 249     }
 250
 251     if(sf & ISF_ANGLES)
 252     {
 253         WriteCoord(MSG_ENTITY, self.angles.x);
 254         WriteCoord(MSG_ENTITY, self.angles.y);
 255         WriteCoord(MSG_ENTITY, self.angles.z);
 256     }
 257
 258     if(sf & ISF_SIZE)
 259     {
 260         WriteCoord(MSG_ENTITY, self.mins.x);
 261         WriteCoord(MSG_ENTITY, self.mins.y);
 262         WriteCoord(MSG_ENTITY, self.mins.z);
 263         WriteCoord(MSG_ENTITY, self.maxs.x);
 264         WriteCoord(MSG_ENTITY, self.maxs.y);
 265         WriteCoord(MSG_ENTITY, self.maxs.z);
 266     }
 267
 268     if(sf & ISF_STATUS)
 269         WriteByte(MSG_ENTITY, self.ItemStatus);
 270
 271     if(sf & ISF_MODEL)
 272     {
 273
 274         if(self.mdl == "")
 275             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 276
 277         WriteString(MSG_ENTITY, self.mdl);
 278     }
 279
 280
 281     if(sf & ISF_COLORMAP)
 282         WriteShort(MSG_ENTITY, self.colormap);
 283
 284     if(sf & ISF_DROP)
 285     {
 286         WriteCoord(MSG_ENTITY, self.velocity.x);
 287         WriteCoord(MSG_ENTITY, self.velocity.y);
 288         WriteCoord(MSG_ENTITY, self.velocity.z);
 289     }
 290
 291     return true;
 292 }
 293
 294 void ItemUpdate(entity item)
 295 {
 296         item.SendFlags |= ISF_LOCATION;
 297 }
 298
 299 float have_pickup_item(void)
 300 {
 301         if(self.flags & FL_POWERUP)
 302         {
 303                 if(autocvar_g_powerups > 0)
 304                         return true;
 305                 if(autocvar_g_powerups == 0)
 306                         return false;
 307         }
 308         else
 309         {
 310                 if(autocvar_g_pickup_items > 0)
 311                         return true;
 312                 if(autocvar_g_pickup_items == 0)
 313                         return false;
 314                 if(g_weaponarena)
 315                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 316                                 return false;
 317         }
 318         return true;
 319 }
 320
 321 /*
 322 float Item_Customize()
 323 {
 324         if(self.spawnshieldtime)
 325                 return true;
 326         if(self.weapons & ~other.weapons)
 327         {
 328                 self.colormod = '0 0 0';
 329                 self.glowmod = self.colormod;
 330                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 331                 return true;
 332         }
 333         else
 334         {
 335                 if(g_ghost_items)
 336                 {
 337                         self.colormod = stov(autocvar_g_ghost_items_color);
 338                         self.glowmod = self.colormod;
 339                         self.alpha = g_ghost_items;
 340                         return true;
 341                 }
 342                 else
 343                         return false;
 344         }
 345 }
 346 */
 347
 348 void Item_Show (entity e, float mode)
 349 {
 350         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 351         e.ItemStatus &= ~ITS_STAYWEP;
 352         if (mode > 0)
 353         {
 354                 // make the item look normal, and be touchable
 355                 e.model = e.mdl;
 356                 e.solid = SOLID_TRIGGER;
 357                 e.spawnshieldtime = 1;
 358                 e.ItemStatus |= ITS_AVAILABLE;
 359         }
 360         else if (mode < 0)
 361         {
 362                 // hide the item completely
 363                 e.model = string_null;
 364                 e.solid = SOLID_NOT;
 365                 e.spawnshieldtime = 1;
 366                 e.ItemStatus &= ~ITS_AVAILABLE;
 367         }
 368         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 369         {
 370                 // make the item translucent and not touchable
 371                 e.model = e.mdl;
 372                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 373                 e.effects |= EF_STARDUST;
 374                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 375                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 376         }
 377         else
 378         {
 379                 //setmodel(e, "null");
 380                 e.solid = SOLID_NOT;
 381                 e.colormod = '0 0 0';
 382                 e.glowmod = e.colormod;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus &= ~ITS_AVAILABLE;
 385         }
 386
 387         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 388             e.ItemStatus |= ITS_POWERUP;
 389
 390         if (autocvar_g_nodepthtestitems)
 391                 e.effects |= EF_NODEPTHTEST;
 392
 393
 394     if (autocvar_g_fullbrightitems)
 395                 e.ItemStatus |= ITS_ALLOWFB;
 396
 397         if (autocvar_sv_simple_items)
 398         e.ItemStatus |= ITS_ALLOWSI;
 399
 400         // relink entity (because solid may have changed)
 401         setorigin(e, e.origin);
 402     e.SendFlags |= ISF_STATUS;
 403 }
 404
 405 void Item_Think()
 406 {
 407         self.nextthink = time;
 408         if(self.origin != self.oldorigin)
 409         {
 410                 self.oldorigin = self.origin;
 411                 ItemUpdate(self);
 412         }
 413 }
 414
 415 float it_armor_large_time;
 416 float it_health_mega_time;
 417 float it_invisible_time;
 418 float it_speed_time;
 419 float it_extralife_time;
 420 float it_strength_time;
 421 float it_shield_time;
 422 float it_fuelregen_time;
 423 float it_jetpack_time;
 424 float it_superweapons_time;
 425
 426 void Item_ItemsTime_Init()
 427 {
 428         it_armor_large_time = -1;
 429         it_health_mega_time = -1;
 430         it_invisible_time = -1;
 431         it_speed_time = -1;
 432         it_extralife_time = -1;
 433         it_strength_time = -1;
 434         it_shield_time = -1;
 435         it_fuelregen_time = -1;
 436         it_jetpack_time = -1;
 437         it_superweapons_time = -1;
 438 }
 439 void Item_ItemsTime_ResetTimes()
 440 {
 441         it_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 442         it_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 443         it_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 444         it_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 445         it_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 446         it_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 447         it_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 448         it_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 449         it_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 450         it_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 451 }
 452 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 453 {
 454         e.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 455         e.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 456         e.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 457         e.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 458         e.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 459         e.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 460         e.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 461         e.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 462         e.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 463         e.item_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 464 }
 465 void Item_ItemsTime_SetTimesForPlayer(entity e)
 466 {
 467         e.item_armor_large_time = it_armor_large_time;
 468         e.item_health_mega_time = it_health_mega_time;
 469         e.item_invisible_time = it_invisible_time;
 470         e.item_speed_time = it_speed_time;
 471         e.item_extralife_time = it_extralife_time;
 472         e.item_strength_time = it_strength_time;
 473         e.item_shield_time = it_shield_time;
 474         e.item_fuelregen_time = it_fuelregen_time;
 475         e.item_jetpack_time = it_jetpack_time;
 476         e.item_superweapons_time = it_superweapons_time;
 477 }
 478
 479 void Item_ItemsTime_SetTime(entity e, float t)
 480 {
 481         if(!autocvar_sv_itemstime)
 482                 return;
 483
 484         if(g_instagib)
 485         {
 486                 switch(e.items)
 487                 {
 488                         case IT_STRENGTH://"item-invis"
 489                                 it_invisible_time = t;
 490                                 break;
 491                         case IT_NAILS://"item-extralife"
 492                                 it_extralife_time = t;
 493                                 break;
 494                         case IT_INVINCIBLE://"item-speed"
 495                                 it_speed_time = t;
 496                                 break;
 497                 }
 498         }
 499         else
 500         {
 501                 switch(e.items)
 502                 {
 503                         case IT_HEALTH:
 504                                 // if(e.classname == "item_health_mega") // IT_HEALTH unequivocally identifies it
 505                                         it_health_mega_time = t;
 506                                 break;
 507                         case IT_ARMOR:
 508                                 if(e.classname == "item_armor_large") // IT_ARMOR doesn't unequivocally identifies it
 509                                         it_armor_large_time = t;
 510                                 break;
 511                         case IT_STRENGTH://"item-strength"
 512                                 it_strength_time = t;
 513                                 break;
 514                         case IT_INVINCIBLE://"item-shield"
 515                                 it_shield_time = t;
 516                                 break;
 517                         default:
 518                                 if(e.weapons & WEPSET_SUPERWEAPONS)
 519                                         it_superweapons_time = t;
 520                 }
 521         }
 522         switch(e.items)
 523         {
 524                 case IT_FUEL_REGEN://"item-fuelregen"
 525                         it_fuelregen_time = t;
 526                         break;
 527                 case IT_JETPACK://"item-jetpack"
 528                         it_jetpack_time = t;
 529                         break;
 530         }
 531 }
 532 void Item_ItemsTime_SetTimesForAllPlayers()
 533 {
 534         entity e;
 535         if(warmup_stage)
 536         {
 537                 FOR_EACH_REALCLIENT(e)
 538                         Item_ItemsTime_SetTimesForPlayer(e);
 539         }
 540         else
 541         {
 542                 FOR_EACH_REALCLIENT(e)
 543                 {
 544                         if(!IS_PLAYER(e))
 545                                 Item_ItemsTime_SetTimesForPlayer(e);
 546                 }
 547         }
 548 }
 549
 550 float Item_ItemsTime_UpdateTime(entity e, float t)
 551 {
 552         entity head;
 553         bool isavailable = (t == 0);
 554         if(e.weapons & WEPSET_SUPERWEAPONS)
 555         {
 556                 for(head = world; (head = nextent(head)); )
 557                 {
 558                         if(clienttype(head) != CLIENTTYPE_NOTACLIENT || !(head.weapons & WEPSET_SUPERWEAPONS) || head.classname == "weapon_info")
 559                                 continue;
 560                         if(e == head)
 561                                 continue;
 562
 563                         if(head.scheduledrespawntime <= time)
 564                                 isavailable = true;
 565                         else if(t == 0 || head.scheduledrespawntime < t)
 566                                 t = head.scheduledrespawntime;
 567                 }
 568         }
 569         else
 570         {
 571                 for(head = world; (head = nextent(head)); )
 572                 {
 573                         if(head.itemdef != e.itemdef)
 574                                 continue;
 575                         if(e == head)
 576                                 continue;
 577
 578                         if(head.scheduledrespawntime <= time)
 579                                 isavailable = true;
 580                         else if(t == 0 || head.scheduledrespawntime < t)
 581                                 t = head.scheduledrespawntime;
 582                 }
 583         }
 584         if(isavailable)
 585                 t = -t; // let know the client there's another available item
 586         return t;
 587 }
 588
 589 void Item_Respawn (void)
 590 {
 591         Item_Show(self, 1);
 592         // this is ugly...
 593         if(self.items == IT_STRENGTH)
 594                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 595         else if(self.items == IT_INVINCIBLE)
 596                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 597         else
 598                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 599         setorigin (self, self.origin);
 600
 601         if(self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 602         {
 603                 float t = Item_ItemsTime_UpdateTime(self, 0);
 604                 Item_ItemsTime_SetTime(self, t);
 605                 Item_ItemsTime_SetTimesForAllPlayers();
 606         }
 607
 608         self.think = Item_Think;
 609         self.nextthink = time;
 610
 611         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 612         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 613 }
 614
 615 void Item_RespawnCountdown (void)
 616 {
 617         if(self.count >= ITEM_RESPAWN_TICKS)
 618         {
 619                 if(self.waypointsprite_attached)
 620                         WaypointSprite_Kill(self.waypointsprite_attached);
 621                 Item_Respawn();
 622         }
 623         else
 624         {
 625                 self.nextthink = time + 1;
 626                 self.count += 1;
 627                 if(self.count == 1)
 628                 {
 629                         string name;
 630                         vector rgb = '1 0 1';
 631                         name = string_null;
 632                         switch(self.items)
 633                         {
 634                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 635                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 636                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 637                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 638                                 case IT_HEALTH:
 639                                         //if (self.classname == "item_health_mega")
 640                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 641                                         break;
 642                                 case IT_ARMOR:
 643                                         if (self.classname == "item_armor_large")
 644                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 645                                         break;
 646                         }
 647                         MUTATOR_CALLHOOK(Item_RespawnCountdown, name, rgb);
 648                         name = item_name;
 649                         rgb = item_color;
 650                         if(self.flags & FL_WEAPON)
 651                         {
 652                                 entity wi = get_weaponinfo(self.weapon);
 653                                 if(wi)
 654                                 {
 655                                         name = wi.wpmodel;
 656                                         rgb = '1 0 0';
 657                                 }
 658                         }
 659                         if(name)
 660                         {
 661                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 662                                 if(self.waypointsprite_attached)
 663                                 {
 664                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 665                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 666                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 667                                 }
 668                         }
 669                         else
 670                         {
 671                                 print("Unknown powerup-marked item is wanting to respawn\n");
 672                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 673                         }
 674                 }
 675
 676                 if(self.waypointsprite_attached)
 677                 {
 678                         entity e;
 679                         entity it = self;
 680                         self = self.waypointsprite_attached;
 681                         FOR_EACH_REALCLIENT(e)
 682                                 if(self.waypointsprite_visible_for_player(e))
 683                                 {
 684                                         msg_entity = e;
 685                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 686                                 }
 687                         self = it;
 688
 689                         WaypointSprite_Ping(self.waypointsprite_attached);
 690                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 691                 }
 692                 else
 693                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 694         }
 695 }
 696
 697 void Item_RespawnThink()
 698 {
 699         self.nextthink = time;
 700         if(self.origin != self.oldorigin)
 701         {
 702                 self.oldorigin = self.origin;
 703                 ItemUpdate(self);
 704         }
 705
 706         if(time >= self.wait)
 707                 Item_Respawn();
 708 }
 709
 710 void Item_ScheduleRespawnIn(entity e, float t)
 711 {
 712         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 713         {
 714                 e.think = Item_RespawnCountdown;
 715                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 716                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 717                 e.count = 0;
 718                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 719                 Item_ItemsTime_SetTime(e, t);
 720                 Item_ItemsTime_SetTimesForAllPlayers();
 721         }
 722         else
 723         {
 724                 e.think = Item_RespawnThink;
 725                 e.nextthink = time;
 726                 e.scheduledrespawntime = time + t;
 727                 e.wait = time + t;
 728         }
 729 }
 730
 731 void Item_ScheduleRespawn(entity e)
 732 {
 733         if(e.respawntime > 0)
 734         {
 735                 Item_Show(e, 0);
 736                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 737         }
 738         else // if respawntime is -1, this item does not respawn
 739                 Item_Show(e, -1);
 740 }
 741
 742 void Item_ScheduleInitialRespawn(entity e)
 743 {
 744         Item_Show(e, 0);
 745         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 746 }
 747
 748 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 749 {
 750         if (!item.(ammotype))
 751                 return false;
 752
 753         if (item.spawnshieldtime)
 754         {
 755                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 756                 {
 757                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 758                         goto YEAH;
 759                 }
 760         }
 761         else if(g_weapon_stay == 2)
 762         {
 763                 float mi = min(item.(ammotype), ammomax);
 764                 if (player.(ammotype) < mi)
 765                 {
 766                         player.(ammotype) = mi;
 767                         goto YEAH;
 768                 }
 769         }
 770
 771         return false;
 772
 773 :YEAH
 774         switch(mode)
 775         {
 776                 case ITEM_MODE_FUEL:
 777                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 778                         break;
 779                 case ITEM_MODE_HEALTH:
 780                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 781                         break;
 782                 case ITEM_MODE_ARMOR:
 783                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 784                         break;
 785                 default:
 786                         break;
 787         }
 788         return true;
 789 }
 790
 791 float Item_GiveTo(entity item, entity player)
 792 {
 793         float _switchweapon;
 794         float pickedup;
 795         float it;
 796         float i;
 797
 798         // if nothing happens to player, just return without taking the item
 799         pickedup = false;
 800         _switchweapon = false;
 801         // in case the player has autoswitch enabled do the following:
 802         // if the player is using their best weapon before items are given, they
 803         // probably want to switch to an even better weapon after items are given
 804         if (player.autoswitch)
 805         if (player.switchweapon == w_getbestweapon(player))
 806                 _switchweapon = true;
 807
 808         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 809                 _switchweapon = true;
 810
 811         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 812         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 813         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 814         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 815         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 816         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 817         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 818         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 819
 820         if (item.flags & FL_WEAPON)
 821         {
 822                 WepSet it;
 823                 it = item.weapons;
 824                 it &= ~player.weapons;
 825
 826                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 827                 {
 828                         pickedup = true;
 829                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 830                         if(it & WepSet_FromWeapon(i))
 831                         {
 832                                 W_DropEvent(WR_PICKUP, player, i, item);
 833                                 W_GiveWeapon(player, i);
 834                         }
 835                 }
 836         }
 837
 838         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 839         {
 840                 pickedup = true;
 841                 player.items |= it;
 842                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 843         }
 844
 845         if (item.strength_finished)
 846         {
 847                 pickedup = true;
 848                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 849         }
 850         if (item.invincible_finished)
 851         {
 852                 pickedup = true;
 853                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 854         }
 855         if (item.superweapons_finished)
 856         {
 857                 pickedup = true;
 858                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 859         }
 860
 861 :skip
 862
 863         // always eat teamed entities
 864         if(item.team)
 865                 pickedup = true;
 866
 867         if (!pickedup)
 868                 return 0;
 869
 870         if (_switchweapon)
 871                 if (player.switchweapon != w_getbestweapon(player))
 872                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 873
 874         return 1;
 875 }
 876
 877 void Item_Touch (void)
 878 {
 879         entity e, head;
 880
 881         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 882         if(self.classname == "droppedweapon")
 883         {
 884                 if (ITEM_TOUCH_NEEDKILL())
 885                 {
 886                         remove(self);
 887                         return;
 888                 }
 889         }
 890
 891         if (!IS_PLAYER(other))
 892                 return;
 893         if (other.frozen)
 894                 return;
 895         if (other.deadflag)
 896                 return;
 897         if (self.solid != SOLID_TRIGGER)
 898                 return;
 899         if (self.owner == other)
 900                 return;
 901         if (time < self.item_spawnshieldtime)
 902                 return;
 903
 904         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 905         {
 906                 case MUT_ITEMTOUCH_RETURN: { return; }
 907                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 908         }
 909
 910         if (self.classname == "droppedweapon")
 911         {
 912                 self.strength_finished = max(0, self.strength_finished - time);
 913                 self.invincible_finished = max(0, self.invincible_finished - time);
 914                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 915         }
 916         entity it = self.itemdef;
 917         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 918         if (!gave)
 919         {
 920                 if (self.classname == "droppedweapon")
 921                 {
 922                         // undo what we did above
 923                         self.strength_finished += time;
 924                         self.invincible_finished += time;
 925                         self.superweapons_finished += time;
 926                 }
 927                 return;
 928         }
 929
 930         :pickup
 931
 932         other.last_pickup = time;
 933
 934         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 935         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 936
 937         if (self.classname == "droppedweapon")
 938                 remove (self);
 939         else if (self.spawnshieldtime)
 940         {
 941                 if(self.team)
 942                 {
 943                         RandomSelection_Init();
 944                         for(head = world; (head = findfloat(head, team, self.team)); )
 945                         {
 946                                 if(head.flags & FL_ITEM)
 947                                 {
 948                                         Item_Show(head, -1);
 949                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 950                                 }
 951                         }
 952                         e = RandomSelection_chosen_ent;
 953
 954                 }
 955                 else
 956                         e = self;
 957                 Item_ScheduleRespawn(e);
 958         }
 959 }
 960
 961 void Item_Reset()
 962 {
 963         Item_Show(self, !self.state);
 964         setorigin (self, self.origin);
 965
 966         if(self.classname != "droppedweapon")
 967         {
 968                 self.think = Item_Think;
 969                 self.nextthink = time;
 970
 971                 if(self.waypointsprite_attached)
 972                         WaypointSprite_Kill(self.waypointsprite_attached);
 973
 974                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 975                         Item_ScheduleInitialRespawn(self);
 976         }
 977 }
 978
 979 void Item_FindTeam()
 980 {
 981         entity head, e;
 982
 983         if(self.effects & EF_NODRAW)
 984         {
 985                 // marker for item team search
 986                 dprint("Initializing item team ", ftos(self.team), "\n");
 987                 RandomSelection_Init();
 988                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 989                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 990                 e = RandomSelection_chosen_ent;
 991                 e.state = 0;
 992                 Item_Show(e, 1);
 993
 994                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 995                 {
 996                         if(head != e)
 997                         {
 998                                 // make it a non-spawned item
 999                                 Item_Show(head, -1);
1000                                 head.state = 1; // state 1 = initially hidden item
1001                         }
1002                         head.effects &= ~EF_NODRAW;
1003                 }
1004
1005                 Item_Reset();
1006         }
1007 }
1008
1009 // Savage: used for item garbage-collection
1010 // TODO: perhaps nice special effect?
1011 void RemoveItem(void)
1012 {
1013         remove(self);
1014 }
1015
1016 // pickup evaluation functions
1017 // these functions decide how desirable an item is to the bots
1018
1019 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1020
1021 float weapon_pickupevalfunc(entity player, entity item)
1022 {
1023         float c;
1024
1025         // See if I have it already
1026         if(item.weapons & ~player.weapons)
1027         {
1028                 // If I can pick it up
1029                 if(!item.spawnshieldtime)
1030                         c = 0;
1031                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
1032                 {
1033                         // Skilled bots will grab more
1034                         c = bound(0, skill / 10, 1) * 0.5;
1035                 }
1036                 else
1037                         c = 0;
1038         }
1039         else
1040                 c = 1;
1041
1042         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
1043         if( bot_custom_weapon && c )
1044         {
1045                 // Find the highest position on any range
1046                 int position = -1;
1047                 for (int j = 0; j < WEP_LAST ; ++j){
1048                         if(
1049                                         bot_weapons_far[j] == item.weapon ||
1050                                         bot_weapons_mid[j] == item.weapon ||
1051                                         bot_weapons_close[j] == item.weapon
1052                           )
1053                         {
1054                                 position = j;
1055                                 break;
1056                         }
1057                 }
1058
1059                 // Rate it
1060                 if (position >= 0 )
1061                 {
1062                         position = WEP_LAST - position;
1063                         // item.bot_pickupbasevalue is overwritten here
1064                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
1065                 }
1066         }
1067
1068         return item.bot_pickupbasevalue * c;
1069 }
1070
1071 float commodity_pickupevalfunc(entity player, entity item)
1072 {
1073         float c, i;
1074         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1075         entity wi;
1076         c = 0;
1077
1078         // Detect needed ammo
1079         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
1080         {
1081                 wi = get_weaponinfo(i);
1082
1083                 if (!(player.weapons & WepSet_FromWeapon(i)))
1084                         continue;
1085
1086                 if(wi.items & IT_SHELLS)
1087                         need_shells = true;
1088                 else if(wi.items & IT_NAILS)
1089                         need_nails = true;
1090                 else if(wi.items & IT_ROCKETS)
1091                         need_rockets = true;
1092                 else if(wi.items & IT_CELLS)
1093                         need_cells = true;
1094                 else if(wi.items & IT_PLASMA)
1095                         need_plasma = true;
1096                 else if(wi.items & IT_FUEL)
1097                         need_fuel = true;
1098         }
1099
1100         // TODO: figure out if the player even has the weapon this ammo is for?
1101         // may not affect strategy much though...
1102         // find out how much more ammo/armor/health the player can hold
1103         if (need_shells)
1104         if (item.ammo_shells)
1105         if (player.ammo_shells < g_pickup_shells_max)
1106                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1107         if (need_nails)
1108         if (item.ammo_nails)
1109         if (player.ammo_nails < g_pickup_nails_max)
1110                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1111         if (need_rockets)
1112         if (item.ammo_rockets)
1113         if (player.ammo_rockets < g_pickup_rockets_max)
1114                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1115         if (need_cells)
1116         if (item.ammo_cells)
1117         if (player.ammo_cells < g_pickup_cells_max)
1118                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1119         if (need_plasma)
1120         if (item.ammo_plasma)
1121         if (player.ammo_plasma < g_pickup_plasma_max)
1122                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1123         if (need_fuel)
1124         if (item.ammo_fuel)
1125         if (player.ammo_fuel < g_pickup_fuel_max)
1126                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1127         if (item.armorvalue)
1128         if (player.armorvalue < item.max_armorvalue)
1129                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1130         if (item.health)
1131         if (player.health < item.max_health)
1132                 c = c + max(0, 1 - player.health / item.max_health);
1133
1134         return item.bot_pickupbasevalue * c;
1135 }
1136
1137 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1138 {
1139         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1140                 RemoveItem();
1141 }
1142
1143 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1144 {
1145         startitem_failed = false;
1146
1147         if(self.model == "")
1148                 self.model = itemmodel;
1149
1150         if(self.model == "")
1151     {
1152         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1153         return;
1154     }
1155
1156         if(self.item_pickupsound == "")
1157                 self.item_pickupsound = pickupsound;
1158
1159         if(!self.respawntime) // both need to be set
1160         {
1161                 self.respawntime = defaultrespawntime;
1162                 self.respawntimejitter = defaultrespawntimejitter;
1163         }
1164
1165         self.items = itemid;
1166         self.weapon = weaponid;
1167
1168         if(weaponid)
1169                 self.weapons = WepSet_FromWeapon(weaponid);
1170
1171         self.flags = FL_ITEM | itemflags;
1172
1173         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1174         {
1175                 startitem_failed = true;
1176                 remove(self);
1177                 return;
1178         }
1179
1180         // is it a dropped weapon?
1181         if (self.classname == "droppedweapon")
1182         {
1183                 self.reset = SUB_Remove;
1184                 // it's a dropped weapon
1185                 self.movetype = MOVETYPE_TOSS;
1186
1187                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1188                 self.think = RemoveItem;
1189                 self.nextthink = time + 20;
1190
1191                 self.takedamage = DAMAGE_YES;
1192                 self.event_damage = Item_Damage;
1193
1194                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1195                 /*
1196                 if(self.items == 0)
1197                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1198                 if(self.ammo_nails == 0)
1199                 if(self.ammo_cells == 0)
1200                 if(self.ammo_rockets == 0)
1201                 if(self.ammo_shells == 0)
1202                 if(self.ammo_fuel == 0)
1203                 if(self.health == 0)
1204                 if(self.armorvalue == 0)
1205                 */
1206                 {
1207                         // if item is worthless after a timer, have it expire then
1208                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1209                 }
1210
1211                 // don't drop if in a NODROP zone (such as lava)
1212                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1213                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1214                 {
1215                         startitem_failed = true;
1216                         remove(self);
1217                         return;
1218                 }
1219         }
1220         else
1221         {
1222                 if(!have_pickup_item())
1223                 {
1224                         startitem_failed = true;
1225                         remove (self);
1226                         return;
1227                 }
1228
1229                 self.reset = Item_Reset;
1230                 // it's a level item
1231                 if(self.spawnflags & 1)
1232                         self.noalign = 1;
1233                 if (self.noalign)
1234                         self.movetype = MOVETYPE_NONE;
1235                 else
1236                         self.movetype = MOVETYPE_TOSS;
1237                 // do item filtering according to game mode and other things
1238                 if (!self.noalign)
1239                 {
1240                         // first nudge it off the floor a little bit to avoid math errors
1241                         setorigin(self, self.origin + '0 0 1');
1242                         // set item size before we spawn a spawnfunc_waypoint
1243                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1244                                 setsize (self, '-16 -16 0', '16 16 48');
1245                         else
1246                                 setsize (self, '-16 -16 0', '16 16 32');
1247
1248                         // note droptofloor returns false if stuck/or would fall too far
1249                         droptofloor();
1250                         waypoint_spawnforitem(self);
1251                 }
1252
1253                 /*
1254                  * can't do it that way, as it would break maps
1255                  * TODO make a target_give like entity another way, that perhaps has
1256                  * the weapon name in a key
1257                 if(self.targetname)
1258                 {
1259                         // target_give not yet supported; maybe later
1260                         print("removed targeted ", self.classname, "\n");
1261                         startitem_failed = true;
1262                         remove (self);
1263                         return;
1264                 }
1265                 */
1266
1267                 if(autocvar_spawn_debug >= 2)
1268                 {
1269                         entity otheritem;
1270                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1271                         {
1272                             // why not flags & fl_item?
1273                                 if(otheritem.is_item)
1274                                 {
1275                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1276                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1277                                         error("Mapper sucks.");
1278                                 }
1279                         }
1280                         self.is_item = true;
1281                 }
1282
1283                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1284
1285                 precache_model (self.model);
1286                 precache_sound (self.item_pickupsound);
1287
1288                 precache_sound ("misc/itemrespawncountdown.wav");
1289                 if(itemid == IT_STRENGTH)
1290                         precache_sound ("misc/strength_respawn.wav");
1291                 else if(itemid == IT_INVINCIBLE)
1292                         precache_sound ("misc/shield_respawn.wav");
1293                 else
1294                         precache_sound ("misc/itemrespawn.wav");
1295
1296                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1297                         self.target = "###item###"; // for finding the nearest item using find()
1298
1299                 Item_ItemsTime_SetTime(self, 0);
1300         }
1301
1302         self.bot_pickup = true;
1303         self.bot_pickupevalfunc = pickupevalfunc;
1304         self.bot_pickupbasevalue = pickupbasevalue;
1305         self.mdl = self.model;
1306         self.netname = itemname;
1307         self.touch = Item_Touch;
1308         setmodel(self, "null"); // precision set below
1309         //self.effects |= EF_LOWPRECISION;
1310
1311         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1312     {
1313         self.pos1 = '-16 -16 0';
1314         self.pos2 = '16 16 48';
1315     }
1316         else
1317     {
1318         self.pos1 = '-16 -16 0';
1319         self.pos2 = '16 16 32';
1320     }
1321     setsize (self, self.pos1, self.pos2);
1322
1323     if(itemflags & FL_POWERUP)
1324         self.ItemStatus |= ITS_ANIMATE1;
1325
1326         if(self.armorvalue || self.health)
1327         self.ItemStatus |= ITS_ANIMATE2;
1328
1329         if(itemflags & FL_WEAPON)
1330         {
1331                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1332             self.colormap = 1024; // color shirt=0 pants=0 grey
1333         else
1334             self.gravity = 1;
1335
1336                 self.ItemStatus |= ITS_ANIMATE1;
1337                 self.ItemStatus |= ISF_COLORMAP;
1338         }
1339
1340         self.state = 0;
1341         if(self.team) // broken, no idea why.
1342         {
1343                 if(!self.cnt)
1344                         self.cnt = 1; // item probability weight
1345
1346                 self.effects |= EF_NODRAW; // marker for item team search
1347                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1348         }
1349         else
1350                 Item_Reset();
1351
1352     Net_LinkEntity(self, false, 0, ItemSend);
1353
1354         self.SendFlags |= ISF_SIZE;
1355         if(self.angles)
1356                 self.SendFlags |= ISF_ANGLES;
1357
1358         // call this hook after everything else has been done
1359         if(MUTATOR_CALLHOOK(Item_Spawn, self))
1360         {
1361                 startitem_failed = true;
1362                 remove(self);
1363                 return;
1364         }
1365 }
1366
1367 void StartItemA (entity a)
1368 {
1369     self.itemdef = a;
1370     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1371 }
1372
1373 void spawnfunc_item_rockets (void) {
1374         if(!self.ammo_rockets)
1375                 self.ammo_rockets = g_pickup_rockets;
1376         if(!self.pickup_anyway)
1377                 self.pickup_anyway = g_pickup_ammo_anyway;
1378     StartItemA (ITEM_Rockets);
1379 }
1380
1381 void spawnfunc_item_bullets (void) {
1382         if(!weaponswapping)
1383         if(autocvar_sv_q3acompat_machineshotgunswap)
1384         if(self.classname != "droppedweapon")
1385         {
1386                 weaponswapping = true;
1387                 spawnfunc_item_shells();
1388                 weaponswapping = false;
1389                 return;
1390         }
1391
1392         if(!self.ammo_nails)
1393                 self.ammo_nails = g_pickup_nails;
1394         if(!self.pickup_anyway)
1395                 self.pickup_anyway = g_pickup_ammo_anyway;
1396     StartItemA (ITEM_Bullets);
1397 }
1398
1399 void spawnfunc_item_cells (void) {
1400         if(!self.ammo_cells)
1401                 self.ammo_cells = g_pickup_cells;
1402         if(!self.pickup_anyway)
1403                 self.pickup_anyway = g_pickup_ammo_anyway;
1404         StartItemA (ITEM_Cells);
1405 }
1406
1407 void spawnfunc_item_plasma()
1408 {
1409         if(!self.ammo_plasma)
1410                 self.ammo_plasma = g_pickup_plasma;
1411         if(!self.pickup_anyway)
1412                 self.pickup_anyway = g_pickup_ammo_anyway;
1413         StartItemA (ITEM_Plasma);
1414 }
1415
1416 void spawnfunc_item_shells (void) {
1417         if(!weaponswapping)
1418         if(autocvar_sv_q3acompat_machineshotgunswap)
1419         if(self.classname != "droppedweapon")
1420         {
1421                 weaponswapping = true;
1422                 spawnfunc_item_bullets();
1423                 weaponswapping = false;
1424                 return;
1425         }
1426
1427         if(!self.ammo_shells)
1428                 self.ammo_shells = g_pickup_shells;
1429         if(!self.pickup_anyway)
1430                 self.pickup_anyway = g_pickup_ammo_anyway;
1431         StartItemA (ITEM_Shells);
1432 }
1433
1434 void spawnfunc_item_armor_small (void) {
1435         if(!self.armorvalue)
1436                 self.armorvalue = g_pickup_armorsmall;
1437         if(!self.max_armorvalue)
1438                 self.max_armorvalue = g_pickup_armorsmall_max;
1439         if(!self.pickup_anyway)
1440                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1441         StartItemA (ITEM_ArmorSmall);
1442 }
1443
1444 void spawnfunc_item_armor_medium (void) {
1445         if(!self.armorvalue)
1446                 self.armorvalue = g_pickup_armormedium;
1447         if(!self.max_armorvalue)
1448                 self.max_armorvalue = g_pickup_armormedium_max;
1449         if(!self.pickup_anyway)
1450                 self.pickup_anyway = g_pickup_armormedium_anyway;
1451         StartItemA (ITEM_ArmorMedium);
1452 }
1453
1454 void spawnfunc_item_armor_big (void) {
1455         if(!self.armorvalue)
1456                 self.armorvalue = g_pickup_armorbig;
1457         if(!self.max_armorvalue)
1458                 self.max_armorvalue = g_pickup_armorbig_max;
1459         if(!self.pickup_anyway)
1460                 self.pickup_anyway = g_pickup_armorbig_anyway;
1461         StartItemA (ITEM_ArmorBig);
1462 }
1463
1464 void spawnfunc_item_armor_large (void) {
1465         if(!self.armorvalue)
1466                 self.armorvalue = g_pickup_armorlarge;
1467         if(!self.max_armorvalue)
1468                 self.max_armorvalue = g_pickup_armorlarge_max;
1469         if(!self.pickup_anyway)
1470                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1471         StartItemA (ITEM_ArmorLarge);
1472 }
1473
1474 void spawnfunc_item_health_small (void) {
1475         if(!self.max_health)
1476                 self.max_health = g_pickup_healthsmall_max;
1477         if(!self.health)
1478                 self.health = g_pickup_healthsmall;
1479         if(!self.pickup_anyway)
1480                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1481         StartItemA (ITEM_HealthSmall);
1482 }
1483
1484 void spawnfunc_item_health_medium (void) {
1485         if(!self.max_health)
1486                 self.max_health = g_pickup_healthmedium_max;
1487         if(!self.health)
1488                 self.health = g_pickup_healthmedium;
1489         if(!self.pickup_anyway)
1490                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1491     StartItemA (ITEM_HealthMedium);
1492 }
1493
1494 void spawnfunc_item_health_large (void) {
1495         if(!self.max_health)
1496                 self.max_health = g_pickup_healthlarge_max;
1497         if(!self.health)
1498                 self.health = g_pickup_healthlarge;
1499         if(!self.pickup_anyway)
1500                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1501         StartItemA (ITEM_HealthLarge);
1502 }
1503
1504 void spawnfunc_item_health_mega (void) {
1505     if(!self.max_health)
1506         self.max_health = g_pickup_healthmega_max;
1507     if(!self.health)
1508         self.health = g_pickup_healthmega;
1509     if(!self.pickup_anyway)
1510         self.pickup_anyway = g_pickup_healthmega_anyway;
1511     StartItemA (ITEM_HealthMega);
1512 }
1513
1514 // support old misnamed entities
1515 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1516 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1517 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1518 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1519 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1520
1521 void spawnfunc_item_strength (void) {
1522                 precache_sound("weapons/strength_fire.wav");
1523                 if(!self.strength_finished)
1524                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1525                 StartItemA (ITEM_Strength);
1526 }
1527
1528 void spawnfunc_item_invincible (void) {
1529                 if(!self.invincible_finished)
1530                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1531                 StartItemA (ITEM_Shield);
1532 }
1533
1534 // compatibility:
1535 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1536
1537 void target_items_use (void)
1538 {
1539         if(activator.classname == "droppedweapon")
1540         {
1541                 EXACTTRIGGER_TOUCH;
1542                 remove(activator);
1543                 return;
1544         }
1545
1546         if (!IS_PLAYER(activator))
1547                 return;
1548         if(activator.deadflag != DEAD_NO)
1549                 return;
1550         EXACTTRIGGER_TOUCH;
1551
1552         entity e;
1553         for(e = world; (e = find(e, classname, "droppedweapon")); )
1554                 if(e.enemy == activator)
1555                         remove(e);
1556
1557         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1558                 centerprint(activator, self.message);
1559 }
1560
1561 void spawnfunc_target_items (void)
1562 {
1563         float n, i, j;
1564         entity e;
1565         string s;
1566
1567         self.use = target_items_use;
1568         if(!self.strength_finished)
1569                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1570         if(!self.invincible_finished)
1571                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1572         if(!self.superweapons_finished)
1573                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1574
1575         precache_sound("misc/itempickup.wav");
1576         precache_sound("misc/megahealth.wav");
1577         precache_sound("misc/armor25.wav");
1578         precache_sound("misc/powerup.wav");
1579         precache_sound("misc/poweroff.wav");
1580         precache_sound("weapons/weaponpickup.wav");
1581
1582         n = tokenize_console(self.netname);
1583         if(argv(0) == "give")
1584         {
1585                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1586         }
1587         else
1588         {
1589                 for(i = 0; i < n; ++i)
1590                 {
1591                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1592                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1593                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1594                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1595                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1596                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1597                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1598                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1599                         else
1600                         {
1601                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1602                                 {
1603                                         e = get_weaponinfo(j);
1604                                         s = W_UndeprecateName(argv(i));
1605                                         if(s == e.netname)
1606                                         {
1607                                                 self.weapons |= WepSet_FromWeapon(j);
1608                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1609                                                         WEP_ACTION(e.weapon, WR_INIT);
1610                                                 break;
1611                                         }
1612                                 }
1613                                 if(j > WEP_LAST)
1614                                         print("target_items: invalid item ", argv(i), "\n");
1615                         }
1616                 }
1617
1618                 string itemprefix, valueprefix;
1619                 if(self.spawnflags == 0)
1620                 {
1621                         itemprefix = "";
1622                         valueprefix = "";
1623                 }
1624                 else if(self.spawnflags == 1)
1625                 {
1626                         itemprefix = "max ";
1627                         valueprefix = "max ";
1628                 }
1629                 else if(self.spawnflags == 2)
1630                 {
1631                         itemprefix = "min ";
1632                         valueprefix = "min ";
1633                 }
1634                 else if(self.spawnflags == 4)
1635                 {
1636                         itemprefix = "minus ";
1637                         valueprefix = "max ";
1638                 }
1639                 else
1640                 {
1641                         error("invalid spawnflags");
1642                         itemprefix = valueprefix = string_null;
1643                 }
1644
1645                 self.netname = "";
1646                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1647                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1648                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1649                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1650                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1651                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1652                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1653                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1654                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1655                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1656                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1657                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1658                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1659                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1660                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1661                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1662                 {
1663                         e = get_weaponinfo(j);
1664                         if(e.weapon)
1665                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1666                 }
1667         }
1668         self.netname = strzone(self.netname);
1669         //print(self.netname, "\n");
1670
1671         n = tokenize_console(self.netname);
1672         for(i = 0; i < n; ++i)
1673         {
1674                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1675                 {
1676                         e = get_weaponinfo(j);
1677                         if(argv(i) == e.netname)
1678                         {
1679                                 WEP_ACTION(e.weapon, WR_INIT);
1680                                 break;
1681                         }
1682                 }
1683         }
1684 }
1685
1686 void spawnfunc_item_fuel(void)
1687 {
1688         if(!self.ammo_fuel)
1689                 self.ammo_fuel = g_pickup_fuel;
1690         if(!self.pickup_anyway)
1691                 self.pickup_anyway = g_pickup_ammo_anyway;
1692         StartItemA (ITEM_JetpackFuel);
1693 }
1694
1695 void spawnfunc_item_fuel_regen(void)
1696 {
1697         if(start_items & IT_FUEL_REGEN)
1698         {
1699                 spawnfunc_item_fuel();
1700                 return;
1701         }
1702         StartItemA (ITEM_JetpackRegen);
1703 }
1704
1705 void spawnfunc_item_jetpack(void)
1706 {
1707         if(!self.ammo_fuel)
1708                 self.ammo_fuel = g_pickup_fuel_jetpack;
1709         if(start_items & IT_JETPACK)
1710         {
1711                 spawnfunc_item_fuel();
1712                 return;
1713         }
1714         StartItemA (ITEM_Jetpack);
1715 }
1716
1717 float GiveWeapon(entity e, float wpn, float op, float val)
1718 {
1719         WepSet v0, v1;
1720         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1721         switch(op)
1722         {
1723                 case OP_SET:
1724                         if(val > 0)
1725                                 e.weapons |= WepSet_FromWeapon(wpn);
1726                         else
1727                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1728                         break;
1729                 case OP_MIN:
1730                 case OP_PLUS:
1731                         if(val > 0)
1732                                 e.weapons |= WepSet_FromWeapon(wpn);
1733                         break;
1734                 case OP_MAX:
1735                         if(val <= 0)
1736                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1737                         break;
1738                 case OP_MINUS:
1739                         if(val > 0)
1740                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1741                         break;
1742         }
1743         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1744         return (v0 != v1);
1745 }
1746
1747 float GiveBit(entity e, .float fld, float bit, float op, float val)
1748 {
1749         float v0, v1;
1750         v0 = (e.(fld) & bit);
1751         switch(op)
1752         {
1753                 case OP_SET:
1754                         if(val > 0)
1755                                 e.(fld) |= bit;
1756                         else
1757                                 e.(fld) &= ~bit;
1758                         break;
1759                 case OP_MIN:
1760                 case OP_PLUS:
1761                         if(val > 0)
1762                                 e.(fld) |= bit;
1763                         break;
1764                 case OP_MAX:
1765                         if(val <= 0)
1766                                 e.(fld) &= ~bit;
1767                         break;
1768                 case OP_MINUS:
1769                         if(val > 0)
1770                                 e.(fld) &= ~bit;
1771                         break;
1772         }
1773         v1 = (e.(fld) & bit);
1774         return (v0 != v1);
1775 }
1776
1777 float GiveValue(entity e, .float fld, float op, float val)
1778 {
1779         float v0, v1;
1780         v0 = e.(fld);
1781         switch(op)
1782         {
1783                 case OP_SET:
1784                         e.(fld) = val;
1785                         break;
1786                 case OP_MIN:
1787                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1788                         break;
1789                 case OP_MAX:
1790                         e.(fld) = min(e.(fld), val);
1791                         break;
1792                 case OP_PLUS:
1793                         e.(fld) += val;
1794                         break;
1795                 case OP_MINUS:
1796                         e.(fld) -= val;
1797                         break;
1798         }
1799         v1 = e.(fld);
1800         return (v0 != v1);
1801 }
1802
1803 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1804 {
1805         if(v1 == v0)
1806                 return;
1807         if(v1 <= v0 - t)
1808         {
1809                 if(snd_decr != "")
1810                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1811         }
1812         else if(v0 >= v0 + t)
1813         {
1814                 if(snd_incr != "")
1815                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1816         }
1817 }
1818
1819 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1820 {
1821         if(v0 < v1)
1822                 e.(rotfield) = max(e.(rotfield), time + rottime);
1823         else if(v0 > v1)
1824                 e.(regenfield) = max(e.(regenfield), time + regentime);
1825 }
1826 float GiveItems(entity e, float beginarg, float endarg)
1827 {
1828         float got, i, j, val, op;
1829         float _switchweapon;
1830         entity wi;
1831         string cmd;
1832
1833         val = 999;
1834         op = OP_SET;
1835
1836         got = 0;
1837
1838         _switchweapon = false;
1839         if (e.autoswitch)
1840                 if (e.switchweapon == w_getbestweapon(e))
1841                         _switchweapon = true;
1842
1843         e.strength_finished = max(0, e.strength_finished - time);
1844         e.invincible_finished = max(0, e.invincible_finished - time);
1845         e.superweapons_finished = max(0, e.superweapons_finished - time);
1846
1847         PREGIVE(e, items);
1848         PREGIVE_WEAPONS(e);
1849         PREGIVE(e, strength_finished);
1850         PREGIVE(e, invincible_finished);
1851         PREGIVE(e, superweapons_finished);
1852         PREGIVE(e, ammo_nails);
1853         PREGIVE(e, ammo_cells);
1854         PREGIVE(e, ammo_plasma);
1855         PREGIVE(e, ammo_shells);
1856         PREGIVE(e, ammo_rockets);
1857         PREGIVE(e, ammo_fuel);
1858         PREGIVE(e, armorvalue);
1859         PREGIVE(e, health);
1860
1861         for(i = beginarg; i < endarg; ++i)
1862         {
1863                 cmd = argv(i);
1864
1865                 if(cmd == "0" || stof(cmd))
1866                 {
1867                         val = stof(cmd);
1868                         continue;
1869                 }
1870                 switch(cmd)
1871                 {
1872                         case "no":
1873                                 op = OP_MAX;
1874                                 val = 0;
1875                                 continue;
1876                         case "max":
1877                                 op = OP_MAX;
1878                                 continue;
1879                         case "min":
1880                                 op = OP_MIN;
1881                                 continue;
1882                         case "plus":
1883                                 op = OP_PLUS;
1884                                 continue;
1885                         case "minus":
1886                                 op = OP_MINUS;
1887                                 continue;
1888                         case "ALL":
1889                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1890                                 got += GiveValue(e, strength_finished, op, val);
1891                                 got += GiveValue(e, invincible_finished, op, val);
1892                                 got += GiveValue(e, superweapons_finished, op, val);
1893                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1894                         case "all":
1895                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1896                                 got += GiveValue(e, health, op, val);
1897                                 got += GiveValue(e, armorvalue, op, val);
1898                         case "allweapons":
1899                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1900                                 {
1901                                         wi = get_weaponinfo(j);
1902                                         if(wi.weapon)
1903                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1904                                                         got += GiveWeapon(e, j, op, val);
1905                                 }
1906                         case "allammo":
1907                                 got += GiveValue(e, ammo_cells, op, val);
1908                                 got += GiveValue(e, ammo_plasma, op, val);
1909                                 got += GiveValue(e, ammo_shells, op, val);
1910                                 got += GiveValue(e, ammo_nails, op, val);
1911                                 got += GiveValue(e, ammo_rockets, op, val);
1912                                 got += GiveValue(e, ammo_fuel, op, val);
1913                                 break;
1914                         case "unlimited_ammo":
1915                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1916                                 break;
1917                         case "unlimited_weapon_ammo":
1918                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1919                                 break;
1920                         case "unlimited_superweapons":
1921                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1922                                 break;
1923                         case "jetpack":
1924                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1925                                 break;
1926                         case "fuel_regen":
1927                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1928                                 break;
1929                         case "strength":
1930                                 got += GiveValue(e, strength_finished, op, val);
1931                                 break;
1932                         case "invincible":
1933                                 got += GiveValue(e, invincible_finished, op, val);
1934                                 break;
1935                         case "superweapons":
1936                                 got += GiveValue(e, superweapons_finished, op, val);
1937                                 break;
1938                         case "cells":
1939                                 got += GiveValue(e, ammo_cells, op, val);
1940                                 break;
1941                         case "plasma":
1942                                 got += GiveValue(e, ammo_plasma, op, val);
1943                                 break;
1944                         case "shells":
1945                                 got += GiveValue(e, ammo_shells, op, val);
1946                                 break;
1947                         case "nails":
1948                         case "bullets":
1949                                 got += GiveValue(e, ammo_nails, op, val);
1950                                 break;
1951                         case "rockets":
1952                                 got += GiveValue(e, ammo_rockets, op, val);
1953                                 break;
1954                         case "health":
1955                                 got += GiveValue(e, health, op, val);
1956                                 break;
1957                         case "armor":
1958                                 got += GiveValue(e, armorvalue, op, val);
1959                                 break;
1960                         case "fuel":
1961                                 got += GiveValue(e, ammo_fuel, op, val);
1962                                 break;
1963                         default:
1964                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1965                                 {
1966                                         wi = get_weaponinfo(j);
1967                                         if(cmd == wi.netname)
1968                                         {
1969                                                 got += GiveWeapon(e, j, op, val);
1970                                                 break;
1971                                         }
1972                                 }
1973                                 if(j > WEP_LAST)
1974                                         print("give: invalid item ", cmd, "\n");
1975                                 break;
1976                 }
1977                 val = 999;
1978                 op = OP_SET;
1979         }
1980
1981         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1982         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1983         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1984         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1985         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1986         {
1987                 wi = get_weaponinfo(j);
1988                 if(wi.weapon)
1989                 {
1990                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1991                         if (!(save_weapons & WepSet_FromWeapon(j)))
1992                                 if(e.weapons & WepSet_FromWeapon(j))
1993                                         WEP_ACTION(wi.weapon, WR_INIT);
1994                 }
1995         }
1996         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1997         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1998         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1999         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2000         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
2001         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2002         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2003         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2004         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2005         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2006
2007         if(e.superweapons_finished <= 0)
2008                 if(self.weapons & WEPSET_SUPERWEAPONS)
2009                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2010
2011         if(e.strength_finished <= 0)
2012                 e.strength_finished = 0;
2013         else
2014                 e.strength_finished += time;
2015         if(e.invincible_finished <= 0)
2016                 e.invincible_finished = 0;
2017         else
2018                 e.invincible_finished += time;
2019         if(e.superweapons_finished <= 0)
2020                 e.superweapons_finished = 0;
2021         else
2022                 e.superweapons_finished += time;
2023
2024         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
2025                 _switchweapon = true;
2026         if(_switchweapon)
2027                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2028
2029         return got;
2030 }
2031 #endif