qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "bot/bot.qh"
   9     #include "bot/waypoints.qh"
  10
  11     #include "mutators/mutators_include.qh"
  12
  13     #include "weapons/common.qh"
  14     #include "weapons/selection.qh"
  15     #include "weapons/weaponsystem.qh"
  16
  17     #include "../common/constants.qh"
  18     #include "../common/deathtypes.qh"
  19     #include "../common/notifications.qh"
  20         #include "../common/triggers/subs.qh"
  21     #include "../common/util.qh"
  22
  23     #include "../common/monsters/all.qh"
  24
  25     #include "../common/weapons/all.qh"
  26
  27     #include "../warpzonelib/util_server.qh"
  28 #endif
  29
  30 #ifdef CSQC
  31 void ItemDraw()
  32 {
  33     if(self.gravity)
  34     {
  35         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  36         if(self.move_flags & FL_ONGROUND)
  37         { // For some reason move_avelocity gets set to '0 0 0' here ...
  38             self.oldorigin = self.origin;
  39             self.gravity = 0;
  40
  41             if(autocvar_cl_animate_items)
  42             { // ... so reset it if animations are requested.
  43                 if(self.ItemStatus & ITS_ANIMATE1)
  44                     self.move_avelocity = '0 180 0';
  45
  46                 if(self.ItemStatus & ITS_ANIMATE2)
  47                     self.move_avelocity = '0 -90 0';
  48             }
  49         }
  50     }
  51     else if (autocvar_cl_animate_items)
  52     {
  53         if(self.ItemStatus & ITS_ANIMATE1)
  54         {
  55             self.angles += self.move_avelocity * frametime;
  56             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  57         }
  58
  59         if(self.ItemStatus & ITS_ANIMATE2)
  60         {
  61             self.angles += self.move_avelocity * frametime;
  62             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  63         }
  64     }
  65 }
  66
  67 void ItemDrawSimple()
  68 {
  69     if(self.gravity)
  70     {
  71         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  72
  73         if(self.move_flags & FL_ONGROUND)
  74             self.gravity = 0;
  75     }
  76 }
  77
  78 void ItemRead(float _IsNew)
  79 {
  80     int sf = ReadByte();
  81
  82     if(sf & ISF_LOCATION)
  83     {
  84         self.origin_x = ReadCoord();
  85         self.origin_y = ReadCoord();
  86         self.origin_z = ReadCoord();
  87         setorigin(self, self.origin);
  88         self.oldorigin = self.origin;
  89     }
  90
  91     if(sf & ISF_ANGLES)
  92     {
  93         self.angles_x = ReadCoord();
  94         self.angles_y = ReadCoord();
  95         self.angles_z = ReadCoord();
  96         self.move_angles = self.angles;
  97     }
  98
  99     if(sf & ISF_SIZE)
 100     {
 101         self.mins_x = ReadCoord();
 102         self.mins_y = ReadCoord();
 103         self.mins_z = ReadCoord();
 104         self.maxs_x = ReadCoord();
 105         self.maxs_y = ReadCoord();
 106         self.maxs_z = ReadCoord();
 107         setsize(self, self.mins, self.maxs);
 108     }
 109
 110     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 111     {
 112         self.ItemStatus = ReadByte();
 113
 114         if(self.ItemStatus & ITS_AVAILABLE)
 115         {
 116             self.alpha = 1;
 117             self.colormod = self.glowmod = '1 1 1';
 118         }
 119         else
 120         {
 121             if (autocvar_cl_ghost_items_color)
 122             {
 123                 self.alpha = autocvar_cl_ghost_items;
 124                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 125             }
 126             else
 127                 self.alpha = -1;
 128         }
 129
 130         if(autocvar_cl_fullbright_items)
 131             if(self.ItemStatus & ITS_ALLOWFB)
 132                 self.effects |= EF_FULLBRIGHT;
 133
 134         if(self.ItemStatus & ITS_STAYWEP)
 135         {
 136             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 137             self.alpha = autocvar_cl_weapon_stay_alpha;
 138
 139         }
 140
 141         if(self.ItemStatus & ITS_POWERUP)
 142         {
 143             if(self.ItemStatus & ITS_AVAILABLE)
 144                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 145             else
 146                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 147         }
 148     }
 149
 150     if(sf & ISF_MODEL)
 151     {
 152         self.drawmask  = MASK_NORMAL;
 153         self.movetype  = MOVETYPE_TOSS;
 154         self.draw       = ItemDraw;
 155
 156         if(self.mdl)
 157             strunzone(self.mdl);
 158
 159         self.mdl = "";
 160         string _fn = ReadString();
 161
 162         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 163         {
 164             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 165             self.draw = ItemDrawSimple;
 166
 167
 168
 169             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 170                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 171             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 177             else
 178             {
 179                 self.draw = ItemDraw;
 180                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 181             }
 182         }
 183
 184         if(self.draw != ItemDrawSimple)
 185             self.mdl = strzone(_fn);
 186
 187
 188         if(self.mdl == "")
 189             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 190
 191         precache_model(self.mdl);
 192         setmodel(self, self.mdl);
 193     }
 194
 195     if(sf & ISF_COLORMAP)
 196         self.colormap = ReadShort();
 197
 198     if(sf & ISF_DROP)
 199     {
 200         self.gravity = 1;
 201         //self.move_angles = '0 0 0';
 202         self.move_movetype = MOVETYPE_TOSS;
 203         self.move_velocity_x = ReadCoord();
 204         self.move_velocity_y = ReadCoord();
 205         self.move_velocity_z = ReadCoord();
 206         self.velocity = self.move_velocity;
 207         self.move_origin = self.oldorigin;
 208
 209         if(!self.move_time)
 210         {
 211             self.move_time = time;
 212             self.spawntime = time;
 213         }
 214         else
 215             self.move_time = max(self.move_time, time);
 216     }
 217
 218     if(autocvar_cl_animate_items)
 219     {
 220         if(self.ItemStatus & ITS_ANIMATE1)
 221             self.move_avelocity = '0 180 0';
 222
 223         if(self.ItemStatus & ITS_ANIMATE2)
 224             self.move_avelocity = '0 -90 0';
 225     }
 226 }
 227
 228 #endif
 229
 230 #ifdef SVQC
 231 bool ItemSend(entity to, int sf)
 232 {
 233     if(self.gravity)
 234         sf |= ISF_DROP;
 235     else
 236         sf &= ~ISF_DROP;
 237
 238         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 239         WriteByte(MSG_ENTITY, sf);
 240
 241         //WriteByte(MSG_ENTITY, self.cnt);
 242     if(sf & ISF_LOCATION)
 243     {
 244         WriteCoord(MSG_ENTITY, self.origin.x);
 245         WriteCoord(MSG_ENTITY, self.origin.y);
 246         WriteCoord(MSG_ENTITY, self.origin.z);
 247     }
 248
 249     if(sf & ISF_ANGLES)
 250     {
 251         WriteCoord(MSG_ENTITY, self.angles.x);
 252         WriteCoord(MSG_ENTITY, self.angles.y);
 253         WriteCoord(MSG_ENTITY, self.angles.z);
 254     }
 255
 256     if(sf & ISF_SIZE)
 257     {
 258         WriteCoord(MSG_ENTITY, self.mins.x);
 259         WriteCoord(MSG_ENTITY, self.mins.y);
 260         WriteCoord(MSG_ENTITY, self.mins.z);
 261         WriteCoord(MSG_ENTITY, self.maxs.x);
 262         WriteCoord(MSG_ENTITY, self.maxs.y);
 263         WriteCoord(MSG_ENTITY, self.maxs.z);
 264     }
 265
 266     if(sf & ISF_STATUS)
 267         WriteByte(MSG_ENTITY, self.ItemStatus);
 268
 269     if(sf & ISF_MODEL)
 270     {
 271
 272         if(self.mdl == "")
 273             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 274
 275         WriteString(MSG_ENTITY, self.mdl);
 276     }
 277
 278
 279     if(sf & ISF_COLORMAP)
 280         WriteShort(MSG_ENTITY, self.colormap);
 281
 282     if(sf & ISF_DROP)
 283     {
 284         WriteCoord(MSG_ENTITY, self.velocity.x);
 285         WriteCoord(MSG_ENTITY, self.velocity.y);
 286         WriteCoord(MSG_ENTITY, self.velocity.z);
 287     }
 288
 289     return true;
 290 }
 291
 292 void ItemUpdate(entity item)
 293 {
 294         item.SendFlags |= ISF_LOCATION;
 295 }
 296
 297 float have_pickup_item(void)
 298 {
 299         if(self.flags & FL_POWERUP)
 300         {
 301                 if(autocvar_g_powerups > 0)
 302                         return true;
 303                 if(autocvar_g_powerups == 0)
 304                         return false;
 305         }
 306         else
 307         {
 308                 if(autocvar_g_pickup_items > 0)
 309                         return true;
 310                 if(autocvar_g_pickup_items == 0)
 311                         return false;
 312                 if(g_weaponarena)
 313                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 314                                 return false;
 315         }
 316         return true;
 317 }
 318
 319 /*
 320 float Item_Customize()
 321 {
 322         if(self.spawnshieldtime)
 323                 return true;
 324         if(self.weapons & ~other.weapons)
 325         {
 326                 self.colormod = '0 0 0';
 327                 self.glowmod = self.colormod;
 328                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 329                 return true;
 330         }
 331         else
 332         {
 333                 if(g_ghost_items)
 334                 {
 335                         self.colormod = stov(autocvar_g_ghost_items_color);
 336                         self.glowmod = self.colormod;
 337                         self.alpha = g_ghost_items;
 338                         return true;
 339                 }
 340                 else
 341                         return false;
 342         }
 343 }
 344 */
 345
 346 void Item_Show (entity e, float mode)
 347 {
 348         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 349         e.ItemStatus &= ~ITS_STAYWEP;
 350         if (mode > 0)
 351         {
 352                 // make the item look normal, and be touchable
 353                 e.model = e.mdl;
 354                 e.solid = SOLID_TRIGGER;
 355                 e.spawnshieldtime = 1;
 356                 e.ItemStatus |= ITS_AVAILABLE;
 357         }
 358         else if (mode < 0)
 359         {
 360                 // hide the item completely
 361                 e.model = string_null;
 362                 e.solid = SOLID_NOT;
 363                 e.spawnshieldtime = 1;
 364                 e.ItemStatus &= ~ITS_AVAILABLE;
 365         }
 366         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 367         {
 368                 // make the item translucent and not touchable
 369                 e.model = e.mdl;
 370                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 371                 e.effects |= EF_STARDUST;
 372                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 373                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 374         }
 375         else
 376         {
 377                 //setmodel(e, "null");
 378                 e.solid = SOLID_NOT;
 379                 e.colormod = '0 0 0';
 380                 e.glowmod = e.colormod;
 381                 e.spawnshieldtime = 1;
 382                 e.ItemStatus &= ~ITS_AVAILABLE;
 383         }
 384
 385         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 386             e.ItemStatus |= ITS_POWERUP;
 387
 388         if (autocvar_g_nodepthtestitems)
 389                 e.effects |= EF_NODEPTHTEST;
 390
 391
 392     if (autocvar_g_fullbrightitems)
 393                 e.ItemStatus |= ITS_ALLOWFB;
 394
 395         if (autocvar_sv_simple_items)
 396         e.ItemStatus |= ITS_ALLOWSI;
 397
 398         // relink entity (because solid may have changed)
 399         setorigin(e, e.origin);
 400     e.SendFlags |= ISF_STATUS;
 401 }
 402
 403 void Item_Think()
 404 {
 405         self.nextthink = time;
 406         if(self.origin != self.oldorigin)
 407         {
 408                 self.oldorigin = self.origin;
 409                 ItemUpdate(self);
 410         }
 411 }
 412
 413 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 414 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 415 float Item_ItemsTime_UpdateTime(entity e, float t);
 416 void Item_ItemsTime_SetTime(entity e, float t);
 417 void Item_ItemsTime_SetTimesForAllPlayers();
 418
 419 void Item_Respawn (void)
 420 {
 421         Item_Show(self, 1);
 422         // this is ugly...
 423         if(self.items == ITEM_Strength.m_itemid)
 424                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 425         else if(self.items == ITEM_Shield.m_itemid)
 426                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 427         else
 428                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 429         setorigin (self, self.origin);
 430
 431     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 432         {
 433                 float t = Item_ItemsTime_UpdateTime(self, 0);
 434                 Item_ItemsTime_SetTime(self, t);
 435                 Item_ItemsTime_SetTimesForAllPlayers();
 436         }
 437
 438         self.think = Item_Think;
 439         self.nextthink = time;
 440
 441         //Send_Effect("item_respawn", self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 442         Send_Effect("item_respawn", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 443 }
 444
 445 void Item_RespawnCountdown (void)
 446 {
 447         if(self.count >= ITEM_RESPAWN_TICKS)
 448         {
 449                 if(self.waypointsprite_attached)
 450                         WaypointSprite_Kill(self.waypointsprite_attached);
 451                 Item_Respawn();
 452         }
 453         else
 454         {
 455                 self.nextthink = time + 1;
 456                 self.count += 1;
 457                 if(self.count == 1)
 458                 {
 459                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 460                         int wpextra = 0;
 461             entity e = self.itemdef;
 462             if (e) wpextra = e.m_id;
 463                         if (self.flags & FL_WEAPON) {
 464                                 entity wi = get_weaponinfo(self.weapon);
 465                                 if (wi) wpextra = wi.m_id;
 466                         }
 467             entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP);
 468             wp.wp_extra = wpextra;
 469             if(self.waypointsprite_attached)
 470             {
 471                 GameItem def = self.itemdef;
 472                 if (Item_ItemsTime_SpectatorOnly(def))
 473                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 474                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 475             }
 476                 }
 477
 478                 if(self.waypointsprite_attached)
 479                 {
 480                         entity e;
 481                         entity it = self;
 482                         self = self.waypointsprite_attached;
 483                         FOR_EACH_REALCLIENT(e)
 484                                 if(self.waypointsprite_visible_for_player(e))
 485                                 {
 486                                         msg_entity = e;
 487                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 488                                 }
 489                         self = it;
 490
 491                         WaypointSprite_Ping(self.waypointsprite_attached);
 492                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 493                 }
 494                 else
 495                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 496         }
 497 }
 498
 499 void Item_RespawnThink()
 500 {
 501         self.nextthink = time;
 502         if(self.origin != self.oldorigin)
 503         {
 504                 self.oldorigin = self.origin;
 505                 ItemUpdate(self);
 506         }
 507
 508         if(time >= self.wait)
 509                 Item_Respawn();
 510 }
 511
 512 void Item_ScheduleRespawnIn(entity e, float t)
 513 {
 514         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 515         {
 516                 e.think = Item_RespawnCountdown;
 517                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 518                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 519                 e.count = 0;
 520                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 521                 Item_ItemsTime_SetTime(e, t);
 522                 Item_ItemsTime_SetTimesForAllPlayers();
 523         }
 524         else
 525         {
 526                 e.think = Item_RespawnThink;
 527                 e.nextthink = time;
 528                 e.scheduledrespawntime = time + t;
 529                 e.wait = time + t;
 530         }
 531 }
 532
 533 void Item_ScheduleRespawn(entity e)
 534 {
 535         if(e.respawntime > 0)
 536         {
 537                 Item_Show(e, 0);
 538                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 539         }
 540         else // if respawntime is -1, this item does not respawn
 541                 Item_Show(e, -1);
 542 }
 543
 544 void Item_ScheduleInitialRespawn(entity e)
 545 {
 546         Item_Show(e, 0);
 547         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 548 }
 549
 550 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 551 {
 552         if (!item.(ammotype))
 553                 return false;
 554
 555         if (item.spawnshieldtime)
 556         {
 557                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 558                 {
 559                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 560                         goto YEAH;
 561                 }
 562         }
 563         else if(g_weapon_stay == 2)
 564         {
 565                 float mi = min(item.(ammotype), ammomax);
 566                 if (player.(ammotype) < mi)
 567                 {
 568                         player.(ammotype) = mi;
 569                         goto YEAH;
 570                 }
 571         }
 572
 573         return false;
 574
 575 :YEAH
 576         switch(mode)
 577         {
 578                 case ITEM_MODE_FUEL:
 579                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 580                         break;
 581                 case ITEM_MODE_HEALTH:
 582                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 583                         break;
 584                 case ITEM_MODE_ARMOR:
 585                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 586                         break;
 587                 default:
 588                         break;
 589         }
 590         return true;
 591 }
 592
 593 float Item_GiveTo(entity item, entity player)
 594 {
 595         float _switchweapon;
 596         float pickedup;
 597         float it;
 598         float i;
 599
 600         // if nothing happens to player, just return without taking the item
 601         pickedup = false;
 602         _switchweapon = false;
 603         // in case the player has autoswitch enabled do the following:
 604         // if the player is using their best weapon before items are given, they
 605         // probably want to switch to an even better weapon after items are given
 606         if (player.autoswitch)
 607         if (player.switchweapon == w_getbestweapon(player))
 608                 _switchweapon = true;
 609
 610         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 611                 _switchweapon = true;
 612
 613         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 614         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 615         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 616         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 617         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 618         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 619         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 620         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 621
 622         if (item.flags & FL_WEAPON)
 623         {
 624                 WepSet it;
 625                 it = item.weapons;
 626                 it &= ~player.weapons;
 627
 628                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 629                 {
 630                         pickedup = true;
 631                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 632                         if(it & WepSet_FromWeapon(i))
 633                         {
 634                                 W_DropEvent(WR_PICKUP, player, i, item);
 635                                 W_GiveWeapon(player, i);
 636                         }
 637                 }
 638         }
 639
 640         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 641         {
 642                 pickedup = true;
 643                 player.items |= it;
 644                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 645         }
 646
 647         if (item.strength_finished)
 648         {
 649                 pickedup = true;
 650                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 651         }
 652         if (item.invincible_finished)
 653         {
 654                 pickedup = true;
 655                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 656         }
 657         if (item.superweapons_finished)
 658         {
 659                 pickedup = true;
 660                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 661         }
 662
 663 :skip
 664
 665         // always eat teamed entities
 666         if(item.team)
 667                 pickedup = true;
 668
 669         if (!pickedup)
 670                 return 0;
 671
 672         if (_switchweapon)
 673                 if (player.switchweapon != w_getbestweapon(player))
 674                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 675
 676         return 1;
 677 }
 678
 679 void Item_Touch (void)
 680 {
 681         entity e, head;
 682
 683         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 684         if(self.classname == "droppedweapon")
 685         {
 686                 if (ITEM_TOUCH_NEEDKILL())
 687                 {
 688                         remove(self);
 689                         return;
 690                 }
 691         }
 692
 693         if (!IS_PLAYER(other))
 694                 return;
 695         if (other.frozen)
 696                 return;
 697         if (other.deadflag)
 698                 return;
 699         if (self.solid != SOLID_TRIGGER)
 700                 return;
 701         if (self.owner == other)
 702                 return;
 703         if (time < self.item_spawnshieldtime)
 704                 return;
 705
 706         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 707         {
 708                 case MUT_ITEMTOUCH_RETURN: { return; }
 709                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 710         }
 711
 712         if (self.classname == "droppedweapon")
 713         {
 714                 self.strength_finished = max(0, self.strength_finished - time);
 715                 self.invincible_finished = max(0, self.invincible_finished - time);
 716                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 717         }
 718         entity it = self.itemdef;
 719         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 720         if (!gave)
 721         {
 722                 if (self.classname == "droppedweapon")
 723                 {
 724                         // undo what we did above
 725                         self.strength_finished += time;
 726                         self.invincible_finished += time;
 727                         self.superweapons_finished += time;
 728                 }
 729                 return;
 730         }
 731
 732         :pickup
 733
 734         other.last_pickup = time;
 735
 736         Send_Effect("item_pickup", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 737         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 738
 739         if (self.classname == "droppedweapon")
 740                 remove (self);
 741         else if (self.spawnshieldtime)
 742         {
 743                 if(self.team)
 744                 {
 745                         RandomSelection_Init();
 746                         for(head = world; (head = findfloat(head, team, self.team)); )
 747                         {
 748                                 if(head.flags & FL_ITEM)
 749                                 {
 750                                         Item_Show(head, -1);
 751                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 752                                 }
 753                         }
 754                         e = RandomSelection_chosen_ent;
 755
 756                 }
 757                 else
 758                         e = self;
 759                 Item_ScheduleRespawn(e);
 760         }
 761 }
 762
 763 void Item_Reset()
 764 {
 765         Item_Show(self, !self.state);
 766         setorigin (self, self.origin);
 767
 768         if(self.classname != "droppedweapon")
 769         {
 770                 self.think = Item_Think;
 771                 self.nextthink = time;
 772
 773                 if(self.waypointsprite_attached)
 774                         WaypointSprite_Kill(self.waypointsprite_attached);
 775
 776                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 777                         Item_ScheduleInitialRespawn(self);
 778         }
 779 }
 780
 781 void Item_FindTeam()
 782 {
 783         entity head, e;
 784
 785         if(self.effects & EF_NODRAW)
 786         {
 787                 // marker for item team search
 788                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 789                 RandomSelection_Init();
 790                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 791                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 792                 e = RandomSelection_chosen_ent;
 793                 e.state = 0;
 794                 Item_Show(e, 1);
 795
 796                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 797                 {
 798                         if(head != e)
 799                         {
 800                                 // make it a non-spawned item
 801                                 Item_Show(head, -1);
 802                                 head.state = 1; // state 1 = initially hidden item
 803                         }
 804                         head.effects &= ~EF_NODRAW;
 805                 }
 806
 807                 Item_Reset();
 808         }
 809 }
 810
 811 // Savage: used for item garbage-collection
 812 // TODO: perhaps nice special effect?
 813 void RemoveItem(void)
 814 {
 815         Send_Effect("item_pickup", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 816         remove(self);
 817 }
 818
 819 // pickup evaluation functions
 820 // these functions decide how desirable an item is to the bots
 821
 822 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 823
 824 float weapon_pickupevalfunc(entity player, entity item)
 825 {
 826         float c;
 827
 828         // See if I have it already
 829         if(item.weapons & ~player.weapons)
 830         {
 831                 // If I can pick it up
 832                 if(!item.spawnshieldtime)
 833                         c = 0;
 834                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 835                 {
 836                         // Skilled bots will grab more
 837                         c = bound(0, skill / 10, 1) * 0.5;
 838                 }
 839                 else
 840                         c = 0;
 841         }
 842         else
 843                 c = 1;
 844
 845         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 846         if( bot_custom_weapon && c )
 847         {
 848                 // Find the highest position on any range
 849                 int position = -1;
 850                 for (int j = 0; j < WEP_LAST ; ++j){
 851                         if(
 852                                         bot_weapons_far[j] == item.weapon ||
 853                                         bot_weapons_mid[j] == item.weapon ||
 854                                         bot_weapons_close[j] == item.weapon
 855                           )
 856                         {
 857                                 position = j;
 858                                 break;
 859                         }
 860                 }
 861
 862                 // Rate it
 863                 if (position >= 0 )
 864                 {
 865                         position = WEP_LAST - position;
 866                         // item.bot_pickupbasevalue is overwritten here
 867                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 868                 }
 869         }
 870
 871         return item.bot_pickupbasevalue * c;
 872 }
 873
 874 float commodity_pickupevalfunc(entity player, entity item)
 875 {
 876         float c, i;
 877         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 878         entity wi;
 879         c = 0;
 880
 881         // Detect needed ammo
 882         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 883         {
 884                 wi = get_weaponinfo(i);
 885
 886                 if (!(player.weapons & WepSet_FromWeapon(i)))
 887                         continue;
 888
 889                 if(wi.items & ITEM_Shells.m_itemid)
 890                         need_shells = true;
 891                 else if(wi.items & ITEM_Bullets.m_itemid)
 892                         need_nails = true;
 893                 else if(wi.items & ITEM_Rockets.m_itemid)
 894                         need_rockets = true;
 895                 else if(wi.items & ITEM_Cells.m_itemid)
 896                         need_cells = true;
 897                 else if(wi.items & ITEM_Plasma.m_itemid)
 898                         need_plasma = true;
 899                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 900                         need_fuel = true;
 901         }
 902
 903         // TODO: figure out if the player even has the weapon this ammo is for?
 904         // may not affect strategy much though...
 905         // find out how much more ammo/armor/health the player can hold
 906         if (need_shells)
 907         if (item.ammo_shells)
 908         if (player.ammo_shells < g_pickup_shells_max)
 909                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 910         if (need_nails)
 911         if (item.ammo_nails)
 912         if (player.ammo_nails < g_pickup_nails_max)
 913                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 914         if (need_rockets)
 915         if (item.ammo_rockets)
 916         if (player.ammo_rockets < g_pickup_rockets_max)
 917                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 918         if (need_cells)
 919         if (item.ammo_cells)
 920         if (player.ammo_cells < g_pickup_cells_max)
 921                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 922         if (need_plasma)
 923         if (item.ammo_plasma)
 924         if (player.ammo_plasma < g_pickup_plasma_max)
 925                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 926         if (need_fuel)
 927         if (item.ammo_fuel)
 928         if (player.ammo_fuel < g_pickup_fuel_max)
 929                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 930         if (item.armorvalue)
 931         if (player.armorvalue < item.max_armorvalue)
 932                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 933         if (item.health)
 934         if (player.health < item.max_health)
 935                 c = c + max(0, 1 - player.health / item.max_health);
 936
 937         return item.bot_pickupbasevalue * c;
 938 }
 939
 940 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 941 {
 942         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 943                 RemoveItem();
 944 }
 945
 946 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 947 {
 948         startitem_failed = false;
 949
 950         if(self.model == "")
 951                 self.model = itemmodel;
 952
 953         if(self.model == "")
 954     {
 955         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 956         return;
 957     }
 958
 959         if(self.item_pickupsound == "")
 960                 self.item_pickupsound = pickupsound;
 961
 962         if(!self.respawntime) // both need to be set
 963         {
 964                 self.respawntime = defaultrespawntime;
 965                 self.respawntimejitter = defaultrespawntimejitter;
 966         }
 967
 968         self.items = itemid;
 969         self.weapon = weaponid;
 970
 971         if(weaponid)
 972                 self.weapons = WepSet_FromWeapon(weaponid);
 973
 974         self.flags = FL_ITEM | itemflags;
 975
 976         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 977         {
 978                 startitem_failed = true;
 979                 remove(self);
 980                 return;
 981         }
 982
 983         // is it a dropped weapon?
 984         if (self.classname == "droppedweapon")
 985         {
 986                 self.reset = SUB_Remove;
 987                 // it's a dropped weapon
 988                 self.movetype = MOVETYPE_TOSS;
 989
 990                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 991                 self.think = RemoveItem;
 992                 self.nextthink = time + 20;
 993
 994                 self.takedamage = DAMAGE_YES;
 995                 self.event_damage = Item_Damage;
 996
 997                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 998                 /*
 999                 if(self.items == 0)
1000                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1001                 if(self.ammo_nails == 0)
1002                 if(self.ammo_cells == 0)
1003                 if(self.ammo_rockets == 0)
1004                 if(self.ammo_shells == 0)
1005                 if(self.ammo_fuel == 0)
1006                 if(self.health == 0)
1007                 if(self.armorvalue == 0)
1008                 */
1009                 {
1010                         // if item is worthless after a timer, have it expire then
1011                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1012                 }
1013
1014                 // don't drop if in a NODROP zone (such as lava)
1015                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1016                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1017                 {
1018                         startitem_failed = true;
1019                         remove(self);
1020                         return;
1021                 }
1022         }
1023         else
1024         {
1025                 if(!have_pickup_item())
1026                 {
1027                         startitem_failed = true;
1028                         remove (self);
1029                         return;
1030                 }
1031
1032                 self.reset = Item_Reset;
1033                 // it's a level item
1034                 if(self.spawnflags & 1)
1035                         self.noalign = 1;
1036                 if (self.noalign)
1037                         self.movetype = MOVETYPE_NONE;
1038                 else
1039                         self.movetype = MOVETYPE_TOSS;
1040                 // do item filtering according to game mode and other things
1041                 if (!self.noalign)
1042                 {
1043                         // first nudge it off the floor a little bit to avoid math errors
1044                         setorigin(self, self.origin + '0 0 1');
1045                         // set item size before we spawn a spawnfunc_waypoint
1046                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1047                                 setsize (self, '-16 -16 0', '16 16 48');
1048                         else
1049                                 setsize (self, '-16 -16 0', '16 16 32');
1050
1051                         // note droptofloor returns false if stuck/or would fall too far
1052                         droptofloor();
1053                         waypoint_spawnforitem(self);
1054                 }
1055
1056                 /*
1057                  * can't do it that way, as it would break maps
1058                  * TODO make a target_give like entity another way, that perhaps has
1059                  * the weapon name in a key
1060                 if(self.targetname)
1061                 {
1062                         // target_give not yet supported; maybe later
1063                         print("removed targeted ", self.classname, "\n");
1064                         startitem_failed = true;
1065                         remove (self);
1066                         return;
1067                 }
1068                 */
1069
1070                 if(autocvar_spawn_debug >= 2)
1071                 {
1072                         entity otheritem;
1073                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1074                         {
1075                             // why not flags & fl_item?
1076                                 if(otheritem.is_item)
1077                                 {
1078                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(self.origin));
1079                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1080                                         error("Mapper sucks.");
1081                                 }
1082                         }
1083                         self.is_item = true;
1084                 }
1085
1086                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1087
1088                 precache_model (self.model);
1089                 precache_sound (self.item_pickupsound);
1090
1091                 precache_sound ("misc/itemrespawncountdown.wav");
1092                 if(itemid == ITEM_Strength.m_itemid)
1093                         precache_sound ("misc/strength_respawn.wav");
1094                 else if(itemid == ITEM_Shield.m_itemid)
1095                         precache_sound ("misc/shield_respawn.wav");
1096                 else
1097                         precache_sound ("misc/itemrespawn.wav");
1098
1099                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1100                         self.target = "###item###"; // for finding the nearest item using find()
1101
1102                 Item_ItemsTime_SetTime(self, 0);
1103         }
1104
1105         self.bot_pickup = true;
1106         self.bot_pickupevalfunc = pickupevalfunc;
1107         self.bot_pickupbasevalue = pickupbasevalue;
1108         self.mdl = self.model;
1109         self.netname = itemname;
1110         self.touch = Item_Touch;
1111         setmodel(self, "null"); // precision set below
1112         //self.effects |= EF_LOWPRECISION;
1113
1114         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1115     {
1116         self.pos1 = '-16 -16 0';
1117         self.pos2 = '16 16 48';
1118     }
1119         else
1120     {
1121         self.pos1 = '-16 -16 0';
1122         self.pos2 = '16 16 32';
1123     }
1124     setsize (self, self.pos1, self.pos2);
1125
1126     if(itemflags & FL_POWERUP)
1127         self.ItemStatus |= ITS_ANIMATE1;
1128
1129         if(self.armorvalue || self.health)
1130         self.ItemStatus |= ITS_ANIMATE2;
1131
1132         if(itemflags & FL_WEAPON)
1133         {
1134                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1135             self.colormap = 1024; // color shirt=0 pants=0 grey
1136         else
1137             self.gravity = 1;
1138
1139                 self.ItemStatus |= ITS_ANIMATE1;
1140                 self.ItemStatus |= ISF_COLORMAP;
1141         }
1142
1143         self.state = 0;
1144         if(self.team) // broken, no idea why.
1145         {
1146                 if(!self.cnt)
1147                         self.cnt = 1; // item probability weight
1148
1149                 self.effects |= EF_NODRAW; // marker for item team search
1150                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1151         }
1152         else
1153                 Item_Reset();
1154
1155     Net_LinkEntity(self, false, 0, ItemSend);
1156
1157         self.SendFlags |= ISF_SIZE;
1158         if(self.angles)
1159                 self.SendFlags |= ISF_ANGLES;
1160
1161         // call this hook after everything else has been done
1162         if(MUTATOR_CALLHOOK(Item_Spawn, self))
1163         {
1164                 startitem_failed = true;
1165                 remove(self);
1166                 return;
1167         }
1168 }
1169
1170 string Item_Model(string item_mdl)
1171 {
1172         string output = strcat("models/items/", item_mdl);
1173         MUTATOR_CALLHOOK(ItemModel, item_mdl, output);
1174         return strzone(item_model_output);
1175 }
1176
1177 void StartItemA (entity a)
1178 {
1179     self.itemdef = a;
1180     StartItem(Item_Model(a.m_model), a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1181 }
1182
1183 void spawnfunc_item_rockets (void) {
1184         if(!self.ammo_rockets)
1185                 self.ammo_rockets = g_pickup_rockets;
1186         if(!self.pickup_anyway)
1187                 self.pickup_anyway = g_pickup_ammo_anyway;
1188     StartItemA (ITEM_Rockets);
1189 }
1190
1191 void spawnfunc_item_bullets (void) {
1192         if(!weaponswapping)
1193         if(autocvar_sv_q3acompat_machineshotgunswap)
1194         if(self.classname != "droppedweapon")
1195         {
1196                 weaponswapping = true;
1197                 spawnfunc_item_shells();
1198                 weaponswapping = false;
1199                 return;
1200         }
1201
1202         if(!self.ammo_nails)
1203                 self.ammo_nails = g_pickup_nails;
1204         if(!self.pickup_anyway)
1205                 self.pickup_anyway = g_pickup_ammo_anyway;
1206     StartItemA (ITEM_Bullets);
1207 }
1208
1209 void spawnfunc_item_cells (void) {
1210         if(!self.ammo_cells)
1211                 self.ammo_cells = g_pickup_cells;
1212         if(!self.pickup_anyway)
1213                 self.pickup_anyway = g_pickup_ammo_anyway;
1214         StartItemA (ITEM_Cells);
1215 }
1216
1217 void spawnfunc_item_plasma()
1218 {
1219         if(!self.ammo_plasma)
1220                 self.ammo_plasma = g_pickup_plasma;
1221         if(!self.pickup_anyway)
1222                 self.pickup_anyway = g_pickup_ammo_anyway;
1223         StartItemA (ITEM_Plasma);
1224 }
1225
1226 void spawnfunc_item_shells (void) {
1227         if(!weaponswapping)
1228         if(autocvar_sv_q3acompat_machineshotgunswap)
1229         if(self.classname != "droppedweapon")
1230         {
1231                 weaponswapping = true;
1232                 spawnfunc_item_bullets();
1233                 weaponswapping = false;
1234                 return;
1235         }
1236
1237         if(!self.ammo_shells)
1238                 self.ammo_shells = g_pickup_shells;
1239         if(!self.pickup_anyway)
1240                 self.pickup_anyway = g_pickup_ammo_anyway;
1241         StartItemA (ITEM_Shells);
1242 }
1243
1244 void spawnfunc_item_armor_small (void) {
1245         if(!self.armorvalue)
1246                 self.armorvalue = g_pickup_armorsmall;
1247         if(!self.max_armorvalue)
1248                 self.max_armorvalue = g_pickup_armorsmall_max;
1249         if(!self.pickup_anyway)
1250                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1251         StartItemA (ITEM_ArmorSmall);
1252 }
1253
1254 void spawnfunc_item_armor_medium (void) {
1255         if(!self.armorvalue)
1256                 self.armorvalue = g_pickup_armormedium;
1257         if(!self.max_armorvalue)
1258                 self.max_armorvalue = g_pickup_armormedium_max;
1259         if(!self.pickup_anyway)
1260                 self.pickup_anyway = g_pickup_armormedium_anyway;
1261         StartItemA (ITEM_ArmorMedium);
1262 }
1263
1264 void spawnfunc_item_armor_big (void) {
1265         if(!self.armorvalue)
1266                 self.armorvalue = g_pickup_armorbig;
1267         if(!self.max_armorvalue)
1268                 self.max_armorvalue = g_pickup_armorbig_max;
1269         if(!self.pickup_anyway)
1270                 self.pickup_anyway = g_pickup_armorbig_anyway;
1271         StartItemA (ITEM_ArmorLarge);
1272 }
1273
1274 void spawnfunc_item_armor_large (void) {
1275         if(!self.armorvalue)
1276                 self.armorvalue = g_pickup_armorlarge;
1277         if(!self.max_armorvalue)
1278                 self.max_armorvalue = g_pickup_armorlarge_max;
1279         if(!self.pickup_anyway)
1280                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1281         StartItemA (ITEM_ArmorMega);
1282 }
1283
1284 void spawnfunc_item_health_small (void) {
1285         if(!self.max_health)
1286                 self.max_health = g_pickup_healthsmall_max;
1287         if(!self.health)
1288                 self.health = g_pickup_healthsmall;
1289         if(!self.pickup_anyway)
1290                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1291         StartItemA (ITEM_HealthSmall);
1292 }
1293
1294 void spawnfunc_item_health_medium (void) {
1295         if(!self.max_health)
1296                 self.max_health = g_pickup_healthmedium_max;
1297         if(!self.health)
1298                 self.health = g_pickup_healthmedium;
1299         if(!self.pickup_anyway)
1300                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1301     StartItemA (ITEM_HealthMedium);
1302 }
1303
1304 void spawnfunc_item_health_large (void) {
1305         if(!self.max_health)
1306                 self.max_health = g_pickup_healthlarge_max;
1307         if(!self.health)
1308                 self.health = g_pickup_healthlarge;
1309         if(!self.pickup_anyway)
1310                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1311         StartItemA (ITEM_HealthLarge);
1312 }
1313
1314 void spawnfunc_item_health_mega (void) {
1315     if(!self.max_health)
1316         self.max_health = g_pickup_healthmega_max;
1317     if(!self.health)
1318         self.health = g_pickup_healthmega;
1319     if(!self.pickup_anyway)
1320         self.pickup_anyway = g_pickup_healthmega_anyway;
1321     StartItemA (ITEM_HealthMega);
1322 }
1323
1324 // support old misnamed entities
1325 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1326 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1327 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1328 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1329 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1330
1331 void spawnfunc_item_strength (void) {
1332                 precache_sound("weapons/strength_fire.wav");
1333                 if(!self.strength_finished)
1334                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1335                 StartItemA (ITEM_Strength);
1336 }
1337
1338 void spawnfunc_item_invincible (void) {
1339                 if(!self.invincible_finished)
1340                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1341                 StartItemA (ITEM_Shield);
1342 }
1343
1344 // compatibility:
1345 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1346
1347 void target_items_use (void)
1348 {
1349         if(activator.classname == "droppedweapon")
1350         {
1351                 EXACTTRIGGER_TOUCH;
1352                 remove(activator);
1353                 return;
1354         }
1355
1356         if (!IS_PLAYER(activator))
1357                 return;
1358         if(activator.deadflag != DEAD_NO)
1359                 return;
1360         EXACTTRIGGER_TOUCH;
1361
1362         entity e;
1363         for(e = world; (e = find(e, classname, "droppedweapon")); )
1364                 if(e.enemy == activator)
1365                         remove(e);
1366
1367         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1368                 centerprint(activator, self.message);
1369 }
1370
1371 void spawnfunc_target_items (void)
1372 {
1373         float n, i, j;
1374         entity e;
1375         string s;
1376
1377         self.use = target_items_use;
1378         if(!self.strength_finished)
1379                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1380         if(!self.invincible_finished)
1381                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1382         if(!self.superweapons_finished)
1383                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1384
1385         precache_sound("misc/itempickup.wav");
1386         precache_sound("misc/megahealth.wav");
1387         precache_sound("misc/armor25.wav");
1388         precache_sound("misc/powerup.wav");
1389         precache_sound("misc/poweroff.wav");
1390         precache_sound(W_Sound("weaponpickup"));
1391
1392         n = tokenize_console(self.netname);
1393         if(argv(0) == "give")
1394         {
1395                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1396         }
1397         else
1398         {
1399                 for(i = 0; i < n; ++i)
1400                 {
1401                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1402                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1403                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1404                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1405                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1406                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1407                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1408                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1409                         else
1410                         {
1411                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1412                                 {
1413                                         e = get_weaponinfo(j);
1414                                         s = W_UndeprecateName(argv(i));
1415                                         if(s == e.netname)
1416                                         {
1417                                                 self.weapons |= WepSet_FromWeapon(j);
1418                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1419                                                         WEP_ACTION(e.weapon, WR_INIT);
1420                                                 break;
1421                                         }
1422                                 }
1423                                 if(j > WEP_LAST)
1424                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1425                         }
1426                 }
1427
1428                 string itemprefix, valueprefix;
1429                 if(self.spawnflags == 0)
1430                 {
1431                         itemprefix = "";
1432                         valueprefix = "";
1433                 }
1434                 else if(self.spawnflags == 1)
1435                 {
1436                         itemprefix = "max ";
1437                         valueprefix = "max ";
1438                 }
1439                 else if(self.spawnflags == 2)
1440                 {
1441                         itemprefix = "min ";
1442                         valueprefix = "min ";
1443                 }
1444                 else if(self.spawnflags == 4)
1445                 {
1446                         itemprefix = "minus ";
1447                         valueprefix = "max ";
1448                 }
1449                 else
1450                 {
1451                         error("invalid spawnflags");
1452                         itemprefix = valueprefix = string_null;
1453                 }
1454
1455                 self.netname = "";
1456                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1457                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1458                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1459                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1460                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1461                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1462                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1463                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1464                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1465                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1466                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1467                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1468                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1469                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1470                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1471                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1472                 {
1473                         e = get_weaponinfo(j);
1474                         if(e.weapon)
1475                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1476                 }
1477         }
1478         self.netname = strzone(self.netname);
1479         //print(self.netname, "\n");
1480
1481         n = tokenize_console(self.netname);
1482         for(i = 0; i < n; ++i)
1483         {
1484                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1485                 {
1486                         e = get_weaponinfo(j);
1487                         if(argv(i) == e.netname)
1488                         {
1489                                 WEP_ACTION(e.weapon, WR_INIT);
1490                                 break;
1491                         }
1492                 }
1493         }
1494 }
1495
1496 void spawnfunc_item_fuel(void)
1497 {
1498         if(!self.ammo_fuel)
1499                 self.ammo_fuel = g_pickup_fuel;
1500         if(!self.pickup_anyway)
1501                 self.pickup_anyway = g_pickup_ammo_anyway;
1502         StartItemA (ITEM_JetpackFuel);
1503 }
1504
1505 void spawnfunc_item_fuel_regen(void)
1506 {
1507         if(start_items & ITEM_JetpackRegen.m_itemid)
1508         {
1509                 spawnfunc_item_fuel();
1510                 return;
1511         }
1512         StartItemA (ITEM_JetpackRegen);
1513 }
1514
1515 void spawnfunc_item_jetpack(void)
1516 {
1517         if(!self.ammo_fuel)
1518                 self.ammo_fuel = g_pickup_fuel_jetpack;
1519         if(start_items & ITEM_Jetpack.m_itemid)
1520         {
1521                 spawnfunc_item_fuel();
1522                 return;
1523         }
1524         StartItemA (ITEM_Jetpack);
1525 }
1526
1527 float GiveWeapon(entity e, float wpn, float op, float val)
1528 {
1529         WepSet v0, v1;
1530         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1531         switch(op)
1532         {
1533                 case OP_SET:
1534                         if(val > 0)
1535                                 e.weapons |= WepSet_FromWeapon(wpn);
1536                         else
1537                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1538                         break;
1539                 case OP_MIN:
1540                 case OP_PLUS:
1541                         if(val > 0)
1542                                 e.weapons |= WepSet_FromWeapon(wpn);
1543                         break;
1544                 case OP_MAX:
1545                         if(val <= 0)
1546                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1547                         break;
1548                 case OP_MINUS:
1549                         if(val > 0)
1550                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1551                         break;
1552         }
1553         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1554         return (v0 != v1);
1555 }
1556
1557 float GiveBit(entity e, .float fld, float bit, float op, float val)
1558 {
1559         float v0, v1;
1560         v0 = (e.(fld) & bit);
1561         switch(op)
1562         {
1563                 case OP_SET:
1564                         if(val > 0)
1565                                 e.(fld) |= bit;
1566                         else
1567                                 e.(fld) &= ~bit;
1568                         break;
1569                 case OP_MIN:
1570                 case OP_PLUS:
1571                         if(val > 0)
1572                                 e.(fld) |= bit;
1573                         break;
1574                 case OP_MAX:
1575                         if(val <= 0)
1576                                 e.(fld) &= ~bit;
1577                         break;
1578                 case OP_MINUS:
1579                         if(val > 0)
1580                                 e.(fld) &= ~bit;
1581                         break;
1582         }
1583         v1 = (e.(fld) & bit);
1584         return (v0 != v1);
1585 }
1586
1587 float GiveValue(entity e, .float fld, float op, float val)
1588 {
1589         float v0, v1;
1590         v0 = e.(fld);
1591         switch(op)
1592         {
1593                 case OP_SET:
1594                         e.(fld) = val;
1595                         break;
1596                 case OP_MIN:
1597                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1598                         break;
1599                 case OP_MAX:
1600                         e.(fld) = min(e.(fld), val);
1601                         break;
1602                 case OP_PLUS:
1603                         e.(fld) += val;
1604                         break;
1605                 case OP_MINUS:
1606                         e.(fld) -= val;
1607                         break;
1608         }
1609         v1 = e.(fld);
1610         return (v0 != v1);
1611 }
1612
1613 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1614 {
1615         if(v1 == v0)
1616                 return;
1617         if(v1 <= v0 - t)
1618         {
1619                 if(snd_decr != "")
1620                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1621         }
1622         else if(v0 >= v0 + t)
1623         {
1624                 if(snd_incr != "")
1625                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1626         }
1627 }
1628
1629 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1630 {
1631         if(v0 < v1)
1632                 e.(rotfield) = max(e.(rotfield), time + rottime);
1633         else if(v0 > v1)
1634                 e.(regenfield) = max(e.(regenfield), time + regentime);
1635 }
1636 float GiveItems(entity e, float beginarg, float endarg)
1637 {
1638         float got, i, j, val, op;
1639         float _switchweapon;
1640         entity wi;
1641         string cmd;
1642
1643         val = 999;
1644         op = OP_SET;
1645
1646         got = 0;
1647
1648         _switchweapon = false;
1649         if (e.autoswitch)
1650                 if (e.switchweapon == w_getbestweapon(e))
1651                         _switchweapon = true;
1652
1653         e.strength_finished = max(0, e.strength_finished - time);
1654         e.invincible_finished = max(0, e.invincible_finished - time);
1655         e.superweapons_finished = max(0, e.superweapons_finished - time);
1656
1657         PREGIVE(e, items);
1658         PREGIVE_WEAPONS(e);
1659         PREGIVE(e, strength_finished);
1660         PREGIVE(e, invincible_finished);
1661         PREGIVE(e, superweapons_finished);
1662         PREGIVE(e, ammo_nails);
1663         PREGIVE(e, ammo_cells);
1664         PREGIVE(e, ammo_plasma);
1665         PREGIVE(e, ammo_shells);
1666         PREGIVE(e, ammo_rockets);
1667         PREGIVE(e, ammo_fuel);
1668         PREGIVE(e, armorvalue);
1669         PREGIVE(e, health);
1670
1671         for(i = beginarg; i < endarg; ++i)
1672         {
1673                 cmd = argv(i);
1674
1675                 if(cmd == "0" || stof(cmd))
1676                 {
1677                         val = stof(cmd);
1678                         continue;
1679                 }
1680                 switch(cmd)
1681                 {
1682                         case "no":
1683                                 op = OP_MAX;
1684                                 val = 0;
1685                                 continue;
1686                         case "max":
1687                                 op = OP_MAX;
1688                                 continue;
1689                         case "min":
1690                                 op = OP_MIN;
1691                                 continue;
1692                         case "plus":
1693                                 op = OP_PLUS;
1694                                 continue;
1695                         case "minus":
1696                                 op = OP_MINUS;
1697                                 continue;
1698                         case "ALL":
1699                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1700                                 got += GiveValue(e, strength_finished, op, val);
1701                                 got += GiveValue(e, invincible_finished, op, val);
1702                                 got += GiveValue(e, superweapons_finished, op, val);
1703                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1704                         case "all":
1705                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1706                                 got += GiveValue(e, health, op, val);
1707                                 got += GiveValue(e, armorvalue, op, val);
1708                         case "allweapons":
1709                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1710                                 {
1711                                         wi = get_weaponinfo(j);
1712                                         if(wi.weapon)
1713                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1714                                                         got += GiveWeapon(e, j, op, val);
1715                                 }
1716                         case "allammo":
1717                                 got += GiveValue(e, ammo_cells, op, val);
1718                                 got += GiveValue(e, ammo_plasma, op, val);
1719                                 got += GiveValue(e, ammo_shells, op, val);
1720                                 got += GiveValue(e, ammo_nails, op, val);
1721                                 got += GiveValue(e, ammo_rockets, op, val);
1722                                 got += GiveValue(e, ammo_fuel, op, val);
1723                                 break;
1724                         case "unlimited_ammo":
1725                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1726                                 break;
1727                         case "unlimited_weapon_ammo":
1728                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1729                                 break;
1730                         case "unlimited_superweapons":
1731                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1732                                 break;
1733                         case "jetpack":
1734                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1735                                 break;
1736                         case "fuel_regen":
1737                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1738                                 break;
1739                         case "strength":
1740                                 got += GiveValue(e, strength_finished, op, val);
1741                                 break;
1742                         case "invincible":
1743                                 got += GiveValue(e, invincible_finished, op, val);
1744                                 break;
1745                         case "superweapons":
1746                                 got += GiveValue(e, superweapons_finished, op, val);
1747                                 break;
1748                         case "cells":
1749                                 got += GiveValue(e, ammo_cells, op, val);
1750                                 break;
1751                         case "plasma":
1752                                 got += GiveValue(e, ammo_plasma, op, val);
1753                                 break;
1754                         case "shells":
1755                                 got += GiveValue(e, ammo_shells, op, val);
1756                                 break;
1757                         case "nails":
1758                         case "bullets":
1759                                 got += GiveValue(e, ammo_nails, op, val);
1760                                 break;
1761                         case "rockets":
1762                                 got += GiveValue(e, ammo_rockets, op, val);
1763                                 break;
1764                         case "health":
1765                                 got += GiveValue(e, health, op, val);
1766                                 break;
1767                         case "armor":
1768                                 got += GiveValue(e, armorvalue, op, val);
1769                                 break;
1770                         case "fuel":
1771                                 got += GiveValue(e, ammo_fuel, op, val);
1772                                 break;
1773                         default:
1774                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1775                                 {
1776                                         wi = get_weaponinfo(j);
1777                                         if(cmd == wi.netname)
1778                                         {
1779                                                 got += GiveWeapon(e, j, op, val);
1780                                                 break;
1781                                         }
1782                                 }
1783                                 if(j > WEP_LAST)
1784                                         LOG_INFO("give: invalid item ", cmd, "\n");
1785                                 break;
1786                 }
1787                 val = 999;
1788                 op = OP_SET;
1789         }
1790
1791         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, "misc/itempickup.wav", string_null);
1792         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1793         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1794         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, "misc/itempickup.wav", string_null);
1795         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1796         {
1797                 wi = get_weaponinfo(j);
1798                 if(wi.weapon)
1799                 {
1800                         POSTGIVE_WEAPON(e, j, W_Sound("weaponpickup"), string_null);
1801                         if (!(save_weapons & WepSet_FromWeapon(j)))
1802                                 if(e.weapons & WepSet_FromWeapon(j))
1803                                         WEP_ACTION(wi.weapon, WR_INIT);
1804                 }
1805         }
1806         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1807         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1808         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1809         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1810         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1811         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1812         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1813         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1814         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1815         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1816
1817         if(e.superweapons_finished <= 0)
1818                 if(self.weapons & WEPSET_SUPERWEAPONS)
1819                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1820
1821         if(e.strength_finished <= 0)
1822                 e.strength_finished = 0;
1823         else
1824                 e.strength_finished += time;
1825         if(e.invincible_finished <= 0)
1826                 e.invincible_finished = 0;
1827         else
1828                 e.invincible_finished += time;
1829         if(e.superweapons_finished <= 0)
1830                 e.superweapons_finished = 0;
1831         else
1832                 e.superweapons_finished += time;
1833
1834         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1835                 _switchweapon = true;
1836         if(_switchweapon)
1837                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1838
1839         return got;
1840 }
1841 #endif