qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &= ~ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271 void ItemUpdate(entity item)
 272 {
 273         item.SendFlags |= ISF_LOCATION;
 274 }
 275
 276 float have_pickup_item(void)
 277 {
 278         if(self.flags & FL_POWERUP)
 279         {
 280                 if(autocvar_g_powerups > 0)
 281                         return TRUE;
 282                 if(autocvar_g_powerups == 0)
 283                         return FALSE;
 284         }
 285         else
 286         {
 287                 if(autocvar_g_pickup_items > 0)
 288                         return TRUE;
 289                 if(autocvar_g_pickup_items == 0)
 290                         return FALSE;
 291                 if(g_weaponarena)
 292                         if(self.weapons || (self.items & IT_AMMO))
 293                                 return FALSE;
 294         }
 295         return TRUE;
 296 }
 297
 298 #define ITEM_RESPAWN_TICKS 10
 299
 300 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 301         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 302 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 303         // range: 10 .. respawntime + respawntimejitter
 304
 305 floatfield Item_CounterField(float it)
 306 {
 307         switch(it)
 308         {
 309                 case IT_SHELLS:      return ammo_shells;
 310                 case IT_NAILS:       return ammo_nails;
 311                 case IT_ROCKETS:     return ammo_rockets;
 312                 case IT_CELLS:       return ammo_cells;
 313                 case IT_FUEL:        return ammo_fuel;
 314                 case IT_5HP:         return health;
 315                 case IT_25HP:        return health;
 316                 case IT_HEALTH:      return health;
 317                 case IT_ARMOR_SHARD: return armorvalue;
 318                 case IT_ARMOR:       return armorvalue;
 319                 // add more things here (health, armor)
 320                 default:             error("requested item has no counter field");
 321         }
 322 #ifdef GMQCC
 323         // should never happen
 324         return health;
 325 #endif
 326 }
 327
 328 string Item_CounterFieldName(float it)
 329 {
 330         switch(it)
 331         {
 332                 case IT_SHELLS:      return "shells";
 333                 case IT_NAILS:       return "nails";
 334                 case IT_ROCKETS:     return "rockets";
 335                 case IT_CELLS:       return "cells";
 336                 case IT_FUEL:        return "fuel";
 337
 338                 // add more things here (health, armor)
 339                 default:             error("requested item has no counter field name");
 340         }
 341 #ifdef GMQCC
 342         // should never happen
 343         return string_null;
 344 #endif
 345 }
 346
 347 .float max_armorvalue;
 348 .float pickup_anyway;
 349 /*
 350 float Item_Customize()
 351 {
 352         if(self.spawnshieldtime)
 353                 return TRUE;
 354         if(self.weapons & ~other.weapons)
 355         {
 356                 self.colormod = '0 0 0';
 357                 self.glowmod = self.colormod;
 358                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 359                 return TRUE;
 360         }
 361         else
 362         {
 363                 if(g_ghost_items)
 364                 {
 365                         self.colormod = stov(autocvar_g_ghost_items_color);
 366                         self.glowmod = self.colormod;
 367                         self.alpha = g_ghost_items;
 368                         return TRUE;
 369                 }
 370                 else
 371                         return FALSE;
 372         }
 373 }
 374 */
 375
 376 void Item_Show (entity e, float mode)
 377 {
 378         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 379         e.ItemStatus &= ~ITS_STAYWEP;
 380         if (mode > 0)
 381         {
 382                 // make the item look normal, and be touchable
 383                 e.model = e.mdl;
 384                 e.solid = SOLID_TRIGGER;
 385                 e.spawnshieldtime = 1;
 386                 e.ItemStatus |= ITS_AVAILABLE;
 387         }
 388         else if (mode < 0)
 389         {
 390                 // hide the item completely
 391                 e.model = string_null;
 392                 e.solid = SOLID_NOT;
 393                 e.spawnshieldtime = 1;
 394                 e.ItemStatus &= ~ITS_AVAILABLE;
 395         }
 396         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 397         {
 398                 // make the item translucent and not touchable
 399                 e.model = e.mdl;
 400                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 401                 e.effects |= EF_STARDUST;
 402                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 403                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 404         }
 405         else
 406         {
 407                 //setmodel(e, "null");
 408                 e.solid = SOLID_NOT;
 409                 e.colormod = '0 0 0';
 410                 e.glowmod = e.colormod;
 411                 e.spawnshieldtime = 1;
 412                 e.ItemStatus &= ~ITS_AVAILABLE;
 413         }
 414
 415         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 416             e.ItemStatus |= ITS_POWERUP;
 417
 418         if (autocvar_g_nodepthtestitems)
 419                 e.effects |= EF_NODEPTHTEST;
 420
 421
 422     if (autocvar_g_fullbrightitems)
 423                 e.ItemStatus |= ITS_ALLOWFB;
 424
 425         if (autocvar_sv_simple_items)
 426         e.ItemStatus |= ITS_ALLOWSI;
 427
 428         // relink entity (because solid may have changed)
 429         setorigin(e, e.origin);
 430     e.SendFlags |= ISF_STATUS;
 431 }
 432
 433 void Item_Respawn (void)
 434 {
 435         Item_Show(self, 1);
 436         // this is ugly...
 437         if(self.items == IT_STRENGTH)
 438                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 439         else if(self.items == IT_INVINCIBLE)
 440                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 441         else
 442                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 443         setorigin (self, self.origin);
 444
 445         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 446         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 447 }
 448
 449 void Item_RespawnCountdown (void)
 450 {
 451         if(self.count >= ITEM_RESPAWN_TICKS)
 452         {
 453                 if(self.waypointsprite_attached)
 454                         WaypointSprite_Kill(self.waypointsprite_attached);
 455                 Item_Respawn();
 456         }
 457         else
 458         {
 459                 self.nextthink = time + 1;
 460                 self.count += 1;
 461                 if(self.count == 1)
 462                 {
 463                         string name;
 464                         vector rgb = '1 0 1';
 465                         name = string_null;
 466                         switch(self.items)
 467                         {
 468                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 469                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 470                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 471                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 472                         }
 473                         item_name = name;
 474                         item_color = rgb;
 475                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 476                         name = item_name;
 477                         rgb = item_color;
 478                         if(self.flags & FL_WEAPON)
 479                         {
 480                                 entity wi = get_weaponinfo(self.weapon);
 481                                 if(wi)
 482                                 {
 483                                         name = wi.model2;
 484                                         rgb = '1 0 0';
 485                                 }
 486                         }
 487                         if(name)
 488                         {
 489                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 490                                 if(self.waypointsprite_attached)
 491                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 492                         }
 493                         else
 494                         {
 495                                 print("Unknown powerup-marked item is wanting to respawn\n");
 496                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 497                         }
 498                 }
 499                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 500                 if(self.waypointsprite_attached)
 501                 {
 502                         WaypointSprite_Ping(self.waypointsprite_attached);
 503                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 504                 }
 505         }
 506 }
 507
 508 void Item_ScheduleRespawnIn(entity e, float t)
 509 {
 510         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS))
 511         {
 512                 e.think = Item_RespawnCountdown;
 513                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 514                 e.count = 0;
 515         }
 516         else
 517         {
 518                 e.think = Item_Respawn;
 519                 e.nextthink = time + t;
 520         }
 521 }
 522
 523 void Item_ScheduleRespawn(entity e)
 524 {
 525         if(e.respawntime > 0)
 526         {
 527                 Item_Show(e, 0);
 528                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 529         }
 530         else // if respawntime is -1, this item does not respawn
 531                 Item_Show(e, -1);
 532 }
 533
 534 void Item_ScheduleInitialRespawn(entity e)
 535 {
 536         Item_Show(e, 0);
 537         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 538 }
 539
 540 const float ITEM_MODE_NONE = 0;
 541 const float ITEM_MODE_HEALTH = 1;
 542 const float ITEM_MODE_ARMOR = 2;
 543 const float ITEM_MODE_FUEL = 3;
 544 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 545 {
 546         if (!item.ammofield)
 547                 return FALSE;
 548
 549         if (item.spawnshieldtime)
 550         {
 551                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 552                 {
 553                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 554                         goto YEAH;
 555                 }
 556         }
 557         else if(g_weapon_stay == 2)
 558         {
 559                 float mi = min(item.ammofield, ammomax);
 560                 if (player.ammofield < mi)
 561                 {
 562                         player.ammofield = mi;
 563                         goto YEAH;
 564                 }
 565         }
 566
 567         return FALSE;
 568
 569 :YEAH
 570         switch(mode)
 571         {
 572                 case ITEM_MODE_FUEL:
 573                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 574                         break;
 575                 case ITEM_MODE_HEALTH:
 576                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 577                         break;
 578                 case ITEM_MODE_ARMOR:
 579                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 580                         break;
 581                 default:
 582                         break;
 583         }
 584         return TRUE;
 585 }
 586
 587 float Item_GiveTo(entity item, entity player)
 588 {
 589         float _switchweapon;
 590         float pickedup;
 591         float it;
 592         float i;
 593
 594         // if nothing happens to player, just return without taking the item
 595         pickedup = FALSE;
 596         _switchweapon = FALSE;
 597         // in case the player has autoswitch enabled do the following:
 598         // if the player is using their best weapon before items are given, they
 599         // probably want to switch to an even better weapon after items are given
 600         if (player.autoswitch)
 601         if (player.switchweapon == w_getbestweapon(player))
 602                 _switchweapon = TRUE;
 603
 604         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 605                 _switchweapon = TRUE;
 606
 607         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 608         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 609         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 610         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 611         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 612         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 613         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 614
 615         if (item.flags & FL_WEAPON)
 616         {
 617                 WepSet it;
 618                 it = item.weapons;
 619                 it &= ~player.weapons;
 620
 621                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 622                 {
 623                         pickedup = TRUE;
 624                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 625                         if(it & WepSet_FromWeapon(i))
 626                                 W_GiveWeapon(player, i);
 627                 }
 628         }
 629
 630         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 631         {
 632                 pickedup = TRUE;
 633                 player.items |= it;
 634                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 635         }
 636
 637         if (item.strength_finished)
 638         {
 639                 pickedup = TRUE;
 640                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 641         }
 642         if (item.invincible_finished)
 643         {
 644                 pickedup = TRUE;
 645                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 646         }
 647         if (item.superweapons_finished)
 648         {
 649                 pickedup = TRUE;
 650                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 651         }
 652
 653 :skip
 654
 655         // always eat teamed entities
 656         if(item.team)
 657                 pickedup = TRUE;
 658
 659         if (!pickedup)
 660                 return 0;
 661
 662         if (_switchweapon)
 663                 if (player.switchweapon != w_getbestweapon(player))
 664                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 665
 666         return 1;
 667 }
 668
 669 void Item_Touch (void)
 670 {
 671         entity e, head;
 672
 673         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 674         if(self.classname == "droppedweapon")
 675         {
 676                 if (ITEM_TOUCH_NEEDKILL())
 677                 {
 678                         remove(self);
 679                         return;
 680                 }
 681         }
 682
 683         if (!IS_PLAYER(other))
 684                 return;
 685         if (other.deadflag)
 686                 return;
 687         if (self.solid != SOLID_TRIGGER)
 688                 return;
 689         if (self.owner == other)
 690                 return;
 691         if (time < self.item_spawnshieldtime)
 692                 return;
 693
 694         switch(MUTATOR_CALLHOOK(ItemTouch))
 695         {
 696                 case MUT_ITEMTOUCH_RETURN: { return; }
 697                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 698         }
 699
 700         if (self.classname == "droppedweapon")
 701         {
 702                 self.strength_finished = max(0, self.strength_finished - time);
 703                 self.invincible_finished = max(0, self.invincible_finished - time);
 704                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 705         }
 706
 707         if(!Item_GiveTo(self, other))
 708         {
 709                 if (self.classname == "droppedweapon")
 710                 {
 711                         // undo what we did above
 712                         self.strength_finished += time;
 713                         self.invincible_finished += time;
 714                         self.superweapons_finished += time;
 715                 }
 716                 return;
 717         }
 718
 719         :pickup
 720
 721         other.last_pickup = time;
 722
 723         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 724         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 725
 726         if (self.classname == "droppedweapon")
 727                 remove (self);
 728         else if (!self.spawnshieldtime)
 729                 return;
 730         else
 731         {
 732                 if(self.team)
 733                 {
 734                         RandomSelection_Init();
 735                         for(head = world; (head = findfloat(head, team, self.team)); )
 736                         {
 737                                 if(head.flags & FL_ITEM)
 738                                 {
 739                                         Item_Show(head, -1);
 740                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 741                                 }
 742                         }
 743                         e = RandomSelection_chosen_ent;
 744
 745                 }
 746                 else
 747                         e = self;
 748                 Item_ScheduleRespawn(e);
 749         }
 750 }
 751
 752 void Item_Reset()
 753 {
 754         Item_Show(self, !self.state);
 755         setorigin (self, self.origin);
 756
 757         if(self.classname != "droppedweapon")
 758         {
 759                 self.think = func_null;
 760                 self.nextthink = 0;
 761
 762                 if(self.waypointsprite_attached)
 763                         WaypointSprite_Kill(self.waypointsprite_attached);
 764
 765                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 766                         Item_ScheduleInitialRespawn(self);
 767         }
 768 }
 769
 770 void Item_FindTeam()
 771 {
 772         entity head, e;
 773
 774         if(self.effects & EF_NODRAW)
 775         {
 776                 // marker for item team search
 777                 dprint("Initializing item team ", ftos(self.team), "\n");
 778                 RandomSelection_Init();
 779                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 780                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 781                 e = RandomSelection_chosen_ent;
 782                 e.state = 0;
 783                 Item_Show(e, 1);
 784
 785                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 786                 {
 787                         if(head != e)
 788                         {
 789                                 // make it a non-spawned item
 790                                 Item_Show(head, -1);
 791                                 head.state = 1; // state 1 = initially hidden item
 792                         }
 793                         head.effects &= ~EF_NODRAW;
 794                 }
 795
 796                 Item_Reset();
 797         }
 798 }
 799
 800 // Savage: used for item garbage-collection
 801 // TODO: perhaps nice special effect?
 802 void RemoveItem(void)
 803 {
 804         remove(self);
 805 }
 806
 807 // pickup evaluation functions
 808 // these functions decide how desirable an item is to the bots
 809
 810 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 811
 812 float weapon_pickupevalfunc(entity player, entity item)
 813 {
 814         float c, j, position;
 815
 816         // See if I have it already
 817         if(item.weapons & ~player.weapons)
 818         {
 819                 // If I can pick it up
 820                 if(!item.spawnshieldtime)
 821                         c = 0;
 822                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 823                 {
 824                         // Skilled bots will grab more
 825                         c = bound(0, skill / 10, 1) * 0.5;
 826                 }
 827                 else
 828                         c = 0;
 829         }
 830         else
 831                 c = 1;
 832
 833         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 834         if( bot_custom_weapon && c )
 835         {
 836                 // Find the highest position on any range
 837                 position = -1;
 838                 for(j = 0; j < WEP_LAST ; ++j){
 839                         if(
 840                                         bot_weapons_far[j] == item.weapon ||
 841                                         bot_weapons_mid[j] == item.weapon ||
 842                                         bot_weapons_close[j] == item.weapon
 843                           )
 844                         {
 845                                 position = j;
 846                                 break;
 847                         }
 848                 }
 849
 850                 // Rate it
 851                 if (position >= 0 )
 852                 {
 853                         position = WEP_LAST - position;
 854                         // item.bot_pickupbasevalue is overwritten here
 855                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 856                 }
 857         }
 858
 859         return item.bot_pickupbasevalue * c;
 860 }
 861
 862 float commodity_pickupevalfunc(entity player, entity item)
 863 {
 864         float c, i;
 865         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 866         entity wi;
 867         c = 0;
 868
 869         // Detect needed ammo
 870         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 871         {
 872                 wi = get_weaponinfo(i);
 873
 874                 if (!(player.weapons & WepSet_FromWeapon(i)))
 875                         continue;
 876
 877                 if(wi.items & IT_SHELLS)
 878                         need_shells = TRUE;
 879                 else if(wi.items & IT_NAILS)
 880                         need_nails = TRUE;
 881                 else if(wi.items & IT_ROCKETS)
 882                         need_rockets = TRUE;
 883                 else if(wi.items & IT_CELLS)
 884                         need_cells = TRUE;
 885                 else if(wi.items & IT_FUEL)
 886                         need_cells = TRUE;
 887         }
 888
 889         // TODO: figure out if the player even has the weapon this ammo is for?
 890         // may not affect strategy much though...
 891         // find out how much more ammo/armor/health the player can hold
 892         if (need_shells)
 893         if (item.ammo_shells)
 894         if (player.ammo_shells < g_pickup_shells_max)
 895                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 896         if (need_nails)
 897         if (item.ammo_nails)
 898         if (player.ammo_nails < g_pickup_nails_max)
 899                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 900         if (need_rockets)
 901         if (item.ammo_rockets)
 902         if (player.ammo_rockets < g_pickup_rockets_max)
 903                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 904         if (need_cells)
 905         if (item.ammo_cells)
 906         if (player.ammo_cells < g_pickup_cells_max)
 907                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 908         if (need_fuel)
 909         if (item.ammo_fuel)
 910         if (player.ammo_fuel < g_pickup_fuel_max)
 911                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 912         if (item.armorvalue)
 913         if (player.armorvalue < item.max_armorvalue)
 914                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 915         if (item.health)
 916         if (player.health < item.max_health)
 917                 c = c + max(0, 1 - player.health / item.max_health);
 918
 919         return item.bot_pickupbasevalue * c;
 920 }
 921
 922 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 923 {
 924         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 925                 RemoveItem();
 926 }
 927
 928 .float is_item;
 929 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 930 {
 931         startitem_failed = FALSE;
 932
 933         if(self.model == "")
 934                 self.model = itemmodel;
 935
 936         if(self.model == "")
 937     {
 938         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 939         return;
 940     }
 941
 942         if(self.item_pickupsound == "")
 943                 self.item_pickupsound = pickupsound;
 944
 945         if(!self.respawntime) // both need to be set
 946         {
 947                 self.respawntime = defaultrespawntime;
 948                 self.respawntimejitter = defaultrespawntimejitter;
 949         }
 950
 951         self.items = itemid;
 952         self.weapon = weaponid;
 953
 954         if(weaponid)
 955                 self.weapons = WepSet_FromWeapon(weaponid);
 956
 957         self.flags = FL_ITEM | itemflags;
 958
 959         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 960         {
 961                 startitem_failed = TRUE;
 962                 remove(self);
 963                 return;
 964         }
 965
 966         // is it a dropped weapon?
 967         if (self.classname == "droppedweapon")
 968         {
 969                 self.reset = SUB_Remove;
 970                 // it's a dropped weapon
 971                 self.movetype = MOVETYPE_TOSS;
 972
 973                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 974                 self.think = RemoveItem;
 975                 self.nextthink = time + 20;
 976
 977                 self.takedamage = DAMAGE_YES;
 978                 self.event_damage = Item_Damage;
 979
 980                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 981                 /*
 982                 if(self.items == 0)
 983                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
 984                 if(self.ammo_nails == 0)
 985                 if(self.ammo_cells == 0)
 986                 if(self.ammo_rockets == 0)
 987                 if(self.ammo_shells == 0)
 988                 if(self.ammo_fuel == 0)
 989                 if(self.health == 0)
 990                 if(self.armorvalue == 0)
 991                 */
 992                 {
 993                         // if item is worthless after a timer, have it expire then
 994                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 995                 }
 996
 997                 // don't drop if in a NODROP zone (such as lava)
 998                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 999                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1000                 {
1001                         startitem_failed = TRUE;
1002                         remove(self);
1003                         return;
1004                 }
1005         }
1006         else
1007         {
1008                 if(!have_pickup_item())
1009                 {
1010                         startitem_failed = TRUE;
1011                         remove (self);
1012                         return;
1013                 }
1014
1015                 if(self.angles != '0 0 0')
1016             self.SendFlags |= ISF_ANGLES;
1017
1018                 self.reset = Item_Reset;
1019                 // it's a level item
1020                 if(self.spawnflags & 1)
1021                         self.noalign = 1;
1022                 if (self.noalign)
1023                         self.movetype = MOVETYPE_NONE;
1024                 else
1025                         self.movetype = MOVETYPE_TOSS;
1026                 // do item filtering according to game mode and other things
1027                 if (!self.noalign)
1028                 {
1029                         // first nudge it off the floor a little bit to avoid math errors
1030                         setorigin(self, self.origin + '0 0 1');
1031                         // set item size before we spawn a spawnfunc_waypoint
1032                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1033                                 setsize (self, '-16 -16 0', '16 16 48');
1034                         else
1035                                 setsize (self, '-16 -16 0', '16 16 32');
1036                         // note droptofloor returns FALSE if stuck/or would fall too far
1037                         droptofloor();
1038                         waypoint_spawnforitem(self);
1039                 }
1040
1041                 /*
1042                  * can't do it that way, as it would break maps
1043                  * TODO make a target_give like entity another way, that perhaps has
1044                  * the weapon name in a key
1045                 if(self.targetname)
1046                 {
1047                         // target_give not yet supported; maybe later
1048                         print("removed targeted ", self.classname, "\n");
1049                         startitem_failed = TRUE;
1050                         remove (self);
1051                         return;
1052                 }
1053                 */
1054
1055                 if(autocvar_spawn_debug >= 2)
1056                 {
1057                         entity otheritem;
1058                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1059                         {
1060                             // why not flags & fl_item?
1061                                 if(otheritem.is_item)
1062                                 {
1063                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1064                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1065                                         error("Mapper sucks.");
1066                                 }
1067                         }
1068                         self.is_item = TRUE;
1069                 }
1070
1071                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1072
1073                 precache_model (self.model);
1074                 precache_sound (self.item_pickupsound);
1075
1076                 precache_sound ("misc/itemrespawncountdown.wav");
1077                 if(itemid == IT_STRENGTH)
1078                         precache_sound ("misc/strength_respawn.wav");
1079                 else if(itemid == IT_INVINCIBLE)
1080                         precache_sound ("misc/shield_respawn.wav");
1081                 else
1082                         precache_sound ("misc/itemrespawn.wav");
1083
1084                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1085                         self.target = "###item###"; // for finding the nearest item using find()
1086         }
1087
1088         self.bot_pickup = TRUE;
1089         self.bot_pickupevalfunc = pickupevalfunc;
1090         self.bot_pickupbasevalue = pickupbasevalue;
1091         self.mdl = self.model;
1092         self.netname = itemname;
1093         self.touch = Item_Touch;
1094         setmodel(self, "null"); // precision set below
1095         //self.effects |= EF_LOWPRECISION;
1096
1097         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1098     {
1099         self.pos1 = '-16 -16 0';
1100         self.pos2 = '16 16 48';
1101     }
1102         else
1103     {
1104         self.pos1 = '-16 -16 0';
1105         self.pos2 = '16 16 32';
1106     }
1107     setsize (self, self.pos1, self.pos2);
1108
1109     if(itemflags & FL_POWERUP)
1110         self.ItemStatus |= ITS_ANIMATE1;
1111
1112         if(self.armorvalue || self.health)
1113         self.ItemStatus |= ITS_ANIMATE2;
1114
1115         if(itemflags & FL_WEAPON)
1116         {
1117                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1118             self.colormap = 1024; // color shirt=0 pants=0 grey
1119         else
1120             self.gravity = 1;
1121
1122                 self.ItemStatus |= ITS_ANIMATE1;
1123                 self.ItemStatus |= ISF_COLORMAP;
1124         }
1125
1126         self.state = 0;
1127         if(self.team) // broken, no idea why.
1128         {
1129                 if(!self.cnt)
1130                         self.cnt = 1; // item probability weight
1131
1132                 self.effects |= EF_NODRAW; // marker for item team search
1133                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1134         }
1135         else
1136                 Item_Reset();
1137
1138     Net_LinkEntity(self, FALSE, 0, ItemSend);
1139
1140         // call this hook after everything else has been done
1141         if(MUTATOR_CALLHOOK(Item_Spawn))
1142         {
1143                 startitem_failed = TRUE;
1144                 remove(self);
1145                 return;
1146         }
1147 }
1148
1149 float weaponswapping;
1150 float internalteam;
1151
1152 void weapon_defaultspawnfunc(float wpn)
1153 {
1154         entity e;
1155         float t;
1156         var .float ammofield;
1157         string s;
1158         entity oldself;
1159         float i, j;
1160         float f;
1161
1162         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1163         {
1164                 e = get_weaponinfo(wpn);
1165
1166                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1167                 {
1168                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1169                         startitem_failed = TRUE;
1170                         return;
1171                 }
1172
1173                 s = W_Apply_Weaponreplace(e.netname);
1174                 ret_string = s;
1175                 other = e;
1176                 MUTATOR_CALLHOOK(SetWeaponreplace);
1177                 s = ret_string;
1178                 if(s == "")
1179                 {
1180                         remove(self);
1181                         startitem_failed = TRUE;
1182                         return;
1183                 }
1184                 t = tokenize_console(s);
1185                 if(t >= 2)
1186                 {
1187                         self.team = --internalteam;
1188                         oldself = self;
1189                         for(i = 1; i < t; ++i)
1190                         {
1191                                 s = argv(i);
1192                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1193                                 {
1194                                         e = get_weaponinfo(j);
1195                                         if(e.netname == s)
1196                                         {
1197                                                 self = spawn();
1198                                                 copyentity(oldself, self);
1199                                                 self.classname = "replacedweapon";
1200                                                 weapon_defaultspawnfunc(j);
1201                                                 break;
1202                                         }
1203                                 }
1204                                 if(j > WEP_LAST)
1205                                 {
1206                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1207                                 }
1208                         }
1209                         self = oldself;
1210                 }
1211                 if(t >= 1) // always the case!
1212                 {
1213                         s = argv(0);
1214                         wpn = 0;
1215                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1216                         {
1217                                 e = get_weaponinfo(j);
1218                                 if(e.netname == s)
1219                                 {
1220                                         wpn = j;
1221                                         break;
1222                                 }
1223                         }
1224                         if(j > WEP_LAST)
1225                         {
1226                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1227                         }
1228                 }
1229                 if(wpn == 0)
1230                 {
1231                         remove(self);
1232                         startitem_failed = TRUE;
1233                         return;
1234                 }
1235         }
1236
1237         e = get_weaponinfo(wpn);
1238
1239         if(!self.respawntime)
1240         {
1241                 if(e.weapons & WEPSET_SUPERWEAPONS)
1242                 {
1243                         self.respawntime = g_pickup_respawntime_superweapon;
1244                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1245                 }
1246                 else
1247                 {
1248                         self.respawntime = g_pickup_respawntime_weapon;
1249                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1250                 }
1251         }
1252
1253         if(e.weapons & WEPSET_SUPERWEAPONS)
1254                 if(!self.superweapons_finished)
1255                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1256
1257         if(e.items)
1258         {
1259                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1260                 {
1261                         if(e.items & j)
1262                         {
1263                                 ammofield = Item_CounterField(j);
1264                                 if(!self.ammofield)
1265                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1266                         }
1267                 }
1268         }
1269
1270         // pickup anyway
1271         if(g_pickup_weapons_anyway)
1272                 self.pickup_anyway = TRUE;
1273
1274         f = FL_WEAPON;
1275
1276         // no weapon-stay on superweapons
1277         if(e.weapons & WEPSET_SUPERWEAPONS)
1278                 f |= FL_NO_WEAPON_STAY;
1279
1280         // weapon stay isn't supported for teamed weapons
1281         if(self.team)
1282                 f |= FL_NO_WEAPON_STAY;
1283
1284         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1285         if (self.modelindex) // don't precache if self was removed
1286                 weapon_action(e.weapon, WR_PRECACHE);
1287 }
1288
1289 void spawnfunc_weapon_shotgun (void);
1290 void spawnfunc_weapon_uzi (void) {
1291         if(autocvar_sv_q3acompat_machineshotgunswap)
1292         if(self.classname != "droppedweapon")
1293         {
1294                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1295                 return;
1296         }
1297         weapon_defaultspawnfunc(WEP_UZI);
1298 }
1299
1300 void spawnfunc_weapon_shotgun (void) {
1301         if(autocvar_sv_q3acompat_machineshotgunswap)
1302         if(self.classname != "droppedweapon")
1303         {
1304                 weapon_defaultspawnfunc(WEP_UZI);
1305                 return;
1306         }
1307         weapon_defaultspawnfunc(WEP_SHOTGUN);
1308 }
1309
1310 void spawnfunc_weapon_nex (void)
1311 {
1312         weapon_defaultspawnfunc(WEP_NEX);
1313 }
1314
1315 void spawnfunc_weapon_minstanex (void)
1316 {
1317         weapon_defaultspawnfunc(WEP_MINSTANEX);
1318 }
1319
1320 void spawnfunc_weapon_rocketlauncher (void)
1321 {
1322         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1323 }
1324
1325 void spawnfunc_item_rockets (void) {
1326         if(!self.ammo_rockets)
1327                 self.ammo_rockets = g_pickup_rockets;
1328         if(!self.pickup_anyway)
1329                 self.pickup_anyway = g_pickup_ammo_anyway;
1330         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1331 }
1332
1333 void spawnfunc_item_shells (void);
1334 void spawnfunc_item_bullets (void) {
1335         if(!weaponswapping)
1336         if(autocvar_sv_q3acompat_machineshotgunswap)
1337         if(self.classname != "droppedweapon")
1338         {
1339                 weaponswapping = TRUE;
1340                 spawnfunc_item_shells();
1341                 weaponswapping = FALSE;
1342                 return;
1343         }
1344
1345         if(!self.ammo_nails)
1346                 self.ammo_nails = g_pickup_nails;
1347         if(!self.pickup_anyway)
1348                 self.pickup_anyway = g_pickup_ammo_anyway;
1349         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1350 }
1351
1352 void spawnfunc_item_cells (void) {
1353         if(!self.ammo_cells)
1354                 self.ammo_cells = g_pickup_cells;
1355         if(!self.pickup_anyway)
1356                 self.pickup_anyway = g_pickup_ammo_anyway;
1357         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1358 }
1359
1360 void spawnfunc_item_shells (void) {
1361         if(!weaponswapping)
1362         if(autocvar_sv_q3acompat_machineshotgunswap)
1363         if(self.classname != "droppedweapon")
1364         {
1365                 weaponswapping = TRUE;
1366                 spawnfunc_item_bullets();
1367                 weaponswapping = FALSE;
1368                 return;
1369         }
1370
1371         if(!self.ammo_shells)
1372                 self.ammo_shells = g_pickup_shells;
1373         if(!self.pickup_anyway)
1374                 self.pickup_anyway = g_pickup_ammo_anyway;
1375         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1376 }
1377
1378 void spawnfunc_item_armor_small (void) {
1379         if(!self.armorvalue)
1380                 self.armorvalue = g_pickup_armorsmall;
1381         if(!self.max_armorvalue)
1382                 self.max_armorvalue = g_pickup_armorsmall_max;
1383         if(!self.pickup_anyway)
1384                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1385         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1386 }
1387
1388 void spawnfunc_item_armor_medium (void) {
1389         if(!self.armorvalue)
1390                 self.armorvalue = g_pickup_armormedium;
1391         if(!self.max_armorvalue)
1392                 self.max_armorvalue = g_pickup_armormedium_max;
1393         if(!self.pickup_anyway)
1394                 self.pickup_anyway = g_pickup_armormedium_anyway;
1395         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1396 }
1397
1398 void spawnfunc_item_armor_big (void) {
1399         if(!self.armorvalue)
1400                 self.armorvalue = g_pickup_armorbig;
1401         if(!self.max_armorvalue)
1402                 self.max_armorvalue = g_pickup_armorbig_max;
1403         if(!self.pickup_anyway)
1404                 self.pickup_anyway = g_pickup_armorbig_anyway;
1405         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1406 }
1407
1408 void spawnfunc_item_armor_large (void) {
1409         if(!self.armorvalue)
1410                 self.armorvalue = g_pickup_armorlarge;
1411         if(!self.max_armorvalue)
1412                 self.max_armorvalue = g_pickup_armorlarge_max;
1413         if(!self.pickup_anyway)
1414                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1415         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1416 }
1417
1418 void spawnfunc_item_health_small (void) {
1419         if(!self.max_health)
1420                 self.max_health = g_pickup_healthsmall_max;
1421         if(!self.health)
1422                 self.health = g_pickup_healthsmall;
1423         if(!self.pickup_anyway)
1424                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1425         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1426 }
1427
1428 void spawnfunc_item_health_medium (void) {
1429         if(!self.max_health)
1430                 self.max_health = g_pickup_healthmedium_max;
1431         if(!self.health)
1432                 self.health = g_pickup_healthmedium;
1433         if(!self.pickup_anyway)
1434                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1435         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1436 }
1437
1438 void spawnfunc_item_health_large (void) {
1439         if(!self.max_health)
1440                 self.max_health = g_pickup_healthlarge_max;
1441         if(!self.health)
1442                 self.health = g_pickup_healthlarge;
1443         if(!self.pickup_anyway)
1444                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1445         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1446 }
1447
1448 void spawnfunc_item_health_mega (void) {
1449                 if(!self.max_health)
1450                         self.max_health = g_pickup_healthmega_max;
1451                 if(!self.health)
1452                         self.health = g_pickup_healthmega;
1453                 if(!self.pickup_anyway)
1454                         self.pickup_anyway = g_pickup_healthmega_anyway;
1455                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1456 }
1457
1458 // support old misnamed entities
1459 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1460 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1461 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1462 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1463 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1464
1465 void spawnfunc_item_strength (void) {
1466                 precache_sound("weapons/strength_fire.wav");
1467                 if(!self.strength_finished)
1468                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1469                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1470 }
1471
1472 void spawnfunc_item_invincible (void) {
1473                 if(!self.invincible_finished)
1474                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1475                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1476 }
1477
1478 // compatibility:
1479 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1480
1481 float GiveItems(entity e, float beginarg, float endarg);
1482 void target_items_use (void)
1483 {
1484         if(activator.classname == "droppedweapon")
1485         {
1486                 EXACTTRIGGER_TOUCH;
1487                 remove(activator);
1488                 return;
1489         }
1490
1491         if (!IS_PLAYER(activator))
1492                 return;
1493         if(activator.deadflag != DEAD_NO)
1494                 return;
1495         EXACTTRIGGER_TOUCH;
1496
1497         entity e;
1498         for(e = world; (e = find(e, classname, "droppedweapon")); )
1499                 if(e.enemy == activator)
1500                         remove(e);
1501
1502         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1503                 centerprint(activator, self.message);
1504 }
1505
1506 void spawnfunc_target_items (void)
1507 {
1508         float n, i, j;
1509         entity e;
1510
1511         self.use = target_items_use;
1512         if(!self.strength_finished)
1513                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1514         if(!self.invincible_finished)
1515                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1516         if(!self.superweapons_finished)
1517                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1518
1519         precache_sound("misc/itempickup.wav");
1520         precache_sound("misc/megahealth.wav");
1521         precache_sound("misc/armor25.wav");
1522         precache_sound("misc/powerup.wav");
1523         precache_sound("misc/poweroff.wav");
1524         precache_sound("weapons/weaponpickup.wav");
1525
1526         n = tokenize_console(self.netname);
1527         if(argv(0) == "give")
1528         {
1529                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1530         }
1531         else
1532         {
1533                 for(i = 0; i < n; ++i)
1534                 {
1535                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1536                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1537                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1538                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1539                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1540                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1541                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1542                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1543                         else
1544                         {
1545                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1546                                 {
1547                                         e = get_weaponinfo(j);
1548                                         if(argv(i) == e.netname)
1549                                         {
1550                                                 self.weapons |= WepSet_FromWeapon(j);
1551                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1552                                                         weapon_action(e.weapon, WR_PRECACHE);
1553                                                 break;
1554                                         }
1555                                 }
1556                                 if(j > WEP_LAST)
1557                                         print("target_items: invalid item ", argv(i), "\n");
1558                         }
1559                 }
1560
1561                 string itemprefix, valueprefix;
1562                 if(self.spawnflags == 0)
1563                 {
1564                         itemprefix = "";
1565                         valueprefix = "";
1566                 }
1567                 else if(self.spawnflags == 1)
1568                 {
1569                         itemprefix = "max ";
1570                         valueprefix = "max ";
1571                 }
1572                 else if(self.spawnflags == 2)
1573                 {
1574                         itemprefix = "min ";
1575                         valueprefix = "min ";
1576                 }
1577                 else if(self.spawnflags == 4)
1578                 {
1579                         itemprefix = "minus ";
1580                         valueprefix = "max ";
1581                 }
1582                 else
1583                 {
1584                         error("invalid spawnflags");
1585 #ifdef GMQCC
1586                         itemprefix = string_null;
1587                         valueprefix = string_null;
1588 #endif
1589                 }
1590
1591                 self.netname = "";
1592                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1593                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1594                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1595                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1596                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1597                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1598                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1599                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1600                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1601                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1602                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1603                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1604                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1605                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1606                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1607                 {
1608                         e = get_weaponinfo(j);
1609                         if(e.weapon)
1610                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1611                 }
1612         }
1613         self.netname = strzone(self.netname);
1614         //print(self.netname, "\n");
1615
1616         n = tokenize_console(self.netname);
1617         for(i = 0; i < n; ++i)
1618         {
1619                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1620                 {
1621                         e = get_weaponinfo(j);
1622                         if(argv(i) == e.netname)
1623                         {
1624                                 weapon_action(e.weapon, WR_PRECACHE);
1625                                 break;
1626                         }
1627                 }
1628         }
1629 }
1630
1631 void spawnfunc_item_fuel(void)
1632 {
1633         if(!self.ammo_fuel)
1634                 self.ammo_fuel = g_pickup_fuel;
1635         if(!self.pickup_anyway)
1636                 self.pickup_anyway = g_pickup_ammo_anyway;
1637         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1638 }
1639
1640 void spawnfunc_item_fuel_regen(void)
1641 {
1642         if(start_items & IT_FUEL_REGEN)
1643         {
1644                 spawnfunc_item_fuel();
1645                 return;
1646         }
1647         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1648 }
1649
1650 void spawnfunc_item_jetpack(void)
1651 {
1652         if(g_grappling_hook)
1653                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1654         if(!self.ammo_fuel)
1655                 self.ammo_fuel = g_pickup_fuel_jetpack;
1656         if(start_items & IT_JETPACK)
1657         {
1658                 spawnfunc_item_fuel();
1659                 return;
1660         }
1661         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1662 }
1663
1664
1665 #define OP_SET 0
1666 #define OP_MIN 1
1667 #define OP_MAX 2
1668 #define OP_PLUS 3
1669 #define OP_MINUS 4
1670
1671 float GiveWeapon(entity e, float wpn, float op, float val)
1672 {
1673         WepSet v0, v1;
1674         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1675         switch(op)
1676         {
1677                 case OP_SET:
1678                         if(val > 0)
1679                                 e.weapons |= WepSet_FromWeapon(wpn);
1680                         else
1681                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1682                         break;
1683                 case OP_MIN:
1684                 case OP_PLUS:
1685                         if(val > 0)
1686                                 e.weapons |= WepSet_FromWeapon(wpn);
1687                         break;
1688                 case OP_MAX:
1689                         if(val <= 0)
1690                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1691                         break;
1692                 case OP_MINUS:
1693                         if(val > 0)
1694                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1695                         break;
1696         }
1697         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1698         return (v0 != v1);
1699 }
1700
1701 float GiveBit(entity e, .float fld, float bit, float op, float val)
1702 {
1703         float v0, v1;
1704         v0 = (e.fld & bit);
1705         switch(op)
1706         {
1707                 case OP_SET:
1708                         if(val > 0)
1709                                 e.fld |= bit;
1710                         else
1711                                 e.fld &= ~bit;
1712                         break;
1713                 case OP_MIN:
1714                 case OP_PLUS:
1715                         if(val > 0)
1716                                 e.fld |= bit;
1717                         break;
1718                 case OP_MAX:
1719                         if(val <= 0)
1720                                 e.fld &= ~bit;
1721                         break;
1722                 case OP_MINUS:
1723                         if(val > 0)
1724                                 e.fld &= ~bit;
1725                         break;
1726         }
1727         v1 = (e.fld & bit);
1728         return (v0 != v1);
1729 }
1730
1731 float GiveValue(entity e, .float fld, float op, float val)
1732 {
1733         float v0, v1;
1734         v0 = e.fld;
1735         switch(op)
1736         {
1737                 case OP_SET:
1738                         e.fld = val;
1739                         break;
1740                 case OP_MIN:
1741                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1742                         break;
1743                 case OP_MAX:
1744                         e.fld = min(e.fld, val);
1745                         break;
1746                 case OP_PLUS:
1747                         e.fld += val;
1748                         break;
1749                 case OP_MINUS:
1750                         e.fld -= val;
1751                         break;
1752         }
1753         v1 = e.fld;
1754         return (v0 != v1);
1755 }
1756
1757 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1758 {
1759         if(v1 == v0)
1760                 return;
1761         if(v1 <= v0 - t)
1762         {
1763                 if(snd_decr != "")
1764                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1765         }
1766         else if(v0 >= v0 + t)
1767         {
1768                 if(snd_incr != "")
1769                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1770         }
1771 }
1772
1773 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1774 {
1775         if(v0 < v1)
1776                 e.rotfield = max(e.rotfield, time + rottime);
1777         else if(v0 > v1)
1778                 e.regenfield = max(e.regenfield, time + regentime);
1779 }
1780
1781 #define PREGIVE_WEAPONS(e) WepSet save_weapons; save_weapons = e.weapons
1782 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1783 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), !!(save_weapons & WepSet_FromWeapon(b)), !!(e.weapons & WepSet_FromWeapon(b)), 0, snd_incr, snd_decr)
1784 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1785 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1786 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1787
1788 float GiveItems(entity e, float beginarg, float endarg)
1789 {
1790         float got, i, j, val, op;
1791         float _switchweapon;
1792         entity wi;
1793         string cmd;
1794
1795         val = 999;
1796         op = OP_SET;
1797
1798         got = 0;
1799
1800         _switchweapon = FALSE;
1801         if (e.autoswitch)
1802                 if (e.switchweapon == w_getbestweapon(e))
1803                         _switchweapon = TRUE;
1804
1805         e.strength_finished = max(0, e.strength_finished - time);
1806         e.invincible_finished = max(0, e.invincible_finished - time);
1807         e.superweapons_finished = max(0, e.superweapons_finished - time);
1808
1809         PREGIVE(e, items);
1810         PREGIVE_WEAPONS(e);
1811         PREGIVE(e, strength_finished);
1812         PREGIVE(e, invincible_finished);
1813         PREGIVE(e, superweapons_finished);
1814         PREGIVE(e, ammo_nails);
1815         PREGIVE(e, ammo_cells);
1816         PREGIVE(e, ammo_shells);
1817         PREGIVE(e, ammo_rockets);
1818         PREGIVE(e, ammo_fuel);
1819         PREGIVE(e, armorvalue);
1820         PREGIVE(e, health);
1821
1822         for(i = beginarg; i < endarg; ++i)
1823         {
1824                 cmd = argv(i);
1825
1826                 if(cmd == "0" || stof(cmd))
1827                 {
1828                         val = stof(cmd);
1829                         continue;
1830                 }
1831                 switch(cmd)
1832                 {
1833                         case "no":
1834                                 op = OP_MAX;
1835                                 val = 0;
1836                                 continue;
1837                         case "max":
1838                                 op = OP_MAX;
1839                                 continue;
1840                         case "min":
1841                                 op = OP_MIN;
1842                                 continue;
1843                         case "plus":
1844                                 op = OP_PLUS;
1845                                 continue;
1846                         case "minus":
1847                                 op = OP_MINUS;
1848                                 continue;
1849                         case "ALL":
1850                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1851                                 got += GiveValue(e, strength_finished, op, val);
1852                                 got += GiveValue(e, invincible_finished, op, val);
1853                                 got += GiveValue(e, superweapons_finished, op, val);
1854                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1855                         case "all":
1856                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1857                                 got += GiveValue(e, health, op, val);
1858                                 got += GiveValue(e, armorvalue, op, val);
1859                         case "allweapons":
1860                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1861                                 {
1862                                         wi = get_weaponinfo(j);
1863                                         if(wi.weapon)
1864                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1865                                                         got += GiveWeapon(e, j, op, val);
1866                                 }
1867                         case "allammo":
1868                                 got += GiveValue(e, ammo_cells, op, val);
1869                                 got += GiveValue(e, ammo_shells, op, val);
1870                                 got += GiveValue(e, ammo_nails, op, val);
1871                                 got += GiveValue(e, ammo_rockets, op, val);
1872                                 got += GiveValue(e, ammo_fuel, op, val);
1873                                 break;
1874                         case "unlimited_ammo":
1875                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1876                                 break;
1877                         case "unlimited_weapon_ammo":
1878                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1879                                 break;
1880                         case "unlimited_superweapons":
1881                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1882                                 break;
1883                         case "jetpack":
1884                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1885                                 break;
1886                         case "fuel_regen":
1887                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1888                                 break;
1889                         case "strength":
1890                                 got += GiveValue(e, strength_finished, op, val);
1891                                 break;
1892                         case "invincible":
1893                                 got += GiveValue(e, invincible_finished, op, val);
1894                                 break;
1895                         case "superweapons":
1896                                 got += GiveValue(e, superweapons_finished, op, val);
1897                                 break;
1898                         case "cells":
1899                                 got += GiveValue(e, ammo_cells, op, val);
1900                                 break;
1901                         case "shells":
1902                                 got += GiveValue(e, ammo_shells, op, val);
1903                                 break;
1904                         case "nails":
1905                         case "bullets":
1906                                 got += GiveValue(e, ammo_nails, op, val);
1907                                 break;
1908                         case "rockets":
1909                                 got += GiveValue(e, ammo_rockets, op, val);
1910                                 break;
1911                         case "health":
1912                                 got += GiveValue(e, health, op, val);
1913                                 break;
1914                         case "armor":
1915                                 got += GiveValue(e, armorvalue, op, val);
1916                                 break;
1917                         case "fuel":
1918                                 got += GiveValue(e, ammo_fuel, op, val);
1919                                 break;
1920                         default:
1921                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1922                                 {
1923                                         wi = get_weaponinfo(j);
1924                                         if(cmd == wi.netname)
1925                                         {
1926                                                 got += GiveWeapon(e, j, op, val);
1927                                                 break;
1928                                         }
1929                                 }
1930                                 if(j > WEP_LAST)
1931                                         print("give: invalid item ", cmd, "\n");
1932                                 break;
1933                 }
1934                 val = 999;
1935                 op = OP_SET;
1936         }
1937
1938         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1939         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1940         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1941         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1942         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1943         {
1944                 wi = get_weaponinfo(j);
1945                 if(wi.weapon)
1946                 {
1947                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1948                         if (!(save_weapons & WepSet_FromWeapon(j)))
1949                                 if(e.weapons & WepSet_FromWeapon(j))
1950                                         weapon_action(wi.weapon, WR_PRECACHE);
1951                 }
1952         }
1953         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1954         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1955         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1956         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1957         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1958         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1959         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1960         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1961         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1962
1963         if(e.superweapons_finished <= 0)
1964                 if(self.weapons & WEPSET_SUPERWEAPONS)
1965                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1966
1967         if(e.strength_finished <= 0)
1968                 e.strength_finished = 0;
1969         else
1970                 e.strength_finished += time;
1971         if(e.invincible_finished <= 0)
1972                 e.invincible_finished = 0;
1973         else
1974                 e.invincible_finished += time;
1975         if(e.superweapons_finished <= 0)
1976                 e.superweapons_finished = 0;
1977         else
1978                 e.superweapons_finished += time;
1979
1980         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1981                 _switchweapon = TRUE;
1982         if(_switchweapon)
1983                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1984
1985         return got;
1986 }
1987 #endif