qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 void trigger_push_use()
  12 {
  13         if(teamplay)
  14                 self.team = activator.team;
  15 }
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         float grav, sdist, zdist, vs, vz, jumpheight;
  34         vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = autocvar_sv_gravity;
  39
  40         zdist = torg_z - org_z;
  41         sdist = vlen(torg - org - zdist * '0 0 1');
  42         sdir = normalize(torg - org - zdist * '0 0 1');
  43
  44         // how high do we need to push the player?
  45         jumpheight = fabs(ht);
  46         if(zdist > 0)
  47                 jumpheight = jumpheight + zdist;
  48
  49         /*
  50                 STOP.
  51
  52                 You will not understand the following equations anyway...
  53                 But here is what I did to get them.
  54
  55                 I used the functions
  56
  57                   s(t) = t * vs
  58                   z(t) = t * vz - 1/2 grav t^2
  59
  60                 and solved for:
  61
  62                   s(ti) = sdist
  63                   z(ti) = zdist
  64                   max(z, ti) = jumpheight
  65
  66                 From these three equations, you will find the three parameters vs, vz
  67                 and ti.
  68          */
  69
  70         // push him so high...
  71         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  72
  73         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  74         if(ht < 0)
  75                 if(zdist < 0)
  76                         vz = -vz;
  77
  78         vector solution;
  79         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  80         // ALWAYS solvable because jumpheight >= zdist
  81         if(!solution_z)
  82                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  83         if(zdist == 0)
  84                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  85
  86         if(zdist < 0)
  87         {
  88                 // down-jump
  89                 if(ht < 0)
  90                 {
  91                         // almost straight line type
  92                         // jump apex is before the jump
  93                         // we must take the larger one
  94                         trigger_push_calculatevelocity_flighttime = solution_y;
  95                 }
  96                 else
  97                 {
  98                         // regular jump
  99                         // jump apex is during the jump
 100                         // we must take the larger one too
 101                         trigger_push_calculatevelocity_flighttime = solution_y;
 102                 }
 103         }
 104         else
 105         {
 106                 // up-jump
 107                 if(ht < 0)
 108                 {
 109                         // almost straight line type
 110                         // jump apex is after the jump
 111                         // we must take the smaller one
 112                         trigger_push_calculatevelocity_flighttime = solution_x;
 113                 }
 114                 else
 115                 {
 116                         // regular jump
 117                         // jump apex is during the jump
 118                         // we must take the larger one
 119                         trigger_push_calculatevelocity_flighttime = solution_y;
 120                 }
 121         }
 122         vs = sdist / trigger_push_calculatevelocity_flighttime;
 123
 124         // finally calculate the velocity
 125         return sdir * vs + '0 0 1' * vz;
 126 }
 127
 128 void trigger_push_touch()
 129 {
 130         if (self.active == ACTIVE_NOT)
 131                 return;
 132
 133         if (!isPushable(other))
 134                 return;
 135
 136         if(self.team)
 137                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 138                         return;
 139
 140         EXACTTRIGGER_TOUCH;
 141
 142         if(self.enemy)
 143         {
 144                 other.velocity = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 145         }
 146         else if(self.target)
 147         {
 148                 entity e;
 149                 RandomSelection_Init();
 150                 for(e = world; (e = find(e, targetname, self.target)); )
 151                 {
 152                         if(e.cnt)
 153                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
 154                         else
 155                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 156                 }
 157                 other.velocity = trigger_push_calculatevelocity(other.origin, RandomSelection_chosen_ent, self.height);
 158         }
 159         else
 160         {
 161                 other.velocity = self.movedir;
 162         }
 163
 164         other.flags &~= FL_ONGROUND;
 165
 166         if (other.classname == "player")
 167         {
 168                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 169                 other.oldvelocity = other.velocity;
 170
 171                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 172                 {
 173                         // flash when activated
 174                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 175                         sound (other, CH_TRIGGER, self.noise, VOL_BASE, ATTN_NORM);
 176                         self.pushltime = time + 0.2;
 177                 }
 178                 float ct;
 179                 ct = clienttype(other);
 180                 if( ct == CLIENTTYPE_REAL || ct == CLIENTTYPE_BOT)
 181                 {
 182                         float i;
 183                         float found;
 184                         found = FALSE;
 185                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 186                                 if(other.(jumppadsused[i]) == self)
 187                                         found = TRUE;
 188                         if(!found)
 189                         {
 190                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 191                                 other.jumppadcount = other.jumppadcount + 1;
 192                         }
 193
 194                         if(ct == CLIENTTYPE_REAL)
 195                         {
 196                                 if(self.message)
 197                                         centerprint(other, self.message);
 198                         }
 199                         else
 200                                 other.lastteleporttime = time;
 201
 202                         if (!other.animstate_override)
 203                         {
 204                                 if (other.crouch)
 205                                         setanim(other, other.anim_duckjump, FALSE, TRUE, TRUE);
 206                                 else
 207                                         setanim(other, other.anim_jump, FALSE, TRUE, TRUE);
 208                         }
 209                 }
 210                 else
 211                         other.jumppadcount = TRUE;
 212
 213                 // reset tracking of who pushed you into a hazard (for kill credit)
 214                 other.pushltime = 0;
 215         }
 216
 217         if(self.enemy.target)
 218         {
 219                 entity oldself;
 220                 oldself = self;
 221                 activator = other;
 222                 self = self.enemy;
 223                 SUB_UseTargets();
 224                 self = oldself;
 225         }
 226
 227         if (other.flags & FL_PROJECTILE)
 228         {
 229                 other.angles = vectoangles (other.velocity);
 230                 switch(other.movetype)
 231                 {
 232                         case MOVETYPE_FLY:
 233                                 other.movetype = MOVETYPE_TOSS;
 234                                 other.gravity = 1;
 235                                 break;
 236                         case MOVETYPE_BOUNCEMISSILE:
 237                                 other.movetype = MOVETYPE_BOUNCE;
 238                                 other.gravity = 1;
 239                                 break;
 240                 }
 241                 UpdateCSQCProjectile(other);
 242         }
 243
 244         if (self.spawnflags & PUSH_ONCE)
 245         {
 246                 self.touch = SUB_Null;
 247                 self.think = SUB_Remove;
 248                 self.nextthink = time;
 249         }
 250 }
 251
 252 .vector dest;
 253 void trigger_push_findtarget()
 254 {
 255         entity e, t;
 256         vector org;
 257
 258         // first calculate a typical start point for the jump
 259         org = (self.absmin + self.absmax) * 0.5;
 260         org_z = self.absmax_z - PL_MIN_z;
 261
 262         if (self.target)
 263         {
 264                 float n;
 265                 n = 0;
 266                 for(t = world; (t = find(t, targetname, self.target)); )
 267                 {
 268                         ++n;
 269                         e = spawn();
 270                         setorigin(e, org);
 271                         setsize(e, PL_MIN, PL_MAX);
 272                         e.velocity = trigger_push_calculatevelocity(org, t, self.height);
 273                         tracetoss(e, e);
 274                         if(e.movetype == MOVETYPE_NONE)
 275                                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 276                         remove(e);
 277                 }
 278
 279                 if(n == 0)
 280                 {
 281                         // no dest!
 282                         objerror ("Jumppad with nonexistant target");
 283                         return;
 284                 }
 285                 else if(n == 1)
 286                 {
 287                         // exactly one dest - bots love that
 288                         self.enemy = find(e, targetname, self.target);
 289                 }
 290                 else
 291                 {
 292                         // have to use random selection every single time
 293                         self.enemy = world;
 294                 }
 295         }
 296         else
 297         {
 298                 e = spawn();
 299                 setorigin(e, org);
 300                 setsize(e, PL_MIN, PL_MAX);
 301                 e.velocity = self.movedir;
 302                 tracetoss(e, e);
 303                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 304                 remove(e);
 305         }
 306 }
 307
 308 /*
 309  * ENTITY PARAMETERS:
 310  *
 311  *   target:  target of jump
 312  *   height:  the absolute value is the height of the highest point of the jump
 313  *            trajectory above the higher one of the player and the target.
 314  *            the sign indicates whether the highest point is INSIDE (positive)
 315  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 316  *            positive values for targets mounted on the floor, and use negative
 317  *            values to target a point on the ceiling.
 318  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 319  */
 320 void spawnfunc_trigger_push()
 321 {
 322         SetMovedir ();
 323
 324         EXACTTRIGGER_INIT;
 325
 326         self.active = ACTIVE_ACTIVE;
 327         self.use = trigger_push_use;
 328         self.touch = trigger_push_touch;
 329
 330         // normal push setup
 331         if (!self.speed)
 332                 self.speed = 1000;
 333         self.movedir = self.movedir * self.speed * 10;
 334
 335         if not(self.noise)
 336                 self.noise = "misc/jumppad.wav";
 337         precache_sound (self.noise);
 338
 339         // this must be called to spawn the teleport waypoints for bots
 340         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 341 }
 342
 343 void spawnfunc_target_push() {}
 344 void spawnfunc_info_notnull() {}
 345 void spawnfunc_target_position() {}