qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         // minstagib: only allow filtered items
 275         if(g_minstagib)
 276                 if(self.classname != "minstagib")
 277                         return FALSE;
 278
 279         if(self.flags & FL_POWERUP)
 280         {
 281                 if(autocvar_g_powerups > 0)
 282                         return TRUE;
 283                 if(autocvar_g_powerups == 0)
 284                         return FALSE;
 285                 if(g_lms)
 286                         return FALSE;
 287                 if(g_ca)
 288                         return FALSE;
 289                 if(g_arena)
 290                         return FALSE;
 291         }
 292         else
 293         {
 294                 if(autocvar_g_pickup_items > 0)
 295                         return TRUE;
 296                 if(autocvar_g_pickup_items == 0)
 297                         return FALSE;
 298                 if(g_lms)
 299                         return FALSE;
 300                 if(g_ca)
 301                         return FALSE;
 302                 if(g_weaponarena)
 303                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 304                                 return FALSE;
 305         }
 306         return TRUE;
 307 }
 308
 309 #define ITEM_RESPAWN_TICKS 10
 310
 311 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 312         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 313 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 314         // range: 10 .. respawntime + respawntimejitter
 315
 316 floatfield Item_CounterField(float it)
 317 {
 318         switch(it)
 319         {
 320                 case IT_SHELLS:      return ammo_shells;
 321                 case IT_NAILS:       return ammo_nails;
 322                 case IT_ROCKETS:     return ammo_rockets;
 323                 case IT_CELLS:       return ammo_cells;
 324                 case IT_FUEL:        return ammo_fuel;
 325                 case IT_5HP:         return health;
 326                 case IT_25HP:        return health;
 327                 case IT_HEALTH:      return health;
 328                 case IT_ARMOR_SHARD: return armorvalue;
 329                 case IT_ARMOR:       return armorvalue;
 330                 // add more things here (health, armor)
 331                 default:             error("requested item has no counter field");
 332         }
 333 #ifdef GMQCC
 334         // should never happen
 335         return health;
 336 #endif
 337 }
 338
 339 string Item_CounterFieldName(float it)
 340 {
 341         switch(it)
 342         {
 343                 case IT_SHELLS:      return "shells";
 344                 case IT_NAILS:       return "nails";
 345                 case IT_ROCKETS:     return "rockets";
 346                 case IT_CELLS:       return "cells";
 347                 case IT_FUEL:        return "fuel";
 348
 349                 // add more things here (health, armor)
 350                 default:             error("requested item has no counter field name");
 351         }
 352 #ifdef GMQCC
 353         // should never happen
 354         return string_null;
 355 #endif
 356 }
 357
 358 .float max_armorvalue;
 359 .float pickup_anyway;
 360 /*
 361 float Item_Customize()
 362 {
 363         if(self.spawnshieldtime)
 364                 return TRUE;
 365         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 366         {
 367                 self.colormod = '0 0 0';
 368                 self.glowmod = self.colormod;
 369                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 370                 return TRUE;
 371         }
 372         else
 373         {
 374                 if(g_ghost_items)
 375                 {
 376                         self.colormod = stov(autocvar_g_ghost_items_color);
 377                         self.glowmod = self.colormod;
 378                         self.alpha = g_ghost_items;
 379                         return TRUE;
 380                 }
 381                 else
 382                         return FALSE;
 383         }
 384 }
 385 */
 386
 387 void Item_Show (entity e, float mode)
 388 {
 389         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 390         e.ItemStatus &~= ITS_STAYWEP;
 391         if (mode > 0)
 392         {
 393                 // make the item look normal, and be touchable
 394                 e.model = e.mdl;
 395                 e.solid = SOLID_TRIGGER;
 396                 e.spawnshieldtime = 1;
 397                 e.ItemStatus |= ITS_AVAILABLE;
 398         }
 399         else if (mode < 0)
 400         {
 401                 // hide the item completely
 402                 e.model = string_null;
 403                 e.solid = SOLID_NOT;
 404                 e.spawnshieldtime = 1;
 405                 e.ItemStatus &~= ITS_AVAILABLE;
 406         }
 407         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 408         {
 409                 // make the item translucent and not touchable
 410                 e.model = e.mdl;
 411                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 412                 e.effects |= EF_STARDUST;
 413                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 414                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 415         }
 416         else
 417         {
 418                 //setmodel(e, "null");
 419                 e.solid = SOLID_NOT;
 420                 e.colormod = '0 0 0';
 421                 e.glowmod = e.colormod;
 422                 e.spawnshieldtime = 1;
 423                 e.ItemStatus &~= ITS_AVAILABLE;
 424         }
 425
 426         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 427             e.ItemStatus |= ITS_POWERUP;
 428
 429         if (autocvar_g_nodepthtestitems)
 430                 e.effects |= EF_NODEPTHTEST;
 431
 432
 433     if (autocvar_g_fullbrightitems)
 434                 e.ItemStatus |= ITS_ALLOWFB;
 435
 436         if (autocvar_sv_simple_items)
 437         e.ItemStatus |= ITS_ALLOWSI;
 438
 439         // relink entity (because solid may have changed)
 440         setorigin(e, e.origin);
 441     e.SendFlags |= ISF_STATUS;
 442 }
 443
 444 void Item_Respawn (void)
 445 {
 446         Item_Show(self, 1);
 447         if(!g_minstagib && self.items == IT_STRENGTH)
 448                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 449         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 450                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 451         else
 452                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 453         setorigin (self, self.origin);
 454
 455         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 456         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 457 }
 458
 459 void Item_RespawnCountdown (void)
 460 {
 461         if(self.count >= ITEM_RESPAWN_TICKS)
 462         {
 463                 if(self.waypointsprite_attached)
 464                         WaypointSprite_Kill(self.waypointsprite_attached);
 465                 Item_Respawn();
 466         }
 467         else
 468         {
 469                 self.nextthink = time + 1;
 470                 self.count += 1;
 471                 if(self.count == 1)
 472                 {
 473                         string name;
 474                         vector rgb = '1 0 1';
 475                         name = string_null;
 476                         if(g_minstagib)
 477                         {
 478                                 switch(self.items)
 479                                 {
 480                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 481                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 482                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 483                                 }
 484                         }
 485                         else
 486                         {
 487                                 switch(self.items)
 488                                 {
 489                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 490                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 491                                 }
 492                         }
 493                         switch(self.items)
 494                         {
 495                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 496                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 497                         }
 498                         if(self.flags & FL_WEAPON)
 499                         {
 500                                 entity wi = get_weaponinfo(self.weapon);
 501                                 if(wi)
 502                                 {
 503                                         name = wi.model2;
 504                                         rgb = '1 0 0';
 505                                 }
 506                         }
 507                         if(name)
 508                         {
 509                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 510                                 if(self.waypointsprite_attached)
 511                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 512                         }
 513                         else
 514                         {
 515                                 print("Unknown powerup-marked item is wanting to respawn\n");
 516                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 517                         }
 518                 }
 519                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 520                 if(self.waypointsprite_attached)
 521                 {
 522                         WaypointSprite_Ping(self.waypointsprite_attached);
 523                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 524                 }
 525         }
 526 }
 527
 528 void Item_ScheduleRespawnIn(entity e, float t)
 529 {
 530         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 531         {
 532                 e.think = Item_RespawnCountdown;
 533                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 534                 e.count = 0;
 535         }
 536         else
 537         {
 538                 e.think = Item_Respawn;
 539                 e.nextthink = time + t;
 540         }
 541 }
 542
 543 void Item_ScheduleRespawn(entity e)
 544 {
 545         if(e.respawntime > 0)
 546         {
 547                 Item_Show(e, 0);
 548                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 549         }
 550         else // if respawntime is -1, this item does not respawn
 551                 Item_Show(e, -1);
 552 }
 553
 554 void Item_ScheduleInitialRespawn(entity e)
 555 {
 556         Item_Show(e, 0);
 557         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 558 }
 559
 560 float ITEM_MODE_NONE = 0;
 561 float ITEM_MODE_HEALTH = 1;
 562 float ITEM_MODE_ARMOR = 2;
 563 float ITEM_MODE_FUEL = 3;
 564 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 565 {
 566         if (!item.ammofield)
 567                 return FALSE;
 568
 569         if (item.spawnshieldtime)
 570         {
 571                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 572                 {
 573                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 574                         goto YEAH;
 575                 }
 576         }
 577         else if(g_weapon_stay == 2)
 578         {
 579                 float mi = min(item.ammofield, ammomax);
 580                 if (player.ammofield < mi)
 581                 {
 582                         player.ammofield = mi;
 583                         goto YEAH;
 584                 }
 585         }
 586
 587         return FALSE;
 588
 589 :YEAH
 590         switch(mode)
 591         {
 592                 case ITEM_MODE_FUEL:
 593                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 594                         break;
 595                 case ITEM_MODE_HEALTH:
 596                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 597                         break;
 598                 case ITEM_MODE_ARMOR:
 599                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 600                         break;
 601                 default:
 602                         break;
 603         }
 604         return TRUE;
 605 }
 606
 607 float Item_GiveTo(entity item, entity player)
 608 {
 609         float _switchweapon;
 610         float pickedup;
 611         float it;
 612         float i;
 613
 614         // if nothing happens to player, just return without taking the item
 615         pickedup = FALSE;
 616         _switchweapon = FALSE;
 617
 618         if (g_minstagib)
 619         {
 620                 float prevcells = player.ammo_cells;
 621
 622                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 623                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 624
 625                 if(player.ammo_cells > prevcells)
 626                 {
 627                         _switchweapon = TRUE;
 628
 629                         // play some cool sounds ;)
 630                         if (clienttype(player) == CLIENTTYPE_REAL)
 631                         {
 632                                 if(player.health <= 5)
 633                                         AnnounceTo(player, "lastsecond");
 634                                 else if(player.health < 50)
 635                                         AnnounceTo(player, "narrowly");
 636                         }
 637                         // sound not available
 638                         // else if(item.items == IT_CELLS)
 639                         //      AnnounceTo(player, "ammo");
 640
 641                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 642                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 643                         player.health = 100;
 644                 }
 645
 646                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 647                 {
 648                         pickedup = TRUE;
 649                         player.items |= it;
 650                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 651                 }
 652
 653                 // extralife powerup
 654                 if (item.max_health)
 655                 {
 656                         pickedup = TRUE;
 657                         // sound not available
 658                         // AnnounceTo(player, "_lives");
 659                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 660                         sprint(player, "^3You picked up some extra lives\n");
 661                 }
 662
 663                 // invis powerup
 664                 if (item.strength_finished)
 665                 {
 666                         pickedup = TRUE;
 667                         // sound not available
 668                         // AnnounceTo(player, "invisible");
 669                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 670                 }
 671
 672                 // speed powerup
 673                 if (item.invincible_finished)
 674                 {
 675                         pickedup = TRUE;
 676                         // sound not available
 677                         // AnnounceTo(player, "speed");
 678                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 679                 }
 680         }
 681         else
 682         {
 683                 // in case the player has autoswitch enabled do the following:
 684                 // if the player is using their best weapon before items are given, they
 685                 // probably want to switch to an even better weapon after items are given
 686                 if (player.autoswitch)
 687                 if (player.switchweapon == w_getbestweapon(player))
 688                         _switchweapon = TRUE;
 689
 690                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 691                         _switchweapon = TRUE;
 692
 693                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 694                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 695                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 696                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 697                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 698                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 699                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 700
 701                 if (item.flags & FL_WEAPON)
 702                 {
 703                         WEPSET_DECLARE_A(it);
 704                         WEPSET_COPY_AE(it, item);
 705                         WEPSET_ANDNOT_AE(it, player);
 706
 707                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 708                         {
 709                                 pickedup = TRUE;
 710                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 711                                         if(WEPSET_CONTAINS_AW(it, i))
 712                                                 W_GiveWeapon (player, i, item.netname);
 713                         }
 714                 }
 715
 716                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 717                 {
 718                         pickedup = TRUE;
 719                         player.items |= it;
 720                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 721                 }
 722
 723                 if (item.strength_finished)
 724                 {
 725                         pickedup = TRUE;
 726                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 727                 }
 728                 if (item.invincible_finished)
 729                 {
 730                         pickedup = TRUE;
 731                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 732                 }
 733                 if (item.superweapons_finished)
 734                 {
 735                         pickedup = TRUE;
 736                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 737                 }
 738         }
 739
 740 :skip
 741         // always eat teamed entities
 742         if(item.team)
 743                 pickedup = TRUE;
 744
 745         if (!pickedup)
 746                 return 0;
 747
 748         if (_switchweapon)
 749                 if (player.switchweapon != w_getbestweapon(player))
 750                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 751
 752         return 1;
 753 }
 754
 755 void Item_Touch (void)
 756 {
 757         entity e, head;
 758
 759         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 760         if(self.classname == "droppedweapon")
 761         {
 762                 if (ITEM_TOUCH_NEEDKILL())
 763                 {
 764                         remove(self);
 765                         return;
 766                 }
 767         }
 768
 769         if (other.classname != "player")
 770                 return;
 771         if (other.deadflag)
 772                 return;
 773         if (self.solid != SOLID_TRIGGER)
 774                 return;
 775         if (self.owner == other)
 776                 return;
 777         if(MUTATOR_CALLHOOK(ItemTouch))
 778                 return;
 779
 780         if (self.classname == "droppedweapon")
 781         {
 782                 self.strength_finished = max(0, self.strength_finished - time);
 783                 self.invincible_finished = max(0, self.invincible_finished - time);
 784                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 785         }
 786
 787         if(!Item_GiveTo(self, other))
 788         {
 789                 if (self.classname == "droppedweapon")
 790                 {
 791                         // undo what we did above
 792                         self.strength_finished += time;
 793                         self.invincible_finished += time;
 794                         self.superweapons_finished += time;
 795                 }
 796                 return;
 797         }
 798
 799         other.last_pickup = time;
 800
 801         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 802         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 803
 804         if (self.classname == "droppedweapon")
 805                 remove (self);
 806         else if not(self.spawnshieldtime)
 807                 return;
 808         else
 809         {
 810                 if(self.team)
 811                 {
 812                         RandomSelection_Init();
 813                         for(head = world; (head = findfloat(head, team, self.team)); )
 814                         {
 815                                 if(head.flags & FL_ITEM)
 816                                 {
 817                                         Item_Show(head, -1);
 818                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 819                                 }
 820                         }
 821                         e = RandomSelection_chosen_ent;
 822
 823                 }
 824                 else
 825                         e = self;
 826                 Item_ScheduleRespawn(e);
 827         }
 828 }
 829
 830 void Item_Reset()
 831 {
 832         Item_Show(self, !self.state);
 833         setorigin (self, self.origin);
 834
 835         if(self.classname != "droppedweapon")
 836         {
 837                 self.think = func_null;
 838                 self.nextthink = 0;
 839
 840                 if(self.waypointsprite_attached)
 841                         WaypointSprite_Kill(self.waypointsprite_attached);
 842
 843                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 844                         Item_ScheduleInitialRespawn(self);
 845         }
 846 }
 847
 848 void Item_FindTeam()
 849 {
 850         entity head, e;
 851
 852         if(self.effects & EF_NODRAW)
 853         {
 854                 // marker for item team search
 855                 dprint("Initializing item team ", ftos(self.team), "\n");
 856                 RandomSelection_Init();
 857                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 858                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 859                 e = RandomSelection_chosen_ent;
 860                 e.state = 0;
 861                 Item_Show(e, 1);
 862
 863                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 864                 {
 865                         if(head != e)
 866                         {
 867                                 // make it a non-spawned item
 868                                 Item_Show(head, -1);
 869                                 head.state = 1; // state 1 = initially hidden item
 870                         }
 871                         head.effects &~= EF_NODRAW;
 872                 }
 873
 874                 Item_Reset();
 875         }
 876 }
 877
 878 // Savage: used for item garbage-collection
 879 // TODO: perhaps nice special effect?
 880 void RemoveItem(void)
 881 {
 882         remove(self);
 883 }
 884
 885 // pickup evaluation functions
 886 // these functions decide how desirable an item is to the bots
 887
 888 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 889
 890 float weapon_pickupevalfunc(entity player, entity item)
 891 {
 892         float c, j, position;
 893
 894         // See if I have it already
 895         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 896         {
 897                 // If I can pick it up
 898                 if(!item.spawnshieldtime)
 899                         c = 0;
 900                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 901                 {
 902                         // Skilled bots will grab more
 903                         c = bound(0, skill / 10, 1) * 0.5;
 904                 }
 905                 else
 906                         c = 0;
 907         }
 908         else
 909                 c = 1;
 910
 911         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 912         if( bot_custom_weapon && c )
 913         {
 914                 // Find the highest position on any range
 915                 position = -1;
 916                 for(j = 0; j < WEP_LAST ; ++j){
 917                         if(
 918                                         bot_weapons_far[j] == item.weapon ||
 919                                         bot_weapons_mid[j] == item.weapon ||
 920                                         bot_weapons_close[j] == item.weapon
 921                           )
 922                         {
 923                                 position = j;
 924                                 break;
 925                         }
 926                 }
 927
 928                 // Rate it
 929                 if (position >= 0 )
 930                 {
 931                         position = WEP_LAST - position;
 932                         // item.bot_pickupbasevalue is overwritten here
 933                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 934                 }
 935         }
 936
 937         return item.bot_pickupbasevalue * c;
 938 }
 939
 940 float commodity_pickupevalfunc(entity player, entity item)
 941 {
 942         float c, i;
 943         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 944         entity wi;
 945         c = 0;
 946
 947         // Detect needed ammo
 948         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 949         {
 950                 wi = get_weaponinfo(i);
 951
 952                 if not(WEPSET_CONTAINS_EW(player, i))
 953                         continue;
 954
 955                 if(wi.items & IT_SHELLS)
 956                         need_shells = TRUE;
 957                 else if(wi.items & IT_NAILS)
 958                         need_nails = TRUE;
 959                 else if(wi.items & IT_ROCKETS)
 960                         need_rockets = TRUE;
 961                 else if(wi.items & IT_CELLS)
 962                         need_cells = TRUE;
 963                 else if(wi.items & IT_FUEL)
 964                         need_cells = TRUE;
 965         }
 966
 967         // TODO: figure out if the player even has the weapon this ammo is for?
 968         // may not affect strategy much though...
 969         // find out how much more ammo/armor/health the player can hold
 970         if (need_shells)
 971         if (item.ammo_shells)
 972         if (player.ammo_shells < g_pickup_shells_max)
 973                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 974         if (need_nails)
 975         if (item.ammo_nails)
 976         if (player.ammo_nails < g_pickup_nails_max)
 977                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 978         if (need_rockets)
 979         if (item.ammo_rockets)
 980         if (player.ammo_rockets < g_pickup_rockets_max)
 981                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 982         if (need_cells)
 983         if (item.ammo_cells)
 984         if (player.ammo_cells < g_pickup_cells_max)
 985                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 986         if (need_fuel)
 987         if (item.ammo_fuel)
 988         if (player.ammo_fuel < g_pickup_fuel_max)
 989                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 990         if (item.armorvalue)
 991         if (player.armorvalue < item.max_armorvalue)
 992                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 993         if (item.health)
 994         if (player.health < item.max_health)
 995                 c = c + max(0, 1 - player.health / item.max_health);
 996
 997         return item.bot_pickupbasevalue * c;
 998 }
 999
1000 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
1001 {
1002         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1003                 RemoveItem();
1004 }
1005
1006 .float is_item;
1007 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1008 {
1009         startitem_failed = FALSE;
1010
1011         if(self.model == "")
1012                 self.model = itemmodel;
1013
1014         if(self.model == "")
1015     {
1016         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1017         return;
1018     }
1019
1020         if(self.item_pickupsound == "")
1021                 self.item_pickupsound = pickupsound;
1022
1023         if(!self.respawntime) // both need to be set
1024         {
1025                 self.respawntime = defaultrespawntime;
1026                 self.respawntimejitter = defaultrespawntimejitter;
1027         }
1028
1029         self.items = itemid;
1030         self.weapon = weaponid;
1031
1032         if(weaponid)
1033                 WEPSET_COPY_EW(self, weaponid);
1034
1035         self.flags = FL_ITEM | itemflags;
1036
1037         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1038         {
1039                 startitem_failed = TRUE;
1040                 remove(self);
1041                 return;
1042         }
1043
1044         // is it a dropped weapon?
1045         if (self.classname == "droppedweapon")
1046         {
1047                 self.reset = SUB_Remove;
1048                 // it's a dropped weapon
1049                 self.movetype = MOVETYPE_TOSS;
1050
1051                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1052                 self.think = RemoveItem;
1053                 self.nextthink = time + 20;
1054
1055                 self.takedamage = DAMAGE_YES;
1056                 self.event_damage = Item_Damage;
1057
1058                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1059                 /*
1060                 if(self.items == 0)
1061                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
1062                 if(self.ammo_nails == 0)
1063                 if(self.ammo_cells == 0)
1064                 if(self.ammo_rockets == 0)
1065                 if(self.ammo_shells == 0)
1066                 if(self.ammo_fuel == 0)
1067                 if(self.health == 0)
1068                 if(self.armorvalue == 0)
1069                 */
1070                 {
1071                         // if item is worthless after a timer, have it expire then
1072                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1073                 }
1074
1075                 // don't drop if in a NODROP zone (such as lava)
1076                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1077                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1078                 {
1079                         startitem_failed = TRUE;
1080                         remove(self);
1081                         return;
1082                 }
1083         }
1084         else
1085         {
1086                 if(!have_pickup_item())
1087                 {
1088                         startitem_failed = TRUE;
1089                         remove (self);
1090                         return;
1091                 }
1092
1093                 if(self.angles != '0 0 0')
1094             self.SendFlags |= ISF_ANGLES;
1095
1096                 self.reset = Item_Reset;
1097                 // it's a level item
1098                 if(self.spawnflags & 1)
1099                         self.noalign = 1;
1100                 if (self.noalign)
1101                         self.movetype = MOVETYPE_NONE;
1102                 else
1103                         self.movetype = MOVETYPE_TOSS;
1104                 // do item filtering according to game mode and other things
1105                 if (!self.noalign)
1106                 {
1107                         // first nudge it off the floor a little bit to avoid math errors
1108                         setorigin(self, self.origin + '0 0 1');
1109                         // set item size before we spawn a spawnfunc_waypoint
1110                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1111                                 setsize (self, '-16 -16 0', '16 16 48');
1112                         else
1113                                 setsize (self, '-16 -16 0', '16 16 32');
1114                         // note droptofloor returns FALSE if stuck/or would fall too far
1115                         droptofloor();
1116                         waypoint_spawnforitem(self);
1117                 }
1118
1119                 /*
1120                  * can't do it that way, as it would break maps
1121                  * TODO make a target_give like entity another way, that perhaps has
1122                  * the weapon name in a key
1123                 if(self.targetname)
1124                 {
1125                         // target_give not yet supported; maybe later
1126                         print("removed targeted ", self.classname, "\n");
1127                         startitem_failed = TRUE;
1128                         remove (self);
1129                         return;
1130                 }
1131                 */
1132
1133                 if(autocvar_spawn_debug >= 2)
1134                 {
1135                         entity otheritem;
1136                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1137                         {
1138                             // why not flags & fl_item?
1139                                 if(otheritem.is_item)
1140                                 {
1141                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1142                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1143                                         error("Mapper sucks.");
1144                                 }
1145                         }
1146                         self.is_item = TRUE;
1147                 }
1148
1149                 WEPSET_OR_AW(weaponsInMap, weaponid);
1150
1151                 precache_model (self.model);
1152                 precache_sound (self.item_pickupsound);
1153
1154                 precache_sound ("misc/itemrespawncountdown.wav");
1155                 if(!g_minstagib && itemid == IT_STRENGTH)
1156                         precache_sound ("misc/strength_respawn.wav");
1157                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
1158                         precache_sound ("misc/shield_respawn.wav");
1159                 else
1160                         precache_sound ("misc/itemrespawn.wav");
1161
1162                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1163                         self.target = "###item###"; // for finding the nearest item using find()
1164         }
1165
1166         self.bot_pickup = TRUE;
1167         self.bot_pickupevalfunc = pickupevalfunc;
1168         self.bot_pickupbasevalue = pickupbasevalue;
1169         self.mdl = self.model;
1170         self.netname = itemname;
1171         self.touch = Item_Touch;
1172         setmodel(self, "null"); // precision set below
1173         //self.effects |= EF_LOWPRECISION;
1174
1175         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1176     {
1177         self.pos1 = '-16 -16 0';
1178         self.pos2 = '16 16 48';
1179     }
1180         else
1181     {
1182         self.pos1 = '-16 -16 0';
1183         self.pos2 = '16 16 32';
1184     }
1185     setsize (self, self.pos1, self.pos2);
1186
1187     if(itemflags & FL_POWERUP)
1188         self.ItemStatus |= ITS_ANIMATE1;
1189
1190         if(self.armorvalue || self.health)
1191         self.ItemStatus |= ITS_ANIMATE2;
1192
1193         if(itemflags & FL_WEAPON)
1194         {
1195                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1196             self.colormap = 1024; // color shirt=0 pants=0 grey
1197         else
1198             self.gravity = 1;
1199
1200                 self.ItemStatus |= ITS_ANIMATE1;
1201                 self.ItemStatus |= ISF_COLORMAP;
1202         }
1203
1204         self.state = 0;
1205         if(self.team) // broken, no idea why.
1206         {
1207                 if(!self.cnt)
1208                         self.cnt = 1; // item probability weight
1209
1210                 self.effects |= EF_NODRAW; // marker for item team search
1211                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1212         }
1213         else
1214                 Item_Reset();
1215
1216     Net_LinkEntity(self, FALSE, 0, ItemSend);
1217 }
1218
1219 /* replace items in minstagib
1220  * IT_STRENGTH   = invisibility
1221  * IT_NAILS      = extra lives
1222  * IT_INVINCIBLE = speed
1223  */
1224 void minstagib_items (float itemid) // will be deleted soon.
1225 {
1226         float rnd;
1227         self.classname = "minstagib"; // ...?
1228
1229         // replace rocket launchers and nex guns with ammo cells
1230         if (itemid == IT_CELLS)
1231         {
1232                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1233                 StartItem ("models/items/a_cells.md3",
1234                         "misc/itempickup.wav", 45, 0,
1235                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
1236                 return;
1237         }
1238
1239         // randomize
1240         rnd = random() * 3;
1241         if (rnd <= 1)
1242                 itemid = IT_STRENGTH;
1243         else if (rnd <= 2)
1244                 itemid = IT_NAILS;
1245         else
1246                 itemid = IT_INVINCIBLE;
1247
1248         // replace with invis
1249         if (itemid == IT_STRENGTH)
1250         {
1251                 if(!self.strength_finished)
1252                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1253                 StartItem ("models/items/g_strength.md3",
1254                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1255                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1256         }
1257         // replace with extra lives
1258         if (itemid == IT_NAILS)
1259         {
1260                 self.max_health = 1;
1261                 StartItem ("models/items/g_h100.md3",
1262                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1263                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1264         }
1265         // replace with speed
1266         if (itemid == IT_INVINCIBLE)
1267         {
1268                 if(!self.invincible_finished)
1269                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1270                 StartItem ("models/items/g_invincible.md3",
1271                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1272                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1273         }
1274 }
1275
1276 float minst_no_auto_cells;
1277 void minst_remove_item (void) {
1278         if(minst_no_auto_cells)
1279                 remove(self);
1280 }
1281
1282 float weaponswapping;
1283 float internalteam;
1284
1285 void weapon_defaultspawnfunc(float wpn)
1286 {
1287         entity e;
1288         float t;
1289         var .float ammofield;
1290         string s;
1291         entity oldself;
1292         float i, j;
1293         float f;
1294
1295         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1296         {
1297                 e = get_weaponinfo(wpn);
1298
1299                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1300                 {
1301                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1302                         /*
1303                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1304                         startitem_failed = TRUE;
1305                         return;
1306                         */
1307                 }
1308
1309                 s = W_Apply_Weaponreplace(e.netname);
1310                 ret_string = s;
1311                 other = e;
1312                 MUTATOR_CALLHOOK(SetWeaponreplace);
1313                 s = ret_string;
1314                 if(s == "")
1315                 {
1316                         remove(self);
1317                         startitem_failed = TRUE;
1318                         return;
1319                 }
1320                 t = tokenize_console(s);
1321                 if(t >= 2)
1322                 {
1323                         self.team = --internalteam;
1324                         oldself = self;
1325                         for(i = 1; i < t; ++i)
1326                         {
1327                                 s = argv(i);
1328                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1329                                 {
1330                                         e = get_weaponinfo(j);
1331                                         if(e.netname == s)
1332                                         {
1333                                                 self = spawn();
1334                                                 copyentity(oldself, self);
1335                                                 self.classname = "replacedweapon";
1336                                                 weapon_defaultspawnfunc(j);
1337                                                 break;
1338                                         }
1339                                 }
1340                                 if(j > WEP_LAST)
1341                                 {
1342                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1343                                 }
1344                         }
1345                         self = oldself;
1346                 }
1347                 if(t >= 1) // always the case!
1348                 {
1349                         s = argv(0);
1350                         wpn = 0;
1351                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1352                         {
1353                                 e = get_weaponinfo(j);
1354                                 if(e.netname == s)
1355                                 {
1356                                         wpn = j;
1357                                         break;
1358                                 }
1359                         }
1360                         if(j > WEP_LAST)
1361                         {
1362                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1363                         }
1364                 }
1365                 if(wpn == 0)
1366                 {
1367                         remove(self);
1368                         startitem_failed = TRUE;
1369                         return;
1370                 }
1371         }
1372
1373         e = get_weaponinfo(wpn);
1374
1375         if(!self.respawntime)
1376         {
1377                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1378                 {
1379                         self.respawntime = g_pickup_respawntime_superweapon;
1380                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1381                 }
1382                 else
1383                 {
1384                         self.respawntime = g_pickup_respawntime_weapon;
1385                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1386                 }
1387         }
1388
1389         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1390                 if(!self.superweapons_finished)
1391                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1392
1393         if(e.items)
1394         {
1395                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1396                 {
1397                         if(e.items & j)
1398                         {
1399                                 ammofield = Item_CounterField(j);
1400                                 if(!self.ammofield)
1401                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1402                         }
1403                 }
1404         }
1405
1406         // pickup anyway
1407         if(g_pickup_weapons_anyway)
1408                 self.pickup_anyway = TRUE;
1409
1410         f = FL_WEAPON;
1411
1412         // no weapon-stay on superweapons
1413         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1414                 f |= FL_NO_WEAPON_STAY;
1415
1416         // weapon stay isn't supported for teamed weapons
1417         if(self.team)
1418                 f |= FL_NO_WEAPON_STAY;
1419
1420         // stupid minstagib hack, don't ask
1421         if(g_minstagib)
1422                 if(self.ammo_cells)
1423                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1424
1425         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1426         if (self.modelindex) // don't precache if self was removed
1427                 weapon_action(e.weapon, WR_PRECACHE);
1428 }
1429
1430 void spawnfunc_weapon_shotgun (void);
1431 void spawnfunc_weapon_uzi (void) {
1432         if(autocvar_sv_q3acompat_machineshotgunswap)
1433         if(self.classname != "droppedweapon")
1434         {
1435                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1436                 return;
1437         }
1438         weapon_defaultspawnfunc(WEP_UZI);
1439 }
1440
1441 void spawnfunc_weapon_shotgun (void) {
1442         if(autocvar_sv_q3acompat_machineshotgunswap)
1443         if(self.classname != "droppedweapon")
1444         {
1445                 weapon_defaultspawnfunc(WEP_UZI);
1446                 return;
1447         }
1448         weapon_defaultspawnfunc(WEP_SHOTGUN);
1449 }
1450
1451 void spawnfunc_weapon_nex (void)
1452 {
1453         if (g_minstagib)
1454         {
1455                 minstagib_items(IT_CELLS);
1456                 self.think = minst_remove_item;
1457                 self.nextthink = time;
1458                 return;
1459         }
1460         weapon_defaultspawnfunc(WEP_NEX);
1461 }
1462
1463 void spawnfunc_weapon_minstanex (void)
1464 {
1465         if (g_minstagib)
1466         {
1467                 minstagib_items(IT_CELLS);
1468                 self.think = minst_remove_item;
1469                 self.nextthink = time;
1470                 return;
1471         }
1472         weapon_defaultspawnfunc(WEP_MINSTANEX);
1473 }
1474
1475 void spawnfunc_weapon_rocketlauncher (void)
1476 {
1477         if (g_minstagib)
1478         {
1479                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1480                 self.think = minst_remove_item;
1481                 self.nextthink = time;
1482                 return;
1483         }
1484         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1485 }
1486
1487 void spawnfunc_item_rockets (void) {
1488         if(!self.ammo_rockets)
1489                 self.ammo_rockets = g_pickup_rockets;
1490         if(!self.pickup_anyway)
1491                 self.pickup_anyway = g_pickup_ammo_anyway;
1492         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1493 }
1494
1495 void spawnfunc_item_shells (void);
1496 void spawnfunc_item_bullets (void) {
1497         if(!weaponswapping)
1498         if(autocvar_sv_q3acompat_machineshotgunswap)
1499         if(self.classname != "droppedweapon")
1500         {
1501                 weaponswapping = TRUE;
1502                 spawnfunc_item_shells();
1503                 weaponswapping = FALSE;
1504                 return;
1505         }
1506
1507         if(!self.ammo_nails)
1508                 self.ammo_nails = g_pickup_nails;
1509         if(!self.pickup_anyway)
1510                 self.pickup_anyway = g_pickup_ammo_anyway;
1511         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1512 }
1513
1514 void spawnfunc_item_cells (void) {
1515         if(!self.ammo_cells)
1516                 self.ammo_cells = g_pickup_cells;
1517         if(!self.pickup_anyway)
1518                 self.pickup_anyway = g_pickup_ammo_anyway;
1519         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1520 }
1521
1522 void spawnfunc_item_shells (void) {
1523         if(!weaponswapping)
1524         if(autocvar_sv_q3acompat_machineshotgunswap)
1525         if(self.classname != "droppedweapon")
1526         {
1527                 weaponswapping = TRUE;
1528                 spawnfunc_item_bullets();
1529                 weaponswapping = FALSE;
1530                 return;
1531         }
1532
1533         if(!self.ammo_shells)
1534                 self.ammo_shells = g_pickup_shells;
1535         if(!self.pickup_anyway)
1536                 self.pickup_anyway = g_pickup_ammo_anyway;
1537         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1538 }
1539
1540 void spawnfunc_item_armor_small (void) {
1541         if(!self.armorvalue)
1542                 self.armorvalue = g_pickup_armorsmall;
1543         if(!self.max_armorvalue)
1544                 self.max_armorvalue = g_pickup_armorsmall_max;
1545         if(!self.pickup_anyway)
1546                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1547         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1548 }
1549
1550 void spawnfunc_item_armor_medium (void) {
1551         if(!self.armorvalue)
1552                 self.armorvalue = g_pickup_armormedium;
1553         if(!self.max_armorvalue)
1554                 self.max_armorvalue = g_pickup_armormedium_max;
1555         if(!self.pickup_anyway)
1556                 self.pickup_anyway = g_pickup_armormedium_anyway;
1557         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1558 }
1559
1560 void spawnfunc_item_armor_big (void) {
1561         if(!self.armorvalue)
1562                 self.armorvalue = g_pickup_armorbig;
1563         if(!self.max_armorvalue)
1564                 self.max_armorvalue = g_pickup_armorbig_max;
1565         if(!self.pickup_anyway)
1566                 self.pickup_anyway = g_pickup_armorbig_anyway;
1567         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1568 }
1569
1570 void spawnfunc_item_armor_large (void) {
1571         if(!self.armorvalue)
1572                 self.armorvalue = g_pickup_armorlarge;
1573         if(!self.max_armorvalue)
1574                 self.max_armorvalue = g_pickup_armorlarge_max;
1575         if(!self.pickup_anyway)
1576                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1577         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1578 }
1579
1580 void spawnfunc_item_health_small (void) {
1581         if(!self.max_health)
1582                 self.max_health = g_pickup_healthsmall_max;
1583         if(!self.health)
1584                 self.health = g_pickup_healthsmall;
1585         if(!self.pickup_anyway)
1586                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1587         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1588 }
1589
1590 void spawnfunc_item_health_medium (void) {
1591         if(!self.max_health)
1592                 self.max_health = g_pickup_healthmedium_max;
1593         if(!self.health)
1594                 self.health = g_pickup_healthmedium;
1595         if(!self.pickup_anyway)
1596                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1597         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1598 }
1599
1600 void spawnfunc_item_health_large (void) {
1601         if(!self.max_health)
1602                 self.max_health = g_pickup_healthlarge_max;
1603         if(!self.health)
1604                 self.health = g_pickup_healthlarge;
1605         if(!self.pickup_anyway)
1606                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1607         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1608 }
1609
1610 void spawnfunc_item_health_mega (void) {
1611         if(g_minstagib) {
1612                 minstagib_items(IT_NAILS);
1613         } else {
1614                 if(!self.max_health)
1615                         self.max_health = g_pickup_healthmega_max;
1616                 if(!self.health)
1617                         self.health = g_pickup_healthmega;
1618                 if(!self.pickup_anyway)
1619                         self.pickup_anyway = g_pickup_healthmega_anyway;
1620                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1621         }
1622 }
1623
1624 // support old misnamed entities
1625 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1626 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1627 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1628 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1629 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1630
1631 void spawnfunc_item_strength (void) {
1632         if(g_minstagib) {
1633                 minstagib_items(IT_STRENGTH);
1634         } else {
1635                 precache_sound("weapons/strength_fire.wav");
1636                 if(!self.strength_finished)
1637                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1638                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1639         }
1640 }
1641
1642 void spawnfunc_item_invincible (void) {
1643         if(g_minstagib) {
1644                 minstagib_items(IT_INVINCIBLE);
1645         } else {
1646                 if(!self.invincible_finished)
1647                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1648                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1649         }
1650 }
1651
1652 void spawnfunc_item_minst_cells (void) {
1653         if (g_minstagib)
1654         {
1655                 minst_no_auto_cells = TRUE;
1656                 minstagib_items(IT_CELLS);
1657         }
1658         else
1659                 remove(self);
1660 }
1661
1662 // compatibility:
1663 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1664
1665 float GiveItems(entity e, float beginarg, float endarg);
1666 void target_items_use (void)
1667 {
1668         if(activator.classname == "droppedweapon")
1669         {
1670                 EXACTTRIGGER_TOUCH;
1671                 remove(activator);
1672                 return;
1673         }
1674
1675         if(activator.classname != "player")
1676                 return;
1677         if(activator.deadflag != DEAD_NO)
1678                 return;
1679         EXACTTRIGGER_TOUCH;
1680
1681         entity e;
1682         for(e = world; (e = find(e, classname, "droppedweapon")); )
1683                 if(e.enemy == activator)
1684                         remove(e);
1685
1686         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1687                 centerprint(activator, self.message);
1688 }
1689
1690 void spawnfunc_target_items (void)
1691 {
1692         float n, i, j;
1693         entity e;
1694
1695         self.use = target_items_use;
1696         if(!self.strength_finished)
1697                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1698         if(!self.invincible_finished)
1699                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1700         if(!self.superweapons_finished)
1701                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1702
1703         precache_sound("misc/itempickup.wav");
1704         precache_sound("misc/megahealth.wav");
1705         precache_sound("misc/armor25.wav");
1706         precache_sound("misc/powerup.wav");
1707         precache_sound("misc/poweroff.wav");
1708         precache_sound("weapons/weaponpickup.wav");
1709
1710         n = tokenize_console(self.netname);
1711         if(argv(0) == "give")
1712         {
1713                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1714         }
1715         else
1716         {
1717                 for(i = 0; i < n; ++i)
1718                 {
1719                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1720                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1721                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1722                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1723                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1724                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1725                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1726                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1727                         else
1728                         {
1729                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1730                                 {
1731                                         e = get_weaponinfo(j);
1732                                         if(argv(i) == e.netname)
1733                                         {
1734                                                 WEPSET_OR_EW(self, j);
1735                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1736                                                         weapon_action(e.weapon, WR_PRECACHE);
1737                                                 break;
1738                                         }
1739                                 }
1740                                 if(j > WEP_LAST)
1741                                         print("target_items: invalid item ", argv(i), "\n");
1742                         }
1743                 }
1744
1745                 string itemprefix, valueprefix;
1746                 if(self.spawnflags == 0)
1747                 {
1748                         itemprefix = "";
1749                         valueprefix = "";
1750                 }
1751                 else if(self.spawnflags == 1)
1752                 {
1753                         itemprefix = "max ";
1754                         valueprefix = "max ";
1755                 }
1756                 else if(self.spawnflags == 2)
1757                 {
1758                         itemprefix = "min ";
1759                         valueprefix = "min ";
1760                 }
1761                 else if(self.spawnflags == 4)
1762                 {
1763                         itemprefix = "minus ";
1764                         valueprefix = "max ";
1765                 }
1766                 else
1767                 {
1768                         error("invalid spawnflags");
1769 #ifdef GMQCC
1770                         itemprefix = string_null;
1771                         valueprefix = string_null;
1772 #endif
1773                 }
1774
1775                 self.netname = "";
1776                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1777                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1778                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1779                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1780                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1781                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1782                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1783                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1784                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1785                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1786                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1787                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1788                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1789                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1790                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1791                 {
1792                         e = get_weaponinfo(j);
1793                         if(e.weapon)
1794                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1795                 }
1796         }
1797         self.netname = strzone(self.netname);
1798         //print(self.netname, "\n");
1799
1800         n = tokenize_console(self.netname);
1801         for(i = 0; i < n; ++i)
1802         {
1803                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1804                 {
1805                         e = get_weaponinfo(j);
1806                         if(argv(i) == e.netname)
1807                         {
1808                                 weapon_action(e.weapon, WR_PRECACHE);
1809                                 break;
1810                         }
1811                 }
1812         }
1813 }
1814
1815 void spawnfunc_item_fuel(void)
1816 {
1817         if(!self.ammo_fuel)
1818                 self.ammo_fuel = g_pickup_fuel;
1819         if(!self.pickup_anyway)
1820                 self.pickup_anyway = g_pickup_ammo_anyway;
1821         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1822 }
1823
1824 void spawnfunc_item_fuel_regen(void)
1825 {
1826         if(start_items & IT_FUEL_REGEN)
1827         {
1828                 spawnfunc_item_fuel();
1829                 return;
1830         }
1831         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1832 }
1833
1834 void spawnfunc_item_jetpack(void)
1835 {
1836         if(g_grappling_hook)
1837                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1838         if(!self.ammo_fuel)
1839                 self.ammo_fuel = g_pickup_fuel_jetpack;
1840         if(start_items & IT_JETPACK)
1841         {
1842                 spawnfunc_item_fuel();
1843                 return;
1844         }
1845         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1846 }
1847
1848
1849 #define OP_SET 0
1850 #define OP_MIN 1
1851 #define OP_MAX 2
1852 #define OP_PLUS 3
1853 #define OP_MINUS 4
1854
1855 float GiveWeapon(entity e, float wpn, float op, float val)
1856 {
1857         float v0, v1;
1858         v0 = WEPSET_CONTAINS_EW(e, wpn);
1859         switch(op)
1860         {
1861                 case OP_SET:
1862                         if(val > 0)
1863                                 WEPSET_OR_EW(e, wpn);
1864                         else
1865                                 WEPSET_ANDNOT_EW(e, wpn);
1866                         break;
1867                 case OP_MIN:
1868                 case OP_PLUS:
1869                         if(val > 0)
1870                                 WEPSET_OR_EW(e, wpn);
1871                         break;
1872                 case OP_MAX:
1873                         if(val <= 0)
1874                                 WEPSET_ANDNOT_EW(e, wpn);
1875                         break;
1876                 case OP_MINUS:
1877                         if(val > 0)
1878                                 WEPSET_ANDNOT_EW(e, wpn);
1879                         break;
1880         }
1881         v1 = WEPSET_CONTAINS_EW(e, wpn);
1882         return (v0 != v1);
1883 }
1884
1885 float GiveBit(entity e, .float fld, float bit, float op, float val)
1886 {
1887         float v0, v1;
1888         v0 = (e.fld & bit);
1889         switch(op)
1890         {
1891                 case OP_SET:
1892                         if(val > 0)
1893                                 e.fld |= bit;
1894                         else
1895                                 e.fld &~= bit;
1896                         break;
1897                 case OP_MIN:
1898                 case OP_PLUS:
1899                         if(val > 0)
1900                                 e.fld |= bit;
1901                         break;
1902                 case OP_MAX:
1903                         if(val <= 0)
1904                                 e.fld &~= bit;
1905                         break;
1906                 case OP_MINUS:
1907                         if(val > 0)
1908                                 e.fld &~= bit;
1909                         break;
1910         }
1911         v1 = (e.fld & bit);
1912         return (v0 != v1);
1913 }
1914
1915 float GiveValue(entity e, .float fld, float op, float val)
1916 {
1917         float v0, v1;
1918         v0 = e.fld;
1919         switch(op)
1920         {
1921                 case OP_SET:
1922                         e.fld = val;
1923                         break;
1924                 case OP_MIN:
1925                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1926                         break;
1927                 case OP_MAX:
1928                         e.fld = min(e.fld, val);
1929                         break;
1930                 case OP_PLUS:
1931                         e.fld += val;
1932                         break;
1933                 case OP_MINUS:
1934                         e.fld -= val;
1935                         break;
1936         }
1937         v1 = e.fld;
1938         return (v0 != v1);
1939 }
1940
1941 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1942 {
1943         if(v1 == v0)
1944                 return;
1945         if(v1 <= v0 - t)
1946         {
1947                 if(snd_decr != "")
1948                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1949         }
1950         else if(v0 >= v0 + t)
1951         {
1952                 if(snd_incr != "")
1953                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1954         }
1955 }
1956
1957 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1958 {
1959         if(v0 < v1)
1960                 e.rotfield = max(e.rotfield, time + rottime);
1961         else if(v0 > v1)
1962                 e.regenfield = max(e.regenfield, time + regentime);
1963 }
1964
1965 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1966 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1967 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1968 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1969 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1970 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1971
1972 float GiveItems(entity e, float beginarg, float endarg)
1973 {
1974         float got, i, j, val, op;
1975         float _switchweapon;
1976         entity wi;
1977         string cmd;
1978
1979         val = 999;
1980         op = OP_SET;
1981
1982         got = 0;
1983
1984         _switchweapon = FALSE;
1985         if (e.autoswitch)
1986                 if (e.switchweapon == w_getbestweapon(e))
1987                         _switchweapon = TRUE;
1988
1989         e.strength_finished = max(0, e.strength_finished - time);
1990         e.invincible_finished = max(0, e.invincible_finished - time);
1991         e.superweapons_finished = max(0, e.superweapons_finished - time);
1992
1993         PREGIVE(e, items);
1994         PREGIVE_WEAPONS(e);
1995         PREGIVE(e, strength_finished);
1996         PREGIVE(e, invincible_finished);
1997         PREGIVE(e, superweapons_finished);
1998         PREGIVE(e, ammo_nails);
1999         PREGIVE(e, ammo_cells);
2000         PREGIVE(e, ammo_shells);
2001         PREGIVE(e, ammo_rockets);
2002         PREGIVE(e, ammo_fuel);
2003         PREGIVE(e, armorvalue);
2004         PREGIVE(e, health);
2005
2006         for(i = beginarg; i < endarg; ++i)
2007         {
2008                 cmd = argv(i);
2009
2010                 if(cmd == "0" || stof(cmd))
2011                 {
2012                         val = stof(cmd);
2013                         continue;
2014                 }
2015                 switch(cmd)
2016                 {
2017                         case "no":
2018                                 op = OP_MAX;
2019                                 val = 0;
2020                                 continue;
2021                         case "max":
2022                                 op = OP_MAX;
2023                                 continue;
2024                         case "min":
2025                                 op = OP_MIN;
2026                                 continue;
2027                         case "plus":
2028                                 op = OP_PLUS;
2029                                 continue;
2030                         case "minus":
2031                                 op = OP_MINUS;
2032                                 continue;
2033                         case "ALL":
2034                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2035                                 got += GiveValue(e, strength_finished, op, val);
2036                                 got += GiveValue(e, invincible_finished, op, val);
2037                                 got += GiveValue(e, superweapons_finished, op, val);
2038                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2039                         case "all":
2040                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2041                                 got += GiveValue(e, health, op, val);
2042                                 got += GiveValue(e, armorvalue, op, val);
2043                         case "allweapons":
2044                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2045                                 {
2046                                         wi = get_weaponinfo(j);
2047                                         if(wi.weapon)
2048                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
2049                                                         got += GiveWeapon(e, j, op, val);
2050                                 }
2051                         case "allammo":
2052                                 got += GiveValue(e, ammo_cells, op, val);
2053                                 got += GiveValue(e, ammo_shells, op, val);
2054                                 got += GiveValue(e, ammo_nails, op, val);
2055                                 got += GiveValue(e, ammo_rockets, op, val);
2056                                 got += GiveValue(e, ammo_fuel, op, val);
2057                                 break;
2058                         case "unlimited_ammo":
2059                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2060                                 break;
2061                         case "unlimited_weapon_ammo":
2062                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
2063                                 break;
2064                         case "unlimited_superweapons":
2065                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
2066                                 break;
2067                         case "jetpack":
2068                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2069                                 break;
2070                         case "fuel_regen":
2071                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2072                                 break;
2073                         case "strength":
2074                                 got += GiveValue(e, strength_finished, op, val);
2075                                 break;
2076                         case "invincible":
2077                                 got += GiveValue(e, invincible_finished, op, val);
2078                                 break;
2079                         case "superweapons":
2080                                 got += GiveValue(e, superweapons_finished, op, val);
2081                                 break;
2082                         case "cells":
2083                                 got += GiveValue(e, ammo_cells, op, val);
2084                                 break;
2085                         case "shells":
2086                                 got += GiveValue(e, ammo_shells, op, val);
2087                                 break;
2088                         case "nails":
2089                         case "bullets":
2090                                 got += GiveValue(e, ammo_nails, op, val);
2091                                 break;
2092                         case "rockets":
2093                                 got += GiveValue(e, ammo_rockets, op, val);
2094                                 break;
2095                         case "health":
2096                                 got += GiveValue(e, health, op, val);
2097                                 break;
2098                         case "armor":
2099                                 got += GiveValue(e, armorvalue, op, val);
2100                                 break;
2101                         case "fuel":
2102                                 got += GiveValue(e, ammo_fuel, op, val);
2103                                 break;
2104                         default:
2105                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2106                                 {
2107                                         wi = get_weaponinfo(j);
2108                                         if(cmd == wi.netname)
2109                                         {
2110                                                 got += GiveWeapon(e, j, op, val);
2111                                                 break;
2112                                         }
2113                                 }
2114                                 if(j > WEP_LAST)
2115                                         print("give: invalid item ", cmd, "\n");
2116                                 break;
2117                 }
2118                 val = 999;
2119                 op = OP_SET;
2120         }
2121
2122         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
2123         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
2124         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
2125         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
2126         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2127         {
2128                 wi = get_weaponinfo(j);
2129                 if(wi.weapon)
2130                 {
2131                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
2132                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
2133                                 if(WEPSET_CONTAINS_EW(e, j))
2134                                         weapon_action(wi.weapon, WR_PRECACHE);
2135                 }
2136         }
2137         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2138         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2139         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2140         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2141         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2142         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2143         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2144         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2145         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2146
2147         if(e.superweapons_finished <= 0)
2148                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
2149                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2150
2151         if (g_minstagib)
2152         {
2153                 e.health = bound(0, e.health, 100);
2154                 e.armorvalue = bound(0, e.armorvalue, 999);
2155         }
2156
2157         if(e.strength_finished <= 0)
2158                 e.strength_finished = 0;
2159         else
2160                 e.strength_finished += time;
2161         if(e.invincible_finished <= 0)
2162                 e.invincible_finished = 0;
2163         else
2164                 e.invincible_finished += time;
2165         if(e.superweapons_finished <= 0)
2166                 e.superweapons_finished = 0;
2167         else
2168                 e.superweapons_finished += time;
2169
2170         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
2171                 _switchweapon = TRUE;
2172         if(_switchweapon)
2173                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2174
2175         return got;
2176 }
2177 #endif