qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(cvar_string("g_ghost_items_color"));
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent green and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent green and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (cvar("g_nodepthtestitems"))
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (cvar("g_fullbrightitems"))
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 152         else
 153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 202                                 if(self.waypointsprite_attached)
 203                                 {
 204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 207                                 }
 208                         }
 209                 }
 210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 211                 if(self.waypointsprite_attached)
 212                 {
 213                         WaypointSprite_Ping(self.waypointsprite_attached);
 214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 215                 }
 216         }
 217 }
 218
 219 void Item_ScheduleRespawnIn(entity e, float t)
 220 {
 221         if(e.flags & FL_POWERUP)
 222         {
 223                 e.think = Item_RespawnCountdown;
 224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 225                 e.count = 0;
 226         }
 227         else
 228         {
 229                 e.think = Item_Respawn;
 230                 e.nextthink = time + t;
 231         }
 232 }
 233
 234 void Item_ScheduleRespawn(entity e)
 235 {
 236         Item_Show(e, 0);
 237         if(e.respawntime > 0) // if respawntime is -1, this item does not respawn
 238                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 239         else
 240                 remove(e);
 241 }
 242
 243 void Item_ScheduleInitialRespawn(entity e)
 244 {
 245         Item_Show(e, 0);
 246         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 247 }
 248
 249 float Item_GiveTo(entity item, entity player)
 250 {
 251         float _switchweapon;
 252         float pickedup;
 253         float it;
 254         float i;
 255         entity e;
 256
 257         // if nothing happens to player, just return without taking the item
 258         pickedup = FALSE;
 259         _switchweapon = FALSE;
 260
 261         if (g_minstagib)
 262         {
 263                 if(item.spawnshieldtime)
 264                 {
 265                         if (item.ammo_fuel)
 266                         if (player.ammo_fuel < g_pickup_fuel_max)
 267                         {
 268                                 pickedup = TRUE;
 269                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 270                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 271                         }
 272                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 273                         {
 274                                 pickedup = TRUE;
 275                                 player.items |= it;
 276                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 277                         }
 278
 279                         _switchweapon = TRUE;
 280                         if (item.ammo_cells)
 281                         {
 282                                 pickedup = TRUE;
 283                                 // play some cool sounds ;)
 284                                 centerprint(player, "\n");
 285                                 if (clienttype(player) == CLIENTTYPE_REAL)
 286                                 {
 287                                         if(player.health <= 5)
 288                                                 AnnounceTo(player, "lastsecond");
 289                                         else if(player.health < 50)
 290                                                 AnnounceTo(player, "narrowly");
 291                                 }
 292                                 // sound not available
 293                                 // else if(item.items == IT_CELLS)
 294                                 //      AnnounceTo(player, "ammo");
 295
 296                                 if (item.weapons & WEPBIT_MINSTANEX)
 297                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 298                                 if (item.ammo_cells)
 299                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 300                                 player.health = 100;
 301                         }
 302
 303                         // extralife powerup
 304                         if (item.max_health)
 305                         {
 306                                 pickedup = TRUE;
 307                                 // sound not available
 308                                 // AnnounceTo(player, "_lives");
 309                                 player.armorvalue = min(player.armorvalue + cvar("g_minstagib_extralives"), 999);
 310                                 sprint(player, "^3You picked up some extra lives\n");
 311                         }
 312
 313                         // invis powerup
 314                         if (item.strength_finished)
 315                         {
 316                                 pickedup = TRUE;
 317                                 // sound not available
 318                                 // AnnounceTo(player, "invisible");
 319                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 320                         }
 321
 322                         // speed powerup
 323                         if (item.invincible_finished)
 324                         {
 325                                 pickedup = TRUE;
 326                                 // sound not available
 327                                 // AnnounceTo(player, "speed");
 328                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 329                         }
 330
 331                         if (item.ammo_fuel)
 332                         if (player.ammo_fuel < g_pickup_fuel_max)
 333                         {
 334                                 pickedup = TRUE;
 335                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 336                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 337                         }
 338                 }
 339         }
 340         else
 341         {
 342                 if (g_weapon_stay == 1)
 343                 if not(item.flags & FL_NO_WEAPON_STAY)
 344                 if (item.flags & FL_WEAPON)
 345                 {
 346                         if(item.classname == "droppedweapon")
 347                         {
 348                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 349                                         goto skip;
 350                         }
 351                         else
 352                         {
 353                                 if (player.weapons & item.weapons)
 354                                         goto skip;
 355                         }
 356                 }
 357
 358                 // in case the player has autoswitch enabled do the following:
 359                 // if the player is using their best weapon before items are given, they
 360                 // probably want to switch to an even better weapon after items are given
 361                 if (player.autoswitch)
 362                 if (player.switchweapon == w_getbestweapon(player))
 363                         _switchweapon = TRUE;
 364
 365                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 366                         _switchweapon = TRUE;
 367
 368                 if(item.spawnshieldtime)
 369                 {
 370                         if (item.ammo_shells)
 371                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 372                         {
 373                                 pickedup = TRUE;
 374                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 375                         }
 376                         if (item.ammo_nails)
 377                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 378                         {
 379                                 pickedup = TRUE;
 380                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 381                         }
 382                         if (item.ammo_rockets)
 383                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 384                         {
 385                                 pickedup = TRUE;
 386                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 387                         }
 388                         if (item.ammo_cells)
 389                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 390                         {
 391                                 pickedup = TRUE;
 392                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 393                         }
 394                         if (item.ammo_fuel)
 395                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 396                         {
 397                                 pickedup = TRUE;
 398                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 399                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 400                         }
 401                 }
 402
 403                 if (item.flags & FL_WEAPON)
 404                 if ((it = item.weapons - (item.weapons & player.weapons)) || g_pickup_weapons_anyway)
 405                 {
 406                         pickedup = TRUE;
 407                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 408                         {
 409                                 e = get_weaponinfo(i);
 410                                 if(it & e.weapons)
 411                                         W_GiveWeapon (player, e.weapon, item.netname);
 412                         }
 413                 }
 414
 415                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 416                 {
 417                         pickedup = TRUE;
 418                         player.items |= it;
 419                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 420                 }
 421
 422                 if(item.spawnshieldtime)
 423                 {
 424                         if (item.strength_finished)
 425                         {
 426                                 pickedup = TRUE;
 427                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 428                         }
 429                         if (item.invincible_finished)
 430                         {
 431                                 pickedup = TRUE;
 432                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 433                         }
 434
 435                         if (item.health)
 436                         if ((player.health < item.max_health) || item.pickup_anyway)
 437                         {
 438                                 pickedup = TRUE;
 439                                 player.health = min(player.health + item.health, item.max_health);
 440                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 441                         }
 442                         if (item.armorvalue)
 443                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 444                         {
 445                                 pickedup = TRUE;
 446                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 447                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 448                         }
 449                 }
 450         }
 451
 452 :skip
 453         // always eat teamed entities
 454         if(item.team)
 455                 pickedup = TRUE;
 456
 457         if (!pickedup)
 458                 return 0;
 459
 460         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 461         if (_switchweapon)
 462                 if (player.switchweapon != w_getbestweapon(player))
 463                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 464
 465         return 1;
 466 }
 467
 468 void Item_Touch (void)
 469 {
 470         entity e, head;
 471
 472         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 473         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 474         {
 475                 remove(self);
 476                 return;
 477         }
 478         if (other.classname != "player")
 479                 return;
 480         if (other.deadflag)
 481                 return;
 482         if (self.solid != SOLID_TRIGGER)
 483                 return;
 484         if (self.owner == other)
 485                 return;
 486
 487         if(!Item_GiveTo(self, other))
 488                 return;
 489
 490         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 491
 492         if (self.classname == "droppedweapon")
 493                 remove (self);
 494         else if not(self.spawnshieldtime)
 495                 return;
 496         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 497                 return;
 498         else
 499         {
 500                 if(self.team)
 501                 {
 502                         RandomSelection_Init();
 503                         for(head = world; (head = findfloat(head, team, self.team)); )
 504                         {
 505                                 if(head.flags & FL_ITEM)
 506                                 {
 507                                         Item_Show(head, -1);
 508                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 509                                 }
 510                         }
 511                         e = RandomSelection_chosen_ent;
 512                 }
 513                 else
 514                         e = self;
 515                 Item_ScheduleRespawn(e);
 516         }
 517 }
 518
 519 void Item_FindTeam()
 520 {
 521         entity head, e;
 522
 523         if(self.effects & EF_NODRAW)
 524         {
 525                 // marker for item team search
 526                 dprint("Initializing item team ", ftos(self.team), "\n");
 527                 RandomSelection_Init();
 528                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 529                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 530                 e = RandomSelection_chosen_ent;
 531                 e.state = 0;
 532                 Item_Show(e, 1);
 533
 534                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 535                 {
 536                         if(head != e)
 537                         {
 538                                 // make it a non-spawned item
 539                                 Item_Show(head, -1);
 540                                 head.state = 1; // state 1 = initially hidden item
 541                         }
 542                         head.effects &~= EF_NODRAW;
 543                 }
 544
 545                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 546                         Item_ScheduleInitialRespawn(e);
 547         }
 548 }
 549
 550 void Item_Reset()
 551 {
 552         Item_Show(self, !self.state);
 553         setorigin (self, self.origin);
 554         self.think = SUB_Null;
 555         self.nextthink = 0;
 556
 557         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 558                 Item_ScheduleInitialRespawn(self);
 559 }
 560
 561 // Savage: used for item garbage-collection
 562 // TODO: perhaps nice special effect?
 563 void RemoveItem(void)
 564 {
 565         remove(self);
 566 }
 567
 568 // pickup evaluation functions
 569 // these functions decide how desirable an item is to the bots
 570
 571 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 572
 573 float weapon_pickupevalfunc(entity player, entity item)
 574 {
 575         float c, i, j, position;
 576
 577         // See if I have it already
 578         if(player.weapons & item.weapons == item.weapons)
 579         {
 580                 // If I can pick it up
 581                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 582                         c = 0;
 583                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 584                 {
 585                         // Skilled bots will grab more
 586                         c = bound(0, skill / 10, 1) * 0.5;
 587                 }
 588                 else
 589                         c = 0;
 590         }
 591         else
 592                 c = 1;
 593
 594         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 595         if( bot_custom_weapon && c )
 596         {
 597                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 598                 {
 599                         // Find weapon
 600                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 601                                 continue;
 602
 603                         // Find the highest position on any range
 604                         position = -1;
 605                         for(j = 0; j < WEP_LAST ; ++j){
 606                                 if(
 607                                                 bot_weapons_far[j] == i ||
 608                                                 bot_weapons_mid[j] == i ||
 609                                                 bot_weapons_close[j] == i
 610                                   )
 611                                 {
 612                                         position = j;
 613                                         break;
 614                                 }
 615                         }
 616
 617                         // Rate it
 618                         if (position >= 0 )
 619                         {
 620                                 position = WEP_LAST - position;
 621                                 // item.bot_pickupbasevalue is overwritten here
 622                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 623                         }
 624                 }
 625         }
 626
 627         return item.bot_pickupbasevalue * c;
 628 };
 629
 630 float commodity_pickupevalfunc(entity player, entity item)
 631 {
 632         float c, i, need_shells, need_nails, need_rockets, need_cells;
 633         entity wi;
 634         c = 0;
 635
 636         // Detect needed ammo
 637         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 638         {
 639                 wi = get_weaponinfo(i);
 640
 641                 if not(wi.weapons & player.weapons)
 642                         continue;
 643
 644                 if(wi.items & IT_SHELLS)
 645                         need_shells = TRUE;
 646                 else if(wi.items & IT_NAILS)
 647                         need_nails = TRUE;
 648                 else if(wi.items & IT_ROCKETS)
 649                         need_rockets = TRUE;
 650                 else if(wi.items & IT_CELLS)
 651                         need_cells = TRUE;
 652         }
 653
 654         // TODO: figure out if the player even has the weapon this ammo is for?
 655         // may not affect strategy much though...
 656         // find out how much more ammo/armor/health the player can hold
 657         if (need_shells)
 658         if (item.ammo_shells)
 659         if (player.ammo_shells < g_pickup_shells_max)
 660                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 661         if (need_nails)
 662         if (item.ammo_nails)
 663         if (player.ammo_nails < g_pickup_nails_max)
 664                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 665         if (need_rockets)
 666         if (item.ammo_rockets)
 667         if (player.ammo_rockets < g_pickup_rockets_max)
 668                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 669         if (need_cells)
 670         if (item.ammo_cells)
 671         if (player.ammo_cells < g_pickup_cells_max)
 672                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 673         if (item.armorvalue)
 674         if (player.armorvalue < item.max_armorvalue)
 675                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 676         if (item.health)
 677         if (player.health < item.max_health)
 678                 c = c + max(0, 1 - player.health / item.max_health);
 679
 680         return item.bot_pickupbasevalue * c;
 681 };
 682
 683
 684 .float is_item;
 685 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 686 {
 687         startitem_failed = FALSE;
 688
 689         self.items = itemid;
 690         self.weapons = weaponid;
 691
 692         // is it a dropped weapon?
 693         if (self.classname == "droppedweapon")
 694         {
 695                 self.reset = SUB_Remove;
 696                 // it's a dropped weapon
 697                 self.movetype = MOVETYPE_TOSS;
 698                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 699                 self.think = RemoveItem;
 700                 self.nextthink = time + 60;
 701                 // don't drop if in a NODROP zone (such as lava)
 702                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 703                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 704                 {
 705                         startitem_failed = TRUE;
 706                         remove(self);
 707                         return;
 708                 }
 709         }
 710         else
 711         {
 712                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 713                 {
 714                         startitem_failed = TRUE;
 715                         remove(self);
 716                         return;
 717                 }
 718
 719                 self.reset = Item_Reset;
 720                 // it's a level item
 721                 if(self.spawnflags & 1)
 722                         self.noalign = 1;
 723                 if (self.noalign)
 724                         self.movetype = MOVETYPE_NONE;
 725                 else
 726                         self.movetype = MOVETYPE_TOSS;
 727                 // do item filtering according to game mode and other things
 728                 if (!self.noalign)
 729                 {
 730                         // first nudge it off the floor a little bit to avoid math errors
 731                         setorigin(self, self.origin + '0 0 1');
 732                         // set item size before we spawn a spawnfunc_waypoint
 733                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 734                                 setsize (self, '-16 -16 0', '16 16 48');
 735                         else
 736                                 setsize (self, '-16 -16 0', '16 16 32');
 737                         // note droptofloor returns FALSE if stuck/or would fall too far
 738                         droptofloor();
 739                         waypoint_spawnforitem(self);
 740                 }
 741
 742                 if(teams_matter)
 743                 {
 744                         if(self.notteam)
 745                         {
 746                                 print("removed non-teamplay ", self.classname, "\n");
 747                                 startitem_failed = TRUE;
 748                                 remove (self);
 749                                 return;
 750                         }
 751                 }
 752                 else
 753                 {
 754                         if(self.notfree)
 755                         {
 756                                 print("removed non-FFA ", self.classname, "\n");
 757                                 startitem_failed = TRUE;
 758                                 remove (self);
 759                                 return;
 760                         }
 761                 }
 762
 763                 if(self.notq3a)
 764                 {
 765                         // We aren't TA or something like that, so we keep the Q3A entities
 766                         print("removed non-Q3A ", self.classname, "\n");
 767                         startitem_failed = TRUE;
 768                         remove (self);
 769                         return;
 770                 }
 771
 772                 /*
 773                  * can't do it that way, as it would break maps
 774                  * TODO make a target_give like entity another way, that perhaps has
 775                  * the weapon name in a key
 776                 if(self.targetname)
 777                 {
 778                         // target_give not yet supported; maybe later
 779                         print("removed targeted ", self.classname, "\n");
 780                         startitem_failed = TRUE;
 781                         remove (self);
 782                         return;
 783                 }
 784                 */
 785
 786                 if(cvar("spawn_debug") >= 2)
 787                 {
 788                         entity otheritem;
 789                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 790                         {
 791                                 if(otheritem.is_item)
 792                                 {
 793                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 794                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 795                                         error("Mapper sucks.");
 796                                 }
 797                         }
 798                         self.is_item = TRUE;
 799                 }
 800
 801                 if(g_lms || g_ca)
 802                 {
 803                         startitem_failed = TRUE;
 804                         remove(self);
 805                         return;
 806                 }
 807                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 808                 {
 809                         startitem_failed = TRUE;
 810                         remove(self);
 811                         return;
 812                 }
 813                 else if (g_minstagib)
 814                 {
 815                         // don't remove dropped items and powerups
 816                         if (self.classname != "minstagib")
 817                         {
 818                                 startitem_failed = TRUE;
 819                                 remove (self);
 820                                 return;
 821                         }
 822                 }
 823                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 824                 {
 825                         startitem_failed = TRUE;
 826                         remove (self);
 827                         return;
 828                 }
 829
 830                 weaponsInMap |= weaponid;
 831
 832                 precache_model (itemmodel);
 833                 precache_sound (pickupsound);
 834
 835                 precache_sound ("misc/itemrespawncountdown.wav");
 836                 if(!g_minstagib && itemid == IT_STRENGTH)
 837                         precache_sound ("misc/strength_respawn.wav");
 838                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 839                         precache_sound ("misc/shield_respawn.wav");
 840                 else
 841                         precache_sound ("misc/itemrespawn.wav");
 842
 843                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 844                         self.target = "###item###"; // for finding the nearest item using find()
 845         }
 846
 847         self.bot_pickup = TRUE;
 848         self.bot_pickupevalfunc = pickupevalfunc;
 849         self.bot_pickupbasevalue = pickupbasevalue;
 850         self.mdl = itemmodel;
 851         self.item_pickupsound = pickupsound;
 852         // let mappers override respawntime
 853         if(!self.respawntime) // both set
 854         {
 855                 self.respawntime = defaultrespawntime;
 856                 self.respawntimejitter = defaultrespawntimejitter;
 857         }
 858         self.netname = itemname;
 859         self.flags = FL_ITEM | itemflags;
 860         self.touch = Item_Touch;
 861         setmodel (self, self.mdl); // precision set below
 862         self.effects |= EF_LOWPRECISION;
 863         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 864                 setsize (self, '-16 -16 0', '16 16 48');
 865         else
 866                 setsize (self, '-16 -16 0', '16 16 32');
 867         if(itemflags & FL_WEAPON)
 868                 self.modelflags |= MF_ROTATE;
 869
 870         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 871         if (itemflags & FL_WEAPON)
 872         {
 873                 // neutral team color for pickup weapons
 874                 self.colormap = 1024; // color shirt=0 pants=0 grey
 875         }
 876
 877         Item_Show(self, 1);
 878         self.state = 0;
 879         if(self.team)
 880         {
 881                 if(!self.cnt)
 882                         self.cnt = 1; // item probability weight
 883                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 884                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 885         }
 886         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 887                 Item_ScheduleInitialRespawn(self);
 888 }
 889
 890 /* replace items in minstagib
 891  * IT_STRENGTH   = invisibility
 892  * IT_NAILS      = extra lives
 893  * IT_INVINCIBLE = speed
 894  */
 895 void minstagib_items (float itemid)
 896 {
 897         local float rnd;
 898         self.classname = "minstagib";
 899
 900         // replace rocket launchers and nex guns with ammo cells
 901         if (itemid == IT_CELLS)
 902         {
 903                 self.ammo_cells = 1;
 904                 StartItem ("models/items/a_cells.md3",
 905                         "misc/itempickup.wav", 45, 0,
 906                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 907                 return;
 908         }
 909
 910         // randomize
 911         rnd = random() * 3;
 912         if (rnd <= 1)
 913                 itemid = IT_STRENGTH;
 914         else if (rnd <= 2)
 915                 itemid = IT_NAILS;
 916         else
 917                 itemid = IT_INVINCIBLE;
 918
 919         // replace with invis
 920         if (itemid == IT_STRENGTH)
 921         {
 922                 self.strength_finished = 30;
 923                 StartItem ("models/items/g_strength.md3",
 924                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 925                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 926         }
 927         // replace with extra lives
 928         if (itemid == IT_NAILS)
 929         {
 930                 self.max_health = 1;
 931                 StartItem ("models/items/g_h100.md3",
 932                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 933                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 934         }
 935         // replace with speed
 936         if (itemid == IT_INVINCIBLE)
 937         {
 938                 self.invincible_finished = 30;
 939                 StartItem ("models/items/g_invincible.md3",
 940                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 941                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 942         }
 943 }
 944
 945 float minst_no_auto_cells;
 946 void minst_remove_item (void) {
 947         if(minst_no_auto_cells)
 948                 remove(self);
 949 }
 950
 951 float weaponswapping;
 952 float internalteam;
 953
 954 void weapon_defaultspawnfunc(float wpn)
 955 {
 956         entity e;
 957         float t;
 958         var .float ammofield;
 959         string s;
 960         entity oldself;
 961         float i, j;
 962
 963         // set the respawntime in advance (so replaced weapons can copy it)
 964
 965         if(!self.respawntime)
 966         {
 967                 e = get_weaponinfo(wpn);
 968                 if(e.items == IT_SUPERWEAPON)
 969                 {
 970                         self.respawntime = g_pickup_respawntime_powerup;
 971                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 972                 }
 973                 else
 974                 {
 975                         self.respawntime = g_pickup_respawntime_weapon;
 976                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 977                 }
 978         }
 979
 980         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 981         {
 982                 e = get_weaponinfo(wpn);
 983                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 984                 if(s == "0")
 985                 {
 986                         remove(self);
 987                         startitem_failed = TRUE;
 988                         return;
 989                 }
 990                 t = tokenize_console(s);
 991                 if(t >= 2)
 992                 {
 993                         self.team = --internalteam;
 994                         oldself = self;
 995                         for(i = 1; i < t; ++i)
 996                         {
 997                                 s = argv(i);
 998                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 999                                 {
1000                                         e = get_weaponinfo(j);
1001                                         if(e.netname == s)
1002                                         {
1003                                                 self = spawn();
1004                                                 copyentity(oldself, self);
1005                                                 self.classname = "replacedweapon";
1006                                                 weapon_defaultspawnfunc(j);
1007                                                 break;
1008                                         }
1009                                 }
1010                                 if(j > WEP_LAST)
1011                                 {
1012                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1013                                 }
1014                         }
1015                         self = oldself;
1016                 }
1017                 if(t >= 1)
1018                 {
1019                         s = argv(0);
1020                         wpn = 0;
1021                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1022                         {
1023                                 e = get_weaponinfo(j);
1024                                 if(e.netname == s)
1025                                 {
1026                                         wpn = j;
1027                                         break;
1028                                 }
1029                         }
1030                         if(j > WEP_LAST)
1031                         {
1032                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1033                         }
1034                 }
1035                 if(wpn == 0)
1036                 {
1037                         remove(self);
1038                         startitem_failed = TRUE;
1039                         return;
1040                 }
1041         }
1042
1043         e = get_weaponinfo(wpn);
1044
1045         if(e.items && e.items != IT_SUPERWEAPON)
1046         {
1047                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1048                 {
1049                         if(e.items & j)
1050                         {
1051                                 ammofield = Item_CounterField(j);
1052                                 if(!self.ammofield)
1053                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1054                         }
1055                 }
1056         }
1057         else
1058         {
1059                 self.flags |= FL_NO_WEAPON_STAY;
1060         }
1061
1062         // weapon stay isn't supported for teamed weapons
1063         if(self.team)
1064                 self.flags |= FL_NO_WEAPON_STAY;
1065
1066         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1067         {
1068                 self.ammo_shells = 0;
1069                 self.ammo_nails = 0;
1070                 self.ammo_cells = 0;
1071                 self.ammo_rockets = 0;
1072                 // weapon stay 2: don't use ammo on weapon pickups; instead
1073                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1074         }
1075
1076         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1077         if (self.modelindex) // don't precache if self was removed
1078                 weapon_action(e.weapon, WR_PRECACHE);
1079 }
1080
1081 void spawnfunc_weapon_shotgun (void);
1082 void spawnfunc_weapon_uzi (void) {
1083         if(q3acompat_machineshotgunswap)
1084         if(self.classname != "droppedweapon")
1085         {
1086                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1087                 return;
1088         }
1089         weapon_defaultspawnfunc(WEP_UZI);
1090 }
1091
1092 void spawnfunc_weapon_shotgun (void) {
1093         if(q3acompat_machineshotgunswap)
1094         if(self.classname != "droppedweapon")
1095         {
1096                 weapon_defaultspawnfunc(WEP_UZI);
1097                 return;
1098         }
1099         weapon_defaultspawnfunc(WEP_SHOTGUN);
1100 }
1101
1102 void spawnfunc_weapon_nex (void)
1103 {
1104         if (g_minstagib)
1105         {
1106                 minstagib_items(IT_CELLS);
1107                 self.think = minst_remove_item;
1108                 self.nextthink = time;
1109                 return;
1110         }
1111         weapon_defaultspawnfunc(WEP_NEX);
1112 }
1113
1114 void spawnfunc_weapon_minstanex (void)
1115 {
1116         if (g_minstagib)
1117         {
1118                 minstagib_items(IT_CELLS);
1119                 self.think = minst_remove_item;
1120                 self.nextthink = time;
1121                 return;
1122         }
1123         weapon_defaultspawnfunc(WEP_MINSTANEX);
1124 }
1125
1126 void spawnfunc_weapon_rocketlauncher (void)
1127 {
1128         if (g_minstagib)
1129         {
1130                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1131                 self.think = minst_remove_item;
1132                 self.nextthink = time;
1133                 return;
1134         }
1135         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1136 }
1137
1138 void spawnfunc_item_rockets (void) {
1139         if(!self.ammo_rockets)
1140                 self.ammo_rockets = g_pickup_rockets;
1141         if(!self.pickup_anyway)
1142                 self.pickup_anyway = g_pickup_ammo_anyway;
1143         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1144 }
1145
1146 void spawnfunc_item_shells (void);
1147 void spawnfunc_item_bullets (void) {
1148         if(!weaponswapping)
1149         if(q3acompat_machineshotgunswap)
1150         if(self.classname != "droppedweapon")
1151         {
1152                 weaponswapping = TRUE;
1153                 spawnfunc_item_shells();
1154                 weaponswapping = FALSE;
1155                 return;
1156         }
1157
1158         if(!self.ammo_nails)
1159                 self.ammo_nails = g_pickup_nails;
1160         if(!self.pickup_anyway)
1161                 self.pickup_anyway = g_pickup_ammo_anyway;
1162         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1163 }
1164
1165 void spawnfunc_item_cells (void) {
1166         if(!self.ammo_cells)
1167                 self.ammo_cells = g_pickup_cells;
1168         if(!self.pickup_anyway)
1169                 self.pickup_anyway = g_pickup_ammo_anyway;
1170         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1171 }
1172
1173 void spawnfunc_item_shells (void) {
1174         if(!weaponswapping)
1175         if(q3acompat_machineshotgunswap)
1176         if(self.classname != "droppedweapon")
1177         {
1178                 weaponswapping = TRUE;
1179                 spawnfunc_item_bullets();
1180                 weaponswapping = FALSE;
1181                 return;
1182         }
1183
1184         if(!self.ammo_shells)
1185                 self.ammo_shells = g_pickup_shells;
1186         if(!self.pickup_anyway)
1187                 self.pickup_anyway = g_pickup_ammo_anyway;
1188         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1189 }
1190
1191 void spawnfunc_item_armor_small (void) {
1192         if(!self.armorvalue)
1193                 self.armorvalue = g_pickup_armorsmall;
1194         if(!self.max_armorvalue)
1195                 self.max_armorvalue = g_pickup_armorsmall_max;
1196         if(!self.pickup_anyway)
1197                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1198         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1199 }
1200
1201 void spawnfunc_item_armor_medium (void) {
1202         if(!self.armorvalue)
1203                 self.armorvalue = g_pickup_armormedium;
1204         if(!self.max_armorvalue)
1205                 self.max_armorvalue = g_pickup_armormedium_max;
1206         if(!self.pickup_anyway)
1207                 self.pickup_anyway = g_pickup_armormedium_anyway;
1208         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1209 }
1210
1211 void spawnfunc_item_armor_big (void) {
1212         if(!self.armorvalue)
1213                 self.armorvalue = g_pickup_armorbig;
1214         if(!self.max_armorvalue)
1215                 self.max_armorvalue = g_pickup_armorbig_max;
1216         if(!self.pickup_anyway)
1217                 self.pickup_anyway = g_pickup_armorbig_anyway;
1218         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1219 }
1220
1221 void spawnfunc_item_armor_large (void) {
1222         if(!self.armorvalue)
1223                 self.armorvalue = g_pickup_armorlarge;
1224         if(!self.max_armorvalue)
1225                 self.max_armorvalue = g_pickup_armorlarge_max;
1226         if(!self.pickup_anyway)
1227                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1228         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1229 }
1230
1231 void spawnfunc_item_health_small (void) {
1232         if(!self.max_health)
1233                 self.max_health = g_pickup_healthsmall_max;
1234         if(!self.health)
1235                 self.health = g_pickup_healthsmall;
1236         if(!self.pickup_anyway)
1237                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1238         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1239 }
1240
1241 void spawnfunc_item_health_medium (void) {
1242         if(!self.max_health)
1243                 self.max_health = g_pickup_healthmedium_max;
1244         if(!self.health)
1245                 self.health = g_pickup_healthmedium;
1246         if(!self.pickup_anyway)
1247                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1248         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1249 }
1250
1251 void spawnfunc_item_health_large (void) {
1252         if(!self.max_health)
1253                 self.max_health = g_pickup_healthlarge_max;
1254         if(!self.health)
1255                 self.health = g_pickup_healthlarge;
1256         if(!self.pickup_anyway)
1257                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1258         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1259 }
1260
1261 void spawnfunc_item_health_mega (void) {
1262         if(!cvar("g_powerup_superhealth"))
1263                 return;
1264
1265         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1266                 return;
1267
1268         if(g_minstagib) {
1269                 minstagib_items(IT_NAILS);
1270         } else {
1271                 if(!self.max_health)
1272                         self.max_health = g_pickup_healthmega_max;
1273                 if(!self.health)
1274                         self.health = g_pickup_healthmega;
1275                 if(!self.pickup_anyway)
1276                         self.pickup_anyway = g_pickup_healthmega_anyway;
1277                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1278         }
1279 }
1280
1281 // support old misnamed entities
1282 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1283 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1284 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1285 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1286 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1287
1288 void spawnfunc_item_strength (void) {
1289         if(!cvar("g_powerup_strength"))
1290                 return;
1291
1292         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1293                 return;
1294
1295         if(g_minstagib) {
1296                 minstagib_items(IT_STRENGTH);
1297         } else {
1298                 precache_sound("weapons/strength_fire.wav");
1299                 self.strength_finished = 30;
1300                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1301         }
1302 }
1303
1304 void spawnfunc_item_invincible (void) {
1305         if(!cvar("g_powerup_shield"))
1306                 return;
1307
1308         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1309                 return;
1310
1311         if(g_minstagib) {
1312                 minstagib_items(IT_INVINCIBLE);
1313         } else {
1314                 self.invincible_finished = 30;
1315                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1316         }
1317 }
1318
1319 void spawnfunc_item_minst_cells (void) {
1320         if (g_minstagib)
1321         {
1322                 minst_no_auto_cells = 1;
1323                 minstagib_items(IT_CELLS);
1324         }
1325         else
1326                 remove(self);
1327 }
1328
1329 // compatibility:
1330 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1331
1332 float GiveItems(entity e, float beginarg, float endarg);
1333 void target_items_use (void)
1334 {
1335         if(activator.classname == "droppedweapon")
1336         {
1337                 EXACTTRIGGER_TOUCH;
1338                 remove(activator);
1339                 return;
1340         }
1341
1342         if(activator.classname != "player")
1343                 return;
1344         if(activator.deadflag != DEAD_NO)
1345                 return;
1346         EXACTTRIGGER_TOUCH;
1347
1348         entity e;
1349         for(e = world; (e = find(e, classname, "droppedweapon")); )
1350                 if(e.enemy == activator)
1351                         remove(e);
1352
1353         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1354                 centerprint(activator, self.message);
1355 }
1356
1357 void spawnfunc_target_items (void)
1358 {
1359         float n, i, j;
1360         entity e;
1361
1362         self.use = target_items_use;
1363         if(!self.strength_finished)
1364                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1365         if(!self.invincible_finished)
1366                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1367
1368         precache_sound("misc/itempickup.wav");
1369         precache_sound("misc/megahealth.wav");
1370         precache_sound("misc/armor25.wav");
1371         precache_sound("misc/powerup.wav");
1372         precache_sound("misc/poweroff.wav");
1373         precache_sound("weapons/weaponpickup.wav");
1374
1375         n = tokenize_console(self.netname);
1376         if(argv(0) == "give")
1377         {
1378                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1379         }
1380         else
1381         {
1382                 for(i = 0; i < n; ++i)
1383                 {
1384                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1385                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1386                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1387                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1388                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1389                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1390                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1391                         else
1392                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1393                         {
1394                                 e = get_weaponinfo(j);
1395                                 if(argv(i) == e.netname)
1396                                 {
1397                                         self.weapons |= e.weapons;
1398                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1399                                                 weapon_action(e.weapon, WR_PRECACHE);
1400                                         break;
1401                                 }
1402                         }
1403                         if(j > WEP_LAST)
1404                                 print("target_items: invalid item ", argv(i), "\n");
1405                 }
1406
1407                 string itemprefix, valueprefix;
1408                 if(self.spawnflags == 0)
1409                 {
1410                         itemprefix = "";
1411                         valueprefix = "";
1412                 }
1413                 else if(self.spawnflags == 1)
1414                 {
1415                         itemprefix = "max ";
1416                         valueprefix = "max ";
1417                 }
1418                 else if(self.spawnflags == 2)
1419                 {
1420                         itemprefix = "min ";
1421                         valueprefix = "min ";
1422                 }
1423                 else if(self.spawnflags == 4)
1424                 {
1425                         itemprefix = "minus ";
1426                         valueprefix = "max ";
1427                 }
1428                 else
1429                         error("invalid spawnflags");
1430
1431                 self.netname = "";
1432                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1433                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1434                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1435                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1436                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1437                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1438                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1439                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1440                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1441                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1442                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1443                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1444                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1445                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1446                 {
1447                         e = get_weaponinfo(j);
1448                         if(e.weapons)
1449                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1450                 }
1451         }
1452         self.netname = strzone(self.netname);
1453         //print(self.netname, "\n");
1454
1455         n = tokenize_console(self.netname);
1456         for(i = 0; i < n; ++i)
1457         {
1458                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1459                 {
1460                         e = get_weaponinfo(j);
1461                         if(argv(i) == e.netname)
1462                         {
1463                                 weapon_action(e.weapon, WR_PRECACHE);
1464                                 break;
1465                         }
1466                 }
1467         }
1468 }
1469
1470 void spawnfunc_item_fuel(void)
1471 {
1472         if(!self.ammo_fuel)
1473                 self.ammo_fuel = g_pickup_fuel;
1474         if(!self.pickup_anyway)
1475                 self.pickup_anyway = g_pickup_ammo_anyway;
1476         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1477 }
1478
1479 void spawnfunc_item_fuel_regen(void)
1480 {
1481         if(start_items & IT_FUEL_REGEN)
1482         {
1483                 spawnfunc_item_fuel();
1484                 return;
1485         }
1486         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1487 }
1488
1489 void spawnfunc_item_jetpack(void)
1490 {
1491         if(g_grappling_hook)
1492                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1493         if(!self.ammo_fuel)
1494                 self.ammo_fuel = g_pickup_fuel_jetpack;
1495         if(start_items & IT_JETPACK)
1496         {
1497                 spawnfunc_item_fuel();
1498                 return;
1499         }
1500         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1501 }
1502
1503
1504 #define OP_SET 0
1505 #define OP_MIN 1
1506 #define OP_MAX 2
1507 #define OP_PLUS 3
1508 #define OP_MINUS 4
1509
1510 float GiveBit(entity e, .float fld, float bit, float op, float val)
1511 {
1512         float v0, v1;
1513         v0 = (e.fld & bit);
1514         switch(op)
1515         {
1516                 case OP_SET:
1517                         if(val > 0)
1518                                 e.fld |= bit;
1519                         else
1520                                 e.fld &~= bit;
1521                         break;
1522                 case OP_MIN:
1523                 case OP_PLUS:
1524                         if(val > 0)
1525                                 e.fld |= bit;
1526                         break;
1527                 case OP_MAX:
1528                         if(val <= 0)
1529                                 e.fld &~= bit;
1530                         break;
1531                 case OP_MINUS:
1532                         if(val > 0)
1533                                 e.fld &~= bit;
1534                         break;
1535         }
1536         v1 = (e.fld & bit);
1537         return (v0 != v1);
1538 }
1539
1540 float GiveValue(entity e, .float fld, float op, float val)
1541 {
1542         float v0, v1;
1543         v0 = e.fld;
1544         switch(op)
1545         {
1546                 case OP_SET:
1547                         e.fld = val;
1548                         break;
1549                 case OP_MIN:
1550                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1551                         break;
1552                 case OP_MAX:
1553                         e.fld = min(e.fld, val);
1554                         break;
1555                 case OP_PLUS:
1556                         e.fld += val;
1557                         break;
1558                 case OP_MINUS:
1559                         e.fld -= val;
1560                         break;
1561         }
1562         v1 = e.fld;
1563         return (v0 != v1);
1564 }
1565
1566 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1567 {
1568         if(v1 == v0)
1569                 return;
1570         if(v1 <= v0 - t)
1571         {
1572                 if(snd_decr != "")
1573                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1574         }
1575         else if(v0 >= v0 + t)
1576         {
1577                 if(snd_incr != "")
1578                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1579         }
1580 }
1581
1582 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1583 {
1584         if(v0 < v1)
1585                 e.rotfield = max(e.rotfield, time + rottime);
1586         else if(v0 > v1)
1587                 e.regenfield = max(e.regenfield, time + regentime);
1588 }
1589
1590 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1591 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1592 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1593 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1594
1595 float GiveItems(entity e, float beginarg, float endarg)
1596 {
1597         float got, i, j, val, op;
1598         float _switchweapon;
1599         entity wi;
1600         string cmd;
1601
1602         val = 999;
1603         op = OP_SET;
1604
1605         got = 0;
1606
1607         _switchweapon = FALSE;
1608         if (e.autoswitch)
1609                 if (e.switchweapon == w_getbestweapon(e))
1610                         _switchweapon = TRUE;
1611
1612         e.strength_finished = max(0, e.strength_finished - time);
1613         e.invincible_finished = max(0, e.invincible_finished - time);
1614
1615         PREGIVE(e, items);
1616         PREGIVE(e, weapons);
1617         PREGIVE(e, strength_finished);
1618         PREGIVE(e, invincible_finished);
1619         PREGIVE(e, ammo_nails);
1620         PREGIVE(e, ammo_cells);
1621         PREGIVE(e, ammo_shells);
1622         PREGIVE(e, ammo_rockets);
1623         PREGIVE(e, ammo_fuel);
1624         PREGIVE(e, armorvalue);
1625         PREGIVE(e, health);
1626
1627         for(i = beginarg; i < endarg; ++i)
1628         {
1629                 cmd = argv(i);
1630
1631                 if(cmd == "0" || stof(cmd))
1632                 {
1633                         val = stof(cmd);
1634                         continue;
1635                 }
1636                 switch(cmd)
1637                 {
1638                         case "no":
1639                                 op = OP_MAX;
1640                                 val = 0;
1641                                 continue;
1642                         case "max":
1643                                 op = OP_MAX;
1644                                 continue;
1645                         case "min":
1646                                 op = OP_MIN;
1647                                 continue;
1648                         case "plus":
1649                                 op = OP_PLUS;
1650                                 continue;
1651                         case "minus":
1652                                 op = OP_MINUS;
1653                                 continue;
1654                         case "ALL":
1655                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1656                                 got += GiveValue(e, strength_finished, op, time);
1657                                 got += GiveValue(e, invincible_finished, op, time);
1658                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1659                         case "all":
1660                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1661                                 got += GiveValue(e, health, op, val);
1662                                 got += GiveValue(e, armorvalue, op, val);
1663                         case "allweapons":
1664                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1665                                 {
1666                                         wi = get_weaponinfo(j);
1667                                         if(wi.weapons)
1668                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1669                                 }
1670                         case "allammo":
1671                                 got += GiveValue(e, ammo_cells, op, val);
1672                                 got += GiveValue(e, ammo_shells, op, val);
1673                                 got += GiveValue(e, ammo_nails, op, val);
1674                                 got += GiveValue(e, ammo_rockets, op, val);
1675                                 got += GiveValue(e, ammo_fuel, op, val);
1676                                 break;
1677                         case "unlimited_ammo":
1678                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1679                                 break;
1680                         case "unlimited_weapon_ammo":
1681                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1682                                 break;
1683                         case "unlimited_superweapons":
1684                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1685                                 break;
1686                         case "jetpack":
1687                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1688                                 break;
1689                         case "fuel_regen":
1690                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1691                                 break;
1692                         case "strength":
1693                                 got += GiveValue(e, strength_finished, op, val);
1694                                 break;
1695                         case "invincible":
1696                                 got += GiveValue(e, invincible_finished, op, val);
1697                                 break;
1698                         case "cells":
1699                                 got += GiveValue(e, ammo_cells, op, val);
1700                                 break;
1701                         case "shells":
1702                                 got += GiveValue(e, ammo_shells, op, val);
1703                                 break;
1704                         case "nails":
1705                         case "bullets":
1706                                 got += GiveValue(e, ammo_nails, op, val);
1707                                 break;
1708                         case "rockets":
1709                                 got += GiveValue(e, ammo_rockets, op, val);
1710                                 break;
1711                         case "health":
1712                                 got += GiveValue(e, health, op, val);
1713                                 break;
1714                         case "armor":
1715                                 got += GiveValue(e, armorvalue, op, val);
1716                                 break;
1717                         case "fuel":
1718                                 got += GiveValue(e, ammo_fuel, op, val);
1719                                 break;
1720                         default:
1721                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1722                                 {
1723                                         wi = get_weaponinfo(j);
1724                                         if(cmd == wi.netname)
1725                                         {
1726                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1727                                                 break;
1728                                         }
1729                                 }
1730                                 if(j > WEP_LAST)
1731                                         print("give: invalid item ", cmd, "\n");
1732                                 break;
1733                 }
1734                 val = 999;
1735                 op = OP_SET;
1736         }
1737
1738         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1739         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1740         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1741         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1742         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1743         {
1744                 wi = get_weaponinfo(j);
1745                 if(wi.weapons)
1746                 {
1747                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1748                         if not(save_weapons & wi.weapons)
1749                                 if(e.weapons & wi.weapons)
1750                                         weapon_action(wi.weapon, WR_PRECACHE);
1751                 }
1752         }
1753         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1754         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1755         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1756         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1757         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1758         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1759         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1760         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1761         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1762
1763         if (g_minstagib)
1764         {
1765                 e.health = bound(0, e.health, 100);
1766                 e.armorvalue = bound(0, e.armorvalue, 999);
1767         }
1768
1769         if(e.strength_finished <= 0)
1770                 e.strength_finished = 0;
1771         else
1772                 e.strength_finished += time;
1773         if(e.invincible_finished <= 0)
1774                 e.invincible_finished = 0;
1775         else
1776                 e.invincible_finished += time;
1777
1778         if not(e.weapons & W_WeaponBit(e.switchweapon))
1779                 _switchweapon = TRUE;
1780         if(_switchweapon)
1781                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1782
1783         return got;
1784 }