qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(cvar_string("g_ghost_items_color"));
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent green and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent green and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 115                 self.glowmod = self.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 127                 self.glowmod = self.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (cvar("g_nodepthtestitems"))
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (cvar("g_fullbrightitems"))
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 152         else
 153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 202                                 if(self.waypointsprite_attached)
 203                                 {
 204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 207                                 }
 208                         }
 209                 }
 210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 211                 if(self.waypointsprite_attached)
 212                 {
 213                         WaypointSprite_Ping(self.waypointsprite_attached);
 214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 215                 }
 216         }
 217 }
 218
 219 void Item_ScheduleRespawnIn(entity e, float t)
 220 {
 221         if(e.flags & FL_POWERUP)
 222         {
 223                 e.think = Item_RespawnCountdown;
 224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 225                 e.count = 0;
 226         }
 227         else
 228         {
 229                 e.think = Item_Respawn;
 230                 e.nextthink = time + t;
 231         }
 232 }
 233
 234 void Item_ScheduleRespawn(entity e)
 235 {
 236         Item_Show(e, 0);
 237         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 238 }
 239
 240 void Item_ScheduleInitialRespawn(entity e)
 241 {
 242         Item_Show(e, 0);
 243         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 244 }
 245
 246 float Item_GiveTo(entity item, entity player)
 247 {
 248         float _switchweapon;
 249         float pickedup;
 250         float it;
 251         float i;
 252         entity e;
 253
 254         // if nothing happens to player, just return without taking the item
 255         pickedup = FALSE;
 256         _switchweapon = FALSE;
 257
 258         if (g_minstagib)
 259         {
 260                 if(item.spawnshieldtime)
 261                 {
 262                         if (item.ammo_fuel)
 263                         if (player.ammo_fuel < g_pickup_fuel_max)
 264                         {
 265                                 pickedup = TRUE;
 266                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 267                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 268                         }
 269                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 270                         {
 271                                 pickedup = TRUE;
 272                                 player.items |= it;
 273                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 274                         }
 275
 276                         _switchweapon = TRUE;
 277                         if (item.ammo_cells)
 278                         {
 279                                 pickedup = TRUE;
 280                                 // play some cool sounds ;)
 281                                 centerprint(player, "\n");
 282                                 if (clienttype(player) == CLIENTTYPE_REAL)
 283                                 {
 284                                         if(player.health <= 5)
 285                                                 AnnounceTo(player, "lastsecond");
 286                                         else if(player.health < 50)
 287                                                 AnnounceTo(player, "narrowly");
 288                                 }
 289                                 // sound not available
 290                                 // else if(item.items == IT_CELLS)
 291                                 //      AnnounceTo(player, "ammo");
 292
 293                                 if (item.weapons & WEPBIT_MINSTANEX)
 294                                         W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 295                                 if (item.ammo_cells)
 296                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 297                                 player.health = 100;
 298                         }
 299
 300                         // extralife powerup
 301                         if (item.max_health)
 302                         {
 303                                 pickedup = TRUE;
 304                                 // sound not available
 305                                 // AnnounceTo(player, "_lives");
 306                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 307                                 sprint(player, "^3You picked up some extra lives\n");
 308                         }
 309
 310                         // invis powerup
 311                         if (item.strength_finished)
 312                         {
 313                                 pickedup = TRUE;
 314                                 // sound not available
 315                                 // AnnounceTo(player, "invisible");
 316                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 317                         }
 318
 319                         // speed powerup
 320                         if (item.invincible_finished)
 321                         {
 322                                 pickedup = TRUE;
 323                                 // sound not available
 324                                 // AnnounceTo(player, "speed");
 325                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 326                         }
 327
 328                         if (item.ammo_fuel)
 329                         if (player.ammo_fuel < g_pickup_fuel_max)
 330                         {
 331                                 pickedup = TRUE;
 332                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 333                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 334                         }
 335                 }
 336         }
 337         else
 338         {
 339                 if (g_weapon_stay == 1)
 340                 if not(item.flags & FL_NO_WEAPON_STAY)
 341                 if (item.flags & FL_WEAPON)
 342                 {
 343                         if(item.classname == "droppedweapon")
 344                         {
 345                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 346                                         goto skip;
 347                         }
 348                         else
 349                         {
 350                                 if (player.weapons & item.weapons)
 351                                         goto skip;
 352                         }
 353                 }
 354
 355                 // in case the player has autoswitch enabled do the following:
 356                 // if the player is using their best weapon before items are given, they
 357                 // probably want to switch to an even better weapon after items are given
 358                 if (player.autoswitch)
 359                 if (player.switchweapon == w_getbestweapon(player))
 360                         _switchweapon = TRUE;
 361
 362                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 363                         _switchweapon = TRUE;
 364
 365                 if(item.spawnshieldtime)
 366                 {
 367                         if (item.ammo_shells)
 368                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 369                         {
 370                                 pickedup = TRUE;
 371                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 372                         }
 373                         if (item.ammo_nails)
 374                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 375                         {
 376                                 pickedup = TRUE;
 377                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 378                         }
 379                         if (item.ammo_rockets)
 380                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 381                         {
 382                                 pickedup = TRUE;
 383                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 384                         }
 385                         if (item.ammo_cells)
 386                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 387                         {
 388                                 pickedup = TRUE;
 389                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 390                         }
 391                         if (item.ammo_fuel)
 392                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 393                         {
 394                                 pickedup = TRUE;
 395                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 396                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 397                         }
 398                 }
 399
 400                 if (item.flags & FL_WEAPON)
 401                 if ((it = item.weapons - (item.weapons & player.weapons)) || g_pickup_weapons_anyway)
 402                 {
 403                         pickedup = TRUE;
 404                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 405                         {
 406                                 e = get_weaponinfo(i);
 407                                 if(it & e.weapons)
 408                                         W_GiveWeapon (player, e.weapon, item.netname);
 409                         }
 410                 }
 411
 412                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 413                 {
 414                         pickedup = TRUE;
 415                         player.items |= it;
 416                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 417                 }
 418
 419                 if(item.spawnshieldtime)
 420                 {
 421                         if (item.strength_finished)
 422                         {
 423                                 pickedup = TRUE;
 424                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 425                         }
 426                         if (item.invincible_finished)
 427                         {
 428                                 pickedup = TRUE;
 429                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 430                         }
 431
 432                         if (item.health)
 433                         if ((player.health < item.max_health) || item.pickup_anyway)
 434                         {
 435                                 pickedup = TRUE;
 436                                 player.health = min(player.health + item.health, item.max_health);
 437                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 438                         }
 439                         if (item.armorvalue)
 440                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 441                         {
 442                                 pickedup = TRUE;
 443                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 444                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 445                         }
 446                 }
 447         }
 448
 449 :skip
 450         // always eat teamed entities
 451         if(item.team)
 452                 pickedup = TRUE;
 453
 454         if (!pickedup)
 455                 return 0;
 456
 457         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 458         if (_switchweapon)
 459                 if (player.switchweapon != w_getbestweapon(player))
 460                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 461
 462         return 1;
 463 }
 464
 465 void Item_Touch (void)
 466 {
 467         entity e, head;
 468
 469         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 470         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 471         {
 472                 remove(self);
 473                 return;
 474         }
 475         if (other.classname != "player")
 476                 return;
 477         if (other.deadflag)
 478                 return;
 479         if (self.solid != SOLID_TRIGGER)
 480                 return;
 481         if (self.owner == other)
 482                 return;
 483
 484         if(!Item_GiveTo(self, other))
 485                 return;
 486
 487         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 488
 489         if (self.classname == "droppedweapon")
 490                 remove (self);
 491         else if not(self.spawnshieldtime)
 492                 return;
 493         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 494                 return;
 495         else
 496         {
 497                 if(self.team)
 498                 {
 499                         RandomSelection_Init();
 500                         for(head = world; (head = findfloat(head, team, self.team)); )
 501                         {
 502                                 if(head.flags & FL_ITEM)
 503                                 {
 504                                         Item_Show(head, -1);
 505                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 506                                 }
 507                         }
 508                         e = RandomSelection_chosen_ent;
 509                 }
 510                 else
 511                         e = self;
 512                 Item_ScheduleRespawn(e);
 513         }
 514 }
 515
 516 void Item_FindTeam()
 517 {
 518         entity head, e;
 519
 520         if(self.effects & EF_NODRAW)
 521         {
 522                 // marker for item team search
 523                 dprint("Initializing item team ", ftos(self.team), "\n");
 524                 RandomSelection_Init();
 525                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 526                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 527                 e = RandomSelection_chosen_ent;
 528                 e.state = 0;
 529                 Item_Show(e, 1);
 530
 531                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 532                 {
 533                         if(head != e)
 534                         {
 535                                 // make it a non-spawned item
 536                                 Item_Show(head, -1);
 537                                 head.state = 1; // state 1 = initially hidden item
 538                         }
 539                         head.effects &~= EF_NODRAW;
 540                 }
 541
 542                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 543                         Item_ScheduleInitialRespawn(e);
 544         }
 545 }
 546
 547 void Item_Reset()
 548 {
 549         Item_Show(self, !self.state);
 550         setorigin (self, self.origin);
 551         self.think = SUB_Null;
 552         self.nextthink = 0;
 553
 554         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 555                 Item_ScheduleInitialRespawn(self);
 556 }
 557
 558 // Savage: used for item garbage-collection
 559 // TODO: perhaps nice special effect?
 560 void RemoveItem(void)
 561 {
 562         remove(self);
 563 }
 564
 565 // pickup evaluation functions
 566 // these functions decide how desirable an item is to the bots
 567
 568 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 569
 570 float weapon_pickupevalfunc(entity player, entity item)
 571 {
 572         float c, i, j, position;
 573
 574         // See if I have it already
 575         if(player.weapons & item.weapons == item.weapons)
 576         {
 577                 // If I can pick it up
 578                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 579                         c = 0;
 580                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 581                 {
 582                         // Skilled bots will grab more
 583                         c = bound(0, skill / 10, 1) * 0.5;
 584                 }
 585                 else
 586                         c = 0;
 587         }
 588         else
 589                 c = 1;
 590
 591         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 592         if( bot_custom_weapon && c )
 593         {
 594                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 595                 {
 596                         // Find weapon
 597                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 598                                 continue;
 599
 600                         // Find the highest position on any range
 601                         position = -1;
 602                         for(j = 0; j < WEP_LAST ; ++j){
 603                                 if(
 604                                                 bot_weapons_far[j] == i ||
 605                                                 bot_weapons_mid[j] == i ||
 606                                                 bot_weapons_close[j] == i
 607                                   )
 608                                 {
 609                                         position = j;
 610                                         break;
 611                                 }
 612                         }
 613
 614                         // Rate it
 615                         if (position >= 0 )
 616                         {
 617                                 position = WEP_LAST - position;
 618                                 // item.bot_pickupbasevalue is overwritten here
 619                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 620                         }
 621                 }
 622         }
 623
 624         return item.bot_pickupbasevalue * c;
 625 };
 626
 627 float commodity_pickupevalfunc(entity player, entity item)
 628 {
 629         float c, i, need_shells, need_nails, need_rockets, need_cells;
 630         entity wi;
 631         c = 0;
 632
 633         // Detect needed ammo
 634         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 635         {
 636                 wi = get_weaponinfo(i);
 637
 638                 if not(wi.weapons & player.weapons)
 639                         continue;
 640
 641                 if(wi.items & IT_SHELLS)
 642                         need_shells = TRUE;
 643                 else if(wi.items & IT_NAILS)
 644                         need_nails = TRUE;
 645                 else if(wi.items & IT_ROCKETS)
 646                         need_rockets = TRUE;
 647                 else if(wi.items & IT_CELLS)
 648                         need_cells = TRUE;
 649         }
 650
 651         // TODO: figure out if the player even has the weapon this ammo is for?
 652         // may not affect strategy much though...
 653         // find out how much more ammo/armor/health the player can hold
 654         if (need_shells)
 655         if (item.ammo_shells)
 656         if (player.ammo_shells < g_pickup_shells_max)
 657                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 658         if (need_nails)
 659         if (item.ammo_nails)
 660         if (player.ammo_nails < g_pickup_nails_max)
 661                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 662         if (need_rockets)
 663         if (item.ammo_rockets)
 664         if (player.ammo_rockets < g_pickup_rockets_max)
 665                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 666         if (need_cells)
 667         if (item.ammo_cells)
 668         if (player.ammo_cells < g_pickup_cells_max)
 669                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 670         if (item.armorvalue)
 671         if (player.armorvalue < item.max_armorvalue)
 672                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 673         if (item.health)
 674         if (player.health < item.max_health)
 675                 c = c + max(0, 1 - player.health / item.max_health);
 676
 677         return item.bot_pickupbasevalue * c;
 678 };
 679
 680
 681 .float is_item;
 682 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 683 {
 684         startitem_failed = FALSE;
 685
 686         self.items = itemid;
 687         self.weapons = weaponid;
 688
 689         // is it a dropped weapon?
 690         if (self.classname == "droppedweapon")
 691         {
 692                 self.reset = SUB_Remove;
 693                 // it's a dropped weapon
 694                 self.movetype = MOVETYPE_TOSS;
 695                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 696                 self.think = RemoveItem;
 697                 self.nextthink = time + 60;
 698                 // don't drop if in a NODROP zone (such as lava)
 699                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 700                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 701                 {
 702                         startitem_failed = TRUE;
 703                         remove(self);
 704                         return;
 705                 }
 706         }
 707         else
 708         {
 709                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 710                 {
 711                         startitem_failed = TRUE;
 712                         remove(self);
 713                         return;
 714                 }
 715
 716                 itemid = self.items;
 717                 weaponid = self.weapons;
 718
 719                 self.reset = Item_Reset;
 720                 // it's a level item
 721                 if(self.spawnflags & 1)
 722                         self.noalign = 1;
 723                 if (self.noalign)
 724                         self.movetype = MOVETYPE_NONE;
 725                 else
 726                         self.movetype = MOVETYPE_TOSS;
 727                 // do item filtering according to game mode and other things
 728                 if (!self.noalign)
 729                 {
 730                         // first nudge it off the floor a little bit to avoid math errors
 731                         setorigin(self, self.origin + '0 0 1');
 732                         // set item size before we spawn a spawnfunc_waypoint
 733                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 734                                 setsize (self, '-16 -16 0', '16 16 48');
 735                         else
 736                                 setsize (self, '-16 -16 0', '16 16 32');
 737                         // note droptofloor returns FALSE if stuck/or would fall too far
 738                         droptofloor();
 739                         waypoint_spawnforitem(self);
 740                 }
 741
 742                 if(teams_matter)
 743                 {
 744                         if(self.notteam)
 745                         {
 746                                 print("removed non-teamplay ", self.classname, "\n");
 747                                 startitem_failed = TRUE;
 748                                 remove (self);
 749                                 return;
 750                         }
 751                 }
 752                 else
 753                 {
 754                         if(self.notfree)
 755                         {
 756                                 print("removed non-FFA ", self.classname, "\n");
 757                                 startitem_failed = TRUE;
 758                                 remove (self);
 759                                 return;
 760                         }
 761                 }
 762
 763                 if(self.notq3a)
 764                 {
 765                         // We aren't TA or something like that, so we keep the Q3A entities
 766                         print("removed non-Q3A ", self.classname, "\n");
 767                         startitem_failed = TRUE;
 768                         remove (self);
 769                         return;
 770                 }
 771
 772                 /*
 773                  * can't do it that way, as it would break maps
 774                  * TODO make a target_give like entity another way, that perhaps has
 775                  * the weapon name in a key
 776                 if(self.targetname)
 777                 {
 778                         // target_give not yet supported; maybe later
 779                         print("removed targeted ", self.classname, "\n");
 780                         startitem_failed = TRUE;
 781                         remove (self);
 782                         return;
 783                 }
 784                 */
 785
 786                 if(cvar("spawn_debug") >= 2)
 787                 {
 788                         entity otheritem;
 789                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 790                         {
 791                                 if(otheritem.is_item)
 792                                 {
 793                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 794                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 795                                         error("Mapper sucks.");
 796                                 }
 797                         }
 798                         self.is_item = TRUE;
 799                 }
 800
 801                 weaponsInMap |= weaponid;
 802
 803                 if(g_lms || g_ca)
 804                 {
 805                         startitem_failed = TRUE;
 806                         remove(self);
 807                         return;
 808                 }
 809                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 810                 {
 811                         startitem_failed = TRUE;
 812                         remove(self);
 813                         return;
 814                 }
 815                 else if (g_minstagib)
 816                 {
 817                         // don't remove dropped items and powerups
 818                         if (self.classname != "minstagib")
 819                         {
 820                                 startitem_failed = TRUE;
 821                                 remove (self);
 822                                 return;
 823                         }
 824                 }
 825                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 826                 {
 827                         startitem_failed = TRUE;
 828                         remove (self);
 829                         return;
 830                 }
 831
 832                 precache_model (itemmodel);
 833                 precache_sound (pickupsound);
 834                 precache_sound ("misc/itemrespawn.wav");
 835                 precache_sound ("misc/itemrespawncountdown.wav");
 836
 837                 if(itemid == IT_STRENGTH)
 838                         precache_sound ("misc/strength_respawn.wav");
 839                 if(itemid == IT_INVINCIBLE)
 840                         precache_sound ("misc/shield_respawn.wav");
 841
 842                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 843                         self.target = "###item###"; // for finding the nearest item using find()
 844         }
 845
 846         self.bot_pickup = TRUE;
 847         self.bot_pickupevalfunc = pickupevalfunc;
 848         self.bot_pickupbasevalue = pickupbasevalue;
 849         self.mdl = itemmodel;
 850         self.item_pickupsound = pickupsound;
 851         // let mappers override respawntime
 852         if(!self.respawntime) // both set
 853         {
 854                 self.respawntime = defaultrespawntime;
 855                 self.respawntimejitter = defaultrespawntimejitter;
 856         }
 857         self.netname = itemname;
 858         self.flags = FL_ITEM | itemflags;
 859         self.touch = Item_Touch;
 860         setmodel (self, self.mdl); // precision set below
 861         self.effects |= EF_LOWPRECISION;
 862         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 863                 setsize (self, '-16 -16 0', '16 16 48');
 864         else
 865                 setsize (self, '-16 -16 0', '16 16 32');
 866         if(itemflags & FL_WEAPON)
 867                 self.modelflags |= MF_ROTATE;
 868
 869         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 870         if (itemflags & FL_WEAPON)
 871         {
 872                 // neutral team color for pickup weapons
 873                 self.colormap = 1024; // color shirt=0 pants=0 grey
 874         }
 875
 876         Item_Show(self, 1);
 877         self.state = 0;
 878         if(self.team)
 879         {
 880                 if(!self.cnt)
 881                         self.cnt = 1; // item probability weight
 882                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 883                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 884         }
 885         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 886                 Item_ScheduleInitialRespawn(self);
 887 }
 888
 889 /* replace items in minstagib
 890  * IT_STRENGTH   = invisibility
 891  * IT_NAILS      = extra lives
 892  * IT_INVINCIBLE = speed
 893  */
 894 void minstagib_items (float itemid)
 895 {
 896         // we don't want to replace dropped weapons ;)
 897         if (self.classname == "droppedweapon")
 898         {
 899                 self.ammo_cells = 25;
 900                 StartItem ("models/weapons/g_nex.md3",
 901                         "weapons/weaponpickup.wav", 15, 0,
 902                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 903                 return;
 904         }
 905
 906         local float rnd;
 907         self.classname = "minstagib";
 908
 909         // replace rocket launchers and nex guns with ammo cells
 910         if (itemid == IT_CELLS)
 911         {
 912                 self.ammo_cells = 1;
 913                 StartItem ("models/items/a_cells.md3",
 914                         "misc/itempickup.wav", 45, 0,
 915                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 916                 return;
 917         }
 918
 919         // randomize
 920         rnd = random() * 3;
 921         if (rnd <= 1)
 922                 itemid = IT_STRENGTH;
 923         else if (rnd <= 2)
 924                 itemid = IT_NAILS;
 925         else
 926                 itemid = IT_INVINCIBLE;
 927
 928         // replace with invis
 929         if (itemid == IT_STRENGTH)
 930         {
 931                 self.strength_finished = 30;
 932                 StartItem ("models/items/g_strength.md3",
 933                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 934                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 935         }
 936         // replace with extra lives
 937         if (itemid == IT_NAILS)
 938         {
 939                 self.max_health = 1;
 940                 StartItem ("models/items/g_h100.md3",
 941                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 942                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 943
 944         }
 945         // replace with speed
 946         if (itemid == IT_INVINCIBLE)
 947         {
 948                 self.invincible_finished = 30;
 949                 StartItem ("models/items/g_invincible.md3",
 950                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 951                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 952         }
 953
 954 }
 955
 956 float minst_no_auto_cells;
 957 void minst_remove_item (void) {
 958         if(minst_no_auto_cells)
 959                 remove(self);
 960 }
 961
 962 float weaponswapping;
 963 float internalteam;
 964
 965 void weapon_defaultspawnfunc(float wpn)
 966 {
 967         entity e;
 968         float t;
 969         var .float ammofield;
 970         string s;
 971         entity oldself;
 972         float i, j;
 973
 974         // set the respawntime in advance (so replaced weapons can copy it)
 975
 976         if(!self.respawntime)
 977         {
 978                 e = get_weaponinfo(wpn);
 979                 if(e.items == IT_SUPERWEAPON)
 980                 {
 981                         self.respawntime = g_pickup_respawntime_powerup;
 982                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 983                 }
 984                 else
 985                 {
 986                         self.respawntime = g_pickup_respawntime_weapon;
 987                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 988                 }
 989         }
 990
 991         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 992         {
 993                 e = get_weaponinfo(wpn);
 994                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 995                 if(s == "0")
 996                 {
 997                         remove(self);
 998                         startitem_failed = TRUE;
 999                         return;
1000                 }
1001                 t = tokenize_console(s);
1002                 if(t >= 2)
1003                 {
1004                         self.team = --internalteam;
1005                         oldself = self;
1006                         for(i = 1; i < t; ++i)
1007                         {
1008                                 s = argv(i);
1009                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1010                                 {
1011                                         e = get_weaponinfo(j);
1012                                         if(e.netname == s)
1013                                         {
1014                                                 self = spawn();
1015                                                 copyentity(oldself, self);
1016                                                 self.classname = "replacedweapon";
1017                                                 weapon_defaultspawnfunc(j);
1018                                                 break;
1019                                         }
1020                                 }
1021                                 if(j > WEP_LAST)
1022                                 {
1023                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1024                                 }
1025                         }
1026                         self = oldself;
1027                 }
1028                 if(t >= 1)
1029                 {
1030                         s = argv(0);
1031                         wpn = 0;
1032                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1033                         {
1034                                 e = get_weaponinfo(j);
1035                                 if(e.netname == s)
1036                                 {
1037                                         wpn = j;
1038                                         break;
1039                                 }
1040                         }
1041                         if(j > WEP_LAST)
1042                         {
1043                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1044                         }
1045                 }
1046                 if(wpn == 0)
1047                 {
1048                         remove(self);
1049                         startitem_failed = TRUE;
1050                         return;
1051                 }
1052         }
1053
1054         e = get_weaponinfo(wpn);
1055
1056         if(e.items && e.items != IT_SUPERWEAPON)
1057         {
1058                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1059                 {
1060                         if(e.items & j)
1061                         {
1062                                 ammofield = Item_CounterField(j);
1063                                 if(!self.ammofield)
1064                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1065                         }
1066                 }
1067         }
1068         else
1069         {
1070                 self.flags |= FL_NO_WEAPON_STAY;
1071         }
1072
1073         // weapon stay isn't supported for teamed weapons
1074         if(self.team)
1075                 self.flags |= FL_NO_WEAPON_STAY;
1076
1077         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1078         {
1079                 self.ammo_shells = 0;
1080                 self.ammo_nails = 0;
1081                 self.ammo_cells = 0;
1082                 self.ammo_rockets = 0;
1083                 // weapon stay 2: don't use ammo on weapon pickups; instead
1084                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1085         }
1086
1087         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1088         if (self.modelindex) // don't precache if self was removed
1089                 weapon_action(e.weapon, WR_PRECACHE);
1090 }
1091
1092 void spawnfunc_weapon_shotgun (void);
1093 void spawnfunc_weapon_uzi (void) {
1094         if(q3acompat_machineshotgunswap)
1095         if(self.classname != "droppedweapon")
1096         {
1097                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1098                 return;
1099         }
1100         weapon_defaultspawnfunc(WEP_UZI);
1101 }
1102
1103 void spawnfunc_weapon_shotgun (void) {
1104         if(q3acompat_machineshotgunswap)
1105         if(self.classname != "droppedweapon")
1106         {
1107                 weapon_defaultspawnfunc(WEP_UZI);
1108                 return;
1109         }
1110         weapon_defaultspawnfunc(WEP_SHOTGUN);
1111 }
1112
1113 void spawnfunc_weapon_nex (void)
1114 {
1115         if (g_minstagib)
1116         {
1117                 minstagib_items(IT_CELLS);
1118                 self.think = minst_remove_item;
1119                 self.nextthink = time;
1120                 return;
1121         }
1122         weapon_defaultspawnfunc(WEP_NEX);
1123 }
1124
1125 void spawnfunc_weapon_minstanex (void)
1126 {
1127         if (g_minstagib)
1128         {
1129                 minstagib_items(IT_CELLS);
1130                 self.think = minst_remove_item;
1131                 self.nextthink = time;
1132                 return;
1133         }
1134         weapon_defaultspawnfunc(WEP_MINSTANEX);
1135 }
1136
1137 void spawnfunc_weapon_rocketlauncher (void)
1138 {
1139         if (g_minstagib)
1140         {
1141                 minstagib_items(IT_CELLS);
1142                 self.think = minst_remove_item;
1143                 self.nextthink = time;
1144                 return;
1145         }
1146         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1147 }
1148
1149 void spawnfunc_item_rockets (void) {
1150         if(!self.ammo_rockets)
1151                 self.ammo_rockets = g_pickup_rockets;
1152         if(!self.pickup_anyway)
1153                 self.pickup_anyway = g_pickup_ammo_anyway;
1154         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1155 }
1156
1157 void spawnfunc_item_shells (void);
1158 void spawnfunc_item_bullets (void) {
1159         if(!weaponswapping)
1160         if(q3acompat_machineshotgunswap)
1161         if(self.classname != "droppedweapon")
1162         {
1163                 weaponswapping = TRUE;
1164                 spawnfunc_item_shells();
1165                 weaponswapping = FALSE;
1166                 return;
1167         }
1168
1169         if(!self.ammo_nails)
1170                 self.ammo_nails = g_pickup_nails;
1171         if(!self.pickup_anyway)
1172                 self.pickup_anyway = g_pickup_ammo_anyway;
1173         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1174 }
1175
1176 void spawnfunc_item_cells (void) {
1177         if(!self.ammo_cells)
1178                 self.ammo_cells = g_pickup_cells;
1179         if(!self.pickup_anyway)
1180                 self.pickup_anyway = g_pickup_ammo_anyway;
1181         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1182 }
1183
1184 void spawnfunc_item_shells (void) {
1185         if(!weaponswapping)
1186         if(q3acompat_machineshotgunswap)
1187         if(self.classname != "droppedweapon")
1188         {
1189                 weaponswapping = TRUE;
1190                 spawnfunc_item_bullets();
1191                 weaponswapping = FALSE;
1192                 return;
1193         }
1194
1195         if(!self.ammo_shells)
1196                 self.ammo_shells = g_pickup_shells;
1197         if(!self.pickup_anyway)
1198                 self.pickup_anyway = g_pickup_ammo_anyway;
1199         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1200 }
1201
1202 void spawnfunc_item_armor_small (void) {
1203         if(!self.armorvalue)
1204                 self.armorvalue = g_pickup_armorsmall;
1205         if(!self.max_armorvalue)
1206                 self.max_armorvalue = g_pickup_armorsmall_max;
1207         if(!self.pickup_anyway)
1208                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1209         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1210 }
1211
1212 void spawnfunc_item_armor_medium (void) {
1213         if(!self.armorvalue)
1214                 self.armorvalue = g_pickup_armormedium;
1215         if(!self.max_armorvalue)
1216                 self.max_armorvalue = g_pickup_armormedium_max;
1217         if(!self.pickup_anyway)
1218                 self.pickup_anyway = g_pickup_armormedium_anyway;
1219         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1220 }
1221
1222 void spawnfunc_item_armor_big (void) {
1223         if(!self.armorvalue)
1224                 self.armorvalue = g_pickup_armorbig;
1225         if(!self.max_armorvalue)
1226                 self.max_armorvalue = g_pickup_armorbig_max;
1227         if(!self.pickup_anyway)
1228                 self.pickup_anyway = g_pickup_armorbig_anyway;
1229         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1230 }
1231
1232 void spawnfunc_item_armor_large (void) {
1233         if(!self.armorvalue)
1234                 self.armorvalue = g_pickup_armorlarge;
1235         if(!self.max_armorvalue)
1236                 self.max_armorvalue = g_pickup_armorlarge_max;
1237         if(!self.pickup_anyway)
1238                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1239         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1240 }
1241
1242 void spawnfunc_item_health_small (void) {
1243         if(!self.max_health)
1244                 self.max_health = g_pickup_healthsmall_max;
1245         if(!self.health)
1246                 self.health = g_pickup_healthsmall;
1247         if(!self.pickup_anyway)
1248                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1249         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1250 }
1251
1252 void spawnfunc_item_health_medium (void) {
1253         if(!self.max_health)
1254                 self.max_health = g_pickup_healthmedium_max;
1255         if(!self.health)
1256                 self.health = g_pickup_healthmedium;
1257         if(!self.pickup_anyway)
1258                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1259         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1260 }
1261
1262 void spawnfunc_item_health_large (void) {
1263         if(!self.max_health)
1264                 self.max_health = g_pickup_healthlarge_max;
1265         if(!self.health)
1266                 self.health = g_pickup_healthlarge;
1267         if(!self.pickup_anyway)
1268                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1269         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1270 }
1271
1272 void spawnfunc_item_health_mega (void) {
1273         if(!cvar("g_powerup_superhealth"))
1274                 return;
1275
1276         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1277                 return;
1278
1279         if(g_minstagib) {
1280                 minstagib_items(IT_NAILS);
1281         } else {
1282                 if(!self.max_health)
1283                         self.max_health = g_pickup_healthmega_max;
1284                 if(!self.health)
1285                         self.health = g_pickup_healthmega;
1286                 if(!self.pickup_anyway)
1287                         self.pickup_anyway = g_pickup_healthmega_anyway;
1288                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1289         }
1290 }
1291
1292 // support old misnamed entities
1293 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1294 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1295 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1296 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1297 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1298
1299 void spawnfunc_item_strength (void) {
1300         if(!cvar("g_powerup_strength"))
1301                 return;
1302
1303         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1304                 return;
1305
1306         if(g_minstagib) {
1307                 minstagib_items(IT_STRENGTH);
1308         } else {
1309                 precache_sound("weapons/strength_fire.wav");
1310                 self.strength_finished = 30;
1311                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1312         }
1313 }
1314
1315 void spawnfunc_item_invincible (void) {
1316         if(!cvar("g_powerup_shield"))
1317                 return;
1318
1319         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1320                 return;
1321
1322         if(g_minstagib) {
1323                 minstagib_items(IT_INVINCIBLE);
1324         } else {
1325                 self.invincible_finished = 30;
1326                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1327         }
1328 }
1329
1330 void spawnfunc_item_minst_cells (void) {
1331         if (g_minstagib)
1332         {
1333                 minst_no_auto_cells = 1;
1334                 minstagib_items(IT_CELLS);
1335         }
1336         else
1337                 remove(self);
1338 }
1339
1340 // compatibility:
1341 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1342
1343 float GiveItems(entity e, float beginarg, float endarg);
1344 void target_items_use (void)
1345 {
1346         if(activator.classname == "droppedweapon")
1347         {
1348                 EXACTTRIGGER_TOUCH;
1349                 remove(activator);
1350                 return;
1351         }
1352
1353         if(activator.classname != "player")
1354                 return;
1355         if(activator.deadflag != DEAD_NO)
1356                 return;
1357         EXACTTRIGGER_TOUCH;
1358
1359         entity e;
1360         for(e = world; (e = find(e, classname, "droppedweapon")); )
1361                 if(e.enemy == activator)
1362                         remove(e);
1363
1364         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1365                 centerprint(activator, self.message);
1366 }
1367
1368 void spawnfunc_target_items (void)
1369 {
1370         float n, i, j;
1371         entity e;
1372
1373         self.use = target_items_use;
1374         if(!self.strength_finished)
1375                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1376         if(!self.invincible_finished)
1377                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1378
1379         precache_sound("misc/itempickup.wav");
1380         precache_sound("misc/itempickup.wav");
1381         precache_sound("misc/itempickup.wav");
1382         precache_sound("misc/itempickup.wav");
1383         precache_sound("misc/megahealth.wav");
1384         precache_sound("misc/armor25.wav");
1385         precache_sound("misc/powerup.wav");
1386         precache_sound("misc/poweroff.wav");
1387         precache_sound("weapons/weaponpickup.wav");
1388
1389         n = tokenize_console(self.netname);
1390         if(argv(0) == "give")
1391         {
1392                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1393         }
1394         else
1395         {
1396                 for(i = 0; i < n; ++i)
1397                 {
1398                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1399                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1400                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1401                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1402                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1403                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1404                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1405                         else
1406                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1407                         {
1408                                 e = get_weaponinfo(j);
1409                                 if(argv(i) == e.netname)
1410                                 {
1411                                         self.weapons |= e.weapons;
1412                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1413                                                 weapon_action(e.weapon, WR_PRECACHE);
1414                                         break;
1415                                 }
1416                         }
1417                         if(j > WEP_LAST)
1418                                 print("target_items: invalid item ", argv(i), "\n");
1419                 }
1420
1421                 string itemprefix, valueprefix;
1422                 if(self.spawnflags == 0)
1423                 {
1424                         itemprefix = "";
1425                         valueprefix = "";
1426                 }
1427                 else if(self.spawnflags == 1)
1428                 {
1429                         itemprefix = "max ";
1430                         valueprefix = "max ";
1431                 }
1432                 else if(self.spawnflags == 2)
1433                 {
1434                         itemprefix = "min ";
1435                         valueprefix = "min ";
1436                 }
1437                 else if(self.spawnflags == 4)
1438                 {
1439                         itemprefix = "minus ";
1440                         valueprefix = "max ";
1441                 }
1442                 else
1443                         error("invalid spawnflags");
1444
1445                 self.netname = "";
1446                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1447                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1448                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1449                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1450                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1451                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1452                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1453                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1454                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1455                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1456                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1457                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1458                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1459                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1460                 {
1461                         e = get_weaponinfo(j);
1462                         if(e.weapons)
1463                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1464                 }
1465         }
1466         self.netname = strzone(self.netname);
1467         //print(self.netname, "\n");
1468
1469         n = tokenize_console(self.netname);
1470         for(i = 0; i < n; ++i)
1471         {
1472                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1473                 {
1474                         e = get_weaponinfo(j);
1475                         if(argv(i) == e.netname)
1476                         {
1477                                 weapon_action(e.weapon, WR_PRECACHE);
1478                                 break;
1479                         }
1480                 }
1481         }
1482 }
1483
1484 void spawnfunc_item_fuel(void)
1485 {
1486         if(!self.ammo_fuel)
1487                 self.ammo_fuel = g_pickup_fuel;
1488         if(!self.pickup_anyway)
1489                 self.pickup_anyway = g_pickup_ammo_anyway;
1490         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1491 }
1492
1493 void spawnfunc_item_fuel_regen(void)
1494 {
1495         if(start_items & IT_FUEL_REGEN)
1496         {
1497                 spawnfunc_item_fuel();
1498                 return;
1499         }
1500         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1501 }
1502
1503 void spawnfunc_item_jetpack(void)
1504 {
1505         if(g_grappling_hook)
1506                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1507         if(!self.ammo_fuel)
1508                 self.ammo_fuel = g_pickup_fuel_jetpack;
1509         if(start_items & IT_JETPACK)
1510         {
1511                 spawnfunc_item_fuel();
1512                 return;
1513         }
1514         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1515 }
1516
1517
1518 #define OP_SET 0
1519 #define OP_MIN 1
1520 #define OP_MAX 2
1521 #define OP_PLUS 3
1522 #define OP_MINUS 4
1523
1524 float GiveBit(entity e, .float fld, float bit, float op, float val)
1525 {
1526         float v0, v1;
1527         v0 = (e.fld & bit);
1528         switch(op)
1529         {
1530                 case OP_SET:
1531                         if(val > 0)
1532                                 e.fld |= bit;
1533                         else
1534                                 e.fld &~= bit;
1535                         break;
1536                 case OP_MIN:
1537                 case OP_PLUS:
1538                         if(val > 0)
1539                                 e.fld |= bit;
1540                         break;
1541                 case OP_MAX:
1542                         if(val <= 0)
1543                                 e.fld &~= bit;
1544                         break;
1545                 case OP_MINUS:
1546                         if(val > 0)
1547                                 e.fld &~= bit;
1548                         break;
1549         }
1550         v1 = (e.fld & bit);
1551         return (v0 != v1);
1552 }
1553
1554 float GiveValue(entity e, .float fld, float op, float val)
1555 {
1556         float v0, v1;
1557         v0 = e.fld;
1558         switch(op)
1559         {
1560                 case OP_SET:
1561                         e.fld = val;
1562                         break;
1563                 case OP_MIN:
1564                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1565                         break;
1566                 case OP_MAX:
1567                         e.fld = min(e.fld, val);
1568                         break;
1569                 case OP_PLUS:
1570                         e.fld += val;
1571                         break;
1572                 case OP_MINUS:
1573                         e.fld -= val;
1574                         break;
1575         }
1576         v1 = e.fld;
1577         return (v0 != v1);
1578 }
1579
1580 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1581 {
1582         if(v1 == v0)
1583                 return;
1584         if(v1 <= v0 - t)
1585         {
1586                 if(snd_decr != "")
1587                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1588         }
1589         else if(v0 >= v0 + t)
1590         {
1591                 if(snd_incr != "")
1592                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1593         }
1594 }
1595
1596 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1597 {
1598         if(v0 < v1)
1599                 e.rotfield = max(e.rotfield, time + rottime);
1600         else if(v0 > v1)
1601                 e.regenfield = max(e.regenfield, time + regentime);
1602 }
1603
1604 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1605 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1606 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1607 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1608
1609 float GiveItems(entity e, float beginarg, float endarg)
1610 {
1611         float got, i, j, val, op;
1612         float _switchweapon;
1613         entity wi;
1614         string cmd;
1615
1616         val = 999;
1617         op = OP_SET;
1618
1619         got = 0;
1620
1621         _switchweapon = FALSE;
1622         if (e.autoswitch)
1623                 if (e.switchweapon == w_getbestweapon(e))
1624                         _switchweapon = TRUE;
1625
1626         e.strength_finished = max(0, e.strength_finished - time);
1627         e.invincible_finished = max(0, e.invincible_finished - time);
1628
1629         PREGIVE(e, items);
1630         PREGIVE(e, weapons);
1631         PREGIVE(e, strength_finished);
1632         PREGIVE(e, invincible_finished);
1633         PREGIVE(e, ammo_nails);
1634         PREGIVE(e, ammo_cells);
1635         PREGIVE(e, ammo_shells);
1636         PREGIVE(e, ammo_rockets);
1637         PREGIVE(e, ammo_fuel);
1638         PREGIVE(e, armorvalue);
1639         PREGIVE(e, health);
1640
1641         for(i = beginarg; i < endarg; ++i)
1642         {
1643                 cmd = argv(i);
1644
1645                 if(cmd == "0" || stof(cmd))
1646                 {
1647                         val = stof(cmd);
1648                         continue;
1649                 }
1650                 switch(cmd)
1651                 {
1652                         case "no":
1653                                 op = OP_MAX;
1654                                 val = 0;
1655                                 continue;
1656                         case "max":
1657                                 op = OP_MAX;
1658                                 continue;
1659                         case "min":
1660                                 op = OP_MIN;
1661                                 continue;
1662                         case "plus":
1663                                 op = OP_PLUS;
1664                                 continue;
1665                         case "minus":
1666                                 op = OP_MINUS;
1667                                 continue;
1668                         case "ALL":
1669                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1670                                 got += GiveValue(e, strength_finished, op, time);
1671                                 got += GiveValue(e, invincible_finished, op, time);
1672                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1673                         case "all":
1674                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1675                                 got += GiveValue(e, health, op, val);
1676                                 got += GiveValue(e, armorvalue, op, val);
1677                         case "allweapons":
1678                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1679                                 {
1680                                         wi = get_weaponinfo(j);
1681                                         if(wi.weapons)
1682                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1683                                 }
1684                         case "allammo":
1685                                 got += GiveValue(e, ammo_cells, op, val);
1686                                 got += GiveValue(e, ammo_shells, op, val);
1687                                 got += GiveValue(e, ammo_nails, op, val);
1688                                 got += GiveValue(e, ammo_rockets, op, val);
1689                                 got += GiveValue(e, ammo_fuel, op, val);
1690                                 break;
1691                         case "unlimited_ammo":
1692                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1693                                 break;
1694                         case "unlimited_weapon_ammo":
1695                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1696                                 break;
1697                         case "unlimited_superweapons":
1698                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1699                                 break;
1700                         case "jetpack":
1701                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1702                                 break;
1703                         case "fuel_regen":
1704                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1705                                 break;
1706                         case "strength":
1707                                 got += GiveValue(e, strength_finished, op, val);
1708                                 break;
1709                         case "invincible":
1710                                 got += GiveValue(e, invincible_finished, op, val);
1711                                 break;
1712                         case "cells":
1713                                 got += GiveValue(e, ammo_cells, op, val);
1714                                 break;
1715                         case "shells":
1716                                 got += GiveValue(e, ammo_shells, op, val);
1717                                 break;
1718                         case "nails":
1719                         case "bullets":
1720                                 got += GiveValue(e, ammo_nails, op, val);
1721                                 break;
1722                         case "rockets":
1723                                 got += GiveValue(e, ammo_rockets, op, val);
1724                                 break;
1725                         case "health":
1726                                 got += GiveValue(e, health, op, val);
1727                                 break;
1728                         case "armor":
1729                                 got += GiveValue(e, armorvalue, op, val);
1730                                 break;
1731                         case "fuel":
1732                                 got += GiveValue(e, ammo_fuel, op, val);
1733                                 break;
1734                         default:
1735                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1736                                 {
1737                                         wi = get_weaponinfo(j);
1738                                         if(cmd == wi.netname)
1739                                         {
1740                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1741                                                 break;
1742                                         }
1743                                 }
1744                                 if(j > WEP_LAST)
1745                                         print("give: invalid item ", cmd, "\n");
1746                                 break;
1747                 }
1748                 val = 999;
1749                 op = OP_SET;
1750         }
1751
1752         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1753         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1754         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1755         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1756         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1757         {
1758                 wi = get_weaponinfo(j);
1759                 if(wi.weapons)
1760                 {
1761                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1762                         if not(save_weapons & wi.weapons)
1763                                 if(e.weapons & wi.weapons)
1764                                         weapon_action(wi.weapon, WR_PRECACHE);
1765                 }
1766         }
1767         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1768         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1769         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1770         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1771         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1772         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1773         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1774         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1775         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1776
1777         if(e.strength_finished <= 0)
1778                 e.strength_finished = 0;
1779         else
1780                 e.strength_finished += time;
1781         if(e.invincible_finished <= 0)
1782                 e.invincible_finished = 0;
1783         else
1784                 e.invincible_finished += time;
1785
1786         if not(e.weapons & W_WeaponBit(e.switchweapon))
1787                 _switchweapon = TRUE;
1788         if(_switchweapon)
1789                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1790
1791         return got;
1792 }