qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(autocvar_g_ghost_items_color);
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(autocvar_g_ghost_items_color);
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = '0 0 0';
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (autocvar_g_nodepthtestitems)
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (autocvar_g_fullbrightitems)
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 152         else
 153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 202                                 if(self.waypointsprite_attached)
 203                                 {
 204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 207                                 }
 208                         }
 209                 }
 210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 211                 if(self.waypointsprite_attached)
 212                 {
 213                         WaypointSprite_Ping(self.waypointsprite_attached);
 214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 215                 }
 216         }
 217 }
 218
 219 void Item_ScheduleRespawnIn(entity e, float t)
 220 {
 221         if(e.flags & FL_POWERUP)
 222         {
 223                 e.think = Item_RespawnCountdown;
 224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 225                 e.count = 0;
 226         }
 227         else
 228         {
 229                 e.think = Item_Respawn;
 230                 e.nextthink = time + t;
 231         }
 232 }
 233
 234 void Item_ScheduleRespawn(entity e)
 235 {
 236         if(e.respawntime > 0)
 237         {
 238                 Item_Show(e, 0);
 239                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 240         }
 241         else // if respawntime is -1, this item does not respawn
 242                 Item_Show(e, -1);
 243 }
 244
 245 void Item_ScheduleInitialRespawn(entity e)
 246 {
 247         Item_Show(e, 0);
 248         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 249 }
 250
 251 float Item_GiveTo(entity item, entity player)
 252 {
 253         float _switchweapon;
 254         float pickedup;
 255         float it;
 256         float i;
 257         entity e;
 258
 259         // if nothing happens to player, just return without taking the item
 260         pickedup = FALSE;
 261         _switchweapon = FALSE;
 262
 263         if (g_minstagib)
 264         {
 265                 if(item.spawnshieldtime)
 266                 {
 267                         if (item.ammo_fuel)
 268                         if (player.ammo_fuel < g_pickup_fuel_max)
 269                         {
 270                                 pickedup = TRUE;
 271                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 272                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 273                         }
 274                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 275                         {
 276                                 pickedup = TRUE;
 277                                 player.items |= it;
 278                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 279                         }
 280
 281                         _switchweapon = TRUE;
 282                         if (item.ammo_cells)
 283                         {
 284                                 pickedup = TRUE;
 285                                 // play some cool sounds ;)
 286                                 if (clienttype(player) == CLIENTTYPE_REAL)
 287                                 {
 288                                         if(player.health <= 5)
 289                                                 AnnounceTo(player, "lastsecond");
 290                                         else if(player.health < 50)
 291                                                 AnnounceTo(player, "narrowly");
 292                                 }
 293                                 // sound not available
 294                                 // else if(item.items == IT_CELLS)
 295                                 //      AnnounceTo(player, "ammo");
 296
 297                                 if (item.weapons & WEPBIT_MINSTANEX)
 298                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 299                                 if (item.ammo_cells)
 300                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 301                                 player.health = 100;
 302                         }
 303
 304                         // extralife powerup
 305                         if (item.max_health)
 306                         {
 307                                 pickedup = TRUE;
 308                                 // sound not available
 309                                 // AnnounceTo(player, "_lives");
 310                                 player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 311                                 sprint(player, "^3You picked up some extra lives\n");
 312                         }
 313
 314                         // invis powerup
 315                         if (item.strength_finished)
 316                         {
 317                                 pickedup = TRUE;
 318                                 // sound not available
 319                                 // AnnounceTo(player, "invisible");
 320                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 321                         }
 322
 323                         // speed powerup
 324                         if (item.invincible_finished)
 325                         {
 326                                 pickedup = TRUE;
 327                                 // sound not available
 328                                 // AnnounceTo(player, "speed");
 329                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 330                         }
 331                 }
 332         }
 333         else
 334         {
 335                 if (g_weapon_stay == 1)
 336                 if not(item.flags & FL_NO_WEAPON_STAY)
 337                 if (item.flags & FL_WEAPON)
 338                 {
 339                         if(item.classname == "droppedweapon")
 340                         {
 341                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 342                                         goto skip;
 343                         }
 344                         else
 345                         {
 346                                 if (player.weapons & item.weapons)
 347                                         goto skip;
 348                         }
 349                 }
 350
 351                 // in case the player has autoswitch enabled do the following:
 352                 // if the player is using their best weapon before items are given, they
 353                 // probably want to switch to an even better weapon after items are given
 354                 if (player.autoswitch)
 355                 if (player.switchweapon == w_getbestweapon(player))
 356                         _switchweapon = TRUE;
 357
 358                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 359                         _switchweapon = TRUE;
 360
 361                 if(item.spawnshieldtime)
 362                 {
 363                         if (item.ammo_shells)
 364                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 365                         {
 366                                 pickedup = TRUE;
 367                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 368                         }
 369                         if (item.ammo_nails)
 370                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 371                         {
 372                                 pickedup = TRUE;
 373                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 374                         }
 375                         if (item.ammo_rockets)
 376                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 377                         {
 378                                 pickedup = TRUE;
 379                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 380                         }
 381                         if (item.ammo_cells)
 382                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 383                         {
 384                                 pickedup = TRUE;
 385                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 386                         }
 387                         if (item.ammo_fuel)
 388                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 389                         {
 390                                 pickedup = TRUE;
 391                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 392                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 393                         }
 394                 }
 395
 396                 if (item.flags & FL_WEAPON)
 397                 if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway && !(g_weapon_stay == 3 && !e.spawnshieldtime)))
 398                 {
 399                         pickedup = TRUE;
 400                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 401                         {
 402                                 e = get_weaponinfo(i);
 403                                 if(it & e.weapons)
 404                                         W_GiveWeapon (player, e.weapon, item.netname);
 405                         }
 406                 }
 407
 408                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 409                 {
 410                         pickedup = TRUE;
 411                         player.items |= it;
 412                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 413                 }
 414
 415                 if(item.spawnshieldtime)
 416                 {
 417                         if (item.strength_finished)
 418                         {
 419                                 pickedup = TRUE;
 420                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 421                         }
 422                         if (item.invincible_finished)
 423                         {
 424                                 pickedup = TRUE;
 425                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 426                         }
 427
 428                         if (item.health)
 429                         if ((player.health < item.max_health) || item.pickup_anyway)
 430                         {
 431                                 pickedup = TRUE;
 432                                 player.health = bound(player.health, item.max_health, player.health + item.health);
 433                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 434                         }
 435                         if (item.armorvalue)
 436                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 437                         {
 438                                 pickedup = TRUE;
 439                                 player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 440                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 441                         }
 442                 }
 443         }
 444
 445 :skip
 446         // always eat teamed entities
 447         if(item.team)
 448                 pickedup = TRUE;
 449
 450         if (!pickedup)
 451                 return 0;
 452
 453         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 454         if (_switchweapon)
 455                 if (player.switchweapon != w_getbestweapon(player))
 456                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 457
 458         return 1;
 459 }
 460
 461 void Item_Touch (void)
 462 {
 463         entity e, head;
 464
 465         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 466         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 467         {
 468                 remove(self);
 469                 return;
 470         }
 471         if (other.classname != "player")
 472                 return;
 473         if (other.deadflag)
 474                 return;
 475         if (self.solid != SOLID_TRIGGER)
 476                 return;
 477         if (self.owner == other)
 478                 return;
 479
 480         if(!Item_GiveTo(self, other))
 481                 return;
 482
 483         other.last_pickup = time;
 484
 485         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 486
 487         if (self.classname == "droppedweapon")
 488                 remove (self);
 489         else if not(self.spawnshieldtime)
 490                 return;
 491         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 492                 return;
 493         else
 494         {
 495                 if(self.team)
 496                 {
 497                         RandomSelection_Init();
 498                         for(head = world; (head = findfloat(head, team, self.team)); )
 499                         {
 500                                 if(head.flags & FL_ITEM)
 501                                 {
 502                                         Item_Show(head, -1);
 503                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 504                                 }
 505                         }
 506                         e = RandomSelection_chosen_ent;
 507                 }
 508                 else
 509                         e = self;
 510                 Item_ScheduleRespawn(e);
 511         }
 512 }
 513
 514 void Item_FindTeam()
 515 {
 516         entity head, e;
 517
 518         if(self.effects & EF_NODRAW)
 519         {
 520                 // marker for item team search
 521                 dprint("Initializing item team ", ftos(self.team), "\n");
 522                 RandomSelection_Init();
 523                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 524                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 525                 e = RandomSelection_chosen_ent;
 526                 e.state = 0;
 527                 Item_Show(e, 1);
 528
 529                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 530                 {
 531                         if(head != e)
 532                         {
 533                                 // make it a non-spawned item
 534                                 Item_Show(head, -1);
 535                                 head.state = 1; // state 1 = initially hidden item
 536                         }
 537                         head.effects &~= EF_NODRAW;
 538                 }
 539
 540                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 541                         Item_ScheduleInitialRespawn(e);
 542         }
 543 }
 544
 545 void Item_Reset()
 546 {
 547         Item_Show(self, !self.state);
 548         setorigin (self, self.origin);
 549         self.think = SUB_Null;
 550         self.nextthink = 0;
 551
 552         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 553                 Item_ScheduleInitialRespawn(self);
 554 }
 555
 556 // Savage: used for item garbage-collection
 557 // TODO: perhaps nice special effect?
 558 void RemoveItem(void)
 559 {
 560         remove(self);
 561 }
 562
 563 // pickup evaluation functions
 564 // these functions decide how desirable an item is to the bots
 565
 566 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 567
 568 float weapon_pickupevalfunc(entity player, entity item)
 569 {
 570         float c, i, j, position;
 571
 572         // See if I have it already
 573         if(player.weapons & item.weapons == item.weapons)
 574         {
 575                 // If I can pick it up
 576                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 577                         c = 0;
 578                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 579                 {
 580                         // Skilled bots will grab more
 581                         c = bound(0, skill / 10, 1) * 0.5;
 582                 }
 583                 else
 584                         c = 0;
 585         }
 586         else
 587                 c = 1;
 588
 589         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 590         if( bot_custom_weapon && c )
 591         {
 592                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 593                 {
 594                         // Find weapon
 595                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 596                                 continue;
 597
 598                         // Find the highest position on any range
 599                         position = -1;
 600                         for(j = 0; j < WEP_LAST ; ++j){
 601                                 if(
 602                                                 bot_weapons_far[j] == i ||
 603                                                 bot_weapons_mid[j] == i ||
 604                                                 bot_weapons_close[j] == i
 605                                   )
 606                                 {
 607                                         position = j;
 608                                         break;
 609                                 }
 610                         }
 611
 612                         // Rate it
 613                         if (position >= 0 )
 614                         {
 615                                 position = WEP_LAST - position;
 616                                 // item.bot_pickupbasevalue is overwritten here
 617                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 618                         }
 619                 }
 620         }
 621
 622         return item.bot_pickupbasevalue * c;
 623 };
 624
 625 float commodity_pickupevalfunc(entity player, entity item)
 626 {
 627         float c, i, need_shells, need_nails, need_rockets, need_cells;
 628         entity wi;
 629         c = 0;
 630
 631         // Detect needed ammo
 632         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 633         {
 634                 wi = get_weaponinfo(i);
 635
 636                 if not(wi.weapons & player.weapons)
 637                         continue;
 638
 639                 if(wi.items & IT_SHELLS)
 640                         need_shells = TRUE;
 641                 else if(wi.items & IT_NAILS)
 642                         need_nails = TRUE;
 643                 else if(wi.items & IT_ROCKETS)
 644                         need_rockets = TRUE;
 645                 else if(wi.items & IT_CELLS)
 646                         need_cells = TRUE;
 647         }
 648
 649         // TODO: figure out if the player even has the weapon this ammo is for?
 650         // may not affect strategy much though...
 651         // find out how much more ammo/armor/health the player can hold
 652         if (need_shells)
 653         if (item.ammo_shells)
 654         if (player.ammo_shells < g_pickup_shells_max)
 655                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 656         if (need_nails)
 657         if (item.ammo_nails)
 658         if (player.ammo_nails < g_pickup_nails_max)
 659                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 660         if (need_rockets)
 661         if (item.ammo_rockets)
 662         if (player.ammo_rockets < g_pickup_rockets_max)
 663                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 664         if (need_cells)
 665         if (item.ammo_cells)
 666         if (player.ammo_cells < g_pickup_cells_max)
 667                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 668         if (item.armorvalue)
 669         if (player.armorvalue < item.max_armorvalue)
 670                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 671         if (item.health)
 672         if (player.health < item.max_health)
 673                 c = c + max(0, 1 - player.health / item.max_health);
 674
 675         return item.bot_pickupbasevalue * c;
 676 };
 677
 678
 679 .float is_item;
 680 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 681 {
 682         startitem_failed = FALSE;
 683
 684         self.items = itemid;
 685         self.weapons = weaponid;
 686
 687         // is it a dropped weapon?
 688         if (self.classname == "droppedweapon")
 689         {
 690                 self.reset = SUB_Remove;
 691                 // it's a dropped weapon
 692                 self.movetype = MOVETYPE_TOSS;
 693                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 694                 self.think = RemoveItem;
 695                 self.nextthink = time + 60;
 696                 // don't drop if in a NODROP zone (such as lava)
 697                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 698                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 699                 {
 700                         startitem_failed = TRUE;
 701                         remove(self);
 702                         return;
 703                 }
 704         }
 705         else
 706         {
 707                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 708                 {
 709                         startitem_failed = TRUE;
 710                         remove(self);
 711                         return;
 712                 }
 713
 714                 self.reset = Item_Reset;
 715                 // it's a level item
 716                 if(self.spawnflags & 1)
 717                         self.noalign = 1;
 718                 if (self.noalign)
 719                         self.movetype = MOVETYPE_NONE;
 720                 else
 721                         self.movetype = MOVETYPE_TOSS;
 722                 // do item filtering according to game mode and other things
 723                 if (!self.noalign)
 724                 {
 725                         // first nudge it off the floor a little bit to avoid math errors
 726                         setorigin(self, self.origin + '0 0 1');
 727                         // set item size before we spawn a spawnfunc_waypoint
 728                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 729                                 setsize (self, '-16 -16 0', '16 16 48');
 730                         else
 731                                 setsize (self, '-16 -16 0', '16 16 32');
 732                         // note droptofloor returns FALSE if stuck/or would fall too far
 733                         droptofloor();
 734                         waypoint_spawnforitem(self);
 735                 }
 736
 737                 /*
 738                  * can't do it that way, as it would break maps
 739                  * TODO make a target_give like entity another way, that perhaps has
 740                  * the weapon name in a key
 741                 if(self.targetname)
 742                 {
 743                         // target_give not yet supported; maybe later
 744                         print("removed targeted ", self.classname, "\n");
 745                         startitem_failed = TRUE;
 746                         remove (self);
 747                         return;
 748                 }
 749                 */
 750
 751                 if(autocvar_spawn_debug >= 2)
 752                 {
 753                         entity otheritem;
 754                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 755                         {
 756                                 if(otheritem.is_item)
 757                                 {
 758                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 759                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 760                                         error("Mapper sucks.");
 761                                 }
 762                         }
 763                         self.is_item = TRUE;
 764                 }
 765
 766                 if(g_lms || g_ca)
 767                 {
 768                         startitem_failed = TRUE;
 769                         remove(self);
 770                         return;
 771                 }
 772                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 773                 {
 774                         startitem_failed = TRUE;
 775                         remove(self);
 776                         return;
 777                 }
 778                 else if (g_minstagib)
 779                 {
 780                         // don't remove dropped items and powerups
 781                         if (self.classname != "minstagib")
 782                         {
 783                                 startitem_failed = TRUE;
 784                                 remove (self);
 785                                 return;
 786                         }
 787                 }
 788                 else if (!autocvar_g_pickup_items && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 789                 {
 790                         startitem_failed = TRUE;
 791                         remove (self);
 792                         return;
 793                 }
 794
 795                 weaponsInMap |= weaponid;
 796
 797                 precache_model (itemmodel);
 798                 precache_sound (pickupsound);
 799
 800                 precache_sound ("misc/itemrespawncountdown.wav");
 801                 if(!g_minstagib && itemid == IT_STRENGTH)
 802                         precache_sound ("misc/strength_respawn.wav");
 803                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 804                         precache_sound ("misc/shield_respawn.wav");
 805                 else
 806                         precache_sound ("misc/itemrespawn.wav");
 807
 808                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 809                         self.target = "###item###"; // for finding the nearest item using find()
 810         }
 811
 812         self.bot_pickup = TRUE;
 813         self.bot_pickupevalfunc = pickupevalfunc;
 814         self.bot_pickupbasevalue = pickupbasevalue;
 815         self.mdl = itemmodel;
 816         self.item_pickupsound = pickupsound;
 817         // let mappers override respawntime
 818         if(!self.respawntime) // both set
 819         {
 820                 self.respawntime = defaultrespawntime;
 821                 self.respawntimejitter = defaultrespawntimejitter;
 822         }
 823         self.netname = itemname;
 824         self.flags = FL_ITEM | itemflags;
 825         self.touch = Item_Touch;
 826         setmodel (self, self.mdl); // precision set below
 827         self.effects |= EF_LOWPRECISION;
 828         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 829                 setsize (self, '-16 -16 0', '16 16 48');
 830         else
 831                 setsize (self, '-16 -16 0', '16 16 32');
 832         if(itemflags & FL_WEAPON)
 833                 self.modelflags |= MF_ROTATE;
 834
 835         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 836         if (itemflags & FL_WEAPON)
 837         {
 838                 // neutral team color for pickup weapons
 839                 self.colormap = 1024; // color shirt=0 pants=0 grey
 840         }
 841
 842         Item_Show(self, 1);
 843         self.state = 0;
 844         if(self.team)
 845         {
 846                 if(!self.cnt)
 847                         self.cnt = 1; // item probability weight
 848                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 849                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 850         }
 851         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 852                 Item_ScheduleInitialRespawn(self);
 853 }
 854
 855 /* replace items in minstagib
 856  * IT_STRENGTH   = invisibility
 857  * IT_NAILS      = extra lives
 858  * IT_INVINCIBLE = speed
 859  */
 860 void minstagib_items (float itemid)
 861 {
 862         local float rnd;
 863         self.classname = "minstagib";
 864
 865         // replace rocket launchers and nex guns with ammo cells
 866         if (itemid == IT_CELLS)
 867         {
 868                 self.ammo_cells = 1;
 869                 StartItem ("models/items/a_cells.md3",
 870                         "misc/itempickup.wav", 45, 0,
 871                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 872                 return;
 873         }
 874
 875         // randomize
 876         rnd = random() * 3;
 877         if (rnd <= 1)
 878                 itemid = IT_STRENGTH;
 879         else if (rnd <= 2)
 880                 itemid = IT_NAILS;
 881         else
 882                 itemid = IT_INVINCIBLE;
 883
 884         // replace with invis
 885         if (itemid == IT_STRENGTH)
 886         {
 887                 self.strength_finished = 30;
 888                 StartItem ("models/items/g_strength.md3",
 889                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 890                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 891         }
 892         // replace with extra lives
 893         if (itemid == IT_NAILS)
 894         {
 895                 self.max_health = 1;
 896                 StartItem ("models/items/g_h100.md3",
 897                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 898                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 899         }
 900         // replace with speed
 901         if (itemid == IT_INVINCIBLE)
 902         {
 903                 self.invincible_finished = 30;
 904                 StartItem ("models/items/g_invincible.md3",
 905                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 906                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 907         }
 908 }
 909
 910 float minst_no_auto_cells;
 911 void minst_remove_item (void) {
 912         if(minst_no_auto_cells)
 913                 remove(self);
 914 }
 915
 916 float weaponswapping;
 917 float internalteam;
 918
 919 void weapon_defaultspawnfunc(float wpn)
 920 {
 921         entity e;
 922         float t;
 923         var .float ammofield;
 924         string s;
 925         entity oldself;
 926         float i, j;
 927
 928         // set the respawntime in advance (so replaced weapons can copy it)
 929
 930         if(!self.respawntime)
 931         {
 932                 e = get_weaponinfo(wpn);
 933                 if(e.items == IT_SUPERWEAPON)
 934                 {
 935                         self.respawntime = g_pickup_respawntime_powerup;
 936                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 937                 }
 938                 else
 939                 {
 940                         self.respawntime = g_pickup_respawntime_weapon;
 941                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 942                 }
 943         }
 944
 945         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 946         {
 947                 e = get_weaponinfo(wpn);
 948                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 949                 if(s == "0")
 950                 {
 951                         remove(self);
 952                         startitem_failed = TRUE;
 953                         return;
 954                 }
 955                 t = tokenize_console(s);
 956                 if(t >= 2)
 957                 {
 958                         self.team = --internalteam;
 959                         oldself = self;
 960                         for(i = 1; i < t; ++i)
 961                         {
 962                                 s = argv(i);
 963                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 964                                 {
 965                                         e = get_weaponinfo(j);
 966                                         if(e.netname == s)
 967                                         {
 968                                                 self = spawn();
 969                                                 copyentity(oldself, self);
 970                                                 self.classname = "replacedweapon";
 971                                                 weapon_defaultspawnfunc(j);
 972                                                 break;
 973                                         }
 974                                 }
 975                                 if(j > WEP_LAST)
 976                                 {
 977                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 978                                 }
 979                         }
 980                         self = oldself;
 981                 }
 982                 if(t >= 1)
 983                 {
 984                         s = argv(0);
 985                         wpn = 0;
 986                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 987                         {
 988                                 e = get_weaponinfo(j);
 989                                 if(e.netname == s)
 990                                 {
 991                                         wpn = j;
 992                                         break;
 993                                 }
 994                         }
 995                         if(j > WEP_LAST)
 996                         {
 997                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 998                         }
 999                 }
1000                 if(wpn == 0)
1001                 {
1002                         remove(self);
1003                         startitem_failed = TRUE;
1004                         return;
1005                 }
1006         }
1007
1008         e = get_weaponinfo(wpn);
1009
1010         if(e.items && e.items != IT_SUPERWEAPON)
1011         {
1012                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1013                 {
1014                         if(e.items & j)
1015                         {
1016                                 ammofield = Item_CounterField(j);
1017                                 if(!self.ammofield)
1018                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1019                         }
1020                 }
1021         }
1022         else
1023         {
1024                 self.flags |= FL_NO_WEAPON_STAY;
1025         }
1026
1027         // weapon stay isn't supported for teamed weapons
1028         if(self.team)
1029                 self.flags |= FL_NO_WEAPON_STAY;
1030
1031         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1032         {
1033                 self.ammo_shells = 0;
1034                 self.ammo_nails = 0;
1035                 self.ammo_cells = 0;
1036                 self.ammo_rockets = 0;
1037                 // weapon stay 2: don't use ammo on weapon pickups; instead
1038                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1039         }
1040
1041         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1042         if (self.modelindex) // don't precache if self was removed
1043                 weapon_action(e.weapon, WR_PRECACHE);
1044 }
1045
1046 void spawnfunc_weapon_shotgun (void);
1047 void spawnfunc_weapon_uzi (void) {
1048         if(q3acompat_machineshotgunswap)
1049         if(self.classname != "droppedweapon")
1050         {
1051                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1052                 return;
1053         }
1054         weapon_defaultspawnfunc(WEP_UZI);
1055 }
1056
1057 void spawnfunc_weapon_shotgun (void) {
1058         if(q3acompat_machineshotgunswap)
1059         if(self.classname != "droppedweapon")
1060         {
1061                 weapon_defaultspawnfunc(WEP_UZI);
1062                 return;
1063         }
1064         weapon_defaultspawnfunc(WEP_SHOTGUN);
1065 }
1066
1067 void spawnfunc_weapon_nex (void)
1068 {
1069         if (g_minstagib)
1070         {
1071                 minstagib_items(IT_CELLS);
1072                 self.think = minst_remove_item;
1073                 self.nextthink = time;
1074                 return;
1075         }
1076         weapon_defaultspawnfunc(WEP_NEX);
1077 }
1078
1079 void spawnfunc_weapon_minstanex (void)
1080 {
1081         if (g_minstagib)
1082         {
1083                 minstagib_items(IT_CELLS);
1084                 self.think = minst_remove_item;
1085                 self.nextthink = time;
1086                 return;
1087         }
1088         weapon_defaultspawnfunc(WEP_MINSTANEX);
1089 }
1090
1091 void spawnfunc_weapon_rocketlauncher (void)
1092 {
1093         if (g_minstagib)
1094         {
1095                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1096                 self.think = minst_remove_item;
1097                 self.nextthink = time;
1098                 return;
1099         }
1100         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1101 }
1102
1103 void spawnfunc_item_rockets (void) {
1104         if(!self.ammo_rockets)
1105                 self.ammo_rockets = g_pickup_rockets;
1106         if(!self.pickup_anyway)
1107                 self.pickup_anyway = g_pickup_ammo_anyway;
1108         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1109 }
1110
1111 void spawnfunc_item_shells (void);
1112 void spawnfunc_item_bullets (void) {
1113         if(!weaponswapping)
1114         if(q3acompat_machineshotgunswap)
1115         if(self.classname != "droppedweapon")
1116         {
1117                 weaponswapping = TRUE;
1118                 spawnfunc_item_shells();
1119                 weaponswapping = FALSE;
1120                 return;
1121         }
1122
1123         if(!self.ammo_nails)
1124                 self.ammo_nails = g_pickup_nails;
1125         if(!self.pickup_anyway)
1126                 self.pickup_anyway = g_pickup_ammo_anyway;
1127         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1128 }
1129
1130 void spawnfunc_item_cells (void) {
1131         if(!self.ammo_cells)
1132                 self.ammo_cells = g_pickup_cells;
1133         if(!self.pickup_anyway)
1134                 self.pickup_anyway = g_pickup_ammo_anyway;
1135         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1136 }
1137
1138 void spawnfunc_item_shells (void) {
1139         if(!weaponswapping)
1140         if(q3acompat_machineshotgunswap)
1141         if(self.classname != "droppedweapon")
1142         {
1143                 weaponswapping = TRUE;
1144                 spawnfunc_item_bullets();
1145                 weaponswapping = FALSE;
1146                 return;
1147         }
1148
1149         if(!self.ammo_shells)
1150                 self.ammo_shells = g_pickup_shells;
1151         if(!self.pickup_anyway)
1152                 self.pickup_anyway = g_pickup_ammo_anyway;
1153         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1154 }
1155
1156 void spawnfunc_item_armor_small (void) {
1157         if(!self.armorvalue)
1158                 self.armorvalue = g_pickup_armorsmall;
1159         if(!self.max_armorvalue)
1160                 self.max_armorvalue = g_pickup_armorsmall_max;
1161         if(!self.pickup_anyway)
1162                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1163         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1164 }
1165
1166 void spawnfunc_item_armor_medium (void) {
1167         if(!self.armorvalue)
1168                 self.armorvalue = g_pickup_armormedium;
1169         if(!self.max_armorvalue)
1170                 self.max_armorvalue = g_pickup_armormedium_max;
1171         if(!self.pickup_anyway)
1172                 self.pickup_anyway = g_pickup_armormedium_anyway;
1173         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1174 }
1175
1176 void spawnfunc_item_armor_big (void) {
1177         if(!self.armorvalue)
1178                 self.armorvalue = g_pickup_armorbig;
1179         if(!self.max_armorvalue)
1180                 self.max_armorvalue = g_pickup_armorbig_max;
1181         if(!self.pickup_anyway)
1182                 self.pickup_anyway = g_pickup_armorbig_anyway;
1183         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1184 }
1185
1186 void spawnfunc_item_armor_large (void) {
1187         if(!self.armorvalue)
1188                 self.armorvalue = g_pickup_armorlarge;
1189         if(!self.max_armorvalue)
1190                 self.max_armorvalue = g_pickup_armorlarge_max;
1191         if(!self.pickup_anyway)
1192                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1193         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1194 }
1195
1196 void spawnfunc_item_health_small (void) {
1197         if(!self.max_health)
1198                 self.max_health = g_pickup_healthsmall_max;
1199         if(!self.health)
1200                 self.health = g_pickup_healthsmall;
1201         if(!self.pickup_anyway)
1202                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1203         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1204 }
1205
1206 void spawnfunc_item_health_medium (void) {
1207         if(!self.max_health)
1208                 self.max_health = g_pickup_healthmedium_max;
1209         if(!self.health)
1210                 self.health = g_pickup_healthmedium;
1211         if(!self.pickup_anyway)
1212                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1213         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1214 }
1215
1216 void spawnfunc_item_health_large (void) {
1217         if(!self.max_health)
1218                 self.max_health = g_pickup_healthlarge_max;
1219         if(!self.health)
1220                 self.health = g_pickup_healthlarge;
1221         if(!self.pickup_anyway)
1222                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1223         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1224 }
1225
1226 void spawnfunc_item_health_mega (void) {
1227         if(!autocvar_g_powerup_superhealth)
1228                 return;
1229
1230         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1231                 return;
1232
1233         if(g_minstagib) {
1234                 minstagib_items(IT_NAILS);
1235         } else {
1236                 if(!self.max_health)
1237                         self.max_health = g_pickup_healthmega_max;
1238                 if(!self.health)
1239                         self.health = g_pickup_healthmega;
1240                 if(!self.pickup_anyway)
1241                         self.pickup_anyway = g_pickup_healthmega_anyway;
1242                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1243         }
1244 }
1245
1246 // support old misnamed entities
1247 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1248 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1249 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1250 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1251 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1252
1253 void spawnfunc_item_strength (void) {
1254         if(!autocvar_g_powerup_strength)
1255                 return;
1256
1257         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1258                 return;
1259
1260         if(g_minstagib) {
1261                 minstagib_items(IT_STRENGTH);
1262         } else {
1263                 precache_sound("weapons/strength_fire.wav");
1264                 self.strength_finished = 30;
1265                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1266         }
1267 }
1268
1269 void spawnfunc_item_invincible (void) {
1270         if(!autocvar_g_powerup_shield)
1271                 return;
1272
1273         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1274                 return;
1275
1276         if(g_minstagib) {
1277                 minstagib_items(IT_INVINCIBLE);
1278         } else {
1279                 self.invincible_finished = 30;
1280                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1281         }
1282 }
1283
1284 void spawnfunc_item_minst_cells (void) {
1285         if (g_minstagib)
1286         {
1287                 minst_no_auto_cells = 1;
1288                 minstagib_items(IT_CELLS);
1289         }
1290         else
1291                 remove(self);
1292 }
1293
1294 // compatibility:
1295 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1296
1297 float GiveItems(entity e, float beginarg, float endarg);
1298 void target_items_use (void)
1299 {
1300         if(activator.classname == "droppedweapon")
1301         {
1302                 EXACTTRIGGER_TOUCH;
1303                 remove(activator);
1304                 return;
1305         }
1306
1307         if(activator.classname != "player")
1308                 return;
1309         if(activator.deadflag != DEAD_NO)
1310                 return;
1311         EXACTTRIGGER_TOUCH;
1312
1313         entity e;
1314         for(e = world; (e = find(e, classname, "droppedweapon")); )
1315                 if(e.enemy == activator)
1316                         remove(e);
1317
1318         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1319                 centerprint(activator, self.message);
1320 }
1321
1322 void spawnfunc_target_items (void)
1323 {
1324         float n, i, j;
1325         entity e;
1326
1327         self.use = target_items_use;
1328         if(!self.strength_finished)
1329                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1330         if(!self.invincible_finished)
1331                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1332
1333         precache_sound("misc/itempickup.wav");
1334         precache_sound("misc/megahealth.wav");
1335         precache_sound("misc/armor25.wav");
1336         precache_sound("misc/powerup.wav");
1337         precache_sound("misc/poweroff.wav");
1338         precache_sound("weapons/weaponpickup.wav");
1339
1340         n = tokenize_console(self.netname);
1341         if(argv(0) == "give")
1342         {
1343                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1344         }
1345         else
1346         {
1347                 for(i = 0; i < n; ++i)
1348                 {
1349                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1350                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1351                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1352                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1353                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1354                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1355                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1356                         else
1357                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1358                         {
1359                                 e = get_weaponinfo(j);
1360                                 if(argv(i) == e.netname)
1361                                 {
1362                                         self.weapons |= e.weapons;
1363                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1364                                                 weapon_action(e.weapon, WR_PRECACHE);
1365                                         break;
1366                                 }
1367                         }
1368                         if(j > WEP_LAST)
1369                                 print("target_items: invalid item ", argv(i), "\n");
1370                 }
1371
1372                 string itemprefix, valueprefix;
1373                 if(self.spawnflags == 0)
1374                 {
1375                         itemprefix = "";
1376                         valueprefix = "";
1377                 }
1378                 else if(self.spawnflags == 1)
1379                 {
1380                         itemprefix = "max ";
1381                         valueprefix = "max ";
1382                 }
1383                 else if(self.spawnflags == 2)
1384                 {
1385                         itemprefix = "min ";
1386                         valueprefix = "min ";
1387                 }
1388                 else if(self.spawnflags == 4)
1389                 {
1390                         itemprefix = "minus ";
1391                         valueprefix = "max ";
1392                 }
1393                 else
1394                         error("invalid spawnflags");
1395
1396                 self.netname = "";
1397                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1398                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1399                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1400                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1401                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1402                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1403                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1404                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1405                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1406                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1407                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1408                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1409                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1410                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1411                 {
1412                         e = get_weaponinfo(j);
1413                         if(e.weapons)
1414                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1415                 }
1416         }
1417         self.netname = strzone(self.netname);
1418         //print(self.netname, "\n");
1419
1420         n = tokenize_console(self.netname);
1421         for(i = 0; i < n; ++i)
1422         {
1423                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1424                 {
1425                         e = get_weaponinfo(j);
1426                         if(argv(i) == e.netname)
1427                         {
1428                                 weapon_action(e.weapon, WR_PRECACHE);
1429                                 break;
1430                         }
1431                 }
1432         }
1433 }
1434
1435 void spawnfunc_item_fuel(void)
1436 {
1437         if(!self.ammo_fuel)
1438                 self.ammo_fuel = g_pickup_fuel;
1439         if(!self.pickup_anyway)
1440                 self.pickup_anyway = g_pickup_ammo_anyway;
1441         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1442 }
1443
1444 void spawnfunc_item_fuel_regen(void)
1445 {
1446         if(start_items & IT_FUEL_REGEN)
1447         {
1448                 spawnfunc_item_fuel();
1449                 return;
1450         }
1451         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1452 }
1453
1454 void spawnfunc_item_jetpack(void)
1455 {
1456         if(g_grappling_hook)
1457                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1458         if(!self.ammo_fuel)
1459                 self.ammo_fuel = g_pickup_fuel_jetpack;
1460         if(start_items & IT_JETPACK)
1461         {
1462                 spawnfunc_item_fuel();
1463                 return;
1464         }
1465         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1466 }
1467
1468
1469 #define OP_SET 0
1470 #define OP_MIN 1
1471 #define OP_MAX 2
1472 #define OP_PLUS 3
1473 #define OP_MINUS 4
1474
1475 float GiveBit(entity e, .float fld, float bit, float op, float val)
1476 {
1477         float v0, v1;
1478         v0 = (e.fld & bit);
1479         switch(op)
1480         {
1481                 case OP_SET:
1482                         if(val > 0)
1483                                 e.fld |= bit;
1484                         else
1485                                 e.fld &~= bit;
1486                         break;
1487                 case OP_MIN:
1488                 case OP_PLUS:
1489                         if(val > 0)
1490                                 e.fld |= bit;
1491                         break;
1492                 case OP_MAX:
1493                         if(val <= 0)
1494                                 e.fld &~= bit;
1495                         break;
1496                 case OP_MINUS:
1497                         if(val > 0)
1498                                 e.fld &~= bit;
1499                         break;
1500         }
1501         v1 = (e.fld & bit);
1502         return (v0 != v1);
1503 }
1504
1505 float GiveValue(entity e, .float fld, float op, float val)
1506 {
1507         float v0, v1;
1508         v0 = e.fld;
1509         switch(op)
1510         {
1511                 case OP_SET:
1512                         e.fld = val;
1513                         break;
1514                 case OP_MIN:
1515                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1516                         break;
1517                 case OP_MAX:
1518                         e.fld = min(e.fld, val);
1519                         break;
1520                 case OP_PLUS:
1521                         e.fld += val;
1522                         break;
1523                 case OP_MINUS:
1524                         e.fld -= val;
1525                         break;
1526         }
1527         v1 = e.fld;
1528         return (v0 != v1);
1529 }
1530
1531 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1532 {
1533         if(v1 == v0)
1534                 return;
1535         if(v1 <= v0 - t)
1536         {
1537                 if(snd_decr != "")
1538                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1539         }
1540         else if(v0 >= v0 + t)
1541         {
1542                 if(snd_incr != "")
1543                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1544         }
1545 }
1546
1547 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1548 {
1549         if(v0 < v1)
1550                 e.rotfield = max(e.rotfield, time + rottime);
1551         else if(v0 > v1)
1552                 e.regenfield = max(e.regenfield, time + regentime);
1553 }
1554
1555 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1556 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1557 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1558 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1559
1560 float GiveItems(entity e, float beginarg, float endarg)
1561 {
1562         float got, i, j, val, op;
1563         float _switchweapon;
1564         entity wi;
1565         string cmd;
1566
1567         val = 999;
1568         op = OP_SET;
1569
1570         got = 0;
1571
1572         _switchweapon = FALSE;
1573         if (e.autoswitch)
1574                 if (e.switchweapon == w_getbestweapon(e))
1575                         _switchweapon = TRUE;
1576
1577         e.strength_finished = max(0, e.strength_finished - time);
1578         e.invincible_finished = max(0, e.invincible_finished - time);
1579
1580         PREGIVE(e, items);
1581         PREGIVE(e, weapons);
1582         PREGIVE(e, strength_finished);
1583         PREGIVE(e, invincible_finished);
1584         PREGIVE(e, ammo_nails);
1585         PREGIVE(e, ammo_cells);
1586         PREGIVE(e, ammo_shells);
1587         PREGIVE(e, ammo_rockets);
1588         PREGIVE(e, ammo_fuel);
1589         PREGIVE(e, armorvalue);
1590         PREGIVE(e, health);
1591
1592         for(i = beginarg; i < endarg; ++i)
1593         {
1594                 cmd = argv(i);
1595
1596                 if(cmd == "0" || stof(cmd))
1597                 {
1598                         val = stof(cmd);
1599                         continue;
1600                 }
1601                 switch(cmd)
1602                 {
1603                         case "no":
1604                                 op = OP_MAX;
1605                                 val = 0;
1606                                 continue;
1607                         case "max":
1608                                 op = OP_MAX;
1609                                 continue;
1610                         case "min":
1611                                 op = OP_MIN;
1612                                 continue;
1613                         case "plus":
1614                                 op = OP_PLUS;
1615                                 continue;
1616                         case "minus":
1617                                 op = OP_MINUS;
1618                                 continue;
1619                         case "ALL":
1620                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1621                                 got += GiveValue(e, strength_finished, op, time);
1622                                 got += GiveValue(e, invincible_finished, op, time);
1623                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1624                         case "all":
1625                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1626                                 got += GiveValue(e, health, op, val);
1627                                 got += GiveValue(e, armorvalue, op, val);
1628                         case "allweapons":
1629                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1630                                 {
1631                                         wi = get_weaponinfo(j);
1632                                         if(wi.weapons)
1633                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1634                                 }
1635                         case "allammo":
1636                                 got += GiveValue(e, ammo_cells, op, val);
1637                                 got += GiveValue(e, ammo_shells, op, val);
1638                                 got += GiveValue(e, ammo_nails, op, val);
1639                                 got += GiveValue(e, ammo_rockets, op, val);
1640                                 got += GiveValue(e, ammo_fuel, op, val);
1641                                 break;
1642                         case "unlimited_ammo":
1643                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1644                                 break;
1645                         case "unlimited_weapon_ammo":
1646                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1647                                 break;
1648                         case "unlimited_superweapons":
1649                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1650                                 break;
1651                         case "jetpack":
1652                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1653                                 break;
1654                         case "fuel_regen":
1655                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1656                                 break;
1657                         case "strength":
1658                                 got += GiveValue(e, strength_finished, op, val);
1659                                 break;
1660                         case "invincible":
1661                                 got += GiveValue(e, invincible_finished, op, val);
1662                                 break;
1663                         case "cells":
1664                                 got += GiveValue(e, ammo_cells, op, val);
1665                                 break;
1666                         case "shells":
1667                                 got += GiveValue(e, ammo_shells, op, val);
1668                                 break;
1669                         case "nails":
1670                         case "bullets":
1671                                 got += GiveValue(e, ammo_nails, op, val);
1672                                 break;
1673                         case "rockets":
1674                                 got += GiveValue(e, ammo_rockets, op, val);
1675                                 break;
1676                         case "health":
1677                                 got += GiveValue(e, health, op, val);
1678                                 break;
1679                         case "armor":
1680                                 got += GiveValue(e, armorvalue, op, val);
1681                                 break;
1682                         case "fuel":
1683                                 got += GiveValue(e, ammo_fuel, op, val);
1684                                 break;
1685                         default:
1686                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1687                                 {
1688                                         wi = get_weaponinfo(j);
1689                                         if(cmd == wi.netname)
1690                                         {
1691                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1692                                                 break;
1693                                         }
1694                                 }
1695                                 if(j > WEP_LAST)
1696                                         print("give: invalid item ", cmd, "\n");
1697                                 break;
1698                 }
1699                 val = 999;
1700                 op = OP_SET;
1701         }
1702
1703         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1704         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1705         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1706         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1707         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1708         {
1709                 wi = get_weaponinfo(j);
1710                 if(wi.weapons)
1711                 {
1712                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1713                         if not(save_weapons & wi.weapons)
1714                                 if(e.weapons & wi.weapons)
1715                                         weapon_action(wi.weapon, WR_PRECACHE);
1716                 }
1717         }
1718         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1719         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1720         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1721         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1722         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1723         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1724         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1725         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1726         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1727
1728         if (g_minstagib)
1729         {
1730                 e.health = bound(0, e.health, 100);
1731                 e.armorvalue = bound(0, e.armorvalue, 999);
1732         }
1733
1734         if(e.strength_finished <= 0)
1735                 e.strength_finished = 0;
1736         else
1737                 e.strength_finished += time;
1738         if(e.invincible_finished <= 0)
1739                 e.invincible_finished = 0;
1740         else
1741                 e.invincible_finished += time;
1742
1743         if not(e.weapons & W_WeaponBit(e.switchweapon))
1744                 _switchweapon = TRUE;
1745         if(_switchweapon)
1746                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1747
1748         return got;
1749 }