qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || (e.weapons & WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         player.health = 100;
 383                 }
 384
 385                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 386                 {
 387                         pickedup = TRUE;
 388                         player.items |= it;
 389                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 390                 }
 391
 392                 // extralife powerup
 393                 if (item.max_health)
 394                 {
 395                         pickedup = TRUE;
 396                         // sound not available
 397                         // AnnounceTo(player, "_lives");
 398                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 399                         sprint(player, "^3You picked up some extra lives\n");
 400                 }
 401
 402                 // invis powerup
 403                 if (item.strength_finished)
 404                 {
 405                         pickedup = TRUE;
 406                         // sound not available
 407                         // AnnounceTo(player, "invisible");
 408                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 409                 }
 410
 411                 // speed powerup
 412                 if (item.invincible_finished)
 413                 {
 414                         pickedup = TRUE;
 415                         // sound not available
 416                         // AnnounceTo(player, "speed");
 417                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 418                 }
 419         }
 420         else
 421         {
 422                 // in case the player has autoswitch enabled do the following:
 423                 // if the player is using their best weapon before items are given, they
 424                 // probably want to switch to an even better weapon after items are given
 425                 if (player.autoswitch)
 426                 if (player.switchweapon == w_getbestweapon(player))
 427                         _switchweapon = TRUE;
 428
 429                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 430                         _switchweapon = TRUE;
 431
 432                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 438                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 439
 440                 if (item.flags & FL_WEAPON)
 441                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && self.pickup_anyway))
 442                 {
 443                         pickedup = TRUE;
 444                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 445                         {
 446                                 e = get_weaponinfo(i);
 447                                 if(it & e.weapons)
 448                                         W_GiveWeapon (player, e.weapon, item.netname);
 449                         }
 450                 }
 451
 452                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 453                 {
 454                         pickedup = TRUE;
 455                         player.items |= it;
 456                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 457                 }
 458
 459                 if (item.strength_finished)
 460                 {
 461                         pickedup = TRUE;
 462                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 463                 }
 464                 if (item.invincible_finished)
 465                 {
 466                         pickedup = TRUE;
 467                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 468                 }
 469                 if (item.superweapons_finished)
 470                 {
 471                         pickedup = TRUE;
 472                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 473                 }
 474         }
 475
 476 :skip
 477         // always eat teamed entities
 478         if(item.team)
 479                 pickedup = TRUE;
 480
 481         if (!pickedup)
 482                 return 0;
 483
 484         if (_switchweapon)
 485                 if (player.switchweapon != w_getbestweapon(player))
 486                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 487
 488         return 1;
 489 }
 490
 491 void Item_Touch (void)
 492 {
 493         entity e, head;
 494
 495         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 496         if(self.classname == "droppedweapon")
 497         {
 498                 if (ITEM_TOUCH_NEEDKILL())
 499                 {
 500                         remove(self);
 501                         return;
 502                 }
 503         }
 504
 505         if (other.classname != "player")
 506                 return;
 507         if (other.deadflag)
 508                 return;
 509         if (self.solid != SOLID_TRIGGER)
 510                 return;
 511         if (self.owner == other)
 512                 return;
 513
 514         if (self.classname == "droppedweapon")
 515         {
 516                 self.strength_finished = max(0, self.strength_finished - time);
 517                 self.invincible_finished = max(0, self.invincible_finished - time);
 518                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 519         }
 520
 521         if(!Item_GiveTo(self, other))
 522         {
 523                 if (self.classname == "droppedweapon")
 524                 {
 525                         // undo what we did above
 526                         self.strength_finished += time;
 527                         self.invincible_finished += time;
 528                         self.superweapons_finished += time;
 529                 }
 530                 return;
 531         }
 532
 533         other.last_pickup = time;
 534
 535         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 536         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 537
 538         if (self.classname == "droppedweapon")
 539                 remove (self);
 540         else if not(self.spawnshieldtime)
 541                 return;
 542         else
 543         {
 544                 if(self.team)
 545                 {
 546                         RandomSelection_Init();
 547                         for(head = world; (head = findfloat(head, team, self.team)); )
 548                         {
 549                                 if(head.flags & FL_ITEM)
 550                                 {
 551                                         Item_Show(head, -1);
 552                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 553                                 }
 554                         }
 555                         e = RandomSelection_chosen_ent;
 556                 }
 557                 else
 558                         e = self;
 559                 Item_ScheduleRespawn(e);
 560         }
 561 }
 562
 563 void Item_Reset()
 564 {
 565         Item_Show(self, !self.state);
 566         setorigin (self, self.origin);
 567
 568         if(self.classname != "droppedweapon")
 569         {
 570                 self.think = SUB_Null;
 571                 self.nextthink = 0;
 572
 573                 if(self.waypointsprite_attached)
 574                         WaypointSprite_Kill(self.waypointsprite_attached);
 575
 576                 if((self.flags & FL_POWERUP) | (self.weapons & WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 577                         Item_ScheduleInitialRespawn(self);
 578         }
 579 }
 580
 581 void Item_FindTeam()
 582 {
 583         entity head, e;
 584
 585         if(self.effects & EF_NODRAW)
 586         {
 587                 // marker for item team search
 588                 dprint("Initializing item team ", ftos(self.team), "\n");
 589                 RandomSelection_Init();
 590                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 591                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 592                 e = RandomSelection_chosen_ent;
 593                 e.state = 0;
 594                 Item_Show(e, 1);
 595
 596                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 597                 {
 598                         if(head != e)
 599                         {
 600                                 // make it a non-spawned item
 601                                 Item_Show(head, -1);
 602                                 head.state = 1; // state 1 = initially hidden item
 603                         }
 604                         head.effects &~= EF_NODRAW;
 605                 }
 606
 607                 Item_Reset();
 608         }
 609 }
 610
 611 // Savage: used for item garbage-collection
 612 // TODO: perhaps nice special effect?
 613 void RemoveItem(void)
 614 {
 615         remove(self);
 616 }
 617
 618 // pickup evaluation functions
 619 // these functions decide how desirable an item is to the bots
 620
 621 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 622
 623 float weapon_pickupevalfunc(entity player, entity item)
 624 {
 625         float c, i, j, position;
 626
 627         // See if I have it already
 628         if(player.weapons & item.weapons == item.weapons)
 629         {
 630                 // If I can pick it up
 631                 if(!item.spawnshieldtime)
 632                         c = 0;
 633                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 634                 {
 635                         // Skilled bots will grab more
 636                         c = bound(0, skill / 10, 1) * 0.5;
 637                 }
 638                 else
 639                         c = 0;
 640         }
 641         else
 642                 c = 1;
 643
 644         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 645         if( bot_custom_weapon && c )
 646         {
 647                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 648                 {
 649                         // Find weapon
 650                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 651                                 continue;
 652
 653                         // Find the highest position on any range
 654                         position = -1;
 655                         for(j = 0; j < WEP_LAST ; ++j){
 656                                 if(
 657                                                 bot_weapons_far[j] == i ||
 658                                                 bot_weapons_mid[j] == i ||
 659                                                 bot_weapons_close[j] == i
 660                                   )
 661                                 {
 662                                         position = j;
 663                                         break;
 664                                 }
 665                         }
 666
 667                         // Rate it
 668                         if (position >= 0 )
 669                         {
 670                                 position = WEP_LAST - position;
 671                                 // item.bot_pickupbasevalue is overwritten here
 672                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 673                         }
 674                 }
 675         }
 676
 677         return item.bot_pickupbasevalue * c;
 678 }
 679
 680 float commodity_pickupevalfunc(entity player, entity item)
 681 {
 682         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 683         entity wi;
 684         c = 0;
 685
 686         // Detect needed ammo
 687         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 688         {
 689                 wi = get_weaponinfo(i);
 690
 691                 if not(wi.weapons & player.weapons)
 692                         continue;
 693
 694                 if(wi.items & IT_SHELLS)
 695                         need_shells = TRUE;
 696                 else if(wi.items & IT_NAILS)
 697                         need_nails = TRUE;
 698                 else if(wi.items & IT_ROCKETS)
 699                         need_rockets = TRUE;
 700                 else if(wi.items & IT_CELLS)
 701                         need_cells = TRUE;
 702                 else if(wi.items & IT_FUEL)
 703                         need_cells = TRUE;
 704         }
 705
 706         // TODO: figure out if the player even has the weapon this ammo is for?
 707         // may not affect strategy much though...
 708         // find out how much more ammo/armor/health the player can hold
 709         if (need_shells)
 710         if (item.ammo_shells)
 711         if (player.ammo_shells < g_pickup_shells_max)
 712                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 713         if (need_nails)
 714         if (item.ammo_nails)
 715         if (player.ammo_nails < g_pickup_nails_max)
 716                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 717         if (need_rockets)
 718         if (item.ammo_rockets)
 719         if (player.ammo_rockets < g_pickup_rockets_max)
 720                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 721         if (need_cells)
 722         if (item.ammo_cells)
 723         if (player.ammo_cells < g_pickup_cells_max)
 724                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 725         if (need_fuel)
 726         if (item.ammo_fuel)
 727         if (player.ammo_fuel < g_pickup_fuel_max)
 728                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 729         if (item.armorvalue)
 730         if (player.armorvalue < item.max_armorvalue)
 731                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 732         if (item.health)
 733         if (player.health < item.max_health)
 734                 c = c + max(0, 1 - player.health / item.max_health);
 735
 736         return item.bot_pickupbasevalue * c;
 737 }
 738
 739 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 740 {
 741         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 742                 RemoveItem();
 743 }
 744
 745 .float is_item;
 746 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 747 {
 748         startitem_failed = FALSE;
 749
 750         self.items = itemid;
 751         self.weapons = weaponid;
 752         self.flags = FL_ITEM | itemflags;
 753
 754         if(MUTATOR_CALLHOOK(Item_Spawn))
 755         {
 756                 startitem_failed = TRUE;
 757                 remove(self);
 758                 return;
 759         }
 760
 761         // is it a dropped weapon?
 762         if (self.classname == "droppedweapon")
 763         {
 764                 self.reset = SUB_Remove;
 765                 // it's a dropped weapon
 766                 self.movetype = MOVETYPE_TOSS;
 767
 768                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 769                 self.think = RemoveItem;
 770                 self.nextthink = time + 20;
 771
 772                 self.takedamage = DAMAGE_YES;
 773                 self.event_damage = Item_Damage;
 774
 775                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 776                 /*
 777                 if(self.items == 0)
 778                 if(self.weapons == (self.weapons & WEPBIT_SUPERWEAPONS)) // only superweapons
 779                 if(self.ammo_nails == 0)
 780                 if(self.ammo_cells == 0)
 781                 if(self.ammo_rockets == 0)
 782                 if(self.ammo_shells == 0)
 783                 if(self.ammo_fuel == 0)
 784                 if(self.health == 0)
 785                 if(self.armorvalue == 0)
 786                 */
 787                 {
 788                         // if item is worthless after a timer, have it expire then
 789                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 790                 }
 791
 792                 // don't drop if in a NODROP zone (such as lava)
 793                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 794                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 795                 {
 796                         startitem_failed = TRUE;
 797                         remove(self);
 798                         return;
 799                 }
 800         }
 801         else
 802         {
 803                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 804                 {
 805                         startitem_failed = TRUE;
 806                         remove(self);
 807                         return;
 808                 }
 809
 810                 if(!have_pickup_item())
 811                 {
 812                         startitem_failed = TRUE;
 813                         remove (self);
 814                         return;
 815                 }
 816
 817                 if(self.model != "")
 818                         itemmodel = self.model;
 819                 if(self.item_pickupsound != "")
 820                         pickupsound = self.item_pickupsound;
 821
 822                 self.reset = Item_Reset;
 823                 // it's a level item
 824                 if(self.spawnflags & 1)
 825                         self.noalign = 1;
 826                 if (self.noalign)
 827                         self.movetype = MOVETYPE_NONE;
 828                 else
 829                         self.movetype = MOVETYPE_TOSS;
 830                 // do item filtering according to game mode and other things
 831                 if (!self.noalign)
 832                 {
 833                         // first nudge it off the floor a little bit to avoid math errors
 834                         setorigin(self, self.origin + '0 0 1');
 835                         // set item size before we spawn a spawnfunc_waypoint
 836                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 837                                 setsize (self, '-16 -16 0', '16 16 48');
 838                         else
 839                                 setsize (self, '-16 -16 0', '16 16 32');
 840                         // note droptofloor returns FALSE if stuck/or would fall too far
 841                         droptofloor();
 842                         waypoint_spawnforitem(self);
 843                 }
 844
 845                 /*
 846                  * can't do it that way, as it would break maps
 847                  * TODO make a target_give like entity another way, that perhaps has
 848                  * the weapon name in a key
 849                 if(self.targetname)
 850                 {
 851                         // target_give not yet supported; maybe later
 852                         print("removed targeted ", self.classname, "\n");
 853                         startitem_failed = TRUE;
 854                         remove (self);
 855                         return;
 856                 }
 857                 */
 858
 859                 if(autocvar_spawn_debug >= 2)
 860                 {
 861                         entity otheritem;
 862                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 863                         {
 864                                 if(otheritem.is_item)
 865                                 {
 866                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 867                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 868                                         error("Mapper sucks.");
 869                                 }
 870                         }
 871                         self.is_item = TRUE;
 872                 }
 873
 874                 weaponsInMap |= weaponid;
 875
 876                 precache_model (itemmodel);
 877                 precache_sound (pickupsound);
 878
 879                 precache_sound ("misc/itemrespawncountdown.wav");
 880                 if(!g_minstagib && itemid == IT_STRENGTH)
 881                         precache_sound ("misc/strength_respawn.wav");
 882                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 883                         precache_sound ("misc/shield_respawn.wav");
 884                 else
 885                         precache_sound ("misc/itemrespawn.wav");
 886
 887                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 888                         self.target = "###item###"; // for finding the nearest item using find()
 889         }
 890
 891         self.bot_pickup = TRUE;
 892         self.bot_pickupevalfunc = pickupevalfunc;
 893         self.bot_pickupbasevalue = pickupbasevalue;
 894         self.mdl = itemmodel;
 895         self.item_pickupsound = pickupsound;
 896         if(self.weapons)
 897                 self.weapon = WEP_FIRST + log2of(lowestbit(self.weapons));
 898         else
 899                 self.weapon = 0;
 900         // let mappers override respawntime
 901         if(!self.respawntime) // both set
 902         {
 903                 self.respawntime = defaultrespawntime;
 904                 self.respawntimejitter = defaultrespawntimejitter;
 905         }
 906         self.netname = itemname;
 907         self.touch = Item_Touch;
 908         setmodel (self, self.mdl); // precision set below
 909         self.effects |= EF_LOWPRECISION;
 910         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 911                 setsize (self, '-16 -16 0', '16 16 48');
 912         else
 913                 setsize (self, '-16 -16 0', '16 16 32');
 914         if(itemflags & FL_WEAPON)
 915                 self.modelflags |= MF_ROTATE;
 916
 917         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 918         if (itemflags & FL_WEAPON)
 919         {
 920                 // neutral team color for pickup weapons
 921                 self.colormap = 1024; // color shirt=0 pants=0 grey
 922         }
 923
 924         self.state = 0;
 925         if(self.team)
 926         {
 927                 if(!self.cnt)
 928                         self.cnt = 1; // item probability weight
 929                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 930                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 931         }
 932         else
 933                 Item_Reset();
 934 }
 935
 936 /* replace items in minstagib
 937  * IT_STRENGTH   = invisibility
 938  * IT_NAILS      = extra lives
 939  * IT_INVINCIBLE = speed
 940  */
 941 void minstagib_items (float itemid)
 942 {
 943         float rnd;
 944         self.classname = "minstagib";
 945
 946         // replace rocket launchers and nex guns with ammo cells
 947         if (itemid == IT_CELLS)
 948         {
 949                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 950                 StartItem ("models/items/a_cells.md3",
 951                         "misc/itempickup.wav", 45, 0,
 952                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 953                 return;
 954         }
 955
 956         // randomize
 957         rnd = random() * 3;
 958         if (rnd <= 1)
 959                 itemid = IT_STRENGTH;
 960         else if (rnd <= 2)
 961                 itemid = IT_NAILS;
 962         else
 963                 itemid = IT_INVINCIBLE;
 964
 965         // replace with invis
 966         if (itemid == IT_STRENGTH)
 967         {
 968                 if(!self.strength_finished)
 969                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 970                 StartItem ("models/items/g_strength.md3",
 971                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 972                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 973         }
 974         // replace with extra lives
 975         if (itemid == IT_NAILS)
 976         {
 977                 self.max_health = 1;
 978                 StartItem ("models/items/g_h100.md3",
 979                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 980                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 981         }
 982         // replace with speed
 983         if (itemid == IT_INVINCIBLE)
 984         {
 985                 if(!self.invincible_finished)
 986                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 987                 StartItem ("models/items/g_invincible.md3",
 988                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 989                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 990         }
 991 }
 992
 993 float minst_no_auto_cells;
 994 void minst_remove_item (void) {
 995         if(minst_no_auto_cells)
 996                 remove(self);
 997 }
 998
 999 float weaponswapping;
1000 float internalteam;
1001
1002 void weapon_defaultspawnfunc(float wpn)
1003 {
1004         entity e;
1005         float t;
1006         var .float ammofield;
1007         string s;
1008         entity oldself;
1009         float i, j;
1010         float f;
1011
1012         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1013         {
1014                 e = get_weaponinfo(wpn);
1015                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1016                 if(s == "0")
1017                 {
1018                         remove(self);
1019                         startitem_failed = TRUE;
1020                         return;
1021                 }
1022                 t = tokenize_console(s);
1023                 if(t >= 2)
1024                 {
1025                         self.team = --internalteam;
1026                         oldself = self;
1027                         for(i = 1; i < t; ++i)
1028                         {
1029                                 s = argv(i);
1030                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1031                                 {
1032                                         e = get_weaponinfo(j);
1033                                         if(e.netname == s)
1034                                         {
1035                                                 self = spawn();
1036                                                 copyentity(oldself, self);
1037                                                 self.classname = "replacedweapon";
1038                                                 weapon_defaultspawnfunc(j);
1039                                                 break;
1040                                         }
1041                                 }
1042                                 if(j > WEP_LAST)
1043                                 {
1044                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1045                                 }
1046                         }
1047                         self = oldself;
1048                 }
1049                 if(t >= 1)
1050                 {
1051                         s = argv(0);
1052                         wpn = 0;
1053                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1054                         {
1055                                 e = get_weaponinfo(j);
1056                                 if(e.netname == s)
1057                                 {
1058                                         wpn = j;
1059                                         break;
1060                                 }
1061                         }
1062                         if(j > WEP_LAST)
1063                         {
1064                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1065                         }
1066                 }
1067                 if(wpn == 0)
1068                 {
1069                         remove(self);
1070                         startitem_failed = TRUE;
1071                         return;
1072                 }
1073         }
1074
1075         e = get_weaponinfo(wpn);
1076
1077         if(!self.respawntime)
1078         {
1079                 if(e.weapons & WEPBIT_SUPERWEAPONS)
1080                 {
1081                         self.respawntime = g_pickup_respawntime_superweapon;
1082                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1083                 }
1084                 else
1085                 {
1086                         self.respawntime = g_pickup_respawntime_weapon;
1087                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1088                 }
1089         }
1090
1091         if(e.weapons & WEPBIT_SUPERWEAPONS)
1092                 if(!self.superweapons_finished)
1093                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1094
1095         if(e.items)
1096         {
1097                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1098                 {
1099                         if(e.items & j)
1100                         {
1101                                 ammofield = Item_CounterField(j);
1102                                 if(!self.ammofield)
1103                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1104                         }
1105                 }
1106         }
1107
1108         // pickup anyway
1109         if(g_pickup_weapons_anyway)
1110                 self.pickup_anyway = TRUE;
1111
1112         f = FL_WEAPON;
1113
1114         // no weapon-stay on superweapons
1115         if(e.weapons & WEPBIT_SUPERWEAPONS)
1116                 f |= FL_NO_WEAPON_STAY;
1117
1118         // weapon stay isn't supported for teamed weapons
1119         if(self.team)
1120                 f |= FL_NO_WEAPON_STAY;
1121
1122         // stupid minstagib hack, don't ask
1123         if(g_minstagib)
1124                 if(self.ammo_cells)
1125                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1126
1127         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1128         if (self.modelindex) // don't precache if self was removed
1129                 weapon_action(e.weapon, WR_PRECACHE);
1130 }
1131
1132 void spawnfunc_weapon_shotgun (void);
1133 void spawnfunc_weapon_uzi (void) {
1134         if(autocvar_sv_q3acompat_machineshotgunswap)
1135         if(self.classname != "droppedweapon")
1136         {
1137                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1138                 return;
1139         }
1140         weapon_defaultspawnfunc(WEP_UZI);
1141 }
1142
1143 void spawnfunc_weapon_shotgun (void) {
1144         if(autocvar_sv_q3acompat_machineshotgunswap)
1145         if(self.classname != "droppedweapon")
1146         {
1147                 weapon_defaultspawnfunc(WEP_UZI);
1148                 return;
1149         }
1150         weapon_defaultspawnfunc(WEP_SHOTGUN);
1151 }
1152
1153 void spawnfunc_weapon_nex (void)
1154 {
1155         if (g_minstagib)
1156         {
1157                 minstagib_items(IT_CELLS);
1158                 self.think = minst_remove_item;
1159                 self.nextthink = time;
1160                 return;
1161         }
1162         weapon_defaultspawnfunc(WEP_NEX);
1163 }
1164
1165 void spawnfunc_weapon_minstanex (void)
1166 {
1167         if (g_minstagib)
1168         {
1169                 minstagib_items(IT_CELLS);
1170                 self.think = minst_remove_item;
1171                 self.nextthink = time;
1172                 return;
1173         }
1174         weapon_defaultspawnfunc(WEP_MINSTANEX);
1175 }
1176
1177 void spawnfunc_weapon_rocketlauncher (void)
1178 {
1179         if (g_minstagib)
1180         {
1181                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1182                 self.think = minst_remove_item;
1183                 self.nextthink = time;
1184                 return;
1185         }
1186         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1187 }
1188
1189 void spawnfunc_item_rockets (void) {
1190         if(!self.ammo_rockets)
1191                 self.ammo_rockets = g_pickup_rockets;
1192         if(!self.pickup_anyway)
1193                 self.pickup_anyway = g_pickup_ammo_anyway;
1194         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1195 }
1196
1197 void spawnfunc_item_shells (void);
1198 void spawnfunc_item_bullets (void) {
1199         if(!weaponswapping)
1200         if(autocvar_sv_q3acompat_machineshotgunswap)
1201         if(self.classname != "droppedweapon")
1202         {
1203                 weaponswapping = TRUE;
1204                 spawnfunc_item_shells();
1205                 weaponswapping = FALSE;
1206                 return;
1207         }
1208
1209         if(!self.ammo_nails)
1210                 self.ammo_nails = g_pickup_nails;
1211         if(!self.pickup_anyway)
1212                 self.pickup_anyway = g_pickup_ammo_anyway;
1213         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1214 }
1215
1216 void spawnfunc_item_cells (void) {
1217         if(!self.ammo_cells)
1218                 self.ammo_cells = g_pickup_cells;
1219         if(!self.pickup_anyway)
1220                 self.pickup_anyway = g_pickup_ammo_anyway;
1221         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1222 }
1223
1224 void spawnfunc_item_shells (void) {
1225         if(!weaponswapping)
1226         if(autocvar_sv_q3acompat_machineshotgunswap)
1227         if(self.classname != "droppedweapon")
1228         {
1229                 weaponswapping = TRUE;
1230                 spawnfunc_item_bullets();
1231                 weaponswapping = FALSE;
1232                 return;
1233         }
1234
1235         if(!self.ammo_shells)
1236                 self.ammo_shells = g_pickup_shells;
1237         if(!self.pickup_anyway)
1238                 self.pickup_anyway = g_pickup_ammo_anyway;
1239         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1240 }
1241
1242 void spawnfunc_item_armor_small (void) {
1243         if(!self.armorvalue)
1244                 self.armorvalue = g_pickup_armorsmall;
1245         if(!self.max_armorvalue)
1246                 self.max_armorvalue = g_pickup_armorsmall_max;
1247         if(!self.pickup_anyway)
1248                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1249         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1250 }
1251
1252 void spawnfunc_item_armor_medium (void) {
1253         if(!self.armorvalue)
1254                 self.armorvalue = g_pickup_armormedium;
1255         if(!self.max_armorvalue)
1256                 self.max_armorvalue = g_pickup_armormedium_max;
1257         if(!self.pickup_anyway)
1258                 self.pickup_anyway = g_pickup_armormedium_anyway;
1259         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1260 }
1261
1262 void spawnfunc_item_armor_big (void) {
1263         if(!self.armorvalue)
1264                 self.armorvalue = g_pickup_armorbig;
1265         if(!self.max_armorvalue)
1266                 self.max_armorvalue = g_pickup_armorbig_max;
1267         if(!self.pickup_anyway)
1268                 self.pickup_anyway = g_pickup_armorbig_anyway;
1269         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1270 }
1271
1272 void spawnfunc_item_armor_large (void) {
1273         if(!self.armorvalue)
1274                 self.armorvalue = g_pickup_armorlarge;
1275         if(!self.max_armorvalue)
1276                 self.max_armorvalue = g_pickup_armorlarge_max;
1277         if(!self.pickup_anyway)
1278                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1279         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1280 }
1281
1282 void spawnfunc_item_health_small (void) {
1283         if(!self.max_health)
1284                 self.max_health = g_pickup_healthsmall_max;
1285         if(!self.health)
1286                 self.health = g_pickup_healthsmall;
1287         if(!self.pickup_anyway)
1288                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1289         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1290 }
1291
1292 void spawnfunc_item_health_medium (void) {
1293         if(!self.max_health)
1294                 self.max_health = g_pickup_healthmedium_max;
1295         if(!self.health)
1296                 self.health = g_pickup_healthmedium;
1297         if(!self.pickup_anyway)
1298                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1299         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1300 }
1301
1302 void spawnfunc_item_health_large (void) {
1303         if(!self.max_health)
1304                 self.max_health = g_pickup_healthlarge_max;
1305         if(!self.health)
1306                 self.health = g_pickup_healthlarge;
1307         if(!self.pickup_anyway)
1308                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1309         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1310 }
1311
1312 void spawnfunc_item_health_mega (void) {
1313         if(g_minstagib) {
1314                 minstagib_items(IT_NAILS);
1315         } else {
1316                 if(!self.max_health)
1317                         self.max_health = g_pickup_healthmega_max;
1318                 if(!self.health)
1319                         self.health = g_pickup_healthmega;
1320                 if(!self.pickup_anyway)
1321                         self.pickup_anyway = g_pickup_healthmega_anyway;
1322                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1323         }
1324 }
1325
1326 // support old misnamed entities
1327 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1328 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1329 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1330 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1331 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1332
1333 void spawnfunc_item_strength (void) {
1334         if(g_minstagib) {
1335                 minstagib_items(IT_STRENGTH);
1336         } else {
1337                 precache_sound("weapons/strength_fire.wav");
1338                 if(!self.strength_finished)
1339                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1340                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1341         }
1342 }
1343
1344 void spawnfunc_item_invincible (void) {
1345         if(g_minstagib) {
1346                 minstagib_items(IT_INVINCIBLE);
1347         } else {
1348                 if(!self.invincible_finished)
1349                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1350                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1351         }
1352 }
1353
1354 void spawnfunc_item_minst_cells (void) {
1355         if (g_minstagib)
1356         {
1357                 minst_no_auto_cells = 1;
1358                 minstagib_items(IT_CELLS);
1359         }
1360         else
1361                 remove(self);
1362 }
1363
1364 // compatibility:
1365 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1366
1367 float GiveItems(entity e, float beginarg, float endarg);
1368 void target_items_use (void)
1369 {
1370         if(activator.classname == "droppedweapon")
1371         {
1372                 EXACTTRIGGER_TOUCH;
1373                 remove(activator);
1374                 return;
1375         }
1376
1377         if(activator.classname != "player")
1378                 return;
1379         if(activator.deadflag != DEAD_NO)
1380                 return;
1381         EXACTTRIGGER_TOUCH;
1382
1383         entity e;
1384         for(e = world; (e = find(e, classname, "droppedweapon")); )
1385                 if(e.enemy == activator)
1386                         remove(e);
1387
1388         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1389                 centerprint(activator, self.message);
1390 }
1391
1392 void spawnfunc_target_items (void)
1393 {
1394         float n, i, j;
1395         entity e;
1396
1397         self.use = target_items_use;
1398         if(!self.strength_finished)
1399                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1400         if(!self.invincible_finished)
1401                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1402         if(!self.superweapons_finished)
1403                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1404
1405         precache_sound("misc/itempickup.wav");
1406         precache_sound("misc/megahealth.wav");
1407         precache_sound("misc/armor25.wav");
1408         precache_sound("misc/powerup.wav");
1409         precache_sound("misc/poweroff.wav");
1410         precache_sound("weapons/weaponpickup.wav");
1411
1412         n = tokenize_console(self.netname);
1413         if(argv(0) == "give")
1414         {
1415                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1416         }
1417         else
1418         {
1419                 for(i = 0; i < n; ++i)
1420                 {
1421                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1422                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1423                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1424                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1425                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1426                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1427                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1428                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1429                         else
1430                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1431                         {
1432                                 e = get_weaponinfo(j);
1433                                 if(argv(i) == e.netname)
1434                                 {
1435                                         self.weapons |= e.weapons;
1436                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1437                                                 weapon_action(e.weapon, WR_PRECACHE);
1438                                         break;
1439                                 }
1440                         }
1441                         if(j > WEP_LAST)
1442                                 print("target_items: invalid item ", argv(i), "\n");
1443                 }
1444
1445                 string itemprefix, valueprefix;
1446                 if(self.spawnflags == 0)
1447                 {
1448                         itemprefix = "";
1449                         valueprefix = "";
1450                 }
1451                 else if(self.spawnflags == 1)
1452                 {
1453                         itemprefix = "max ";
1454                         valueprefix = "max ";
1455                 }
1456                 else if(self.spawnflags == 2)
1457                 {
1458                         itemprefix = "min ";
1459                         valueprefix = "min ";
1460                 }
1461                 else if(self.spawnflags == 4)
1462                 {
1463                         itemprefix = "minus ";
1464                         valueprefix = "max ";
1465                 }
1466                 else
1467                         error("invalid spawnflags");
1468
1469                 self.netname = "";
1470                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1471                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1472                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1473                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1474                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1475                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1476                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1477                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1478                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1479                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1480                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1481                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1482                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1483                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1484                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1485                 {
1486                         e = get_weaponinfo(j);
1487                         if(e.weapons)
1488                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1489                 }
1490         }
1491         self.netname = strzone(self.netname);
1492         //print(self.netname, "\n");
1493
1494         n = tokenize_console(self.netname);
1495         for(i = 0; i < n; ++i)
1496         {
1497                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1498                 {
1499                         e = get_weaponinfo(j);
1500                         if(argv(i) == e.netname)
1501                         {
1502                                 weapon_action(e.weapon, WR_PRECACHE);
1503                                 break;
1504                         }
1505                 }
1506         }
1507 }
1508
1509 void spawnfunc_item_fuel(void)
1510 {
1511         if(!self.ammo_fuel)
1512                 self.ammo_fuel = g_pickup_fuel;
1513         if(!self.pickup_anyway)
1514                 self.pickup_anyway = g_pickup_ammo_anyway;
1515         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1516 }
1517
1518 void spawnfunc_item_fuel_regen(void)
1519 {
1520         if(start_items & IT_FUEL_REGEN)
1521         {
1522                 spawnfunc_item_fuel();
1523                 return;
1524         }
1525         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1526 }
1527
1528 void spawnfunc_item_jetpack(void)
1529 {
1530         if(g_grappling_hook)
1531                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1532         if(!self.ammo_fuel)
1533                 self.ammo_fuel = g_pickup_fuel_jetpack;
1534         if(start_items & IT_JETPACK)
1535         {
1536                 spawnfunc_item_fuel();
1537                 return;
1538         }
1539         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1540 }
1541
1542
1543 #define OP_SET 0
1544 #define OP_MIN 1
1545 #define OP_MAX 2
1546 #define OP_PLUS 3
1547 #define OP_MINUS 4
1548
1549 float GiveBit(entity e, .float fld, float bit, float op, float val)
1550 {
1551         float v0, v1;
1552         v0 = (e.fld & bit);
1553         switch(op)
1554         {
1555                 case OP_SET:
1556                         if(val > 0)
1557                                 e.fld |= bit;
1558                         else
1559                                 e.fld &~= bit;
1560                         break;
1561                 case OP_MIN:
1562                 case OP_PLUS:
1563                         if(val > 0)
1564                                 e.fld |= bit;
1565                         break;
1566                 case OP_MAX:
1567                         if(val <= 0)
1568                                 e.fld &~= bit;
1569                         break;
1570                 case OP_MINUS:
1571                         if(val > 0)
1572                                 e.fld &~= bit;
1573                         break;
1574         }
1575         v1 = (e.fld & bit);
1576         return (v0 != v1);
1577 }
1578
1579 float GiveValue(entity e, .float fld, float op, float val)
1580 {
1581         float v0, v1;
1582         v0 = e.fld;
1583         switch(op)
1584         {
1585                 case OP_SET:
1586                         e.fld = val;
1587                         break;
1588                 case OP_MIN:
1589                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1590                         break;
1591                 case OP_MAX:
1592                         e.fld = min(e.fld, val);
1593                         break;
1594                 case OP_PLUS:
1595                         e.fld += val;
1596                         break;
1597                 case OP_MINUS:
1598                         e.fld -= val;
1599                         break;
1600         }
1601         v1 = e.fld;
1602         return (v0 != v1);
1603 }
1604
1605 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1606 {
1607         if(v1 == v0)
1608                 return;
1609         if(v1 <= v0 - t)
1610         {
1611                 if(snd_decr != "")
1612                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1613         }
1614         else if(v0 >= v0 + t)
1615         {
1616                 if(snd_incr != "")
1617                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1618         }
1619 }
1620
1621 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1622 {
1623         if(v0 < v1)
1624                 e.rotfield = max(e.rotfield, time + rottime);
1625         else if(v0 > v1)
1626                 e.regenfield = max(e.regenfield, time + regentime);
1627 }
1628
1629 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1630 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1631 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1632 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1633
1634 float GiveItems(entity e, float beginarg, float endarg)
1635 {
1636         float got, i, j, val, op;
1637         float _switchweapon;
1638         entity wi;
1639         string cmd;
1640
1641         val = 999;
1642         op = OP_SET;
1643
1644         got = 0;
1645
1646         _switchweapon = FALSE;
1647         if (e.autoswitch)
1648                 if (e.switchweapon == w_getbestweapon(e))
1649                         _switchweapon = TRUE;
1650
1651         e.strength_finished = max(0, e.strength_finished - time);
1652         e.invincible_finished = max(0, e.invincible_finished - time);
1653         e.superweapons_finished = max(0, e.superweapons_finished - time);
1654
1655         PREGIVE(e, items);
1656         PREGIVE(e, weapons);
1657         PREGIVE(e, strength_finished);
1658         PREGIVE(e, invincible_finished);
1659         PREGIVE(e, superweapons_finished);
1660         PREGIVE(e, ammo_nails);
1661         PREGIVE(e, ammo_cells);
1662         PREGIVE(e, ammo_shells);
1663         PREGIVE(e, ammo_rockets);
1664         PREGIVE(e, ammo_fuel);
1665         PREGIVE(e, armorvalue);
1666         PREGIVE(e, health);
1667
1668         for(i = beginarg; i < endarg; ++i)
1669         {
1670                 cmd = argv(i);
1671
1672                 if(cmd == "0" || stof(cmd))
1673                 {
1674                         val = stof(cmd);
1675                         continue;
1676                 }
1677                 switch(cmd)
1678                 {
1679                         case "no":
1680                                 op = OP_MAX;
1681                                 val = 0;
1682                                 continue;
1683                         case "max":
1684                                 op = OP_MAX;
1685                                 continue;
1686                         case "min":
1687                                 op = OP_MIN;
1688                                 continue;
1689                         case "plus":
1690                                 op = OP_PLUS;
1691                                 continue;
1692                         case "minus":
1693                                 op = OP_MINUS;
1694                                 continue;
1695                         case "ALL":
1696                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1697                                 got += GiveValue(e, strength_finished, op, val);
1698                                 got += GiveValue(e, invincible_finished, op, val);
1699                                 got += GiveValue(e, superweapons_finished, op, val);
1700                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1701                         case "all":
1702                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1703                                 got += GiveValue(e, health, op, val);
1704                                 got += GiveValue(e, armorvalue, op, val);
1705                         case "allweapons":
1706                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1707                                 {
1708                                         wi = get_weaponinfo(j);
1709                                         if(wi.weapons)
1710                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1711                                 }
1712                         case "allammo":
1713                                 got += GiveValue(e, ammo_cells, op, val);
1714                                 got += GiveValue(e, ammo_shells, op, val);
1715                                 got += GiveValue(e, ammo_nails, op, val);
1716                                 got += GiveValue(e, ammo_rockets, op, val);
1717                                 got += GiveValue(e, ammo_fuel, op, val);
1718                                 break;
1719                         case "unlimited_ammo":
1720                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1721                                 break;
1722                         case "unlimited_weapon_ammo":
1723                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1724                                 break;
1725                         case "unlimited_superweapons":
1726                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1727                                 break;
1728                         case "jetpack":
1729                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1730                                 break;
1731                         case "fuel_regen":
1732                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1733                                 break;
1734                         case "strength":
1735                                 got += GiveValue(e, strength_finished, op, val);
1736                                 break;
1737                         case "invincible":
1738                                 got += GiveValue(e, invincible_finished, op, val);
1739                                 break;
1740                         case "superweapons":
1741                                 got += GiveValue(e, superweapons_finished, op, val);
1742                                 break;
1743                         case "cells":
1744                                 got += GiveValue(e, ammo_cells, op, val);
1745                                 break;
1746                         case "shells":
1747                                 got += GiveValue(e, ammo_shells, op, val);
1748                                 break;
1749                         case "nails":
1750                         case "bullets":
1751                                 got += GiveValue(e, ammo_nails, op, val);
1752                                 break;
1753                         case "rockets":
1754                                 got += GiveValue(e, ammo_rockets, op, val);
1755                                 break;
1756                         case "health":
1757                                 got += GiveValue(e, health, op, val);
1758                                 break;
1759                         case "armor":
1760                                 got += GiveValue(e, armorvalue, op, val);
1761                                 break;
1762                         case "fuel":
1763                                 got += GiveValue(e, ammo_fuel, op, val);
1764                                 break;
1765                         default:
1766                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1767                                 {
1768                                         wi = get_weaponinfo(j);
1769                                         if(cmd == wi.netname)
1770                                         {
1771                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1772                                                 break;
1773                                         }
1774                                 }
1775                                 if(j > WEP_LAST)
1776                                         print("give: invalid item ", cmd, "\n");
1777                                 break;
1778                 }
1779                 val = 999;
1780                 op = OP_SET;
1781         }
1782
1783         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1784         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1785         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1786         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1787         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1788         {
1789                 wi = get_weaponinfo(j);
1790                 if(wi.weapons)
1791                 {
1792                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1793                         if not(save_weapons & wi.weapons)
1794                                 if(e.weapons & wi.weapons)
1795                                         weapon_action(wi.weapon, WR_PRECACHE);
1796                 }
1797         }
1798         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1799         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1800         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1801         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1802         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1803         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1804         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1805         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1806         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1807
1808         if(e.superweapons_finished <= 0)
1809                 if(self.weapons & WEPBIT_SUPERWEAPONS)
1810                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1811
1812         if (g_minstagib)
1813         {
1814                 e.health = bound(0, e.health, 100);
1815                 e.armorvalue = bound(0, e.armorvalue, 999);
1816         }
1817
1818         if(e.strength_finished <= 0)
1819                 e.strength_finished = 0;
1820         else
1821                 e.strength_finished += time;
1822         if(e.invincible_finished <= 0)
1823                 e.invincible_finished = 0;
1824         else
1825                 e.invincible_finished += time;
1826         if(e.superweapons_finished <= 0)
1827                 e.superweapons_finished = 0;
1828         else
1829                 e.superweapons_finished += time;
1830
1831         if not(e.weapons & W_WeaponBit(e.switchweapon))
1832                 _switchweapon = TRUE;
1833         if(_switchweapon)
1834                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1835
1836         return got;
1837 }