qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         // minstagib: only allow filtered items
 275         if(g_minstagib)
 276                 if(self.classname != "minstagib")
 277                         return FALSE;
 278
 279         if(self.flags & FL_POWERUP)
 280         {
 281                 if(autocvar_g_powerups > 0)
 282                         return TRUE;
 283                 if(autocvar_g_powerups == 0)
 284                         return FALSE;
 285                 if(g_lms)
 286                         return FALSE;
 287                 if(g_ca)
 288                         return FALSE;
 289                 if(g_arena)
 290                         return FALSE;
 291         }
 292         else
 293         {
 294                 if(autocvar_g_pickup_items > 0)
 295                         return TRUE;
 296                 if(autocvar_g_pickup_items == 0)
 297                         return FALSE;
 298                 if(g_lms)
 299                         return FALSE;
 300                 if(g_ca)
 301                         return FALSE;
 302                 if(g_weaponarena)
 303                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 304                                 return FALSE;
 305         }
 306         return TRUE;
 307 }
 308
 309 #define ITEM_RESPAWN_TICKS 10
 310
 311 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 312         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 313 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 314         // range: 10 .. respawntime + respawntimejitter
 315
 316 floatfield Item_CounterField(float it)
 317 {
 318         switch(it)
 319         {
 320                 case IT_SHELLS:      return ammo_shells;
 321                 case IT_NAILS:       return ammo_nails;
 322                 case IT_ROCKETS:     return ammo_rockets;
 323                 case IT_CELLS:       return ammo_cells;
 324                 case IT_FUEL:        return ammo_fuel;
 325                 case IT_5HP:         return health;
 326                 case IT_25HP:        return health;
 327                 case IT_HEALTH:      return health;
 328                 case IT_ARMOR_SHARD: return armorvalue;
 329                 case IT_ARMOR:       return armorvalue;
 330                 // add more things here (health, armor)
 331                 default:             error("requested item has no counter field");
 332         }
 333 #ifdef GMQCC
 334         // should never happen
 335         return health;
 336 #endif
 337 }
 338
 339 string Item_CounterFieldName(float it)
 340 {
 341         switch(it)
 342         {
 343                 case IT_SHELLS:      return "shells";
 344                 case IT_NAILS:       return "nails";
 345                 case IT_ROCKETS:     return "rockets";
 346                 case IT_CELLS:       return "cells";
 347                 case IT_FUEL:        return "fuel";
 348
 349                 // add more things here (health, armor)
 350                 default:             error("requested item has no counter field name");
 351         }
 352 #ifdef GMQCC
 353         // should never happen
 354         return string_null;
 355 #endif
 356 }
 357
 358 .float max_armorvalue;
 359 .float pickup_anyway;
 360 /*
 361 float Item_Customize()
 362 {
 363         if(self.spawnshieldtime)
 364                 return TRUE;
 365         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 366         {
 367                 self.colormod = '0 0 0';
 368                 self.glowmod = self.colormod;
 369                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 370                 return TRUE;
 371         }
 372         else
 373         {
 374                 if(g_ghost_items)
 375                 {
 376                         self.colormod = stov(autocvar_g_ghost_items_color);
 377                         self.glowmod = self.colormod;
 378                         self.alpha = g_ghost_items;
 379                         return TRUE;
 380                 }
 381                 else
 382                         return FALSE;
 383         }
 384 }
 385 */
 386
 387 void Item_Show (entity e, float mode)
 388 {
 389         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 390         e.ItemStatus &~= ITS_STAYWEP;
 391         if (mode > 0)
 392         {
 393                 // make the item look normal, and be touchable
 394                 e.model = e.mdl;
 395                 e.solid = SOLID_TRIGGER;
 396                 e.spawnshieldtime = 1;
 397                 e.ItemStatus |= ITS_AVAILABLE;
 398         }
 399         else if (mode < 0)
 400         {
 401                 // hide the item completely
 402                 e.model = string_null;
 403                 e.solid = SOLID_NOT;
 404                 e.spawnshieldtime = 1;
 405                 e.ItemStatus &~= ITS_AVAILABLE;
 406         }
 407         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 408         {
 409                 // make the item translucent and not touchable
 410                 e.model = e.mdl;
 411                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 412                 e.effects |= EF_STARDUST;
 413                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 414                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 415         }
 416         else
 417         {
 418                 //setmodel(e, "null");
 419                 e.solid = SOLID_NOT;
 420                 e.colormod = '0 0 0';
 421                 e.glowmod = e.colormod;
 422                 e.spawnshieldtime = 1;
 423                 e.ItemStatus &~= ITS_AVAILABLE;
 424         }
 425
 426         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 427             e.ItemStatus |= ITS_POWERUP;
 428
 429         if (autocvar_g_nodepthtestitems)
 430                 e.effects |= EF_NODEPTHTEST;
 431
 432
 433     if (autocvar_g_fullbrightitems)
 434                 e.ItemStatus |= ITS_ALLOWFB;
 435
 436         if (autocvar_sv_simple_items)
 437         e.ItemStatus |= ITS_ALLOWSI;
 438
 439         // relink entity (because solid may have changed)
 440         setorigin(e, e.origin);
 441     e.SendFlags |= ISF_STATUS;
 442 }
 443
 444 void Item_Respawn (void)
 445 {
 446         Item_Show(self, 1);
 447         if(!g_minstagib && self.items == IT_STRENGTH)
 448                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 449         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 450                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 451         else
 452                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 453         setorigin (self, self.origin);
 454
 455         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 456         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 457 }
 458
 459 void Item_RespawnCountdown (void)
 460 {
 461         if(self.count >= ITEM_RESPAWN_TICKS)
 462         {
 463                 if(self.waypointsprite_attached)
 464                         WaypointSprite_Kill(self.waypointsprite_attached);
 465                 Item_Respawn();
 466         }
 467         else
 468         {
 469                 self.nextthink = time + 1;
 470                 self.count += 1;
 471                 if(self.count == 1)
 472                 {
 473                         string name;
 474                         vector rgb = '1 0 1';
 475                         name = string_null;
 476                         if(g_minstagib)
 477                         {
 478                                 switch(self.items)
 479                                 {
 480                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 481                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 482                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 483                                 }
 484                         }
 485                         else
 486                         {
 487                                 switch(self.items)
 488                                 {
 489                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 490                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 491                                 }
 492                         }
 493                         switch(self.items)
 494                         {
 495                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 496                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 497                         }
 498                         if(self.flags & FL_WEAPON)
 499                         {
 500                                 entity wi = get_weaponinfo(self.weapon);
 501                                 if(wi)
 502                                 {
 503                                         name = wi.model2;
 504                                         rgb = '1 0 0';
 505                                 }
 506                         }
 507                         if(name)
 508                         {
 509                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 510                                 if(self.waypointsprite_attached)
 511                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 512                         }
 513                         else
 514                         {
 515                                 print("Unknown powerup-marked item is wanting to respawn\n");
 516                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 517                         }
 518                 }
 519                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 520                 if(self.waypointsprite_attached)
 521                 {
 522                         WaypointSprite_Ping(self.waypointsprite_attached);
 523                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 524                 }
 525         }
 526 }
 527
 528 void Item_ScheduleRespawnIn(entity e, float t)
 529 {
 530         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 531         {
 532                 e.think = Item_RespawnCountdown;
 533                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 534                 e.count = 0;
 535         }
 536         else
 537         {
 538                 e.think = Item_Respawn;
 539                 e.nextthink = time + t;
 540         }
 541 }
 542
 543 void Item_ScheduleRespawn(entity e)
 544 {
 545         if(e.respawntime > 0)
 546         {
 547                 Item_Show(e, 0);
 548                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 549         }
 550         else // if respawntime is -1, this item does not respawn
 551                 Item_Show(e, -1);
 552 }
 553
 554 void Item_ScheduleInitialRespawn(entity e)
 555 {
 556         Item_Show(e, 0);
 557         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 558 }
 559
 560 float ITEM_MODE_NONE = 0;
 561 float ITEM_MODE_HEALTH = 1;
 562 float ITEM_MODE_ARMOR = 2;
 563 float ITEM_MODE_FUEL = 3;
 564 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 565 {
 566         if (!item.ammofield)
 567                 return FALSE;
 568
 569         if (item.spawnshieldtime)
 570         {
 571                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 572                 {
 573                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 574                         goto YEAH;
 575                 }
 576         }
 577         else if(g_weapon_stay == 2)
 578         {
 579                 float mi = min(item.ammofield, ammomax);
 580                 if (player.ammofield < mi)
 581                 {
 582                         player.ammofield = mi;
 583                         goto YEAH;
 584                 }
 585         }
 586
 587         return FALSE;
 588
 589 :YEAH
 590         switch(mode)
 591         {
 592                 case ITEM_MODE_FUEL:
 593                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 594                         break;
 595                 case ITEM_MODE_HEALTH:
 596                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 597                         break;
 598                 case ITEM_MODE_ARMOR:
 599                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 600                         break;
 601                 default:
 602                         break;
 603         }
 604         return TRUE;
 605 }
 606
 607 float Item_GiveTo(entity item, entity player)
 608 {
 609         float _switchweapon;
 610         float pickedup;
 611         float it;
 612         float i;
 613
 614         // if nothing happens to player, just return without taking the item
 615         pickedup = FALSE;
 616         _switchweapon = FALSE;
 617
 618         if (g_minstagib)
 619         {
 620                 float prevcells = player.ammo_cells;
 621
 622                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 623                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 624
 625                 if(player.ammo_cells > prevcells)
 626                 {
 627                         _switchweapon = TRUE;
 628
 629                         // play some cool sounds ;)
 630                         if (clienttype(player) == CLIENTTYPE_REAL)
 631                         {
 632                                 if(player.health <= 5)
 633                                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
 634                                 else if(player.health < 50)
 635                                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
 636                         }
 637                         // sound not available
 638                         // else if(item.items == IT_CELLS)
 639                         //      AnnounceTo(player, "ammo");
 640
 641                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 642                                 W_GiveWeapon (player, WEP_MINSTANEX);
 643                         player.health = 100;
 644                 }
 645
 646                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 647                 {
 648                         pickedup = TRUE;
 649                         player.items |= it;
 650                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 651                 }
 652
 653                 // extralife powerup
 654                 if (item.max_health)
 655                 {
 656                         pickedup = TRUE;
 657                         // sound not available
 658                         // AnnounceTo(player, "_lives");
 659                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 660                         sprint(player, "^3You picked up some extra lives\n");
 661                 }
 662
 663                 // invis powerup
 664                 if (item.strength_finished)
 665                 {
 666                         pickedup = TRUE;
 667                         // sound not available
 668                         // AnnounceTo(player, "invisible");
 669                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 670                 }
 671
 672                 // speed powerup
 673                 if (item.invincible_finished)
 674                 {
 675                         pickedup = TRUE;
 676                         // sound not available
 677                         // AnnounceTo(player, "speed");
 678                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 679                 }
 680         }
 681         else
 682         {
 683                 // in case the player has autoswitch enabled do the following:
 684                 // if the player is using their best weapon before items are given, they
 685                 // probably want to switch to an even better weapon after items are given
 686                 if (player.autoswitch)
 687                 if (player.switchweapon == w_getbestweapon(player))
 688                         _switchweapon = TRUE;
 689
 690                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 691                         _switchweapon = TRUE;
 692
 693                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 694                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 695                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 696                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 697                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 698                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 699                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 700
 701                 if (item.flags & FL_WEAPON)
 702                 {
 703                         WEPSET_DECLARE_A(it);
 704                         WEPSET_COPY_AE(it, item);
 705                         WEPSET_ANDNOT_AE(it, player);
 706
 707                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 708                         {
 709                                 pickedup = TRUE;
 710                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 711                                         if(WEPSET_CONTAINS_AW(it, i))
 712                                                 W_GiveWeapon(player, i);
 713                         }
 714                 }
 715
 716                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 717                 {
 718                         pickedup = TRUE;
 719                         player.items |= it;
 720                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 721                 }
 722
 723                 if (item.strength_finished)
 724                 {
 725                         pickedup = TRUE;
 726                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 727                 }
 728                 if (item.invincible_finished)
 729                 {
 730                         pickedup = TRUE;
 731                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 732                 }
 733                 if (item.superweapons_finished)
 734                 {
 735                         pickedup = TRUE;
 736                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 737                 }
 738         }
 739
 740 :skip
 741         // always eat teamed entities
 742         if(item.team)
 743                 pickedup = TRUE;
 744
 745         if (!pickedup)
 746                 return 0;
 747
 748         if (_switchweapon)
 749                 if (player.switchweapon != w_getbestweapon(player))
 750                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 751
 752         return 1;
 753 }
 754
 755 void Item_Touch (void)
 756 {
 757         entity e, head;
 758
 759         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 760         if(self.classname == "droppedweapon")
 761         {
 762                 if (ITEM_TOUCH_NEEDKILL())
 763                 {
 764                         remove(self);
 765                         return;
 766                 }
 767         }
 768
 769         if (other.classname != "player")
 770                 return;
 771         if (other.deadflag)
 772                 return;
 773         if (self.solid != SOLID_TRIGGER)
 774                 return;
 775         if (self.owner == other)
 776                 return;
 777         if(MUTATOR_CALLHOOK(ItemTouch))
 778                 return;
 779
 780         if (self.classname == "droppedweapon")
 781         {
 782                 self.strength_finished = max(0, self.strength_finished - time);
 783                 self.invincible_finished = max(0, self.invincible_finished - time);
 784                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 785         }
 786
 787         if(!Item_GiveTo(self, other))
 788         {
 789                 if (self.classname == "droppedweapon")
 790                 {
 791                         // undo what we did above
 792                         self.strength_finished += time;
 793                         self.invincible_finished += time;
 794                         self.superweapons_finished += time;
 795                 }
 796                 return;
 797         }
 798
 799         other.last_pickup = time;
 800
 801         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 802         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 803
 804         if (self.classname == "droppedweapon")
 805                 remove (self);
 806         else if not(self.spawnshieldtime)
 807                 return;
 808         else
 809         {
 810                 if(self.team)
 811                 {
 812                         RandomSelection_Init();
 813                         for(head = world; (head = findfloat(head, team, self.team)); )
 814                         {
 815                                 if(head.flags & FL_ITEM)
 816                                 {
 817                                         Item_Show(head, -1);
 818                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 819                                 }
 820                         }
 821                         e = RandomSelection_chosen_ent;
 822
 823                 }
 824                 else
 825                         e = self;
 826                 Item_ScheduleRespawn(e);
 827         }
 828 }
 829
 830 void Item_Reset()
 831 {
 832         Item_Show(self, !self.state);
 833         setorigin (self, self.origin);
 834
 835         if(self.classname != "droppedweapon")
 836         {
 837                 self.think = func_null;
 838                 self.nextthink = 0;
 839
 840                 if(self.waypointsprite_attached)
 841                         WaypointSprite_Kill(self.waypointsprite_attached);
 842
 843                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 844                         Item_ScheduleInitialRespawn(self);
 845         }
 846 }
 847
 848 void Item_FindTeam()
 849 {
 850         entity head, e;
 851
 852         if(self.effects & EF_NODRAW)
 853         {
 854                 // marker for item team search
 855                 dprint("Initializing item team ", ftos(self.team), "\n");
 856                 RandomSelection_Init();
 857                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 858                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 859                 e = RandomSelection_chosen_ent;
 860                 e.state = 0;
 861                 Item_Show(e, 1);
 862
 863                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 864                 {
 865                         if(head != e)
 866                         {
 867                                 // make it a non-spawned item
 868                                 Item_Show(head, -1);
 869                                 head.state = 1; // state 1 = initially hidden item
 870                         }
 871                         head.effects &~= EF_NODRAW;
 872                 }
 873
 874                 Item_Reset();
 875         }
 876 }
 877
 878 // Savage: used for item garbage-collection
 879 // TODO: perhaps nice special effect?
 880 void RemoveItem(void)
 881 {
 882         remove(self);
 883 }
 884
 885 // pickup evaluation functions
 886 // these functions decide how desirable an item is to the bots
 887
 888 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 889
 890 float weapon_pickupevalfunc(entity player, entity item)
 891 {
 892         float c, j, position;
 893
 894         // See if I have it already
 895         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 896         {
 897                 // If I can pick it up
 898                 if(!item.spawnshieldtime)
 899                         c = 0;
 900                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 901                 {
 902                         // Skilled bots will grab more
 903                         c = bound(0, skill / 10, 1) * 0.5;
 904                 }
 905                 else
 906                         c = 0;
 907         }
 908         else
 909                 c = 1;
 910
 911         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 912         if( bot_custom_weapon && c )
 913         {
 914                 // Find the highest position on any range
 915                 position = -1;
 916                 for(j = 0; j < WEP_LAST ; ++j){
 917                         if(
 918                                         bot_weapons_far[j] == item.weapon ||
 919                                         bot_weapons_mid[j] == item.weapon ||
 920                                         bot_weapons_close[j] == item.weapon
 921                           )
 922                         {
 923                                 position = j;
 924                                 break;
 925                         }
 926                 }
 927
 928                 // Rate it
 929                 if (position >= 0 )
 930                 {
 931                         position = WEP_LAST - position;
 932                         // item.bot_pickupbasevalue is overwritten here
 933                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 934                 }
 935         }
 936
 937         return item.bot_pickupbasevalue * c;
 938 }
 939
 940 float commodity_pickupevalfunc(entity player, entity item)
 941 {
 942         float c, i;
 943         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 944         entity wi;
 945         c = 0;
 946
 947         // Detect needed ammo
 948         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 949         {
 950                 wi = get_weaponinfo(i);
 951
 952                 if not(WEPSET_CONTAINS_EW(player, i))
 953                         continue;
 954
 955                 if(wi.items & IT_SHELLS)
 956                         need_shells = TRUE;
 957                 else if(wi.items & IT_NAILS)
 958                         need_nails = TRUE;
 959                 else if(wi.items & IT_ROCKETS)
 960                         need_rockets = TRUE;
 961                 else if(wi.items & IT_CELLS)
 962                         need_cells = TRUE;
 963                 else if(wi.items & IT_FUEL)
 964                         need_cells = TRUE;
 965         }
 966
 967         // TODO: figure out if the player even has the weapon this ammo is for?
 968         // may not affect strategy much though...
 969         // find out how much more ammo/armor/health the player can hold
 970         if (need_shells)
 971         if (item.ammo_shells)
 972         if (player.ammo_shells < g_pickup_shells_max)
 973                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 974         if (need_nails)
 975         if (item.ammo_nails)
 976         if (player.ammo_nails < g_pickup_nails_max)
 977                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 978         if (need_rockets)
 979         if (item.ammo_rockets)
 980         if (player.ammo_rockets < g_pickup_rockets_max)
 981                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 982         if (need_cells)
 983         if (item.ammo_cells)
 984         if (player.ammo_cells < g_pickup_cells_max)
 985                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 986         if (need_fuel)
 987         if (item.ammo_fuel)
 988         if (player.ammo_fuel < g_pickup_fuel_max)
 989                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 990         if (item.armorvalue)
 991         if (player.armorvalue < item.max_armorvalue)
 992                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 993         if (item.health)
 994         if (player.health < item.max_health)
 995                 c = c + max(0, 1 - player.health / item.max_health);
 996
 997         return item.bot_pickupbasevalue * c;
 998 }
 999
1000 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
1001 {
1002         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1003                 RemoveItem();
1004 }
1005
1006 .float is_item;
1007 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1008 {
1009         startitem_failed = FALSE;
1010
1011         if(self.model == "")
1012                 self.model = itemmodel;
1013
1014         if(self.model == "")
1015     {
1016         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1017         return;
1018     }
1019
1020         if(self.item_pickupsound == "")
1021                 self.item_pickupsound = pickupsound;
1022
1023         if(!self.respawntime) // both need to be set
1024         {
1025                 self.respawntime = defaultrespawntime;
1026                 self.respawntimejitter = defaultrespawntimejitter;
1027         }
1028
1029         self.items = itemid;
1030         self.weapon = weaponid;
1031
1032         if(weaponid)
1033                 WEPSET_COPY_EW(self, weaponid);
1034
1035         self.flags = FL_ITEM | itemflags;
1036
1037         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1038         {
1039                 startitem_failed = TRUE;
1040                 remove(self);
1041                 return;
1042         }
1043
1044         // is it a dropped weapon?
1045         if (self.classname == "droppedweapon")
1046         {
1047                 self.reset = SUB_Remove;
1048                 // it's a dropped weapon
1049                 self.movetype = MOVETYPE_TOSS;
1050
1051                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1052                 self.think = RemoveItem;
1053                 self.nextthink = time + 20;
1054
1055                 self.takedamage = DAMAGE_YES;
1056                 self.event_damage = Item_Damage;
1057
1058                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1059                 /*
1060                 if(self.items == 0)
1061                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
1062                 if(self.ammo_nails == 0)
1063                 if(self.ammo_cells == 0)
1064                 if(self.ammo_rockets == 0)
1065                 if(self.ammo_shells == 0)
1066                 if(self.ammo_fuel == 0)
1067                 if(self.health == 0)
1068                 if(self.armorvalue == 0)
1069                 */
1070                 {
1071                         // if item is worthless after a timer, have it expire then
1072                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1073                 }
1074
1075                 // don't drop if in a NODROP zone (such as lava)
1076                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1077                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1078                 {
1079                         startitem_failed = TRUE;
1080                         remove(self);
1081                         return;
1082                 }
1083         }
1084         else
1085         {
1086                 if(!have_pickup_item())
1087                 {
1088                         startitem_failed = TRUE;
1089                         remove (self);
1090                         return;
1091                 }
1092
1093                 if(self.angles != '0 0 0')
1094             self.SendFlags |= ISF_ANGLES;
1095
1096                 self.reset = Item_Reset;
1097                 // it's a level item
1098                 if(self.spawnflags & 1)
1099                         self.noalign = 1;
1100                 if (self.noalign)
1101                         self.movetype = MOVETYPE_NONE;
1102                 else
1103                         self.movetype = MOVETYPE_TOSS;
1104                 // do item filtering according to game mode and other things
1105                 if (!self.noalign)
1106                 {
1107                         // first nudge it off the floor a little bit to avoid math errors
1108                         setorigin(self, self.origin + '0 0 1');
1109                         // set item size before we spawn a spawnfunc_waypoint
1110                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1111                                 setsize (self, '-16 -16 0', '16 16 48');
1112                         else
1113                                 setsize (self, '-16 -16 0', '16 16 32');
1114                         // note droptofloor returns FALSE if stuck/or would fall too far
1115                         droptofloor();
1116                         waypoint_spawnforitem(self);
1117                 }
1118
1119                 /*
1120                  * can't do it that way, as it would break maps
1121                  * TODO make a target_give like entity another way, that perhaps has
1122                  * the weapon name in a key
1123                 if(self.targetname)
1124                 {
1125                         // target_give not yet supported; maybe later
1126                         print("removed targeted ", self.classname, "\n");
1127                         startitem_failed = TRUE;
1128                         remove (self);
1129                         return;
1130                 }
1131                 */
1132
1133                 if(autocvar_spawn_debug >= 2)
1134                 {
1135                         entity otheritem;
1136                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1137                         {
1138                             // why not flags & fl_item?
1139                                 if(otheritem.is_item)
1140                                 {
1141                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1142                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1143                                         error("Mapper sucks.");
1144                                 }
1145                         }
1146                         self.is_item = TRUE;
1147                 }
1148
1149                 WEPSET_OR_AW(weaponsInMap, weaponid);
1150
1151                 precache_model (self.model);
1152                 precache_sound (self.item_pickupsound);
1153
1154                 precache_sound ("misc/itemrespawncountdown.wav");
1155                 if(!g_minstagib && itemid == IT_STRENGTH)
1156                         precache_sound ("misc/strength_respawn.wav");
1157                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
1158                         precache_sound ("misc/shield_respawn.wav");
1159                 else
1160                         precache_sound ("misc/itemrespawn.wav");
1161
1162                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1163                         self.target = "###item###"; // for finding the nearest item using find()
1164         }
1165
1166         self.bot_pickup = TRUE;
1167         self.bot_pickupevalfunc = pickupevalfunc;
1168         self.bot_pickupbasevalue = pickupbasevalue;
1169         self.mdl = self.model;
1170         self.netname = itemname;
1171         self.touch = Item_Touch;
1172         setmodel(self, "null"); // precision set below
1173         //self.effects |= EF_LOWPRECISION;
1174
1175         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1176     {
1177         self.pos1 = '-16 -16 0';
1178         self.pos2 = '16 16 48';
1179     }
1180         else
1181     {
1182         self.pos1 = '-16 -16 0';
1183         self.pos2 = '16 16 32';
1184     }
1185     setsize (self, self.pos1, self.pos2);
1186
1187     if(itemflags & FL_POWERUP)
1188         self.ItemStatus |= ITS_ANIMATE1;
1189
1190         if(self.armorvalue || self.health)
1191         self.ItemStatus |= ITS_ANIMATE2;
1192
1193         if(itemflags & FL_WEAPON)
1194         {
1195                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1196             self.colormap = 1024; // color shirt=0 pants=0 grey
1197         else
1198             self.gravity = 1;
1199
1200                 self.ItemStatus |= ITS_ANIMATE1;
1201                 self.ItemStatus |= ISF_COLORMAP;
1202         }
1203
1204         self.state = 0;
1205         if(self.team) // broken, no idea why.
1206         {
1207                 if(!self.cnt)
1208                         self.cnt = 1; // item probability weight
1209
1210                 self.effects |= EF_NODRAW; // marker for item team search
1211                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1212         }
1213         else
1214                 Item_Reset();
1215
1216     Net_LinkEntity(self, FALSE, 0, ItemSend);
1217
1218         // call this hook after everything else has been done
1219         if(MUTATOR_CALLHOOK(Item_Spawn))
1220         {
1221                 startitem_failed = TRUE;
1222                 remove(self);
1223                 return;
1224         }
1225 }
1226
1227 /* replace items in minstagib
1228  * IT_STRENGTH   = invisibility
1229  * IT_NAILS      = extra lives
1230  * IT_INVINCIBLE = speed
1231  */
1232 void minstagib_items (float itemid) // will be deleted soon.
1233 {
1234         float rnd;
1235         self.classname = "minstagib"; // ...?
1236
1237         // replace rocket launchers and nex guns with ammo cells
1238         if (itemid == IT_CELLS)
1239         {
1240                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1241                 StartItem ("models/items/a_cells.md3",
1242                         "misc/itempickup.wav", 45, 0,
1243                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
1244                 return;
1245         }
1246
1247         // randomize
1248         rnd = random() * 3;
1249         if (rnd <= 1)
1250                 itemid = IT_STRENGTH;
1251         else if (rnd <= 2)
1252                 itemid = IT_NAILS;
1253         else
1254                 itemid = IT_INVINCIBLE;
1255
1256         // replace with invis
1257         if (itemid == IT_STRENGTH)
1258         {
1259                 if(!self.strength_finished)
1260                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1261                 StartItem ("models/items/g_strength.md3",
1262                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1263                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1264         }
1265         // replace with extra lives
1266         if (itemid == IT_NAILS)
1267         {
1268                 self.max_health = 1;
1269                 StartItem ("models/items/g_h100.md3",
1270                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1271                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1272         }
1273         // replace with speed
1274         if (itemid == IT_INVINCIBLE)
1275         {
1276                 if(!self.invincible_finished)
1277                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1278                 StartItem ("models/items/g_invincible.md3",
1279                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1280                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1281         }
1282 }
1283
1284 float minst_no_auto_cells;
1285 void minst_remove_item (void) {
1286         if(minst_no_auto_cells)
1287                 remove(self);
1288 }
1289
1290 float weaponswapping;
1291 float internalteam;
1292
1293 void weapon_defaultspawnfunc(float wpn)
1294 {
1295         entity e;
1296         float t;
1297         var .float ammofield;
1298         string s;
1299         entity oldself;
1300         float i, j;
1301         float f;
1302
1303         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1304         {
1305                 e = get_weaponinfo(wpn);
1306
1307                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1308                 {
1309                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1310                         /*
1311                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1312                         startitem_failed = TRUE;
1313                         return;
1314                         */
1315                 }
1316
1317                 s = W_Apply_Weaponreplace(e.netname);
1318                 ret_string = s;
1319                 other = e;
1320                 MUTATOR_CALLHOOK(SetWeaponreplace);
1321                 s = ret_string;
1322                 if(s == "")
1323                 {
1324                         remove(self);
1325                         startitem_failed = TRUE;
1326                         return;
1327                 }
1328                 t = tokenize_console(s);
1329                 if(t >= 2)
1330                 {
1331                         self.team = --internalteam;
1332                         oldself = self;
1333                         for(i = 1; i < t; ++i)
1334                         {
1335                                 s = argv(i);
1336                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1337                                 {
1338                                         e = get_weaponinfo(j);
1339                                         if(e.netname == s)
1340                                         {
1341                                                 self = spawn();
1342                                                 copyentity(oldself, self);
1343                                                 self.classname = "replacedweapon";
1344                                                 weapon_defaultspawnfunc(j);
1345                                                 break;
1346                                         }
1347                                 }
1348                                 if(j > WEP_LAST)
1349                                 {
1350                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1351                                 }
1352                         }
1353                         self = oldself;
1354                 }
1355                 if(t >= 1) // always the case!
1356                 {
1357                         s = argv(0);
1358                         wpn = 0;
1359                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1360                         {
1361                                 e = get_weaponinfo(j);
1362                                 if(e.netname == s)
1363                                 {
1364                                         wpn = j;
1365                                         break;
1366                                 }
1367                         }
1368                         if(j > WEP_LAST)
1369                         {
1370                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1371                         }
1372                 }
1373                 if(wpn == 0)
1374                 {
1375                         remove(self);
1376                         startitem_failed = TRUE;
1377                         return;
1378                 }
1379         }
1380
1381         e = get_weaponinfo(wpn);
1382
1383         if(!self.respawntime)
1384         {
1385                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1386                 {
1387                         self.respawntime = g_pickup_respawntime_superweapon;
1388                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1389                 }
1390                 else
1391                 {
1392                         self.respawntime = g_pickup_respawntime_weapon;
1393                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1394                 }
1395         }
1396
1397         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1398                 if(!self.superweapons_finished)
1399                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1400
1401         if(e.items)
1402         {
1403                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1404                 {
1405                         if(e.items & j)
1406                         {
1407                                 ammofield = Item_CounterField(j);
1408                                 if(!self.ammofield)
1409                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1410                         }
1411                 }
1412         }
1413
1414         // pickup anyway
1415         if(g_pickup_weapons_anyway)
1416                 self.pickup_anyway = TRUE;
1417
1418         f = FL_WEAPON;
1419
1420         // no weapon-stay on superweapons
1421         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1422                 f |= FL_NO_WEAPON_STAY;
1423
1424         // weapon stay isn't supported for teamed weapons
1425         if(self.team)
1426                 f |= FL_NO_WEAPON_STAY;
1427
1428         // stupid minstagib hack, don't ask
1429         if(g_minstagib)
1430                 if(self.ammo_cells)
1431                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1432
1433         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1434         if (self.modelindex) // don't precache if self was removed
1435                 weapon_action(e.weapon, WR_PRECACHE);
1436 }
1437
1438 void spawnfunc_weapon_shotgun (void);
1439 void spawnfunc_weapon_uzi (void) {
1440         if(autocvar_sv_q3acompat_machineshotgunswap)
1441         if(self.classname != "droppedweapon")
1442         {
1443                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1444                 return;
1445         }
1446         weapon_defaultspawnfunc(WEP_UZI);
1447 }
1448
1449 void spawnfunc_weapon_shotgun (void) {
1450         if(autocvar_sv_q3acompat_machineshotgunswap)
1451         if(self.classname != "droppedweapon")
1452         {
1453                 weapon_defaultspawnfunc(WEP_UZI);
1454                 return;
1455         }
1456         weapon_defaultspawnfunc(WEP_SHOTGUN);
1457 }
1458
1459 void spawnfunc_weapon_nex (void)
1460 {
1461         if (g_minstagib)
1462         {
1463                 minstagib_items(IT_CELLS);
1464                 self.think = minst_remove_item;
1465                 self.nextthink = time;
1466                 return;
1467         }
1468         weapon_defaultspawnfunc(WEP_NEX);
1469 }
1470
1471 void spawnfunc_weapon_minstanex (void)
1472 {
1473         if (g_minstagib)
1474         {
1475                 minstagib_items(IT_CELLS);
1476                 self.think = minst_remove_item;
1477                 self.nextthink = time;
1478                 return;
1479         }
1480         weapon_defaultspawnfunc(WEP_MINSTANEX);
1481 }
1482
1483 void spawnfunc_weapon_rocketlauncher (void)
1484 {
1485         if (g_minstagib)
1486         {
1487                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1488                 self.think = minst_remove_item;
1489                 self.nextthink = time;
1490                 return;
1491         }
1492         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1493 }
1494
1495 void spawnfunc_item_rockets (void) {
1496         if(!self.ammo_rockets)
1497                 self.ammo_rockets = g_pickup_rockets;
1498         if(!self.pickup_anyway)
1499                 self.pickup_anyway = g_pickup_ammo_anyway;
1500         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1501 }
1502
1503 void spawnfunc_item_shells (void);
1504 void spawnfunc_item_bullets (void) {
1505         if(!weaponswapping)
1506         if(autocvar_sv_q3acompat_machineshotgunswap)
1507         if(self.classname != "droppedweapon")
1508         {
1509                 weaponswapping = TRUE;
1510                 spawnfunc_item_shells();
1511                 weaponswapping = FALSE;
1512                 return;
1513         }
1514
1515         if(!self.ammo_nails)
1516                 self.ammo_nails = g_pickup_nails;
1517         if(!self.pickup_anyway)
1518                 self.pickup_anyway = g_pickup_ammo_anyway;
1519         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1520 }
1521
1522 void spawnfunc_item_cells (void) {
1523         if(!self.ammo_cells)
1524                 self.ammo_cells = g_pickup_cells;
1525         if(!self.pickup_anyway)
1526                 self.pickup_anyway = g_pickup_ammo_anyway;
1527         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1528 }
1529
1530 void spawnfunc_item_shells (void) {
1531         if(!weaponswapping)
1532         if(autocvar_sv_q3acompat_machineshotgunswap)
1533         if(self.classname != "droppedweapon")
1534         {
1535                 weaponswapping = TRUE;
1536                 spawnfunc_item_bullets();
1537                 weaponswapping = FALSE;
1538                 return;
1539         }
1540
1541         if(!self.ammo_shells)
1542                 self.ammo_shells = g_pickup_shells;
1543         if(!self.pickup_anyway)
1544                 self.pickup_anyway = g_pickup_ammo_anyway;
1545         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1546 }
1547
1548 void spawnfunc_item_armor_small (void) {
1549         if(!self.armorvalue)
1550                 self.armorvalue = g_pickup_armorsmall;
1551         if(!self.max_armorvalue)
1552                 self.max_armorvalue = g_pickup_armorsmall_max;
1553         if(!self.pickup_anyway)
1554                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1555         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1556 }
1557
1558 void spawnfunc_item_armor_medium (void) {
1559         if(!self.armorvalue)
1560                 self.armorvalue = g_pickup_armormedium;
1561         if(!self.max_armorvalue)
1562                 self.max_armorvalue = g_pickup_armormedium_max;
1563         if(!self.pickup_anyway)
1564                 self.pickup_anyway = g_pickup_armormedium_anyway;
1565         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1566 }
1567
1568 void spawnfunc_item_armor_big (void) {
1569         if(!self.armorvalue)
1570                 self.armorvalue = g_pickup_armorbig;
1571         if(!self.max_armorvalue)
1572                 self.max_armorvalue = g_pickup_armorbig_max;
1573         if(!self.pickup_anyway)
1574                 self.pickup_anyway = g_pickup_armorbig_anyway;
1575         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1576 }
1577
1578 void spawnfunc_item_armor_large (void) {
1579         if(!self.armorvalue)
1580                 self.armorvalue = g_pickup_armorlarge;
1581         if(!self.max_armorvalue)
1582                 self.max_armorvalue = g_pickup_armorlarge_max;
1583         if(!self.pickup_anyway)
1584                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1585         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1586 }
1587
1588 void spawnfunc_item_health_small (void) {
1589         if(!self.max_health)
1590                 self.max_health = g_pickup_healthsmall_max;
1591         if(!self.health)
1592                 self.health = g_pickup_healthsmall;
1593         if(!self.pickup_anyway)
1594                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1595         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1596 }
1597
1598 void spawnfunc_item_health_medium (void) {
1599         if(!self.max_health)
1600                 self.max_health = g_pickup_healthmedium_max;
1601         if(!self.health)
1602                 self.health = g_pickup_healthmedium;
1603         if(!self.pickup_anyway)
1604                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1605         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1606 }
1607
1608 void spawnfunc_item_health_large (void) {
1609         if(!self.max_health)
1610                 self.max_health = g_pickup_healthlarge_max;
1611         if(!self.health)
1612                 self.health = g_pickup_healthlarge;
1613         if(!self.pickup_anyway)
1614                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1615         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1616 }
1617
1618 void spawnfunc_item_health_mega (void) {
1619         if(g_minstagib) {
1620                 minstagib_items(IT_NAILS);
1621         } else {
1622                 if(!self.max_health)
1623                         self.max_health = g_pickup_healthmega_max;
1624                 if(!self.health)
1625                         self.health = g_pickup_healthmega;
1626                 if(!self.pickup_anyway)
1627                         self.pickup_anyway = g_pickup_healthmega_anyway;
1628                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1629         }
1630 }
1631
1632 // support old misnamed entities
1633 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1634 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1635 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1636 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1637 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1638
1639 void spawnfunc_item_strength (void) {
1640         if(g_minstagib) {
1641                 minstagib_items(IT_STRENGTH);
1642         } else {
1643                 precache_sound("weapons/strength_fire.wav");
1644                 if(!self.strength_finished)
1645                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1646                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1647         }
1648 }
1649
1650 void spawnfunc_item_invincible (void) {
1651         if(g_minstagib) {
1652                 minstagib_items(IT_INVINCIBLE);
1653         } else {
1654                 if(!self.invincible_finished)
1655                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1656                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1657         }
1658 }
1659
1660 void spawnfunc_item_minst_cells (void) {
1661         if (g_minstagib)
1662         {
1663                 minst_no_auto_cells = TRUE;
1664                 minstagib_items(IT_CELLS);
1665         }
1666         else
1667                 remove(self);
1668 }
1669
1670 // compatibility:
1671 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1672
1673 float GiveItems(entity e, float beginarg, float endarg);
1674 void target_items_use (void)
1675 {
1676         if(activator.classname == "droppedweapon")
1677         {
1678                 EXACTTRIGGER_TOUCH;
1679                 remove(activator);
1680                 return;
1681         }
1682
1683         if(activator.classname != "player")
1684                 return;
1685         if(activator.deadflag != DEAD_NO)
1686                 return;
1687         EXACTTRIGGER_TOUCH;
1688
1689         entity e;
1690         for(e = world; (e = find(e, classname, "droppedweapon")); )
1691                 if(e.enemy == activator)
1692                         remove(e);
1693
1694         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1695                 centerprint(activator, self.message);
1696 }
1697
1698 void spawnfunc_target_items (void)
1699 {
1700         float n, i, j;
1701         entity e;
1702
1703         self.use = target_items_use;
1704         if(!self.strength_finished)
1705                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1706         if(!self.invincible_finished)
1707                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1708         if(!self.superweapons_finished)
1709                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1710
1711         precache_sound("misc/itempickup.wav");
1712         precache_sound("misc/megahealth.wav");
1713         precache_sound("misc/armor25.wav");
1714         precache_sound("misc/powerup.wav");
1715         precache_sound("misc/poweroff.wav");
1716         precache_sound("weapons/weaponpickup.wav");
1717
1718         n = tokenize_console(self.netname);
1719         if(argv(0) == "give")
1720         {
1721                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1722         }
1723         else
1724         {
1725                 for(i = 0; i < n; ++i)
1726                 {
1727                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1728                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1729                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1730                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1731                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1732                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1733                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1734                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1735                         else
1736                         {
1737                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1738                                 {
1739                                         e = get_weaponinfo(j);
1740                                         if(argv(i) == e.netname)
1741                                         {
1742                                                 WEPSET_OR_EW(self, j);
1743                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1744                                                         weapon_action(e.weapon, WR_PRECACHE);
1745                                                 break;
1746                                         }
1747                                 }
1748                                 if(j > WEP_LAST)
1749                                         print("target_items: invalid item ", argv(i), "\n");
1750                         }
1751                 }
1752
1753                 string itemprefix, valueprefix;
1754                 if(self.spawnflags == 0)
1755                 {
1756                         itemprefix = "";
1757                         valueprefix = "";
1758                 }
1759                 else if(self.spawnflags == 1)
1760                 {
1761                         itemprefix = "max ";
1762                         valueprefix = "max ";
1763                 }
1764                 else if(self.spawnflags == 2)
1765                 {
1766                         itemprefix = "min ";
1767                         valueprefix = "min ";
1768                 }
1769                 else if(self.spawnflags == 4)
1770                 {
1771                         itemprefix = "minus ";
1772                         valueprefix = "max ";
1773                 }
1774                 else
1775                 {
1776                         error("invalid spawnflags");
1777 #ifdef GMQCC
1778                         itemprefix = string_null;
1779                         valueprefix = string_null;
1780 #endif
1781                 }
1782
1783                 self.netname = "";
1784                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1785                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1786                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1787                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1788                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1789                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1790                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1791                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1792                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1793                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1794                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1795                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1796                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1797                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1798                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1799                 {
1800                         e = get_weaponinfo(j);
1801                         if(e.weapon)
1802                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1803                 }
1804         }
1805         self.netname = strzone(self.netname);
1806         //print(self.netname, "\n");
1807
1808         n = tokenize_console(self.netname);
1809         for(i = 0; i < n; ++i)
1810         {
1811                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1812                 {
1813                         e = get_weaponinfo(j);
1814                         if(argv(i) == e.netname)
1815                         {
1816                                 weapon_action(e.weapon, WR_PRECACHE);
1817                                 break;
1818                         }
1819                 }
1820         }
1821 }
1822
1823 void spawnfunc_item_fuel(void)
1824 {
1825         if(!self.ammo_fuel)
1826                 self.ammo_fuel = g_pickup_fuel;
1827         if(!self.pickup_anyway)
1828                 self.pickup_anyway = g_pickup_ammo_anyway;
1829         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1830 }
1831
1832 void spawnfunc_item_fuel_regen(void)
1833 {
1834         if(start_items & IT_FUEL_REGEN)
1835         {
1836                 spawnfunc_item_fuel();
1837                 return;
1838         }
1839         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1840 }
1841
1842 void spawnfunc_item_jetpack(void)
1843 {
1844         if(g_grappling_hook)
1845                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1846         if(!self.ammo_fuel)
1847                 self.ammo_fuel = g_pickup_fuel_jetpack;
1848         if(start_items & IT_JETPACK)
1849         {
1850                 spawnfunc_item_fuel();
1851                 return;
1852         }
1853         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1854 }
1855
1856
1857 #define OP_SET 0
1858 #define OP_MIN 1
1859 #define OP_MAX 2
1860 #define OP_PLUS 3
1861 #define OP_MINUS 4
1862
1863 float GiveWeapon(entity e, float wpn, float op, float val)
1864 {
1865         float v0, v1;
1866         v0 = WEPSET_CONTAINS_EW(e, wpn);
1867         switch(op)
1868         {
1869                 case OP_SET:
1870                         if(val > 0)
1871                                 WEPSET_OR_EW(e, wpn);
1872                         else
1873                                 WEPSET_ANDNOT_EW(e, wpn);
1874                         break;
1875                 case OP_MIN:
1876                 case OP_PLUS:
1877                         if(val > 0)
1878                                 WEPSET_OR_EW(e, wpn);
1879                         break;
1880                 case OP_MAX:
1881                         if(val <= 0)
1882                                 WEPSET_ANDNOT_EW(e, wpn);
1883                         break;
1884                 case OP_MINUS:
1885                         if(val > 0)
1886                                 WEPSET_ANDNOT_EW(e, wpn);
1887                         break;
1888         }
1889         v1 = WEPSET_CONTAINS_EW(e, wpn);
1890         return (v0 != v1);
1891 }
1892
1893 float GiveBit(entity e, .float fld, float bit, float op, float val)
1894 {
1895         float v0, v1;
1896         v0 = (e.fld & bit);
1897         switch(op)
1898         {
1899                 case OP_SET:
1900                         if(val > 0)
1901                                 e.fld |= bit;
1902                         else
1903                                 e.fld &~= bit;
1904                         break;
1905                 case OP_MIN:
1906                 case OP_PLUS:
1907                         if(val > 0)
1908                                 e.fld |= bit;
1909                         break;
1910                 case OP_MAX:
1911                         if(val <= 0)
1912                                 e.fld &~= bit;
1913                         break;
1914                 case OP_MINUS:
1915                         if(val > 0)
1916                                 e.fld &~= bit;
1917                         break;
1918         }
1919         v1 = (e.fld & bit);
1920         return (v0 != v1);
1921 }
1922
1923 float GiveValue(entity e, .float fld, float op, float val)
1924 {
1925         float v0, v1;
1926         v0 = e.fld;
1927         switch(op)
1928         {
1929                 case OP_SET:
1930                         e.fld = val;
1931                         break;
1932                 case OP_MIN:
1933                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1934                         break;
1935                 case OP_MAX:
1936                         e.fld = min(e.fld, val);
1937                         break;
1938                 case OP_PLUS:
1939                         e.fld += val;
1940                         break;
1941                 case OP_MINUS:
1942                         e.fld -= val;
1943                         break;
1944         }
1945         v1 = e.fld;
1946         return (v0 != v1);
1947 }
1948
1949 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1950 {
1951         if(v1 == v0)
1952                 return;
1953         if(v1 <= v0 - t)
1954         {
1955                 if(snd_decr != "")
1956                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1957         }
1958         else if(v0 >= v0 + t)
1959         {
1960                 if(snd_incr != "")
1961                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1962         }
1963 }
1964
1965 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1966 {
1967         if(v0 < v1)
1968                 e.rotfield = max(e.rotfield, time + rottime);
1969         else if(v0 > v1)
1970                 e.regenfield = max(e.regenfield, time + regentime);
1971 }
1972
1973 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1974 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1975 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1976 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1977 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1978 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1979
1980 float GiveItems(entity e, float beginarg, float endarg)
1981 {
1982         float got, i, j, val, op;
1983         float _switchweapon;
1984         entity wi;
1985         string cmd;
1986
1987         val = 999;
1988         op = OP_SET;
1989
1990         got = 0;
1991
1992         _switchweapon = FALSE;
1993         if (e.autoswitch)
1994                 if (e.switchweapon == w_getbestweapon(e))
1995                         _switchweapon = TRUE;
1996
1997         e.strength_finished = max(0, e.strength_finished - time);
1998         e.invincible_finished = max(0, e.invincible_finished - time);
1999         e.superweapons_finished = max(0, e.superweapons_finished - time);
2000
2001         PREGIVE(e, items);
2002         PREGIVE_WEAPONS(e);
2003         PREGIVE(e, strength_finished);
2004         PREGIVE(e, invincible_finished);
2005         PREGIVE(e, superweapons_finished);
2006         PREGIVE(e, ammo_nails);
2007         PREGIVE(e, ammo_cells);
2008         PREGIVE(e, ammo_shells);
2009         PREGIVE(e, ammo_rockets);
2010         PREGIVE(e, ammo_fuel);
2011         PREGIVE(e, armorvalue);
2012         PREGIVE(e, health);
2013
2014         for(i = beginarg; i < endarg; ++i)
2015         {
2016                 cmd = argv(i);
2017
2018                 if(cmd == "0" || stof(cmd))
2019                 {
2020                         val = stof(cmd);
2021                         continue;
2022                 }
2023                 switch(cmd)
2024                 {
2025                         case "no":
2026                                 op = OP_MAX;
2027                                 val = 0;
2028                                 continue;
2029                         case "max":
2030                                 op = OP_MAX;
2031                                 continue;
2032                         case "min":
2033                                 op = OP_MIN;
2034                                 continue;
2035                         case "plus":
2036                                 op = OP_PLUS;
2037                                 continue;
2038                         case "minus":
2039                                 op = OP_MINUS;
2040                                 continue;
2041                         case "ALL":
2042                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2043                                 got += GiveValue(e, strength_finished, op, val);
2044                                 got += GiveValue(e, invincible_finished, op, val);
2045                                 got += GiveValue(e, superweapons_finished, op, val);
2046                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2047                         case "all":
2048                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2049                                 got += GiveValue(e, health, op, val);
2050                                 got += GiveValue(e, armorvalue, op, val);
2051                         case "allweapons":
2052                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2053                                 {
2054                                         wi = get_weaponinfo(j);
2055                                         if(wi.weapon)
2056                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
2057                                                         got += GiveWeapon(e, j, op, val);
2058                                 }
2059                         case "allammo":
2060                                 got += GiveValue(e, ammo_cells, op, val);
2061                                 got += GiveValue(e, ammo_shells, op, val);
2062                                 got += GiveValue(e, ammo_nails, op, val);
2063                                 got += GiveValue(e, ammo_rockets, op, val);
2064                                 got += GiveValue(e, ammo_fuel, op, val);
2065                                 break;
2066                         case "unlimited_ammo":
2067                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2068                                 break;
2069                         case "unlimited_weapon_ammo":
2070                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
2071                                 break;
2072                         case "unlimited_superweapons":
2073                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
2074                                 break;
2075                         case "jetpack":
2076                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2077                                 break;
2078                         case "fuel_regen":
2079                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2080                                 break;
2081                         case "strength":
2082                                 got += GiveValue(e, strength_finished, op, val);
2083                                 break;
2084                         case "invincible":
2085                                 got += GiveValue(e, invincible_finished, op, val);
2086                                 break;
2087                         case "superweapons":
2088                                 got += GiveValue(e, superweapons_finished, op, val);
2089                                 break;
2090                         case "cells":
2091                                 got += GiveValue(e, ammo_cells, op, val);
2092                                 break;
2093                         case "shells":
2094                                 got += GiveValue(e, ammo_shells, op, val);
2095                                 break;
2096                         case "nails":
2097                         case "bullets":
2098                                 got += GiveValue(e, ammo_nails, op, val);
2099                                 break;
2100                         case "rockets":
2101                                 got += GiveValue(e, ammo_rockets, op, val);
2102                                 break;
2103                         case "health":
2104                                 got += GiveValue(e, health, op, val);
2105                                 break;
2106                         case "armor":
2107                                 got += GiveValue(e, armorvalue, op, val);
2108                                 break;
2109                         case "fuel":
2110                                 got += GiveValue(e, ammo_fuel, op, val);
2111                                 break;
2112                         default:
2113                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2114                                 {
2115                                         wi = get_weaponinfo(j);
2116                                         if(cmd == wi.netname)
2117                                         {
2118                                                 got += GiveWeapon(e, j, op, val);
2119                                                 break;
2120                                         }
2121                                 }
2122                                 if(j > WEP_LAST)
2123                                         print("give: invalid item ", cmd, "\n");
2124                                 break;
2125                 }
2126                 val = 999;
2127                 op = OP_SET;
2128         }
2129
2130         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
2131         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
2132         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
2133         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
2134         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2135         {
2136                 wi = get_weaponinfo(j);
2137                 if(wi.weapon)
2138                 {
2139                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
2140                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
2141                                 if(WEPSET_CONTAINS_EW(e, j))
2142                                         weapon_action(wi.weapon, WR_PRECACHE);
2143                 }
2144         }
2145         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2146         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2147         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2148         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2149         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2150         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2151         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2152         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2153         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2154
2155         if(e.superweapons_finished <= 0)
2156                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
2157                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2158
2159         if (g_minstagib)
2160         {
2161                 e.health = bound(0, e.health, 100);
2162                 e.armorvalue = bound(0, e.armorvalue, 999);
2163         }
2164
2165         if(e.strength_finished <= 0)
2166                 e.strength_finished = 0;
2167         else
2168                 e.strength_finished += time;
2169         if(e.invincible_finished <= 0)
2170                 e.invincible_finished = 0;
2171         else
2172                 e.invincible_finished += time;
2173         if(e.superweapons_finished <= 0)
2174                 e.superweapons_finished = 0;
2175         else
2176                 e.superweapons_finished += time;
2177
2178         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
2179                 _switchweapon = TRUE;
2180         if(_switchweapon)
2181                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2182
2183         return got;
2184 }
2185 #endif