qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(!name)
 237                         {
 238                                 print("Unknown powerup-marked item is wanting to respawn\n");
 239                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 240                         }
 241                         if(name)
 242                         {
 243                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 244                                 if(self.waypointsprite_attached)
 245                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 246                         }
 247                 }
 248                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 249                 if(self.waypointsprite_attached)
 250                 {
 251                         WaypointSprite_Ping(self.waypointsprite_attached);
 252                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 253                 }
 254         }
 255 }
 256
 257 void Item_ScheduleRespawnIn(entity e, float t)
 258 {
 259         if(e.flags & FL_POWERUP)
 260         {
 261                 e.think = Item_RespawnCountdown;
 262                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 263                 e.count = 0;
 264         }
 265         else
 266         {
 267                 e.think = Item_Respawn;
 268                 e.nextthink = time + t;
 269         }
 270 }
 271
 272 void Item_ScheduleRespawn(entity e)
 273 {
 274         if(e.respawntime > 0)
 275         {
 276                 Item_Show(e, 0);
 277                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 278         }
 279         else // if respawntime is -1, this item does not respawn
 280                 Item_Show(e, -1);
 281 }
 282
 283 void Item_ScheduleInitialRespawn(entity e)
 284 {
 285         Item_Show(e, 0);
 286         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 287 }
 288
 289 float ITEM_MODE_NONE = 0;
 290 float ITEM_MODE_HEALTH = 1;
 291 float ITEM_MODE_ARMOR = 2;
 292 float ITEM_MODE_FUEL = 3;
 293 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 294 {
 295         if (!item.ammofield)
 296                 return FALSE;
 297
 298         if (item.spawnshieldtime)
 299         {
 300                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 301                 {
 302                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 303                         goto YEAH;
 304                 }
 305         }
 306         else if(g_weapon_stay == 2)
 307         {
 308                 float mi = min(item.ammofield, ammomax);
 309                 if (player.ammofield < mi)
 310                 {
 311                         player.ammofield = mi;
 312                         goto YEAH;
 313                 }
 314         }
 315
 316         return FALSE;
 317
 318 :YEAH
 319         switch(mode)
 320         {
 321                 case ITEM_MODE_FUEL:
 322                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 323                         break;
 324                 case ITEM_MODE_HEALTH:
 325                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 326                         break;
 327                 case ITEM_MODE_ARMOR:
 328                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 329                         break;
 330                 default:
 331                         break;
 332         }
 333         return TRUE;
 334 }
 335
 336 float Item_GiveTo(entity item, entity player)
 337 {
 338         float _switchweapon;
 339         float pickedup;
 340         float it;
 341         float i;
 342         entity e;
 343
 344         // if nothing happens to player, just return without taking the item
 345         pickedup = FALSE;
 346         _switchweapon = FALSE;
 347
 348         if (g_minstagib)
 349         {
 350                 float prevcells = player.ammo_cells;
 351
 352                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 353                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 354
 355                 if(player.ammo_cells > prevcells)
 356                 {
 357                         _switchweapon = TRUE;
 358
 359                         // play some cool sounds ;)
 360                         if (clienttype(player) == CLIENTTYPE_REAL)
 361                         {
 362                                 if(player.health <= 5)
 363                                         AnnounceTo(player, "lastsecond");
 364                                 else if(player.health < 50)
 365                                         AnnounceTo(player, "narrowly");
 366                         }
 367                         // sound not available
 368                         // else if(item.items == IT_CELLS)
 369                         //      AnnounceTo(player, "ammo");
 370
 371                         if (item.weapons & WEPBIT_MINSTANEX)
 372                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 373                         if (item.ammo_cells)
 374                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 375                         player.health = 100;
 376                 }
 377
 378                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 379                 {
 380                         pickedup = TRUE;
 381                         player.items |= it;
 382                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 383                 }
 384
 385                 // extralife powerup
 386                 if (item.max_health)
 387                 {
 388                         pickedup = TRUE;
 389                         // sound not available
 390                         // AnnounceTo(player, "_lives");
 391                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 392                         sprint(player, "^3You picked up some extra lives\n");
 393                 }
 394
 395                 // invis powerup
 396                 if (item.strength_finished)
 397                 {
 398                         pickedup = TRUE;
 399                         // sound not available
 400                         // AnnounceTo(player, "invisible");
 401                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 402                 }
 403
 404                 // speed powerup
 405                 if (item.invincible_finished)
 406                 {
 407                         pickedup = TRUE;
 408                         // sound not available
 409                         // AnnounceTo(player, "speed");
 410                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 411                 }
 412         }
 413         else
 414         {
 415                 // in case the player has autoswitch enabled do the following:
 416                 // if the player is using their best weapon before items are given, they
 417                 // probably want to switch to an even better weapon after items are given
 418                 if (player.autoswitch)
 419                 if (player.switchweapon == w_getbestweapon(player))
 420                         _switchweapon = TRUE;
 421
 422                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 423                         _switchweapon = TRUE;
 424
 425                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 426                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 427                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 428                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 429                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 430                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 431                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 432
 433                 if (item.flags & FL_WEAPON)
 434                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && g_pickup_weapons_anyway))
 435                 {
 436                         pickedup = TRUE;
 437                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 438                         {
 439                                 e = get_weaponinfo(i);
 440                                 if(it & e.weapons)
 441                                         W_GiveWeapon (player, e.weapon, item.netname);
 442                         }
 443                 }
 444
 445                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 446                 {
 447                         pickedup = TRUE;
 448                         player.items |= it;
 449                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 450                 }
 451
 452                 if (item.strength_finished)
 453                 {
 454                         pickedup = TRUE;
 455                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 456                 }
 457                 if (item.invincible_finished)
 458                 {
 459                         pickedup = TRUE;
 460                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 461                 }
 462         }
 463
 464 :skip
 465         // always eat teamed entities
 466         if(item.team)
 467                 pickedup = TRUE;
 468
 469         if (!pickedup)
 470                 return 0;
 471
 472         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 473         if (_switchweapon)
 474                 if (player.switchweapon != w_getbestweapon(player))
 475                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 476
 477         return 1;
 478 }
 479
 480 void Item_Touch (void)
 481 {
 482         entity e, head;
 483
 484         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 485         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 486         {
 487                 remove(self);
 488                 return;
 489         }
 490         if (other.classname != "player")
 491                 return;
 492         if (other.deadflag)
 493                 return;
 494         if (self.solid != SOLID_TRIGGER)
 495                 return;
 496         if (self.owner == other)
 497                 return;
 498
 499         if(!Item_GiveTo(self, other))
 500                 return;
 501
 502         other.last_pickup = time;
 503
 504         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 505
 506         if (self.classname == "droppedweapon")
 507                 remove (self);
 508         else if not(self.spawnshieldtime)
 509                 return;
 510         else
 511         {
 512                 if(self.team)
 513                 {
 514                         RandomSelection_Init();
 515                         for(head = world; (head = findfloat(head, team, self.team)); )
 516                         {
 517                                 if(head.flags & FL_ITEM)
 518                                 {
 519                                         Item_Show(head, -1);
 520                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 521                                 }
 522                         }
 523                         e = RandomSelection_chosen_ent;
 524                 }
 525                 else
 526                         e = self;
 527                 Item_ScheduleRespawn(e);
 528         }
 529 }
 530
 531 void Item_FindTeam()
 532 {
 533         entity head, e;
 534
 535         if(self.effects & EF_NODRAW)
 536         {
 537                 // marker for item team search
 538                 dprint("Initializing item team ", ftos(self.team), "\n");
 539                 RandomSelection_Init();
 540                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 541                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 542                 e = RandomSelection_chosen_ent;
 543                 e.state = 0;
 544                 Item_Show(e, 1);
 545
 546                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 547                 {
 548                         if(head != e)
 549                         {
 550                                 // make it a non-spawned item
 551                                 Item_Show(head, -1);
 552                                 head.state = 1; // state 1 = initially hidden item
 553                         }
 554                         head.effects &~= EF_NODRAW;
 555                 }
 556
 557                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 558                         Item_ScheduleInitialRespawn(e);
 559         }
 560 }
 561
 562 void Item_Reset()
 563 {
 564         Item_Show(self, !self.state);
 565         setorigin (self, self.origin);
 566         self.think = SUB_Null;
 567         self.nextthink = 0;
 568
 569         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 570                 Item_ScheduleInitialRespawn(self);
 571 }
 572
 573 // Savage: used for item garbage-collection
 574 // TODO: perhaps nice special effect?
 575 void RemoveItem(void)
 576 {
 577         remove(self);
 578 }
 579
 580 // pickup evaluation functions
 581 // these functions decide how desirable an item is to the bots
 582
 583 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 584
 585 float weapon_pickupevalfunc(entity player, entity item)
 586 {
 587         float c, i, j, position;
 588
 589         // See if I have it already
 590         if(player.weapons & item.weapons == item.weapons)
 591         {
 592                 // If I can pick it up
 593                 if(!item.spawnshieldtime)
 594                         c = 0;
 595                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 596                 {
 597                         // Skilled bots will grab more
 598                         c = bound(0, skill / 10, 1) * 0.5;
 599                 }
 600                 else
 601                         c = 0;
 602         }
 603         else
 604                 c = 1;
 605
 606         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 607         if( bot_custom_weapon && c )
 608         {
 609                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 610                 {
 611                         // Find weapon
 612                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 613                                 continue;
 614
 615                         // Find the highest position on any range
 616                         position = -1;
 617                         for(j = 0; j < WEP_LAST ; ++j){
 618                                 if(
 619                                                 bot_weapons_far[j] == i ||
 620                                                 bot_weapons_mid[j] == i ||
 621                                                 bot_weapons_close[j] == i
 622                                   )
 623                                 {
 624                                         position = j;
 625                                         break;
 626                                 }
 627                         }
 628
 629                         // Rate it
 630                         if (position >= 0 )
 631                         {
 632                                 position = WEP_LAST - position;
 633                                 // item.bot_pickupbasevalue is overwritten here
 634                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 635                         }
 636                 }
 637         }
 638
 639         return item.bot_pickupbasevalue * c;
 640 }
 641
 642 float commodity_pickupevalfunc(entity player, entity item)
 643 {
 644         float c, i, need_shells, need_nails, need_rockets, need_cells;
 645         entity wi;
 646         c = 0;
 647
 648         // Detect needed ammo
 649         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 650         {
 651                 wi = get_weaponinfo(i);
 652
 653                 if not(wi.weapons & player.weapons)
 654                         continue;
 655
 656                 if(wi.items & IT_SHELLS)
 657                         need_shells = TRUE;
 658                 else if(wi.items & IT_NAILS)
 659                         need_nails = TRUE;
 660                 else if(wi.items & IT_ROCKETS)
 661                         need_rockets = TRUE;
 662                 else if(wi.items & IT_CELLS)
 663                         need_cells = TRUE;
 664         }
 665
 666         // TODO: figure out if the player even has the weapon this ammo is for?
 667         // may not affect strategy much though...
 668         // find out how much more ammo/armor/health the player can hold
 669         if (need_shells)
 670         if (item.ammo_shells)
 671         if (player.ammo_shells < g_pickup_shells_max)
 672                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 673         if (need_nails)
 674         if (item.ammo_nails)
 675         if (player.ammo_nails < g_pickup_nails_max)
 676                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 677         if (need_rockets)
 678         if (item.ammo_rockets)
 679         if (player.ammo_rockets < g_pickup_rockets_max)
 680                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 681         if (need_cells)
 682         if (item.ammo_cells)
 683         if (player.ammo_cells < g_pickup_cells_max)
 684                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 685         if (item.armorvalue)
 686         if (player.armorvalue < item.max_armorvalue)
 687                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 688         if (item.health)
 689         if (player.health < item.max_health)
 690                 c = c + max(0, 1 - player.health / item.max_health);
 691
 692         return item.bot_pickupbasevalue * c;
 693 }
 694
 695
 696 .float is_item;
 697 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 698 {
 699         startitem_failed = FALSE;
 700
 701         self.items = itemid;
 702         self.weapons = weaponid;
 703         self.flags = FL_ITEM | itemflags;
 704
 705         // is it a dropped weapon?
 706         if (self.classname == "droppedweapon")
 707         {
 708                 self.reset = SUB_Remove;
 709                 // it's a dropped weapon
 710                 self.movetype = MOVETYPE_TOSS;
 711                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 712                 self.think = RemoveItem;
 713                 self.nextthink = time + 60;
 714                 // don't drop if in a NODROP zone (such as lava)
 715                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 716                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 717                 {
 718                         startitem_failed = TRUE;
 719                         remove(self);
 720                         return;
 721                 }
 722         }
 723         else
 724         {
 725                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 726                 {
 727                         startitem_failed = TRUE;
 728                         remove(self);
 729                         return;
 730                 }
 731
 732                 if(!have_pickup_item())
 733                 {
 734                         startitem_failed = TRUE;
 735                         remove (self);
 736                         return;
 737                 }
 738
 739                 self.reset = Item_Reset;
 740                 // it's a level item
 741                 if(self.spawnflags & 1)
 742                         self.noalign = 1;
 743                 if (self.noalign)
 744                         self.movetype = MOVETYPE_NONE;
 745                 else
 746                         self.movetype = MOVETYPE_TOSS;
 747                 // do item filtering according to game mode and other things
 748                 if (!self.noalign)
 749                 {
 750                         // first nudge it off the floor a little bit to avoid math errors
 751                         setorigin(self, self.origin + '0 0 1');
 752                         // set item size before we spawn a spawnfunc_waypoint
 753                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 754                                 setsize (self, '-16 -16 0', '16 16 48');
 755                         else
 756                                 setsize (self, '-16 -16 0', '16 16 32');
 757                         // note droptofloor returns FALSE if stuck/or would fall too far
 758                         droptofloor();
 759                         waypoint_spawnforitem(self);
 760                 }
 761
 762                 /*
 763                  * can't do it that way, as it would break maps
 764                  * TODO make a target_give like entity another way, that perhaps has
 765                  * the weapon name in a key
 766                 if(self.targetname)
 767                 {
 768                         // target_give not yet supported; maybe later
 769                         print("removed targeted ", self.classname, "\n");
 770                         startitem_failed = TRUE;
 771                         remove (self);
 772                         return;
 773                 }
 774                 */
 775
 776                 if(autocvar_spawn_debug >= 2)
 777                 {
 778                         entity otheritem;
 779                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 780                         {
 781                                 if(otheritem.is_item)
 782                                 {
 783                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 784                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 785                                         error("Mapper sucks.");
 786                                 }
 787                         }
 788                         self.is_item = TRUE;
 789                 }
 790
 791                 weaponsInMap |= weaponid;
 792
 793                 precache_model (itemmodel);
 794                 precache_sound (pickupsound);
 795
 796                 precache_sound ("misc/itemrespawncountdown.wav");
 797                 if(!g_minstagib && itemid == IT_STRENGTH)
 798                         precache_sound ("misc/strength_respawn.wav");
 799                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 800                         precache_sound ("misc/shield_respawn.wav");
 801                 else
 802                         precache_sound ("misc/itemrespawn.wav");
 803
 804                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 805                         self.target = "###item###"; // for finding the nearest item using find()
 806         }
 807
 808         self.bot_pickup = TRUE;
 809         self.bot_pickupevalfunc = pickupevalfunc;
 810         self.bot_pickupbasevalue = pickupbasevalue;
 811         self.mdl = itemmodel;
 812         self.item_pickupsound = pickupsound;
 813         // let mappers override respawntime
 814         if(!self.respawntime) // both set
 815         {
 816                 self.respawntime = defaultrespawntime;
 817                 self.respawntimejitter = defaultrespawntimejitter;
 818         }
 819         self.netname = itemname;
 820         self.touch = Item_Touch;
 821         setmodel (self, self.mdl); // precision set below
 822         self.effects |= EF_LOWPRECISION;
 823         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 824                 setsize (self, '-16 -16 0', '16 16 48');
 825         else
 826                 setsize (self, '-16 -16 0', '16 16 32');
 827         if(itemflags & FL_WEAPON)
 828                 self.modelflags |= MF_ROTATE;
 829
 830         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 831         if (itemflags & FL_WEAPON)
 832         {
 833                 // neutral team color for pickup weapons
 834                 self.colormap = 1024; // color shirt=0 pants=0 grey
 835         }
 836
 837         Item_Show(self, 1);
 838         self.state = 0;
 839         if(self.team)
 840         {
 841                 if(!self.cnt)
 842                         self.cnt = 1; // item probability weight
 843                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 844                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 845         }
 846         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 847                 Item_ScheduleInitialRespawn(self);
 848 }
 849
 850 /* replace items in minstagib
 851  * IT_STRENGTH   = invisibility
 852  * IT_NAILS      = extra lives
 853  * IT_INVINCIBLE = speed
 854  */
 855 void minstagib_items (float itemid)
 856 {
 857         float rnd;
 858         self.classname = "minstagib";
 859
 860         // replace rocket launchers and nex guns with ammo cells
 861         if (itemid == IT_CELLS)
 862         {
 863                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 864                 StartItem ("models/items/a_cells.md3",
 865                         "misc/itempickup.wav", 45, 0,
 866                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 867                 return;
 868         }
 869
 870         // randomize
 871         rnd = random() * 3;
 872         if (rnd <= 1)
 873                 itemid = IT_STRENGTH;
 874         else if (rnd <= 2)
 875                 itemid = IT_NAILS;
 876         else
 877                 itemid = IT_INVINCIBLE;
 878
 879         // replace with invis
 880         if (itemid == IT_STRENGTH)
 881         {
 882                 self.strength_finished = 30;
 883                 StartItem ("models/items/g_strength.md3",
 884                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 885                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 886         }
 887         // replace with extra lives
 888         if (itemid == IT_NAILS)
 889         {
 890                 self.max_health = 1;
 891                 StartItem ("models/items/g_h100.md3",
 892                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 893                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 894         }
 895         // replace with speed
 896         if (itemid == IT_INVINCIBLE)
 897         {
 898                 self.invincible_finished = 30;
 899                 StartItem ("models/items/g_invincible.md3",
 900                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 901                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 902         }
 903 }
 904
 905 float minst_no_auto_cells;
 906 void minst_remove_item (void) {
 907         if(minst_no_auto_cells)
 908                 remove(self);
 909 }
 910
 911 float weaponswapping;
 912 float internalteam;
 913
 914 void weapon_defaultspawnfunc(float wpn)
 915 {
 916         entity e;
 917         float t;
 918         var .float ammofield;
 919         string s;
 920         entity oldself;
 921         float i, j;
 922
 923         // set the respawntime in advance (so replaced weapons can copy it)
 924
 925         if(!self.respawntime)
 926         {
 927                 e = get_weaponinfo(wpn);
 928                 if(e.items == IT_SUPERWEAPON)
 929                 {
 930                         self.respawntime = g_pickup_respawntime_powerup;
 931                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 932                 }
 933                 else
 934                 {
 935                         self.respawntime = g_pickup_respawntime_weapon;
 936                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 937                 }
 938         }
 939
 940         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 941         {
 942                 e = get_weaponinfo(wpn);
 943                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 944                 if(s == "0")
 945                 {
 946                         remove(self);
 947                         startitem_failed = TRUE;
 948                         return;
 949                 }
 950                 t = tokenize_console(s);
 951                 if(t >= 2)
 952                 {
 953                         self.team = --internalteam;
 954                         oldself = self;
 955                         for(i = 1; i < t; ++i)
 956                         {
 957                                 s = argv(i);
 958                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 959                                 {
 960                                         e = get_weaponinfo(j);
 961                                         if(e.netname == s)
 962                                         {
 963                                                 self = spawn();
 964                                                 copyentity(oldself, self);
 965                                                 self.classname = "replacedweapon";
 966                                                 weapon_defaultspawnfunc(j);
 967                                                 break;
 968                                         }
 969                                 }
 970                                 if(j > WEP_LAST)
 971                                 {
 972                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 973                                 }
 974                         }
 975                         self = oldself;
 976                 }
 977                 if(t >= 1)
 978                 {
 979                         s = argv(0);
 980                         wpn = 0;
 981                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 982                         {
 983                                 e = get_weaponinfo(j);
 984                                 if(e.netname == s)
 985                                 {
 986                                         wpn = j;
 987                                         break;
 988                                 }
 989                         }
 990                         if(j > WEP_LAST)
 991                         {
 992                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 993                         }
 994                 }
 995                 if(wpn == 0)
 996                 {
 997                         remove(self);
 998                         startitem_failed = TRUE;
 999                         return;
1000                 }
1001         }
1002
1003         e = get_weaponinfo(wpn);
1004
1005         if(e.items && e.items != IT_SUPERWEAPON)
1006         {
1007                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1008                 {
1009                         if(e.items & j)
1010                         {
1011                                 ammofield = Item_CounterField(j);
1012                                 if(!self.ammofield)
1013                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1014                         }
1015                 }
1016         }
1017         else
1018         {
1019                 self.flags |= FL_NO_WEAPON_STAY;
1020         }
1021
1022         // weapon stay isn't supported for teamed weapons
1023         if(self.team)
1024                 self.flags |= FL_NO_WEAPON_STAY;
1025
1026         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1027         if (self.modelindex) // don't precache if self was removed
1028                 weapon_action(e.weapon, WR_PRECACHE);
1029 }
1030
1031 void spawnfunc_weapon_shotgun (void);
1032 void spawnfunc_weapon_uzi (void) {
1033         if(autocvar_sv_q3acompat_machineshotgunswap)
1034         if(self.classname != "droppedweapon")
1035         {
1036                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1037                 return;
1038         }
1039         weapon_defaultspawnfunc(WEP_UZI);
1040 }
1041
1042 void spawnfunc_weapon_shotgun (void) {
1043         if(autocvar_sv_q3acompat_machineshotgunswap)
1044         if(self.classname != "droppedweapon")
1045         {
1046                 weapon_defaultspawnfunc(WEP_UZI);
1047                 return;
1048         }
1049         weapon_defaultspawnfunc(WEP_SHOTGUN);
1050 }
1051
1052 void spawnfunc_weapon_nex (void)
1053 {
1054         if (g_minstagib)
1055         {
1056                 minstagib_items(IT_CELLS);
1057                 self.think = minst_remove_item;
1058                 self.nextthink = time;
1059                 return;
1060         }
1061         weapon_defaultspawnfunc(WEP_NEX);
1062 }
1063
1064 void spawnfunc_weapon_minstanex (void)
1065 {
1066         if (g_minstagib)
1067         {
1068                 minstagib_items(IT_CELLS);
1069                 self.think = minst_remove_item;
1070                 self.nextthink = time;
1071                 return;
1072         }
1073         weapon_defaultspawnfunc(WEP_MINSTANEX);
1074 }
1075
1076 void spawnfunc_weapon_rocketlauncher (void)
1077 {
1078         if (g_minstagib)
1079         {
1080                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1081                 self.think = minst_remove_item;
1082                 self.nextthink = time;
1083                 return;
1084         }
1085         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1086 }
1087
1088 void spawnfunc_item_rockets (void) {
1089         if(!self.ammo_rockets)
1090                 self.ammo_rockets = g_pickup_rockets;
1091         if(!self.pickup_anyway)
1092                 self.pickup_anyway = g_pickup_ammo_anyway;
1093         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1094 }
1095
1096 void spawnfunc_item_shells (void);
1097 void spawnfunc_item_bullets (void) {
1098         if(!weaponswapping)
1099         if(autocvar_sv_q3acompat_machineshotgunswap)
1100         if(self.classname != "droppedweapon")
1101         {
1102                 weaponswapping = TRUE;
1103                 spawnfunc_item_shells();
1104                 weaponswapping = FALSE;
1105                 return;
1106         }
1107
1108         if(!self.ammo_nails)
1109                 self.ammo_nails = g_pickup_nails;
1110         if(!self.pickup_anyway)
1111                 self.pickup_anyway = g_pickup_ammo_anyway;
1112         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1113 }
1114
1115 void spawnfunc_item_cells (void) {
1116         if(!self.ammo_cells)
1117                 self.ammo_cells = g_pickup_cells;
1118         if(!self.pickup_anyway)
1119                 self.pickup_anyway = g_pickup_ammo_anyway;
1120         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1121 }
1122
1123 void spawnfunc_item_shells (void) {
1124         if(!weaponswapping)
1125         if(autocvar_sv_q3acompat_machineshotgunswap)
1126         if(self.classname != "droppedweapon")
1127         {
1128                 weaponswapping = TRUE;
1129                 spawnfunc_item_bullets();
1130                 weaponswapping = FALSE;
1131                 return;
1132         }
1133
1134         if(!self.ammo_shells)
1135                 self.ammo_shells = g_pickup_shells;
1136         if(!self.pickup_anyway)
1137                 self.pickup_anyway = g_pickup_ammo_anyway;
1138         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1139 }
1140
1141 void spawnfunc_item_armor_small (void) {
1142         if(!self.armorvalue)
1143                 self.armorvalue = g_pickup_armorsmall;
1144         if(!self.max_armorvalue)
1145                 self.max_armorvalue = g_pickup_armorsmall_max;
1146         if(!self.pickup_anyway)
1147                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1148         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1149 }
1150
1151 void spawnfunc_item_armor_medium (void) {
1152         if(!self.armorvalue)
1153                 self.armorvalue = g_pickup_armormedium;
1154         if(!self.max_armorvalue)
1155                 self.max_armorvalue = g_pickup_armormedium_max;
1156         if(!self.pickup_anyway)
1157                 self.pickup_anyway = g_pickup_armormedium_anyway;
1158         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1159 }
1160
1161 void spawnfunc_item_armor_big (void) {
1162         if(!self.armorvalue)
1163                 self.armorvalue = g_pickup_armorbig;
1164         if(!self.max_armorvalue)
1165                 self.max_armorvalue = g_pickup_armorbig_max;
1166         if(!self.pickup_anyway)
1167                 self.pickup_anyway = g_pickup_armorbig_anyway;
1168         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1169 }
1170
1171 void spawnfunc_item_armor_large (void) {
1172         if(!self.armorvalue)
1173                 self.armorvalue = g_pickup_armorlarge;
1174         if(!self.max_armorvalue)
1175                 self.max_armorvalue = g_pickup_armorlarge_max;
1176         if(!self.pickup_anyway)
1177                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1178         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1179 }
1180
1181 void spawnfunc_item_health_small (void) {
1182         if(!self.max_health)
1183                 self.max_health = g_pickup_healthsmall_max;
1184         if(!self.health)
1185                 self.health = g_pickup_healthsmall;
1186         if(!self.pickup_anyway)
1187                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1188         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1189 }
1190
1191 void spawnfunc_item_health_medium (void) {
1192         if(!self.max_health)
1193                 self.max_health = g_pickup_healthmedium_max;
1194         if(!self.health)
1195                 self.health = g_pickup_healthmedium;
1196         if(!self.pickup_anyway)
1197                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1198         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1199 }
1200
1201 void spawnfunc_item_health_large (void) {
1202         if(!self.max_health)
1203                 self.max_health = g_pickup_healthlarge_max;
1204         if(!self.health)
1205                 self.health = g_pickup_healthlarge;
1206         if(!self.pickup_anyway)
1207                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1208         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1209 }
1210
1211 void spawnfunc_item_health_mega (void) {
1212         if(g_minstagib) {
1213                 minstagib_items(IT_NAILS);
1214         } else {
1215                 if(!self.max_health)
1216                         self.max_health = g_pickup_healthmega_max;
1217                 if(!self.health)
1218                         self.health = g_pickup_healthmega;
1219                 if(!self.pickup_anyway)
1220                         self.pickup_anyway = g_pickup_healthmega_anyway;
1221                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1222         }
1223 }
1224
1225 // support old misnamed entities
1226 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1227 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1228 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1229 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1230 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1231
1232 void spawnfunc_item_strength (void) {
1233         if(g_minstagib) {
1234                 minstagib_items(IT_STRENGTH);
1235         } else {
1236                 precache_sound("weapons/strength_fire.wav");
1237                 self.strength_finished = 30;
1238                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1239         }
1240 }
1241
1242 void spawnfunc_item_invincible (void) {
1243         if(g_minstagib) {
1244                 minstagib_items(IT_INVINCIBLE);
1245         } else {
1246                 self.invincible_finished = 30;
1247                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1248         }
1249 }
1250
1251 void spawnfunc_item_minst_cells (void) {
1252         if (g_minstagib)
1253         {
1254                 minst_no_auto_cells = 1;
1255                 minstagib_items(IT_CELLS);
1256         }
1257         else
1258                 remove(self);
1259 }
1260
1261 // compatibility:
1262 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1263
1264 float GiveItems(entity e, float beginarg, float endarg);
1265 void target_items_use (void)
1266 {
1267         if(activator.classname == "droppedweapon")
1268         {
1269                 EXACTTRIGGER_TOUCH;
1270                 remove(activator);
1271                 return;
1272         }
1273
1274         if(activator.classname != "player")
1275                 return;
1276         if(activator.deadflag != DEAD_NO)
1277                 return;
1278         EXACTTRIGGER_TOUCH;
1279
1280         entity e;
1281         for(e = world; (e = find(e, classname, "droppedweapon")); )
1282                 if(e.enemy == activator)
1283                         remove(e);
1284
1285         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1286                 centerprint(activator, self.message);
1287 }
1288
1289 void spawnfunc_target_items (void)
1290 {
1291         float n, i, j;
1292         entity e;
1293
1294         self.use = target_items_use;
1295         if(!self.strength_finished)
1296                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1297         if(!self.invincible_finished)
1298                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1299
1300         precache_sound("misc/itempickup.wav");
1301         precache_sound("misc/megahealth.wav");
1302         precache_sound("misc/armor25.wav");
1303         precache_sound("misc/powerup.wav");
1304         precache_sound("misc/poweroff.wav");
1305         precache_sound("weapons/weaponpickup.wav");
1306
1307         n = tokenize_console(self.netname);
1308         if(argv(0) == "give")
1309         {
1310                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1311         }
1312         else
1313         {
1314                 for(i = 0; i < n; ++i)
1315                 {
1316                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1317                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1318                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1319                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1320                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1321                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1322                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1323                         else
1324                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1325                         {
1326                                 e = get_weaponinfo(j);
1327                                 if(argv(i) == e.netname)
1328                                 {
1329                                         self.weapons |= e.weapons;
1330                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1331                                                 weapon_action(e.weapon, WR_PRECACHE);
1332                                         break;
1333                                 }
1334                         }
1335                         if(j > WEP_LAST)
1336                                 print("target_items: invalid item ", argv(i), "\n");
1337                 }
1338
1339                 string itemprefix, valueprefix;
1340                 if(self.spawnflags == 0)
1341                 {
1342                         itemprefix = "";
1343                         valueprefix = "";
1344                 }
1345                 else if(self.spawnflags == 1)
1346                 {
1347                         itemprefix = "max ";
1348                         valueprefix = "max ";
1349                 }
1350                 else if(self.spawnflags == 2)
1351                 {
1352                         itemprefix = "min ";
1353                         valueprefix = "min ";
1354                 }
1355                 else if(self.spawnflags == 4)
1356                 {
1357                         itemprefix = "minus ";
1358                         valueprefix = "max ";
1359                 }
1360                 else
1361                         error("invalid spawnflags");
1362
1363                 self.netname = "";
1364                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1365                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1366                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1367                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1368                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1369                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1370                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1371                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1372                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1373                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1374                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1375                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1376                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1377                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1378                 {
1379                         e = get_weaponinfo(j);
1380                         if(e.weapons)
1381                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1382                 }
1383         }
1384         self.netname = strzone(self.netname);
1385         //print(self.netname, "\n");
1386
1387         n = tokenize_console(self.netname);
1388         for(i = 0; i < n; ++i)
1389         {
1390                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1391                 {
1392                         e = get_weaponinfo(j);
1393                         if(argv(i) == e.netname)
1394                         {
1395                                 weapon_action(e.weapon, WR_PRECACHE);
1396                                 break;
1397                         }
1398                 }
1399         }
1400 }
1401
1402 void spawnfunc_item_fuel(void)
1403 {
1404         if(!self.ammo_fuel)
1405                 self.ammo_fuel = g_pickup_fuel;
1406         if(!self.pickup_anyway)
1407                 self.pickup_anyway = g_pickup_ammo_anyway;
1408         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1409 }
1410
1411 void spawnfunc_item_fuel_regen(void)
1412 {
1413         if(start_items & IT_FUEL_REGEN)
1414         {
1415                 spawnfunc_item_fuel();
1416                 return;
1417         }
1418         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1419 }
1420
1421 void spawnfunc_item_jetpack(void)
1422 {
1423         if(g_grappling_hook)
1424                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1425         if(!self.ammo_fuel)
1426                 self.ammo_fuel = g_pickup_fuel_jetpack;
1427         if(start_items & IT_JETPACK)
1428         {
1429                 spawnfunc_item_fuel();
1430                 return;
1431         }
1432         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1433 }
1434
1435
1436 #define OP_SET 0
1437 #define OP_MIN 1
1438 #define OP_MAX 2
1439 #define OP_PLUS 3
1440 #define OP_MINUS 4
1441
1442 float GiveBit(entity e, .float fld, float bit, float op, float val)
1443 {
1444         float v0, v1;
1445         v0 = (e.fld & bit);
1446         switch(op)
1447         {
1448                 case OP_SET:
1449                         if(val > 0)
1450                                 e.fld |= bit;
1451                         else
1452                                 e.fld &~= bit;
1453                         break;
1454                 case OP_MIN:
1455                 case OP_PLUS:
1456                         if(val > 0)
1457                                 e.fld |= bit;
1458                         break;
1459                 case OP_MAX:
1460                         if(val <= 0)
1461                                 e.fld &~= bit;
1462                         break;
1463                 case OP_MINUS:
1464                         if(val > 0)
1465                                 e.fld &~= bit;
1466                         break;
1467         }
1468         v1 = (e.fld & bit);
1469         return (v0 != v1);
1470 }
1471
1472 float GiveValue(entity e, .float fld, float op, float val)
1473 {
1474         float v0, v1;
1475         v0 = e.fld;
1476         switch(op)
1477         {
1478                 case OP_SET:
1479                         e.fld = val;
1480                         break;
1481                 case OP_MIN:
1482                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1483                         break;
1484                 case OP_MAX:
1485                         e.fld = min(e.fld, val);
1486                         break;
1487                 case OP_PLUS:
1488                         e.fld += val;
1489                         break;
1490                 case OP_MINUS:
1491                         e.fld -= val;
1492                         break;
1493         }
1494         v1 = e.fld;
1495         return (v0 != v1);
1496 }
1497
1498 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1499 {
1500         if(v1 == v0)
1501                 return;
1502         if(v1 <= v0 - t)
1503         {
1504                 if(snd_decr != "")
1505                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1506         }
1507         else if(v0 >= v0 + t)
1508         {
1509                 if(snd_incr != "")
1510                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1511         }
1512 }
1513
1514 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1515 {
1516         if(v0 < v1)
1517                 e.rotfield = max(e.rotfield, time + rottime);
1518         else if(v0 > v1)
1519                 e.regenfield = max(e.regenfield, time + regentime);
1520 }
1521
1522 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1523 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1524 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1525 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1526
1527 float GiveItems(entity e, float beginarg, float endarg)
1528 {
1529         float got, i, j, val, op;
1530         float _switchweapon;
1531         entity wi;
1532         string cmd;
1533
1534         val = 999;
1535         op = OP_SET;
1536
1537         got = 0;
1538
1539         _switchweapon = FALSE;
1540         if (e.autoswitch)
1541                 if (e.switchweapon == w_getbestweapon(e))
1542                         _switchweapon = TRUE;
1543
1544         e.strength_finished = max(0, e.strength_finished - time);
1545         e.invincible_finished = max(0, e.invincible_finished - time);
1546
1547         PREGIVE(e, items);
1548         PREGIVE(e, weapons);
1549         PREGIVE(e, strength_finished);
1550         PREGIVE(e, invincible_finished);
1551         PREGIVE(e, ammo_nails);
1552         PREGIVE(e, ammo_cells);
1553         PREGIVE(e, ammo_shells);
1554         PREGIVE(e, ammo_rockets);
1555         PREGIVE(e, ammo_fuel);
1556         PREGIVE(e, armorvalue);
1557         PREGIVE(e, health);
1558
1559         for(i = beginarg; i < endarg; ++i)
1560         {
1561                 cmd = argv(i);
1562
1563                 if(cmd == "0" || stof(cmd))
1564                 {
1565                         val = stof(cmd);
1566                         continue;
1567                 }
1568                 switch(cmd)
1569                 {
1570                         case "no":
1571                                 op = OP_MAX;
1572                                 val = 0;
1573                                 continue;
1574                         case "max":
1575                                 op = OP_MAX;
1576                                 continue;
1577                         case "min":
1578                                 op = OP_MIN;
1579                                 continue;
1580                         case "plus":
1581                                 op = OP_PLUS;
1582                                 continue;
1583                         case "minus":
1584                                 op = OP_MINUS;
1585                                 continue;
1586                         case "ALL":
1587                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1588                                 got += GiveValue(e, strength_finished, op, time);
1589                                 got += GiveValue(e, invincible_finished, op, time);
1590                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1591                         case "all":
1592                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1593                                 got += GiveValue(e, health, op, val);
1594                                 got += GiveValue(e, armorvalue, op, val);
1595                         case "allweapons":
1596                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1597                                 {
1598                                         wi = get_weaponinfo(j);
1599                                         if(wi.weapons)
1600                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1601                                 }
1602                         case "allammo":
1603                                 got += GiveValue(e, ammo_cells, op, val);
1604                                 got += GiveValue(e, ammo_shells, op, val);
1605                                 got += GiveValue(e, ammo_nails, op, val);
1606                                 got += GiveValue(e, ammo_rockets, op, val);
1607                                 got += GiveValue(e, ammo_fuel, op, val);
1608                                 break;
1609                         case "unlimited_ammo":
1610                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1611                                 break;
1612                         case "unlimited_weapon_ammo":
1613                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1614                                 break;
1615                         case "unlimited_superweapons":
1616                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1617                                 break;
1618                         case "jetpack":
1619                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1620                                 break;
1621                         case "fuel_regen":
1622                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1623                                 break;
1624                         case "strength":
1625                                 got += GiveValue(e, strength_finished, op, val);
1626                                 break;
1627                         case "invincible":
1628                                 got += GiveValue(e, invincible_finished, op, val);
1629                                 break;
1630                         case "cells":
1631                                 got += GiveValue(e, ammo_cells, op, val);
1632                                 break;
1633                         case "shells":
1634                                 got += GiveValue(e, ammo_shells, op, val);
1635                                 break;
1636                         case "nails":
1637                         case "bullets":
1638                                 got += GiveValue(e, ammo_nails, op, val);
1639                                 break;
1640                         case "rockets":
1641                                 got += GiveValue(e, ammo_rockets, op, val);
1642                                 break;
1643                         case "health":
1644                                 got += GiveValue(e, health, op, val);
1645                                 break;
1646                         case "armor":
1647                                 got += GiveValue(e, armorvalue, op, val);
1648                                 break;
1649                         case "fuel":
1650                                 got += GiveValue(e, ammo_fuel, op, val);
1651                                 break;
1652                         default:
1653                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1654                                 {
1655                                         wi = get_weaponinfo(j);
1656                                         if(cmd == wi.netname)
1657                                         {
1658                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1659                                                 break;
1660                                         }
1661                                 }
1662                                 if(j > WEP_LAST)
1663                                         print("give: invalid item ", cmd, "\n");
1664                                 break;
1665                 }
1666                 val = 999;
1667                 op = OP_SET;
1668         }
1669
1670         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1671         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1672         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1673         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1674         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1675         {
1676                 wi = get_weaponinfo(j);
1677                 if(wi.weapons)
1678                 {
1679                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1680                         if not(save_weapons & wi.weapons)
1681                                 if(e.weapons & wi.weapons)
1682                                         weapon_action(wi.weapon, WR_PRECACHE);
1683                 }
1684         }
1685         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1686         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1687         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1688         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1689         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1690         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1691         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1692         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1693         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1694
1695         if (g_minstagib)
1696         {
1697                 e.health = bound(0, e.health, 100);
1698                 e.armorvalue = bound(0, e.armorvalue, 999);
1699         }
1700
1701         if(e.strength_finished <= 0)
1702                 e.strength_finished = 0;
1703         else
1704                 e.strength_finished += time;
1705         if(e.invincible_finished <= 0)
1706                 e.invincible_finished = 0;
1707         else
1708                 e.invincible_finished += time;
1709
1710         if not(e.weapons & W_WeaponBit(e.switchweapon))
1711                 _switchweapon = TRUE;
1712         if(_switchweapon)
1713                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1714
1715         return got;
1716 }