qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || (e.weapons & WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         player.health = 100;
 383                 }
 384
 385                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 386                 {
 387                         pickedup = TRUE;
 388                         player.items |= it;
 389                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 390                 }
 391
 392                 // extralife powerup
 393                 if (item.max_health)
 394                 {
 395                         pickedup = TRUE;
 396                         // sound not available
 397                         // AnnounceTo(player, "_lives");
 398                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 399                         sprint(player, "^3You picked up some extra lives\n");
 400                 }
 401
 402                 // invis powerup
 403                 if (item.strength_finished)
 404                 {
 405                         pickedup = TRUE;
 406                         // sound not available
 407                         // AnnounceTo(player, "invisible");
 408                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 409                 }
 410
 411                 // speed powerup
 412                 if (item.invincible_finished)
 413                 {
 414                         pickedup = TRUE;
 415                         // sound not available
 416                         // AnnounceTo(player, "speed");
 417                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 418                 }
 419         }
 420         else
 421         {
 422                 // in case the player has autoswitch enabled do the following:
 423                 // if the player is using their best weapon before items are given, they
 424                 // probably want to switch to an even better weapon after items are given
 425                 if (player.autoswitch)
 426                 if (player.switchweapon == w_getbestweapon(player))
 427                         _switchweapon = TRUE;
 428
 429                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 430                         _switchweapon = TRUE;
 431
 432                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 438                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 439
 440                 if (item.flags & FL_WEAPON)
 441                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && self.pickup_anyway))
 442                 {
 443                         pickedup = TRUE;
 444                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 445                         {
 446                                 e = get_weaponinfo(i);
 447                                 if(it & e.weapons)
 448                                         W_GiveWeapon (player, e.weapon, item.netname);
 449                         }
 450                 }
 451
 452                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 453                 {
 454                         pickedup = TRUE;
 455                         player.items |= it;
 456                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 457                 }
 458
 459                 if (item.strength_finished)
 460                 {
 461                         pickedup = TRUE;
 462                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 463                 }
 464                 if (item.invincible_finished)
 465                 {
 466                         pickedup = TRUE;
 467                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 468                 }
 469                 if (item.superweapons_finished)
 470                 {
 471                         pickedup = TRUE;
 472                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 473                 }
 474         }
 475
 476 :skip
 477         // always eat teamed entities
 478         if(item.team)
 479                 pickedup = TRUE;
 480
 481         if (!pickedup)
 482                 return 0;
 483
 484         if (_switchweapon)
 485                 if (player.switchweapon != w_getbestweapon(player))
 486                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 487
 488         return 1;
 489 }
 490
 491 void Item_Touch (void)
 492 {
 493         entity e, head;
 494
 495         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 496         if(self.classname == "droppedweapon")
 497         {
 498                 if (ITEM_TOUCH_NEEDKILL())
 499                 {
 500                         remove(self);
 501                         return;
 502                 }
 503         }
 504
 505         if (other.classname != "player")
 506                 return;
 507         if (other.deadflag)
 508                 return;
 509         if (self.solid != SOLID_TRIGGER)
 510                 return;
 511         if (self.owner == other)
 512                 return;
 513
 514         if (self.classname == "droppedweapon")
 515         {
 516                 self.strength_finished = max(0, self.strength_finished - time);
 517                 self.invincible_finished = max(0, self.invincible_finished - time);
 518                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 519         }
 520
 521         if(!Item_GiveTo(self, other))
 522         {
 523                 if (self.classname == "droppedweapon")
 524                 {
 525                         // undo what we did above
 526                         self.strength_finished += time;
 527                         self.invincible_finished += time;
 528                         self.superweapons_finished += time;
 529                 }
 530                 return;
 531         }
 532
 533         other.last_pickup = time;
 534
 535         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 536         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 537
 538         if (self.classname == "droppedweapon")
 539                 remove (self);
 540         else if not(self.spawnshieldtime)
 541                 return;
 542         else
 543         {
 544                 if(self.team)
 545                 {
 546                         RandomSelection_Init();
 547                         for(head = world; (head = findfloat(head, team, self.team)); )
 548                         {
 549                                 if(head.flags & FL_ITEM)
 550                                 {
 551                                         Item_Show(head, -1);
 552                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 553                                 }
 554                         }
 555                         e = RandomSelection_chosen_ent;
 556                 }
 557                 else
 558                         e = self;
 559                 Item_ScheduleRespawn(e);
 560         }
 561 }
 562
 563 void Item_Reset()
 564 {
 565         Item_Show(self, !self.state);
 566         setorigin (self, self.origin);
 567
 568         if(self.classname != "droppedweapon")
 569         {
 570                 self.think = SUB_Null;
 571                 self.nextthink = 0;
 572
 573                 if(self.waypointsprite_attached)
 574                         WaypointSprite_Kill(self.waypointsprite_attached);
 575
 576                 if((self.flags & FL_POWERUP) | (self.weapons & WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 577                         Item_ScheduleInitialRespawn(self);
 578         }
 579 }
 580
 581 void Item_FindTeam()
 582 {
 583         entity head, e;
 584
 585         if(self.effects & EF_NODRAW)
 586         {
 587                 // marker for item team search
 588                 dprint("Initializing item team ", ftos(self.team), "\n");
 589                 RandomSelection_Init();
 590                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 591                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 592                 e = RandomSelection_chosen_ent;
 593                 e.state = 0;
 594                 Item_Show(e, 1);
 595
 596                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 597                 {
 598                         if(head != e)
 599                         {
 600                                 // make it a non-spawned item
 601                                 Item_Show(head, -1);
 602                                 head.state = 1; // state 1 = initially hidden item
 603                         }
 604                         head.effects &~= EF_NODRAW;
 605                 }
 606
 607                 Item_Reset();
 608         }
 609 }
 610
 611 // Savage: used for item garbage-collection
 612 // TODO: perhaps nice special effect?
 613 void RemoveItem(void)
 614 {
 615         remove(self);
 616 }
 617
 618 // pickup evaluation functions
 619 // these functions decide how desirable an item is to the bots
 620
 621 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 622
 623 float weapon_pickupevalfunc(entity player, entity item)
 624 {
 625         float c, i, j, position;
 626
 627         // See if I have it already
 628         if(player.weapons & item.weapons == item.weapons)
 629         {
 630                 // If I can pick it up
 631                 if(!item.spawnshieldtime)
 632                         c = 0;
 633                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 634                 {
 635                         // Skilled bots will grab more
 636                         c = bound(0, skill / 10, 1) * 0.5;
 637                 }
 638                 else
 639                         c = 0;
 640         }
 641         else
 642                 c = 1;
 643
 644         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 645         if( bot_custom_weapon && c )
 646         {
 647                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 648                 {
 649                         // Find weapon
 650                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 651                                 continue;
 652
 653                         // Find the highest position on any range
 654                         position = -1;
 655                         for(j = 0; j < WEP_LAST ; ++j){
 656                                 if(
 657                                                 bot_weapons_far[j] == i ||
 658                                                 bot_weapons_mid[j] == i ||
 659                                                 bot_weapons_close[j] == i
 660                                   )
 661                                 {
 662                                         position = j;
 663                                         break;
 664                                 }
 665                         }
 666
 667                         // Rate it
 668                         if (position >= 0 )
 669                         {
 670                                 position = WEP_LAST - position;
 671                                 // item.bot_pickupbasevalue is overwritten here
 672                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 673                         }
 674                 }
 675         }
 676
 677         return item.bot_pickupbasevalue * c;
 678 }
 679
 680 float commodity_pickupevalfunc(entity player, entity item)
 681 {
 682         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 683         entity wi;
 684         c = 0;
 685
 686         // Detect needed ammo
 687         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 688         {
 689                 wi = get_weaponinfo(i);
 690
 691                 if not(wi.weapons & player.weapons)
 692                         continue;
 693
 694                 if(wi.items & IT_SHELLS)
 695                         need_shells = TRUE;
 696                 else if(wi.items & IT_NAILS)
 697                         need_nails = TRUE;
 698                 else if(wi.items & IT_ROCKETS)
 699                         need_rockets = TRUE;
 700                 else if(wi.items & IT_CELLS)
 701                         need_cells = TRUE;
 702                 else if(wi.items & IT_FUEL)
 703                         need_cells = TRUE;
 704         }
 705
 706         // TODO: figure out if the player even has the weapon this ammo is for?
 707         // may not affect strategy much though...
 708         // find out how much more ammo/armor/health the player can hold
 709         if (need_shells)
 710         if (item.ammo_shells)
 711         if (player.ammo_shells < g_pickup_shells_max)
 712                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 713         if (need_nails)
 714         if (item.ammo_nails)
 715         if (player.ammo_nails < g_pickup_nails_max)
 716                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 717         if (need_rockets)
 718         if (item.ammo_rockets)
 719         if (player.ammo_rockets < g_pickup_rockets_max)
 720                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 721         if (need_cells)
 722         if (item.ammo_cells)
 723         if (player.ammo_cells < g_pickup_cells_max)
 724                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 725         if (need_fuel)
 726         if (item.ammo_fuel)
 727         if (player.ammo_fuel < g_pickup_fuel_max)
 728                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 729         if (item.armorvalue)
 730         if (player.armorvalue < item.max_armorvalue)
 731                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 732         if (item.health)
 733         if (player.health < item.max_health)
 734                 c = c + max(0, 1 - player.health / item.max_health);
 735
 736         return item.bot_pickupbasevalue * c;
 737 }
 738
 739 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 740 {
 741         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 742                 RemoveItem();
 743 }
 744
 745 .float is_item;
 746 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 747 {
 748         startitem_failed = FALSE;
 749
 750         self.items = itemid;
 751         self.weapons = weaponid;
 752         self.flags = FL_ITEM | itemflags;
 753
 754         // is it a dropped weapon?
 755         if (self.classname == "droppedweapon")
 756         {
 757                 self.reset = SUB_Remove;
 758                 // it's a dropped weapon
 759                 self.movetype = MOVETYPE_TOSS;
 760
 761                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 762                 self.think = RemoveItem;
 763                 self.nextthink = time + 20;
 764
 765                 self.takedamage = DAMAGE_YES;
 766                 self.event_damage = Item_Damage;
 767
 768                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 769                 /*
 770                 if(self.items == 0)
 771                 if(self.weapons == (self.weapons & WEPBIT_SUPERWEAPONS)) // only superweapons
 772                 if(self.ammo_nails == 0)
 773                 if(self.ammo_cells == 0)
 774                 if(self.ammo_rockets == 0)
 775                 if(self.ammo_shells == 0)
 776                 if(self.ammo_fuel == 0)
 777                 if(self.health == 0)
 778                 if(self.armorvalue == 0)
 779                 */
 780                 {
 781                         // if item is worthless after a timer, have it expire then
 782                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 783                 }
 784
 785                 // don't drop if in a NODROP zone (such as lava)
 786                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 787                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 788                 {
 789                         startitem_failed = TRUE;
 790                         remove(self);
 791                         return;
 792                 }
 793         }
 794         else
 795         {
 796                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 797                 {
 798                         startitem_failed = TRUE;
 799                         remove(self);
 800                         return;
 801                 }
 802
 803                 if(!have_pickup_item())
 804                 {
 805                         startitem_failed = TRUE;
 806                         remove (self);
 807                         return;
 808                 }
 809
 810                 if(self.model != "")
 811                         itemmodel = self.model;
 812                 if(self.item_pickupsound != "")
 813                         pickupsound = self.item_pickupsound;
 814
 815                 self.reset = Item_Reset;
 816                 // it's a level item
 817                 if(self.spawnflags & 1)
 818                         self.noalign = 1;
 819                 if (self.noalign)
 820                         self.movetype = MOVETYPE_NONE;
 821                 else
 822                         self.movetype = MOVETYPE_TOSS;
 823                 // do item filtering according to game mode and other things
 824                 if (!self.noalign)
 825                 {
 826                         // first nudge it off the floor a little bit to avoid math errors
 827                         setorigin(self, self.origin + '0 0 1');
 828                         // set item size before we spawn a spawnfunc_waypoint
 829                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 830                                 setsize (self, '-16 -16 0', '16 16 48');
 831                         else
 832                                 setsize (self, '-16 -16 0', '16 16 32');
 833                         // note droptofloor returns FALSE if stuck/or would fall too far
 834                         droptofloor();
 835                         waypoint_spawnforitem(self);
 836                 }
 837
 838                 /*
 839                  * can't do it that way, as it would break maps
 840                  * TODO make a target_give like entity another way, that perhaps has
 841                  * the weapon name in a key
 842                 if(self.targetname)
 843                 {
 844                         // target_give not yet supported; maybe later
 845                         print("removed targeted ", self.classname, "\n");
 846                         startitem_failed = TRUE;
 847                         remove (self);
 848                         return;
 849                 }
 850                 */
 851
 852                 if(autocvar_spawn_debug >= 2)
 853                 {
 854                         entity otheritem;
 855                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 856                         {
 857                                 if(otheritem.is_item)
 858                                 {
 859                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 860                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 861                                         error("Mapper sucks.");
 862                                 }
 863                         }
 864                         self.is_item = TRUE;
 865                 }
 866
 867                 weaponsInMap |= weaponid;
 868
 869                 precache_model (itemmodel);
 870                 precache_sound (pickupsound);
 871
 872                 precache_sound ("misc/itemrespawncountdown.wav");
 873                 if(!g_minstagib && itemid == IT_STRENGTH)
 874                         precache_sound ("misc/strength_respawn.wav");
 875                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 876                         precache_sound ("misc/shield_respawn.wav");
 877                 else
 878                         precache_sound ("misc/itemrespawn.wav");
 879
 880                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 881                         self.target = "###item###"; // for finding the nearest item using find()
 882         }
 883
 884         self.bot_pickup = TRUE;
 885         self.bot_pickupevalfunc = pickupevalfunc;
 886         self.bot_pickupbasevalue = pickupbasevalue;
 887         self.mdl = itemmodel;
 888         self.item_pickupsound = pickupsound;
 889         if(self.weapons)
 890                 self.weapon = WEP_FIRST + log2of(lowestbit(self.weapons));
 891         else
 892                 self.weapon = 0;
 893         // let mappers override respawntime
 894         if(!self.respawntime) // both set
 895         {
 896                 self.respawntime = defaultrespawntime;
 897                 self.respawntimejitter = defaultrespawntimejitter;
 898         }
 899         self.netname = itemname;
 900         self.touch = Item_Touch;
 901         setmodel (self, self.mdl); // precision set below
 902         self.effects |= EF_LOWPRECISION;
 903         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 904                 setsize (self, '-16 -16 0', '16 16 48');
 905         else
 906                 setsize (self, '-16 -16 0', '16 16 32');
 907         if(itemflags & FL_WEAPON)
 908                 self.modelflags |= MF_ROTATE;
 909
 910         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 911         if (itemflags & FL_WEAPON)
 912         {
 913                 // neutral team color for pickup weapons
 914                 self.colormap = 1024; // color shirt=0 pants=0 grey
 915         }
 916
 917         self.state = 0;
 918         if(self.team)
 919         {
 920                 if(!self.cnt)
 921                         self.cnt = 1; // item probability weight
 922                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 923                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 924         }
 925         else
 926                 Item_Reset();
 927 }
 928
 929 /* replace items in minstagib
 930  * IT_STRENGTH   = invisibility
 931  * IT_NAILS      = extra lives
 932  * IT_INVINCIBLE = speed
 933  */
 934 void minstagib_items (float itemid)
 935 {
 936         float rnd;
 937         self.classname = "minstagib";
 938
 939         // replace rocket launchers and nex guns with ammo cells
 940         if (itemid == IT_CELLS)
 941         {
 942                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 943                 StartItem ("models/items/a_cells.md3",
 944                         "misc/itempickup.wav", 45, 0,
 945                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 946                 return;
 947         }
 948
 949         // randomize
 950         rnd = random() * 3;
 951         if (rnd <= 1)
 952                 itemid = IT_STRENGTH;
 953         else if (rnd <= 2)
 954                 itemid = IT_NAILS;
 955         else
 956                 itemid = IT_INVINCIBLE;
 957
 958         // replace with invis
 959         if (itemid == IT_STRENGTH)
 960         {
 961                 if(!self.strength_finished)
 962                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 963                 StartItem ("models/items/g_strength.md3",
 964                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 965                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 966         }
 967         // replace with extra lives
 968         if (itemid == IT_NAILS)
 969         {
 970                 self.max_health = 1;
 971                 StartItem ("models/items/g_h100.md3",
 972                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 973                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 974         }
 975         // replace with speed
 976         if (itemid == IT_INVINCIBLE)
 977         {
 978                 if(!self.invincible_finished)
 979                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 980                 StartItem ("models/items/g_invincible.md3",
 981                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 982                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 983         }
 984 }
 985
 986 float minst_no_auto_cells;
 987 void minst_remove_item (void) {
 988         if(minst_no_auto_cells)
 989                 remove(self);
 990 }
 991
 992 float weaponswapping;
 993 float internalteam;
 994
 995 void weapon_defaultspawnfunc(float wpn)
 996 {
 997         entity e;
 998         float t;
 999         var .float ammofield;
1000         string s;
1001         entity oldself;
1002         float i, j;
1003         float f;
1004
1005         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1006         {
1007                 e = get_weaponinfo(wpn);
1008                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1009                 if(s == "0")
1010                 {
1011                         remove(self);
1012                         startitem_failed = TRUE;
1013                         return;
1014                 }
1015                 t = tokenize_console(s);
1016                 if(t >= 2)
1017                 {
1018                         self.team = --internalteam;
1019                         oldself = self;
1020                         for(i = 1; i < t; ++i)
1021                         {
1022                                 s = argv(i);
1023                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1024                                 {
1025                                         e = get_weaponinfo(j);
1026                                         if(e.netname == s)
1027                                         {
1028                                                 self = spawn();
1029                                                 copyentity(oldself, self);
1030                                                 self.classname = "replacedweapon";
1031                                                 weapon_defaultspawnfunc(j);
1032                                                 break;
1033                                         }
1034                                 }
1035                                 if(j > WEP_LAST)
1036                                 {
1037                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1038                                 }
1039                         }
1040                         self = oldself;
1041                 }
1042                 if(t >= 1)
1043                 {
1044                         s = argv(0);
1045                         wpn = 0;
1046                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1047                         {
1048                                 e = get_weaponinfo(j);
1049                                 if(e.netname == s)
1050                                 {
1051                                         wpn = j;
1052                                         break;
1053                                 }
1054                         }
1055                         if(j > WEP_LAST)
1056                         {
1057                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1058                         }
1059                 }
1060                 if(wpn == 0)
1061                 {
1062                         remove(self);
1063                         startitem_failed = TRUE;
1064                         return;
1065                 }
1066         }
1067
1068         e = get_weaponinfo(wpn);
1069
1070         if(!self.respawntime)
1071         {
1072                 if(e.weapons & WEPBIT_SUPERWEAPONS)
1073                 {
1074                         self.respawntime = g_pickup_respawntime_superweapon;
1075                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1076                 }
1077                 else
1078                 {
1079                         self.respawntime = g_pickup_respawntime_weapon;
1080                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1081                 }
1082         }
1083
1084         if(e.weapons & WEPBIT_SUPERWEAPONS)
1085                 if(!self.superweapons_finished)
1086                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1087
1088         if(e.items)
1089         {
1090                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1091                 {
1092                         if(e.items & j)
1093                         {
1094                                 ammofield = Item_CounterField(j);
1095                                 if(!self.ammofield)
1096                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1097                         }
1098                 }
1099         }
1100
1101         // pickup anyway
1102         if(g_pickup_weapons_anyway)
1103                 self.pickup_anyway = TRUE;
1104
1105         f = FL_WEAPON;
1106
1107         // no weapon-stay on superweapons
1108         if(e.weapons & WEPBIT_SUPERWEAPONS)
1109                 f |= FL_NO_WEAPON_STAY;
1110
1111         // weapon stay isn't supported for teamed weapons
1112         if(self.team)
1113                 f |= FL_NO_WEAPON_STAY;
1114
1115         // stupid minstagib hack, don't ask
1116         if(g_minstagib)
1117                 if(self.ammo_cells)
1118                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1119
1120         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1121         if (self.modelindex) // don't precache if self was removed
1122                 weapon_action(e.weapon, WR_PRECACHE);
1123 }
1124
1125 void spawnfunc_weapon_shotgun (void);
1126 void spawnfunc_weapon_uzi (void) {
1127         if(autocvar_sv_q3acompat_machineshotgunswap)
1128         if(self.classname != "droppedweapon")
1129         {
1130                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1131                 return;
1132         }
1133         weapon_defaultspawnfunc(WEP_UZI);
1134 }
1135
1136 void spawnfunc_weapon_shotgun (void) {
1137         if(autocvar_sv_q3acompat_machineshotgunswap)
1138         if(self.classname != "droppedweapon")
1139         {
1140                 weapon_defaultspawnfunc(WEP_UZI);
1141                 return;
1142         }
1143         weapon_defaultspawnfunc(WEP_SHOTGUN);
1144 }
1145
1146 void spawnfunc_weapon_nex (void)
1147 {
1148         if (g_minstagib)
1149         {
1150                 minstagib_items(IT_CELLS);
1151                 self.think = minst_remove_item;
1152                 self.nextthink = time;
1153                 return;
1154         }
1155         weapon_defaultspawnfunc(WEP_NEX);
1156 }
1157
1158 void spawnfunc_weapon_minstanex (void)
1159 {
1160         if (g_minstagib)
1161         {
1162                 minstagib_items(IT_CELLS);
1163                 self.think = minst_remove_item;
1164                 self.nextthink = time;
1165                 return;
1166         }
1167         weapon_defaultspawnfunc(WEP_MINSTANEX);
1168 }
1169
1170 void spawnfunc_weapon_rocketlauncher (void)
1171 {
1172         if (g_minstagib)
1173         {
1174                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1175                 self.think = minst_remove_item;
1176                 self.nextthink = time;
1177                 return;
1178         }
1179         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1180 }
1181
1182 void spawnfunc_item_rockets (void) {
1183         if(!self.ammo_rockets)
1184                 self.ammo_rockets = g_pickup_rockets;
1185         if(!self.pickup_anyway)
1186                 self.pickup_anyway = g_pickup_ammo_anyway;
1187         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1188 }
1189
1190 void spawnfunc_item_shells (void);
1191 void spawnfunc_item_bullets (void) {
1192         if(!weaponswapping)
1193         if(autocvar_sv_q3acompat_machineshotgunswap)
1194         if(self.classname != "droppedweapon")
1195         {
1196                 weaponswapping = TRUE;
1197                 spawnfunc_item_shells();
1198                 weaponswapping = FALSE;
1199                 return;
1200         }
1201
1202         if(!self.ammo_nails)
1203                 self.ammo_nails = g_pickup_nails;
1204         if(!self.pickup_anyway)
1205                 self.pickup_anyway = g_pickup_ammo_anyway;
1206         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1207 }
1208
1209 void spawnfunc_item_cells (void) {
1210         if(!self.ammo_cells)
1211                 self.ammo_cells = g_pickup_cells;
1212         if(!self.pickup_anyway)
1213                 self.pickup_anyway = g_pickup_ammo_anyway;
1214         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1215 }
1216
1217 void spawnfunc_item_shells (void) {
1218         if(!weaponswapping)
1219         if(autocvar_sv_q3acompat_machineshotgunswap)
1220         if(self.classname != "droppedweapon")
1221         {
1222                 weaponswapping = TRUE;
1223                 spawnfunc_item_bullets();
1224                 weaponswapping = FALSE;
1225                 return;
1226         }
1227
1228         if(!self.ammo_shells)
1229                 self.ammo_shells = g_pickup_shells;
1230         if(!self.pickup_anyway)
1231                 self.pickup_anyway = g_pickup_ammo_anyway;
1232         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1233 }
1234
1235 void spawnfunc_item_armor_small (void) {
1236         if(!self.armorvalue)
1237                 self.armorvalue = g_pickup_armorsmall;
1238         if(!self.max_armorvalue)
1239                 self.max_armorvalue = g_pickup_armorsmall_max;
1240         if(!self.pickup_anyway)
1241                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1242         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1243 }
1244
1245 void spawnfunc_item_armor_medium (void) {
1246         if(!self.armorvalue)
1247                 self.armorvalue = g_pickup_armormedium;
1248         if(!self.max_armorvalue)
1249                 self.max_armorvalue = g_pickup_armormedium_max;
1250         if(!self.pickup_anyway)
1251                 self.pickup_anyway = g_pickup_armormedium_anyway;
1252         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1253 }
1254
1255 void spawnfunc_item_armor_big (void) {
1256         if(!self.armorvalue)
1257                 self.armorvalue = g_pickup_armorbig;
1258         if(!self.max_armorvalue)
1259                 self.max_armorvalue = g_pickup_armorbig_max;
1260         if(!self.pickup_anyway)
1261                 self.pickup_anyway = g_pickup_armorbig_anyway;
1262         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1263 }
1264
1265 void spawnfunc_item_armor_large (void) {
1266         if(!self.armorvalue)
1267                 self.armorvalue = g_pickup_armorlarge;
1268         if(!self.max_armorvalue)
1269                 self.max_armorvalue = g_pickup_armorlarge_max;
1270         if(!self.pickup_anyway)
1271                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1272         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1273 }
1274
1275 void spawnfunc_item_health_small (void) {
1276         if(!self.max_health)
1277                 self.max_health = g_pickup_healthsmall_max;
1278         if(!self.health)
1279                 self.health = g_pickup_healthsmall;
1280         if(!self.pickup_anyway)
1281                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1282         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1283 }
1284
1285 void spawnfunc_item_health_medium (void) {
1286         if(!self.max_health)
1287                 self.max_health = g_pickup_healthmedium_max;
1288         if(!self.health)
1289                 self.health = g_pickup_healthmedium;
1290         if(!self.pickup_anyway)
1291                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1292         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1293 }
1294
1295 void spawnfunc_item_health_large (void) {
1296         if(!self.max_health)
1297                 self.max_health = g_pickup_healthlarge_max;
1298         if(!self.health)
1299                 self.health = g_pickup_healthlarge;
1300         if(!self.pickup_anyway)
1301                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1302         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1303 }
1304
1305 void spawnfunc_item_health_mega (void) {
1306         if(g_minstagib) {
1307                 minstagib_items(IT_NAILS);
1308         } else {
1309                 if(!self.max_health)
1310                         self.max_health = g_pickup_healthmega_max;
1311                 if(!self.health)
1312                         self.health = g_pickup_healthmega;
1313                 if(!self.pickup_anyway)
1314                         self.pickup_anyway = g_pickup_healthmega_anyway;
1315                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1316         }
1317 }
1318
1319 // support old misnamed entities
1320 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1321 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1322 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1323 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1324 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1325
1326 void spawnfunc_item_strength (void) {
1327         if(g_minstagib) {
1328                 minstagib_items(IT_STRENGTH);
1329         } else {
1330                 precache_sound("weapons/strength_fire.wav");
1331                 if(!self.strength_finished)
1332                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1333                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1334         }
1335 }
1336
1337 void spawnfunc_item_invincible (void) {
1338         if(g_minstagib) {
1339                 minstagib_items(IT_INVINCIBLE);
1340         } else {
1341                 if(!self.invincible_finished)
1342                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1343                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1344         }
1345 }
1346
1347 void spawnfunc_item_minst_cells (void) {
1348         if (g_minstagib)
1349         {
1350                 minst_no_auto_cells = 1;
1351                 minstagib_items(IT_CELLS);
1352         }
1353         else
1354                 remove(self);
1355 }
1356
1357 // compatibility:
1358 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1359
1360 float GiveItems(entity e, float beginarg, float endarg);
1361 void target_items_use (void)
1362 {
1363         if(activator.classname == "droppedweapon")
1364         {
1365                 EXACTTRIGGER_TOUCH;
1366                 remove(activator);
1367                 return;
1368         }
1369
1370         if(activator.classname != "player")
1371                 return;
1372         if(activator.deadflag != DEAD_NO)
1373                 return;
1374         EXACTTRIGGER_TOUCH;
1375
1376         entity e;
1377         for(e = world; (e = find(e, classname, "droppedweapon")); )
1378                 if(e.enemy == activator)
1379                         remove(e);
1380
1381         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1382                 centerprint(activator, self.message);
1383 }
1384
1385 void spawnfunc_target_items (void)
1386 {
1387         float n, i, j;
1388         entity e;
1389
1390         self.use = target_items_use;
1391         if(!self.strength_finished)
1392                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1393         if(!self.invincible_finished)
1394                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1395         if(!self.superweapons_finished)
1396                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1397
1398         precache_sound("misc/itempickup.wav");
1399         precache_sound("misc/megahealth.wav");
1400         precache_sound("misc/armor25.wav");
1401         precache_sound("misc/powerup.wav");
1402         precache_sound("misc/poweroff.wav");
1403         precache_sound("weapons/weaponpickup.wav");
1404
1405         n = tokenize_console(self.netname);
1406         if(argv(0) == "give")
1407         {
1408                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1409         }
1410         else
1411         {
1412                 for(i = 0; i < n; ++i)
1413                 {
1414                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1415                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1416                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1417                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1418                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1419                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1420                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1421                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1422                         else
1423                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1424                         {
1425                                 e = get_weaponinfo(j);
1426                                 if(argv(i) == e.netname)
1427                                 {
1428                                         self.weapons |= e.weapons;
1429                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1430                                                 weapon_action(e.weapon, WR_PRECACHE);
1431                                         break;
1432                                 }
1433                         }
1434                         if(j > WEP_LAST)
1435                                 print("target_items: invalid item ", argv(i), "\n");
1436                 }
1437
1438                 string itemprefix, valueprefix;
1439                 if(self.spawnflags == 0)
1440                 {
1441                         itemprefix = "";
1442                         valueprefix = "";
1443                 }
1444                 else if(self.spawnflags == 1)
1445                 {
1446                         itemprefix = "max ";
1447                         valueprefix = "max ";
1448                 }
1449                 else if(self.spawnflags == 2)
1450                 {
1451                         itemprefix = "min ";
1452                         valueprefix = "min ";
1453                 }
1454                 else if(self.spawnflags == 4)
1455                 {
1456                         itemprefix = "minus ";
1457                         valueprefix = "max ";
1458                 }
1459                 else
1460                         error("invalid spawnflags");
1461
1462                 self.netname = "";
1463                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1464                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1465                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1466                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1467                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1468                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1469                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1470                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1471                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1472                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1473                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1474                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1475                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1476                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1477                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1478                 {
1479                         e = get_weaponinfo(j);
1480                         if(e.weapons)
1481                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1482                 }
1483         }
1484         self.netname = strzone(self.netname);
1485         //print(self.netname, "\n");
1486
1487         n = tokenize_console(self.netname);
1488         for(i = 0; i < n; ++i)
1489         {
1490                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1491                 {
1492                         e = get_weaponinfo(j);
1493                         if(argv(i) == e.netname)
1494                         {
1495                                 weapon_action(e.weapon, WR_PRECACHE);
1496                                 break;
1497                         }
1498                 }
1499         }
1500 }
1501
1502 void spawnfunc_item_fuel(void)
1503 {
1504         if(!self.ammo_fuel)
1505                 self.ammo_fuel = g_pickup_fuel;
1506         if(!self.pickup_anyway)
1507                 self.pickup_anyway = g_pickup_ammo_anyway;
1508         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1509 }
1510
1511 void spawnfunc_item_fuel_regen(void)
1512 {
1513         if(start_items & IT_FUEL_REGEN)
1514         {
1515                 spawnfunc_item_fuel();
1516                 return;
1517         }
1518         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1519 }
1520
1521 void spawnfunc_item_jetpack(void)
1522 {
1523         if(g_grappling_hook)
1524                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1525         if(!self.ammo_fuel)
1526                 self.ammo_fuel = g_pickup_fuel_jetpack;
1527         if(start_items & IT_JETPACK)
1528         {
1529                 spawnfunc_item_fuel();
1530                 return;
1531         }
1532         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1533 }
1534
1535
1536 #define OP_SET 0
1537 #define OP_MIN 1
1538 #define OP_MAX 2
1539 #define OP_PLUS 3
1540 #define OP_MINUS 4
1541
1542 float GiveBit(entity e, .float fld, float bit, float op, float val)
1543 {
1544         float v0, v1;
1545         v0 = (e.fld & bit);
1546         switch(op)
1547         {
1548                 case OP_SET:
1549                         if(val > 0)
1550                                 e.fld |= bit;
1551                         else
1552                                 e.fld &~= bit;
1553                         break;
1554                 case OP_MIN:
1555                 case OP_PLUS:
1556                         if(val > 0)
1557                                 e.fld |= bit;
1558                         break;
1559                 case OP_MAX:
1560                         if(val <= 0)
1561                                 e.fld &~= bit;
1562                         break;
1563                 case OP_MINUS:
1564                         if(val > 0)
1565                                 e.fld &~= bit;
1566                         break;
1567         }
1568         v1 = (e.fld & bit);
1569         return (v0 != v1);
1570 }
1571
1572 float GiveValue(entity e, .float fld, float op, float val)
1573 {
1574         float v0, v1;
1575         v0 = e.fld;
1576         switch(op)
1577         {
1578                 case OP_SET:
1579                         e.fld = val;
1580                         break;
1581                 case OP_MIN:
1582                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1583                         break;
1584                 case OP_MAX:
1585                         e.fld = min(e.fld, val);
1586                         break;
1587                 case OP_PLUS:
1588                         e.fld += val;
1589                         break;
1590                 case OP_MINUS:
1591                         e.fld -= val;
1592                         break;
1593         }
1594         v1 = e.fld;
1595         return (v0 != v1);
1596 }
1597
1598 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1599 {
1600         if(v1 == v0)
1601                 return;
1602         if(v1 <= v0 - t)
1603         {
1604                 if(snd_decr != "")
1605                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1606         }
1607         else if(v0 >= v0 + t)
1608         {
1609                 if(snd_incr != "")
1610                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1611         }
1612 }
1613
1614 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1615 {
1616         if(v0 < v1)
1617                 e.rotfield = max(e.rotfield, time + rottime);
1618         else if(v0 > v1)
1619                 e.regenfield = max(e.regenfield, time + regentime);
1620 }
1621
1622 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1623 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1624 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1625 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1626
1627 float GiveItems(entity e, float beginarg, float endarg)
1628 {
1629         float got, i, j, val, op;
1630         float _switchweapon;
1631         entity wi;
1632         string cmd;
1633
1634         val = 999;
1635         op = OP_SET;
1636
1637         got = 0;
1638
1639         _switchweapon = FALSE;
1640         if (e.autoswitch)
1641                 if (e.switchweapon == w_getbestweapon(e))
1642                         _switchweapon = TRUE;
1643
1644         e.strength_finished = max(0, e.strength_finished - time);
1645         e.invincible_finished = max(0, e.invincible_finished - time);
1646         e.superweapons_finished = max(0, e.superweapons_finished - time);
1647
1648         PREGIVE(e, items);
1649         PREGIVE(e, weapons);
1650         PREGIVE(e, strength_finished);
1651         PREGIVE(e, invincible_finished);
1652         PREGIVE(e, superweapons_finished);
1653         PREGIVE(e, ammo_nails);
1654         PREGIVE(e, ammo_cells);
1655         PREGIVE(e, ammo_shells);
1656         PREGIVE(e, ammo_rockets);
1657         PREGIVE(e, ammo_fuel);
1658         PREGIVE(e, armorvalue);
1659         PREGIVE(e, health);
1660
1661         for(i = beginarg; i < endarg; ++i)
1662         {
1663                 cmd = argv(i);
1664
1665                 if(cmd == "0" || stof(cmd))
1666                 {
1667                         val = stof(cmd);
1668                         continue;
1669                 }
1670                 switch(cmd)
1671                 {
1672                         case "no":
1673                                 op = OP_MAX;
1674                                 val = 0;
1675                                 continue;
1676                         case "max":
1677                                 op = OP_MAX;
1678                                 continue;
1679                         case "min":
1680                                 op = OP_MIN;
1681                                 continue;
1682                         case "plus":
1683                                 op = OP_PLUS;
1684                                 continue;
1685                         case "minus":
1686                                 op = OP_MINUS;
1687                                 continue;
1688                         case "ALL":
1689                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1690                                 got += GiveValue(e, strength_finished, op, val);
1691                                 got += GiveValue(e, invincible_finished, op, val);
1692                                 got += GiveValue(e, superweapons_finished, op, val);
1693                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1694                         case "all":
1695                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1696                                 got += GiveValue(e, health, op, val);
1697                                 got += GiveValue(e, armorvalue, op, val);
1698                         case "allweapons":
1699                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1700                                 {
1701                                         wi = get_weaponinfo(j);
1702                                         if(wi.weapons)
1703                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1704                                 }
1705                         case "allammo":
1706                                 got += GiveValue(e, ammo_cells, op, val);
1707                                 got += GiveValue(e, ammo_shells, op, val);
1708                                 got += GiveValue(e, ammo_nails, op, val);
1709                                 got += GiveValue(e, ammo_rockets, op, val);
1710                                 got += GiveValue(e, ammo_fuel, op, val);
1711                                 break;
1712                         case "unlimited_ammo":
1713                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1714                                 break;
1715                         case "unlimited_weapon_ammo":
1716                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1717                                 break;
1718                         case "unlimited_superweapons":
1719                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1720                                 break;
1721                         case "jetpack":
1722                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1723                                 break;
1724                         case "fuel_regen":
1725                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1726                                 break;
1727                         case "strength":
1728                                 got += GiveValue(e, strength_finished, op, val);
1729                                 break;
1730                         case "invincible":
1731                                 got += GiveValue(e, invincible_finished, op, val);
1732                                 break;
1733                         case "superweapons":
1734                                 got += GiveValue(e, superweapons_finished, op, val);
1735                                 break;
1736                         case "cells":
1737                                 got += GiveValue(e, ammo_cells, op, val);
1738                                 break;
1739                         case "shells":
1740                                 got += GiveValue(e, ammo_shells, op, val);
1741                                 break;
1742                         case "nails":
1743                         case "bullets":
1744                                 got += GiveValue(e, ammo_nails, op, val);
1745                                 break;
1746                         case "rockets":
1747                                 got += GiveValue(e, ammo_rockets, op, val);
1748                                 break;
1749                         case "health":
1750                                 got += GiveValue(e, health, op, val);
1751                                 break;
1752                         case "armor":
1753                                 got += GiveValue(e, armorvalue, op, val);
1754                                 break;
1755                         case "fuel":
1756                                 got += GiveValue(e, ammo_fuel, op, val);
1757                                 break;
1758                         default:
1759                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1760                                 {
1761                                         wi = get_weaponinfo(j);
1762                                         if(cmd == wi.netname)
1763                                         {
1764                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1765                                                 break;
1766                                         }
1767                                 }
1768                                 if(j > WEP_LAST)
1769                                         print("give: invalid item ", cmd, "\n");
1770                                 break;
1771                 }
1772                 val = 999;
1773                 op = OP_SET;
1774         }
1775
1776         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1777         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1778         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1779         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1780         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1781         {
1782                 wi = get_weaponinfo(j);
1783                 if(wi.weapons)
1784                 {
1785                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1786                         if not(save_weapons & wi.weapons)
1787                                 if(e.weapons & wi.weapons)
1788                                         weapon_action(wi.weapon, WR_PRECACHE);
1789                 }
1790         }
1791         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1792         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1793         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1794         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1795         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1796         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1797         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1798         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1799         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1800
1801         if(e.superweapons_finished <= 0)
1802                 if(self.weapons & WEPBIT_SUPERWEAPONS)
1803                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1804
1805         if (g_minstagib)
1806         {
1807                 e.health = bound(0, e.health, 100);
1808                 e.armorvalue = bound(0, e.armorvalue, 999);
1809         }
1810
1811         if(e.strength_finished <= 0)
1812                 e.strength_finished = 0;
1813         else
1814                 e.strength_finished += time;
1815         if(e.invincible_finished <= 0)
1816                 e.invincible_finished = 0;
1817         else
1818                 e.invincible_finished += time;
1819         if(e.superweapons_finished <= 0)
1820                 e.superweapons_finished = 0;
1821         else
1822                 e.superweapons_finished += time;
1823
1824         if not(e.weapons & W_WeaponBit(e.switchweapon))
1825                 _switchweapon = TRUE;
1826         if(_switchweapon)
1827                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1828
1829         return got;
1830 }