qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280                 if(g_lms)
 281                         return FALSE;
 282                 if(g_ca)
 283                         return FALSE;
 284                 if(g_arena)
 285                         return FALSE;
 286         }
 287         else
 288         {
 289                 if(autocvar_g_pickup_items > 0)
 290                         return TRUE;
 291                 if(autocvar_g_pickup_items == 0)
 292                         return FALSE;
 293                 if(g_lms)
 294                         return FALSE;
 295                 if(g_ca)
 296                         return FALSE;
 297                 if(g_weaponarena)
 298                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 299                                 return FALSE;
 300         }
 301         return TRUE;
 302 }
 303
 304 #define ITEM_RESPAWN_TICKS 10
 305
 306 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 307         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 308 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 309         // range: 10 .. respawntime + respawntimejitter
 310
 311 floatfield Item_CounterField(float it)
 312 {
 313         switch(it)
 314         {
 315                 case IT_SHELLS:      return ammo_shells;
 316                 case IT_NAILS:       return ammo_nails;
 317                 case IT_ROCKETS:     return ammo_rockets;
 318                 case IT_CELLS:       return ammo_cells;
 319                 case IT_FUEL:        return ammo_fuel;
 320                 case IT_5HP:         return health;
 321                 case IT_25HP:        return health;
 322                 case IT_HEALTH:      return health;
 323                 case IT_ARMOR_SHARD: return armorvalue;
 324                 case IT_ARMOR:       return armorvalue;
 325                 // add more things here (health, armor)
 326                 default:             error("requested item has no counter field");
 327         }
 328 #ifdef GMQCC
 329         // should never happen
 330         return health;
 331 #endif
 332 }
 333
 334 string Item_CounterFieldName(float it)
 335 {
 336         switch(it)
 337         {
 338                 case IT_SHELLS:      return "shells";
 339                 case IT_NAILS:       return "nails";
 340                 case IT_ROCKETS:     return "rockets";
 341                 case IT_CELLS:       return "cells";
 342                 case IT_FUEL:        return "fuel";
 343
 344                 // add more things here (health, armor)
 345                 default:             error("requested item has no counter field name");
 346         }
 347 #ifdef GMQCC
 348         // should never happen
 349         return string_null;
 350 #endif
 351 }
 352
 353 .float max_armorvalue;
 354 .float pickup_anyway;
 355 /*
 356 float Item_Customize()
 357 {
 358         if(self.spawnshieldtime)
 359                 return TRUE;
 360         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 361         {
 362                 self.colormod = '0 0 0';
 363                 self.glowmod = self.colormod;
 364                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 365                 return TRUE;
 366         }
 367         else
 368         {
 369                 if(g_ghost_items)
 370                 {
 371                         self.colormod = stov(autocvar_g_ghost_items_color);
 372                         self.glowmod = self.colormod;
 373                         self.alpha = g_ghost_items;
 374                         return TRUE;
 375                 }
 376                 else
 377                         return FALSE;
 378         }
 379 }
 380 */
 381
 382 void Item_Show (entity e, float mode)
 383 {
 384         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 385         e.ItemStatus &~= ITS_STAYWEP;
 386         if (mode > 0)
 387         {
 388                 // make the item look normal, and be touchable
 389                 e.model = e.mdl;
 390                 e.solid = SOLID_TRIGGER;
 391                 e.spawnshieldtime = 1;
 392                 e.ItemStatus |= ITS_AVAILABLE;
 393         }
 394         else if (mode < 0)
 395         {
 396                 // hide the item completely
 397                 e.model = string_null;
 398                 e.solid = SOLID_NOT;
 399                 e.spawnshieldtime = 1;
 400                 e.ItemStatus &~= ITS_AVAILABLE;
 401         }
 402         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 403         {
 404                 // make the item translucent and not touchable
 405                 e.model = e.mdl;
 406                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 407                 e.effects |= EF_STARDUST;
 408                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 409                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 410         }
 411         else
 412         {
 413                 //setmodel(e, "null");
 414                 e.solid = SOLID_NOT;
 415                 e.colormod = '0 0 0';
 416                 e.glowmod = e.colormod;
 417                 e.spawnshieldtime = 1;
 418                 e.ItemStatus &~= ITS_AVAILABLE;
 419         }
 420
 421         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 422             e.ItemStatus |= ITS_POWERUP;
 423
 424         if (autocvar_g_nodepthtestitems)
 425                 e.effects |= EF_NODEPTHTEST;
 426
 427
 428     if (autocvar_g_fullbrightitems)
 429                 e.ItemStatus |= ITS_ALLOWFB;
 430
 431         if (autocvar_sv_simple_items)
 432         e.ItemStatus |= ITS_ALLOWSI;
 433
 434         // relink entity (because solid may have changed)
 435         setorigin(e, e.origin);
 436     e.SendFlags |= ISF_STATUS;
 437 }
 438
 439 void Item_Respawn (void)
 440 {
 441         Item_Show(self, 1);
 442         // this is ugly...
 443         if(self.items == IT_STRENGTH)
 444                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 445         else if(self.items == IT_INVINCIBLE)
 446                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 447         else
 448                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 449         setorigin (self, self.origin);
 450
 451         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 452         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 453 }
 454
 455 void Item_RespawnCountdown (void)
 456 {
 457         if(self.count >= ITEM_RESPAWN_TICKS)
 458         {
 459                 if(self.waypointsprite_attached)
 460                         WaypointSprite_Kill(self.waypointsprite_attached);
 461                 Item_Respawn();
 462         }
 463         else
 464         {
 465                 self.nextthink = time + 1;
 466                 self.count += 1;
 467                 if(self.count == 1)
 468                 {
 469                         string name;
 470                         vector rgb = '1 0 1';
 471                         name = string_null;
 472                         switch(self.items)
 473                         {
 474                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 475                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 476                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 477                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 478                         }
 479                         item_name = name;
 480                         item_color = rgb;
 481                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 482                         name = item_name;
 483                         rgb = item_color;
 484                         if(self.flags & FL_WEAPON)
 485                         {
 486                                 entity wi = get_weaponinfo(self.weapon);
 487                                 if(wi)
 488                                 {
 489                                         name = wi.model2;
 490                                         rgb = '1 0 0';
 491                                 }
 492                         }
 493                         if(name)
 494                         {
 495                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 496                                 if(self.waypointsprite_attached)
 497                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 498                         }
 499                         else
 500                         {
 501                                 print("Unknown powerup-marked item is wanting to respawn\n");
 502                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 503                         }
 504                 }
 505                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 506                 if(self.waypointsprite_attached)
 507                 {
 508                         WaypointSprite_Ping(self.waypointsprite_attached);
 509                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 510                 }
 511         }
 512 }
 513
 514 void Item_ScheduleRespawnIn(entity e, float t)
 515 {
 516         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 517         {
 518                 e.think = Item_RespawnCountdown;
 519                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 520                 e.count = 0;
 521         }
 522         else
 523         {
 524                 e.think = Item_Respawn;
 525                 e.nextthink = time + t;
 526         }
 527 }
 528
 529 void Item_ScheduleRespawn(entity e)
 530 {
 531         if(e.respawntime > 0)
 532         {
 533                 Item_Show(e, 0);
 534                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 535         }
 536         else // if respawntime is -1, this item does not respawn
 537                 Item_Show(e, -1);
 538 }
 539
 540 void Item_ScheduleInitialRespawn(entity e)
 541 {
 542         Item_Show(e, 0);
 543         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 544 }
 545
 546 float ITEM_MODE_NONE = 0;
 547 float ITEM_MODE_HEALTH = 1;
 548 float ITEM_MODE_ARMOR = 2;
 549 float ITEM_MODE_FUEL = 3;
 550 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 551 {
 552         if (!item.ammofield)
 553                 return FALSE;
 554
 555         if (item.spawnshieldtime)
 556         {
 557                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 558                 {
 559                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 560                         goto YEAH;
 561                 }
 562         }
 563         else if(g_weapon_stay == 2)
 564         {
 565                 float mi = min(item.ammofield, ammomax);
 566                 if (player.ammofield < mi)
 567                 {
 568                         player.ammofield = mi;
 569                         goto YEAH;
 570                 }
 571         }
 572
 573         return FALSE;
 574
 575 :YEAH
 576         switch(mode)
 577         {
 578                 case ITEM_MODE_FUEL:
 579                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 580                         break;
 581                 case ITEM_MODE_HEALTH:
 582                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 583                         break;
 584                 case ITEM_MODE_ARMOR:
 585                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 586                         break;
 587                 default:
 588                         break;
 589         }
 590         return TRUE;
 591 }
 592
 593 float Item_GiveTo(entity item, entity player)
 594 {
 595         float _switchweapon;
 596         float pickedup;
 597         float it;
 598         float i;
 599
 600         // if nothing happens to player, just return without taking the item
 601         pickedup = FALSE;
 602         _switchweapon = FALSE;
 603
 604                 // in case the player has autoswitch enabled do the following:
 605                 // if the player is using their best weapon before items are given, they
 606                 // probably want to switch to an even better weapon after items are given
 607                 if (player.autoswitch)
 608                 if (player.switchweapon == w_getbestweapon(player))
 609                         _switchweapon = TRUE;
 610
 611                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 612                         _switchweapon = TRUE;
 613
 614                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 615                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 616                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 617                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 618                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 619                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 620                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 621
 622                 if (item.flags & FL_WEAPON)
 623                 {
 624                         WEPSET_DECLARE_A(it);
 625                         WEPSET_COPY_AE(it, item);
 626                         WEPSET_ANDNOT_AE(it, player);
 627
 628                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 629                         {
 630                                 pickedup = TRUE;
 631                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 632                                         if(WEPSET_CONTAINS_AW(it, i))
 633                                                 W_GiveWeapon(player, i);
 634                         }
 635                 }
 636
 637                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 638                 {
 639                         pickedup = TRUE;
 640                         player.items |= it;
 641                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 642                 }
 643
 644                 if (item.strength_finished)
 645                 {
 646                         pickedup = TRUE;
 647                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 648                 }
 649                 if (item.invincible_finished)
 650                 {
 651                         pickedup = TRUE;
 652                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 653                 }
 654                 if (item.superweapons_finished)
 655                 {
 656                         pickedup = TRUE;
 657                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 658                 }
 659
 660 :skip
 661
 662         other = player;
 663         giveitem = item;
 664         player_wswitch = _switchweapon;
 665         player_pickedup = pickedup;
 666         MUTATOR_CALLHOOK(Item_GiveTo);
 667         _switchweapon = player_wswitch;
 668         pickedup = player_pickedup;
 669
 670         // always eat teamed entities
 671         if(item.team)
 672                 pickedup = TRUE;
 673
 674         if (!pickedup)
 675                 return 0;
 676
 677         if (_switchweapon)
 678                 if (player.switchweapon != w_getbestweapon(player))
 679                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 680
 681         return 1;
 682 }
 683
 684 void Item_Touch (void)
 685 {
 686         entity e, head;
 687
 688         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 689         if(self.classname == "droppedweapon")
 690         {
 691                 if (ITEM_TOUCH_NEEDKILL())
 692                 {
 693                         remove(self);
 694                         return;
 695                 }
 696         }
 697
 698         if (other.classname != "player")
 699                 return;
 700         if (other.deadflag)
 701                 return;
 702         if (self.solid != SOLID_TRIGGER)
 703                 return;
 704         if (self.owner == other)
 705                 return;
 706         if(MUTATOR_CALLHOOK(ItemTouch))
 707                 return;
 708
 709         if (self.classname == "droppedweapon")
 710         {
 711                 self.strength_finished = max(0, self.strength_finished - time);
 712                 self.invincible_finished = max(0, self.invincible_finished - time);
 713                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 714         }
 715
 716         if(!Item_GiveTo(self, other))
 717         {
 718                 if (self.classname == "droppedweapon")
 719                 {
 720                         // undo what we did above
 721                         self.strength_finished += time;
 722                         self.invincible_finished += time;
 723                         self.superweapons_finished += time;
 724                 }
 725                 return;
 726         }
 727
 728         other.last_pickup = time;
 729
 730         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 731         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 732
 733         if (self.classname == "droppedweapon")
 734                 remove (self);
 735         else if not(self.spawnshieldtime)
 736                 return;
 737         else
 738         {
 739                 if(self.team)
 740                 {
 741                         RandomSelection_Init();
 742                         for(head = world; (head = findfloat(head, team, self.team)); )
 743                         {
 744                                 if(head.flags & FL_ITEM)
 745                                 {
 746                                         Item_Show(head, -1);
 747                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 748                                 }
 749                         }
 750                         e = RandomSelection_chosen_ent;
 751
 752                 }
 753                 else
 754                         e = self;
 755                 Item_ScheduleRespawn(e);
 756         }
 757 }
 758
 759 void Item_Reset()
 760 {
 761         Item_Show(self, !self.state);
 762         setorigin (self, self.origin);
 763
 764         if(self.classname != "droppedweapon")
 765         {
 766                 self.think = func_null;
 767                 self.nextthink = 0;
 768
 769                 if(self.waypointsprite_attached)
 770                         WaypointSprite_Kill(self.waypointsprite_attached);
 771
 772                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 773                         Item_ScheduleInitialRespawn(self);
 774         }
 775 }
 776
 777 void Item_FindTeam()
 778 {
 779         entity head, e;
 780
 781         if(self.effects & EF_NODRAW)
 782         {
 783                 // marker for item team search
 784                 dprint("Initializing item team ", ftos(self.team), "\n");
 785                 RandomSelection_Init();
 786                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 787                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 788                 e = RandomSelection_chosen_ent;
 789                 e.state = 0;
 790                 Item_Show(e, 1);
 791
 792                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 793                 {
 794                         if(head != e)
 795                         {
 796                                 // make it a non-spawned item
 797                                 Item_Show(head, -1);
 798                                 head.state = 1; // state 1 = initially hidden item
 799                         }
 800                         head.effects &~= EF_NODRAW;
 801                 }
 802
 803                 Item_Reset();
 804         }
 805 }
 806
 807 // Savage: used for item garbage-collection
 808 // TODO: perhaps nice special effect?
 809 void RemoveItem(void)
 810 {
 811         remove(self);
 812 }
 813
 814 // pickup evaluation functions
 815 // these functions decide how desirable an item is to the bots
 816
 817 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 818
 819 float weapon_pickupevalfunc(entity player, entity item)
 820 {
 821         float c, j, position;
 822
 823         // See if I have it already
 824         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 825         {
 826                 // If I can pick it up
 827                 if(!item.spawnshieldtime)
 828                         c = 0;
 829                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 830                 {
 831                         // Skilled bots will grab more
 832                         c = bound(0, skill / 10, 1) * 0.5;
 833                 }
 834                 else
 835                         c = 0;
 836         }
 837         else
 838                 c = 1;
 839
 840         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 841         if( bot_custom_weapon && c )
 842         {
 843                 // Find the highest position on any range
 844                 position = -1;
 845                 for(j = 0; j < WEP_LAST ; ++j){
 846                         if(
 847                                         bot_weapons_far[j] == item.weapon ||
 848                                         bot_weapons_mid[j] == item.weapon ||
 849                                         bot_weapons_close[j] == item.weapon
 850                           )
 851                         {
 852                                 position = j;
 853                                 break;
 854                         }
 855                 }
 856
 857                 // Rate it
 858                 if (position >= 0 )
 859                 {
 860                         position = WEP_LAST - position;
 861                         // item.bot_pickupbasevalue is overwritten here
 862                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 863                 }
 864         }
 865
 866         return item.bot_pickupbasevalue * c;
 867 }
 868
 869 float commodity_pickupevalfunc(entity player, entity item)
 870 {
 871         float c, i;
 872         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 873         entity wi;
 874         c = 0;
 875
 876         // Detect needed ammo
 877         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 878         {
 879                 wi = get_weaponinfo(i);
 880
 881                 if not(WEPSET_CONTAINS_EW(player, i))
 882                         continue;
 883
 884                 if(wi.items & IT_SHELLS)
 885                         need_shells = TRUE;
 886                 else if(wi.items & IT_NAILS)
 887                         need_nails = TRUE;
 888                 else if(wi.items & IT_ROCKETS)
 889                         need_rockets = TRUE;
 890                 else if(wi.items & IT_CELLS)
 891                         need_cells = TRUE;
 892                 else if(wi.items & IT_FUEL)
 893                         need_cells = TRUE;
 894         }
 895
 896         // TODO: figure out if the player even has the weapon this ammo is for?
 897         // may not affect strategy much though...
 898         // find out how much more ammo/armor/health the player can hold
 899         if (need_shells)
 900         if (item.ammo_shells)
 901         if (player.ammo_shells < g_pickup_shells_max)
 902                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 903         if (need_nails)
 904         if (item.ammo_nails)
 905         if (player.ammo_nails < g_pickup_nails_max)
 906                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 907         if (need_rockets)
 908         if (item.ammo_rockets)
 909         if (player.ammo_rockets < g_pickup_rockets_max)
 910                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 911         if (need_cells)
 912         if (item.ammo_cells)
 913         if (player.ammo_cells < g_pickup_cells_max)
 914                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 915         if (need_fuel)
 916         if (item.ammo_fuel)
 917         if (player.ammo_fuel < g_pickup_fuel_max)
 918                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 919         if (item.armorvalue)
 920         if (player.armorvalue < item.max_armorvalue)
 921                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 922         if (item.health)
 923         if (player.health < item.max_health)
 924                 c = c + max(0, 1 - player.health / item.max_health);
 925
 926         return item.bot_pickupbasevalue * c;
 927 }
 928
 929 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 930 {
 931         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 932                 RemoveItem();
 933 }
 934
 935 .float is_item;
 936 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 937 {
 938         startitem_failed = FALSE;
 939
 940         if(self.model == "")
 941                 self.model = itemmodel;
 942
 943         if(self.model == "")
 944     {
 945         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 946         return;
 947     }
 948
 949         if(self.item_pickupsound == "")
 950                 self.item_pickupsound = pickupsound;
 951
 952         if(!self.respawntime) // both need to be set
 953         {
 954                 self.respawntime = defaultrespawntime;
 955                 self.respawntimejitter = defaultrespawntimejitter;
 956         }
 957
 958         self.items = itemid;
 959         self.weapon = weaponid;
 960
 961         if(weaponid)
 962                 WEPSET_COPY_EW(self, weaponid);
 963
 964         self.flags = FL_ITEM | itemflags;
 965
 966         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 967         {
 968                 startitem_failed = TRUE;
 969                 remove(self);
 970                 return;
 971         }
 972
 973         // is it a dropped weapon?
 974         if (self.classname == "droppedweapon")
 975         {
 976                 self.reset = SUB_Remove;
 977                 // it's a dropped weapon
 978                 self.movetype = MOVETYPE_TOSS;
 979
 980                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 981                 self.think = RemoveItem;
 982                 self.nextthink = time + 20;
 983
 984                 self.takedamage = DAMAGE_YES;
 985                 self.event_damage = Item_Damage;
 986
 987                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 988                 /*
 989                 if(self.items == 0)
 990                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 991                 if(self.ammo_nails == 0)
 992                 if(self.ammo_cells == 0)
 993                 if(self.ammo_rockets == 0)
 994                 if(self.ammo_shells == 0)
 995                 if(self.ammo_fuel == 0)
 996                 if(self.health == 0)
 997                 if(self.armorvalue == 0)
 998                 */
 999                 {
1000                         // if item is worthless after a timer, have it expire then
1001                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1002                 }
1003
1004                 // don't drop if in a NODROP zone (such as lava)
1005                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1006                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1007                 {
1008                         startitem_failed = TRUE;
1009                         remove(self);
1010                         return;
1011                 }
1012         }
1013         else
1014         {
1015                 if(!have_pickup_item())
1016                 {
1017                         startitem_failed = TRUE;
1018                         remove (self);
1019                         return;
1020                 }
1021
1022                 if(self.angles != '0 0 0')
1023             self.SendFlags |= ISF_ANGLES;
1024
1025                 self.reset = Item_Reset;
1026                 // it's a level item
1027                 if(self.spawnflags & 1)
1028                         self.noalign = 1;
1029                 if (self.noalign)
1030                         self.movetype = MOVETYPE_NONE;
1031                 else
1032                         self.movetype = MOVETYPE_TOSS;
1033                 // do item filtering according to game mode and other things
1034                 if (!self.noalign)
1035                 {
1036                         // first nudge it off the floor a little bit to avoid math errors
1037                         setorigin(self, self.origin + '0 0 1');
1038                         // set item size before we spawn a spawnfunc_waypoint
1039                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1040                                 setsize (self, '-16 -16 0', '16 16 48');
1041                         else
1042                                 setsize (self, '-16 -16 0', '16 16 32');
1043                         // note droptofloor returns FALSE if stuck/or would fall too far
1044                         droptofloor();
1045                         waypoint_spawnforitem(self);
1046                 }
1047
1048                 /*
1049                  * can't do it that way, as it would break maps
1050                  * TODO make a target_give like entity another way, that perhaps has
1051                  * the weapon name in a key
1052                 if(self.targetname)
1053                 {
1054                         // target_give not yet supported; maybe later
1055                         print("removed targeted ", self.classname, "\n");
1056                         startitem_failed = TRUE;
1057                         remove (self);
1058                         return;
1059                 }
1060                 */
1061
1062                 if(autocvar_spawn_debug >= 2)
1063                 {
1064                         entity otheritem;
1065                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1066                         {
1067                             // why not flags & fl_item?
1068                                 if(otheritem.is_item)
1069                                 {
1070                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1071                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1072                                         error("Mapper sucks.");
1073                                 }
1074                         }
1075                         self.is_item = TRUE;
1076                 }
1077
1078                 WEPSET_OR_AW(weaponsInMap, weaponid);
1079
1080                 precache_model (self.model);
1081                 precache_sound (self.item_pickupsound);
1082
1083                 precache_sound ("misc/itemrespawncountdown.wav");
1084                 if(itemid == IT_STRENGTH)
1085                         precache_sound ("misc/strength_respawn.wav");
1086                 else if(itemid == IT_INVINCIBLE)
1087                         precache_sound ("misc/shield_respawn.wav");
1088                 else
1089                         precache_sound ("misc/itemrespawn.wav");
1090
1091                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1092                         self.target = "###item###"; // for finding the nearest item using find()
1093         }
1094
1095         self.bot_pickup = TRUE;
1096         self.bot_pickupevalfunc = pickupevalfunc;
1097         self.bot_pickupbasevalue = pickupbasevalue;
1098         self.mdl = self.model;
1099         self.netname = itemname;
1100         self.touch = Item_Touch;
1101         setmodel(self, "null"); // precision set below
1102         //self.effects |= EF_LOWPRECISION;
1103
1104         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1105     {
1106         self.pos1 = '-16 -16 0';
1107         self.pos2 = '16 16 48';
1108     }
1109         else
1110     {
1111         self.pos1 = '-16 -16 0';
1112         self.pos2 = '16 16 32';
1113     }
1114     setsize (self, self.pos1, self.pos2);
1115
1116     if(itemflags & FL_POWERUP)
1117         self.ItemStatus |= ITS_ANIMATE1;
1118
1119         if(self.armorvalue || self.health)
1120         self.ItemStatus |= ITS_ANIMATE2;
1121
1122         if(itemflags & FL_WEAPON)
1123         {
1124                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1125             self.colormap = 1024; // color shirt=0 pants=0 grey
1126         else
1127             self.gravity = 1;
1128
1129                 self.ItemStatus |= ITS_ANIMATE1;
1130                 self.ItemStatus |= ISF_COLORMAP;
1131         }
1132
1133         self.state = 0;
1134         if(self.team) // broken, no idea why.
1135         {
1136                 if(!self.cnt)
1137                         self.cnt = 1; // item probability weight
1138
1139                 self.effects |= EF_NODRAW; // marker for item team search
1140                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1141         }
1142         else
1143                 Item_Reset();
1144
1145     Net_LinkEntity(self, FALSE, 0, ItemSend);
1146
1147         // call this hook after everything else has been done
1148         if(MUTATOR_CALLHOOK(Item_Spawn))
1149         {
1150                 startitem_failed = TRUE;
1151                 remove(self);
1152                 return;
1153         }
1154 }
1155
1156 float weaponswapping;
1157 float internalteam;
1158
1159 void weapon_defaultspawnfunc(float wpn)
1160 {
1161         entity e;
1162         float t;
1163         var .float ammofield;
1164         string s;
1165         entity oldself;
1166         float i, j;
1167         float f;
1168
1169         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1170         {
1171                 e = get_weaponinfo(wpn);
1172
1173                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1174                 {
1175                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1176                         /*
1177                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1178                         startitem_failed = TRUE;
1179                         return;
1180                         */
1181                 }
1182
1183                 s = W_Apply_Weaponreplace(e.netname);
1184                 ret_string = s;
1185                 other = e;
1186                 MUTATOR_CALLHOOK(SetWeaponreplace);
1187                 s = ret_string;
1188                 if(s == "")
1189                 {
1190                         remove(self);
1191                         startitem_failed = TRUE;
1192                         return;
1193                 }
1194                 t = tokenize_console(s);
1195                 if(t >= 2)
1196                 {
1197                         self.team = --internalteam;
1198                         oldself = self;
1199                         for(i = 1; i < t; ++i)
1200                         {
1201                                 s = argv(i);
1202                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1203                                 {
1204                                         e = get_weaponinfo(j);
1205                                         if(e.netname == s)
1206                                         {
1207                                                 self = spawn();
1208                                                 copyentity(oldself, self);
1209                                                 self.classname = "replacedweapon";
1210                                                 weapon_defaultspawnfunc(j);
1211                                                 break;
1212                                         }
1213                                 }
1214                                 if(j > WEP_LAST)
1215                                 {
1216                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1217                                 }
1218                         }
1219                         self = oldself;
1220                 }
1221                 if(t >= 1) // always the case!
1222                 {
1223                         s = argv(0);
1224                         wpn = 0;
1225                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1226                         {
1227                                 e = get_weaponinfo(j);
1228                                 if(e.netname == s)
1229                                 {
1230                                         wpn = j;
1231                                         break;
1232                                 }
1233                         }
1234                         if(j > WEP_LAST)
1235                         {
1236                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1237                         }
1238                 }
1239                 if(wpn == 0)
1240                 {
1241                         remove(self);
1242                         startitem_failed = TRUE;
1243                         return;
1244                 }
1245         }
1246
1247         e = get_weaponinfo(wpn);
1248
1249         if(!self.respawntime)
1250         {
1251                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1252                 {
1253                         self.respawntime = g_pickup_respawntime_superweapon;
1254                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1255                 }
1256                 else
1257                 {
1258                         self.respawntime = g_pickup_respawntime_weapon;
1259                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1260                 }
1261         }
1262
1263         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1264                 if(!self.superweapons_finished)
1265                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1266
1267         if(e.items)
1268         {
1269                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1270                 {
1271                         if(e.items & j)
1272                         {
1273                                 ammofield = Item_CounterField(j);
1274                                 if(!self.ammofield)
1275                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1276                         }
1277                 }
1278         }
1279
1280         // pickup anyway
1281         if(g_pickup_weapons_anyway)
1282                 self.pickup_anyway = TRUE;
1283
1284         f = FL_WEAPON;
1285
1286         // no weapon-stay on superweapons
1287         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1288                 f |= FL_NO_WEAPON_STAY;
1289
1290         // weapon stay isn't supported for teamed weapons
1291         if(self.team)
1292                 f |= FL_NO_WEAPON_STAY;
1293
1294         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1295         if (self.modelindex) // don't precache if self was removed
1296                 weapon_action(e.weapon, WR_PRECACHE);
1297 }
1298
1299 void spawnfunc_weapon_shotgun (void);
1300 void spawnfunc_weapon_uzi (void) {
1301         if(autocvar_sv_q3acompat_machineshotgunswap)
1302         if(self.classname != "droppedweapon")
1303         {
1304                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1305                 return;
1306         }
1307         weapon_defaultspawnfunc(WEP_UZI);
1308 }
1309
1310 void spawnfunc_weapon_shotgun (void) {
1311         if(autocvar_sv_q3acompat_machineshotgunswap)
1312         if(self.classname != "droppedweapon")
1313         {
1314                 weapon_defaultspawnfunc(WEP_UZI);
1315                 return;
1316         }
1317         weapon_defaultspawnfunc(WEP_SHOTGUN);
1318 }
1319
1320 void spawnfunc_weapon_nex (void)
1321 {
1322         weapon_defaultspawnfunc(WEP_NEX);
1323 }
1324
1325 void spawnfunc_weapon_minstanex (void)
1326 {
1327         weapon_defaultspawnfunc(WEP_MINSTANEX);
1328 }
1329
1330 void spawnfunc_weapon_rocketlauncher (void)
1331 {
1332         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1333 }
1334
1335 void spawnfunc_item_rockets (void) {
1336         if(!self.ammo_rockets)
1337                 self.ammo_rockets = g_pickup_rockets;
1338         if(!self.pickup_anyway)
1339                 self.pickup_anyway = g_pickup_ammo_anyway;
1340         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1341 }
1342
1343 void spawnfunc_item_shells (void);
1344 void spawnfunc_item_bullets (void) {
1345         if(!weaponswapping)
1346         if(autocvar_sv_q3acompat_machineshotgunswap)
1347         if(self.classname != "droppedweapon")
1348         {
1349                 weaponswapping = TRUE;
1350                 spawnfunc_item_shells();
1351                 weaponswapping = FALSE;
1352                 return;
1353         }
1354
1355         if(!self.ammo_nails)
1356                 self.ammo_nails = g_pickup_nails;
1357         if(!self.pickup_anyway)
1358                 self.pickup_anyway = g_pickup_ammo_anyway;
1359         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1360 }
1361
1362 void spawnfunc_item_cells (void) {
1363         if(!self.ammo_cells)
1364                 self.ammo_cells = g_pickup_cells;
1365         if(!self.pickup_anyway)
1366                 self.pickup_anyway = g_pickup_ammo_anyway;
1367         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1368 }
1369
1370 void spawnfunc_item_shells (void) {
1371         if(!weaponswapping)
1372         if(autocvar_sv_q3acompat_machineshotgunswap)
1373         if(self.classname != "droppedweapon")
1374         {
1375                 weaponswapping = TRUE;
1376                 spawnfunc_item_bullets();
1377                 weaponswapping = FALSE;
1378                 return;
1379         }
1380
1381         if(!self.ammo_shells)
1382                 self.ammo_shells = g_pickup_shells;
1383         if(!self.pickup_anyway)
1384                 self.pickup_anyway = g_pickup_ammo_anyway;
1385         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1386 }
1387
1388 void spawnfunc_item_armor_small (void) {
1389         if(!self.armorvalue)
1390                 self.armorvalue = g_pickup_armorsmall;
1391         if(!self.max_armorvalue)
1392                 self.max_armorvalue = g_pickup_armorsmall_max;
1393         if(!self.pickup_anyway)
1394                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1395         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1396 }
1397
1398 void spawnfunc_item_armor_medium (void) {
1399         if(!self.armorvalue)
1400                 self.armorvalue = g_pickup_armormedium;
1401         if(!self.max_armorvalue)
1402                 self.max_armorvalue = g_pickup_armormedium_max;
1403         if(!self.pickup_anyway)
1404                 self.pickup_anyway = g_pickup_armormedium_anyway;
1405         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1406 }
1407
1408 void spawnfunc_item_armor_big (void) {
1409         if(!self.armorvalue)
1410                 self.armorvalue = g_pickup_armorbig;
1411         if(!self.max_armorvalue)
1412                 self.max_armorvalue = g_pickup_armorbig_max;
1413         if(!self.pickup_anyway)
1414                 self.pickup_anyway = g_pickup_armorbig_anyway;
1415         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1416 }
1417
1418 void spawnfunc_item_armor_large (void) {
1419         if(!self.armorvalue)
1420                 self.armorvalue = g_pickup_armorlarge;
1421         if(!self.max_armorvalue)
1422                 self.max_armorvalue = g_pickup_armorlarge_max;
1423         if(!self.pickup_anyway)
1424                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1425         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1426 }
1427
1428 void spawnfunc_item_health_small (void) {
1429         if(!self.max_health)
1430                 self.max_health = g_pickup_healthsmall_max;
1431         if(!self.health)
1432                 self.health = g_pickup_healthsmall;
1433         if(!self.pickup_anyway)
1434                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1435         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1436 }
1437
1438 void spawnfunc_item_health_medium (void) {
1439         if(!self.max_health)
1440                 self.max_health = g_pickup_healthmedium_max;
1441         if(!self.health)
1442                 self.health = g_pickup_healthmedium;
1443         if(!self.pickup_anyway)
1444                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1445         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1446 }
1447
1448 void spawnfunc_item_health_large (void) {
1449         if(!self.max_health)
1450                 self.max_health = g_pickup_healthlarge_max;
1451         if(!self.health)
1452                 self.health = g_pickup_healthlarge;
1453         if(!self.pickup_anyway)
1454                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1455         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1456 }
1457
1458 void spawnfunc_item_health_mega (void) {
1459                 if(!self.max_health)
1460                         self.max_health = g_pickup_healthmega_max;
1461                 if(!self.health)
1462                         self.health = g_pickup_healthmega;
1463                 if(!self.pickup_anyway)
1464                         self.pickup_anyway = g_pickup_healthmega_anyway;
1465                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1466 }
1467
1468 // support old misnamed entities
1469 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1470 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1471 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1472 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1473 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1474
1475 void spawnfunc_item_strength (void) {
1476                 precache_sound("weapons/strength_fire.wav");
1477                 if(!self.strength_finished)
1478                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1479                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1480 }
1481
1482 void spawnfunc_item_invincible (void) {
1483                 if(!self.invincible_finished)
1484                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1485                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1486 }
1487
1488 // compatibility:
1489 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1490
1491 float GiveItems(entity e, float beginarg, float endarg);
1492 void target_items_use (void)
1493 {
1494         if(activator.classname == "droppedweapon")
1495         {
1496                 EXACTTRIGGER_TOUCH;
1497                 remove(activator);
1498                 return;
1499         }
1500
1501         if(activator.classname != "player")
1502                 return;
1503         if(activator.deadflag != DEAD_NO)
1504                 return;
1505         EXACTTRIGGER_TOUCH;
1506
1507         entity e;
1508         for(e = world; (e = find(e, classname, "droppedweapon")); )
1509                 if(e.enemy == activator)
1510                         remove(e);
1511
1512         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1513                 centerprint(activator, self.message);
1514 }
1515
1516 void spawnfunc_target_items (void)
1517 {
1518         float n, i, j;
1519         entity e;
1520
1521         self.use = target_items_use;
1522         if(!self.strength_finished)
1523                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1524         if(!self.invincible_finished)
1525                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1526         if(!self.superweapons_finished)
1527                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1528
1529         precache_sound("misc/itempickup.wav");
1530         precache_sound("misc/megahealth.wav");
1531         precache_sound("misc/armor25.wav");
1532         precache_sound("misc/powerup.wav");
1533         precache_sound("misc/poweroff.wav");
1534         precache_sound("weapons/weaponpickup.wav");
1535
1536         n = tokenize_console(self.netname);
1537         if(argv(0) == "give")
1538         {
1539                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1540         }
1541         else
1542         {
1543                 for(i = 0; i < n; ++i)
1544                 {
1545                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1546                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1547                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1548                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1549                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1550                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1551                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1552                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1553                         else
1554                         {
1555                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1556                                 {
1557                                         e = get_weaponinfo(j);
1558                                         if(argv(i) == e.netname)
1559                                         {
1560                                                 WEPSET_OR_EW(self, j);
1561                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1562                                                         weapon_action(e.weapon, WR_PRECACHE);
1563                                                 break;
1564                                         }
1565                                 }
1566                                 if(j > WEP_LAST)
1567                                         print("target_items: invalid item ", argv(i), "\n");
1568                         }
1569                 }
1570
1571                 string itemprefix, valueprefix;
1572                 if(self.spawnflags == 0)
1573                 {
1574                         itemprefix = "";
1575                         valueprefix = "";
1576                 }
1577                 else if(self.spawnflags == 1)
1578                 {
1579                         itemprefix = "max ";
1580                         valueprefix = "max ";
1581                 }
1582                 else if(self.spawnflags == 2)
1583                 {
1584                         itemprefix = "min ";
1585                         valueprefix = "min ";
1586                 }
1587                 else if(self.spawnflags == 4)
1588                 {
1589                         itemprefix = "minus ";
1590                         valueprefix = "max ";
1591                 }
1592                 else
1593                 {
1594                         error("invalid spawnflags");
1595 #ifdef GMQCC
1596                         itemprefix = string_null;
1597                         valueprefix = string_null;
1598 #endif
1599                 }
1600
1601                 self.netname = "";
1602                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1603                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1604                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1605                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1606                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1607                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1608                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1609                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1610                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1611                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1612                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1613                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1614                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1615                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1616                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1617                 {
1618                         e = get_weaponinfo(j);
1619                         if(e.weapon)
1620                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1621                 }
1622         }
1623         self.netname = strzone(self.netname);
1624         //print(self.netname, "\n");
1625
1626         n = tokenize_console(self.netname);
1627         for(i = 0; i < n; ++i)
1628         {
1629                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1630                 {
1631                         e = get_weaponinfo(j);
1632                         if(argv(i) == e.netname)
1633                         {
1634                                 weapon_action(e.weapon, WR_PRECACHE);
1635                                 break;
1636                         }
1637                 }
1638         }
1639 }
1640
1641 void spawnfunc_item_fuel(void)
1642 {
1643         if(!self.ammo_fuel)
1644                 self.ammo_fuel = g_pickup_fuel;
1645         if(!self.pickup_anyway)
1646                 self.pickup_anyway = g_pickup_ammo_anyway;
1647         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1648 }
1649
1650 void spawnfunc_item_fuel_regen(void)
1651 {
1652         if(start_items & IT_FUEL_REGEN)
1653         {
1654                 spawnfunc_item_fuel();
1655                 return;
1656         }
1657         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1658 }
1659
1660 void spawnfunc_item_jetpack(void)
1661 {
1662         if(g_grappling_hook)
1663                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1664         if(!self.ammo_fuel)
1665                 self.ammo_fuel = g_pickup_fuel_jetpack;
1666         if(start_items & IT_JETPACK)
1667         {
1668                 spawnfunc_item_fuel();
1669                 return;
1670         }
1671         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1672 }
1673
1674
1675 #define OP_SET 0
1676 #define OP_MIN 1
1677 #define OP_MAX 2
1678 #define OP_PLUS 3
1679 #define OP_MINUS 4
1680
1681 float GiveWeapon(entity e, float wpn, float op, float val)
1682 {
1683         float v0, v1;
1684         v0 = WEPSET_CONTAINS_EW(e, wpn);
1685         switch(op)
1686         {
1687                 case OP_SET:
1688                         if(val > 0)
1689                                 WEPSET_OR_EW(e, wpn);
1690                         else
1691                                 WEPSET_ANDNOT_EW(e, wpn);
1692                         break;
1693                 case OP_MIN:
1694                 case OP_PLUS:
1695                         if(val > 0)
1696                                 WEPSET_OR_EW(e, wpn);
1697                         break;
1698                 case OP_MAX:
1699                         if(val <= 0)
1700                                 WEPSET_ANDNOT_EW(e, wpn);
1701                         break;
1702                 case OP_MINUS:
1703                         if(val > 0)
1704                                 WEPSET_ANDNOT_EW(e, wpn);
1705                         break;
1706         }
1707         v1 = WEPSET_CONTAINS_EW(e, wpn);
1708         return (v0 != v1);
1709 }
1710
1711 float GiveBit(entity e, .float fld, float bit, float op, float val)
1712 {
1713         float v0, v1;
1714         v0 = (e.fld & bit);
1715         switch(op)
1716         {
1717                 case OP_SET:
1718                         if(val > 0)
1719                                 e.fld |= bit;
1720                         else
1721                                 e.fld &~= bit;
1722                         break;
1723                 case OP_MIN:
1724                 case OP_PLUS:
1725                         if(val > 0)
1726                                 e.fld |= bit;
1727                         break;
1728                 case OP_MAX:
1729                         if(val <= 0)
1730                                 e.fld &~= bit;
1731                         break;
1732                 case OP_MINUS:
1733                         if(val > 0)
1734                                 e.fld &~= bit;
1735                         break;
1736         }
1737         v1 = (e.fld & bit);
1738         return (v0 != v1);
1739 }
1740
1741 float GiveValue(entity e, .float fld, float op, float val)
1742 {
1743         float v0, v1;
1744         v0 = e.fld;
1745         switch(op)
1746         {
1747                 case OP_SET:
1748                         e.fld = val;
1749                         break;
1750                 case OP_MIN:
1751                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1752                         break;
1753                 case OP_MAX:
1754                         e.fld = min(e.fld, val);
1755                         break;
1756                 case OP_PLUS:
1757                         e.fld += val;
1758                         break;
1759                 case OP_MINUS:
1760                         e.fld -= val;
1761                         break;
1762         }
1763         v1 = e.fld;
1764         return (v0 != v1);
1765 }
1766
1767 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1768 {
1769         if(v1 == v0)
1770                 return;
1771         if(v1 <= v0 - t)
1772         {
1773                 if(snd_decr != "")
1774                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1775         }
1776         else if(v0 >= v0 + t)
1777         {
1778                 if(snd_incr != "")
1779                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1780         }
1781 }
1782
1783 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1784 {
1785         if(v0 < v1)
1786                 e.rotfield = max(e.rotfield, time + rottime);
1787         else if(v0 > v1)
1788                 e.regenfield = max(e.regenfield, time + regentime);
1789 }
1790
1791 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1792 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1793 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1794 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1795 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1796 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1797
1798 float GiveItems(entity e, float beginarg, float endarg)
1799 {
1800         float got, i, j, val, op;
1801         float _switchweapon;
1802         entity wi;
1803         string cmd;
1804
1805         val = 999;
1806         op = OP_SET;
1807
1808         got = 0;
1809
1810         _switchweapon = FALSE;
1811         if (e.autoswitch)
1812                 if (e.switchweapon == w_getbestweapon(e))
1813                         _switchweapon = TRUE;
1814
1815         e.strength_finished = max(0, e.strength_finished - time);
1816         e.invincible_finished = max(0, e.invincible_finished - time);
1817         e.superweapons_finished = max(0, e.superweapons_finished - time);
1818
1819         PREGIVE(e, items);
1820         PREGIVE_WEAPONS(e);
1821         PREGIVE(e, strength_finished);
1822         PREGIVE(e, invincible_finished);
1823         PREGIVE(e, superweapons_finished);
1824         PREGIVE(e, ammo_nails);
1825         PREGIVE(e, ammo_cells);
1826         PREGIVE(e, ammo_shells);
1827         PREGIVE(e, ammo_rockets);
1828         PREGIVE(e, ammo_fuel);
1829         PREGIVE(e, armorvalue);
1830         PREGIVE(e, health);
1831
1832         for(i = beginarg; i < endarg; ++i)
1833         {
1834                 cmd = argv(i);
1835
1836                 if(cmd == "0" || stof(cmd))
1837                 {
1838                         val = stof(cmd);
1839                         continue;
1840                 }
1841                 switch(cmd)
1842                 {
1843                         case "no":
1844                                 op = OP_MAX;
1845                                 val = 0;
1846                                 continue;
1847                         case "max":
1848                                 op = OP_MAX;
1849                                 continue;
1850                         case "min":
1851                                 op = OP_MIN;
1852                                 continue;
1853                         case "plus":
1854                                 op = OP_PLUS;
1855                                 continue;
1856                         case "minus":
1857                                 op = OP_MINUS;
1858                                 continue;
1859                         case "ALL":
1860                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1861                                 got += GiveValue(e, strength_finished, op, val);
1862                                 got += GiveValue(e, invincible_finished, op, val);
1863                                 got += GiveValue(e, superweapons_finished, op, val);
1864                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1865                         case "all":
1866                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1867                                 got += GiveValue(e, health, op, val);
1868                                 got += GiveValue(e, armorvalue, op, val);
1869                         case "allweapons":
1870                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1871                                 {
1872                                         wi = get_weaponinfo(j);
1873                                         if(wi.weapon)
1874                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1875                                                         got += GiveWeapon(e, j, op, val);
1876                                 }
1877                         case "allammo":
1878                                 got += GiveValue(e, ammo_cells, op, val);
1879                                 got += GiveValue(e, ammo_shells, op, val);
1880                                 got += GiveValue(e, ammo_nails, op, val);
1881                                 got += GiveValue(e, ammo_rockets, op, val);
1882                                 got += GiveValue(e, ammo_fuel, op, val);
1883                                 break;
1884                         case "unlimited_ammo":
1885                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1886                                 break;
1887                         case "unlimited_weapon_ammo":
1888                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1889                                 break;
1890                         case "unlimited_superweapons":
1891                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1892                                 break;
1893                         case "jetpack":
1894                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1895                                 break;
1896                         case "fuel_regen":
1897                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1898                                 break;
1899                         case "strength":
1900                                 got += GiveValue(e, strength_finished, op, val);
1901                                 break;
1902                         case "invincible":
1903                                 got += GiveValue(e, invincible_finished, op, val);
1904                                 break;
1905                         case "superweapons":
1906                                 got += GiveValue(e, superweapons_finished, op, val);
1907                                 break;
1908                         case "cells":
1909                                 got += GiveValue(e, ammo_cells, op, val);
1910                                 break;
1911                         case "shells":
1912                                 got += GiveValue(e, ammo_shells, op, val);
1913                                 break;
1914                         case "nails":
1915                         case "bullets":
1916                                 got += GiveValue(e, ammo_nails, op, val);
1917                                 break;
1918                         case "rockets":
1919                                 got += GiveValue(e, ammo_rockets, op, val);
1920                                 break;
1921                         case "health":
1922                                 got += GiveValue(e, health, op, val);
1923                                 break;
1924                         case "armor":
1925                                 got += GiveValue(e, armorvalue, op, val);
1926                                 break;
1927                         case "fuel":
1928                                 got += GiveValue(e, ammo_fuel, op, val);
1929                                 break;
1930                         default:
1931                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1932                                 {
1933                                         wi = get_weaponinfo(j);
1934                                         if(cmd == wi.netname)
1935                                         {
1936                                                 got += GiveWeapon(e, j, op, val);
1937                                                 break;
1938                                         }
1939                                 }
1940                                 if(j > WEP_LAST)
1941                                         print("give: invalid item ", cmd, "\n");
1942                                 break;
1943                 }
1944                 val = 999;
1945                 op = OP_SET;
1946         }
1947
1948         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1949         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1950         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1951         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1952         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1953         {
1954                 wi = get_weaponinfo(j);
1955                 if(wi.weapon)
1956                 {
1957                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1958                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1959                                 if(WEPSET_CONTAINS_EW(e, j))
1960                                         weapon_action(wi.weapon, WR_PRECACHE);
1961                 }
1962         }
1963         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1964         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1965         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1966         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1967         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1968         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1969         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1970         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1971         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1972
1973         if(e.superweapons_finished <= 0)
1974                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1975                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1976
1977         if(e.strength_finished <= 0)
1978                 e.strength_finished = 0;
1979         else
1980                 e.strength_finished += time;
1981         if(e.invincible_finished <= 0)
1982                 e.invincible_finished = 0;
1983         else
1984                 e.invincible_finished += time;
1985         if(e.superweapons_finished <= 0)
1986                 e.superweapons_finished = 0;
1987         else
1988                 e.superweapons_finished += time;
1989
1990         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1991                 _switchweapon = TRUE;
1992         if(_switchweapon)
1993                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1994
1995         return got;
1996 }
1997 #endif