qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "waypointsprites.qh"
   9
  10     #include "bot/bot.qh"
  11     #include "bot/waypoints.qh"
  12
  13     #include "mutators/mutators_include.qh"
  14
  15     #include "weapons/common.qh"
  16     #include "weapons/selection.qh"
  17     #include "weapons/weaponsystem.qh"
  18
  19     #include "../common/constants.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "../common/notifications.qh"
  22         #include "../common/triggers/subs.qh"
  23     #include "../common/util.qh"
  24
  25     #include "../common/monsters/all.qh"
  26
  27     #include "../common/weapons/all.qh"
  28
  29     #include "../warpzonelib/util_server.qh"
  30 #endif
  31
  32 #ifdef CSQC
  33 void ItemDraw()
  34 {
  35     if(self.gravity)
  36     {
  37         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  38         if(self.move_flags & FL_ONGROUND)
  39         { // For some reason move_avelocity gets set to '0 0 0' here ...
  40             self.oldorigin = self.origin;
  41             self.gravity = 0;
  42
  43             if(autocvar_cl_animate_items)
  44             { // ... so reset it if animations are requested.
  45                 if(self.ItemStatus & ITS_ANIMATE1)
  46                     self.move_avelocity = '0 180 0';
  47
  48                 if(self.ItemStatus & ITS_ANIMATE2)
  49                     self.move_avelocity = '0 -90 0';
  50             }
  51         }
  52     }
  53     else if (autocvar_cl_animate_items)
  54     {
  55         if(self.ItemStatus & ITS_ANIMATE1)
  56         {
  57             self.angles += self.move_avelocity * frametime;
  58             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  59         }
  60
  61         if(self.ItemStatus & ITS_ANIMATE2)
  62         {
  63             self.angles += self.move_avelocity * frametime;
  64             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  65         }
  66     }
  67 }
  68
  69 void ItemDrawSimple()
  70 {
  71     if(self.gravity)
  72     {
  73         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74
  75         if(self.move_flags & FL_ONGROUND)
  76             self.gravity = 0;
  77     }
  78 }
  79
  80 void ItemRead(float _IsNew)
  81 {
  82     int sf = ReadByte();
  83
  84     if(sf & ISF_LOCATION)
  85     {
  86         self.origin_x = ReadCoord();
  87         self.origin_y = ReadCoord();
  88         self.origin_z = ReadCoord();
  89         setorigin(self, self.origin);
  90         self.oldorigin = self.origin;
  91     }
  92
  93     if(sf & ISF_ANGLES)
  94     {
  95         self.angles_x = ReadCoord();
  96         self.angles_y = ReadCoord();
  97         self.angles_z = ReadCoord();
  98         self.move_angles = self.angles;
  99     }
 100
 101     if(sf & ISF_SIZE)
 102     {
 103         self.mins_x = ReadCoord();
 104         self.mins_y = ReadCoord();
 105         self.mins_z = ReadCoord();
 106         self.maxs_x = ReadCoord();
 107         self.maxs_y = ReadCoord();
 108         self.maxs_z = ReadCoord();
 109         setsize(self, self.mins, self.maxs);
 110     }
 111
 112     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 113     {
 114         self.ItemStatus = ReadByte();
 115
 116         if(self.ItemStatus & ITS_AVAILABLE)
 117         {
 118             self.alpha = 1;
 119             self.colormod = self.glowmod = '1 1 1';
 120         }
 121         else
 122         {
 123             if (autocvar_cl_ghost_items_color)
 124             {
 125                 self.alpha = autocvar_cl_ghost_items;
 126                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 127             }
 128             else
 129                 self.alpha = -1;
 130         }
 131
 132         if(autocvar_cl_fullbright_items)
 133             if(self.ItemStatus & ITS_ALLOWFB)
 134                 self.effects |= EF_FULLBRIGHT;
 135
 136         if(self.ItemStatus & ITS_STAYWEP)
 137         {
 138             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 139             self.alpha = autocvar_cl_weapon_stay_alpha;
 140
 141         }
 142
 143         if(self.ItemStatus & ITS_POWERUP)
 144         {
 145             if(self.ItemStatus & ITS_AVAILABLE)
 146                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 147             else
 148                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 149         }
 150     }
 151
 152     if(sf & ISF_MODEL)
 153     {
 154         self.drawmask  = MASK_NORMAL;
 155         self.movetype  = MOVETYPE_TOSS;
 156         self.draw       = ItemDraw;
 157
 158         if(self.mdl)
 159             strunzone(self.mdl);
 160
 161         self.mdl = "";
 162         string _fn = ReadString();
 163
 164         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 165         {
 166             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 167             self.draw = ItemDrawSimple;
 168
 169
 170
 171             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 177             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 178                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 179             else
 180             {
 181                 self.draw = ItemDraw;
 182                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 183             }
 184         }
 185
 186         if(self.draw != ItemDrawSimple)
 187             self.mdl = strzone(_fn);
 188
 189
 190         if(self.mdl == "")
 191             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 192
 193         precache_model(self.mdl);
 194         setmodel(self, self.mdl);
 195     }
 196
 197     if(sf & ISF_COLORMAP)
 198         self.colormap = ReadShort();
 199
 200     if(sf & ISF_DROP)
 201     {
 202         self.gravity = 1;
 203         //self.move_angles = '0 0 0';
 204         self.move_movetype = MOVETYPE_TOSS;
 205         self.move_velocity_x = ReadCoord();
 206         self.move_velocity_y = ReadCoord();
 207         self.move_velocity_z = ReadCoord();
 208         self.velocity = self.move_velocity;
 209         self.move_origin = self.oldorigin;
 210
 211         if(!self.move_time)
 212         {
 213             self.move_time = time;
 214             self.spawntime = time;
 215         }
 216         else
 217             self.move_time = max(self.move_time, time);
 218     }
 219
 220     if(autocvar_cl_animate_items)
 221     {
 222         if(self.ItemStatus & ITS_ANIMATE1)
 223             self.move_avelocity = '0 180 0';
 224
 225         if(self.ItemStatus & ITS_ANIMATE2)
 226             self.move_avelocity = '0 -90 0';
 227     }
 228 }
 229
 230 #endif
 231
 232 #ifdef SVQC
 233 bool ItemSend(entity to, int sf)
 234 {
 235     if(self.gravity)
 236         sf |= ISF_DROP;
 237     else
 238         sf &= ~ISF_DROP;
 239
 240         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 241         WriteByte(MSG_ENTITY, sf);
 242
 243         //WriteByte(MSG_ENTITY, self.cnt);
 244     if(sf & ISF_LOCATION)
 245     {
 246         WriteCoord(MSG_ENTITY, self.origin.x);
 247         WriteCoord(MSG_ENTITY, self.origin.y);
 248         WriteCoord(MSG_ENTITY, self.origin.z);
 249     }
 250
 251     if(sf & ISF_ANGLES)
 252     {
 253         WriteCoord(MSG_ENTITY, self.angles.x);
 254         WriteCoord(MSG_ENTITY, self.angles.y);
 255         WriteCoord(MSG_ENTITY, self.angles.z);
 256     }
 257
 258     if(sf & ISF_SIZE)
 259     {
 260         WriteCoord(MSG_ENTITY, self.mins.x);
 261         WriteCoord(MSG_ENTITY, self.mins.y);
 262         WriteCoord(MSG_ENTITY, self.mins.z);
 263         WriteCoord(MSG_ENTITY, self.maxs.x);
 264         WriteCoord(MSG_ENTITY, self.maxs.y);
 265         WriteCoord(MSG_ENTITY, self.maxs.z);
 266     }
 267
 268     if(sf & ISF_STATUS)
 269         WriteByte(MSG_ENTITY, self.ItemStatus);
 270
 271     if(sf & ISF_MODEL)
 272     {
 273
 274         if(self.mdl == "")
 275             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 276
 277         WriteString(MSG_ENTITY, self.mdl);
 278     }
 279
 280
 281     if(sf & ISF_COLORMAP)
 282         WriteShort(MSG_ENTITY, self.colormap);
 283
 284     if(sf & ISF_DROP)
 285     {
 286         WriteCoord(MSG_ENTITY, self.velocity.x);
 287         WriteCoord(MSG_ENTITY, self.velocity.y);
 288         WriteCoord(MSG_ENTITY, self.velocity.z);
 289     }
 290
 291     return true;
 292 }
 293
 294 void ItemUpdate(entity item)
 295 {
 296         item.SendFlags |= ISF_LOCATION;
 297 }
 298
 299 float have_pickup_item(void)
 300 {
 301         if(self.flags & FL_POWERUP)
 302         {
 303                 if(autocvar_g_powerups > 0)
 304                         return true;
 305                 if(autocvar_g_powerups == 0)
 306                         return false;
 307         }
 308         else
 309         {
 310                 if(autocvar_g_pickup_items > 0)
 311                         return true;
 312                 if(autocvar_g_pickup_items == 0)
 313                         return false;
 314                 if(g_weaponarena)
 315                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 316                                 return false;
 317         }
 318         return true;
 319 }
 320
 321 /*
 322 float Item_Customize()
 323 {
 324         if(self.spawnshieldtime)
 325                 return true;
 326         if(self.weapons & ~other.weapons)
 327         {
 328                 self.colormod = '0 0 0';
 329                 self.glowmod = self.colormod;
 330                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 331                 return true;
 332         }
 333         else
 334         {
 335                 if(g_ghost_items)
 336                 {
 337                         self.colormod = stov(autocvar_g_ghost_items_color);
 338                         self.glowmod = self.colormod;
 339                         self.alpha = g_ghost_items;
 340                         return true;
 341                 }
 342                 else
 343                         return false;
 344         }
 345 }
 346 */
 347
 348 void Item_Show (entity e, float mode)
 349 {
 350         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 351         e.ItemStatus &= ~ITS_STAYWEP;
 352         if (mode > 0)
 353         {
 354                 // make the item look normal, and be touchable
 355                 e.model = e.mdl;
 356                 e.solid = SOLID_TRIGGER;
 357                 e.spawnshieldtime = 1;
 358                 e.ItemStatus |= ITS_AVAILABLE;
 359         }
 360         else if (mode < 0)
 361         {
 362                 // hide the item completely
 363                 e.model = string_null;
 364                 e.solid = SOLID_NOT;
 365                 e.spawnshieldtime = 1;
 366                 e.ItemStatus &= ~ITS_AVAILABLE;
 367         }
 368         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 369         {
 370                 // make the item translucent and not touchable
 371                 e.model = e.mdl;
 372                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 373                 e.effects |= EF_STARDUST;
 374                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 375                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 376         }
 377         else
 378         {
 379                 //setmodel(e, "null");
 380                 e.solid = SOLID_NOT;
 381                 e.colormod = '0 0 0';
 382                 e.glowmod = e.colormod;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus &= ~ITS_AVAILABLE;
 385         }
 386
 387         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 388             e.ItemStatus |= ITS_POWERUP;
 389
 390         if (autocvar_g_nodepthtestitems)
 391                 e.effects |= EF_NODEPTHTEST;
 392
 393
 394     if (autocvar_g_fullbrightitems)
 395                 e.ItemStatus |= ITS_ALLOWFB;
 396
 397         if (autocvar_sv_simple_items)
 398         e.ItemStatus |= ITS_ALLOWSI;
 399
 400         // relink entity (because solid may have changed)
 401         setorigin(e, e.origin);
 402     e.SendFlags |= ISF_STATUS;
 403 }
 404
 405 void Item_Think()
 406 {
 407         self.nextthink = time;
 408         if(self.origin != self.oldorigin)
 409         {
 410                 self.oldorigin = self.origin;
 411                 ItemUpdate(self);
 412         }
 413 }
 414
 415 float it_armor_large_time;
 416 float it_health_mega_time;
 417 float it_invisible_time;
 418 float it_speed_time;
 419 float it_extralife_time;
 420 float it_strength_time;
 421 float it_shield_time;
 422 float it_fuelregen_time;
 423 float it_jetpack_time;
 424 float it_superweapons_time;
 425
 426 void Item_ItemsTime_Init()
 427 {
 428         it_armor_large_time = -1;
 429         it_health_mega_time = -1;
 430         it_invisible_time = -1;
 431         it_speed_time = -1;
 432         it_extralife_time = -1;
 433         it_strength_time = -1;
 434         it_shield_time = -1;
 435         it_fuelregen_time = -1;
 436         it_jetpack_time = -1;
 437         it_superweapons_time = -1;
 438 }
 439 void Item_ItemsTime_ResetTimes()
 440 {
 441         it_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 442         it_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 443         it_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 444         it_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 445         it_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 446         it_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 447         it_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 448         it_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 449         it_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 450         it_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 451 }
 452 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 453 {
 454         e.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 455         e.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 456         e.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 457         e.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 458         e.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 459         e.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 460         e.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 461         e.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 462         e.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 463         e.item_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 464 }
 465 void Item_ItemsTime_SetTimesForPlayer(entity e)
 466 {
 467         e.item_armor_large_time = it_armor_large_time;
 468         e.item_health_mega_time = it_health_mega_time;
 469         e.item_invisible_time = it_invisible_time;
 470         e.item_speed_time = it_speed_time;
 471         e.item_extralife_time = it_extralife_time;
 472         e.item_strength_time = it_strength_time;
 473         e.item_shield_time = it_shield_time;
 474         e.item_fuelregen_time = it_fuelregen_time;
 475         e.item_jetpack_time = it_jetpack_time;
 476         e.item_superweapons_time = it_superweapons_time;
 477 }
 478
 479 void Item_ItemsTime_SetTime(entity e, float t)
 480 {
 481         if(!autocvar_sv_itemstime)
 482                 return;
 483
 484         if(g_instagib)
 485         {
 486                 switch(e.items)
 487                 {
 488                         case IT_STRENGTH://"item-invis"
 489                                 it_invisible_time = t;
 490                                 break;
 491                         case IT_NAILS://"item-extralife"
 492                                 it_extralife_time = t;
 493                                 break;
 494                         case IT_INVINCIBLE://"item-speed"
 495                                 it_speed_time = t;
 496                                 break;
 497                 }
 498         }
 499         else
 500         {
 501                 switch(e.items)
 502                 {
 503                         case IT_HEALTH:
 504                                 // if(e.classname == "item_health_mega") // IT_HEALTH unequivocally identifies it
 505                                         it_health_mega_time = t;
 506                                 break;
 507                         case IT_ARMOR:
 508                                 if(e.classname == "item_armor_large") // IT_ARMOR doesn't unequivocally identifies it
 509                                         it_armor_large_time = t;
 510                                 break;
 511                         case IT_STRENGTH://"item-strength"
 512                                 it_strength_time = t;
 513                                 break;
 514                         case IT_INVINCIBLE://"item-shield"
 515                                 it_shield_time = t;
 516                                 break;
 517                         default:
 518                                 if(e.weapons & WEPSET_SUPERWEAPONS)
 519                                         it_superweapons_time = t;
 520                 }
 521         }
 522         switch(e.items)
 523         {
 524                 case IT_FUEL_REGEN://"item-fuelregen"
 525                         it_fuelregen_time = t;
 526                         break;
 527                 case IT_JETPACK://"item-jetpack"
 528                         it_jetpack_time = t;
 529                         break;
 530         }
 531 }
 532 void Item_ItemsTime_SetTimesForAllPlayers()
 533 {
 534         entity e;
 535         if(warmup_stage)
 536         {
 537                 FOR_EACH_REALCLIENT(e)
 538                         Item_ItemsTime_SetTimesForPlayer(e);
 539         }
 540         else
 541         {
 542                 FOR_EACH_REALCLIENT(e)
 543                 {
 544                         if(!IS_PLAYER(e))
 545                                 Item_ItemsTime_SetTimesForPlayer(e);
 546                 }
 547         }
 548 }
 549
 550 float Item_ItemsTime_UpdateTime(entity e, float t)
 551 {
 552         entity head;
 553         bool isavailable = (t == 0);
 554         if(e.weapons & WEPSET_SUPERWEAPONS)
 555         {
 556                 for(head = world; (head = nextent(head)); )
 557                 {
 558                         if(clienttype(head) != CLIENTTYPE_NOTACLIENT || !(head.weapons & WEPSET_SUPERWEAPONS) || head.classname == "weapon_info")
 559                                 continue;
 560                         if(e == head)
 561                                 continue;
 562
 563                         if(head.scheduledrespawntime <= time)
 564                                 isavailable = true;
 565                         else if(t == 0 || head.scheduledrespawntime < t)
 566                                 t = head.scheduledrespawntime;
 567                 }
 568         }
 569         else
 570         {
 571                 for(head = world; (head = nextent(head)); )
 572                 {
 573                         if(head.itemdef != e.itemdef)
 574                                 continue;
 575                         if(e == head)
 576                                 continue;
 577
 578                         if(head.scheduledrespawntime <= time)
 579                                 isavailable = true;
 580                         else if(t == 0 || head.scheduledrespawntime < t)
 581                                 t = head.scheduledrespawntime;
 582                 }
 583         }
 584         if(isavailable)
 585                 t = -t; // let know the client there's another available item
 586         return t;
 587 }
 588
 589 void Item_Respawn (void)
 590 {
 591         Item_Show(self, 1);
 592         // this is ugly...
 593         if(self.items == IT_STRENGTH)
 594                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 595         else if(self.items == IT_INVINCIBLE)
 596                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 597         else
 598                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 599         setorigin (self, self.origin);
 600
 601         if(self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 602         {
 603                 float t = Item_ItemsTime_UpdateTime(self, 0);
 604                 Item_ItemsTime_SetTime(self, t);
 605                 Item_ItemsTime_SetTimesForAllPlayers();
 606         }
 607
 608         self.think = Item_Think;
 609         self.nextthink = time;
 610
 611         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 612         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 613 }
 614
 615 void Item_RespawnCountdown (void)
 616 {
 617         if(self.count >= ITEM_RESPAWN_TICKS)
 618         {
 619                 if(self.waypointsprite_attached)
 620                         WaypointSprite_Kill(self.waypointsprite_attached);
 621                 Item_Respawn();
 622         }
 623         else
 624         {
 625                 self.nextthink = time + 1;
 626                 self.count += 1;
 627                 if(self.count == 1)
 628                 {
 629                         string name;
 630                         vector rgb = '1 0 1';
 631                         name = string_null;
 632                         switch(self.items)
 633                         {
 634                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 635                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 636                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 637                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 638                                 case IT_HEALTH:
 639                                         //if (self.classname == "item_health_mega")
 640                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 641                                         break;
 642                                 case IT_ARMOR:
 643                                         if (self.classname == "item_armor_large")
 644                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 645                                         break;
 646                         }
 647                         item_name = name;
 648                         item_color = rgb;
 649                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 650                         name = item_name;
 651                         rgb = item_color;
 652                         if(self.flags & FL_WEAPON)
 653                         {
 654                                 entity wi = get_weaponinfo(self.weapon);
 655                                 if(wi)
 656                                 {
 657                                         name = wi.wpmodel;
 658                                         rgb = '1 0 0';
 659                                 }
 660                         }
 661                         if(name)
 662                         {
 663                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 664                                 if(self.waypointsprite_attached)
 665                                 {
 666                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 667                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 668                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 669                                 }
 670                         }
 671                         else
 672                         {
 673                                 print("Unknown powerup-marked item is wanting to respawn\n");
 674                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 675                         }
 676                 }
 677
 678                 if(self.waypointsprite_attached)
 679                 {
 680                         entity e;
 681                         entity it = self;
 682                         self = self.waypointsprite_attached;
 683                         FOR_EACH_REALCLIENT(e)
 684                                 if(self.waypointsprite_visible_for_player(e))
 685                                 {
 686                                         msg_entity = e;
 687                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 688                                 }
 689                         self = it;
 690
 691                         WaypointSprite_Ping(self.waypointsprite_attached);
 692                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 693                 }
 694                 else
 695                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 696         }
 697 }
 698
 699 void Item_RespawnThink()
 700 {
 701         self.nextthink = time;
 702         if(self.origin != self.oldorigin)
 703         {
 704                 self.oldorigin = self.origin;
 705                 ItemUpdate(self);
 706         }
 707
 708         if(time >= self.wait)
 709                 Item_Respawn();
 710 }
 711
 712 void Item_ScheduleRespawnIn(entity e, float t)
 713 {
 714         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 715         {
 716                 e.think = Item_RespawnCountdown;
 717                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 718                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 719                 e.count = 0;
 720                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 721                 Item_ItemsTime_SetTime(e, t);
 722                 Item_ItemsTime_SetTimesForAllPlayers();
 723         }
 724         else
 725         {
 726                 e.think = Item_RespawnThink;
 727                 e.nextthink = time;
 728                 e.scheduledrespawntime = time + t;
 729                 e.wait = time + t;
 730         }
 731 }
 732
 733 void Item_ScheduleRespawn(entity e)
 734 {
 735         if(e.respawntime > 0)
 736         {
 737                 Item_Show(e, 0);
 738                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 739         }
 740         else // if respawntime is -1, this item does not respawn
 741                 Item_Show(e, -1);
 742 }
 743
 744 void Item_ScheduleInitialRespawn(entity e)
 745 {
 746         Item_Show(e, 0);
 747         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 748 }
 749
 750 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 751 {
 752         if (!item.(ammotype))
 753                 return false;
 754
 755         if (item.spawnshieldtime)
 756         {
 757                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 758                 {
 759                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 760                         goto YEAH;
 761                 }
 762         }
 763         else if(g_weapon_stay == 2)
 764         {
 765                 float mi = min(item.(ammotype), ammomax);
 766                 if (player.(ammotype) < mi)
 767                 {
 768                         player.(ammotype) = mi;
 769                         goto YEAH;
 770                 }
 771         }
 772
 773         return false;
 774
 775 :YEAH
 776         switch(mode)
 777         {
 778                 case ITEM_MODE_FUEL:
 779                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 780                         break;
 781                 case ITEM_MODE_HEALTH:
 782                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 783                         break;
 784                 case ITEM_MODE_ARMOR:
 785                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 786                         break;
 787                 default:
 788                         break;
 789         }
 790         return true;
 791 }
 792
 793 float Item_GiveTo(entity item, entity player)
 794 {
 795         float _switchweapon;
 796         float pickedup;
 797         float it;
 798         float i;
 799
 800         // if nothing happens to player, just return without taking the item
 801         pickedup = false;
 802         _switchweapon = false;
 803         // in case the player has autoswitch enabled do the following:
 804         // if the player is using their best weapon before items are given, they
 805         // probably want to switch to an even better weapon after items are given
 806         if (player.autoswitch)
 807         if (player.switchweapon == w_getbestweapon(player))
 808                 _switchweapon = true;
 809
 810         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 811                 _switchweapon = true;
 812
 813         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 814         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 815         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 816         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 817         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 818         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 819         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 820         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 821
 822         if (item.flags & FL_WEAPON)
 823         {
 824                 WepSet it;
 825                 it = item.weapons;
 826                 it &= ~player.weapons;
 827
 828                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 829                 {
 830                         pickedup = true;
 831                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 832                         if(it & WepSet_FromWeapon(i))
 833                         {
 834                                 W_DropEvent(WR_PICKUP, player, i, item);
 835                                 W_GiveWeapon(player, i);
 836                         }
 837                 }
 838         }
 839
 840         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 841         {
 842                 pickedup = true;
 843                 player.items |= it;
 844                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 845         }
 846
 847         if (item.strength_finished)
 848         {
 849                 pickedup = true;
 850                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 851         }
 852         if (item.invincible_finished)
 853         {
 854                 pickedup = true;
 855                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 856         }
 857         if (item.superweapons_finished)
 858         {
 859                 pickedup = true;
 860                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 861         }
 862
 863 :skip
 864
 865         // always eat teamed entities
 866         if(item.team)
 867                 pickedup = true;
 868
 869         if (!pickedup)
 870                 return 0;
 871
 872         if (_switchweapon)
 873                 if (player.switchweapon != w_getbestweapon(player))
 874                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 875
 876         return 1;
 877 }
 878
 879 void Item_Touch (void)
 880 {
 881         entity e, head;
 882
 883         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 884         if(self.classname == "droppedweapon")
 885         {
 886                 if (ITEM_TOUCH_NEEDKILL())
 887                 {
 888                         remove(self);
 889                         return;
 890                 }
 891         }
 892
 893         if (!IS_PLAYER(other))
 894                 return;
 895         if (other.frozen)
 896                 return;
 897         if (other.deadflag)
 898                 return;
 899         if (self.solid != SOLID_TRIGGER)
 900                 return;
 901         if (self.owner == other)
 902                 return;
 903         if (time < self.item_spawnshieldtime)
 904                 return;
 905
 906         switch(MUTATOR_CALLHOOK(ItemTouch))
 907         {
 908                 case MUT_ITEMTOUCH_RETURN: { return; }
 909                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 910         }
 911
 912         if (self.classname == "droppedweapon")
 913         {
 914                 self.strength_finished = max(0, self.strength_finished - time);
 915                 self.invincible_finished = max(0, self.invincible_finished - time);
 916                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 917         }
 918         entity it = self.itemdef;
 919         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 920         if (!gave)
 921         {
 922                 if (self.classname == "droppedweapon")
 923                 {
 924                         // undo what we did above
 925                         self.strength_finished += time;
 926                         self.invincible_finished += time;
 927                         self.superweapons_finished += time;
 928                 }
 929                 return;
 930         }
 931
 932         :pickup
 933
 934         other.last_pickup = time;
 935
 936         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 937         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 938
 939         if (self.classname == "droppedweapon")
 940                 remove (self);
 941         else if (self.spawnshieldtime)
 942         {
 943                 if(self.team)
 944                 {
 945                         RandomSelection_Init();
 946                         for(head = world; (head = findfloat(head, team, self.team)); )
 947                         {
 948                                 if(head.flags & FL_ITEM)
 949                                 {
 950                                         Item_Show(head, -1);
 951                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 952                                 }
 953                         }
 954                         e = RandomSelection_chosen_ent;
 955
 956                 }
 957                 else
 958                         e = self;
 959                 Item_ScheduleRespawn(e);
 960         }
 961 }
 962
 963 void Item_Reset()
 964 {
 965         Item_Show(self, !self.state);
 966         setorigin (self, self.origin);
 967
 968         if(self.classname != "droppedweapon")
 969         {
 970                 self.think = Item_Think;
 971                 self.nextthink = time;
 972
 973                 if(self.waypointsprite_attached)
 974                         WaypointSprite_Kill(self.waypointsprite_attached);
 975
 976                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 977                         Item_ScheduleInitialRespawn(self);
 978         }
 979 }
 980
 981 void Item_FindTeam()
 982 {
 983         entity head, e;
 984
 985         if(self.effects & EF_NODRAW)
 986         {
 987                 // marker for item team search
 988                 dprint("Initializing item team ", ftos(self.team), "\n");
 989                 RandomSelection_Init();
 990                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 991                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 992                 e = RandomSelection_chosen_ent;
 993                 e.state = 0;
 994                 Item_Show(e, 1);
 995
 996                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 997                 {
 998                         if(head != e)
 999                         {
1000                                 // make it a non-spawned item
1001                                 Item_Show(head, -1);
1002                                 head.state = 1; // state 1 = initially hidden item
1003                         }
1004                         head.effects &= ~EF_NODRAW;
1005                 }
1006
1007                 Item_Reset();
1008         }
1009 }
1010
1011 // Savage: used for item garbage-collection
1012 // TODO: perhaps nice special effect?
1013 void RemoveItem(void)
1014 {
1015         remove(self);
1016 }
1017
1018 // pickup evaluation functions
1019 // these functions decide how desirable an item is to the bots
1020
1021 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1022
1023 float weapon_pickupevalfunc(entity player, entity item)
1024 {
1025         float c;
1026
1027         // See if I have it already
1028         if(item.weapons & ~player.weapons)
1029         {
1030                 // If I can pick it up
1031                 if(!item.spawnshieldtime)
1032                         c = 0;
1033                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
1034                 {
1035                         // Skilled bots will grab more
1036                         c = bound(0, skill / 10, 1) * 0.5;
1037                 }
1038                 else
1039                         c = 0;
1040         }
1041         else
1042                 c = 1;
1043
1044         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
1045         if( bot_custom_weapon && c )
1046         {
1047                 // Find the highest position on any range
1048                 int position = -1;
1049                 for (int j = 0; j < WEP_LAST ; ++j){
1050                         if(
1051                                         bot_weapons_far[j] == item.weapon ||
1052                                         bot_weapons_mid[j] == item.weapon ||
1053                                         bot_weapons_close[j] == item.weapon
1054                           )
1055                         {
1056                                 position = j;
1057                                 break;
1058                         }
1059                 }
1060
1061                 // Rate it
1062                 if (position >= 0 )
1063                 {
1064                         position = WEP_LAST - position;
1065                         // item.bot_pickupbasevalue is overwritten here
1066                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
1067                 }
1068         }
1069
1070         return item.bot_pickupbasevalue * c;
1071 }
1072
1073 float commodity_pickupevalfunc(entity player, entity item)
1074 {
1075         float c, i;
1076         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1077         entity wi;
1078         c = 0;
1079
1080         // Detect needed ammo
1081         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
1082         {
1083                 wi = get_weaponinfo(i);
1084
1085                 if (!(player.weapons & WepSet_FromWeapon(i)))
1086                         continue;
1087
1088                 if(wi.items & IT_SHELLS)
1089                         need_shells = true;
1090                 else if(wi.items & IT_NAILS)
1091                         need_nails = true;
1092                 else if(wi.items & IT_ROCKETS)
1093                         need_rockets = true;
1094                 else if(wi.items & IT_CELLS)
1095                         need_cells = true;
1096                 else if(wi.items & IT_PLASMA)
1097                         need_plasma = true;
1098                 else if(wi.items & IT_FUEL)
1099                         need_fuel = true;
1100         }
1101
1102         // TODO: figure out if the player even has the weapon this ammo is for?
1103         // may not affect strategy much though...
1104         // find out how much more ammo/armor/health the player can hold
1105         if (need_shells)
1106         if (item.ammo_shells)
1107         if (player.ammo_shells < g_pickup_shells_max)
1108                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1109         if (need_nails)
1110         if (item.ammo_nails)
1111         if (player.ammo_nails < g_pickup_nails_max)
1112                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1113         if (need_rockets)
1114         if (item.ammo_rockets)
1115         if (player.ammo_rockets < g_pickup_rockets_max)
1116                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1117         if (need_cells)
1118         if (item.ammo_cells)
1119         if (player.ammo_cells < g_pickup_cells_max)
1120                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1121         if (need_plasma)
1122         if (item.ammo_plasma)
1123         if (player.ammo_plasma < g_pickup_plasma_max)
1124                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1125         if (need_fuel)
1126         if (item.ammo_fuel)
1127         if (player.ammo_fuel < g_pickup_fuel_max)
1128                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1129         if (item.armorvalue)
1130         if (player.armorvalue < item.max_armorvalue)
1131                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1132         if (item.health)
1133         if (player.health < item.max_health)
1134                 c = c + max(0, 1 - player.health / item.max_health);
1135
1136         return item.bot_pickupbasevalue * c;
1137 }
1138
1139 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1140 {
1141         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1142                 RemoveItem();
1143 }
1144
1145 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1146 {
1147         startitem_failed = false;
1148
1149         if(self.model == "")
1150                 self.model = itemmodel;
1151
1152         if(self.model == "")
1153     {
1154         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1155         return;
1156     }
1157
1158         if(self.item_pickupsound == "")
1159                 self.item_pickupsound = pickupsound;
1160
1161         if(!self.respawntime) // both need to be set
1162         {
1163                 self.respawntime = defaultrespawntime;
1164                 self.respawntimejitter = defaultrespawntimejitter;
1165         }
1166
1167         self.items = itemid;
1168         self.weapon = weaponid;
1169
1170         if(weaponid)
1171                 self.weapons = WepSet_FromWeapon(weaponid);
1172
1173         self.flags = FL_ITEM | itemflags;
1174
1175         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1176         {
1177                 startitem_failed = true;
1178                 remove(self);
1179                 return;
1180         }
1181
1182         // is it a dropped weapon?
1183         if (self.classname == "droppedweapon")
1184         {
1185                 self.reset = SUB_Remove;
1186                 // it's a dropped weapon
1187                 self.movetype = MOVETYPE_TOSS;
1188
1189                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1190                 self.think = RemoveItem;
1191                 self.nextthink = time + 20;
1192
1193                 self.takedamage = DAMAGE_YES;
1194                 self.event_damage = Item_Damage;
1195
1196                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1197                 /*
1198                 if(self.items == 0)
1199                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1200                 if(self.ammo_nails == 0)
1201                 if(self.ammo_cells == 0)
1202                 if(self.ammo_rockets == 0)
1203                 if(self.ammo_shells == 0)
1204                 if(self.ammo_fuel == 0)
1205                 if(self.health == 0)
1206                 if(self.armorvalue == 0)
1207                 */
1208                 {
1209                         // if item is worthless after a timer, have it expire then
1210                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1211                 }
1212
1213                 // don't drop if in a NODROP zone (such as lava)
1214                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1215                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1216                 {
1217                         startitem_failed = true;
1218                         remove(self);
1219                         return;
1220                 }
1221         }
1222         else
1223         {
1224                 if(!have_pickup_item())
1225                 {
1226                         startitem_failed = true;
1227                         remove (self);
1228                         return;
1229                 }
1230
1231                 self.reset = Item_Reset;
1232                 // it's a level item
1233                 if(self.spawnflags & 1)
1234                         self.noalign = 1;
1235                 if (self.noalign)
1236                         self.movetype = MOVETYPE_NONE;
1237                 else
1238                         self.movetype = MOVETYPE_TOSS;
1239                 // do item filtering according to game mode and other things
1240                 if (!self.noalign)
1241                 {
1242                         // first nudge it off the floor a little bit to avoid math errors
1243                         setorigin(self, self.origin + '0 0 1');
1244                         // set item size before we spawn a spawnfunc_waypoint
1245                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1246                                 setsize (self, '-16 -16 0', '16 16 48');
1247                         else
1248                                 setsize (self, '-16 -16 0', '16 16 32');
1249
1250                         // note droptofloor returns false if stuck/or would fall too far
1251                         droptofloor();
1252                         waypoint_spawnforitem(self);
1253                 }
1254
1255                 /*
1256                  * can't do it that way, as it would break maps
1257                  * TODO make a target_give like entity another way, that perhaps has
1258                  * the weapon name in a key
1259                 if(self.targetname)
1260                 {
1261                         // target_give not yet supported; maybe later
1262                         print("removed targeted ", self.classname, "\n");
1263                         startitem_failed = true;
1264                         remove (self);
1265                         return;
1266                 }
1267                 */
1268
1269                 if(autocvar_spawn_debug >= 2)
1270                 {
1271                         entity otheritem;
1272                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1273                         {
1274                             // why not flags & fl_item?
1275                                 if(otheritem.is_item)
1276                                 {
1277                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1278                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1279                                         error("Mapper sucks.");
1280                                 }
1281                         }
1282                         self.is_item = true;
1283                 }
1284
1285                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1286
1287                 precache_model (self.model);
1288                 precache_sound (self.item_pickupsound);
1289
1290                 precache_sound ("misc/itemrespawncountdown.wav");
1291                 if(itemid == IT_STRENGTH)
1292                         precache_sound ("misc/strength_respawn.wav");
1293                 else if(itemid == IT_INVINCIBLE)
1294                         precache_sound ("misc/shield_respawn.wav");
1295                 else
1296                         precache_sound ("misc/itemrespawn.wav");
1297
1298                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1299                         self.target = "###item###"; // for finding the nearest item using find()
1300
1301                 Item_ItemsTime_SetTime(self, 0);
1302         }
1303
1304         self.bot_pickup = true;
1305         self.bot_pickupevalfunc = pickupevalfunc;
1306         self.bot_pickupbasevalue = pickupbasevalue;
1307         self.mdl = self.model;
1308         self.netname = itemname;
1309         self.touch = Item_Touch;
1310         setmodel(self, "null"); // precision set below
1311         //self.effects |= EF_LOWPRECISION;
1312
1313         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1314     {
1315         self.pos1 = '-16 -16 0';
1316         self.pos2 = '16 16 48';
1317     }
1318         else
1319     {
1320         self.pos1 = '-16 -16 0';
1321         self.pos2 = '16 16 32';
1322     }
1323     setsize (self, self.pos1, self.pos2);
1324
1325     if(itemflags & FL_POWERUP)
1326         self.ItemStatus |= ITS_ANIMATE1;
1327
1328         if(self.armorvalue || self.health)
1329         self.ItemStatus |= ITS_ANIMATE2;
1330
1331         if(itemflags & FL_WEAPON)
1332         {
1333                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1334             self.colormap = 1024; // color shirt=0 pants=0 grey
1335         else
1336             self.gravity = 1;
1337
1338                 self.ItemStatus |= ITS_ANIMATE1;
1339                 self.ItemStatus |= ISF_COLORMAP;
1340         }
1341
1342         self.state = 0;
1343         if(self.team) // broken, no idea why.
1344         {
1345                 if(!self.cnt)
1346                         self.cnt = 1; // item probability weight
1347
1348                 self.effects |= EF_NODRAW; // marker for item team search
1349                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1350         }
1351         else
1352                 Item_Reset();
1353
1354     Net_LinkEntity(self, false, 0, ItemSend);
1355
1356         self.SendFlags |= ISF_SIZE;
1357         if(self.angles)
1358                 self.SendFlags |= ISF_ANGLES;
1359
1360         // call this hook after everything else has been done
1361         if(MUTATOR_CALLHOOK(Item_Spawn))
1362         {
1363                 startitem_failed = true;
1364                 remove(self);
1365                 return;
1366         }
1367 }
1368
1369 void StartItemA (entity a)
1370 {
1371     self.itemdef = a;
1372     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1373 }
1374
1375 void spawnfunc_item_rockets (void) {
1376         if(!self.ammo_rockets)
1377                 self.ammo_rockets = g_pickup_rockets;
1378         if(!self.pickup_anyway)
1379                 self.pickup_anyway = g_pickup_ammo_anyway;
1380     StartItemA (ITEM_Rockets);
1381 }
1382
1383 void spawnfunc_item_bullets (void) {
1384         if(!weaponswapping)
1385         if(autocvar_sv_q3acompat_machineshotgunswap)
1386         if(self.classname != "droppedweapon")
1387         {
1388                 weaponswapping = true;
1389                 spawnfunc_item_shells();
1390                 weaponswapping = false;
1391                 return;
1392         }
1393
1394         if(!self.ammo_nails)
1395                 self.ammo_nails = g_pickup_nails;
1396         if(!self.pickup_anyway)
1397                 self.pickup_anyway = g_pickup_ammo_anyway;
1398     StartItemA (ITEM_Bullets);
1399 }
1400
1401 void spawnfunc_item_cells (void) {
1402         if(!self.ammo_cells)
1403                 self.ammo_cells = g_pickup_cells;
1404         if(!self.pickup_anyway)
1405                 self.pickup_anyway = g_pickup_ammo_anyway;
1406         StartItemA (ITEM_Cells);
1407 }
1408
1409 void spawnfunc_item_plasma()
1410 {
1411         if(!self.ammo_plasma)
1412                 self.ammo_plasma = g_pickup_plasma;
1413         if(!self.pickup_anyway)
1414                 self.pickup_anyway = g_pickup_ammo_anyway;
1415         StartItemA (ITEM_Plasma);
1416 }
1417
1418 void spawnfunc_item_shells (void) {
1419         if(!weaponswapping)
1420         if(autocvar_sv_q3acompat_machineshotgunswap)
1421         if(self.classname != "droppedweapon")
1422         {
1423                 weaponswapping = true;
1424                 spawnfunc_item_bullets();
1425                 weaponswapping = false;
1426                 return;
1427         }
1428
1429         if(!self.ammo_shells)
1430                 self.ammo_shells = g_pickup_shells;
1431         if(!self.pickup_anyway)
1432                 self.pickup_anyway = g_pickup_ammo_anyway;
1433         StartItemA (ITEM_Shells);
1434 }
1435
1436 void spawnfunc_item_armor_small (void) {
1437         if(!self.armorvalue)
1438                 self.armorvalue = g_pickup_armorsmall;
1439         if(!self.max_armorvalue)
1440                 self.max_armorvalue = g_pickup_armorsmall_max;
1441         if(!self.pickup_anyway)
1442                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1443         StartItemA (ITEM_ArmorSmall);
1444 }
1445
1446 void spawnfunc_item_armor_medium (void) {
1447         if(!self.armorvalue)
1448                 self.armorvalue = g_pickup_armormedium;
1449         if(!self.max_armorvalue)
1450                 self.max_armorvalue = g_pickup_armormedium_max;
1451         if(!self.pickup_anyway)
1452                 self.pickup_anyway = g_pickup_armormedium_anyway;
1453         StartItemA (ITEM_ArmorMedium);
1454 }
1455
1456 void spawnfunc_item_armor_big (void) {
1457         if(!self.armorvalue)
1458                 self.armorvalue = g_pickup_armorbig;
1459         if(!self.max_armorvalue)
1460                 self.max_armorvalue = g_pickup_armorbig_max;
1461         if(!self.pickup_anyway)
1462                 self.pickup_anyway = g_pickup_armorbig_anyway;
1463         StartItemA (ITEM_ArmorBig);
1464 }
1465
1466 void spawnfunc_item_armor_large (void) {
1467         if(!self.armorvalue)
1468                 self.armorvalue = g_pickup_armorlarge;
1469         if(!self.max_armorvalue)
1470                 self.max_armorvalue = g_pickup_armorlarge_max;
1471         if(!self.pickup_anyway)
1472                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1473         StartItemA (ITEM_ArmorLarge);
1474 }
1475
1476 void spawnfunc_item_health_small (void) {
1477         if(!self.max_health)
1478                 self.max_health = g_pickup_healthsmall_max;
1479         if(!self.health)
1480                 self.health = g_pickup_healthsmall;
1481         if(!self.pickup_anyway)
1482                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1483         StartItemA (ITEM_HealthSmall);
1484 }
1485
1486 void spawnfunc_item_health_medium (void) {
1487         if(!self.max_health)
1488                 self.max_health = g_pickup_healthmedium_max;
1489         if(!self.health)
1490                 self.health = g_pickup_healthmedium;
1491         if(!self.pickup_anyway)
1492                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1493     StartItemA (ITEM_HealthMedium);
1494 }
1495
1496 void spawnfunc_item_health_large (void) {
1497         if(!self.max_health)
1498                 self.max_health = g_pickup_healthlarge_max;
1499         if(!self.health)
1500                 self.health = g_pickup_healthlarge;
1501         if(!self.pickup_anyway)
1502                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1503         StartItemA (ITEM_HealthLarge);
1504 }
1505
1506 void spawnfunc_item_health_mega (void) {
1507     if(!self.max_health)
1508         self.max_health = g_pickup_healthmega_max;
1509     if(!self.health)
1510         self.health = g_pickup_healthmega;
1511     if(!self.pickup_anyway)
1512         self.pickup_anyway = g_pickup_healthmega_anyway;
1513     StartItemA (ITEM_HealthMega);
1514 }
1515
1516 // support old misnamed entities
1517 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1518 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1519 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1520 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1521 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1522
1523 void spawnfunc_item_strength (void) {
1524                 precache_sound("weapons/strength_fire.wav");
1525                 if(!self.strength_finished)
1526                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1527                 StartItemA (ITEM_Strength);
1528 }
1529
1530 void spawnfunc_item_invincible (void) {
1531                 if(!self.invincible_finished)
1532                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1533                 StartItemA (ITEM_Shield);
1534 }
1535
1536 // compatibility:
1537 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1538
1539 void target_items_use (void)
1540 {
1541         if(activator.classname == "droppedweapon")
1542         {
1543                 EXACTTRIGGER_TOUCH;
1544                 remove(activator);
1545                 return;
1546         }
1547
1548         if (!IS_PLAYER(activator))
1549                 return;
1550         if(activator.deadflag != DEAD_NO)
1551                 return;
1552         EXACTTRIGGER_TOUCH;
1553
1554         entity e;
1555         for(e = world; (e = find(e, classname, "droppedweapon")); )
1556                 if(e.enemy == activator)
1557                         remove(e);
1558
1559         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1560                 centerprint(activator, self.message);
1561 }
1562
1563 void spawnfunc_target_items (void)
1564 {
1565         float n, i, j;
1566         entity e;
1567         string s;
1568
1569         self.use = target_items_use;
1570         if(!self.strength_finished)
1571                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1572         if(!self.invincible_finished)
1573                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1574         if(!self.superweapons_finished)
1575                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1576
1577         precache_sound("misc/itempickup.wav");
1578         precache_sound("misc/megahealth.wav");
1579         precache_sound("misc/armor25.wav");
1580         precache_sound("misc/powerup.wav");
1581         precache_sound("misc/poweroff.wav");
1582         precache_sound("weapons/weaponpickup.wav");
1583
1584         n = tokenize_console(self.netname);
1585         if(argv(0) == "give")
1586         {
1587                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1588         }
1589         else
1590         {
1591                 for(i = 0; i < n; ++i)
1592                 {
1593                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1594                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1595                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1596                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1597                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1598                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1599                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1600                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1601                         else
1602                         {
1603                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1604                                 {
1605                                         e = get_weaponinfo(j);
1606                                         s = W_UndeprecateName(argv(i));
1607                                         if(s == e.netname)
1608                                         {
1609                                                 self.weapons |= WepSet_FromWeapon(j);
1610                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1611                                                         WEP_ACTION(e.weapon, WR_INIT);
1612                                                 break;
1613                                         }
1614                                 }
1615                                 if(j > WEP_LAST)
1616                                         print("target_items: invalid item ", argv(i), "\n");
1617                         }
1618                 }
1619
1620                 string itemprefix, valueprefix;
1621                 if(self.spawnflags == 0)
1622                 {
1623                         itemprefix = "";
1624                         valueprefix = "";
1625                 }
1626                 else if(self.spawnflags == 1)
1627                 {
1628                         itemprefix = "max ";
1629                         valueprefix = "max ";
1630                 }
1631                 else if(self.spawnflags == 2)
1632                 {
1633                         itemprefix = "min ";
1634                         valueprefix = "min ";
1635                 }
1636                 else if(self.spawnflags == 4)
1637                 {
1638                         itemprefix = "minus ";
1639                         valueprefix = "max ";
1640                 }
1641                 else
1642                 {
1643                         error("invalid spawnflags");
1644                         itemprefix = valueprefix = string_null;
1645                 }
1646
1647                 self.netname = "";
1648                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1649                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1650                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1651                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1652                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1653                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1654                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1655                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1656                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1657                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1658                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1659                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1660                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1661                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1662                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1663                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1664                 {
1665                         e = get_weaponinfo(j);
1666                         if(e.weapon)
1667                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1668                 }
1669         }
1670         self.netname = strzone(self.netname);
1671         //print(self.netname, "\n");
1672
1673         n = tokenize_console(self.netname);
1674         for(i = 0; i < n; ++i)
1675         {
1676                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1677                 {
1678                         e = get_weaponinfo(j);
1679                         if(argv(i) == e.netname)
1680                         {
1681                                 WEP_ACTION(e.weapon, WR_INIT);
1682                                 break;
1683                         }
1684                 }
1685         }
1686 }
1687
1688 void spawnfunc_item_fuel(void)
1689 {
1690         if(!self.ammo_fuel)
1691                 self.ammo_fuel = g_pickup_fuel;
1692         if(!self.pickup_anyway)
1693                 self.pickup_anyway = g_pickup_ammo_anyway;
1694         StartItemA (ITEM_JetpackFuel);
1695 }
1696
1697 void spawnfunc_item_fuel_regen(void)
1698 {
1699         if(start_items & IT_FUEL_REGEN)
1700         {
1701                 spawnfunc_item_fuel();
1702                 return;
1703         }
1704         StartItemA (ITEM_JetpackRegen);
1705 }
1706
1707 void spawnfunc_item_jetpack(void)
1708 {
1709         if(!self.ammo_fuel)
1710                 self.ammo_fuel = g_pickup_fuel_jetpack;
1711         if(start_items & IT_JETPACK)
1712         {
1713                 spawnfunc_item_fuel();
1714                 return;
1715         }
1716         StartItemA (ITEM_Jetpack);
1717 }
1718
1719 float GiveWeapon(entity e, float wpn, float op, float val)
1720 {
1721         WepSet v0, v1;
1722         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1723         switch(op)
1724         {
1725                 case OP_SET:
1726                         if(val > 0)
1727                                 e.weapons |= WepSet_FromWeapon(wpn);
1728                         else
1729                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1730                         break;
1731                 case OP_MIN:
1732                 case OP_PLUS:
1733                         if(val > 0)
1734                                 e.weapons |= WepSet_FromWeapon(wpn);
1735                         break;
1736                 case OP_MAX:
1737                         if(val <= 0)
1738                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1739                         break;
1740                 case OP_MINUS:
1741                         if(val > 0)
1742                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1743                         break;
1744         }
1745         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1746         return (v0 != v1);
1747 }
1748
1749 float GiveBit(entity e, .float fld, float bit, float op, float val)
1750 {
1751         float v0, v1;
1752         v0 = (e.(fld) & bit);
1753         switch(op)
1754         {
1755                 case OP_SET:
1756                         if(val > 0)
1757                                 e.(fld) |= bit;
1758                         else
1759                                 e.(fld) &= ~bit;
1760                         break;
1761                 case OP_MIN:
1762                 case OP_PLUS:
1763                         if(val > 0)
1764                                 e.(fld) |= bit;
1765                         break;
1766                 case OP_MAX:
1767                         if(val <= 0)
1768                                 e.(fld) &= ~bit;
1769                         break;
1770                 case OP_MINUS:
1771                         if(val > 0)
1772                                 e.(fld) &= ~bit;
1773                         break;
1774         }
1775         v1 = (e.(fld) & bit);
1776         return (v0 != v1);
1777 }
1778
1779 float GiveValue(entity e, .float fld, float op, float val)
1780 {
1781         float v0, v1;
1782         v0 = e.(fld);
1783         switch(op)
1784         {
1785                 case OP_SET:
1786                         e.(fld) = val;
1787                         break;
1788                 case OP_MIN:
1789                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1790                         break;
1791                 case OP_MAX:
1792                         e.(fld) = min(e.(fld), val);
1793                         break;
1794                 case OP_PLUS:
1795                         e.(fld) += val;
1796                         break;
1797                 case OP_MINUS:
1798                         e.(fld) -= val;
1799                         break;
1800         }
1801         v1 = e.(fld);
1802         return (v0 != v1);
1803 }
1804
1805 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1806 {
1807         if(v1 == v0)
1808                 return;
1809         if(v1 <= v0 - t)
1810         {
1811                 if(snd_decr != "")
1812                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1813         }
1814         else if(v0 >= v0 + t)
1815         {
1816                 if(snd_incr != "")
1817                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1818         }
1819 }
1820
1821 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1822 {
1823         if(v0 < v1)
1824                 e.(rotfield) = max(e.(rotfield), time + rottime);
1825         else if(v0 > v1)
1826                 e.(regenfield) = max(e.(regenfield), time + regentime);
1827 }
1828 float GiveItems(entity e, float beginarg, float endarg)
1829 {
1830         float got, i, j, val, op;
1831         float _switchweapon;
1832         entity wi;
1833         string cmd;
1834
1835         val = 999;
1836         op = OP_SET;
1837
1838         got = 0;
1839
1840         _switchweapon = false;
1841         if (e.autoswitch)
1842                 if (e.switchweapon == w_getbestweapon(e))
1843                         _switchweapon = true;
1844
1845         e.strength_finished = max(0, e.strength_finished - time);
1846         e.invincible_finished = max(0, e.invincible_finished - time);
1847         e.superweapons_finished = max(0, e.superweapons_finished - time);
1848
1849         PREGIVE(e, items);
1850         PREGIVE_WEAPONS(e);
1851         PREGIVE(e, strength_finished);
1852         PREGIVE(e, invincible_finished);
1853         PREGIVE(e, superweapons_finished);
1854         PREGIVE(e, ammo_nails);
1855         PREGIVE(e, ammo_cells);
1856         PREGIVE(e, ammo_plasma);
1857         PREGIVE(e, ammo_shells);
1858         PREGIVE(e, ammo_rockets);
1859         PREGIVE(e, ammo_fuel);
1860         PREGIVE(e, armorvalue);
1861         PREGIVE(e, health);
1862
1863         for(i = beginarg; i < endarg; ++i)
1864         {
1865                 cmd = argv(i);
1866
1867                 if(cmd == "0" || stof(cmd))
1868                 {
1869                         val = stof(cmd);
1870                         continue;
1871                 }
1872                 switch(cmd)
1873                 {
1874                         case "no":
1875                                 op = OP_MAX;
1876                                 val = 0;
1877                                 continue;
1878                         case "max":
1879                                 op = OP_MAX;
1880                                 continue;
1881                         case "min":
1882                                 op = OP_MIN;
1883                                 continue;
1884                         case "plus":
1885                                 op = OP_PLUS;
1886                                 continue;
1887                         case "minus":
1888                                 op = OP_MINUS;
1889                                 continue;
1890                         case "ALL":
1891                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1892                                 got += GiveValue(e, strength_finished, op, val);
1893                                 got += GiveValue(e, invincible_finished, op, val);
1894                                 got += GiveValue(e, superweapons_finished, op, val);
1895                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1896                         case "all":
1897                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1898                                 got += GiveValue(e, health, op, val);
1899                                 got += GiveValue(e, armorvalue, op, val);
1900                         case "allweapons":
1901                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1902                                 {
1903                                         wi = get_weaponinfo(j);
1904                                         if(wi.weapon)
1905                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1906                                                         got += GiveWeapon(e, j, op, val);
1907                                 }
1908                         case "allammo":
1909                                 got += GiveValue(e, ammo_cells, op, val);
1910                                 got += GiveValue(e, ammo_plasma, op, val);
1911                                 got += GiveValue(e, ammo_shells, op, val);
1912                                 got += GiveValue(e, ammo_nails, op, val);
1913                                 got += GiveValue(e, ammo_rockets, op, val);
1914                                 got += GiveValue(e, ammo_fuel, op, val);
1915                                 break;
1916                         case "unlimited_ammo":
1917                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1918                                 break;
1919                         case "unlimited_weapon_ammo":
1920                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1921                                 break;
1922                         case "unlimited_superweapons":
1923                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1924                                 break;
1925                         case "jetpack":
1926                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1927                                 break;
1928                         case "fuel_regen":
1929                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1930                                 break;
1931                         case "strength":
1932                                 got += GiveValue(e, strength_finished, op, val);
1933                                 break;
1934                         case "invincible":
1935                                 got += GiveValue(e, invincible_finished, op, val);
1936                                 break;
1937                         case "superweapons":
1938                                 got += GiveValue(e, superweapons_finished, op, val);
1939                                 break;
1940                         case "cells":
1941                                 got += GiveValue(e, ammo_cells, op, val);
1942                                 break;
1943                         case "plasma":
1944                                 got += GiveValue(e, ammo_plasma, op, val);
1945                                 break;
1946                         case "shells":
1947                                 got += GiveValue(e, ammo_shells, op, val);
1948                                 break;
1949                         case "nails":
1950                         case "bullets":
1951                                 got += GiveValue(e, ammo_nails, op, val);
1952                                 break;
1953                         case "rockets":
1954                                 got += GiveValue(e, ammo_rockets, op, val);
1955                                 break;
1956                         case "health":
1957                                 got += GiveValue(e, health, op, val);
1958                                 break;
1959                         case "armor":
1960                                 got += GiveValue(e, armorvalue, op, val);
1961                                 break;
1962                         case "fuel":
1963                                 got += GiveValue(e, ammo_fuel, op, val);
1964                                 break;
1965                         default:
1966                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1967                                 {
1968                                         wi = get_weaponinfo(j);
1969                                         if(cmd == wi.netname)
1970                                         {
1971                                                 got += GiveWeapon(e, j, op, val);
1972                                                 break;
1973                                         }
1974                                 }
1975                                 if(j > WEP_LAST)
1976                                         print("give: invalid item ", cmd, "\n");
1977                                 break;
1978                 }
1979                 val = 999;
1980                 op = OP_SET;
1981         }
1982
1983         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1984         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1985         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1986         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1987         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1988         {
1989                 wi = get_weaponinfo(j);
1990                 if(wi.weapon)
1991                 {
1992                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1993                         if (!(save_weapons & WepSet_FromWeapon(j)))
1994                                 if(e.weapons & WepSet_FromWeapon(j))
1995                                         WEP_ACTION(wi.weapon, WR_INIT);
1996                 }
1997         }
1998         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1999         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2000         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2001         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2002         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
2003         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2004         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2005         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2006         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2007         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2008
2009         if(e.superweapons_finished <= 0)
2010                 if(self.weapons & WEPSET_SUPERWEAPONS)
2011                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2012
2013         if(e.strength_finished <= 0)
2014                 e.strength_finished = 0;
2015         else
2016                 e.strength_finished += time;
2017         if(e.invincible_finished <= 0)
2018                 e.invincible_finished = 0;
2019         else
2020                 e.invincible_finished += time;
2021         if(e.superweapons_finished <= 0)
2022                 e.superweapons_finished = 0;
2023         else
2024                 e.superweapons_finished += time;
2025
2026         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
2027                 _switchweapon = true;
2028         if(_switchweapon)
2029                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2030
2031         return got;
2032 }
2033 #endif