qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(float player_id, float team_number, float type)
  76 {
  77         if(!cvar("sv_eventlog"))
  78                 return;
  79
  80         if(player_id < 1)
  81                 return;
  82
  83         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  84 }
  85
  86 void WriteGameCvars()
  87 {
  88         cvar_set("g_dm", ftos(g_dm));
  89         cvar_set("g_tdm", ftos(g_tdm));
  90         cvar_set("g_domination", ftos(g_domination));
  91         cvar_set("g_ctf", ftos(g_ctf));
  92         cvar_set("g_runematch", ftos(g_runematch));
  93         cvar_set("g_lms", ftos(g_lms));
  94         cvar_set("g_arena", ftos(g_arena));
  95         cvar_set("g_ca", ftos(g_ca));
  96         cvar_set("g_keyhunt", ftos(g_keyhunt));
  97         cvar_set("g_assault", ftos(g_assault));
  98         cvar_set("g_onslaught", ftos(g_onslaught));
  99         cvar_set("g_race", ftos(g_race));
 100         cvar_set("g_nexball", ftos(g_nexball));
 101         cvar_set("g_cts", ftos(g_cts));
 102 }
 103
 104 void ReadGameCvars()
 105 {
 106         float found;
 107         float prev;
 108         float i;
 109
 110         found = 0;
 111         prev = cvar("gamecfg");
 112         for(i = 0; i < 2; ++i)
 113         {
 114                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 115                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 116                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 117                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 118                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 119                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 120                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 121                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 122                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 123                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 124                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 125                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 126                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 127                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 128
 129                 if(found)
 130                         break;
 131
 132                 prev = -1; // second attempt takes place WITHOUT prev set
 133         }
 134
 135         if(!found)
 136                 g_dm = 1;
 137
 138         if(g_dm && cvar("deathmatch_force_teamplay"))
 139         {
 140                 g_dm = 0;
 141                 g_tdm = 1;
 142         }
 143
 144         teams_matter = 0;
 145 }
 146
 147 void default_delayedinit()
 148 {
 149         if(!scores_initialized)
 150                 ScoreRules_generic();
 151 }
 152
 153 void ActivateTeamplay()
 154 {
 155         float teamplay_default;
 156         teamplay_default = cvar("teamplay_default");
 157
 158         if(teamplay_default)
 159                 teamplay = teamplay_default;
 160         else
 161                 teamplay = 3;
 162         cvar_set("teamplay", ftos(teamplay));
 163
 164         teams_matter = 1;
 165 }
 166
 167 void InitGameplayMode()
 168 {
 169         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 170
 171         qualifying_override = -1;
 172
 173         VoteReset();
 174
 175         teams_matter = 0;
 176         cvar_set("teamplay", "0");
 177
 178         // make sure only ONE type is selected
 179         ReadGameCvars();
 180         WriteGameCvars();
 181
 182         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 183         get_mi_min_max(1);
 184         world.mins = mi_min;
 185         world.maxs = mi_max;
 186
 187         MapInfo_LoadMapSettings(mapname);
 188
 189         if not(cvar_value_issafe(world.fog))
 190         {
 191                 print("The current map contains a potentially harmful fog setting, ignored\n");
 192                 world.fog = string_null;
 193         }
 194         if(MapInfo_Map_fog != "")
 195                 if(MapInfo_Map_fog == "none")
 196                         world.fog = string_null;
 197                 else
 198                         world.fog = strzone(MapInfo_Map_fog);
 199         clientstuff = strzone(MapInfo_Map_clientstuff);
 200
 201         MapInfo_ClearTemps();
 202
 203         // in case mapinfo switched the type
 204         ReadGameCvars();
 205
 206         // set both here, gamemode can override it later
 207         timelimit_override = cvar("timelimit_override");
 208         fraglimit_override = cvar("fraglimit_override");
 209         leadlimit_override = cvar("leadlimit_override");
 210
 211         if(g_dm)
 212         {
 213                 game = GAME_DEATHMATCH;
 214                 gamemode_name = "Deathmatch";
 215         }
 216
 217         if(g_tdm)
 218         {
 219                 game = GAME_TEAM_DEATHMATCH;
 220                 gamemode_name = "Team Deathmatch";
 221                 ActivateTeamplay();
 222                 tdm_init();
 223                 if(cvar("g_tdm_team_spawns"))
 224                         have_team_spawns = -1; // request team spawns
 225         }
 226
 227         if(g_domination)
 228         {
 229                 game = GAME_DOMINATION;
 230                 gamemode_name = "Domination";
 231                 ActivateTeamplay();
 232                 fraglimit_override = cvar("g_domination_point_limit");
 233                 leadlimit_override = cvar("g_domination_point_leadlimit");
 234                 dom_init();
 235                 have_team_spawns = -1; // request team spawns
 236         }
 237
 238         if(g_ctf)
 239         {
 240                 game = GAME_CTF;
 241                 gamemode_name = "Capture the Flag";
 242                 ActivateTeamplay();
 243                 if(cvar("g_campaign"))
 244                         g_ctf_win_mode = 2;
 245                 else
 246                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 247                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 248                 if(g_ctf_win_mode == 2)
 249                 {
 250                         fraglimit_override = cvar("g_ctf_capture_limit");
 251                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 252                 }
 253                 else
 254                 {
 255                         fraglimit_override = cvar("capturelimit_override");
 256                         leadlimit_override = cvar("captureleadlimit_override");
 257                 }
 258                 ctf_init();
 259                 have_team_spawns = -1; // request team spawns
 260         }
 261
 262         if(g_runematch)
 263         {
 264                 game = GAME_RUNEMATCH;
 265                 gamemode_name = "Rune Match";
 266                 if(cvar("deathmatch_force_teamplay"))
 267                         ActivateTeamplay();
 268                 fraglimit_override = cvar("g_runematch_point_limit");
 269                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 270                 runematch_init();
 271         }
 272
 273         if(g_lms)
 274         {
 275                 game = GAME_LMS;
 276                 gamemode_name = "Last Man Standing";
 277                 fraglimit_override = cvar("g_lms_lives_override");
 278                 leadlimit_override = 0; // not supported by LMS
 279                 if(fraglimit_override == 0)
 280                         fraglimit_override = -1;
 281                 lms_lowest_lives = 9999;
 282                 lms_next_place = 0;
 283                 ScoreRules_lms();
 284         }
 285
 286         if(g_arena)
 287         {
 288                 game = GAME_ARENA;
 289                 gamemode_name = "Arena";
 290                 fraglimit_override = cvar("g_arena_point_limit");
 291                 leadlimit_override = cvar("g_arena_point_leadlimit");
 292                 maxspawned = cvar("g_arena_maxspawned");
 293                 if(maxspawned < 2)
 294                         maxspawned = 2;
 295                 arena_roundbased = cvar("g_arena_roundbased");
 296         }
 297
 298         if(g_ca)
 299         {
 300                 game = GAME_CA;
 301                 gamemode_name = "Clan Arena";
 302                 ActivateTeamplay();
 303                 fraglimit_override = cvar("g_ca_point_limit");
 304                 leadlimit_override = cvar("g_ca_point_leadlimit");
 305                 precache_sound("ctf/red_capture.wav");
 306                 precache_sound("ctf/blue_capture.wav");
 307         }
 308         if(g_keyhunt)
 309         {
 310                 game = GAME_KEYHUNT;
 311                 gamemode_name = "Key Hunt";
 312                 ActivateTeamplay();
 313                 fraglimit_override = cvar("g_keyhunt_point_limit");
 314                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 315                 MUTATOR_ADD(gamemode_keyhunt);
 316         }
 317
 318         if(g_assault)
 319         {
 320                 game = GAME_ASSAULT;
 321                 gamemode_name = "Assault";
 322                 ActivateTeamplay();
 323                 ScoreRules_assault();
 324                 have_team_spawns = -1; // request team spawns
 325         }
 326
 327         if(g_onslaught)
 328         {
 329                 game = GAME_ONSLAUGHT;
 330                 gamemode_name = "Onslaught";
 331                 ActivateTeamplay();
 332                 have_team_spawns = -1; // request team spawns
 333         }
 334
 335         if(g_race)
 336         {
 337                 game = GAME_RACE;
 338                 gamemode_name = "Race";
 339
 340                 if(cvar("g_race_teams"))
 341                 {
 342                         ActivateTeamplay();
 343                         race_teams = bound(2, cvar("g_race_teams"), 4);
 344                         have_team_spawns = -1; // request team spawns
 345                 }
 346                 else
 347                         race_teams = 0;
 348
 349                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 350                 fraglimit_override = cvar("g_race_laps_limit");
 351                 leadlimit_override = 0; // currently not supported by race
 352         }
 353
 354         if(g_cts)
 355         {
 356                 game = GAME_CTS;
 357                 gamemode_name = "CTS";
 358                 g_race_qualifying = 1;
 359                 fraglimit_override = 0;
 360                 leadlimit_override = 0;
 361         }
 362
 363         if(g_nexball)
 364         {
 365                 game = GAME_NEXBALL;
 366                 gamemode_name = "Nexball";
 367                 fraglimit_override = cvar("g_nexball_goallimit");
 368                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 369                 ActivateTeamplay();
 370                 nb_init();
 371                 have_team_spawns = -1; // request team spawns
 372         }
 373
 374         if(teams_matter)
 375                 entcs_init();
 376
 377         // save it (for the next startup)
 378         cvar_set("gamecfg", ftos(game));
 379
 380         cache_mutatormsg = strzone("");
 381         cache_lastmutatormsg = strzone("");
 382
 383         // enforce the server's universal frag/time limits
 384         if(!cvar("g_campaign"))
 385         {
 386                 if(fraglimit_override >= 0)
 387                         cvar_set("fraglimit", ftos(fraglimit_override));
 388                 if(timelimit_override >= 0)
 389                         cvar_set("timelimit", ftos(timelimit_override));
 390                 if(leadlimit_override >= 0)
 391                         cvar_set("leadlimit", ftos(leadlimit_override));
 392                 if(qualifying_override >= 0)
 393                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 394         }
 395
 396         if(g_race)
 397         {
 398                 // we need to find out the correct value for g_race_qualifying
 399                 if(cvar("g_campaign"))
 400                 {
 401                         g_race_qualifying = 1;
 402                 }
 403                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 404                 {
 405                         g_race_qualifying = 2;
 406                         race_fraglimit = cvar("fraglimit");
 407                         race_leadlimit = cvar("leadlimit");
 408                         race_timelimit = cvar("timelimit");
 409                         cvar_set("fraglimit", "0");
 410                         cvar_set("leadlimit", "0");
 411                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 412                 }
 413                 else
 414                         g_race_qualifying = 0;
 415         }
 416
 417         if(g_race || g_cts)
 418         {
 419                 if(g_race_qualifying)
 420                         independent_players = 1;
 421
 422                 ScoreRules_race();
 423         }
 424
 425         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 426 }
 427
 428 string GetClientVersionMessage() {
 429         local string versionmsg;
 430         if (self.version_mismatch) {
 431                 if(self.version < cvar("gameversion")) {
 432                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 433                 } else {
 434                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 435                 }
 436         } else {
 437                 versionmsg = "^2client version and server version are compatible.^8";
 438         }
 439         return versionmsg;
 440 }
 441
 442
 443 void PrintWelcomeMessage(entity pl)
 444 {
 445         string s, modifications, motd;
 446
 447         if(self.cvar_scr_centertime == 0) return;
 448
 449         if(cvar("g_campaign"))
 450         {
 451                 if(self.classname == "player" && !self.BUTTON_INFO)
 452                         return;
 453         }
 454         else
 455         {
 456                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 457                         return;
 458         }
 459
 460         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 461                 if(self.welcomemessage_time > time) return;
 462                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 463         }
 464
 465         if(cvar("g_campaign"))
 466         {
 467                 centerprint(pl, campaign_message);
 468                 return;
 469         }
 470
 471 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 472         if(!self.BUTTON_INFO)
 473         {
 474                 // TODO get rid of this too
 475                 local string specString;
 476                 specString = NEWLINES;
 477                 //if(time < game_starttime) //also show the countdown when being a spectator
 478                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 479                 //else
 480                 if (timeoutStatus != 0)
 481                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 482                 else
 483                 {
 484                         if(self.classname == "player")
 485                                 return;
 486                         goto normal;
 487                 }
 488                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 489         }
 490
 491 :normal
 492         modifications = "";
 493         if(g_minstagib)
 494                 modifications = strcat(modifications, ", MinstaGib");
 495         if(g_nixnex)
 496                 modifications = strcat(modifications, ", NixNex");
 497         if(g_weaponarena)
 498         {
 499                 if(g_weaponarena_random)
 500                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 501                 else
 502                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 503         }
 504         if(cvar("g_start_weapon_laser") == 0)
 505                 modifications = strcat(modifications, ", No start weapons");
 506         if(cvar("sv_gravity") < 800)
 507                 modifications = strcat(modifications, ", Low gravity");
 508         if(g_cloaked)
 509                 modifications = strcat(modifications, ", Cloaked");
 510         if(g_footsteps)
 511                 modifications = strcat(modifications, ", Steps");
 512         if(g_grappling_hook)
 513                 modifications = strcat(modifications, ", Hook");
 514         if(g_laserguided_missile)
 515                 modifications = strcat(modifications, ", LG missiles");
 516         if(g_midair)
 517                 modifications = strcat(modifications, ", Midair");
 518         if(g_vampire)
 519                 modifications = strcat(modifications, ", Vampire");
 520         if(g_pinata)
 521                 modifications = strcat(modifications, ", Pinata");
 522         if(g_weapon_stay)
 523                 modifications = strcat(modifications, ", Weapons stay");
 524         if(g_bloodloss > 0)
 525                 modifications = strcat(modifications, ", Bloodloss");
 526         if(g_jetpack)
 527                 modifications = strcat(modifications, ", Jet pack");
 528         modifications = substring(modifications, 2, strlen(modifications) - 2);
 529
 530         local string versionmessage;
 531         versionmessage = GetClientVersionMessage();
 532
 533         s = strcat(s, NEWLINES, "This is Xonotic ", cvar_string("g_xonoticversion"), "\n", versionmessage);
 534         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 535
 536         if(modifications != "")
 537                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 538
 539         if(timeoutStatus != 0)
 540                 s = strcat(s, "\n\n", getTimeoutText(1));
 541
 542         if (g_grappling_hook)
 543                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 544
 545         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 546         {
 547                 if(cache_lastmutatormsg)
 548                         strunzone(cache_lastmutatormsg);
 549                 if(cache_mutatormsg)
 550                         strunzone(cache_mutatormsg);
 551                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 552                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 553         }
 554
 555         if (cache_mutatormsg != "") {
 556                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 557         }
 558
 559         motd = cvar_string("sv_motd");
 560         if (motd != "") {
 561                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 562         }
 563         s = strcat(s, "\n");
 564
 565         centerprint(pl, s);
 566 }
 567
 568
 569 void SetPlayerColors(entity pl, float _color)
 570 {
 571         /*string s;
 572         s = ftos(cl);
 573         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 574         pl.team = cl + 1;
 575         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 576         pl.clientcolors = 16*cl + cl;*/
 577
 578         float pants, shirt;
 579         pants = _color & 0x0F;
 580         shirt = _color & 0xF0;
 581
 582
 583         if(teams_matter) {
 584                 setcolor(pl, 16*pants + pants);
 585         } else {
 586                 setcolor(pl, shirt + pants);
 587         }
 588 }
 589
 590 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 591 {
 592         float _color;
 593
 594         if(t == 4)
 595                 _color = COLOR_TEAM4 - 1;
 596         else if(t == 3)
 597                 _color = COLOR_TEAM3 - 1;
 598         else if(t == 2)
 599                 _color = COLOR_TEAM2 - 1;
 600         else
 601                 _color = COLOR_TEAM1 - 1;
 602
 603         SetPlayerColors(pl,_color);
 604
 605         if(t != s) {
 606                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 607
 608                 if(!noprint)
 609                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 610         }
 611
 612 }
 613
 614 // set c1...c4 to show what teams are allowed
 615 void CheckAllowedTeams (entity for_whom)
 616 {
 617         float dm;
 618         entity head;
 619         string teament_name;
 620
 621         c1 = c2 = c3 = c4 = -1;
 622         cb1 = cb2 = cb3 = cb4 = 0;
 623
 624         if(g_onslaught)
 625         {
 626                 // onslaught is special
 627                 head = findchain(classname, "onslaught_generator");
 628                 while (head)
 629                 {
 630                         if (head.team == COLOR_TEAM1) c1 = 0;
 631                         if (head.team == COLOR_TEAM2) c2 = 0;
 632                         if (head.team == COLOR_TEAM3) c3 = 0;
 633                         if (head.team == COLOR_TEAM4) c4 = 0;
 634                         head = head.chain;
 635                 }
 636         }
 637         else if(g_domination)
 638                 teament_name = "dom_team";
 639         else if(g_ctf)
 640                 teament_name = "ctf_team";
 641         else if(g_tdm)
 642                 teament_name = "tdm_team";
 643         else if(g_nexball)
 644                 teament_name = "nexball_team";
 645         else if(g_assault)
 646                 c1 = c2 = 0; // Assault always has 2 teams
 647         else
 648         {
 649                 // cover anything else by treating it like tdm with no teams spawned
 650                 if(g_race)
 651                         dm = race_teams;
 652                 else
 653                         dm = 2;
 654
 655                 ret_float = dm;
 656                 MUTATOR_CALLHOOK(GetTeamCount);
 657                 dm = ret_float;
 658
 659                 if(dm >= 4)
 660                         c1 = c2 = c3 = c4 = 0;
 661                 else if(dm >= 3)
 662                         c1 = c2 = c3 = 0;
 663                 else
 664                         c1 = c2 = 0;
 665         }
 666
 667         // find out what teams are allowed if necessary
 668         if(teament_name)
 669         {
 670                 head = find(world, classname, teament_name);
 671                 while(head)
 672                 {
 673                         if(!(g_domination && head.netname == ""))
 674                         {
 675                                 if(head.team == COLOR_TEAM1)
 676                                         c1 = 0;
 677                                 else if(head.team == COLOR_TEAM2)
 678                                         c2 = 0;
 679                                 else if(head.team == COLOR_TEAM3)
 680                                         c3 = 0;
 681                                 else if(head.team == COLOR_TEAM4)
 682                                         c4 = 0;
 683                         }
 684                         head = find(head, classname, teament_name);
 685                 }
 686         }
 687
 688         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 689         if(c3==-1&&c4==-1)
 690         if(cvar("bot_vs_human") && for_whom)
 691         {
 692                 if(cvar("bot_vs_human") > 0)
 693                 {
 694                         // bots are all blue
 695                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 696                                 c1 = c3 = c4 = -1;
 697                         else
 698                                 c2 = -1;
 699                 }
 700                 else
 701                 {
 702                         // bots are all red
 703                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 704                                 c2 = c3 = c4 = -1;
 705                         else
 706                                 c1 = -1;
 707                 }
 708         }
 709 }
 710
 711 float PlayerValue(entity p)
 712 {
 713         if(IsTeamBalanceForced() == 1)
 714                 return 1;
 715         return 1;
 716 }
 717
 718 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 719 // teams that are allowed will now have their player counts stored in c1...c4
 720 void GetTeamCounts(entity ignore)
 721 {
 722         entity head;
 723         float value, bvalue;
 724         // now count how many players are on each team already
 725
 726         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 727         // also remember the lowest-scoring player
 728
 729         FOR_EACH_PLAYER(head)
 730         {
 731                 if(head != ignore)// && head.netname != "")
 732                 {
 733                         value = PlayerValue(head);
 734                         if(clienttype(head) == CLIENTTYPE_BOT)
 735                                 bvalue = value;
 736                         else
 737                                 bvalue = 0;
 738                         if(head.team == COLOR_TEAM1)
 739                         {
 740                                 if(c1 >= 0)
 741                                 {
 742                                         c1 = c1 + value;
 743                                         cb1 = cb1 + bvalue;
 744                                 }
 745                         }
 746                         if(head.team == COLOR_TEAM2)
 747                         {
 748                                 if(c2 >= 0)
 749                                 {
 750                                         c2 = c2 + value;
 751                                         cb2 = cb2 + bvalue;
 752                                 }
 753                         }
 754                         if(head.team == COLOR_TEAM3)
 755                         {
 756                                 if(c3 >= 0)
 757                                 {
 758                                         c3 = c3 + value;
 759                                         cb3 = cb3 + bvalue;
 760                                 }
 761                         }
 762                         if(head.team == COLOR_TEAM4)
 763                         {
 764                                 if(c4 >= 0)
 765                                 {
 766                                         c4 = c4 + value;
 767                                         cb4 = cb4 + bvalue;
 768                                 }
 769                         }
 770                 }
 771         }
 772 }
 773
 774 // returns # of smallest team (1, 2, 3, 4)
 775 // NOTE: Assumes CheckAllowedTeams has already been called!
 776 float FindSmallestTeam(entity pl, float ignore_pl)
 777 {
 778         float totalteams, balance_type, maxc;
 779         totalteams = 0;
 780
 781         // find out what teams are available
 782         //CheckAllowedTeams();
 783
 784         // make sure there are at least 2 teams to join
 785         if(c1 >= 0)
 786                 totalteams = totalteams + 1;
 787         if(c2 >= 0)
 788                 totalteams = totalteams + 1;
 789         if(c3 >= 0)
 790                 totalteams = totalteams + 1;
 791         if(c4 >= 0)
 792                 totalteams = totalteams + 1;
 793
 794         if(cvar("bot_vs_human"))
 795                 totalteams += 1;
 796
 797         if(totalteams <= 1)
 798         {
 799                 if(g_domination)
 800                         error("Too few teams available for domination\n");
 801                 else if(g_ctf)
 802                         error("Too few teams available for ctf\n");
 803                 else if(g_keyhunt)
 804                         error("Too few teams available for key hunt\n");
 805                 else
 806                         error("Too few teams available for team deathmatch\n");
 807         }
 808
 809         // count how many players are in each team
 810         if(ignore_pl)
 811                 GetTeamCounts(pl);
 812         else
 813                 GetTeamCounts(world);
 814
 815         // c1...c4 now have counts of each team
 816         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 817
 818         // 2 gives priority to what team you're already on, 1 goes in order
 819         // 2 doesn't seem to work though...
 820         balance_type = 1;
 821
 822         if(bots_would_leave)
 823         //if(pl.classname != "player")
 824         if(clienttype(pl) != CLIENTTYPE_BOT)
 825         {
 826                 c1 -= cb1 * 255.0/256.0;
 827                 c2 -= cb2 * 255.0/256.0;
 828                 c3 -= cb3 * 255.0/256.0;
 829                 c4 -= cb4 * 255.0/256.0;
 830         }
 831         maxc = max4(c1, c2, c3, c4);
 832
 833         RandomSelection_Init();
 834         if(balance_type == 1)
 835         {
 836                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 837                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 838                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 839                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 840                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 841         }
 842         else if(balance_type == 2)
 843         {
 844                 // 1: use team count, if equal prefer own team
 845                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 846                 if(c2 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 847                 if(c3 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 848                 if(c4 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 849         }
 850         else if(balance_type == 3)
 851         {
 852                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 853                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 854                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 855                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 856                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 857         }
 858         return RandomSelection_chosen_float;
 859 }
 860
 861 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 862 {
 863         float smallest, selectedteam;
 864
 865         // don't join a team if we're not playing a team game
 866         if(!teams_matter)
 867                 return 0;
 868
 869         // find out what teams are available
 870         CheckAllowedTeams(pl);
 871
 872         // if we don't care what team he ends up on, put him on whatever team he entered as.
 873         // if he's not on a valid team, then let other code put him on the smallest team
 874         if(!forcebestteam)
 875         {
 876                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 877                         selectedteam = pl.team;
 878                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 879                         selectedteam = pl.team;
 880                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 881                         selectedteam = pl.team;
 882                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 883                         selectedteam = pl.team;
 884                 else
 885                         selectedteam = -1;
 886
 887                 if(selectedteam > 0)
 888                 {
 889                         if(!only_return_best)
 890                         {
 891                                 SetPlayerColors(pl, selectedteam - 1);
 892
 893                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 894                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 895                                 LogTeamchange(pl.playerid, pl.team, 99);
 896                         }
 897                         return selectedteam;
 898                 }
 899                 // otherwise end up on the smallest team (handled below)
 900         }
 901
 902         smallest = FindSmallestTeam(pl, TRUE);
 903
 904         if(!only_return_best)
 905         {
 906                 TeamchangeFrags(self);
 907                 if(smallest == 1)
 908                 {
 909                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 910                 }
 911                 else if(smallest == 2)
 912                 {
 913                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 914                 }
 915                 else if(smallest == 3)
 916                 {
 917                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 918                 }
 919                 else if(smallest == 4)
 920                 {
 921                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 922                 }
 923                 else
 924                 {
 925                         error("smallest team: invalid team\n");
 926                 }
 927
 928                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 929
 930                 if(pl.deadflag == DEAD_NO)
 931                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 932         }
 933
 934         return smallest;
 935 }
 936
 937 //void() ctf_playerchanged;
 938 void SV_ChangeTeam(float _color)
 939 {
 940         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 941
 942         // in normal deathmatch we can just apply the color and we're done
 943         if(!teams_matter) {
 944                 SetPlayerColors(self, _color);
 945                 return;
 946         }
 947
 948         scolor = self.clientcolors & 0x0F;
 949         dcolor = _color & 0x0F;
 950
 951         if(scolor == COLOR_TEAM1 - 1)
 952                 steam = 1;
 953         else if(scolor == COLOR_TEAM2 - 1)
 954                 steam = 2;
 955         else if(scolor == COLOR_TEAM3 - 1)
 956                 steam = 3;
 957         else // if(scolor == COLOR_TEAM4 - 1)
 958                 steam = 4;
 959         if(dcolor == COLOR_TEAM1 - 1)
 960                 dteam = 1;
 961         else if(dcolor == COLOR_TEAM2 - 1)
 962                 dteam = 2;
 963         else if(dcolor == COLOR_TEAM3 - 1)
 964                 dteam = 3;
 965         else // if(dcolor == COLOR_TEAM4 - 1)
 966                 dteam = 4;
 967
 968         CheckAllowedTeams(self);
 969
 970         if(dteam == 1 && c1 < 0) dteam = 4;
 971         if(dteam == 4 && c4 < 0) dteam = 3;
 972         if(dteam == 3 && c3 < 0) dteam = 2;
 973         if(dteam == 2 && c2 < 0) dteam = 1;
 974
 975         // not changing teams
 976         if(scolor == dcolor)
 977         {
 978                 //bprint("same team change\n");
 979                 SetPlayerTeam(self, dteam, steam, TRUE);
 980                 return;
 981         }
 982
 983         if((cvar("g_campaign")) || (cvar("g_changeteam_banned") && self.wasplayer)) {
 984                 sprint(self, "Team changes not allowed\n");
 985                 return; // changing teams is not allowed
 986         }
 987
 988         if(cvar("g_balance_teams_prevent_imbalance"))
 989         {
 990                 // only allow changing to a smaller or equal size team
 991
 992                 // find out what teams are available
 993                 //CheckAllowedTeams();
 994                 // count how many players on each team
 995                 GetTeamCounts(world);
 996
 997                 // get desired team
 998                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 999                 {
1000                         dcount = c1;
1001                         dbotcount = cb1;
1002                 }
1003                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1004                 {
1005                         dcount = c2;
1006                         dbotcount = cb2;
1007                 }
1008                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1009                 {
1010                         dcount = c3;
1011                         dbotcount = cb3;
1012                 }
1013                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1014                 {
1015                         dcount = c4;
1016                         dbotcount = cb4;
1017                 }
1018                 else
1019                 {
1020                         sprint(self, "Cannot change to an invalid team\n");
1021
1022                         return;
1023                 }
1024
1025                 // get starting team
1026                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1027                         scount = c1;
1028                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1029                         scount = c2;
1030                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1031                         scount = c3;
1032                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1033                         scount = c4;
1034
1035                 if(scount) // started at a valid, nonempty team
1036                 {
1037                         // check if we're trying to change to a larger team that doens't have bots to swap with
1038                         if(dcount >= scount && dbotcount <= 0)
1039                         {
1040                                 sprint(self, "Cannot change to a larger team\n");
1041                                 return; // can't change to a larger team
1042                         }
1043                 }
1044         }
1045
1046 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1047
1048         if(self.classname == "player" && steam != dteam)
1049         {
1050                 // reduce frags during a team change
1051                 TeamchangeFrags(self);
1052         }
1053
1054         SetPlayerTeam(self, dteam, steam, FALSE);
1055
1056         if(self.classname == "player" && steam != dteam)
1057         {
1058                 // kill player when changing teams
1059                 if(self.deadflag == DEAD_NO)
1060                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1061         }
1062         //ctf_playerchanged();
1063 }
1064
1065 void ShufflePlayerOutOfTeam (float source_team)
1066 {
1067         float smallestteam, smallestteam_count, steam;
1068         float lowest_bot_score, lowest_player_score;
1069         entity head, lowest_bot, lowest_player, selected;
1070
1071         smallestteam = 0;
1072         smallestteam_count = 999999999;
1073
1074         if(c1 >= 0 && c1 < smallestteam_count)
1075         {
1076                 smallestteam = 1;
1077                 smallestteam_count = c1;
1078         }
1079         if(c2 >= 0 && c2 < smallestteam_count)
1080         {
1081                 smallestteam = 2;
1082                 smallestteam_count = c2;
1083         }
1084         if(c3 >= 0 && c3 < smallestteam_count)
1085         {
1086                 smallestteam = 3;
1087                 smallestteam_count = c3;
1088         }
1089         if(c4 >= 0 && c4 < smallestteam_count)
1090         {
1091                 smallestteam = 4;
1092                 smallestteam_count = c4;
1093         }
1094
1095         if(!smallestteam)
1096         {
1097                 bprint("warning: no smallest team\n");
1098                 return;
1099         }
1100
1101         if(source_team == 1)
1102                 steam = COLOR_TEAM1;
1103         else if(source_team == 2)
1104                 steam = COLOR_TEAM2;
1105         else if(source_team == 3)
1106                 steam = COLOR_TEAM3;
1107         else if(source_team == 4)
1108                 steam = COLOR_TEAM4;
1109
1110         lowest_bot = world;
1111         lowest_bot_score = 999999999;
1112         lowest_player = world;
1113         lowest_player_score = 999999999;
1114
1115         // find the lowest-scoring player & bot of that team
1116         FOR_EACH_PLAYER(head)
1117         {
1118                 if(head.team == steam)
1119                 {
1120                         if(head.isbot)
1121                         {
1122                                 if(head.totalfrags < lowest_bot_score)
1123                                 {
1124                                         lowest_bot = head;
1125                                         lowest_bot_score = head.totalfrags;
1126                                 }
1127                         }
1128                         else
1129                         {
1130                                 if(head.totalfrags < lowest_player_score)
1131                                 {
1132                                         lowest_player = head;
1133                                         lowest_player_score = head.totalfrags;
1134                                 }
1135                         }
1136                 }
1137         }
1138
1139         // prefers to move a bot...
1140         if(lowest_bot != world)
1141                 selected = lowest_bot;
1142         // but it will move a player if it has to
1143         else
1144                 selected = lowest_player;
1145         // don't do anything if it couldn't find anyone
1146         if(!selected)
1147         {
1148                 bprint("warning: couldn't find a player to move from team\n");
1149                 return;
1150         }
1151
1152         // smallest team gains a member
1153         if(smallestteam == 1)
1154         {
1155                 c1 = c1 + 1;
1156         }
1157         else if(smallestteam == 2)
1158         {
1159                 c2 = c2 + 1;
1160         }
1161         else if(smallestteam == 3)
1162         {
1163                 c3 = c3 + 1;
1164         }
1165         else if(smallestteam == 4)
1166         {
1167                 c4 = c4 + 1;
1168         }
1169         else
1170         {
1171                 bprint("warning: destination team invalid\n");
1172                 return;
1173         }
1174         // source team loses a member
1175         if(source_team == 1)
1176         {
1177                 c1 = c1 + 1;
1178         }
1179         else if(source_team == 2)
1180         {
1181                 c2 = c2 + 2;
1182         }
1183         else if(source_team == 3)
1184         {
1185                 c3 = c3 + 3;
1186         }
1187         else if(source_team == 4)
1188         {
1189                 c4 = c4 + 4;
1190         }
1191         else
1192         {
1193                 bprint("warning: source team invalid\n");
1194                 return;
1195         }
1196
1197         // move the player to the new team
1198         TeamchangeFrags(selected);
1199         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1200
1201         if(selected.deadflag == DEAD_NO)
1202                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1203         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1204 }
1205
1206 void CauseRebalance(float source_team, float howmany_toomany)
1207 {
1208         if(IsTeamBalanceForced() == 1)
1209         {
1210                 bprint("Rebalancing Teams\n");
1211                 ShufflePlayerOutOfTeam(source_team);
1212         }
1213 }
1214
1215 // part of g_balance_teams_force
1216 // occasionally perform an audit of the teams to make
1217 // sure they're more or less balanced in player count.
1218 void AuditTeams()
1219 {
1220         float numplayers, numteams, smallest, toomany;
1221         float balance;
1222         balance = IsTeamBalanceForced();
1223         if(balance == 0)
1224                 return;
1225
1226         if(audit_teams_time > time)
1227                 return;
1228
1229         audit_teams_time = time + 4 + random();
1230
1231 //      bprint("Auditing teams\n");
1232
1233         CheckAllowedTeams(world);
1234         GetTeamCounts(world);
1235
1236
1237         numteams = numplayers = smallest = 0;
1238         if(c1 >= 0)
1239         {
1240                 numteams = numteams + 1;
1241                 numplayers = numplayers + c1;
1242                 smallest = c1;
1243         }
1244         if(c2 >= 0)
1245         {
1246                 numteams = numteams + 1;
1247                 numplayers = numplayers + c2;
1248                 if(c2 < smallest)
1249                         smallest = c2;
1250         }
1251         if(c3 >= 0)
1252         {
1253                 numteams = numteams + 1;
1254                 numplayers = numplayers + c3;
1255                 if(c3 < smallest)
1256                         smallest = c3;
1257         }
1258         if(c4 >= 0)
1259         {
1260                 numteams = numteams + 1;
1261                 numplayers = numplayers + c4;
1262                 if(c4 < smallest)
1263                         smallest = c4;
1264         }
1265
1266         if(numplayers <= 0)
1267                 return; // no players to move around
1268         if(numteams < 2)
1269                 return; // don't bother shuffling if for some reason there aren't any teams
1270
1271         toomany = smallest + 1;
1272
1273         if(c1 && c1 > toomany)
1274                 CauseRebalance(1, c1 - toomany);
1275         if(c2 && c2 > toomany)
1276                 CauseRebalance(2, c2 - toomany);
1277         if(c3 && c3 > toomany)
1278                 CauseRebalance(3, c3 - toomany);
1279         if(c4 && c4 > toomany)
1280                 CauseRebalance(4, c4 - toomany);
1281
1282         // if teams are still unbalanced, balance them further in the next audit,
1283         // which will happen sooner (keep doing rapid audits until things are in order)
1284         audit_teams_time = time + 0.7 + random()*0.3;
1285 }
1286
1287 // code from here on is just to support maps that don't have team entities
1288 void tdm_spawnteam (string teamname, float teamcolor)
1289 {
1290         local entity e;
1291         e = spawn();
1292         e.classname = "tdm_team";
1293         e.netname = teamname;
1294         e.cnt = teamcolor;
1295         e.team = e.cnt + 1;
1296 };
1297
1298 // spawn some default teams if the map is not set up for tdm
1299 void tdm_spawnteams()
1300 {
1301         float numteams;
1302
1303         numteams = cvar("g_tdm_teams_override");
1304         if(numteams < 2)
1305                 numteams = cvar("g_tdm_teams");
1306         numteams = bound(2, numteams, 4);
1307
1308         tdm_spawnteam("Red", COLOR_TEAM1-1);
1309         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1310         if(numteams >= 3)
1311                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1312         if(numteams >= 4)
1313                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1314 };
1315
1316 void tdm_delayedinit()
1317 {
1318         // if no teams are found, spawn defaults
1319         if (find(world, classname, "tdm_team") == world)
1320                 tdm_spawnteams();
1321 };
1322
1323 void tdm_init()
1324 {
1325         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1326 };