qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.items == IT_STRENGTH || self.items == IT_INVINCIBLE)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(name)
 237                         {
 238                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 239                                 if(self.waypointsprite_attached)
 240                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 241                         }
 242                 }
 243                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 244                 if(self.waypointsprite_attached)
 245                 {
 246                         WaypointSprite_Ping(self.waypointsprite_attached);
 247                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 248                 }
 249         }
 250 }
 251
 252 void Item_ScheduleRespawnIn(entity e, float t)
 253 {
 254         if(e.flags & FL_POWERUP)
 255         {
 256                 e.think = Item_RespawnCountdown;
 257                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 258                 e.count = 0;
 259         }
 260         else
 261         {
 262                 e.think = Item_Respawn;
 263                 e.nextthink = time + t;
 264         }
 265 }
 266
 267 void Item_ScheduleRespawn(entity e)
 268 {
 269         if(e.respawntime > 0)
 270         {
 271                 Item_Show(e, 0);
 272                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 273         }
 274         else // if respawntime is -1, this item does not respawn
 275                 Item_Show(e, -1);
 276 }
 277
 278 void Item_ScheduleInitialRespawn(entity e)
 279 {
 280         Item_Show(e, 0);
 281         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 282 }
 283
 284 float Item_GiveTo(entity item, entity player)
 285 {
 286         float _switchweapon;
 287         float pickedup;
 288         float it;
 289         float i;
 290         entity e;
 291
 292         // if nothing happens to player, just return without taking the item
 293         pickedup = FALSE;
 294         _switchweapon = FALSE;
 295
 296         if (g_minstagib)
 297         {
 298                 if(item.spawnshieldtime)
 299                 {
 300                         if (item.ammo_fuel)
 301                         if (player.ammo_fuel < g_pickup_fuel_max)
 302                         {
 303                                 pickedup = TRUE;
 304                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 305                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 306                         }
 307                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 308                         {
 309                                 pickedup = TRUE;
 310                                 player.items |= it;
 311                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 312                         }
 313
 314                         _switchweapon = TRUE;
 315                         if (item.ammo_cells)
 316                         {
 317                                 pickedup = TRUE;
 318                                 // play some cool sounds ;)
 319                                 if (clienttype(player) == CLIENTTYPE_REAL)
 320                                 {
 321                                         if(player.health <= 5)
 322                                                 AnnounceTo(player, "lastsecond");
 323                                         else if(player.health < 50)
 324                                                 AnnounceTo(player, "narrowly");
 325                                 }
 326                                 // sound not available
 327                                 // else if(item.items == IT_CELLS)
 328                                 //      AnnounceTo(player, "ammo");
 329
 330                                 if (item.weapons & WEPBIT_MINSTANEX)
 331                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 332                                 if (item.ammo_cells)
 333                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 334                                 player.health = 100;
 335                         }
 336
 337                         // extralife powerup
 338                         if (item.max_health)
 339                         {
 340                                 pickedup = TRUE;
 341                                 // sound not available
 342                                 // AnnounceTo(player, "_lives");
 343                                 player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 344                                 sprint(player, "^3You picked up some extra lives\n");
 345                         }
 346
 347                         // invis powerup
 348                         if (item.strength_finished)
 349                         {
 350                                 pickedup = TRUE;
 351                                 // sound not available
 352                                 // AnnounceTo(player, "invisible");
 353                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 354                         }
 355
 356                         // speed powerup
 357                         if (item.invincible_finished)
 358                         {
 359                                 pickedup = TRUE;
 360                                 // sound not available
 361                                 // AnnounceTo(player, "speed");
 362                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 363                         }
 364                 }
 365         }
 366         else
 367         {
 368                 if (g_weapon_stay == 1)
 369                 if not(item.flags & FL_NO_WEAPON_STAY)
 370                 if (item.flags & FL_WEAPON)
 371                 {
 372                         if(item.classname == "droppedweapon")
 373                         {
 374                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 375                                         goto skip;
 376                         }
 377                         else
 378                         {
 379                                 if (player.weapons & item.weapons)
 380                                         goto skip;
 381                         }
 382                 }
 383
 384                 // in case the player has autoswitch enabled do the following:
 385                 // if the player is using their best weapon before items are given, they
 386                 // probably want to switch to an even better weapon after items are given
 387                 if (player.autoswitch)
 388                 if (player.switchweapon == w_getbestweapon(player))
 389                         _switchweapon = TRUE;
 390
 391                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 392                         _switchweapon = TRUE;
 393
 394                 if(item.spawnshieldtime)
 395                 {
 396                         if (item.ammo_shells)
 397                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 398                         {
 399                                 pickedup = TRUE;
 400                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 401                         }
 402                         if (item.ammo_nails)
 403                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 404                         {
 405                                 pickedup = TRUE;
 406                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 407                         }
 408                         if (item.ammo_rockets)
 409                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 410                         {
 411                                 pickedup = TRUE;
 412                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 413                         }
 414                         if (item.ammo_cells)
 415                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 416                         {
 417                                 pickedup = TRUE;
 418                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 419                         }
 420                         if (item.ammo_fuel)
 421                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 422                         {
 423                                 pickedup = TRUE;
 424                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 425                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 426                         }
 427                 }
 428
 429                 if (item.flags & FL_WEAPON)
 430                         if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway && g_weapon_stay == 0))
 431                 {
 432                         pickedup = TRUE;
 433                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 434                         {
 435                                 e = get_weaponinfo(i);
 436                                 if(it & e.weapons)
 437                                         W_GiveWeapon (player, e.weapon, item.netname);
 438                         }
 439                 }
 440
 441                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 442                 {
 443                         pickedup = TRUE;
 444                         player.items |= it;
 445                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 446                 }
 447
 448                 if(item.spawnshieldtime)
 449                 {
 450                         if (item.strength_finished)
 451                         {
 452                                 pickedup = TRUE;
 453                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 454                         }
 455                         if (item.invincible_finished)
 456                         {
 457                                 pickedup = TRUE;
 458                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 459                         }
 460
 461                         if (item.health)
 462                         if ((player.health < item.max_health) || item.pickup_anyway)
 463                         {
 464                                 pickedup = TRUE;
 465                                 player.health = bound(player.health, item.max_health, player.health + item.health);
 466                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 467                         }
 468                         if (item.armorvalue)
 469                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 470                         {
 471                                 pickedup = TRUE;
 472                                 player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 473                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 474                         }
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 487         if (_switchweapon)
 488                 if (player.switchweapon != w_getbestweapon(player))
 489                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 490
 491         return 1;
 492 }
 493
 494 void Item_Touch (void)
 495 {
 496         entity e, head;
 497
 498         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 499         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 500         {
 501                 remove(self);
 502                 return;
 503         }
 504         if (other.classname != "player")
 505                 return;
 506         if (other.deadflag)
 507                 return;
 508         if (self.solid != SOLID_TRIGGER)
 509                 return;
 510         if (self.owner == other)
 511                 return;
 512
 513         if(!Item_GiveTo(self, other))
 514                 return;
 515
 516         other.last_pickup = time;
 517
 518         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 519
 520         if (self.classname == "droppedweapon")
 521                 remove (self);
 522         else if not(self.spawnshieldtime)
 523                 return;
 524         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 525                 return;
 526         else
 527         {
 528                 if(self.team)
 529                 {
 530                         RandomSelection_Init();
 531                         for(head = world; (head = findfloat(head, team, self.team)); )
 532                         {
 533                                 if(head.flags & FL_ITEM)
 534                                 {
 535                                         Item_Show(head, -1);
 536                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 537                                 }
 538                         }
 539                         e = RandomSelection_chosen_ent;
 540                 }
 541                 else
 542                         e = self;
 543                 Item_ScheduleRespawn(e);
 544         }
 545 }
 546
 547 void Item_FindTeam()
 548 {
 549         entity head, e;
 550
 551         if(self.effects & EF_NODRAW)
 552         {
 553                 // marker for item team search
 554                 dprint("Initializing item team ", ftos(self.team), "\n");
 555                 RandomSelection_Init();
 556                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 557                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 558                 e = RandomSelection_chosen_ent;
 559                 e.state = 0;
 560                 Item_Show(e, 1);
 561
 562                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 563                 {
 564                         if(head != e)
 565                         {
 566                                 // make it a non-spawned item
 567                                 Item_Show(head, -1);
 568                                 head.state = 1; // state 1 = initially hidden item
 569                         }
 570                         head.effects &~= EF_NODRAW;
 571                 }
 572
 573                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 574                         Item_ScheduleInitialRespawn(e);
 575         }
 576 }
 577
 578 void Item_Reset()
 579 {
 580         Item_Show(self, !self.state);
 581         setorigin (self, self.origin);
 582         self.think = SUB_Null;
 583         self.nextthink = 0;
 584
 585         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 586                 Item_ScheduleInitialRespawn(self);
 587 }
 588
 589 // Savage: used for item garbage-collection
 590 // TODO: perhaps nice special effect?
 591 void RemoveItem(void)
 592 {
 593         remove(self);
 594 }
 595
 596 // pickup evaluation functions
 597 // these functions decide how desirable an item is to the bots
 598
 599 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 600
 601 float weapon_pickupevalfunc(entity player, entity item)
 602 {
 603         float c, i, j, position;
 604
 605         // See if I have it already
 606         if(player.weapons & item.weapons == item.weapons)
 607         {
 608                 // If I can pick it up
 609                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 610                         c = 0;
 611                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 612                 {
 613                         // Skilled bots will grab more
 614                         c = bound(0, skill / 10, 1) * 0.5;
 615                 }
 616                 else
 617                         c = 0;
 618         }
 619         else
 620                 c = 1;
 621
 622         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 623         if( bot_custom_weapon && c )
 624         {
 625                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 626                 {
 627                         // Find weapon
 628                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 629                                 continue;
 630
 631                         // Find the highest position on any range
 632                         position = -1;
 633                         for(j = 0; j < WEP_LAST ; ++j){
 634                                 if(
 635                                                 bot_weapons_far[j] == i ||
 636                                                 bot_weapons_mid[j] == i ||
 637                                                 bot_weapons_close[j] == i
 638                                   )
 639                                 {
 640                                         position = j;
 641                                         break;
 642                                 }
 643                         }
 644
 645                         // Rate it
 646                         if (position >= 0 )
 647                         {
 648                                 position = WEP_LAST - position;
 649                                 // item.bot_pickupbasevalue is overwritten here
 650                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 651                         }
 652                 }
 653         }
 654
 655         return item.bot_pickupbasevalue * c;
 656 }
 657
 658 float commodity_pickupevalfunc(entity player, entity item)
 659 {
 660         float c, i, need_shells, need_nails, need_rockets, need_cells;
 661         entity wi;
 662         c = 0;
 663
 664         // Detect needed ammo
 665         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 666         {
 667                 wi = get_weaponinfo(i);
 668
 669                 if not(wi.weapons & player.weapons)
 670                         continue;
 671
 672                 if(wi.items & IT_SHELLS)
 673                         need_shells = TRUE;
 674                 else if(wi.items & IT_NAILS)
 675                         need_nails = TRUE;
 676                 else if(wi.items & IT_ROCKETS)
 677                         need_rockets = TRUE;
 678                 else if(wi.items & IT_CELLS)
 679                         need_cells = TRUE;
 680         }
 681
 682         // TODO: figure out if the player even has the weapon this ammo is for?
 683         // may not affect strategy much though...
 684         // find out how much more ammo/armor/health the player can hold
 685         if (need_shells)
 686         if (item.ammo_shells)
 687         if (player.ammo_shells < g_pickup_shells_max)
 688                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 689         if (need_nails)
 690         if (item.ammo_nails)
 691         if (player.ammo_nails < g_pickup_nails_max)
 692                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 693         if (need_rockets)
 694         if (item.ammo_rockets)
 695         if (player.ammo_rockets < g_pickup_rockets_max)
 696                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 697         if (need_cells)
 698         if (item.ammo_cells)
 699         if (player.ammo_cells < g_pickup_cells_max)
 700                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 701         if (item.armorvalue)
 702         if (player.armorvalue < item.max_armorvalue)
 703                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 704         if (item.health)
 705         if (player.health < item.max_health)
 706                 c = c + max(0, 1 - player.health / item.max_health);
 707
 708         return item.bot_pickupbasevalue * c;
 709 }
 710
 711
 712 .float is_item;
 713 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 714 {
 715         startitem_failed = FALSE;
 716
 717         self.items = itemid;
 718         self.weapons = weaponid;
 719
 720         // is it a dropped weapon?
 721         if (self.classname == "droppedweapon")
 722         {
 723                 self.reset = SUB_Remove;
 724                 // it's a dropped weapon
 725                 self.movetype = MOVETYPE_TOSS;
 726                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 727                 self.think = RemoveItem;
 728                 self.nextthink = time + 60;
 729                 // don't drop if in a NODROP zone (such as lava)
 730                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 731                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 732                 {
 733                         startitem_failed = TRUE;
 734                         remove(self);
 735                         return;
 736                 }
 737         }
 738         else
 739         {
 740                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 741                 {
 742                         startitem_failed = TRUE;
 743                         remove(self);
 744                         return;
 745                 }
 746
 747                 if(!have_pickup_item())
 748                 {
 749                         startitem_failed = TRUE;
 750                         remove (self);
 751                         return;
 752                 }
 753
 754                 self.reset = Item_Reset;
 755                 // it's a level item
 756                 if(self.spawnflags & 1)
 757                         self.noalign = 1;
 758                 if (self.noalign)
 759                         self.movetype = MOVETYPE_NONE;
 760                 else
 761                         self.movetype = MOVETYPE_TOSS;
 762                 // do item filtering according to game mode and other things
 763                 if (!self.noalign)
 764                 {
 765                         // first nudge it off the floor a little bit to avoid math errors
 766                         setorigin(self, self.origin + '0 0 1');
 767                         // set item size before we spawn a spawnfunc_waypoint
 768                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 769                                 setsize (self, '-16 -16 0', '16 16 48');
 770                         else
 771                                 setsize (self, '-16 -16 0', '16 16 32');
 772                         // note droptofloor returns FALSE if stuck/or would fall too far
 773                         droptofloor();
 774                         waypoint_spawnforitem(self);
 775                 }
 776
 777                 /*
 778                  * can't do it that way, as it would break maps
 779                  * TODO make a target_give like entity another way, that perhaps has
 780                  * the weapon name in a key
 781                 if(self.targetname)
 782                 {
 783                         // target_give not yet supported; maybe later
 784                         print("removed targeted ", self.classname, "\n");
 785                         startitem_failed = TRUE;
 786                         remove (self);
 787                         return;
 788                 }
 789                 */
 790
 791                 if(autocvar_spawn_debug >= 2)
 792                 {
 793                         entity otheritem;
 794                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 795                         {
 796                                 if(otheritem.is_item)
 797                                 {
 798                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 799                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 800                                         error("Mapper sucks.");
 801                                 }
 802                         }
 803                         self.is_item = TRUE;
 804                 }
 805
 806                 weaponsInMap |= weaponid;
 807
 808                 precache_model (itemmodel);
 809                 precache_sound (pickupsound);
 810
 811                 precache_sound ("misc/itemrespawncountdown.wav");
 812                 if(!g_minstagib && itemid == IT_STRENGTH)
 813                         precache_sound ("misc/strength_respawn.wav");
 814                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 815                         precache_sound ("misc/shield_respawn.wav");
 816                 else
 817                         precache_sound ("misc/itemrespawn.wav");
 818
 819                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 820                         self.target = "###item###"; // for finding the nearest item using find()
 821         }
 822
 823         self.bot_pickup = TRUE;
 824         self.bot_pickupevalfunc = pickupevalfunc;
 825         self.bot_pickupbasevalue = pickupbasevalue;
 826         self.mdl = itemmodel;
 827         self.item_pickupsound = pickupsound;
 828         // let mappers override respawntime
 829         if(!self.respawntime) // both set
 830         {
 831                 self.respawntime = defaultrespawntime;
 832                 self.respawntimejitter = defaultrespawntimejitter;
 833         }
 834         self.netname = itemname;
 835         self.flags = FL_ITEM | itemflags;
 836         self.touch = Item_Touch;
 837         setmodel (self, self.mdl); // precision set below
 838         self.effects |= EF_LOWPRECISION;
 839         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 840                 setsize (self, '-16 -16 0', '16 16 48');
 841         else
 842                 setsize (self, '-16 -16 0', '16 16 32');
 843         if(itemflags & FL_WEAPON)
 844                 self.modelflags |= MF_ROTATE;
 845
 846         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 847         if (itemflags & FL_WEAPON)
 848         {
 849                 // neutral team color for pickup weapons
 850                 self.colormap = 1024; // color shirt=0 pants=0 grey
 851         }
 852
 853         Item_Show(self, 1);
 854         self.state = 0;
 855         if(self.team)
 856         {
 857                 if(!self.cnt)
 858                         self.cnt = 1; // item probability weight
 859                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 860                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 861         }
 862         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 863                 Item_ScheduleInitialRespawn(self);
 864 }
 865
 866 /* replace items in minstagib
 867  * IT_STRENGTH   = invisibility
 868  * IT_NAILS      = extra lives
 869  * IT_INVINCIBLE = speed
 870  */
 871 void minstagib_items (float itemid)
 872 {
 873         float rnd;
 874         self.classname = "minstagib";
 875
 876         // replace rocket launchers and nex guns with ammo cells
 877         if (itemid == IT_CELLS)
 878         {
 879                 self.ammo_cells = 1;
 880                 StartItem ("models/items/a_cells.md3",
 881                         "misc/itempickup.wav", 45, 0,
 882                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 883                 return;
 884         }
 885
 886         // randomize
 887         rnd = random() * 3;
 888         if (rnd <= 1)
 889                 itemid = IT_STRENGTH;
 890         else if (rnd <= 2)
 891                 itemid = IT_NAILS;
 892         else
 893                 itemid = IT_INVINCIBLE;
 894
 895         // replace with invis
 896         if (itemid == IT_STRENGTH)
 897         {
 898                 self.strength_finished = 30;
 899                 StartItem ("models/items/g_strength.md3",
 900                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 901                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 902         }
 903         // replace with extra lives
 904         if (itemid == IT_NAILS)
 905         {
 906                 self.max_health = 1;
 907                 StartItem ("models/items/g_h100.md3",
 908                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 909                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 910         }
 911         // replace with speed
 912         if (itemid == IT_INVINCIBLE)
 913         {
 914                 self.invincible_finished = 30;
 915                 StartItem ("models/items/g_invincible.md3",
 916                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 917                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 918         }
 919 }
 920
 921 float minst_no_auto_cells;
 922 void minst_remove_item (void) {
 923         if(minst_no_auto_cells)
 924                 remove(self);
 925 }
 926
 927 float weaponswapping;
 928 float internalteam;
 929
 930 void weapon_defaultspawnfunc(float wpn)
 931 {
 932         entity e;
 933         float t;
 934         var .float ammofield;
 935         string s;
 936         entity oldself;
 937         float i, j;
 938
 939         // set the respawntime in advance (so replaced weapons can copy it)
 940
 941         if(!self.respawntime)
 942         {
 943                 e = get_weaponinfo(wpn);
 944                 if(e.items == IT_SUPERWEAPON)
 945                 {
 946                         self.respawntime = g_pickup_respawntime_powerup;
 947                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 948                 }
 949                 else
 950                 {
 951                         self.respawntime = g_pickup_respawntime_weapon;
 952                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 953                 }
 954         }
 955
 956         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 957         {
 958                 e = get_weaponinfo(wpn);
 959                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 960                 if(s == "0")
 961                 {
 962                         remove(self);
 963                         startitem_failed = TRUE;
 964                         return;
 965                 }
 966                 t = tokenize_console(s);
 967                 if(t >= 2)
 968                 {
 969                         self.team = --internalteam;
 970                         oldself = self;
 971                         for(i = 1; i < t; ++i)
 972                         {
 973                                 s = argv(i);
 974                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 975                                 {
 976                                         e = get_weaponinfo(j);
 977                                         if(e.netname == s)
 978                                         {
 979                                                 self = spawn();
 980                                                 copyentity(oldself, self);
 981                                                 self.classname = "replacedweapon";
 982                                                 weapon_defaultspawnfunc(j);
 983                                                 break;
 984                                         }
 985                                 }
 986                                 if(j > WEP_LAST)
 987                                 {
 988                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 989                                 }
 990                         }
 991                         self = oldself;
 992                 }
 993                 if(t >= 1)
 994                 {
 995                         s = argv(0);
 996                         wpn = 0;
 997                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 998                         {
 999                                 e = get_weaponinfo(j);
1000                                 if(e.netname == s)
1001                                 {
1002                                         wpn = j;
1003                                         break;
1004                                 }
1005                         }
1006                         if(j > WEP_LAST)
1007                         {
1008                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1009                         }
1010                 }
1011                 if(wpn == 0)
1012                 {
1013                         remove(self);
1014                         startitem_failed = TRUE;
1015                         return;
1016                 }
1017         }
1018
1019         e = get_weaponinfo(wpn);
1020
1021         if(e.items && e.items != IT_SUPERWEAPON)
1022         {
1023                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1024                 {
1025                         if(e.items & j)
1026                         {
1027                                 ammofield = Item_CounterField(j);
1028                                 if(!self.ammofield)
1029                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1030                         }
1031                 }
1032         }
1033         else
1034         {
1035                 self.flags |= FL_NO_WEAPON_STAY;
1036         }
1037
1038         // weapon stay isn't supported for teamed weapons
1039         if(self.team)
1040                 self.flags |= FL_NO_WEAPON_STAY;
1041
1042         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1043         {
1044                 self.ammo_shells = 0;
1045                 self.ammo_nails = 0;
1046                 self.ammo_cells = 0;
1047                 self.ammo_rockets = 0;
1048                 // weapon stay 2: don't use ammo on weapon pickups; instead
1049                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1050         }
1051
1052         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1053         if (self.modelindex) // don't precache if self was removed
1054                 weapon_action(e.weapon, WR_PRECACHE);
1055 }
1056
1057 void spawnfunc_weapon_shotgun (void);
1058 void spawnfunc_weapon_uzi (void) {
1059         if(autocvar_sv_q3acompat_machineshotgunswap)
1060         if(self.classname != "droppedweapon")
1061         {
1062                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1063                 return;
1064         }
1065         weapon_defaultspawnfunc(WEP_UZI);
1066 }
1067
1068 void spawnfunc_weapon_shotgun (void) {
1069         if(autocvar_sv_q3acompat_machineshotgunswap)
1070         if(self.classname != "droppedweapon")
1071         {
1072                 weapon_defaultspawnfunc(WEP_UZI);
1073                 return;
1074         }
1075         weapon_defaultspawnfunc(WEP_SHOTGUN);
1076 }
1077
1078 void spawnfunc_weapon_nex (void)
1079 {
1080         if (g_minstagib)
1081         {
1082                 minstagib_items(IT_CELLS);
1083                 self.think = minst_remove_item;
1084                 self.nextthink = time;
1085                 return;
1086         }
1087         weapon_defaultspawnfunc(WEP_NEX);
1088 }
1089
1090 void spawnfunc_weapon_minstanex (void)
1091 {
1092         if (g_minstagib)
1093         {
1094                 minstagib_items(IT_CELLS);
1095                 self.think = minst_remove_item;
1096                 self.nextthink = time;
1097                 return;
1098         }
1099         weapon_defaultspawnfunc(WEP_MINSTANEX);
1100 }
1101
1102 void spawnfunc_weapon_rocketlauncher (void)
1103 {
1104         if (g_minstagib)
1105         {
1106                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1107                 self.think = minst_remove_item;
1108                 self.nextthink = time;
1109                 return;
1110         }
1111         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1112 }
1113
1114 void spawnfunc_item_rockets (void) {
1115         if(!self.ammo_rockets)
1116                 self.ammo_rockets = g_pickup_rockets;
1117         if(!self.pickup_anyway)
1118                 self.pickup_anyway = g_pickup_ammo_anyway;
1119         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1120 }
1121
1122 void spawnfunc_item_shells (void);
1123 void spawnfunc_item_bullets (void) {
1124         if(!weaponswapping)
1125         if(autocvar_sv_q3acompat_machineshotgunswap)
1126         if(self.classname != "droppedweapon")
1127         {
1128                 weaponswapping = TRUE;
1129                 spawnfunc_item_shells();
1130                 weaponswapping = FALSE;
1131                 return;
1132         }
1133
1134         if(!self.ammo_nails)
1135                 self.ammo_nails = g_pickup_nails;
1136         if(!self.pickup_anyway)
1137                 self.pickup_anyway = g_pickup_ammo_anyway;
1138         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1139 }
1140
1141 void spawnfunc_item_cells (void) {
1142         if(!self.ammo_cells)
1143                 self.ammo_cells = g_pickup_cells;
1144         if(!self.pickup_anyway)
1145                 self.pickup_anyway = g_pickup_ammo_anyway;
1146         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1147 }
1148
1149 void spawnfunc_item_shells (void) {
1150         if(!weaponswapping)
1151         if(autocvar_sv_q3acompat_machineshotgunswap)
1152         if(self.classname != "droppedweapon")
1153         {
1154                 weaponswapping = TRUE;
1155                 spawnfunc_item_bullets();
1156                 weaponswapping = FALSE;
1157                 return;
1158         }
1159
1160         if(!self.ammo_shells)
1161                 self.ammo_shells = g_pickup_shells;
1162         if(!self.pickup_anyway)
1163                 self.pickup_anyway = g_pickup_ammo_anyway;
1164         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1165 }
1166
1167 void spawnfunc_item_armor_small (void) {
1168         if(!self.armorvalue)
1169                 self.armorvalue = g_pickup_armorsmall;
1170         if(!self.max_armorvalue)
1171                 self.max_armorvalue = g_pickup_armorsmall_max;
1172         if(!self.pickup_anyway)
1173                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1174         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1175 }
1176
1177 void spawnfunc_item_armor_medium (void) {
1178         if(!self.armorvalue)
1179                 self.armorvalue = g_pickup_armormedium;
1180         if(!self.max_armorvalue)
1181                 self.max_armorvalue = g_pickup_armormedium_max;
1182         if(!self.pickup_anyway)
1183                 self.pickup_anyway = g_pickup_armormedium_anyway;
1184         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1185 }
1186
1187 void spawnfunc_item_armor_big (void) {
1188         if(!self.armorvalue)
1189                 self.armorvalue = g_pickup_armorbig;
1190         if(!self.max_armorvalue)
1191                 self.max_armorvalue = g_pickup_armorbig_max;
1192         if(!self.pickup_anyway)
1193                 self.pickup_anyway = g_pickup_armorbig_anyway;
1194         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1195 }
1196
1197 void spawnfunc_item_armor_large (void) {
1198         if(!self.armorvalue)
1199                 self.armorvalue = g_pickup_armorlarge;
1200         if(!self.max_armorvalue)
1201                 self.max_armorvalue = g_pickup_armorlarge_max;
1202         if(!self.pickup_anyway)
1203                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1204         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1205 }
1206
1207 void spawnfunc_item_health_small (void) {
1208         if(!self.max_health)
1209                 self.max_health = g_pickup_healthsmall_max;
1210         if(!self.health)
1211                 self.health = g_pickup_healthsmall;
1212         if(!self.pickup_anyway)
1213                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1214         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1215 }
1216
1217 void spawnfunc_item_health_medium (void) {
1218         if(!self.max_health)
1219                 self.max_health = g_pickup_healthmedium_max;
1220         if(!self.health)
1221                 self.health = g_pickup_healthmedium;
1222         if(!self.pickup_anyway)
1223                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1224         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1225 }
1226
1227 void spawnfunc_item_health_large (void) {
1228         if(!self.max_health)
1229                 self.max_health = g_pickup_healthlarge_max;
1230         if(!self.health)
1231                 self.health = g_pickup_healthlarge;
1232         if(!self.pickup_anyway)
1233                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1234         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1235 }
1236
1237 void spawnfunc_item_health_mega (void) {
1238         if(g_minstagib) {
1239                 minstagib_items(IT_NAILS);
1240         } else {
1241                 if(!self.max_health)
1242                         self.max_health = g_pickup_healthmega_max;
1243                 if(!self.health)
1244                         self.health = g_pickup_healthmega;
1245                 if(!self.pickup_anyway)
1246                         self.pickup_anyway = g_pickup_healthmega_anyway;
1247                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1248         }
1249 }
1250
1251 // support old misnamed entities
1252 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1253 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1254 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1255 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1256 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1257
1258 void spawnfunc_item_strength (void) {
1259         if(g_minstagib) {
1260                 minstagib_items(IT_STRENGTH);
1261         } else {
1262                 precache_sound("weapons/strength_fire.wav");
1263                 self.strength_finished = 30;
1264                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1265         }
1266 }
1267
1268 void spawnfunc_item_invincible (void) {
1269         if(g_minstagib) {
1270                 minstagib_items(IT_INVINCIBLE);
1271         } else {
1272                 self.invincible_finished = 30;
1273                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1274         }
1275 }
1276
1277 void spawnfunc_item_minst_cells (void) {
1278         if (g_minstagib)
1279         {
1280                 minst_no_auto_cells = 1;
1281                 minstagib_items(IT_CELLS);
1282         }
1283         else
1284                 remove(self);
1285 }
1286
1287 // compatibility:
1288 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1289
1290 float GiveItems(entity e, float beginarg, float endarg);
1291 void target_items_use (void)
1292 {
1293         if(activator.classname == "droppedweapon")
1294         {
1295                 EXACTTRIGGER_TOUCH;
1296                 remove(activator);
1297                 return;
1298         }
1299
1300         if(activator.classname != "player")
1301                 return;
1302         if(activator.deadflag != DEAD_NO)
1303                 return;
1304         EXACTTRIGGER_TOUCH;
1305
1306         entity e;
1307         for(e = world; (e = find(e, classname, "droppedweapon")); )
1308                 if(e.enemy == activator)
1309                         remove(e);
1310
1311         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1312                 centerprint(activator, self.message);
1313 }
1314
1315 void spawnfunc_target_items (void)
1316 {
1317         float n, i, j;
1318         entity e;
1319
1320         self.use = target_items_use;
1321         if(!self.strength_finished)
1322                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1323         if(!self.invincible_finished)
1324                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1325
1326         precache_sound("misc/itempickup.wav");
1327         precache_sound("misc/megahealth.wav");
1328         precache_sound("misc/armor25.wav");
1329         precache_sound("misc/powerup.wav");
1330         precache_sound("misc/poweroff.wav");
1331         precache_sound("weapons/weaponpickup.wav");
1332
1333         n = tokenize_console(self.netname);
1334         if(argv(0) == "give")
1335         {
1336                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1337         }
1338         else
1339         {
1340                 for(i = 0; i < n; ++i)
1341                 {
1342                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1343                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1344                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1345                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1346                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1347                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1348                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1349                         else
1350                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1351                         {
1352                                 e = get_weaponinfo(j);
1353                                 if(argv(i) == e.netname)
1354                                 {
1355                                         self.weapons |= e.weapons;
1356                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1357                                                 weapon_action(e.weapon, WR_PRECACHE);
1358                                         break;
1359                                 }
1360                         }
1361                         if(j > WEP_LAST)
1362                                 print("target_items: invalid item ", argv(i), "\n");
1363                 }
1364
1365                 string itemprefix, valueprefix;
1366                 if(self.spawnflags == 0)
1367                 {
1368                         itemprefix = "";
1369                         valueprefix = "";
1370                 }
1371                 else if(self.spawnflags == 1)
1372                 {
1373                         itemprefix = "max ";
1374                         valueprefix = "max ";
1375                 }
1376                 else if(self.spawnflags == 2)
1377                 {
1378                         itemprefix = "min ";
1379                         valueprefix = "min ";
1380                 }
1381                 else if(self.spawnflags == 4)
1382                 {
1383                         itemprefix = "minus ";
1384                         valueprefix = "max ";
1385                 }
1386                 else
1387                         error("invalid spawnflags");
1388
1389                 self.netname = "";
1390                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1391                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1392                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1393                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1394                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1395                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1396                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1397                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1398                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1399                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1400                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1401                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1402                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1403                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1404                 {
1405                         e = get_weaponinfo(j);
1406                         if(e.weapons)
1407                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1408                 }
1409         }
1410         self.netname = strzone(self.netname);
1411         //print(self.netname, "\n");
1412
1413         n = tokenize_console(self.netname);
1414         for(i = 0; i < n; ++i)
1415         {
1416                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1417                 {
1418                         e = get_weaponinfo(j);
1419                         if(argv(i) == e.netname)
1420                         {
1421                                 weapon_action(e.weapon, WR_PRECACHE);
1422                                 break;
1423                         }
1424                 }
1425         }
1426 }
1427
1428 void spawnfunc_item_fuel(void)
1429 {
1430         if(!self.ammo_fuel)
1431                 self.ammo_fuel = g_pickup_fuel;
1432         if(!self.pickup_anyway)
1433                 self.pickup_anyway = g_pickup_ammo_anyway;
1434         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1435 }
1436
1437 void spawnfunc_item_fuel_regen(void)
1438 {
1439         if(start_items & IT_FUEL_REGEN)
1440         {
1441                 spawnfunc_item_fuel();
1442                 return;
1443         }
1444         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1445 }
1446
1447 void spawnfunc_item_jetpack(void)
1448 {
1449         if(g_grappling_hook)
1450                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1451         if(!self.ammo_fuel)
1452                 self.ammo_fuel = g_pickup_fuel_jetpack;
1453         if(start_items & IT_JETPACK)
1454         {
1455                 spawnfunc_item_fuel();
1456                 return;
1457         }
1458         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1459 }
1460
1461
1462 #define OP_SET 0
1463 #define OP_MIN 1
1464 #define OP_MAX 2
1465 #define OP_PLUS 3
1466 #define OP_MINUS 4
1467
1468 float GiveBit(entity e, .float fld, float bit, float op, float val)
1469 {
1470         float v0, v1;
1471         v0 = (e.fld & bit);
1472         switch(op)
1473         {
1474                 case OP_SET:
1475                         if(val > 0)
1476                                 e.fld |= bit;
1477                         else
1478                                 e.fld &~= bit;
1479                         break;
1480                 case OP_MIN:
1481                 case OP_PLUS:
1482                         if(val > 0)
1483                                 e.fld |= bit;
1484                         break;
1485                 case OP_MAX:
1486                         if(val <= 0)
1487                                 e.fld &~= bit;
1488                         break;
1489                 case OP_MINUS:
1490                         if(val > 0)
1491                                 e.fld &~= bit;
1492                         break;
1493         }
1494         v1 = (e.fld & bit);
1495         return (v0 != v1);
1496 }
1497
1498 float GiveValue(entity e, .float fld, float op, float val)
1499 {
1500         float v0, v1;
1501         v0 = e.fld;
1502         switch(op)
1503         {
1504                 case OP_SET:
1505                         e.fld = val;
1506                         break;
1507                 case OP_MIN:
1508                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1509                         break;
1510                 case OP_MAX:
1511                         e.fld = min(e.fld, val);
1512                         break;
1513                 case OP_PLUS:
1514                         e.fld += val;
1515                         break;
1516                 case OP_MINUS:
1517                         e.fld -= val;
1518                         break;
1519         }
1520         v1 = e.fld;
1521         return (v0 != v1);
1522 }
1523
1524 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1525 {
1526         if(v1 == v0)
1527                 return;
1528         if(v1 <= v0 - t)
1529         {
1530                 if(snd_decr != "")
1531                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1532         }
1533         else if(v0 >= v0 + t)
1534         {
1535                 if(snd_incr != "")
1536                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1537         }
1538 }
1539
1540 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1541 {
1542         if(v0 < v1)
1543                 e.rotfield = max(e.rotfield, time + rottime);
1544         else if(v0 > v1)
1545                 e.regenfield = max(e.regenfield, time + regentime);
1546 }
1547
1548 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1549 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1550 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1551 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1552
1553 float GiveItems(entity e, float beginarg, float endarg)
1554 {
1555         float got, i, j, val, op;
1556         float _switchweapon;
1557         entity wi;
1558         string cmd;
1559
1560         val = 999;
1561         op = OP_SET;
1562
1563         got = 0;
1564
1565         _switchweapon = FALSE;
1566         if (e.autoswitch)
1567                 if (e.switchweapon == w_getbestweapon(e))
1568                         _switchweapon = TRUE;
1569
1570         e.strength_finished = max(0, e.strength_finished - time);
1571         e.invincible_finished = max(0, e.invincible_finished - time);
1572
1573         PREGIVE(e, items);
1574         PREGIVE(e, weapons);
1575         PREGIVE(e, strength_finished);
1576         PREGIVE(e, invincible_finished);
1577         PREGIVE(e, ammo_nails);
1578         PREGIVE(e, ammo_cells);
1579         PREGIVE(e, ammo_shells);
1580         PREGIVE(e, ammo_rockets);
1581         PREGIVE(e, ammo_fuel);
1582         PREGIVE(e, armorvalue);
1583         PREGIVE(e, health);
1584
1585         for(i = beginarg; i < endarg; ++i)
1586         {
1587                 cmd = argv(i);
1588
1589                 if(cmd == "0" || stof(cmd))
1590                 {
1591                         val = stof(cmd);
1592                         continue;
1593                 }
1594                 switch(cmd)
1595                 {
1596                         case "no":
1597                                 op = OP_MAX;
1598                                 val = 0;
1599                                 continue;
1600                         case "max":
1601                                 op = OP_MAX;
1602                                 continue;
1603                         case "min":
1604                                 op = OP_MIN;
1605                                 continue;
1606                         case "plus":
1607                                 op = OP_PLUS;
1608                                 continue;
1609                         case "minus":
1610                                 op = OP_MINUS;
1611                                 continue;
1612                         case "ALL":
1613                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1614                                 got += GiveValue(e, strength_finished, op, time);
1615                                 got += GiveValue(e, invincible_finished, op, time);
1616                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1617                         case "all":
1618                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1619                                 got += GiveValue(e, health, op, val);
1620                                 got += GiveValue(e, armorvalue, op, val);
1621                         case "allweapons":
1622                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1623                                 {
1624                                         wi = get_weaponinfo(j);
1625                                         if(wi.weapons)
1626                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1627                                 }
1628                         case "allammo":
1629                                 got += GiveValue(e, ammo_cells, op, val);
1630                                 got += GiveValue(e, ammo_shells, op, val);
1631                                 got += GiveValue(e, ammo_nails, op, val);
1632                                 got += GiveValue(e, ammo_rockets, op, val);
1633                                 got += GiveValue(e, ammo_fuel, op, val);
1634                                 break;
1635                         case "unlimited_ammo":
1636                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1637                                 break;
1638                         case "unlimited_weapon_ammo":
1639                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1640                                 break;
1641                         case "unlimited_superweapons":
1642                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1643                                 break;
1644                         case "jetpack":
1645                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1646                                 break;
1647                         case "fuel_regen":
1648                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1649                                 break;
1650                         case "strength":
1651                                 got += GiveValue(e, strength_finished, op, val);
1652                                 break;
1653                         case "invincible":
1654                                 got += GiveValue(e, invincible_finished, op, val);
1655                                 break;
1656                         case "cells":
1657                                 got += GiveValue(e, ammo_cells, op, val);
1658                                 break;
1659                         case "shells":
1660                                 got += GiveValue(e, ammo_shells, op, val);
1661                                 break;
1662                         case "nails":
1663                         case "bullets":
1664                                 got += GiveValue(e, ammo_nails, op, val);
1665                                 break;
1666                         case "rockets":
1667                                 got += GiveValue(e, ammo_rockets, op, val);
1668                                 break;
1669                         case "health":
1670                                 got += GiveValue(e, health, op, val);
1671                                 break;
1672                         case "armor":
1673                                 got += GiveValue(e, armorvalue, op, val);
1674                                 break;
1675                         case "fuel":
1676                                 got += GiveValue(e, ammo_fuel, op, val);
1677                                 break;
1678                         default:
1679                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1680                                 {
1681                                         wi = get_weaponinfo(j);
1682                                         if(cmd == wi.netname)
1683                                         {
1684                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1685                                                 break;
1686                                         }
1687                                 }
1688                                 if(j > WEP_LAST)
1689                                         print("give: invalid item ", cmd, "\n");
1690                                 break;
1691                 }
1692                 val = 999;
1693                 op = OP_SET;
1694         }
1695
1696         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1697         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1698         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1699         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1700         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1701         {
1702                 wi = get_weaponinfo(j);
1703                 if(wi.weapons)
1704                 {
1705                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1706                         if not(save_weapons & wi.weapons)
1707                                 if(e.weapons & wi.weapons)
1708                                         weapon_action(wi.weapon, WR_PRECACHE);
1709                 }
1710         }
1711         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1712         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1713         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1714         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1715         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1716         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1717         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1718         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1719         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1720
1721         if (g_minstagib)
1722         {
1723                 e.health = bound(0, e.health, 100);
1724                 e.armorvalue = bound(0, e.armorvalue, 999);
1725         }
1726
1727         if(e.strength_finished <= 0)
1728                 e.strength_finished = 0;
1729         else
1730                 e.strength_finished += time;
1731         if(e.invincible_finished <= 0)
1732                 e.invincible_finished = 0;
1733         else
1734                 e.invincible_finished += time;
1735
1736         if not(e.weapons & W_WeaponBit(e.switchweapon))
1737                 _switchweapon = TRUE;
1738         if(_switchweapon)
1739                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1740
1741         return got;
1742 }