qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(autocvar_g_ghost_items_color);
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent green and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent green and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(autocvar_g_ghost_items_color);
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = stov(autocvar_g_ghost_items_color);
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (autocvar_g_nodepthtestitems)
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (autocvar_g_fullbrightitems)
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 152         else
 153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 202                                 if(self.waypointsprite_attached)
 203                                 {
 204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 207                                 }
 208                         }
 209                 }
 210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 211                 if(self.waypointsprite_attached)
 212                 {
 213                         WaypointSprite_Ping(self.waypointsprite_attached);
 214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 215                 }
 216         }
 217 }
 218
 219 void Item_ScheduleRespawnIn(entity e, float t)
 220 {
 221         if(e.flags & FL_POWERUP)
 222         {
 223                 e.think = Item_RespawnCountdown;
 224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 225                 e.count = 0;
 226         }
 227         else
 228         {
 229                 e.think = Item_Respawn;
 230                 e.nextthink = time + t;
 231         }
 232 }
 233
 234 void Item_ScheduleRespawn(entity e)
 235 {
 236         if(e.respawntime > 0)
 237         {
 238                 Item_Show(e, 0);
 239                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 240         }
 241         else // if respawntime is -1, this item does not respawn
 242                 Item_Show(e, -1);
 243 }
 244
 245 void Item_ScheduleInitialRespawn(entity e)
 246 {
 247         Item_Show(e, 0);
 248         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 249 }
 250
 251 float Item_GiveTo(entity item, entity player)
 252 {
 253         float _switchweapon;
 254         float pickedup;
 255         float it;
 256         float i;
 257         entity e;
 258
 259         // if nothing happens to player, just return without taking the item
 260         pickedup = FALSE;
 261         _switchweapon = FALSE;
 262
 263         if (g_minstagib)
 264         {
 265                 if(item.spawnshieldtime)
 266                 {
 267                         if (item.ammo_fuel)
 268                         if (player.ammo_fuel < g_pickup_fuel_max)
 269                         {
 270                                 pickedup = TRUE;
 271                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 272                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 273                         }
 274                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 275                         {
 276                                 pickedup = TRUE;
 277                                 player.items |= it;
 278                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 279                         }
 280
 281                         _switchweapon = TRUE;
 282                         if (item.ammo_cells)
 283                         {
 284                                 pickedup = TRUE;
 285                                 // play some cool sounds ;)
 286                                 centerprint(player, "\n");
 287                                 if (clienttype(player) == CLIENTTYPE_REAL)
 288                                 {
 289                                         if(player.health <= 5)
 290                                                 AnnounceTo(player, "lastsecond");
 291                                         else if(player.health < 50)
 292                                                 AnnounceTo(player, "narrowly");
 293                                 }
 294                                 // sound not available
 295                                 // else if(item.items == IT_CELLS)
 296                                 //      AnnounceTo(player, "ammo");
 297
 298                                 if (item.weapons & WEPBIT_MINSTANEX)
 299                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 300                                 if (item.ammo_cells)
 301                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 302                                 player.health = 100;
 303                         }
 304
 305                         // extralife powerup
 306                         if (item.max_health)
 307                         {
 308                                 pickedup = TRUE;
 309                                 // sound not available
 310                                 // AnnounceTo(player, "_lives");
 311                                 player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 312                                 sprint(player, "^3You picked up some extra lives\n");
 313                         }
 314
 315                         // invis powerup
 316                         if (item.strength_finished)
 317                         {
 318                                 pickedup = TRUE;
 319                                 // sound not available
 320                                 // AnnounceTo(player, "invisible");
 321                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 322                         }
 323
 324                         // speed powerup
 325                         if (item.invincible_finished)
 326                         {
 327                                 pickedup = TRUE;
 328                                 // sound not available
 329                                 // AnnounceTo(player, "speed");
 330                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 331                         }
 332                 }
 333         }
 334         else
 335         {
 336                 if (g_weapon_stay == 1)
 337                 if not(item.flags & FL_NO_WEAPON_STAY)
 338                 if (item.flags & FL_WEAPON)
 339                 {
 340                         if(item.classname == "droppedweapon")
 341                         {
 342                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 343                                         goto skip;
 344                         }
 345                         else
 346                         {
 347                                 if (player.weapons & item.weapons)
 348                                         goto skip;
 349                         }
 350                 }
 351
 352                 // in case the player has autoswitch enabled do the following:
 353                 // if the player is using their best weapon before items are given, they
 354                 // probably want to switch to an even better weapon after items are given
 355                 if (player.autoswitch)
 356                 if (player.switchweapon == w_getbestweapon(player))
 357                         _switchweapon = TRUE;
 358
 359                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 360                         _switchweapon = TRUE;
 361
 362                 if(item.spawnshieldtime)
 363                 {
 364                         if (item.ammo_shells)
 365                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 366                         {
 367                                 pickedup = TRUE;
 368                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 369                         }
 370                         if (item.ammo_nails)
 371                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 372                         {
 373                                 pickedup = TRUE;
 374                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 375                         }
 376                         if (item.ammo_rockets)
 377                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 378                         {
 379                                 pickedup = TRUE;
 380                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 381                         }
 382                         if (item.ammo_cells)
 383                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 384                         {
 385                                 pickedup = TRUE;
 386                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 387                         }
 388                         if (item.ammo_fuel)
 389                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 390                         {
 391                                 pickedup = TRUE;
 392                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 393                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 394                         }
 395                 }
 396
 397                 if (item.flags & FL_WEAPON)
 398                 if ((it = item.weapons - (item.weapons & player.weapons)) || g_pickup_weapons_anyway)
 399                 {
 400                         pickedup = TRUE;
 401                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 402                         {
 403                                 e = get_weaponinfo(i);
 404                                 if(it & e.weapons)
 405                                         W_GiveWeapon (player, e.weapon, item.netname);
 406                         }
 407                 }
 408
 409                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 410                 {
 411                         pickedup = TRUE;
 412                         player.items |= it;
 413                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 414                 }
 415
 416                 if(item.spawnshieldtime)
 417                 {
 418                         if (item.strength_finished)
 419                         {
 420                                 pickedup = TRUE;
 421                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 422                         }
 423                         if (item.invincible_finished)
 424                         {
 425                                 pickedup = TRUE;
 426                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 427                         }
 428
 429                         if (item.health)
 430                         if ((player.health < item.max_health) || item.pickup_anyway)
 431                         {
 432                                 pickedup = TRUE;
 433                                 player.health = bound(player.health, item.max_health, player.health + item.health);
 434                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 435                         }
 436                         if (item.armorvalue)
 437                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 438                         {
 439                                 pickedup = TRUE;
 440                                 player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 441                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 442                         }
 443                 }
 444         }
 445
 446 :skip
 447         // always eat teamed entities
 448         if(item.team)
 449                 pickedup = TRUE;
 450
 451         if (!pickedup)
 452                 return 0;
 453
 454         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 455         if (_switchweapon)
 456                 if (player.switchweapon != w_getbestweapon(player))
 457                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 458
 459         return 1;
 460 }
 461
 462 void Item_Touch (void)
 463 {
 464         entity e, head;
 465
 466         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 467         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 468         {
 469                 remove(self);
 470                 return;
 471         }
 472         if (other.classname != "player")
 473                 return;
 474         if (other.deadflag)
 475                 return;
 476         if (self.solid != SOLID_TRIGGER)
 477                 return;
 478         if (self.owner == other)
 479                 return;
 480
 481         if(!Item_GiveTo(self, other))
 482                 return;
 483
 484         other.last_pickup = time;
 485
 486         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 487
 488         if (self.classname == "droppedweapon")
 489                 remove (self);
 490         else if not(self.spawnshieldtime)
 491                 return;
 492         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 493                 return;
 494         else
 495         {
 496                 if(self.team)
 497                 {
 498                         RandomSelection_Init();
 499                         for(head = world; (head = findfloat(head, team, self.team)); )
 500                         {
 501                                 if(head.flags & FL_ITEM)
 502                                 {
 503                                         Item_Show(head, -1);
 504                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 505                                 }
 506                         }
 507                         e = RandomSelection_chosen_ent;
 508                 }
 509                 else
 510                         e = self;
 511                 Item_ScheduleRespawn(e);
 512         }
 513 }
 514
 515 void Item_FindTeam()
 516 {
 517         entity head, e;
 518
 519         if(self.effects & EF_NODRAW)
 520         {
 521                 // marker for item team search
 522                 dprint("Initializing item team ", ftos(self.team), "\n");
 523                 RandomSelection_Init();
 524                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 525                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 526                 e = RandomSelection_chosen_ent;
 527                 e.state = 0;
 528                 Item_Show(e, 1);
 529
 530                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 531                 {
 532                         if(head != e)
 533                         {
 534                                 // make it a non-spawned item
 535                                 Item_Show(head, -1);
 536                                 head.state = 1; // state 1 = initially hidden item
 537                         }
 538                         head.effects &~= EF_NODRAW;
 539                 }
 540
 541                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 542                         Item_ScheduleInitialRespawn(e);
 543         }
 544 }
 545
 546 void Item_Reset()
 547 {
 548         Item_Show(self, !self.state);
 549         setorigin (self, self.origin);
 550         self.think = SUB_Null;
 551         self.nextthink = 0;
 552
 553         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 554                 Item_ScheduleInitialRespawn(self);
 555 }
 556
 557 // Savage: used for item garbage-collection
 558 // TODO: perhaps nice special effect?
 559 void RemoveItem(void)
 560 {
 561         remove(self);
 562 }
 563
 564 // pickup evaluation functions
 565 // these functions decide how desirable an item is to the bots
 566
 567 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 568
 569 float weapon_pickupevalfunc(entity player, entity item)
 570 {
 571         float c, i, j, position;
 572
 573         // See if I have it already
 574         if(player.weapons & item.weapons == item.weapons)
 575         {
 576                 // If I can pick it up
 577                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 578                         c = 0;
 579                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 580                 {
 581                         // Skilled bots will grab more
 582                         c = bound(0, skill / 10, 1) * 0.5;
 583                 }
 584                 else
 585                         c = 0;
 586         }
 587         else
 588                 c = 1;
 589
 590         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 591         if( bot_custom_weapon && c )
 592         {
 593                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 594                 {
 595                         // Find weapon
 596                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 597                                 continue;
 598
 599                         // Find the highest position on any range
 600                         position = -1;
 601                         for(j = 0; j < WEP_LAST ; ++j){
 602                                 if(
 603                                                 bot_weapons_far[j] == i ||
 604                                                 bot_weapons_mid[j] == i ||
 605                                                 bot_weapons_close[j] == i
 606                                   )
 607                                 {
 608                                         position = j;
 609                                         break;
 610                                 }
 611                         }
 612
 613                         // Rate it
 614                         if (position >= 0 )
 615                         {
 616                                 position = WEP_LAST - position;
 617                                 // item.bot_pickupbasevalue is overwritten here
 618                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 619                         }
 620                 }
 621         }
 622
 623         return item.bot_pickupbasevalue * c;
 624 };
 625
 626 float commodity_pickupevalfunc(entity player, entity item)
 627 {
 628         float c, i, need_shells, need_nails, need_rockets, need_cells;
 629         entity wi;
 630         c = 0;
 631
 632         // Detect needed ammo
 633         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 634         {
 635                 wi = get_weaponinfo(i);
 636
 637                 if not(wi.weapons & player.weapons)
 638                         continue;
 639
 640                 if(wi.items & IT_SHELLS)
 641                         need_shells = TRUE;
 642                 else if(wi.items & IT_NAILS)
 643                         need_nails = TRUE;
 644                 else if(wi.items & IT_ROCKETS)
 645                         need_rockets = TRUE;
 646                 else if(wi.items & IT_CELLS)
 647                         need_cells = TRUE;
 648         }
 649
 650         // TODO: figure out if the player even has the weapon this ammo is for?
 651         // may not affect strategy much though...
 652         // find out how much more ammo/armor/health the player can hold
 653         if (need_shells)
 654         if (item.ammo_shells)
 655         if (player.ammo_shells < g_pickup_shells_max)
 656                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 657         if (need_nails)
 658         if (item.ammo_nails)
 659         if (player.ammo_nails < g_pickup_nails_max)
 660                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 661         if (need_rockets)
 662         if (item.ammo_rockets)
 663         if (player.ammo_rockets < g_pickup_rockets_max)
 664                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 665         if (need_cells)
 666         if (item.ammo_cells)
 667         if (player.ammo_cells < g_pickup_cells_max)
 668                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 669         if (item.armorvalue)
 670         if (player.armorvalue < item.max_armorvalue)
 671                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 672         if (item.health)
 673         if (player.health < item.max_health)
 674                 c = c + max(0, 1 - player.health / item.max_health);
 675
 676         return item.bot_pickupbasevalue * c;
 677 };
 678
 679
 680 .float is_item;
 681 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 682 {
 683         startitem_failed = FALSE;
 684
 685         self.items = itemid;
 686         self.weapons = weaponid;
 687
 688         // is it a dropped weapon?
 689         if (self.classname == "droppedweapon")
 690         {
 691                 self.reset = SUB_Remove;
 692                 // it's a dropped weapon
 693                 self.movetype = MOVETYPE_TOSS;
 694                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 695                 self.think = RemoveItem;
 696                 self.nextthink = time + 60;
 697                 // don't drop if in a NODROP zone (such as lava)
 698                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 699                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 700                 {
 701                         startitem_failed = TRUE;
 702                         remove(self);
 703                         return;
 704                 }
 705         }
 706         else
 707         {
 708                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 709                 {
 710                         startitem_failed = TRUE;
 711                         remove(self);
 712                         return;
 713                 }
 714
 715                 self.reset = Item_Reset;
 716                 // it's a level item
 717                 if(self.spawnflags & 1)
 718                         self.noalign = 1;
 719                 if (self.noalign)
 720                         self.movetype = MOVETYPE_NONE;
 721                 else
 722                         self.movetype = MOVETYPE_TOSS;
 723                 // do item filtering according to game mode and other things
 724                 if (!self.noalign)
 725                 {
 726                         // first nudge it off the floor a little bit to avoid math errors
 727                         setorigin(self, self.origin + '0 0 1');
 728                         // set item size before we spawn a spawnfunc_waypoint
 729                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 730                                 setsize (self, '-16 -16 0', '16 16 48');
 731                         else
 732                                 setsize (self, '-16 -16 0', '16 16 32');
 733                         // note droptofloor returns FALSE if stuck/or would fall too far
 734                         droptofloor();
 735                         waypoint_spawnforitem(self);
 736                 }
 737
 738                 if(teams_matter)
 739                 {
 740                         if(self.notteam)
 741                         {
 742                                 print("removed non-teamplay ", self.classname, "\n");
 743                                 startitem_failed = TRUE;
 744                                 remove (self);
 745                                 return;
 746                         }
 747                 }
 748                 else
 749                 {
 750                         if(self.notfree)
 751                         {
 752                                 print("removed non-FFA ", self.classname, "\n");
 753                                 startitem_failed = TRUE;
 754                                 remove (self);
 755                                 return;
 756                         }
 757                 }
 758
 759                 if(self.notq3a)
 760                 {
 761                         // We aren't TA or something like that, so we keep the Q3A entities
 762                         print("removed non-Q3A ", self.classname, "\n");
 763                         startitem_failed = TRUE;
 764                         remove (self);
 765                         return;
 766                 }
 767
 768                 /*
 769                  * can't do it that way, as it would break maps
 770                  * TODO make a target_give like entity another way, that perhaps has
 771                  * the weapon name in a key
 772                 if(self.targetname)
 773                 {
 774                         // target_give not yet supported; maybe later
 775                         print("removed targeted ", self.classname, "\n");
 776                         startitem_failed = TRUE;
 777                         remove (self);
 778                         return;
 779                 }
 780                 */
 781
 782                 if(autocvar_spawn_debug >= 2)
 783                 {
 784                         entity otheritem;
 785                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 786                         {
 787                                 if(otheritem.is_item)
 788                                 {
 789                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 790                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 791                                         error("Mapper sucks.");
 792                                 }
 793                         }
 794                         self.is_item = TRUE;
 795                 }
 796
 797                 if(g_lms || g_ca)
 798                 {
 799                         startitem_failed = TRUE;
 800                         remove(self);
 801                         return;
 802                 }
 803                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 804                 {
 805                         startitem_failed = TRUE;
 806                         remove(self);
 807                         return;
 808                 }
 809                 else if (g_minstagib)
 810                 {
 811                         // don't remove dropped items and powerups
 812                         if (self.classname != "minstagib")
 813                         {
 814                                 startitem_failed = TRUE;
 815                                 remove (self);
 816                                 return;
 817                         }
 818                 }
 819                 else if (!autocvar_g_pickup_items && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 820                 {
 821                         startitem_failed = TRUE;
 822                         remove (self);
 823                         return;
 824                 }
 825
 826                 weaponsInMap |= weaponid;
 827
 828                 precache_model (itemmodel);
 829                 precache_sound (pickupsound);
 830
 831                 precache_sound ("misc/itemrespawncountdown.wav");
 832                 if(!g_minstagib && itemid == IT_STRENGTH)
 833                         precache_sound ("misc/strength_respawn.wav");
 834                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 835                         precache_sound ("misc/shield_respawn.wav");
 836                 else
 837                         precache_sound ("misc/itemrespawn.wav");
 838
 839                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 840                         self.target = "###item###"; // for finding the nearest item using find()
 841         }
 842
 843         self.bot_pickup = TRUE;
 844         self.bot_pickupevalfunc = pickupevalfunc;
 845         self.bot_pickupbasevalue = pickupbasevalue;
 846         self.mdl = itemmodel;
 847         self.item_pickupsound = pickupsound;
 848         // let mappers override respawntime
 849         if(!self.respawntime) // both set
 850         {
 851                 self.respawntime = defaultrespawntime;
 852                 self.respawntimejitter = defaultrespawntimejitter;
 853         }
 854         self.netname = itemname;
 855         self.flags = FL_ITEM | itemflags;
 856         self.touch = Item_Touch;
 857         setmodel (self, self.mdl); // precision set below
 858         self.effects |= EF_LOWPRECISION;
 859         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 860                 setsize (self, '-16 -16 0', '16 16 48');
 861         else
 862                 setsize (self, '-16 -16 0', '16 16 32');
 863         if(itemflags & FL_WEAPON)
 864                 self.modelflags |= MF_ROTATE;
 865
 866         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 867         if (itemflags & FL_WEAPON)
 868         {
 869                 // neutral team color for pickup weapons
 870                 self.colormap = 1024; // color shirt=0 pants=0 grey
 871         }
 872
 873         Item_Show(self, 1);
 874         self.state = 0;
 875         if(self.team)
 876         {
 877                 if(!self.cnt)
 878                         self.cnt = 1; // item probability weight
 879                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 880                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 881         }
 882         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 883                 Item_ScheduleInitialRespawn(self);
 884 }
 885
 886 /* replace items in minstagib
 887  * IT_STRENGTH   = invisibility
 888  * IT_NAILS      = extra lives
 889  * IT_INVINCIBLE = speed
 890  */
 891 void minstagib_items (float itemid)
 892 {
 893         local float rnd;
 894         self.classname = "minstagib";
 895
 896         // replace rocket launchers and nex guns with ammo cells
 897         if (itemid == IT_CELLS)
 898         {
 899                 self.ammo_cells = 1;
 900                 StartItem ("models/items/a_cells.md3",
 901                         "misc/itempickup.wav", 45, 0,
 902                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 903                 return;
 904         }
 905
 906         // randomize
 907         rnd = random() * 3;
 908         if (rnd <= 1)
 909                 itemid = IT_STRENGTH;
 910         else if (rnd <= 2)
 911                 itemid = IT_NAILS;
 912         else
 913                 itemid = IT_INVINCIBLE;
 914
 915         // replace with invis
 916         if (itemid == IT_STRENGTH)
 917         {
 918                 self.strength_finished = 30;
 919                 StartItem ("models/items/g_strength.md3",
 920                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 921                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 922         }
 923         // replace with extra lives
 924         if (itemid == IT_NAILS)
 925         {
 926                 self.max_health = 1;
 927                 StartItem ("models/items/g_h100.md3",
 928                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 929                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 930         }
 931         // replace with speed
 932         if (itemid == IT_INVINCIBLE)
 933         {
 934                 self.invincible_finished = 30;
 935                 StartItem ("models/items/g_invincible.md3",
 936                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 937                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 938         }
 939 }
 940
 941 float minst_no_auto_cells;
 942 void minst_remove_item (void) {
 943         if(minst_no_auto_cells)
 944                 remove(self);
 945 }
 946
 947 float weaponswapping;
 948 float internalteam;
 949
 950 void weapon_defaultspawnfunc(float wpn)
 951 {
 952         entity e;
 953         float t;
 954         var .float ammofield;
 955         string s;
 956         entity oldself;
 957         float i, j;
 958
 959         // set the respawntime in advance (so replaced weapons can copy it)
 960
 961         if(!self.respawntime)
 962         {
 963                 e = get_weaponinfo(wpn);
 964                 if(e.items == IT_SUPERWEAPON)
 965                 {
 966                         self.respawntime = g_pickup_respawntime_powerup;
 967                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 968                 }
 969                 else
 970                 {
 971                         self.respawntime = g_pickup_respawntime_weapon;
 972                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 973                 }
 974         }
 975
 976         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 977         {
 978                 e = get_weaponinfo(wpn);
 979                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 980                 if(s == "0")
 981                 {
 982                         remove(self);
 983                         startitem_failed = TRUE;
 984                         return;
 985                 }
 986                 t = tokenize_console(s);
 987                 if(t >= 2)
 988                 {
 989                         self.team = --internalteam;
 990                         oldself = self;
 991                         for(i = 1; i < t; ++i)
 992                         {
 993                                 s = argv(i);
 994                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 995                                 {
 996                                         e = get_weaponinfo(j);
 997                                         if(e.netname == s)
 998                                         {
 999                                                 self = spawn();
1000                                                 copyentity(oldself, self);
1001                                                 self.classname = "replacedweapon";
1002                                                 weapon_defaultspawnfunc(j);
1003                                                 break;
1004                                         }
1005                                 }
1006                                 if(j > WEP_LAST)
1007                                 {
1008                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1009                                 }
1010                         }
1011                         self = oldself;
1012                 }
1013                 if(t >= 1)
1014                 {
1015                         s = argv(0);
1016                         wpn = 0;
1017                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1018                         {
1019                                 e = get_weaponinfo(j);
1020                                 if(e.netname == s)
1021                                 {
1022                                         wpn = j;
1023                                         break;
1024                                 }
1025                         }
1026                         if(j > WEP_LAST)
1027                         {
1028                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1029                         }
1030                 }
1031                 if(wpn == 0)
1032                 {
1033                         remove(self);
1034                         startitem_failed = TRUE;
1035                         return;
1036                 }
1037         }
1038
1039         e = get_weaponinfo(wpn);
1040
1041         if(e.items && e.items != IT_SUPERWEAPON)
1042         {
1043                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1044                 {
1045                         if(e.items & j)
1046                         {
1047                                 ammofield = Item_CounterField(j);
1048                                 if(!self.ammofield)
1049                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1050                         }
1051                 }
1052         }
1053         else
1054         {
1055                 self.flags |= FL_NO_WEAPON_STAY;
1056         }
1057
1058         // weapon stay isn't supported for teamed weapons
1059         if(self.team)
1060                 self.flags |= FL_NO_WEAPON_STAY;
1061
1062         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1063         {
1064                 self.ammo_shells = 0;
1065                 self.ammo_nails = 0;
1066                 self.ammo_cells = 0;
1067                 self.ammo_rockets = 0;
1068                 // weapon stay 2: don't use ammo on weapon pickups; instead
1069                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1070         }
1071
1072         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1073         if (self.modelindex) // don't precache if self was removed
1074                 weapon_action(e.weapon, WR_PRECACHE);
1075 }
1076
1077 void spawnfunc_weapon_shotgun (void);
1078 void spawnfunc_weapon_uzi (void) {
1079         if(q3acompat_machineshotgunswap)
1080         if(self.classname != "droppedweapon")
1081         {
1082                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1083                 return;
1084         }
1085         weapon_defaultspawnfunc(WEP_UZI);
1086 }
1087
1088 void spawnfunc_weapon_shotgun (void) {
1089         if(q3acompat_machineshotgunswap)
1090         if(self.classname != "droppedweapon")
1091         {
1092                 weapon_defaultspawnfunc(WEP_UZI);
1093                 return;
1094         }
1095         weapon_defaultspawnfunc(WEP_SHOTGUN);
1096 }
1097
1098 void spawnfunc_weapon_nex (void)
1099 {
1100         if (g_minstagib)
1101         {
1102                 minstagib_items(IT_CELLS);
1103                 self.think = minst_remove_item;
1104                 self.nextthink = time;
1105                 return;
1106         }
1107         weapon_defaultspawnfunc(WEP_NEX);
1108 }
1109
1110 void spawnfunc_weapon_minstanex (void)
1111 {
1112         if (g_minstagib)
1113         {
1114                 minstagib_items(IT_CELLS);
1115                 self.think = minst_remove_item;
1116                 self.nextthink = time;
1117                 return;
1118         }
1119         weapon_defaultspawnfunc(WEP_MINSTANEX);
1120 }
1121
1122 void spawnfunc_weapon_rocketlauncher (void)
1123 {
1124         if (g_minstagib)
1125         {
1126                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1127                 self.think = minst_remove_item;
1128                 self.nextthink = time;
1129                 return;
1130         }
1131         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1132 }
1133
1134 void spawnfunc_item_rockets (void) {
1135         if(!self.ammo_rockets)
1136                 self.ammo_rockets = g_pickup_rockets;
1137         if(!self.pickup_anyway)
1138                 self.pickup_anyway = g_pickup_ammo_anyway;
1139         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1140 }
1141
1142 void spawnfunc_item_shells (void);
1143 void spawnfunc_item_bullets (void) {
1144         if(!weaponswapping)
1145         if(q3acompat_machineshotgunswap)
1146         if(self.classname != "droppedweapon")
1147         {
1148                 weaponswapping = TRUE;
1149                 spawnfunc_item_shells();
1150                 weaponswapping = FALSE;
1151                 return;
1152         }
1153
1154         if(!self.ammo_nails)
1155                 self.ammo_nails = g_pickup_nails;
1156         if(!self.pickup_anyway)
1157                 self.pickup_anyway = g_pickup_ammo_anyway;
1158         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1159 }
1160
1161 void spawnfunc_item_cells (void) {
1162         if(!self.ammo_cells)
1163                 self.ammo_cells = g_pickup_cells;
1164         if(!self.pickup_anyway)
1165                 self.pickup_anyway = g_pickup_ammo_anyway;
1166         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1167 }
1168
1169 void spawnfunc_item_shells (void) {
1170         if(!weaponswapping)
1171         if(q3acompat_machineshotgunswap)
1172         if(self.classname != "droppedweapon")
1173         {
1174                 weaponswapping = TRUE;
1175                 spawnfunc_item_bullets();
1176                 weaponswapping = FALSE;
1177                 return;
1178         }
1179
1180         if(!self.ammo_shells)
1181                 self.ammo_shells = g_pickup_shells;
1182         if(!self.pickup_anyway)
1183                 self.pickup_anyway = g_pickup_ammo_anyway;
1184         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1185 }
1186
1187 void spawnfunc_item_armor_small (void) {
1188         if(!self.armorvalue)
1189                 self.armorvalue = g_pickup_armorsmall;
1190         if(!self.max_armorvalue)
1191                 self.max_armorvalue = g_pickup_armorsmall_max;
1192         if(!self.pickup_anyway)
1193                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1194         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1195 }
1196
1197 void spawnfunc_item_armor_medium (void) {
1198         if(!self.armorvalue)
1199                 self.armorvalue = g_pickup_armormedium;
1200         if(!self.max_armorvalue)
1201                 self.max_armorvalue = g_pickup_armormedium_max;
1202         if(!self.pickup_anyway)
1203                 self.pickup_anyway = g_pickup_armormedium_anyway;
1204         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1205 }
1206
1207 void spawnfunc_item_armor_big (void) {
1208         if(!self.armorvalue)
1209                 self.armorvalue = g_pickup_armorbig;
1210         if(!self.max_armorvalue)
1211                 self.max_armorvalue = g_pickup_armorbig_max;
1212         if(!self.pickup_anyway)
1213                 self.pickup_anyway = g_pickup_armorbig_anyway;
1214         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1215 }
1216
1217 void spawnfunc_item_armor_large (void) {
1218         if(!self.armorvalue)
1219                 self.armorvalue = g_pickup_armorlarge;
1220         if(!self.max_armorvalue)
1221                 self.max_armorvalue = g_pickup_armorlarge_max;
1222         if(!self.pickup_anyway)
1223                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1224         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1225 }
1226
1227 void spawnfunc_item_health_small (void) {
1228         if(!self.max_health)
1229                 self.max_health = g_pickup_healthsmall_max;
1230         if(!self.health)
1231                 self.health = g_pickup_healthsmall;
1232         if(!self.pickup_anyway)
1233                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1234         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1235 }
1236
1237 void spawnfunc_item_health_medium (void) {
1238         if(!self.max_health)
1239                 self.max_health = g_pickup_healthmedium_max;
1240         if(!self.health)
1241                 self.health = g_pickup_healthmedium;
1242         if(!self.pickup_anyway)
1243                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1244         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1245 }
1246
1247 void spawnfunc_item_health_large (void) {
1248         if(!self.max_health)
1249                 self.max_health = g_pickup_healthlarge_max;
1250         if(!self.health)
1251                 self.health = g_pickup_healthlarge;
1252         if(!self.pickup_anyway)
1253                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1254         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1255 }
1256
1257 void spawnfunc_item_health_mega (void) {
1258         if(!autocvar_g_powerup_superhealth)
1259                 return;
1260
1261         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1262                 return;
1263
1264         if(g_minstagib) {
1265                 minstagib_items(IT_NAILS);
1266         } else {
1267                 if(!self.max_health)
1268                         self.max_health = g_pickup_healthmega_max;
1269                 if(!self.health)
1270                         self.health = g_pickup_healthmega;
1271                 if(!self.pickup_anyway)
1272                         self.pickup_anyway = g_pickup_healthmega_anyway;
1273                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1274         }
1275 }
1276
1277 // support old misnamed entities
1278 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1279 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1280 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1281 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1282 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1283
1284 void spawnfunc_item_strength (void) {
1285         if(!autocvar_g_powerup_strength)
1286                 return;
1287
1288         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1289                 return;
1290
1291         if(g_minstagib) {
1292                 minstagib_items(IT_STRENGTH);
1293         } else {
1294                 precache_sound("weapons/strength_fire.wav");
1295                 self.strength_finished = 30;
1296                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1297         }
1298 }
1299
1300 void spawnfunc_item_invincible (void) {
1301         if(!autocvar_g_powerup_shield)
1302                 return;
1303
1304         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1305                 return;
1306
1307         if(g_minstagib) {
1308                 minstagib_items(IT_INVINCIBLE);
1309         } else {
1310                 self.invincible_finished = 30;
1311                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1312         }
1313 }
1314
1315 void spawnfunc_item_minst_cells (void) {
1316         if (g_minstagib)
1317         {
1318                 minst_no_auto_cells = 1;
1319                 minstagib_items(IT_CELLS);
1320         }
1321         else
1322                 remove(self);
1323 }
1324
1325 // compatibility:
1326 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1327
1328 float GiveItems(entity e, float beginarg, float endarg);
1329 void target_items_use (void)
1330 {
1331         if(activator.classname == "droppedweapon")
1332         {
1333                 EXACTTRIGGER_TOUCH;
1334                 remove(activator);
1335                 return;
1336         }
1337
1338         if(activator.classname != "player")
1339                 return;
1340         if(activator.deadflag != DEAD_NO)
1341                 return;
1342         EXACTTRIGGER_TOUCH;
1343
1344         entity e;
1345         for(e = world; (e = find(e, classname, "droppedweapon")); )
1346                 if(e.enemy == activator)
1347                         remove(e);
1348
1349         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1350                 centerprint(activator, self.message);
1351 }
1352
1353 void spawnfunc_target_items (void)
1354 {
1355         float n, i, j;
1356         entity e;
1357
1358         self.use = target_items_use;
1359         if(!self.strength_finished)
1360                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1361         if(!self.invincible_finished)
1362                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1363
1364         precache_sound("misc/itempickup.wav");
1365         precache_sound("misc/megahealth.wav");
1366         precache_sound("misc/armor25.wav");
1367         precache_sound("misc/powerup.wav");
1368         precache_sound("misc/poweroff.wav");
1369         precache_sound("weapons/weaponpickup.wav");
1370
1371         n = tokenize_console(self.netname);
1372         if(argv(0) == "give")
1373         {
1374                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1375         }
1376         else
1377         {
1378                 for(i = 0; i < n; ++i)
1379                 {
1380                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1381                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1382                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1383                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1384                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1385                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1386                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1387                         else
1388                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1389                         {
1390                                 e = get_weaponinfo(j);
1391                                 if(argv(i) == e.netname)
1392                                 {
1393                                         self.weapons |= e.weapons;
1394                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1395                                                 weapon_action(e.weapon, WR_PRECACHE);
1396                                         break;
1397                                 }
1398                         }
1399                         if(j > WEP_LAST)
1400                                 print("target_items: invalid item ", argv(i), "\n");
1401                 }
1402
1403                 string itemprefix, valueprefix;
1404                 if(self.spawnflags == 0)
1405                 {
1406                         itemprefix = "";
1407                         valueprefix = "";
1408                 }
1409                 else if(self.spawnflags == 1)
1410                 {
1411                         itemprefix = "max ";
1412                         valueprefix = "max ";
1413                 }
1414                 else if(self.spawnflags == 2)
1415                 {
1416                         itemprefix = "min ";
1417                         valueprefix = "min ";
1418                 }
1419                 else if(self.spawnflags == 4)
1420                 {
1421                         itemprefix = "minus ";
1422                         valueprefix = "max ";
1423                 }
1424                 else
1425                         error("invalid spawnflags");
1426
1427                 self.netname = "";
1428                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1429                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1430                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1431                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1432                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1433                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1434                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1435                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1436                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1437                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1438                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1439                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1440                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1441                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1442                 {
1443                         e = get_weaponinfo(j);
1444                         if(e.weapons)
1445                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1446                 }
1447         }
1448         self.netname = strzone(self.netname);
1449         //print(self.netname, "\n");
1450
1451         n = tokenize_console(self.netname);
1452         for(i = 0; i < n; ++i)
1453         {
1454                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1455                 {
1456                         e = get_weaponinfo(j);
1457                         if(argv(i) == e.netname)
1458                         {
1459                                 weapon_action(e.weapon, WR_PRECACHE);
1460                                 break;
1461                         }
1462                 }
1463         }
1464 }
1465
1466 void spawnfunc_item_fuel(void)
1467 {
1468         if(!self.ammo_fuel)
1469                 self.ammo_fuel = g_pickup_fuel;
1470         if(!self.pickup_anyway)
1471                 self.pickup_anyway = g_pickup_ammo_anyway;
1472         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1473 }
1474
1475 void spawnfunc_item_fuel_regen(void)
1476 {
1477         if(start_items & IT_FUEL_REGEN)
1478         {
1479                 spawnfunc_item_fuel();
1480                 return;
1481         }
1482         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1483 }
1484
1485 void spawnfunc_item_jetpack(void)
1486 {
1487         if(g_grappling_hook)
1488                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1489         if(!self.ammo_fuel)
1490                 self.ammo_fuel = g_pickup_fuel_jetpack;
1491         if(start_items & IT_JETPACK)
1492         {
1493                 spawnfunc_item_fuel();
1494                 return;
1495         }
1496         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1497 }
1498
1499
1500 #define OP_SET 0
1501 #define OP_MIN 1
1502 #define OP_MAX 2
1503 #define OP_PLUS 3
1504 #define OP_MINUS 4
1505
1506 float GiveBit(entity e, .float fld, float bit, float op, float val)
1507 {
1508         float v0, v1;
1509         v0 = (e.fld & bit);
1510         switch(op)
1511         {
1512                 case OP_SET:
1513                         if(val > 0)
1514                                 e.fld |= bit;
1515                         else
1516                                 e.fld &~= bit;
1517                         break;
1518                 case OP_MIN:
1519                 case OP_PLUS:
1520                         if(val > 0)
1521                                 e.fld |= bit;
1522                         break;
1523                 case OP_MAX:
1524                         if(val <= 0)
1525                                 e.fld &~= bit;
1526                         break;
1527                 case OP_MINUS:
1528                         if(val > 0)
1529                                 e.fld &~= bit;
1530                         break;
1531         }
1532         v1 = (e.fld & bit);
1533         return (v0 != v1);
1534 }
1535
1536 float GiveValue(entity e, .float fld, float op, float val)
1537 {
1538         float v0, v1;
1539         v0 = e.fld;
1540         switch(op)
1541         {
1542                 case OP_SET:
1543                         e.fld = val;
1544                         break;
1545                 case OP_MIN:
1546                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1547                         break;
1548                 case OP_MAX:
1549                         e.fld = min(e.fld, val);
1550                         break;
1551                 case OP_PLUS:
1552                         e.fld += val;
1553                         break;
1554                 case OP_MINUS:
1555                         e.fld -= val;
1556                         break;
1557         }
1558         v1 = e.fld;
1559         return (v0 != v1);
1560 }
1561
1562 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1563 {
1564         if(v1 == v0)
1565                 return;
1566         if(v1 <= v0 - t)
1567         {
1568                 if(snd_decr != "")
1569                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1570         }
1571         else if(v0 >= v0 + t)
1572         {
1573                 if(snd_incr != "")
1574                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1575         }
1576 }
1577
1578 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1579 {
1580         if(v0 < v1)
1581                 e.rotfield = max(e.rotfield, time + rottime);
1582         else if(v0 > v1)
1583                 e.regenfield = max(e.regenfield, time + regentime);
1584 }
1585
1586 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1587 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1588 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1589 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1590
1591 float GiveItems(entity e, float beginarg, float endarg)
1592 {
1593         float got, i, j, val, op;
1594         float _switchweapon;
1595         entity wi;
1596         string cmd;
1597
1598         val = 999;
1599         op = OP_SET;
1600
1601         got = 0;
1602
1603         _switchweapon = FALSE;
1604         if (e.autoswitch)
1605                 if (e.switchweapon == w_getbestweapon(e))
1606                         _switchweapon = TRUE;
1607
1608         e.strength_finished = max(0, e.strength_finished - time);
1609         e.invincible_finished = max(0, e.invincible_finished - time);
1610
1611         PREGIVE(e, items);
1612         PREGIVE(e, weapons);
1613         PREGIVE(e, strength_finished);
1614         PREGIVE(e, invincible_finished);
1615         PREGIVE(e, ammo_nails);
1616         PREGIVE(e, ammo_cells);
1617         PREGIVE(e, ammo_shells);
1618         PREGIVE(e, ammo_rockets);
1619         PREGIVE(e, ammo_fuel);
1620         PREGIVE(e, armorvalue);
1621         PREGIVE(e, health);
1622
1623         for(i = beginarg; i < endarg; ++i)
1624         {
1625                 cmd = argv(i);
1626
1627                 if(cmd == "0" || stof(cmd))
1628                 {
1629                         val = stof(cmd);
1630                         continue;
1631                 }
1632                 switch(cmd)
1633                 {
1634                         case "no":
1635                                 op = OP_MAX;
1636                                 val = 0;
1637                                 continue;
1638                         case "max":
1639                                 op = OP_MAX;
1640                                 continue;
1641                         case "min":
1642                                 op = OP_MIN;
1643                                 continue;
1644                         case "plus":
1645                                 op = OP_PLUS;
1646                                 continue;
1647                         case "minus":
1648                                 op = OP_MINUS;
1649                                 continue;
1650                         case "ALL":
1651                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1652                                 got += GiveValue(e, strength_finished, op, time);
1653                                 got += GiveValue(e, invincible_finished, op, time);
1654                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1655                         case "all":
1656                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1657                                 got += GiveValue(e, health, op, val);
1658                                 got += GiveValue(e, armorvalue, op, val);
1659                         case "allweapons":
1660                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1661                                 {
1662                                         wi = get_weaponinfo(j);
1663                                         if(wi.weapons)
1664                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1665                                 }
1666                         case "allammo":
1667                                 got += GiveValue(e, ammo_cells, op, val);
1668                                 got += GiveValue(e, ammo_shells, op, val);
1669                                 got += GiveValue(e, ammo_nails, op, val);
1670                                 got += GiveValue(e, ammo_rockets, op, val);
1671                                 got += GiveValue(e, ammo_fuel, op, val);
1672                                 break;
1673                         case "unlimited_ammo":
1674                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1675                                 break;
1676                         case "unlimited_weapon_ammo":
1677                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1678                                 break;
1679                         case "unlimited_superweapons":
1680                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1681                                 break;
1682                         case "jetpack":
1683                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1684                                 break;
1685                         case "fuel_regen":
1686                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1687                                 break;
1688                         case "strength":
1689                                 got += GiveValue(e, strength_finished, op, val);
1690                                 break;
1691                         case "invincible":
1692                                 got += GiveValue(e, invincible_finished, op, val);
1693                                 break;
1694                         case "cells":
1695                                 got += GiveValue(e, ammo_cells, op, val);
1696                                 break;
1697                         case "shells":
1698                                 got += GiveValue(e, ammo_shells, op, val);
1699                                 break;
1700                         case "nails":
1701                         case "bullets":
1702                                 got += GiveValue(e, ammo_nails, op, val);
1703                                 break;
1704                         case "rockets":
1705                                 got += GiveValue(e, ammo_rockets, op, val);
1706                                 break;
1707                         case "health":
1708                                 got += GiveValue(e, health, op, val);
1709                                 break;
1710                         case "armor":
1711                                 got += GiveValue(e, armorvalue, op, val);
1712                                 break;
1713                         case "fuel":
1714                                 got += GiveValue(e, ammo_fuel, op, val);
1715                                 break;
1716                         default:
1717                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1718                                 {
1719                                         wi = get_weaponinfo(j);
1720                                         if(cmd == wi.netname)
1721                                         {
1722                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1723                                                 break;
1724                                         }
1725                                 }
1726                                 if(j > WEP_LAST)
1727                                         print("give: invalid item ", cmd, "\n");
1728                                 break;
1729                 }
1730                 val = 999;
1731                 op = OP_SET;
1732         }
1733
1734         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1735         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1736         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1737         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1738         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1739         {
1740                 wi = get_weaponinfo(j);
1741                 if(wi.weapons)
1742                 {
1743                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1744                         if not(save_weapons & wi.weapons)
1745                                 if(e.weapons & wi.weapons)
1746                                         weapon_action(wi.weapon, WR_PRECACHE);
1747                 }
1748         }
1749         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1750         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1751         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1752         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1753         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1754         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1755         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1756         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1757         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1758
1759         if (g_minstagib)
1760         {
1761                 e.health = bound(0, e.health, 100);
1762                 e.armorvalue = bound(0, e.armorvalue, 999);
1763         }
1764
1765         if(e.strength_finished <= 0)
1766                 e.strength_finished = 0;
1767         else
1768                 e.strength_finished += time;
1769         if(e.invincible_finished <= 0)
1770                 e.invincible_finished = 0;
1771         else
1772                 e.invincible_finished += time;
1773
1774         if not(e.weapons & W_WeaponBit(e.switchweapon))
1775                 _switchweapon = TRUE;
1776         if(_switchweapon)
1777                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1778
1779         return got;
1780 }