qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         // minstagib: only allow filtered items
 275         if(g_minstagib)
 276                 if(self.classname != "minstagib")
 277                         return FALSE;
 278
 279         if(self.flags & FL_POWERUP)
 280         {
 281                 if(autocvar_g_powerups > 0)
 282                         return TRUE;
 283                 if(autocvar_g_powerups == 0)
 284                         return FALSE;
 285                 if(g_lms)
 286                         return FALSE;
 287                 if(g_ca)
 288                         return FALSE;
 289                 if(g_arena)
 290                         return FALSE;
 291         }
 292         else
 293         {
 294                 if(autocvar_g_pickup_items > 0)
 295                         return TRUE;
 296                 if(autocvar_g_pickup_items == 0)
 297                         return FALSE;
 298                 if(g_lms)
 299                         return FALSE;
 300                 if(g_ca)
 301                         return FALSE;
 302                 if(g_weaponarena)
 303                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 304                                 return FALSE;
 305         }
 306         return TRUE;
 307 }
 308
 309 #define ITEM_RESPAWN_TICKS 10
 310
 311 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 312         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 313 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 314         // range: 10 .. respawntime + respawntimejitter
 315
 316 floatfield Item_CounterField(float it)
 317 {
 318         switch(it)
 319         {
 320                 case IT_SHELLS:      return ammo_shells;
 321                 case IT_NAILS:       return ammo_nails;
 322                 case IT_ROCKETS:     return ammo_rockets;
 323                 case IT_CELLS:       return ammo_cells;
 324                 case IT_FUEL:        return ammo_fuel;
 325                 case IT_5HP:         return health;
 326                 case IT_25HP:        return health;
 327                 case IT_HEALTH:      return health;
 328                 case IT_ARMOR_SHARD: return armorvalue;
 329                 case IT_ARMOR:       return armorvalue;
 330                 // add more things here (health, armor)
 331                 default:             error("requested item has no counter field");
 332         }
 333 }
 334
 335 string Item_CounterFieldName(float it)
 336 {
 337         switch(it)
 338         {
 339                 case IT_SHELLS:      return "shells";
 340                 case IT_NAILS:       return "nails";
 341                 case IT_ROCKETS:     return "rockets";
 342                 case IT_CELLS:       return "cells";
 343                 case IT_FUEL:        return "fuel";
 344
 345                 // add more things here (health, armor)
 346                 default:             error("requested item has no counter field name");
 347         }
 348 }
 349
 350 .float max_armorvalue;
 351 .float pickup_anyway;
 352 /*
 353 float Item_Customize()
 354 {
 355         if(self.spawnshieldtime)
 356                 return TRUE;
 357         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 358         {
 359                 self.colormod = '0 0 0';
 360                 self.glowmod = self.colormod;
 361                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 362                 return TRUE;
 363         }
 364         else
 365         {
 366                 if(g_ghost_items)
 367                 {
 368                         self.colormod = stov(autocvar_g_ghost_items_color);
 369                         self.glowmod = self.colormod;
 370                         self.alpha = g_ghost_items;
 371                         return TRUE;
 372                 }
 373                 else
 374                         return FALSE;
 375         }
 376 }
 377 */
 378
 379 void Item_Show (entity e, float mode)
 380 {
 381         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 382         e.ItemStatus &~= ITS_STAYWEP;
 383         if (mode > 0)
 384         {
 385                 // make the item look normal, and be touchable
 386                 e.model = e.mdl;
 387                 e.solid = SOLID_TRIGGER;
 388                 e.spawnshieldtime = 1;
 389                 e.ItemStatus |= ITS_AVAILABLE;
 390         }
 391         else if (mode < 0)
 392         {
 393                 // hide the item completely
 394                 e.model = string_null;
 395                 e.solid = SOLID_NOT;
 396                 e.spawnshieldtime = 1;
 397                 e.ItemStatus &~= ITS_AVAILABLE;
 398         }
 399         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 400         {
 401                 // make the item translucent and not touchable
 402                 e.model = e.mdl;
 403                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 404                 e.effects |= EF_STARDUST;
 405                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 406                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 407         }
 408         else
 409         {
 410                 //setmodel(e, "null");
 411                 e.solid = SOLID_NOT;
 412                 e.colormod = '0 0 0';
 413                 e.glowmod = e.colormod;
 414                 e.spawnshieldtime = 1;
 415                 e.ItemStatus &~= ITS_AVAILABLE;
 416         }
 417
 418         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 419             e.ItemStatus |= ITS_POWERUP;
 420
 421         if (autocvar_g_nodepthtestitems)
 422                 e.effects |= EF_NODEPTHTEST;
 423
 424
 425     if (autocvar_g_fullbrightitems)
 426                 e.ItemStatus |= ITS_ALLOWFB;
 427
 428         if (autocvar_sv_simple_items)
 429         e.ItemStatus |= ITS_ALLOWSI;
 430
 431         // relink entity (because solid may have changed)
 432         setorigin(e, e.origin);
 433     e.SendFlags |= ISF_STATUS;
 434 }
 435
 436 void Item_Respawn (void)
 437 {
 438         Item_Show(self, 1);
 439         if(!g_minstagib && self.items == IT_STRENGTH)
 440                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 441         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 442                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 443         else
 444                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 445         setorigin (self, self.origin);
 446
 447         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 448         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 449 }
 450
 451 void Item_RespawnCountdown (void)
 452 {
 453         if(self.count >= ITEM_RESPAWN_TICKS)
 454         {
 455                 if(self.waypointsprite_attached)
 456                         WaypointSprite_Kill(self.waypointsprite_attached);
 457                 Item_Respawn();
 458         }
 459         else
 460         {
 461                 self.nextthink = time + 1;
 462                 self.count += 1;
 463                 if(self.count == 1)
 464                 {
 465                         string name;
 466                         vector rgb = '1 0 1';
 467                         name = string_null;
 468                         if(g_minstagib)
 469                         {
 470                                 switch(self.items)
 471                                 {
 472                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 473                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 474                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 475                                 }
 476                         }
 477                         else
 478                         {
 479                                 switch(self.items)
 480                                 {
 481                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 482                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 483                                 }
 484                         }
 485                         switch(self.items)
 486                         {
 487                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 488                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 489                         }
 490                         if(self.flags & FL_WEAPON)
 491                         {
 492                                 entity wi = get_weaponinfo(self.weapon);
 493                                 if(wi)
 494                                 {
 495                                         name = wi.model2;
 496                                         rgb = '1 0 0';
 497                                 }
 498                         }
 499                         if(!name)
 500                         {
 501                                 print("Unknown powerup-marked item is wanting to respawn\n");
 502                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 503                         }
 504                         if(name)
 505                         {
 506                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 507                                 if(self.waypointsprite_attached)
 508                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 509                         }
 510                 }
 511                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 512                 if(self.waypointsprite_attached)
 513                 {
 514                         WaypointSprite_Ping(self.waypointsprite_attached);
 515                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 516                 }
 517         }
 518 }
 519
 520 void Item_ScheduleRespawnIn(entity e, float t)
 521 {
 522         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 523         {
 524                 e.think = Item_RespawnCountdown;
 525                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 526                 e.count = 0;
 527         }
 528         else
 529         {
 530                 e.think = Item_Respawn;
 531                 e.nextthink = time + t;
 532         }
 533 }
 534
 535 void Item_ScheduleRespawn(entity e)
 536 {
 537         if(e.respawntime > 0)
 538         {
 539                 Item_Show(e, 0);
 540                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 541         }
 542         else // if respawntime is -1, this item does not respawn
 543                 Item_Show(e, -1);
 544 }
 545
 546 void Item_ScheduleInitialRespawn(entity e)
 547 {
 548         Item_Show(e, 0);
 549         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 550 }
 551
 552 float ITEM_MODE_NONE = 0;
 553 float ITEM_MODE_HEALTH = 1;
 554 float ITEM_MODE_ARMOR = 2;
 555 float ITEM_MODE_FUEL = 3;
 556 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 557 {
 558         if (!item.ammofield)
 559                 return FALSE;
 560
 561         if (item.spawnshieldtime)
 562         {
 563                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 564                 {
 565                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 566                         goto YEAH;
 567                 }
 568         }
 569         else if(g_weapon_stay == 2)
 570         {
 571                 float mi = min(item.ammofield, ammomax);
 572                 if (player.ammofield < mi)
 573                 {
 574                         player.ammofield = mi;
 575                         goto YEAH;
 576                 }
 577         }
 578
 579         return FALSE;
 580
 581 :YEAH
 582         switch(mode)
 583         {
 584                 case ITEM_MODE_FUEL:
 585                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 586                         break;
 587                 case ITEM_MODE_HEALTH:
 588                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 589                         break;
 590                 case ITEM_MODE_ARMOR:
 591                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 592                         break;
 593                 default:
 594                         break;
 595         }
 596         return TRUE;
 597 }
 598
 599 float Item_GiveTo(entity item, entity player)
 600 {
 601         float _switchweapon;
 602         float pickedup;
 603         float it;
 604         float i;
 605
 606         // if nothing happens to player, just return without taking the item
 607         pickedup = FALSE;
 608         _switchweapon = FALSE;
 609
 610         if (g_minstagib)
 611         {
 612                 float prevcells = player.ammo_cells;
 613
 614                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 615                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 616
 617                 if(player.ammo_cells > prevcells)
 618                 {
 619                         _switchweapon = TRUE;
 620
 621                         // play some cool sounds ;)
 622                         if (clienttype(player) == CLIENTTYPE_REAL)
 623                         {
 624                                 if(player.health <= 5)
 625                                         AnnounceTo(player, "lastsecond");
 626                                 else if(player.health < 50)
 627                                         AnnounceTo(player, "narrowly");
 628                         }
 629                         // sound not available
 630                         // else if(item.items == IT_CELLS)
 631                         //      AnnounceTo(player, "ammo");
 632
 633                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 634                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 635                         player.health = 100;
 636                 }
 637
 638                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 639                 {
 640                         pickedup = TRUE;
 641                         player.items |= it;
 642                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 643                 }
 644
 645                 // extralife powerup
 646                 if (item.max_health)
 647                 {
 648                         pickedup = TRUE;
 649                         // sound not available
 650                         // AnnounceTo(player, "_lives");
 651                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 652                         sprint(player, "^3You picked up some extra lives\n");
 653                 }
 654
 655                 // invis powerup
 656                 if (item.strength_finished)
 657                 {
 658                         pickedup = TRUE;
 659                         // sound not available
 660                         // AnnounceTo(player, "invisible");
 661                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 662                 }
 663
 664                 // speed powerup
 665                 if (item.invincible_finished)
 666                 {
 667                         pickedup = TRUE;
 668                         // sound not available
 669                         // AnnounceTo(player, "speed");
 670                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 671                 }
 672         }
 673         else
 674         {
 675                 // in case the player has autoswitch enabled do the following:
 676                 // if the player is using their best weapon before items are given, they
 677                 // probably want to switch to an even better weapon after items are given
 678                 if (player.autoswitch)
 679                 if (player.switchweapon == w_getbestweapon(player))
 680                         _switchweapon = TRUE;
 681
 682                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 683                         _switchweapon = TRUE;
 684
 685                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 686                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 687                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 688                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 689                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 690                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 691                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 692
 693                 if (item.flags & FL_WEAPON)
 694                 {
 695                         WEPSET_DECLARE_A(it);
 696                         WEPSET_COPY_AE(it, item);
 697                         WEPSET_ANDNOT_AE(it, player);
 698
 699                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 700                         {
 701                                 pickedup = TRUE;
 702                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 703                                         if(WEPSET_CONTAINS_AW(it, i))
 704                                                 W_GiveWeapon (player, i, item.netname);
 705                         }
 706                 }
 707
 708                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 709                 {
 710                         pickedup = TRUE;
 711                         player.items |= it;
 712                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 713                 }
 714
 715                 if (item.strength_finished)
 716                 {
 717                         pickedup = TRUE;
 718                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 719                 }
 720                 if (item.invincible_finished)
 721                 {
 722                         pickedup = TRUE;
 723                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 724                 }
 725                 if (item.superweapons_finished)
 726                 {
 727                         pickedup = TRUE;
 728                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 729                 }
 730         }
 731
 732 :skip
 733         // always eat teamed entities
 734         if(item.team)
 735                 pickedup = TRUE;
 736
 737         if (!pickedup)
 738                 return 0;
 739
 740         if (_switchweapon)
 741                 if (player.switchweapon != w_getbestweapon(player))
 742                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 743
 744         return 1;
 745 }
 746
 747 void Item_Touch (void)
 748 {
 749         entity e, head;
 750
 751         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 752         if(self.classname == "droppedweapon")
 753         {
 754                 if (ITEM_TOUCH_NEEDKILL())
 755                 {
 756                         remove(self);
 757                         return;
 758                 }
 759         }
 760
 761         if (other.classname != "player")
 762                 return;
 763         if (other.deadflag)
 764                 return;
 765         if (self.solid != SOLID_TRIGGER)
 766                 return;
 767         if (self.owner == other)
 768                 return;
 769         if(MUTATOR_CALLHOOK(ItemTouch))
 770                 return;
 771
 772         if (self.classname == "droppedweapon")
 773         {
 774                 self.strength_finished = max(0, self.strength_finished - time);
 775                 self.invincible_finished = max(0, self.invincible_finished - time);
 776                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 777         }
 778
 779         if(!Item_GiveTo(self, other))
 780         {
 781                 if (self.classname == "droppedweapon")
 782                 {
 783                         // undo what we did above
 784                         self.strength_finished += time;
 785                         self.invincible_finished += time;
 786                         self.superweapons_finished += time;
 787                 }
 788                 return;
 789         }
 790
 791         other.last_pickup = time;
 792
 793         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 794         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 795
 796         if (self.classname == "droppedweapon")
 797                 remove (self);
 798         else if not(self.spawnshieldtime)
 799                 return;
 800         else
 801         {
 802                 if(self.team)
 803                 {
 804                         RandomSelection_Init();
 805                         for(head = world; (head = findfloat(head, team, self.team)); )
 806                         {
 807                                 if(head.flags & FL_ITEM)
 808                                 {
 809                                         Item_Show(head, -1);
 810                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 811                                 }
 812                         }
 813                         e = RandomSelection_chosen_ent;
 814
 815                 }
 816                 else
 817                         e = self;
 818                 Item_ScheduleRespawn(e);
 819         }
 820 }
 821
 822 void Item_Reset()
 823 {
 824         Item_Show(self, !self.state);
 825         setorigin (self, self.origin);
 826
 827         if(self.classname != "droppedweapon")
 828         {
 829                 self.think = SUB_Null;
 830                 self.nextthink = 0;
 831
 832                 if(self.waypointsprite_attached)
 833                         WaypointSprite_Kill(self.waypointsprite_attached);
 834
 835                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 836                         Item_ScheduleInitialRespawn(self);
 837         }
 838 }
 839
 840 void Item_FindTeam()
 841 {
 842         entity head, e;
 843
 844         if(self.effects & EF_NODRAW)
 845         {
 846                 // marker for item team search
 847                 dprint("Initializing item team ", ftos(self.team), "\n");
 848                 RandomSelection_Init();
 849                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 850                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 851                 e = RandomSelection_chosen_ent;
 852                 e.state = 0;
 853                 Item_Show(e, 1);
 854
 855                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 856                 {
 857                         if(head != e)
 858                         {
 859                                 // make it a non-spawned item
 860                                 Item_Show(head, -1);
 861                                 head.state = 1; // state 1 = initially hidden item
 862                         }
 863                         head.effects &~= EF_NODRAW;
 864                 }
 865
 866                 Item_Reset();
 867         }
 868 }
 869
 870 // Savage: used for item garbage-collection
 871 // TODO: perhaps nice special effect?
 872 void RemoveItem(void)
 873 {
 874         remove(self);
 875 }
 876
 877 // pickup evaluation functions
 878 // these functions decide how desirable an item is to the bots
 879
 880 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 881
 882 float weapon_pickupevalfunc(entity player, entity item)
 883 {
 884         float c, j, position;
 885
 886         // See if I have it already
 887         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 888         {
 889                 // If I can pick it up
 890                 if(!item.spawnshieldtime)
 891                         c = 0;
 892                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 893                 {
 894                         // Skilled bots will grab more
 895                         c = bound(0, skill / 10, 1) * 0.5;
 896                 }
 897                 else
 898                         c = 0;
 899         }
 900         else
 901                 c = 1;
 902
 903         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 904         if( bot_custom_weapon && c )
 905         {
 906                 // Find the highest position on any range
 907                 position = -1;
 908                 for(j = 0; j < WEP_LAST ; ++j){
 909                         if(
 910                                         bot_weapons_far[j] == item.weapon ||
 911                                         bot_weapons_mid[j] == item.weapon ||
 912                                         bot_weapons_close[j] == item.weapon
 913                           )
 914                         {
 915                                 position = j;
 916                                 break;
 917                         }
 918                 }
 919
 920                 // Rate it
 921                 if (position >= 0 )
 922                 {
 923                         position = WEP_LAST - position;
 924                         // item.bot_pickupbasevalue is overwritten here
 925                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 926                 }
 927         }
 928
 929         return item.bot_pickupbasevalue * c;
 930 }
 931
 932 float commodity_pickupevalfunc(entity player, entity item)
 933 {
 934         float c, i;
 935         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 936         entity wi;
 937         c = 0;
 938
 939         // Detect needed ammo
 940         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 941         {
 942                 wi = get_weaponinfo(i);
 943
 944                 if not(WEPSET_CONTAINS_EW(player, i))
 945                         continue;
 946
 947                 if(wi.items & IT_SHELLS)
 948                         need_shells = TRUE;
 949                 else if(wi.items & IT_NAILS)
 950                         need_nails = TRUE;
 951                 else if(wi.items & IT_ROCKETS)
 952                         need_rockets = TRUE;
 953                 else if(wi.items & IT_CELLS)
 954                         need_cells = TRUE;
 955                 else if(wi.items & IT_FUEL)
 956                         need_cells = TRUE;
 957         }
 958
 959         // TODO: figure out if the player even has the weapon this ammo is for?
 960         // may not affect strategy much though...
 961         // find out how much more ammo/armor/health the player can hold
 962         if (need_shells)
 963         if (item.ammo_shells)
 964         if (player.ammo_shells < g_pickup_shells_max)
 965                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 966         if (need_nails)
 967         if (item.ammo_nails)
 968         if (player.ammo_nails < g_pickup_nails_max)
 969                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 970         if (need_rockets)
 971         if (item.ammo_rockets)
 972         if (player.ammo_rockets < g_pickup_rockets_max)
 973                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 974         if (need_cells)
 975         if (item.ammo_cells)
 976         if (player.ammo_cells < g_pickup_cells_max)
 977                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 978         if (need_fuel)
 979         if (item.ammo_fuel)
 980         if (player.ammo_fuel < g_pickup_fuel_max)
 981                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 982         if (item.armorvalue)
 983         if (player.armorvalue < item.max_armorvalue)
 984                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 985         if (item.health)
 986         if (player.health < item.max_health)
 987                 c = c + max(0, 1 - player.health / item.max_health);
 988
 989         return item.bot_pickupbasevalue * c;
 990 }
 991
 992 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 993 {
 994         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 995                 RemoveItem();
 996 }
 997
 998 .float is_item;
 999 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1000 {
1001         startitem_failed = FALSE;
1002
1003         if(self.model == "")
1004                 self.model = itemmodel;
1005
1006         if(self.model == "")
1007     {
1008         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1009         return;
1010     }
1011
1012         if(self.item_pickupsound == "")
1013                 self.item_pickupsound = pickupsound;
1014
1015         if(!self.respawntime) // both need to be set
1016         {
1017                 self.respawntime = defaultrespawntime;
1018                 self.respawntimejitter = defaultrespawntimejitter;
1019         }
1020
1021         self.items = itemid;
1022         self.weapon = weaponid;
1023
1024         if(weaponid)
1025                 WEPSET_COPY_EW(self, weaponid);
1026
1027         self.flags = FL_ITEM | itemflags;
1028
1029         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1030         {
1031                 startitem_failed = TRUE;
1032                 remove(self);
1033                 return;
1034         }
1035
1036         // is it a dropped weapon?
1037         if (self.classname == "droppedweapon")
1038         {
1039                 self.reset = SUB_Remove;
1040                 // it's a dropped weapon
1041                 self.movetype = MOVETYPE_TOSS;
1042
1043                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1044                 self.think = RemoveItem;
1045                 self.nextthink = time + 20;
1046
1047                 self.takedamage = DAMAGE_YES;
1048                 self.event_damage = Item_Damage;
1049
1050                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1051                 /*
1052                 if(self.items == 0)
1053                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
1054                 if(self.ammo_nails == 0)
1055                 if(self.ammo_cells == 0)
1056                 if(self.ammo_rockets == 0)
1057                 if(self.ammo_shells == 0)
1058                 if(self.ammo_fuel == 0)
1059                 if(self.health == 0)
1060                 if(self.armorvalue == 0)
1061                 */
1062                 {
1063                         // if item is worthless after a timer, have it expire then
1064                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1065                 }
1066
1067                 // don't drop if in a NODROP zone (such as lava)
1068                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1069                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1070                 {
1071                         startitem_failed = TRUE;
1072                         remove(self);
1073                         return;
1074                 }
1075         }
1076         else
1077         {
1078                 if(!have_pickup_item())
1079                 {
1080                         startitem_failed = TRUE;
1081                         remove (self);
1082                         return;
1083                 }
1084
1085                 if(self.angles != '0 0 0')
1086             self.SendFlags |= ISF_ANGLES;
1087
1088                 self.reset = Item_Reset;
1089                 // it's a level item
1090                 if(self.spawnflags & 1)
1091                         self.noalign = 1;
1092                 if (self.noalign)
1093                         self.movetype = MOVETYPE_NONE;
1094                 else
1095                         self.movetype = MOVETYPE_TOSS;
1096                 // do item filtering according to game mode and other things
1097                 if (!self.noalign)
1098                 {
1099                         // first nudge it off the floor a little bit to avoid math errors
1100                         setorigin(self, self.origin + '0 0 1');
1101                         // set item size before we spawn a spawnfunc_waypoint
1102                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1103                                 setsize (self, '-16 -16 0', '16 16 48');
1104                         else
1105                                 setsize (self, '-16 -16 0', '16 16 32');
1106                         // note droptofloor returns FALSE if stuck/or would fall too far
1107                         droptofloor();
1108                         waypoint_spawnforitem(self);
1109                 }
1110
1111                 /*
1112                  * can't do it that way, as it would break maps
1113                  * TODO make a target_give like entity another way, that perhaps has
1114                  * the weapon name in a key
1115                 if(self.targetname)
1116                 {
1117                         // target_give not yet supported; maybe later
1118                         print("removed targeted ", self.classname, "\n");
1119                         startitem_failed = TRUE;
1120                         remove (self);
1121                         return;
1122                 }
1123                 */
1124
1125                 if(autocvar_spawn_debug >= 2)
1126                 {
1127                         entity otheritem;
1128                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1129                         {
1130                             // why not flags & fl_item?
1131                                 if(otheritem.is_item)
1132                                 {
1133                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1134                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1135                                         error("Mapper sucks.");
1136                                 }
1137                         }
1138                         self.is_item = TRUE;
1139                 }
1140
1141                 WEPSET_OR_AW(weaponsInMap, weaponid);
1142
1143                 precache_model (self.model);
1144                 precache_sound (self.item_pickupsound);
1145
1146                 precache_sound ("misc/itemrespawncountdown.wav");
1147                 if(!g_minstagib && itemid == IT_STRENGTH)
1148                         precache_sound ("misc/strength_respawn.wav");
1149                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
1150                         precache_sound ("misc/shield_respawn.wav");
1151                 else
1152                         precache_sound ("misc/itemrespawn.wav");
1153
1154                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1155                         self.target = "###item###"; // for finding the nearest item using find()
1156         }
1157
1158         self.bot_pickup = TRUE;
1159         self.bot_pickupevalfunc = pickupevalfunc;
1160         self.bot_pickupbasevalue = pickupbasevalue;
1161         self.mdl = self.model;
1162         self.netname = itemname;
1163         self.touch = Item_Touch;
1164         setmodel(self, "null"); // precision set below
1165         //self.effects |= EF_LOWPRECISION;
1166
1167         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1168     {
1169         self.pos1 = '-16 -16 0';
1170         self.pos2 = '16 16 48';
1171     }
1172         else
1173     {
1174         self.pos1 = '-16 -16 0';
1175         self.pos2 = '16 16 32';
1176     }
1177     setsize (self, self.pos1, self.pos2);
1178
1179     if(itemflags & FL_POWERUP)
1180         self.ItemStatus |= ITS_ANIMATE1;
1181
1182         if(self.armorvalue || self.health)
1183         self.ItemStatus |= ITS_ANIMATE2;
1184
1185         if(itemflags & FL_WEAPON)
1186         {
1187                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1188             self.colormap = 1024; // color shirt=0 pants=0 grey
1189         else
1190             self.gravity = 1;
1191
1192                 self.ItemStatus |= ITS_ANIMATE1;
1193                 self.ItemStatus |= ISF_COLORMAP;
1194         }
1195
1196         self.state = 0;
1197         if(self.team) // broken, no idea why.
1198         {
1199                 if(!self.cnt)
1200                         self.cnt = 1; // item probability weight
1201
1202                 self.effects |= EF_NODRAW; // marker for item team search
1203                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1204         }
1205         else
1206                 Item_Reset();
1207
1208     Net_LinkEntity(self, FALSE, 0, ItemSend);
1209 }
1210
1211 /* replace items in minstagib
1212  * IT_STRENGTH   = invisibility
1213  * IT_NAILS      = extra lives
1214  * IT_INVINCIBLE = speed
1215  */
1216 void minstagib_items (float itemid) // will be deleted soon.
1217 {
1218         float rnd;
1219         self.classname = "minstagib"; // ...?
1220
1221         // replace rocket launchers and nex guns with ammo cells
1222         if (itemid == IT_CELLS)
1223         {
1224                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1225                 StartItem ("models/items/a_cells.md3",
1226                         "misc/itempickup.wav", 45, 0,
1227                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
1228                 return;
1229         }
1230
1231         // randomize
1232         rnd = random() * 3;
1233         if (rnd <= 1)
1234                 itemid = IT_STRENGTH;
1235         else if (rnd <= 2)
1236                 itemid = IT_NAILS;
1237         else
1238                 itemid = IT_INVINCIBLE;
1239
1240         // replace with invis
1241         if (itemid == IT_STRENGTH)
1242         {
1243                 if(!self.strength_finished)
1244                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1245                 StartItem ("models/items/g_strength.md3",
1246                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1247                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1248         }
1249         // replace with extra lives
1250         if (itemid == IT_NAILS)
1251         {
1252                 self.max_health = 1;
1253                 StartItem ("models/items/g_h100.md3",
1254                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1255                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1256         }
1257         // replace with speed
1258         if (itemid == IT_INVINCIBLE)
1259         {
1260                 if(!self.invincible_finished)
1261                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1262                 StartItem ("models/items/g_invincible.md3",
1263                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1264                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1265         }
1266 }
1267
1268 float minst_no_auto_cells;
1269 void minst_remove_item (void) {
1270         if(minst_no_auto_cells)
1271                 remove(self);
1272 }
1273
1274 float weaponswapping;
1275 float internalteam;
1276
1277 void weapon_defaultspawnfunc(float wpn)
1278 {
1279         entity e;
1280         float t;
1281         var .float ammofield;
1282         string s;
1283         entity oldself;
1284         float i, j;
1285         float f;
1286
1287         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1288         {
1289                 e = get_weaponinfo(wpn);
1290
1291                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1292                 {
1293                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1294                         /*
1295                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1296                         startitem_failed = TRUE;
1297                         return;
1298                         */
1299                 }
1300
1301                 s = W_Apply_Weaponreplace(e.netname);
1302                 ret_string = s;
1303                 other = e;
1304                 MUTATOR_CALLHOOK(SetWeaponreplace);
1305                 s = ret_string;
1306                 if(s == "")
1307                 {
1308                         remove(self);
1309                         startitem_failed = TRUE;
1310                         return;
1311                 }
1312                 t = tokenize_console(s);
1313                 if(t >= 2)
1314                 {
1315                         self.team = --internalteam;
1316                         oldself = self;
1317                         for(i = 1; i < t; ++i)
1318                         {
1319                                 s = argv(i);
1320                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1321                                 {
1322                                         e = get_weaponinfo(j);
1323                                         if(e.netname == s)
1324                                         {
1325                                                 self = spawn();
1326                                                 copyentity(oldself, self);
1327                                                 self.classname = "replacedweapon";
1328                                                 weapon_defaultspawnfunc(j);
1329                                                 break;
1330                                         }
1331                                 }
1332                                 if(j > WEP_LAST)
1333                                 {
1334                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1335                                 }
1336                         }
1337                         self = oldself;
1338                 }
1339                 if(t >= 1) // always the case!
1340                 {
1341                         s = argv(0);
1342                         wpn = 0;
1343                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1344                         {
1345                                 e = get_weaponinfo(j);
1346                                 if(e.netname == s)
1347                                 {
1348                                         wpn = j;
1349                                         break;
1350                                 }
1351                         }
1352                         if(j > WEP_LAST)
1353                         {
1354                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1355                         }
1356                 }
1357                 if(wpn == 0)
1358                 {
1359                         remove(self);
1360                         startitem_failed = TRUE;
1361                         return;
1362                 }
1363         }
1364
1365         e = get_weaponinfo(wpn);
1366
1367         if(!self.respawntime)
1368         {
1369                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1370                 {
1371                         self.respawntime = g_pickup_respawntime_superweapon;
1372                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1373                 }
1374                 else
1375                 {
1376                         self.respawntime = g_pickup_respawntime_weapon;
1377                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1378                 }
1379         }
1380
1381         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1382                 if(!self.superweapons_finished)
1383                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1384
1385         if(e.items)
1386         {
1387                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1388                 {
1389                         if(e.items & j)
1390                         {
1391                                 ammofield = Item_CounterField(j);
1392                                 if(!self.ammofield)
1393                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1394                         }
1395                 }
1396         }
1397
1398         // pickup anyway
1399         if(g_pickup_weapons_anyway)
1400                 self.pickup_anyway = TRUE;
1401
1402         f = FL_WEAPON;
1403
1404         // no weapon-stay on superweapons
1405         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1406                 f |= FL_NO_WEAPON_STAY;
1407
1408         // weapon stay isn't supported for teamed weapons
1409         if(self.team)
1410                 f |= FL_NO_WEAPON_STAY;
1411
1412         // stupid minstagib hack, don't ask
1413         if(g_minstagib)
1414                 if(self.ammo_cells)
1415                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1416
1417         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1418         if (self.modelindex) // don't precache if self was removed
1419                 weapon_action(e.weapon, WR_PRECACHE);
1420 }
1421
1422 void spawnfunc_weapon_shotgun (void);
1423 void spawnfunc_weapon_uzi (void) {
1424         if(autocvar_sv_q3acompat_machineshotgunswap)
1425         if(self.classname != "droppedweapon")
1426         {
1427                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1428                 return;
1429         }
1430         weapon_defaultspawnfunc(WEP_UZI);
1431 }
1432
1433 void spawnfunc_weapon_shotgun (void) {
1434         if(autocvar_sv_q3acompat_machineshotgunswap)
1435         if(self.classname != "droppedweapon")
1436         {
1437                 weapon_defaultspawnfunc(WEP_UZI);
1438                 return;
1439         }
1440         weapon_defaultspawnfunc(WEP_SHOTGUN);
1441 }
1442
1443 void spawnfunc_weapon_nex (void)
1444 {
1445         if (g_minstagib)
1446         {
1447                 minstagib_items(IT_CELLS);
1448                 self.think = minst_remove_item;
1449                 self.nextthink = time;
1450                 return;
1451         }
1452         weapon_defaultspawnfunc(WEP_NEX);
1453 }
1454
1455 void spawnfunc_weapon_minstanex (void)
1456 {
1457         if (g_minstagib)
1458         {
1459                 minstagib_items(IT_CELLS);
1460                 self.think = minst_remove_item;
1461                 self.nextthink = time;
1462                 return;
1463         }
1464         weapon_defaultspawnfunc(WEP_MINSTANEX);
1465 }
1466
1467 void spawnfunc_weapon_rocketlauncher (void)
1468 {
1469         if (g_minstagib)
1470         {
1471                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1472                 self.think = minst_remove_item;
1473                 self.nextthink = time;
1474                 return;
1475         }
1476         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1477 }
1478
1479 void spawnfunc_item_rockets (void) {
1480         if(!self.ammo_rockets)
1481                 self.ammo_rockets = g_pickup_rockets;
1482         if(!self.pickup_anyway)
1483                 self.pickup_anyway = g_pickup_ammo_anyway;
1484         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1485 }
1486
1487 void spawnfunc_item_shells (void);
1488 void spawnfunc_item_bullets (void) {
1489         if(!weaponswapping)
1490         if(autocvar_sv_q3acompat_machineshotgunswap)
1491         if(self.classname != "droppedweapon")
1492         {
1493                 weaponswapping = TRUE;
1494                 spawnfunc_item_shells();
1495                 weaponswapping = FALSE;
1496                 return;
1497         }
1498
1499         if(!self.ammo_nails)
1500                 self.ammo_nails = g_pickup_nails;
1501         if(!self.pickup_anyway)
1502                 self.pickup_anyway = g_pickup_ammo_anyway;
1503         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1504 }
1505
1506 void spawnfunc_item_cells (void) {
1507         if(!self.ammo_cells)
1508                 self.ammo_cells = g_pickup_cells;
1509         if(!self.pickup_anyway)
1510                 self.pickup_anyway = g_pickup_ammo_anyway;
1511         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1512 }
1513
1514 void spawnfunc_item_shells (void) {
1515         if(!weaponswapping)
1516         if(autocvar_sv_q3acompat_machineshotgunswap)
1517         if(self.classname != "droppedweapon")
1518         {
1519                 weaponswapping = TRUE;
1520                 spawnfunc_item_bullets();
1521                 weaponswapping = FALSE;
1522                 return;
1523         }
1524
1525         if(!self.ammo_shells)
1526                 self.ammo_shells = g_pickup_shells;
1527         if(!self.pickup_anyway)
1528                 self.pickup_anyway = g_pickup_ammo_anyway;
1529         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1530 }
1531
1532 void spawnfunc_item_armor_small (void) {
1533         if(!self.armorvalue)
1534                 self.armorvalue = g_pickup_armorsmall;
1535         if(!self.max_armorvalue)
1536                 self.max_armorvalue = g_pickup_armorsmall_max;
1537         if(!self.pickup_anyway)
1538                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1539         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1540 }
1541
1542 void spawnfunc_item_armor_medium (void) {
1543         if(!self.armorvalue)
1544                 self.armorvalue = g_pickup_armormedium;
1545         if(!self.max_armorvalue)
1546                 self.max_armorvalue = g_pickup_armormedium_max;
1547         if(!self.pickup_anyway)
1548                 self.pickup_anyway = g_pickup_armormedium_anyway;
1549         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1550 }
1551
1552 void spawnfunc_item_armor_big (void) {
1553         if(!self.armorvalue)
1554                 self.armorvalue = g_pickup_armorbig;
1555         if(!self.max_armorvalue)
1556                 self.max_armorvalue = g_pickup_armorbig_max;
1557         if(!self.pickup_anyway)
1558                 self.pickup_anyway = g_pickup_armorbig_anyway;
1559         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1560 }
1561
1562 void spawnfunc_item_armor_large (void) {
1563         if(!self.armorvalue)
1564                 self.armorvalue = g_pickup_armorlarge;
1565         if(!self.max_armorvalue)
1566                 self.max_armorvalue = g_pickup_armorlarge_max;
1567         if(!self.pickup_anyway)
1568                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1569         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1570 }
1571
1572 void spawnfunc_item_health_small (void) {
1573         if(!self.max_health)
1574                 self.max_health = g_pickup_healthsmall_max;
1575         if(!self.health)
1576                 self.health = g_pickup_healthsmall;
1577         if(!self.pickup_anyway)
1578                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1579         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1580 }
1581
1582 void spawnfunc_item_health_medium (void) {
1583         if(!self.max_health)
1584                 self.max_health = g_pickup_healthmedium_max;
1585         if(!self.health)
1586                 self.health = g_pickup_healthmedium;
1587         if(!self.pickup_anyway)
1588                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1589         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1590 }
1591
1592 void spawnfunc_item_health_large (void) {
1593         if(!self.max_health)
1594                 self.max_health = g_pickup_healthlarge_max;
1595         if(!self.health)
1596                 self.health = g_pickup_healthlarge;
1597         if(!self.pickup_anyway)
1598                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1599         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1600 }
1601
1602 void spawnfunc_item_health_mega (void) {
1603         if(g_minstagib) {
1604                 minstagib_items(IT_NAILS);
1605         } else {
1606                 if(!self.max_health)
1607                         self.max_health = g_pickup_healthmega_max;
1608                 if(!self.health)
1609                         self.health = g_pickup_healthmega;
1610                 if(!self.pickup_anyway)
1611                         self.pickup_anyway = g_pickup_healthmega_anyway;
1612                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1613         }
1614 }
1615
1616 // support old misnamed entities
1617 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1618 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1619 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1620 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1621 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1622
1623 void spawnfunc_item_strength (void) {
1624         if(g_minstagib) {
1625                 minstagib_items(IT_STRENGTH);
1626         } else {
1627                 precache_sound("weapons/strength_fire.wav");
1628                 if(!self.strength_finished)
1629                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1630                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1631         }
1632 }
1633
1634 void spawnfunc_item_invincible (void) {
1635         if(g_minstagib) {
1636                 minstagib_items(IT_INVINCIBLE);
1637         } else {
1638                 if(!self.invincible_finished)
1639                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1640                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1641         }
1642 }
1643
1644 void spawnfunc_item_minst_cells (void) {
1645         if (g_minstagib)
1646         {
1647                 minst_no_auto_cells = TRUE;
1648                 minstagib_items(IT_CELLS);
1649         }
1650         else
1651                 remove(self);
1652 }
1653
1654 // compatibility:
1655 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1656
1657 float GiveItems(entity e, float beginarg, float endarg);
1658 void target_items_use (void)
1659 {
1660         if(activator.classname == "droppedweapon")
1661         {
1662                 EXACTTRIGGER_TOUCH;
1663                 remove(activator);
1664                 return;
1665         }
1666
1667         if(activator.classname != "player")
1668                 return;
1669         if(activator.deadflag != DEAD_NO)
1670                 return;
1671         EXACTTRIGGER_TOUCH;
1672
1673         entity e;
1674         for(e = world; (e = find(e, classname, "droppedweapon")); )
1675                 if(e.enemy == activator)
1676                         remove(e);
1677
1678         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1679                 centerprint(activator, self.message);
1680 }
1681
1682 void spawnfunc_target_items (void)
1683 {
1684         float n, i, j;
1685         entity e;
1686
1687         self.use = target_items_use;
1688         if(!self.strength_finished)
1689                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1690         if(!self.invincible_finished)
1691                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1692         if(!self.superweapons_finished)
1693                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1694
1695         precache_sound("misc/itempickup.wav");
1696         precache_sound("misc/megahealth.wav");
1697         precache_sound("misc/armor25.wav");
1698         precache_sound("misc/powerup.wav");
1699         precache_sound("misc/poweroff.wav");
1700         precache_sound("weapons/weaponpickup.wav");
1701
1702         n = tokenize_console(self.netname);
1703         if(argv(0) == "give")
1704         {
1705                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1706         }
1707         else
1708         {
1709                 for(i = 0; i < n; ++i)
1710                 {
1711                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1712                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1713                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1714                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1715                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1716                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1717                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1718                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1719                         else
1720                         {
1721                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1722                                 {
1723                                         e = get_weaponinfo(j);
1724                                         if(argv(i) == e.netname)
1725                                         {
1726                                                 WEPSET_OR_EW(self, j);
1727                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1728                                                         weapon_action(e.weapon, WR_PRECACHE);
1729                                                 break;
1730                                         }
1731                                 }
1732                                 if(j > WEP_LAST)
1733                                         print("target_items: invalid item ", argv(i), "\n");
1734                         }
1735                 }
1736
1737                 string itemprefix, valueprefix;
1738                 if(self.spawnflags == 0)
1739                 {
1740                         itemprefix = "";
1741                         valueprefix = "";
1742                 }
1743                 else if(self.spawnflags == 1)
1744                 {
1745                         itemprefix = "max ";
1746                         valueprefix = "max ";
1747                 }
1748                 else if(self.spawnflags == 2)
1749                 {
1750                         itemprefix = "min ";
1751                         valueprefix = "min ";
1752                 }
1753                 else if(self.spawnflags == 4)
1754                 {
1755                         itemprefix = "minus ";
1756                         valueprefix = "max ";
1757                 }
1758                 else
1759                         error("invalid spawnflags");
1760
1761                 self.netname = "";
1762                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1763                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1764                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1765                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1766                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1767                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1768                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1769                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1770                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1771                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1772                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1773                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1774                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1775                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1776                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1777                 {
1778                         e = get_weaponinfo(j);
1779                         if(e.weapon)
1780                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1781                 }
1782         }
1783         self.netname = strzone(self.netname);
1784         //print(self.netname, "\n");
1785
1786         n = tokenize_console(self.netname);
1787         for(i = 0; i < n; ++i)
1788         {
1789                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1790                 {
1791                         e = get_weaponinfo(j);
1792                         if(argv(i) == e.netname)
1793                         {
1794                                 weapon_action(e.weapon, WR_PRECACHE);
1795                                 break;
1796                         }
1797                 }
1798         }
1799 }
1800
1801 void spawnfunc_item_fuel(void)
1802 {
1803         if(!self.ammo_fuel)
1804                 self.ammo_fuel = g_pickup_fuel;
1805         if(!self.pickup_anyway)
1806                 self.pickup_anyway = g_pickup_ammo_anyway;
1807         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1808 }
1809
1810 void spawnfunc_item_fuel_regen(void)
1811 {
1812         if(start_items & IT_FUEL_REGEN)
1813         {
1814                 spawnfunc_item_fuel();
1815                 return;
1816         }
1817         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1818 }
1819
1820 void spawnfunc_item_jetpack(void)
1821 {
1822         if(g_grappling_hook)
1823                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1824         if(!self.ammo_fuel)
1825                 self.ammo_fuel = g_pickup_fuel_jetpack;
1826         if(start_items & IT_JETPACK)
1827         {
1828                 spawnfunc_item_fuel();
1829                 return;
1830         }
1831         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1832 }
1833
1834
1835 #define OP_SET 0
1836 #define OP_MIN 1
1837 #define OP_MAX 2
1838 #define OP_PLUS 3
1839 #define OP_MINUS 4
1840
1841 float GiveWeapon(entity e, float wpn, float op, float val)
1842 {
1843         float v0, v1;
1844         v0 = WEPSET_CONTAINS_EW(e, wpn);
1845         switch(op)
1846         {
1847                 case OP_SET:
1848                         if(val > 0)
1849                                 WEPSET_OR_EW(e, wpn);
1850                         else
1851                                 WEPSET_ANDNOT_EW(e, wpn);
1852                         break;
1853                 case OP_MIN:
1854                 case OP_PLUS:
1855                         if(val > 0)
1856                                 WEPSET_OR_EW(e, wpn);
1857                         break;
1858                 case OP_MAX:
1859                         if(val <= 0)
1860                                 WEPSET_ANDNOT_EW(e, wpn);
1861                         break;
1862                 case OP_MINUS:
1863                         if(val > 0)
1864                                 WEPSET_ANDNOT_EW(e, wpn);
1865                         break;
1866         }
1867         v1 = WEPSET_CONTAINS_EW(e, wpn);
1868         return (v0 != v1);
1869 }
1870
1871 float GiveBit(entity e, .float fld, float bit, float op, float val)
1872 {
1873         float v0, v1;
1874         v0 = (e.fld & bit);
1875         switch(op)
1876         {
1877                 case OP_SET:
1878                         if(val > 0)
1879                                 e.fld |= bit;
1880                         else
1881                                 e.fld &~= bit;
1882                         break;
1883                 case OP_MIN:
1884                 case OP_PLUS:
1885                         if(val > 0)
1886                                 e.fld |= bit;
1887                         break;
1888                 case OP_MAX:
1889                         if(val <= 0)
1890                                 e.fld &~= bit;
1891                         break;
1892                 case OP_MINUS:
1893                         if(val > 0)
1894                                 e.fld &~= bit;
1895                         break;
1896         }
1897         v1 = (e.fld & bit);
1898         return (v0 != v1);
1899 }
1900
1901 float GiveValue(entity e, .float fld, float op, float val)
1902 {
1903         float v0, v1;
1904         v0 = e.fld;
1905         switch(op)
1906         {
1907                 case OP_SET:
1908                         e.fld = val;
1909                         break;
1910                 case OP_MIN:
1911                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1912                         break;
1913                 case OP_MAX:
1914                         e.fld = min(e.fld, val);
1915                         break;
1916                 case OP_PLUS:
1917                         e.fld += val;
1918                         break;
1919                 case OP_MINUS:
1920                         e.fld -= val;
1921                         break;
1922         }
1923         v1 = e.fld;
1924         return (v0 != v1);
1925 }
1926
1927 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1928 {
1929         if(v1 == v0)
1930                 return;
1931         if(v1 <= v0 - t)
1932         {
1933                 if(snd_decr != "")
1934                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1935         }
1936         else if(v0 >= v0 + t)
1937         {
1938                 if(snd_incr != "")
1939                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1940         }
1941 }
1942
1943 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1944 {
1945         if(v0 < v1)
1946                 e.rotfield = max(e.rotfield, time + rottime);
1947         else if(v0 > v1)
1948                 e.regenfield = max(e.regenfield, time + regentime);
1949 }
1950
1951 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1952 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1953 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1954 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1955 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1956 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1957
1958 float GiveItems(entity e, float beginarg, float endarg)
1959 {
1960         float got, i, j, val, op;
1961         float _switchweapon;
1962         entity wi;
1963         string cmd;
1964
1965         val = 999;
1966         op = OP_SET;
1967
1968         got = 0;
1969
1970         _switchweapon = FALSE;
1971         if (e.autoswitch)
1972                 if (e.switchweapon == w_getbestweapon(e))
1973                         _switchweapon = TRUE;
1974
1975         e.strength_finished = max(0, e.strength_finished - time);
1976         e.invincible_finished = max(0, e.invincible_finished - time);
1977         e.superweapons_finished = max(0, e.superweapons_finished - time);
1978
1979         PREGIVE(e, items);
1980         PREGIVE_WEAPONS(e);
1981         PREGIVE(e, strength_finished);
1982         PREGIVE(e, invincible_finished);
1983         PREGIVE(e, superweapons_finished);
1984         PREGIVE(e, ammo_nails);
1985         PREGIVE(e, ammo_cells);
1986         PREGIVE(e, ammo_shells);
1987         PREGIVE(e, ammo_rockets);
1988         PREGIVE(e, ammo_fuel);
1989         PREGIVE(e, armorvalue);
1990         PREGIVE(e, health);
1991
1992         for(i = beginarg; i < endarg; ++i)
1993         {
1994                 cmd = argv(i);
1995
1996                 if(cmd == "0" || stof(cmd))
1997                 {
1998                         val = stof(cmd);
1999                         continue;
2000                 }
2001                 switch(cmd)
2002                 {
2003                         case "no":
2004                                 op = OP_MAX;
2005                                 val = 0;
2006                                 continue;
2007                         case "max":
2008                                 op = OP_MAX;
2009                                 continue;
2010                         case "min":
2011                                 op = OP_MIN;
2012                                 continue;
2013                         case "plus":
2014                                 op = OP_PLUS;
2015                                 continue;
2016                         case "minus":
2017                                 op = OP_MINUS;
2018                                 continue;
2019                         case "ALL":
2020                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2021                                 got += GiveValue(e, strength_finished, op, val);
2022                                 got += GiveValue(e, invincible_finished, op, val);
2023                                 got += GiveValue(e, superweapons_finished, op, val);
2024                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2025                         case "all":
2026                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2027                                 got += GiveValue(e, health, op, val);
2028                                 got += GiveValue(e, armorvalue, op, val);
2029                         case "allweapons":
2030                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2031                                 {
2032                                         wi = get_weaponinfo(j);
2033                                         if(wi.weapon)
2034                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
2035                                                         got += GiveWeapon(e, j, op, val);
2036                                 }
2037                         case "allammo":
2038                                 got += GiveValue(e, ammo_cells, op, val);
2039                                 got += GiveValue(e, ammo_shells, op, val);
2040                                 got += GiveValue(e, ammo_nails, op, val);
2041                                 got += GiveValue(e, ammo_rockets, op, val);
2042                                 got += GiveValue(e, ammo_fuel, op, val);
2043                                 break;
2044                         case "unlimited_ammo":
2045                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2046                                 break;
2047                         case "unlimited_weapon_ammo":
2048                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
2049                                 break;
2050                         case "unlimited_superweapons":
2051                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
2052                                 break;
2053                         case "jetpack":
2054                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2055                                 break;
2056                         case "fuel_regen":
2057                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2058                                 break;
2059                         case "strength":
2060                                 got += GiveValue(e, strength_finished, op, val);
2061                                 break;
2062                         case "invincible":
2063                                 got += GiveValue(e, invincible_finished, op, val);
2064                                 break;
2065                         case "superweapons":
2066                                 got += GiveValue(e, superweapons_finished, op, val);
2067                                 break;
2068                         case "cells":
2069                                 got += GiveValue(e, ammo_cells, op, val);
2070                                 break;
2071                         case "shells":
2072                                 got += GiveValue(e, ammo_shells, op, val);
2073                                 break;
2074                         case "nails":
2075                         case "bullets":
2076                                 got += GiveValue(e, ammo_nails, op, val);
2077                                 break;
2078                         case "rockets":
2079                                 got += GiveValue(e, ammo_rockets, op, val);
2080                                 break;
2081                         case "health":
2082                                 got += GiveValue(e, health, op, val);
2083                                 break;
2084                         case "armor":
2085                                 got += GiveValue(e, armorvalue, op, val);
2086                                 break;
2087                         case "fuel":
2088                                 got += GiveValue(e, ammo_fuel, op, val);
2089                                 break;
2090                         default:
2091                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2092                                 {
2093                                         wi = get_weaponinfo(j);
2094                                         if(cmd == wi.netname)
2095                                         {
2096                                                 got += GiveWeapon(e, j, op, val);
2097                                                 break;
2098                                         }
2099                                 }
2100                                 if(j > WEP_LAST)
2101                                         print("give: invalid item ", cmd, "\n");
2102                                 break;
2103                 }
2104                 val = 999;
2105                 op = OP_SET;
2106         }
2107
2108         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
2109         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
2110         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
2111         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
2112         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2113         {
2114                 wi = get_weaponinfo(j);
2115                 if(wi.weapon)
2116                 {
2117                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
2118                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
2119                                 if(WEPSET_CONTAINS_EW(e, j))
2120                                         weapon_action(wi.weapon, WR_PRECACHE);
2121                 }
2122         }
2123         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2124         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2125         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2126         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2127         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2128         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2129         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2130         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2131         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2132
2133         if(e.superweapons_finished <= 0)
2134                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
2135                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2136
2137         if (g_minstagib)
2138         {
2139                 e.health = bound(0, e.health, 100);
2140                 e.armorvalue = bound(0, e.armorvalue, 999);
2141         }
2142
2143         if(e.strength_finished <= 0)
2144                 e.strength_finished = 0;
2145         else
2146                 e.strength_finished += time;
2147         if(e.invincible_finished <= 0)
2148                 e.invincible_finished = 0;
2149         else
2150                 e.invincible_finished += time;
2151         if(e.superweapons_finished <= 0)
2152                 e.superweapons_finished = 0;
2153         else
2154                 e.superweapons_finished += time;
2155
2156         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
2157                 _switchweapon = TRUE;
2158         if(_switchweapon)
2159                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2160
2161         return got;
2162 }
2163 #endif