qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(cvar_string("g_ghost_items_color"));
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent green and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent green and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (cvar("g_nodepthtestitems"))
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (cvar("g_fullbrightitems"))
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 152         else
 153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 202                                 if(self.waypointsprite_attached)
 203                                 {
 204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 207                                 }
 208                         }
 209                 }
 210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 211                 if(self.waypointsprite_attached)
 212                 {
 213                         WaypointSprite_Ping(self.waypointsprite_attached);
 214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 215                 }
 216         }
 217 }
 218
 219 void Item_ScheduleRespawnIn(entity e, float t)
 220 {
 221         if(e.flags & FL_POWERUP)
 222         {
 223                 e.think = Item_RespawnCountdown;
 224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 225                 e.count = 0;
 226         }
 227         else
 228         {
 229                 e.think = Item_Respawn;
 230                 e.nextthink = time + t;
 231         }
 232 }
 233
 234 void Item_ScheduleRespawn(entity e)
 235 {
 236         if(e.respawntime > 0)
 237         {
 238                 Item_Show(e, 0);
 239                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 240         }
 241         else // if respawntime is -1, this item does not respawn
 242                 Item_Show(e, -1);
 243 }
 244
 245 void Item_ScheduleInitialRespawn(entity e)
 246 {
 247         Item_Show(e, 0);
 248         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 249 }
 250
 251 float Item_GiveTo(entity item, entity player)
 252 {
 253         float _switchweapon;
 254         float pickedup;
 255         float it;
 256         float i;
 257         entity e;
 258
 259         // if nothing happens to player, just return without taking the item
 260         pickedup = FALSE;
 261         _switchweapon = FALSE;
 262
 263         if (g_minstagib)
 264         {
 265                 if(item.spawnshieldtime)
 266                 {
 267                         if (item.ammo_fuel)
 268                         if (player.ammo_fuel < g_pickup_fuel_max)
 269                         {
 270                                 pickedup = TRUE;
 271                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 272                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 273                         }
 274                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 275                         {
 276                                 pickedup = TRUE;
 277                                 player.items |= it;
 278                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 279                         }
 280
 281                         _switchweapon = TRUE;
 282                         if (item.ammo_cells)
 283                         {
 284                                 pickedup = TRUE;
 285                                 // play some cool sounds ;)
 286                                 centerprint(player, "\n");
 287                                 if (clienttype(player) == CLIENTTYPE_REAL)
 288                                 {
 289                                         if(player.health <= 5)
 290                                                 AnnounceTo(player, "lastsecond");
 291                                         else if(player.health < 50)
 292                                                 AnnounceTo(player, "narrowly");
 293                                 }
 294                                 // sound not available
 295                                 // else if(item.items == IT_CELLS)
 296                                 //      AnnounceTo(player, "ammo");
 297
 298                                 if (item.weapons & WEPBIT_MINSTANEX)
 299                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 300                                 if (item.ammo_cells)
 301                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 302                                 player.health = 100;
 303                         }
 304
 305                         // extralife powerup
 306                         if (item.max_health)
 307                         {
 308                                 pickedup = TRUE;
 309                                 // sound not available
 310                                 // AnnounceTo(player, "_lives");
 311                                 player.armorvalue = min(player.armorvalue + cvar("g_minstagib_extralives"), 999);
 312                                 sprint(player, "^3You picked up some extra lives\n");
 313                         }
 314
 315                         // invis powerup
 316                         if (item.strength_finished)
 317                         {
 318                                 pickedup = TRUE;
 319                                 // sound not available
 320                                 // AnnounceTo(player, "invisible");
 321                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 322                         }
 323
 324                         // speed powerup
 325                         if (item.invincible_finished)
 326                         {
 327                                 pickedup = TRUE;
 328                                 // sound not available
 329                                 // AnnounceTo(player, "speed");
 330                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 331                         }
 332
 333                         if (item.ammo_fuel)
 334                         if (player.ammo_fuel < g_pickup_fuel_max)
 335                         {
 336                                 pickedup = TRUE;
 337                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 338                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 339                         }
 340                 }
 341         }
 342         else
 343         {
 344                 if (g_weapon_stay == 1)
 345                 if not(item.flags & FL_NO_WEAPON_STAY)
 346                 if (item.flags & FL_WEAPON)
 347                 {
 348                         if(item.classname == "droppedweapon")
 349                         {
 350                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 351                                         goto skip;
 352                         }
 353                         else
 354                         {
 355                                 if (player.weapons & item.weapons)
 356                                         goto skip;
 357                         }
 358                 }
 359
 360                 // in case the player has autoswitch enabled do the following:
 361                 // if the player is using their best weapon before items are given, they
 362                 // probably want to switch to an even better weapon after items are given
 363                 if (player.autoswitch)
 364                 if (player.switchweapon == w_getbestweapon(player))
 365                         _switchweapon = TRUE;
 366
 367                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 368                         _switchweapon = TRUE;
 369
 370                 if(item.spawnshieldtime)
 371                 {
 372                         if (item.ammo_shells)
 373                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 374                         {
 375                                 pickedup = TRUE;
 376                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 377                         }
 378                         if (item.ammo_nails)
 379                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 380                         {
 381                                 pickedup = TRUE;
 382                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 383                         }
 384                         if (item.ammo_rockets)
 385                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 386                         {
 387                                 pickedup = TRUE;
 388                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 389                         }
 390                         if (item.ammo_cells)
 391                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 392                         {
 393                                 pickedup = TRUE;
 394                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 395                         }
 396                         if (item.ammo_fuel)
 397                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 398                         {
 399                                 pickedup = TRUE;
 400                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 401                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 402                         }
 403                 }
 404
 405                 if (item.flags & FL_WEAPON)
 406                 if ((it = item.weapons - (item.weapons & player.weapons)) || g_pickup_weapons_anyway)
 407                 {
 408                         pickedup = TRUE;
 409                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 410                         {
 411                                 e = get_weaponinfo(i);
 412                                 if(it & e.weapons)
 413                                         W_GiveWeapon (player, e.weapon, item.netname);
 414                         }
 415                 }
 416
 417                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 418                 {
 419                         pickedup = TRUE;
 420                         player.items |= it;
 421                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 422                 }
 423
 424                 if(item.spawnshieldtime)
 425                 {
 426                         if (item.strength_finished)
 427                         {
 428                                 pickedup = TRUE;
 429                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 430                         }
 431                         if (item.invincible_finished)
 432                         {
 433                                 pickedup = TRUE;
 434                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 435                         }
 436
 437                         if (item.health)
 438                         if ((player.health < item.max_health) || item.pickup_anyway)
 439                         {
 440                                 pickedup = TRUE;
 441                                 player.health = min(player.health + item.health, item.max_health);
 442                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 443                         }
 444                         if (item.armorvalue)
 445                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 446                         {
 447                                 pickedup = TRUE;
 448                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 449                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 450                         }
 451                 }
 452         }
 453
 454 :skip
 455         // always eat teamed entities
 456         if(item.team)
 457                 pickedup = TRUE;
 458
 459         if (!pickedup)
 460                 return 0;
 461
 462         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 463         if (_switchweapon)
 464                 if (player.switchweapon != w_getbestweapon(player))
 465                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 466
 467         return 1;
 468 }
 469
 470 void Item_Touch (void)
 471 {
 472         entity e, head;
 473
 474         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 475         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 476         {
 477                 remove(self);
 478                 return;
 479         }
 480         if (other.classname != "player")
 481                 return;
 482         if (other.deadflag)
 483                 return;
 484         if (self.solid != SOLID_TRIGGER)
 485                 return;
 486         if (self.owner == other)
 487                 return;
 488
 489         if(!Item_GiveTo(self, other))
 490                 return;
 491
 492         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 493
 494         if (self.classname == "droppedweapon")
 495                 remove (self);
 496         else if not(self.spawnshieldtime)
 497                 return;
 498         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 499                 return;
 500         else
 501         {
 502                 if(self.team)
 503                 {
 504                         RandomSelection_Init();
 505                         for(head = world; (head = findfloat(head, team, self.team)); )
 506                         {
 507                                 if(head.flags & FL_ITEM)
 508                                 {
 509                                         Item_Show(head, -1);
 510                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 511                                 }
 512                         }
 513                         e = RandomSelection_chosen_ent;
 514                 }
 515                 else
 516                         e = self;
 517                 Item_ScheduleRespawn(e);
 518         }
 519 }
 520
 521 void Item_FindTeam()
 522 {
 523         entity head, e;
 524
 525         if(self.effects & EF_NODRAW)
 526         {
 527                 // marker for item team search
 528                 dprint("Initializing item team ", ftos(self.team), "\n");
 529                 RandomSelection_Init();
 530                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 531                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 532                 e = RandomSelection_chosen_ent;
 533                 e.state = 0;
 534                 Item_Show(e, 1);
 535
 536                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 537                 {
 538                         if(head != e)
 539                         {
 540                                 // make it a non-spawned item
 541                                 Item_Show(head, -1);
 542                                 head.state = 1; // state 1 = initially hidden item
 543                         }
 544                         head.effects &~= EF_NODRAW;
 545                 }
 546
 547                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 548                         Item_ScheduleInitialRespawn(e);
 549         }
 550 }
 551
 552 void Item_Reset()
 553 {
 554         Item_Show(self, !self.state);
 555         setorigin (self, self.origin);
 556         self.think = SUB_Null;
 557         self.nextthink = 0;
 558
 559         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 560                 Item_ScheduleInitialRespawn(self);
 561 }
 562
 563 // Savage: used for item garbage-collection
 564 // TODO: perhaps nice special effect?
 565 void RemoveItem(void)
 566 {
 567         remove(self);
 568 }
 569
 570 // pickup evaluation functions
 571 // these functions decide how desirable an item is to the bots
 572
 573 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 574
 575 float weapon_pickupevalfunc(entity player, entity item)
 576 {
 577         float c, i, j, position;
 578
 579         // See if I have it already
 580         if(player.weapons & item.weapons == item.weapons)
 581         {
 582                 // If I can pick it up
 583                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 584                         c = 0;
 585                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 586                 {
 587                         // Skilled bots will grab more
 588                         c = bound(0, skill / 10, 1) * 0.5;
 589                 }
 590                 else
 591                         c = 0;
 592         }
 593         else
 594                 c = 1;
 595
 596         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 597         if( bot_custom_weapon && c )
 598         {
 599                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 600                 {
 601                         // Find weapon
 602                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 603                                 continue;
 604
 605                         // Find the highest position on any range
 606                         position = -1;
 607                         for(j = 0; j < WEP_LAST ; ++j){
 608                                 if(
 609                                                 bot_weapons_far[j] == i ||
 610                                                 bot_weapons_mid[j] == i ||
 611                                                 bot_weapons_close[j] == i
 612                                   )
 613                                 {
 614                                         position = j;
 615                                         break;
 616                                 }
 617                         }
 618
 619                         // Rate it
 620                         if (position >= 0 )
 621                         {
 622                                 position = WEP_LAST - position;
 623                                 // item.bot_pickupbasevalue is overwritten here
 624                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 625                         }
 626                 }
 627         }
 628
 629         return item.bot_pickupbasevalue * c;
 630 };
 631
 632 float commodity_pickupevalfunc(entity player, entity item)
 633 {
 634         float c, i, need_shells, need_nails, need_rockets, need_cells;
 635         entity wi;
 636         c = 0;
 637
 638         // Detect needed ammo
 639         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 640         {
 641                 wi = get_weaponinfo(i);
 642
 643                 if not(wi.weapons & player.weapons)
 644                         continue;
 645
 646                 if(wi.items & IT_SHELLS)
 647                         need_shells = TRUE;
 648                 else if(wi.items & IT_NAILS)
 649                         need_nails = TRUE;
 650                 else if(wi.items & IT_ROCKETS)
 651                         need_rockets = TRUE;
 652                 else if(wi.items & IT_CELLS)
 653                         need_cells = TRUE;
 654         }
 655
 656         // TODO: figure out if the player even has the weapon this ammo is for?
 657         // may not affect strategy much though...
 658         // find out how much more ammo/armor/health the player can hold
 659         if (need_shells)
 660         if (item.ammo_shells)
 661         if (player.ammo_shells < g_pickup_shells_max)
 662                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 663         if (need_nails)
 664         if (item.ammo_nails)
 665         if (player.ammo_nails < g_pickup_nails_max)
 666                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 667         if (need_rockets)
 668         if (item.ammo_rockets)
 669         if (player.ammo_rockets < g_pickup_rockets_max)
 670                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 671         if (need_cells)
 672         if (item.ammo_cells)
 673         if (player.ammo_cells < g_pickup_cells_max)
 674                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 675         if (item.armorvalue)
 676         if (player.armorvalue < item.max_armorvalue)
 677                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 678         if (item.health)
 679         if (player.health < item.max_health)
 680                 c = c + max(0, 1 - player.health / item.max_health);
 681
 682         return item.bot_pickupbasevalue * c;
 683 };
 684
 685
 686 .float is_item;
 687 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 688 {
 689         startitem_failed = FALSE;
 690
 691         self.items = itemid;
 692         self.weapons = weaponid;
 693
 694         // is it a dropped weapon?
 695         if (self.classname == "droppedweapon")
 696         {
 697                 self.reset = SUB_Remove;
 698                 // it's a dropped weapon
 699                 self.movetype = MOVETYPE_TOSS;
 700                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 701                 self.think = RemoveItem;
 702                 self.nextthink = time + 60;
 703                 // don't drop if in a NODROP zone (such as lava)
 704                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 705                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 706                 {
 707                         startitem_failed = TRUE;
 708                         remove(self);
 709                         return;
 710                 }
 711         }
 712         else
 713         {
 714                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 715                 {
 716                         startitem_failed = TRUE;
 717                         remove(self);
 718                         return;
 719                 }
 720
 721                 self.reset = Item_Reset;
 722                 // it's a level item
 723                 if(self.spawnflags & 1)
 724                         self.noalign = 1;
 725                 if (self.noalign)
 726                         self.movetype = MOVETYPE_NONE;
 727                 else
 728                         self.movetype = MOVETYPE_TOSS;
 729                 // do item filtering according to game mode and other things
 730                 if (!self.noalign)
 731                 {
 732                         // first nudge it off the floor a little bit to avoid math errors
 733                         setorigin(self, self.origin + '0 0 1');
 734                         // set item size before we spawn a spawnfunc_waypoint
 735                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 736                                 setsize (self, '-16 -16 0', '16 16 48');
 737                         else
 738                                 setsize (self, '-16 -16 0', '16 16 32');
 739                         // note droptofloor returns FALSE if stuck/or would fall too far
 740                         droptofloor();
 741                         waypoint_spawnforitem(self);
 742                 }
 743
 744                 if(teams_matter)
 745                 {
 746                         if(self.notteam)
 747                         {
 748                                 print("removed non-teamplay ", self.classname, "\n");
 749                                 startitem_failed = TRUE;
 750                                 remove (self);
 751                                 return;
 752                         }
 753                 }
 754                 else
 755                 {
 756                         if(self.notfree)
 757                         {
 758                                 print("removed non-FFA ", self.classname, "\n");
 759                                 startitem_failed = TRUE;
 760                                 remove (self);
 761                                 return;
 762                         }
 763                 }
 764
 765                 if(self.notq3a)
 766                 {
 767                         // We aren't TA or something like that, so we keep the Q3A entities
 768                         print("removed non-Q3A ", self.classname, "\n");
 769                         startitem_failed = TRUE;
 770                         remove (self);
 771                         return;
 772                 }
 773
 774                 /*
 775                  * can't do it that way, as it would break maps
 776                  * TODO make a target_give like entity another way, that perhaps has
 777                  * the weapon name in a key
 778                 if(self.targetname)
 779                 {
 780                         // target_give not yet supported; maybe later
 781                         print("removed targeted ", self.classname, "\n");
 782                         startitem_failed = TRUE;
 783                         remove (self);
 784                         return;
 785                 }
 786                 */
 787
 788                 if(cvar("spawn_debug") >= 2)
 789                 {
 790                         entity otheritem;
 791                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 792                         {
 793                                 if(otheritem.is_item)
 794                                 {
 795                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 796                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 797                                         error("Mapper sucks.");
 798                                 }
 799                         }
 800                         self.is_item = TRUE;
 801                 }
 802
 803                 if(g_lms || g_ca)
 804                 {
 805                         startitem_failed = TRUE;
 806                         remove(self);
 807                         return;
 808                 }
 809                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 810                 {
 811                         startitem_failed = TRUE;
 812                         remove(self);
 813                         return;
 814                 }
 815                 else if (g_minstagib)
 816                 {
 817                         // don't remove dropped items and powerups
 818                         if (self.classname != "minstagib")
 819                         {
 820                                 startitem_failed = TRUE;
 821                                 remove (self);
 822                                 return;
 823                         }
 824                 }
 825                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 826                 {
 827                         startitem_failed = TRUE;
 828                         remove (self);
 829                         return;
 830                 }
 831
 832                 weaponsInMap |= weaponid;
 833
 834                 precache_model (itemmodel);
 835                 precache_sound (pickupsound);
 836
 837                 precache_sound ("misc/itemrespawncountdown.wav");
 838                 if(!g_minstagib && itemid == IT_STRENGTH)
 839                         precache_sound ("misc/strength_respawn.wav");
 840                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 841                         precache_sound ("misc/shield_respawn.wav");
 842                 else
 843                         precache_sound ("misc/itemrespawn.wav");
 844
 845                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 846                         self.target = "###item###"; // for finding the nearest item using find()
 847         }
 848
 849         self.bot_pickup = TRUE;
 850         self.bot_pickupevalfunc = pickupevalfunc;
 851         self.bot_pickupbasevalue = pickupbasevalue;
 852         self.mdl = itemmodel;
 853         self.item_pickupsound = pickupsound;
 854         // let mappers override respawntime
 855         if(!self.respawntime) // both set
 856         {
 857                 self.respawntime = defaultrespawntime;
 858                 self.respawntimejitter = defaultrespawntimejitter;
 859         }
 860         self.netname = itemname;
 861         self.flags = FL_ITEM | itemflags;
 862         self.touch = Item_Touch;
 863         setmodel (self, self.mdl); // precision set below
 864         self.effects |= EF_LOWPRECISION;
 865         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 866                 setsize (self, '-16 -16 0', '16 16 48');
 867         else
 868                 setsize (self, '-16 -16 0', '16 16 32');
 869         if(itemflags & FL_WEAPON)
 870                 self.modelflags |= MF_ROTATE;
 871
 872         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 873         if (itemflags & FL_WEAPON)
 874         {
 875                 // neutral team color for pickup weapons
 876                 self.colormap = 1024; // color shirt=0 pants=0 grey
 877         }
 878
 879         Item_Show(self, 1);
 880         self.state = 0;
 881         if(self.team)
 882         {
 883                 if(!self.cnt)
 884                         self.cnt = 1; // item probability weight
 885                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 886                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 887         }
 888         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 889                 Item_ScheduleInitialRespawn(self);
 890 }
 891
 892 /* replace items in minstagib
 893  * IT_STRENGTH   = invisibility
 894  * IT_NAILS      = extra lives
 895  * IT_INVINCIBLE = speed
 896  */
 897 void minstagib_items (float itemid)
 898 {
 899         local float rnd;
 900         self.classname = "minstagib";
 901
 902         // replace rocket launchers and nex guns with ammo cells
 903         if (itemid == IT_CELLS)
 904         {
 905                 self.ammo_cells = 1;
 906                 StartItem ("models/items/a_cells.md3",
 907                         "misc/itempickup.wav", 45, 0,
 908                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 909                 return;
 910         }
 911
 912         // randomize
 913         rnd = random() * 3;
 914         if (rnd <= 1)
 915                 itemid = IT_STRENGTH;
 916         else if (rnd <= 2)
 917                 itemid = IT_NAILS;
 918         else
 919                 itemid = IT_INVINCIBLE;
 920
 921         // replace with invis
 922         if (itemid == IT_STRENGTH)
 923         {
 924                 self.strength_finished = 30;
 925                 StartItem ("models/items/g_strength.md3",
 926                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 927                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 928         }
 929         // replace with extra lives
 930         if (itemid == IT_NAILS)
 931         {
 932                 self.max_health = 1;
 933                 StartItem ("models/items/g_h100.md3",
 934                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 935                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 936         }
 937         // replace with speed
 938         if (itemid == IT_INVINCIBLE)
 939         {
 940                 self.invincible_finished = 30;
 941                 StartItem ("models/items/g_invincible.md3",
 942                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 943                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 944         }
 945 }
 946
 947 float minst_no_auto_cells;
 948 void minst_remove_item (void) {
 949         if(minst_no_auto_cells)
 950                 remove(self);
 951 }
 952
 953 float weaponswapping;
 954 float internalteam;
 955
 956 void weapon_defaultspawnfunc(float wpn)
 957 {
 958         entity e;
 959         float t;
 960         var .float ammofield;
 961         string s;
 962         entity oldself;
 963         float i, j;
 964
 965         // set the respawntime in advance (so replaced weapons can copy it)
 966
 967         if(!self.respawntime)
 968         {
 969                 e = get_weaponinfo(wpn);
 970                 if(e.items == IT_SUPERWEAPON)
 971                 {
 972                         self.respawntime = g_pickup_respawntime_powerup;
 973                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 974                 }
 975                 else
 976                 {
 977                         self.respawntime = g_pickup_respawntime_weapon;
 978                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 979                 }
 980         }
 981
 982         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 983         {
 984                 e = get_weaponinfo(wpn);
 985                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 986                 if(s == "0")
 987                 {
 988                         remove(self);
 989                         startitem_failed = TRUE;
 990                         return;
 991                 }
 992                 t = tokenize_console(s);
 993                 if(t >= 2)
 994                 {
 995                         self.team = --internalteam;
 996                         oldself = self;
 997                         for(i = 1; i < t; ++i)
 998                         {
 999                                 s = argv(i);
1000                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1001                                 {
1002                                         e = get_weaponinfo(j);
1003                                         if(e.netname == s)
1004                                         {
1005                                                 self = spawn();
1006                                                 copyentity(oldself, self);
1007                                                 self.classname = "replacedweapon";
1008                                                 weapon_defaultspawnfunc(j);
1009                                                 break;
1010                                         }
1011                                 }
1012                                 if(j > WEP_LAST)
1013                                 {
1014                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1015                                 }
1016                         }
1017                         self = oldself;
1018                 }
1019                 if(t >= 1)
1020                 {
1021                         s = argv(0);
1022                         wpn = 0;
1023                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1024                         {
1025                                 e = get_weaponinfo(j);
1026                                 if(e.netname == s)
1027                                 {
1028                                         wpn = j;
1029                                         break;
1030                                 }
1031                         }
1032                         if(j > WEP_LAST)
1033                         {
1034                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1035                         }
1036                 }
1037                 if(wpn == 0)
1038                 {
1039                         remove(self);
1040                         startitem_failed = TRUE;
1041                         return;
1042                 }
1043         }
1044
1045         e = get_weaponinfo(wpn);
1046
1047         if(e.items && e.items != IT_SUPERWEAPON)
1048         {
1049                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1050                 {
1051                         if(e.items & j)
1052                         {
1053                                 ammofield = Item_CounterField(j);
1054                                 if(!self.ammofield)
1055                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1056                         }
1057                 }
1058         }
1059         else
1060         {
1061                 self.flags |= FL_NO_WEAPON_STAY;
1062         }
1063
1064         // weapon stay isn't supported for teamed weapons
1065         if(self.team)
1066                 self.flags |= FL_NO_WEAPON_STAY;
1067
1068         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1069         {
1070                 self.ammo_shells = 0;
1071                 self.ammo_nails = 0;
1072                 self.ammo_cells = 0;
1073                 self.ammo_rockets = 0;
1074                 // weapon stay 2: don't use ammo on weapon pickups; instead
1075                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1076         }
1077
1078         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1079         if (self.modelindex) // don't precache if self was removed
1080                 weapon_action(e.weapon, WR_PRECACHE);
1081 }
1082
1083 void spawnfunc_weapon_shotgun (void);
1084 void spawnfunc_weapon_uzi (void) {
1085         if(q3acompat_machineshotgunswap)
1086         if(self.classname != "droppedweapon")
1087         {
1088                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1089                 return;
1090         }
1091         weapon_defaultspawnfunc(WEP_UZI);
1092 }
1093
1094 void spawnfunc_weapon_shotgun (void) {
1095         if(q3acompat_machineshotgunswap)
1096         if(self.classname != "droppedweapon")
1097         {
1098                 weapon_defaultspawnfunc(WEP_UZI);
1099                 return;
1100         }
1101         weapon_defaultspawnfunc(WEP_SHOTGUN);
1102 }
1103
1104 void spawnfunc_weapon_nex (void)
1105 {
1106         if (g_minstagib)
1107         {
1108                 minstagib_items(IT_CELLS);
1109                 self.think = minst_remove_item;
1110                 self.nextthink = time;
1111                 return;
1112         }
1113         weapon_defaultspawnfunc(WEP_NEX);
1114 }
1115
1116 void spawnfunc_weapon_minstanex (void)
1117 {
1118         if (g_minstagib)
1119         {
1120                 minstagib_items(IT_CELLS);
1121                 self.think = minst_remove_item;
1122                 self.nextthink = time;
1123                 return;
1124         }
1125         weapon_defaultspawnfunc(WEP_MINSTANEX);
1126 }
1127
1128 void spawnfunc_weapon_rocketlauncher (void)
1129 {
1130         if (g_minstagib)
1131         {
1132                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1133                 self.think = minst_remove_item;
1134                 self.nextthink = time;
1135                 return;
1136         }
1137         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1138 }
1139
1140 void spawnfunc_item_rockets (void) {
1141         if(!self.ammo_rockets)
1142                 self.ammo_rockets = g_pickup_rockets;
1143         if(!self.pickup_anyway)
1144                 self.pickup_anyway = g_pickup_ammo_anyway;
1145         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1146 }
1147
1148 void spawnfunc_item_shells (void);
1149 void spawnfunc_item_bullets (void) {
1150         if(!weaponswapping)
1151         if(q3acompat_machineshotgunswap)
1152         if(self.classname != "droppedweapon")
1153         {
1154                 weaponswapping = TRUE;
1155                 spawnfunc_item_shells();
1156                 weaponswapping = FALSE;
1157                 return;
1158         }
1159
1160         if(!self.ammo_nails)
1161                 self.ammo_nails = g_pickup_nails;
1162         if(!self.pickup_anyway)
1163                 self.pickup_anyway = g_pickup_ammo_anyway;
1164         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1165 }
1166
1167 void spawnfunc_item_cells (void) {
1168         if(!self.ammo_cells)
1169                 self.ammo_cells = g_pickup_cells;
1170         if(!self.pickup_anyway)
1171                 self.pickup_anyway = g_pickup_ammo_anyway;
1172         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1173 }
1174
1175 void spawnfunc_item_shells (void) {
1176         if(!weaponswapping)
1177         if(q3acompat_machineshotgunswap)
1178         if(self.classname != "droppedweapon")
1179         {
1180                 weaponswapping = TRUE;
1181                 spawnfunc_item_bullets();
1182                 weaponswapping = FALSE;
1183                 return;
1184         }
1185
1186         if(!self.ammo_shells)
1187                 self.ammo_shells = g_pickup_shells;
1188         if(!self.pickup_anyway)
1189                 self.pickup_anyway = g_pickup_ammo_anyway;
1190         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1191 }
1192
1193 void spawnfunc_item_armor_small (void) {
1194         if(!self.armorvalue)
1195                 self.armorvalue = g_pickup_armorsmall;
1196         if(!self.max_armorvalue)
1197                 self.max_armorvalue = g_pickup_armorsmall_max;
1198         if(!self.pickup_anyway)
1199                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1200         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1201 }
1202
1203 void spawnfunc_item_armor_medium (void) {
1204         if(!self.armorvalue)
1205                 self.armorvalue = g_pickup_armormedium;
1206         if(!self.max_armorvalue)
1207                 self.max_armorvalue = g_pickup_armormedium_max;
1208         if(!self.pickup_anyway)
1209                 self.pickup_anyway = g_pickup_armormedium_anyway;
1210         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1211 }
1212
1213 void spawnfunc_item_armor_big (void) {
1214         if(!self.armorvalue)
1215                 self.armorvalue = g_pickup_armorbig;
1216         if(!self.max_armorvalue)
1217                 self.max_armorvalue = g_pickup_armorbig_max;
1218         if(!self.pickup_anyway)
1219                 self.pickup_anyway = g_pickup_armorbig_anyway;
1220         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1221 }
1222
1223 void spawnfunc_item_armor_large (void) {
1224         if(!self.armorvalue)
1225                 self.armorvalue = g_pickup_armorlarge;
1226         if(!self.max_armorvalue)
1227                 self.max_armorvalue = g_pickup_armorlarge_max;
1228         if(!self.pickup_anyway)
1229                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1230         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1231 }
1232
1233 void spawnfunc_item_health_small (void) {
1234         if(!self.max_health)
1235                 self.max_health = g_pickup_healthsmall_max;
1236         if(!self.health)
1237                 self.health = g_pickup_healthsmall;
1238         if(!self.pickup_anyway)
1239                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1240         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1241 }
1242
1243 void spawnfunc_item_health_medium (void) {
1244         if(!self.max_health)
1245                 self.max_health = g_pickup_healthmedium_max;
1246         if(!self.health)
1247                 self.health = g_pickup_healthmedium;
1248         if(!self.pickup_anyway)
1249                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1250         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1251 }
1252
1253 void spawnfunc_item_health_large (void) {
1254         if(!self.max_health)
1255                 self.max_health = g_pickup_healthlarge_max;
1256         if(!self.health)
1257                 self.health = g_pickup_healthlarge;
1258         if(!self.pickup_anyway)
1259                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1260         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1261 }
1262
1263 void spawnfunc_item_health_mega (void) {
1264         if(!cvar("g_powerup_superhealth"))
1265                 return;
1266
1267         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1268                 return;
1269
1270         if(g_minstagib) {
1271                 minstagib_items(IT_NAILS);
1272         } else {
1273                 if(!self.max_health)
1274                         self.max_health = g_pickup_healthmega_max;
1275                 if(!self.health)
1276                         self.health = g_pickup_healthmega;
1277                 if(!self.pickup_anyway)
1278                         self.pickup_anyway = g_pickup_healthmega_anyway;
1279                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1280         }
1281 }
1282
1283 // support old misnamed entities
1284 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1285 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1286 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1287 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1288 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1289
1290 void spawnfunc_item_strength (void) {
1291         if(!cvar("g_powerup_strength"))
1292                 return;
1293
1294         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1295                 return;
1296
1297         if(g_minstagib) {
1298                 minstagib_items(IT_STRENGTH);
1299         } else {
1300                 precache_sound("weapons/strength_fire.wav");
1301                 self.strength_finished = 30;
1302                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1303         }
1304 }
1305
1306 void spawnfunc_item_invincible (void) {
1307         if(!cvar("g_powerup_shield"))
1308                 return;
1309
1310         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1311                 return;
1312
1313         if(g_minstagib) {
1314                 minstagib_items(IT_INVINCIBLE);
1315         } else {
1316                 self.invincible_finished = 30;
1317                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1318         }
1319 }
1320
1321 void spawnfunc_item_minst_cells (void) {
1322         if (g_minstagib)
1323         {
1324                 minst_no_auto_cells = 1;
1325                 minstagib_items(IT_CELLS);
1326         }
1327         else
1328                 remove(self);
1329 }
1330
1331 // compatibility:
1332 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1333
1334 float GiveItems(entity e, float beginarg, float endarg);
1335 void target_items_use (void)
1336 {
1337         if(activator.classname == "droppedweapon")
1338         {
1339                 EXACTTRIGGER_TOUCH;
1340                 remove(activator);
1341                 return;
1342         }
1343
1344         if(activator.classname != "player")
1345                 return;
1346         if(activator.deadflag != DEAD_NO)
1347                 return;
1348         EXACTTRIGGER_TOUCH;
1349
1350         entity e;
1351         for(e = world; (e = find(e, classname, "droppedweapon")); )
1352                 if(e.enemy == activator)
1353                         remove(e);
1354
1355         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1356                 centerprint(activator, self.message);
1357 }
1358
1359 void spawnfunc_target_items (void)
1360 {
1361         float n, i, j;
1362         entity e;
1363
1364         self.use = target_items_use;
1365         if(!self.strength_finished)
1366                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1367         if(!self.invincible_finished)
1368                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1369
1370         precache_sound("misc/itempickup.wav");
1371         precache_sound("misc/megahealth.wav");
1372         precache_sound("misc/armor25.wav");
1373         precache_sound("misc/powerup.wav");
1374         precache_sound("misc/poweroff.wav");
1375         precache_sound("weapons/weaponpickup.wav");
1376
1377         n = tokenize_console(self.netname);
1378         if(argv(0) == "give")
1379         {
1380                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1381         }
1382         else
1383         {
1384                 for(i = 0; i < n; ++i)
1385                 {
1386                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1387                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1388                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1389                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1390                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1391                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1392                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1393                         else
1394                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1395                         {
1396                                 e = get_weaponinfo(j);
1397                                 if(argv(i) == e.netname)
1398                                 {
1399                                         self.weapons |= e.weapons;
1400                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1401                                                 weapon_action(e.weapon, WR_PRECACHE);
1402                                         break;
1403                                 }
1404                         }
1405                         if(j > WEP_LAST)
1406                                 print("target_items: invalid item ", argv(i), "\n");
1407                 }
1408
1409                 string itemprefix, valueprefix;
1410                 if(self.spawnflags == 0)
1411                 {
1412                         itemprefix = "";
1413                         valueprefix = "";
1414                 }
1415                 else if(self.spawnflags == 1)
1416                 {
1417                         itemprefix = "max ";
1418                         valueprefix = "max ";
1419                 }
1420                 else if(self.spawnflags == 2)
1421                 {
1422                         itemprefix = "min ";
1423                         valueprefix = "min ";
1424                 }
1425                 else if(self.spawnflags == 4)
1426                 {
1427                         itemprefix = "minus ";
1428                         valueprefix = "max ";
1429                 }
1430                 else
1431                         error("invalid spawnflags");
1432
1433                 self.netname = "";
1434                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1435                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1436                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1437                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1438                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1439                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1440                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1441                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1442                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1443                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1444                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1445                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1446                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1447                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1448                 {
1449                         e = get_weaponinfo(j);
1450                         if(e.weapons)
1451                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1452                 }
1453         }
1454         self.netname = strzone(self.netname);
1455         //print(self.netname, "\n");
1456
1457         n = tokenize_console(self.netname);
1458         for(i = 0; i < n; ++i)
1459         {
1460                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1461                 {
1462                         e = get_weaponinfo(j);
1463                         if(argv(i) == e.netname)
1464                         {
1465                                 weapon_action(e.weapon, WR_PRECACHE);
1466                                 break;
1467                         }
1468                 }
1469         }
1470 }
1471
1472 void spawnfunc_item_fuel(void)
1473 {
1474         if(!self.ammo_fuel)
1475                 self.ammo_fuel = g_pickup_fuel;
1476         if(!self.pickup_anyway)
1477                 self.pickup_anyway = g_pickup_ammo_anyway;
1478         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1479 }
1480
1481 void spawnfunc_item_fuel_regen(void)
1482 {
1483         if(start_items & IT_FUEL_REGEN)
1484         {
1485                 spawnfunc_item_fuel();
1486                 return;
1487         }
1488         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1489 }
1490
1491 void spawnfunc_item_jetpack(void)
1492 {
1493         if(g_grappling_hook)
1494                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1495         if(!self.ammo_fuel)
1496                 self.ammo_fuel = g_pickup_fuel_jetpack;
1497         if(start_items & IT_JETPACK)
1498         {
1499                 spawnfunc_item_fuel();
1500                 return;
1501         }
1502         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1503 }
1504
1505
1506 #define OP_SET 0
1507 #define OP_MIN 1
1508 #define OP_MAX 2
1509 #define OP_PLUS 3
1510 #define OP_MINUS 4
1511
1512 float GiveBit(entity e, .float fld, float bit, float op, float val)
1513 {
1514         float v0, v1;
1515         v0 = (e.fld & bit);
1516         switch(op)
1517         {
1518                 case OP_SET:
1519                         if(val > 0)
1520                                 e.fld |= bit;
1521                         else
1522                                 e.fld &~= bit;
1523                         break;
1524                 case OP_MIN:
1525                 case OP_PLUS:
1526                         if(val > 0)
1527                                 e.fld |= bit;
1528                         break;
1529                 case OP_MAX:
1530                         if(val <= 0)
1531                                 e.fld &~= bit;
1532                         break;
1533                 case OP_MINUS:
1534                         if(val > 0)
1535                                 e.fld &~= bit;
1536                         break;
1537         }
1538         v1 = (e.fld & bit);
1539         return (v0 != v1);
1540 }
1541
1542 float GiveValue(entity e, .float fld, float op, float val)
1543 {
1544         float v0, v1;
1545         v0 = e.fld;
1546         switch(op)
1547         {
1548                 case OP_SET:
1549                         e.fld = val;
1550                         break;
1551                 case OP_MIN:
1552                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1553                         break;
1554                 case OP_MAX:
1555                         e.fld = min(e.fld, val);
1556                         break;
1557                 case OP_PLUS:
1558                         e.fld += val;
1559                         break;
1560                 case OP_MINUS:
1561                         e.fld -= val;
1562                         break;
1563         }
1564         v1 = e.fld;
1565         return (v0 != v1);
1566 }
1567
1568 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1569 {
1570         if(v1 == v0)
1571                 return;
1572         if(v1 <= v0 - t)
1573         {
1574                 if(snd_decr != "")
1575                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1576         }
1577         else if(v0 >= v0 + t)
1578         {
1579                 if(snd_incr != "")
1580                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1581         }
1582 }
1583
1584 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1585 {
1586         if(v0 < v1)
1587                 e.rotfield = max(e.rotfield, time + rottime);
1588         else if(v0 > v1)
1589                 e.regenfield = max(e.regenfield, time + regentime);
1590 }
1591
1592 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1593 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1594 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1595 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1596
1597 float GiveItems(entity e, float beginarg, float endarg)
1598 {
1599         float got, i, j, val, op;
1600         float _switchweapon;
1601         entity wi;
1602         string cmd;
1603
1604         val = 999;
1605         op = OP_SET;
1606
1607         got = 0;
1608
1609         _switchweapon = FALSE;
1610         if (e.autoswitch)
1611                 if (e.switchweapon == w_getbestweapon(e))
1612                         _switchweapon = TRUE;
1613
1614         e.strength_finished = max(0, e.strength_finished - time);
1615         e.invincible_finished = max(0, e.invincible_finished - time);
1616
1617         PREGIVE(e, items);
1618         PREGIVE(e, weapons);
1619         PREGIVE(e, strength_finished);
1620         PREGIVE(e, invincible_finished);
1621         PREGIVE(e, ammo_nails);
1622         PREGIVE(e, ammo_cells);
1623         PREGIVE(e, ammo_shells);
1624         PREGIVE(e, ammo_rockets);
1625         PREGIVE(e, ammo_fuel);
1626         PREGIVE(e, armorvalue);
1627         PREGIVE(e, health);
1628
1629         for(i = beginarg; i < endarg; ++i)
1630         {
1631                 cmd = argv(i);
1632
1633                 if(cmd == "0" || stof(cmd))
1634                 {
1635                         val = stof(cmd);
1636                         continue;
1637                 }
1638                 switch(cmd)
1639                 {
1640                         case "no":
1641                                 op = OP_MAX;
1642                                 val = 0;
1643                                 continue;
1644                         case "max":
1645                                 op = OP_MAX;
1646                                 continue;
1647                         case "min":
1648                                 op = OP_MIN;
1649                                 continue;
1650                         case "plus":
1651                                 op = OP_PLUS;
1652                                 continue;
1653                         case "minus":
1654                                 op = OP_MINUS;
1655                                 continue;
1656                         case "ALL":
1657                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1658                                 got += GiveValue(e, strength_finished, op, time);
1659                                 got += GiveValue(e, invincible_finished, op, time);
1660                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1661                         case "all":
1662                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1663                                 got += GiveValue(e, health, op, val);
1664                                 got += GiveValue(e, armorvalue, op, val);
1665                         case "allweapons":
1666                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1667                                 {
1668                                         wi = get_weaponinfo(j);
1669                                         if(wi.weapons)
1670                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1671                                 }
1672                         case "allammo":
1673                                 got += GiveValue(e, ammo_cells, op, val);
1674                                 got += GiveValue(e, ammo_shells, op, val);
1675                                 got += GiveValue(e, ammo_nails, op, val);
1676                                 got += GiveValue(e, ammo_rockets, op, val);
1677                                 got += GiveValue(e, ammo_fuel, op, val);
1678                                 break;
1679                         case "unlimited_ammo":
1680                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1681                                 break;
1682                         case "unlimited_weapon_ammo":
1683                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1684                                 break;
1685                         case "unlimited_superweapons":
1686                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1687                                 break;
1688                         case "jetpack":
1689                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1690                                 break;
1691                         case "fuel_regen":
1692                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1693                                 break;
1694                         case "strength":
1695                                 got += GiveValue(e, strength_finished, op, val);
1696                                 break;
1697                         case "invincible":
1698                                 got += GiveValue(e, invincible_finished, op, val);
1699                                 break;
1700                         case "cells":
1701                                 got += GiveValue(e, ammo_cells, op, val);
1702                                 break;
1703                         case "shells":
1704                                 got += GiveValue(e, ammo_shells, op, val);
1705                                 break;
1706                         case "nails":
1707                         case "bullets":
1708                                 got += GiveValue(e, ammo_nails, op, val);
1709                                 break;
1710                         case "rockets":
1711                                 got += GiveValue(e, ammo_rockets, op, val);
1712                                 break;
1713                         case "health":
1714                                 got += GiveValue(e, health, op, val);
1715                                 break;
1716                         case "armor":
1717                                 got += GiveValue(e, armorvalue, op, val);
1718                                 break;
1719                         case "fuel":
1720                                 got += GiveValue(e, ammo_fuel, op, val);
1721                                 break;
1722                         default:
1723                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1724                                 {
1725                                         wi = get_weaponinfo(j);
1726                                         if(cmd == wi.netname)
1727                                         {
1728                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1729                                                 break;
1730                                         }
1731                                 }
1732                                 if(j > WEP_LAST)
1733                                         print("give: invalid item ", cmd, "\n");
1734                                 break;
1735                 }
1736                 val = 999;
1737                 op = OP_SET;
1738         }
1739
1740         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1741         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1742         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1743         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1744         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1745         {
1746                 wi = get_weaponinfo(j);
1747                 if(wi.weapons)
1748                 {
1749                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1750                         if not(save_weapons & wi.weapons)
1751                                 if(e.weapons & wi.weapons)
1752                                         weapon_action(wi.weapon, WR_PRECACHE);
1753                 }
1754         }
1755         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1756         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1757         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1758         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1759         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1760         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1761         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1762         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1763         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1764
1765         if (g_minstagib)
1766         {
1767                 e.health = bound(0, e.health, 100);
1768                 e.armorvalue = bound(0, e.armorvalue, 999);
1769         }
1770
1771         if(e.strength_finished <= 0)
1772                 e.strength_finished = 0;
1773         else
1774                 e.strength_finished += time;
1775         if(e.invincible_finished <= 0)
1776                 e.invincible_finished = 0;
1777         else
1778                 e.invincible_finished += time;
1779
1780         if not(e.weapons & W_WeaponBit(e.switchweapon))
1781                 _switchweapon = TRUE;
1782         if(_switchweapon)
1783                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1784
1785         return got;
1786 }