fix starting the gametype
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / teamplay.qc
1 string cache_mutatormsg;
2 string cache_lastmutatormsg;
3
4 // client counts for each team
5 float c1, c2, c3, c4;
6 // # of bots on those teams
7 float cb1, cb2, cb3, cb4;
8
9 float audit_teams_time;
10
11 float IsTeamBalanceForced()
12 {
13         if(intermission_running)
14                 return 0; // no rebalancing whatsoever please
15         if(!teams_matter)
16                 return 0;
17         if(cvar("g_campaign"))
18                 return 0;
19         if(cvar("bot_vs_human") && (c3==-1 && c4==-1))
20                 return 0;
21         if(!cvar("g_balance_teams_force"))
22                 return -1;
23         return 1;
24 }
25
26 void TeamchangeFrags(entity e)
27 {
28         PlayerScore_Clear(e);
29 }
30
31 vector TeamColor(float teem)
32 {
33         switch(teem)
34         {
35                 case COLOR_TEAM1:
36                         return '1 0.0625 0.0625';
37                 case COLOR_TEAM2:
38                         return '0.0625 0.0625 1';
39                 case COLOR_TEAM3:
40                         return '1 1 0.0625';
41                 case COLOR_TEAM4:
42                         return '1 0.0625 1';
43                 default:
44                         return '1 1 1';
45         }
46 }
47
48 string TeamName(float t)
49 {
50         return strcat(Team_ColorName(t), " Team");
51 }
52 string ColoredTeamName(float t)
53 {
54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
55 }
56 string TeamNoName(float t)
57 {
58         // fixme: Search for team entities and get their .netname's!
59         if(t == 1)
60                 return "Red Team";
61         if(t == 2)
62                 return "Blue Team";
63         if(t == 3)
64                 return "Yellow Team";
65         if(t == 4)
66                 return "Pink Team";
67         return "Neutral Team";
68 }
69
70 void dom_init();
71 void ctf_init();
72 void runematch_init();
73 void tdm_init();
74 void nb_init();
75 void entcs_init();
76
77 void LogTeamchange(float player_id, float team_number, float type)
78 {
79         if(!cvar("sv_eventlog"))
80                 return;
81
82         if(player_id < 1)
83                 return;
84
85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
86 }
87
88 void WriteGameCvars()
89 {
90         cvar_set("g_dm", ftos(g_dm));
91         cvar_set("g_tdm", ftos(g_tdm));
92         cvar_set("g_domination", ftos(g_domination));
93         cvar_set("g_ctf", ftos(g_ctf));
94         cvar_set("g_runematch", ftos(g_runematch));
95         cvar_set("g_lms", ftos(g_lms));
96         cvar_set("g_arena", ftos(g_arena));
97         cvar_set("g_ca", ftos(g_ca));
98         cvar_set("g_keyhunt", ftos(g_keyhunt));
99         cvar_set("g_assault", ftos(g_assault));
100         cvar_set("g_onslaught", ftos(g_onslaught));
101         cvar_set("g_race", ftos(g_race));
102         cvar_set("g_nexball", ftos(g_nexball));
103         cvar_set("g_cts", ftos(g_cts));
104         cvar_set("g_freezetag", ftos(g_freezetag));
105 }
106
107 void ReadGameCvars()
108 {
109         float found;
110         float prev;
111         float i;
112
113         found = 0;
114         prev = cvar("gamecfg");
115         for(i = 0; i < 2; ++i)
116         {
117                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
118                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
119                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
120                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
121                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
122                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
123                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
124                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
125                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
126                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
127                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
128                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
129                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
130                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
131                 found += (g_freezetag = (!found && (prev != GAME_FREEZETAG) && cvar("g_freezetag")));
132
133                 if(found)
134                         break;
135
136                 prev = -1; // second attempt takes place WITHOUT prev set
137         }
138
139         if(!found)
140                 g_dm = 1;
141
142         if(g_dm && cvar("deathmatch_force_teamplay"))
143         {
144                 g_dm = 0;
145                 g_tdm = 1;
146         }
147
148         teams_matter = 0;
149 }
150
151 void default_delayedinit()
152 {
153         if(!scores_initialized)
154                 ScoreRules_generic();
155 }
156
157 void ActivateTeamplay()
158 {
159         float teamplay_default;
160         teamplay_default = cvar("teamplay_default");
161
162         if(teamplay_default)
163                 teamplay = teamplay_default;
164         else
165                 teamplay = 3;
166         cvar_set("teamplay", ftos(teamplay));
167
168         teams_matter = 1;
169 }
170
171 void InitGameplayMode()
172 {
173         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
174
175         qualifying_override = -1;
176
177         VoteReset();
178
179         teams_matter = 0;
180         cvar_set("teamplay", "0");
181
182         // make sure only ONE type is selected
183         ReadGameCvars();
184         WriteGameCvars();
185
186         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
187         get_mi_min_max(1);
188         world.mins = mi_min;
189         world.maxs = mi_max;
190
191         MapInfo_LoadMapSettings(mapname);
192
193         if not(cvar_value_issafe(world.fog))
194         {
195                 print("The current map contains a potentially harmful fog setting, ignored\n");
196                 world.fog = string_null;
197         }
198         if(MapInfo_Map_fog != "")
199                 if(MapInfo_Map_fog == "none")
200                         world.fog = string_null;
201                 else
202                         world.fog = strzone(MapInfo_Map_fog);
203         clientstuff = strzone(MapInfo_Map_clientstuff);
204
205         MapInfo_ClearTemps();
206
207         // in case mapinfo switched the type
208         ReadGameCvars();
209
210         // set both here, gamemode can override it later
211         timelimit_override = cvar("timelimit_override");
212         fraglimit_override = cvar("fraglimit_override");
213         leadlimit_override = cvar("leadlimit_override");
214
215         if(g_dm)
216         {
217                 game = GAME_DEATHMATCH;
218                 gamemode_name = "Deathmatch";
219         }
220
221         if(g_tdm)
222         {
223                 game = GAME_TEAM_DEATHMATCH;
224                 gamemode_name = "Team Deathmatch";
225                 ActivateTeamplay();
226                 tdm_init();
227                 if(cvar("g_tdm_team_spawns"))
228                         have_team_spawns = -1; // request team spawns
229         }
230
231         if(g_domination)
232         {
233                 game = GAME_DOMINATION;
234                 gamemode_name = "Domination";
235                 ActivateTeamplay();
236                 fraglimit_override = cvar("g_domination_point_limit");
237                 leadlimit_override = cvar("g_domination_point_leadlimit");
238                 dom_init();
239                 have_team_spawns = -1; // request team spawns
240         }
241
242         if(g_ctf)
243         {
244                 game = GAME_CTF;
245                 gamemode_name = "Capture the Flag";
246                 ActivateTeamplay();
247                 if(cvar("g_campaign"))
248                         g_ctf_win_mode = 2;
249                 else
250                         g_ctf_win_mode = cvar("g_ctf_win_mode");
251                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
252                 if(g_ctf_win_mode == 2)
253                 {
254                         fraglimit_override = cvar("g_ctf_capture_limit");
255                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
256                 }
257                 else
258                 {
259                         fraglimit_override = cvar("capturelimit_override");
260                         leadlimit_override = cvar("captureleadlimit_override");
261                 }
262                 ctf_init();
263                 have_team_spawns = -1; // request team spawns
264         }
265
266         if(g_runematch)
267         {
268                 game = GAME_RUNEMATCH;
269                 gamemode_name = "Rune Match";
270                 if(cvar("deathmatch_force_teamplay"))
271                         ActivateTeamplay();
272                 fraglimit_override = cvar("g_runematch_point_limit");
273                 leadlimit_override = cvar("g_runematch_point_leadlimit");
274                 runematch_init();
275         }
276
277         if(g_lms)
278         {
279                 game = GAME_LMS;
280                 gamemode_name = "Last Man Standing";
281                 fraglimit_override = cvar("g_lms_lives_override");
282                 leadlimit_override = 0; // not supported by LMS
283                 if(fraglimit_override == 0)
284                         fraglimit_override = -1;
285                 lms_lowest_lives = 9999;
286                 lms_next_place = 0;
287                 ScoreRules_lms();
288         }
289
290         if(g_arena)
291         {
292                 game = GAME_ARENA;
293                 gamemode_name = "Arena";
294                 fraglimit_override = cvar("g_arena_point_limit");
295                 leadlimit_override = cvar("g_arena_point_leadlimit");
296                 maxspawned = cvar("g_arena_maxspawned");
297                 if(maxspawned < 2)
298                         maxspawned = 2;
299                 arena_roundbased = cvar("g_arena_roundbased");
300         }
301
302         if(g_ca)
303         {
304                 game = GAME_CA;
305                 gamemode_name = "Clan Arena";
306                 ActivateTeamplay();
307                 fraglimit_override = cvar("g_ca_point_limit");
308                 leadlimit_override = cvar("g_ca_point_leadlimit");
309                 precache_sound("ctf/red_capture.wav");
310                 precache_sound("ctf/blue_capture.wav");
311         }
312         if(g_keyhunt)
313         {
314                 game = GAME_KEYHUNT;
315                 gamemode_name = "Key Hunt";
316                 ActivateTeamplay();
317                 fraglimit_override = cvar("g_keyhunt_point_limit");
318                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
319                 MUTATOR_ADD(gamemode_keyhunt);
320         }
321
322         if(g_freezetag)
323         {
324                 game = GAME_FREEZETAG;
325                 gamemode_name = "Freeze Tag";
326                 ActivateTeamplay();
327                 fraglimit_override = cvar("g_freezetag_point_limit");
328                 leadlimit_override = cvar("g_freezetag_point_leadlimit");
329                 MUTATOR_ADD(gamemode_freezetag);
330         }
331
332         if(g_assault)
333         {
334                 game = GAME_ASSAULT;
335                 gamemode_name = "Assault";
336                 ActivateTeamplay();
337                 ScoreRules_assault();
338                 have_team_spawns = -1; // request team spawns
339         }
340
341         if(g_onslaught)
342         {
343                 game = GAME_ONSLAUGHT;
344                 gamemode_name = "Onslaught";
345                 ActivateTeamplay();
346                 have_team_spawns = -1; // request team spawns
347         }
348
349         if(g_race)
350         {
351                 game = GAME_RACE;
352                 gamemode_name = "Race";
353
354                 if(cvar("g_race_teams"))
355                 {
356                         ActivateTeamplay();
357                         race_teams = bound(2, cvar("g_race_teams"), 4);
358                         have_team_spawns = -1; // request team spawns
359                 }
360                 else
361                         race_teams = 0;
362
363                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
364                 fraglimit_override = cvar("g_race_laps_limit");
365                 leadlimit_override = 0; // currently not supported by race
366         }
367
368         if(g_cts)
369         {
370                 game = GAME_CTS;
371                 gamemode_name = "CTS";
372                 g_race_qualifying = 1;
373                 fraglimit_override = 0;
374                 leadlimit_override = 0;
375         }
376
377         if(g_nexball)
378         {
379                 game = GAME_NEXBALL;
380                 gamemode_name = "Nexball";
381                 fraglimit_override = cvar("g_nexball_goallimit");
382                 leadlimit_override = cvar("g_nexball_goalleadlimit");
383                 ActivateTeamplay();
384                 nb_init();
385                 have_team_spawns = -1; // request team spawns
386         }
387
388         if(teams_matter)
389                 entcs_init();
390
391         // save it (for the next startup)
392         cvar_set("gamecfg", ftos(game));
393
394         cache_mutatormsg = strzone("");
395         cache_lastmutatormsg = strzone("");
396
397         // enforce the server's universal frag/time limits
398         if(!cvar("g_campaign"))
399         {
400                 if(fraglimit_override >= 0)
401                         cvar_set("fraglimit", ftos(fraglimit_override));
402                 if(timelimit_override >= 0)
403                         cvar_set("timelimit", ftos(timelimit_override));
404                 if(leadlimit_override >= 0)
405                         cvar_set("leadlimit", ftos(leadlimit_override));
406                 if(qualifying_override >= 0)
407                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
408         }
409
410         if(g_race)
411         {
412                 // we need to find out the correct value for g_race_qualifying
413                 if(cvar("g_campaign"))
414                 {
415                         g_race_qualifying = 1;
416                 }
417                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
418                 {
419                         g_race_qualifying = 2;
420                         race_fraglimit = cvar("fraglimit");
421                         race_leadlimit = cvar("leadlimit");
422                         race_timelimit = cvar("timelimit");
423                         cvar_set("fraglimit", "0");
424                         cvar_set("leadlimit", "0");
425                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
426                 }
427                 else
428                         g_race_qualifying = 0;
429         }
430
431         if(g_race || g_cts)
432         {
433                 if(g_race_qualifying)
434                         independent_players = 1;
435
436                 ScoreRules_race();
437         }
438
439         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
440 }
441
442 string GetClientVersionMessage() {
443         local string versionmsg;
444         if (self.version_mismatch) {
445                 if(self.version < cvar("gameversion")) {
446                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
447                 } else {
448                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
449                 }
450         } else {
451                 versionmsg = "^2client version and server version are compatible.^8";
452         }
453         return versionmsg;
454 }
455
456
457 void PrintWelcomeMessage(entity pl)
458 {
459         string s, modifications, motd;
460
461         if(self.cvar_scr_centertime == 0) return;
462
463         if(cvar("g_campaign"))
464         {
465                 if(self.classname == "player" && !self.BUTTON_INFO)
466                         return;
467         }
468         else
469         {
470                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
471                         return;
472         }
473
474         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
475                 if(self.welcomemessage_time > time) return;
476                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
477         }
478
479         if(cvar("g_campaign"))
480         {
481                 centerprint(pl, campaign_message);
482                 return;
483         }
484
485 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
486         if(!self.BUTTON_INFO)
487         {
488                 // TODO get rid of this too
489                 local string specString;
490                 specString = NEWLINES;
491                 //if(time < game_starttime) //also show the countdown when being a spectator
492                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
493                 //else
494                 if (timeoutStatus != 0)
495                         specString = strcat(specString, "\n\n", getTimeoutText(1));
496                 else
497                 {
498                         if(self.classname == "player")
499                                 return;
500                         goto normal;
501                 }
502                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
503         }
504
505 :normal
506         ret_string = "";
507         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
508         modifications = ret_string;
509         
510         if(g_minstagib)
511                 modifications = strcat(modifications, ", MinstaGib");
512         if(g_weaponarena)
513         {
514                 if(g_weaponarena_random)
515                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
516                 else
517                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
518         }
519         if(cvar("g_start_weapon_laser") == 0)
520                 modifications = strcat(modifications, ", No start weapons");
521         if(cvar("sv_gravity") < 800)
522                 modifications = strcat(modifications, ", Low gravity");
523         if(g_cloaked)
524                 modifications = strcat(modifications, ", Cloaked");
525         if(g_grappling_hook)
526                 modifications = strcat(modifications, ", Hook");
527         if(g_midair)
528                 modifications = strcat(modifications, ", Midair");
529         if(g_pinata)
530                 modifications = strcat(modifications, ", Pinata");
531         if(g_weapon_stay)
532                 modifications = strcat(modifications, ", Weapons stay");
533         if(g_bloodloss > 0)
534                 modifications = strcat(modifications, ", Bloodloss");
535         if(g_jetpack)
536                 modifications = strcat(modifications, ", Jet pack");
537         modifications = substring(modifications, 2, strlen(modifications) - 2);
538
539         local string versionmessage;
540         versionmessage = GetClientVersionMessage();
541
542         s = strcat(s, NEWLINES, "This is Xonotic ", cvar_string("g_xonoticversion"), "\n", versionmessage);
543         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
544
545         if(modifications != "")
546                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
547
548         if(timeoutStatus != 0)
549                 s = strcat(s, "\n\n", getTimeoutText(1));
550
551         if (g_grappling_hook)
552                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
553
554         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
555         {
556                 if(cache_lastmutatormsg)
557                         strunzone(cache_lastmutatormsg);
558                 if(cache_mutatormsg)
559                         strunzone(cache_mutatormsg);
560                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
561                 cache_mutatormsg = strzone(cache_lastmutatormsg);
562         }
563
564         if (cache_mutatormsg != "") {
565                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
566         }
567
568         motd = cvar_string("sv_motd");
569         if (motd != "") {
570                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
571         }
572         s = strcat(s, "\n");
573
574         centerprint(pl, s);
575 }
576
577
578 void SetPlayerColors(entity pl, float _color)
579 {
580         /*string s;
581         s = ftos(cl);
582         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
583         pl.team = cl + 1;
584         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
585         pl.clientcolors = 16*cl + cl;*/
586
587         float pants, shirt;
588         pants = _color & 0x0F;
589         shirt = _color & 0xF0;
590
591
592         if(teams_matter) {
593                 setcolor(pl, 16*pants + pants);
594         } else {
595                 setcolor(pl, shirt + pants);
596         }
597 }
598
599 void SetPlayerTeam(entity pl, float t, float s, float noprint)
600 {
601         float _color;
602
603         if(t == 4)
604                 _color = COLOR_TEAM4 - 1;
605         else if(t == 3)
606                 _color = COLOR_TEAM3 - 1;
607         else if(t == 2)
608                 _color = COLOR_TEAM2 - 1;
609         else
610                 _color = COLOR_TEAM1 - 1;
611
612         SetPlayerColors(pl,_color);
613
614         if(t != s) {
615                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
616
617                 if(!noprint)
618                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
619         }
620
621 }
622
623 // set c1...c4 to show what teams are allowed
624 void CheckAllowedTeams (entity for_whom)
625 {
626         float dm;
627         entity head;
628         string teament_name;
629
630         c1 = c2 = c3 = c4 = -1;
631         cb1 = cb2 = cb3 = cb4 = 0;
632
633         if(cvar("g_campaign") && for_whom && clienttype(for_whom) == CLIENTTYPE_REAL)
634         {
635                 c1 = 0; // only allow RED team for player joining
636         }
637         else if(g_onslaught)
638         {
639                 // onslaught is special
640                 head = findchain(classname, "onslaught_generator");
641                 while (head)
642                 {
643                         if (head.team == COLOR_TEAM1) c1 = 0;
644                         if (head.team == COLOR_TEAM2) c2 = 0;
645                         if (head.team == COLOR_TEAM3) c3 = 0;
646                         if (head.team == COLOR_TEAM4) c4 = 0;
647                         head = head.chain;
648                 }
649         }
650         else if(g_domination)
651                 teament_name = "dom_team";
652         else if(g_ctf)
653                 teament_name = "ctf_team";
654         else if(g_tdm)
655                 teament_name = "tdm_team";
656         else if(g_nexball)
657                 teament_name = "nexball_team";
658         else if(g_assault)
659                 c1 = c2 = 0; // Assault always has 2 teams
660         else
661         {
662                 // cover anything else by treating it like tdm with no teams spawned
663                 if(g_race)
664                         dm = race_teams;
665                 else
666                         dm = 2;
667
668                 ret_float = dm;
669                 MUTATOR_CALLHOOK(GetTeamCount);
670                 dm = ret_float;
671
672                 if(dm >= 4)
673                         c1 = c2 = c3 = c4 = 0;
674                 else if(dm >= 3)
675                         c1 = c2 = c3 = 0;
676                 else
677                         c1 = c2 = 0;
678         }
679
680         // find out what teams are allowed if necessary
681         if(teament_name)
682         {
683                 head = find(world, classname, teament_name);
684                 while(head)
685                 {
686                         if(!(g_domination && head.netname == ""))
687                         {
688                                 if(head.team == COLOR_TEAM1)
689                                         c1 = 0;
690                                 else if(head.team == COLOR_TEAM2)
691                                         c2 = 0;
692                                 else if(head.team == COLOR_TEAM3)
693                                         c3 = 0;
694                                 else if(head.team == COLOR_TEAM4)
695                                         c4 = 0;
696                         }
697                         head = find(head, classname, teament_name);
698                 }
699         }
700
701         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
702         if(c3==-1 && c4==-1)
703         if(cvar("bot_vs_human") && for_whom)
704         {
705                 if(cvar("bot_vs_human") > 0)
706                 {
707                         // bots are all blue
708                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
709                                 c1 = c3 = c4 = -1;
710                         else
711                                 c2 = -1;
712                 }
713                 else
714                 {
715                         // bots are all red
716                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
717                                 c2 = c3 = c4 = -1;
718                         else
719                                 c1 = -1;
720                 }
721         }
722
723         // if player has a forced team, ONLY allow that one
724         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
725                 c2 = c3 = c4 = -1;
726         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
727                 c1 = c3 = c4 = -1;
728         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
729                 c1 = c2 = c4 = -1;
730         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
731                 c1 = c2 = c3 = -1;
732 }
733
734 float PlayerValue(entity p)
735 {
736         if(IsTeamBalanceForced() == 1)
737                 return 1;
738         return 1;
739         // FIXME: it always returns 1...
740 }
741
742 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
743 // teams that are allowed will now have their player counts stored in c1...c4
744 void GetTeamCounts(entity ignore)
745 {
746         entity head;
747         float value, bvalue;
748         // now count how many players are on each team already
749
750         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
751         // also remember the lowest-scoring player
752
753         FOR_EACH_PLAYER(head)
754         {
755                 if(head != ignore)// && head.netname != "")
756                 {
757                         value = PlayerValue(head);
758                         if(clienttype(head) == CLIENTTYPE_BOT)
759                                 bvalue = value;
760                         else
761                                 bvalue = 0;
762                         if(head.team == COLOR_TEAM1)
763                         {
764                                 if(c1 >= 0)
765                                 {
766                                         c1 = c1 + value;
767                                         cb1 = cb1 + bvalue;
768                                 }
769                         }
770                         if(head.team == COLOR_TEAM2)
771                         {
772                                 if(c2 >= 0)
773                                 {
774                                         c2 = c2 + value;
775                                         cb2 = cb2 + bvalue;
776                                 }
777                         }
778                         if(head.team == COLOR_TEAM3)
779                         {
780                                 if(c3 >= 0)
781                                 {
782                                         c3 = c3 + value;
783                                         cb3 = cb3 + bvalue;
784                                 }
785                         }
786                         if(head.team == COLOR_TEAM4)
787                         {
788                                 if(c4 >= 0)
789                                 {
790                                         c4 = c4 + value;
791                                         cb4 = cb4 + bvalue;
792                                 }
793                         }
794                 }
795         }
796 }
797
798 // returns # of smallest team (1, 2, 3, 4)
799 // NOTE: Assumes CheckAllowedTeams has already been called!
800 float FindSmallestTeam(entity pl, float ignore_pl)
801 {
802         float totalteams, balance_type, maxc;
803         totalteams = 0;
804
805         // find out what teams are available
806         //CheckAllowedTeams();
807
808         // make sure there are at least 2 teams to join
809         if(c1 >= 0)
810                 totalteams = totalteams + 1;
811         if(c2 >= 0)
812                 totalteams = totalteams + 1;
813         if(c3 >= 0)
814                 totalteams = totalteams + 1;
815         if(c4 >= 0)
816                 totalteams = totalteams + 1;
817
818         if((cvar("bot_vs_human") || pl.team_forced > 0) && totalteams == 1)
819                 totalteams += 1;
820
821         if(totalteams <= 1)
822         {
823                 if(cvar("g_campaign") && pl && clienttype(pl) == CLIENTTYPE_REAL)
824                         return 1; // special case for campaign and player joining
825                 else if(g_domination)
826                         error("Too few teams available for domination\n");
827                 else if(g_ctf)
828                         error("Too few teams available for ctf\n");
829                 else if(g_keyhunt)
830                         error("Too few teams available for key hunt\n");
831                 else if(g_freezetag)
832                         error("Too few teams available for freeze tag\n");
833                 else
834                         error("Too few teams available for team deathmatch\n");
835         }
836
837         // count how many players are in each team
838         if(ignore_pl)
839                 GetTeamCounts(pl);
840         else
841                 GetTeamCounts(world);
842
843         // c1...c4 now have counts of each team
844         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
845
846         // 2 gives priority to what team you're already on, 1 goes in order
847         // 2 doesn't seem to work though...
848         balance_type = 1;
849
850         if(bots_would_leave)
851         //if(pl.classname != "player")
852         if(clienttype(pl) != CLIENTTYPE_BOT)
853         {
854                 c1 -= cb1 * 255.0/256.0;
855                 c2 -= cb2 * 255.0/256.0;
856                 c3 -= cb3 * 255.0/256.0;
857                 c4 -= cb4 * 255.0/256.0;
858         }
859         maxc = max4(c1, c2, c3, c4);
860
861         RandomSelection_Init();
862         if(balance_type == 1)
863         {
864                 // 1: use team count, then score (note: can only use 8 significant bits of score)
865                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
866                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
867                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
868                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
869         }
870         else if(balance_type == 2)
871         {
872                 // 1: use team count, if equal prefer own team
873                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
874                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
875                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
876                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
877         }
878         else if(balance_type == 3)
879         {
880                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
881                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
882                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
883                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
884                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
885         }
886         return RandomSelection_chosen_float;
887 }
888
889 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
890 {
891         float smallest, selectedteam;
892
893         // don't join a team if we're not playing a team game
894         if(!teams_matter)
895                 return 0;
896
897         // find out what teams are available
898         CheckAllowedTeams(pl);
899
900         // if we want the player in a certain team for campaign, force him there
901         if(cvar("g_campaign"))
902         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
903         {
904                 switch(cvar("g_campaign_forceteam"))
905                 {
906                         case 1:
907                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
908                                 LogTeamchange(pl.playerid, pl.team, 2);
909                                 return COLOR_TEAM1;
910                         case 2:
911                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
912                                 LogTeamchange(pl.playerid, pl.team, 2);
913                                 return COLOR_TEAM2;
914                         case 3:
915                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
916                                 LogTeamchange(pl.playerid, pl.team, 2);
917                                 return COLOR_TEAM3;
918                         case 4:
919                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
920                                 LogTeamchange(pl.playerid, pl.team, 2);
921                                 return COLOR_TEAM4;
922                         default:
923                                 break;
924                 }
925         }
926
927         // if we don't care what team he ends up on, put him on whatever team he entered as.
928         // if he's not on a valid team, then let other code put him on the smallest team
929         if(!forcebestteam)
930         {
931                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
932                         selectedteam = pl.team;
933                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
934                         selectedteam = pl.team;
935                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
936                         selectedteam = pl.team;
937                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
938                         selectedteam = pl.team;
939                 else
940                         selectedteam = -1;
941
942                 if(selectedteam > 0)
943                 {
944                         if(!only_return_best)
945                         {
946                                 SetPlayerColors(pl, selectedteam - 1);
947
948                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
949                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
950                                 LogTeamchange(pl.playerid, pl.team, 99);
951                         }
952                         return selectedteam;
953                 }
954                 // otherwise end up on the smallest team (handled below)
955         }
956
957         smallest = FindSmallestTeam(pl, TRUE);
958
959         if(!only_return_best && !pl.bot_forced_team)
960         {
961                 TeamchangeFrags(self);
962                 if(smallest == 1)
963                 {
964                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
965                 }
966                 else if(smallest == 2)
967                 {
968                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
969                 }
970                 else if(smallest == 3)
971                 {
972                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
973                 }
974                 else if(smallest == 4)
975                 {
976                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
977                 }
978                 else
979                 {
980                         error("smallest team: invalid team\n");
981                 }
982
983                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
984
985                 if(pl.deadflag == DEAD_NO)
986                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
987         }
988
989         return smallest;
990 }
991
992 //void() ctf_playerchanged;
993 void SV_ChangeTeam(float _color)
994 {
995         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
996
997         // in normal deathmatch we can just apply the color and we're done
998         if(!teams_matter) {
999                 SetPlayerColors(self, _color);
1000                 return;
1001         }
1002
1003         scolor = self.clientcolors & 0x0F;
1004         dcolor = _color & 0x0F;
1005
1006         if(scolor == COLOR_TEAM1 - 1)
1007                 steam = 1;
1008         else if(scolor == COLOR_TEAM2 - 1)
1009                 steam = 2;
1010         else if(scolor == COLOR_TEAM3 - 1)
1011                 steam = 3;
1012         else // if(scolor == COLOR_TEAM4 - 1)
1013                 steam = 4;
1014         if(dcolor == COLOR_TEAM1 - 1)
1015                 dteam = 1;
1016         else if(dcolor == COLOR_TEAM2 - 1)
1017                 dteam = 2;
1018         else if(dcolor == COLOR_TEAM3 - 1)
1019                 dteam = 3;
1020         else // if(dcolor == COLOR_TEAM4 - 1)
1021                 dteam = 4;
1022
1023         CheckAllowedTeams(self);
1024
1025         if(dteam == 1 && c1 < 0) dteam = 4;
1026         if(dteam == 4 && c4 < 0) dteam = 3;
1027         if(dteam == 3 && c3 < 0) dteam = 2;
1028         if(dteam == 2 && c2 < 0) dteam = 1;
1029
1030         // not changing teams
1031         if(scolor == dcolor)
1032         {
1033                 //bprint("same team change\n");
1034                 SetPlayerTeam(self, dteam, steam, TRUE);
1035                 return;
1036         }
1037
1038         if((cvar("g_campaign")) || (cvar("g_changeteam_banned") && self.wasplayer)) {
1039                 sprint(self, "Team changes not allowed\n");
1040                 return; // changing teams is not allowed
1041         }
1042
1043         if(cvar("g_balance_teams_prevent_imbalance"))
1044         {
1045                 // only allow changing to a smaller or equal size team
1046
1047                 // find out what teams are available
1048                 //CheckAllowedTeams();
1049                 // count how many players on each team
1050                 GetTeamCounts(world);
1051
1052                 // get desired team
1053                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1054                 {
1055                         dcount = c1;
1056                         dbotcount = cb1;
1057                 }
1058                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1059                 {
1060                         dcount = c2;
1061                         dbotcount = cb2;
1062                 }
1063                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1064                 {
1065                         dcount = c3;
1066                         dbotcount = cb3;
1067                 }
1068                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1069                 {
1070                         dcount = c4;
1071                         dbotcount = cb4;
1072                 }
1073                 else
1074                 {
1075                         sprint(self, "Cannot change to an invalid team\n");
1076
1077                         return;
1078                 }
1079
1080                 // get starting team
1081                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1082                         scount = c1;
1083                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1084                         scount = c2;
1085                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1086                         scount = c3;
1087                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1088                         scount = c4;
1089
1090                 if(scount) // started at a valid, nonempty team
1091                 {
1092                         // check if we're trying to change to a larger team that doens't have bots to swap with
1093                         if(dcount >= scount && dbotcount <= 0)
1094                         {
1095                                 sprint(self, "Cannot change to a larger team\n");
1096                                 return; // can't change to a larger team
1097                         }
1098                 }
1099         }
1100
1101 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1102
1103         if(self.classname == "player" && steam != dteam)
1104         {
1105                 // reduce frags during a team change
1106                 TeamchangeFrags(self);
1107         }
1108
1109         SetPlayerTeam(self, dteam, steam, FALSE);
1110
1111         if(self.classname == "player" && steam != dteam)
1112         {
1113                 // kill player when changing teams
1114                 if(self.deadflag == DEAD_NO)
1115                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1116         }
1117         //ctf_playerchanged();
1118 }
1119
1120 void ShufflePlayerOutOfTeam (float source_team)
1121 {
1122         float smallestteam, smallestteam_count, steam;
1123         float lowest_bot_score, lowest_player_score;
1124         entity head, lowest_bot, lowest_player, selected;
1125
1126         smallestteam = 0;
1127         smallestteam_count = 999999999;
1128
1129         if(c1 >= 0 && c1 < smallestteam_count)
1130         {
1131                 smallestteam = 1;
1132                 smallestteam_count = c1;
1133         }
1134         if(c2 >= 0 && c2 < smallestteam_count)
1135         {
1136                 smallestteam = 2;
1137                 smallestteam_count = c2;
1138         }
1139         if(c3 >= 0 && c3 < smallestteam_count)
1140         {
1141                 smallestteam = 3;
1142                 smallestteam_count = c3;
1143         }
1144         if(c4 >= 0 && c4 < smallestteam_count)
1145         {
1146                 smallestteam = 4;
1147                 smallestteam_count = c4;
1148         }
1149
1150         if(!smallestteam)
1151         {
1152                 bprint("warning: no smallest team\n");
1153                 return;
1154         }
1155
1156         if(source_team == 1)
1157                 steam = COLOR_TEAM1;
1158         else if(source_team == 2)
1159                 steam = COLOR_TEAM2;
1160         else if(source_team == 3)
1161                 steam = COLOR_TEAM3;
1162         else if(source_team == 4)
1163                 steam = COLOR_TEAM4;
1164
1165         lowest_bot = world;
1166         lowest_bot_score = 999999999;
1167         lowest_player = world;
1168         lowest_player_score = 999999999;
1169
1170         // find the lowest-scoring player & bot of that team
1171         FOR_EACH_PLAYER(head)
1172         {
1173                 if(head.team == steam)
1174                 {
1175                         if(head.isbot)
1176                         {
1177                                 if(head.totalfrags < lowest_bot_score)
1178                                 {
1179                                         lowest_bot = head;
1180                                         lowest_bot_score = head.totalfrags;
1181                                 }
1182                         }
1183                         else
1184                         {
1185                                 if(head.totalfrags < lowest_player_score)
1186                                 {
1187                                         lowest_player = head;
1188                                         lowest_player_score = head.totalfrags;
1189                                 }
1190                         }
1191                 }
1192         }
1193
1194         // prefers to move a bot...
1195         if(lowest_bot != world)
1196                 selected = lowest_bot;
1197         // but it will move a player if it has to
1198         else
1199                 selected = lowest_player;
1200         // don't do anything if it couldn't find anyone
1201         if(!selected)
1202         {
1203                 bprint("warning: couldn't find a player to move from team\n");
1204                 return;
1205         }
1206
1207         // smallest team gains a member
1208         if(smallestteam == 1)
1209         {
1210                 c1 = c1 + 1;
1211         }
1212         else if(smallestteam == 2)
1213         {
1214                 c2 = c2 + 1;
1215         }
1216         else if(smallestteam == 3)
1217         {
1218                 c3 = c3 + 1;
1219         }
1220         else if(smallestteam == 4)
1221         {
1222                 c4 = c4 + 1;
1223         }
1224         else
1225         {
1226                 bprint("warning: destination team invalid\n");
1227                 return;
1228         }
1229         // source team loses a member
1230         if(source_team == 1)
1231         {
1232                 c1 = c1 + 1;
1233         }
1234         else if(source_team == 2)
1235         {
1236                 c2 = c2 + 2;
1237         }
1238         else if(source_team == 3)
1239         {
1240                 c3 = c3 + 3;
1241         }
1242         else if(source_team == 4)
1243         {
1244                 c4 = c4 + 4;
1245         }
1246         else
1247         {
1248                 bprint("warning: source team invalid\n");
1249                 return;
1250         }
1251
1252         // move the player to the new team
1253         TeamchangeFrags(selected);
1254         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1255
1256         if(selected.deadflag == DEAD_NO)
1257                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1258         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1259 }
1260
1261 void CauseRebalance(float source_team, float howmany_toomany)
1262 {
1263         if(IsTeamBalanceForced() == 1)
1264         {
1265                 bprint("Rebalancing Teams\n");
1266                 ShufflePlayerOutOfTeam(source_team);
1267         }
1268 }
1269
1270 // part of g_balance_teams_force
1271 // occasionally perform an audit of the teams to make
1272 // sure they're more or less balanced in player count.
1273 void AuditTeams()
1274 {
1275         float numplayers, numteams, smallest, toomany;
1276         float balance;
1277         balance = IsTeamBalanceForced();
1278         if(balance == 0)
1279                 return;
1280
1281         if(audit_teams_time > time)
1282                 return;
1283
1284         audit_teams_time = time + 4 + random();
1285
1286 //      bprint("Auditing teams\n");
1287
1288         CheckAllowedTeams(world);
1289         GetTeamCounts(world);
1290
1291
1292         numteams = numplayers = smallest = 0;
1293         if(c1 >= 0)
1294         {
1295                 numteams = numteams + 1;
1296                 numplayers = numplayers + c1;
1297                 smallest = c1;
1298         }
1299         if(c2 >= 0)
1300         {
1301                 numteams = numteams + 1;
1302                 numplayers = numplayers + c2;
1303                 if(c2 < smallest)
1304                         smallest = c2;
1305         }
1306         if(c3 >= 0)
1307         {
1308                 numteams = numteams + 1;
1309                 numplayers = numplayers + c3;
1310                 if(c3 < smallest)
1311                         smallest = c3;
1312         }
1313         if(c4 >= 0)
1314         {
1315                 numteams = numteams + 1;
1316                 numplayers = numplayers + c4;
1317                 if(c4 < smallest)
1318                         smallest = c4;
1319         }
1320
1321         if(numplayers <= 0)
1322                 return; // no players to move around
1323         if(numteams < 2)
1324                 return; // don't bother shuffling if for some reason there aren't any teams
1325
1326         toomany = smallest + 1;
1327
1328         if(c1 && c1 > toomany)
1329                 CauseRebalance(1, c1 - toomany);
1330         if(c2 && c2 > toomany)
1331                 CauseRebalance(2, c2 - toomany);
1332         if(c3 && c3 > toomany)
1333                 CauseRebalance(3, c3 - toomany);
1334         if(c4 && c4 > toomany)
1335                 CauseRebalance(4, c4 - toomany);
1336
1337         // if teams are still unbalanced, balance them further in the next audit,
1338         // which will happen sooner (keep doing rapid audits until things are in order)
1339         audit_teams_time = time + 0.7 + random()*0.3;
1340 }
1341
1342 // code from here on is just to support maps that don't have team entities
1343 void tdm_spawnteam (string teamname, float teamcolor)
1344 {
1345         local entity e;
1346         e = spawn();
1347         e.classname = "tdm_team";
1348         e.netname = teamname;
1349         e.cnt = teamcolor;
1350         e.team = e.cnt + 1;
1351 };
1352
1353 // spawn some default teams if the map is not set up for tdm
1354 void tdm_spawnteams()
1355 {
1356         float numteams;
1357
1358         numteams = cvar("g_tdm_teams_override");
1359         if(numteams < 2)
1360                 numteams = cvar("g_tdm_teams");
1361         numteams = bound(2, numteams, 4);
1362
1363         tdm_spawnteam("Red", COLOR_TEAM1-1);
1364         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1365         if(numteams >= 3)
1366                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1367         if(numteams >= 4)
1368                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1369 };
1370
1371 void tdm_delayedinit()
1372 {
1373         // if no teams are found, spawn defaults
1374         if (find(world, classname, "tdm_team") == world)
1375                 tdm_spawnteams();
1376 };
1377
1378 void tdm_init()
1379 {
1380         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1381 };