0654d3efdbec0bfab351cabb57afe257a24d150c
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / teamplay.qc
1 string cache_mutatormsg;
2 string cache_lastmutatormsg;
3
4 // client counts for each team
5 float c1, c2, c3, c4;
6 // # of bots on those teams
7 float cb1, cb2, cb3, cb4;
8
9 //float audit_teams_time;
10
11 void TeamchangeFrags(entity e)
12 {
13         PlayerScore_Clear(e);
14 }
15
16 void entcs_init();
17
18 void LogTeamchange(float player_id, float team_number, float type)
19 {
20         if(!autocvar_sv_eventlog)
21                 return;
22
23         if(player_id < 1)
24                 return;
25
26         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
27 }
28
29 void default_delayedinit()
30 {
31         if(!scores_initialized)
32                 ScoreRules_generic();
33 }
34
35 void ActivateTeamplay()
36 {
37         serverflags |= SERVERFLAG_TEAMPLAY;
38         teamplay = 1;
39 }
40
41 void InitGameplayMode()
42 {
43         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
44
45         qualifying_override = -1;
46
47         VoteReset();
48
49         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
50         get_mi_min_max(1);
51         world.mins = mi_min;
52         world.maxs = mi_max;
53
54         MapInfo_LoadMapSettings(mapname);
55         teamplay = 0;
56         serverflags &= ~SERVERFLAG_TEAMPLAY;
57
58         if (!cvar_value_issafe(world.fog))
59         {
60                 print("The current map contains a potentially harmful fog setting, ignored\n");
61                 world.fog = string_null;
62         }
63         if(MapInfo_Map_fog != "")
64                 if(MapInfo_Map_fog == "none")
65                         world.fog = string_null;
66                 else
67                         world.fog = strzone(MapInfo_Map_fog);
68         clientstuff = strzone(MapInfo_Map_clientstuff);
69
70         MapInfo_ClearTemps();
71
72         // set both here, gamemode can override it later
73         timelimit_override = autocvar_timelimit_override;
74         fraglimit_override = autocvar_fraglimit_override;
75         leadlimit_override = autocvar_leadlimit_override;
76         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
77
78         if(g_dm)
79         {
80         }
81
82         if(g_tdm)
83         {
84                 ActivateTeamplay();
85                 fraglimit_override = autocvar_g_tdm_point_limit;
86                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
87                 if(autocvar_g_tdm_team_spawns)
88                         have_team_spawns = -1; // request team spawns
89                 MUTATOR_ADD(gamemode_tdm);
90         }
91
92         if(g_domination)
93         {
94                 ActivateTeamplay();
95                 fraglimit_override = autocvar_g_domination_point_limit;
96                 leadlimit_override = autocvar_g_domination_point_leadlimit;
97                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
98                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
99                 have_team_spawns = -1; // request team spawns
100                 MUTATOR_ADD(gamemode_domination);
101         }
102
103         if(g_ctf)
104         {
105                 ActivateTeamplay();
106                 fraglimit_override = autocvar_capturelimit_override;
107                 leadlimit_override = autocvar_captureleadlimit_override;
108                 have_team_spawns = -1; // request team spawns
109                 MUTATOR_ADD(gamemode_ctf);
110         }
111
112         if(g_lms)
113         {
114                 fraglimit_override = autocvar_g_lms_lives_override;
115                 leadlimit_override = 0; // not supported by LMS
116                 if(fraglimit_override == 0)
117                         fraglimit_override = -1;
118                 MUTATOR_ADD(gamemode_lms);
119         }
120
121         if(g_ca)
122         {
123                 ActivateTeamplay();
124                 fraglimit_override = autocvar_g_ca_point_limit;
125                 leadlimit_override = autocvar_g_ca_point_leadlimit;
126                 if(autocvar_g_ca_team_spawns)
127                         have_team_spawns = -1; // request team spawns
128                 MUTATOR_ADD(gamemode_ca);
129         }
130
131         if(g_keyhunt)
132         {
133                 ActivateTeamplay();
134                 fraglimit_override = autocvar_g_keyhunt_point_limit;
135                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
136                 MUTATOR_ADD(gamemode_keyhunt);
137         }
138
139         if(g_freezetag)
140         {
141                 ActivateTeamplay();
142                 fraglimit_override = autocvar_g_freezetag_point_limit;
143                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
144                 if(autocvar_g_freezetag_team_spawns)
145                         have_team_spawns = -1; // request team spawns
146                 MUTATOR_ADD(gamemode_freezetag);
147         }
148
149         if(g_assault)
150         {
151                 ActivateTeamplay();
152                 have_team_spawns = -1; // request team spawns
153                 MUTATOR_ADD(gamemode_assault);
154         }
155
156         if(g_onslaught)
157         {
158                 ActivateTeamplay();
159                 have_team_spawns = -1; // request team spawns
160                 MUTATOR_ADD(gamemode_onslaught);
161         }
162
163         if(g_race)
164         {
165                 if(autocvar_g_race_teams)
166                 {
167                         ActivateTeamplay();
168                         race_teams = bound(2, autocvar_g_race_teams, 4);
169                         have_team_spawns = -1; // request team spawns
170                 }
171                 else
172                         race_teams = 0;
173                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
174                 fraglimit_override = autocvar_g_race_laps_limit;
175                 leadlimit_override = 0; // currently not supported by race
176
177                 // we need to find out the correct value for g_race_qualifying
178                 float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
179
180                 if(autocvar_g_campaign)
181                 {
182                         g_race_qualifying = 1;
183                         independent_players = 1;
184                 }
185                 else if(!autocvar_g_campaign && want_qualifying)
186                 {
187                         g_race_qualifying = 2;
188                         independent_players = 1;
189                         race_fraglimit = (race_fraglimit >= 0) ? fraglimit_override : autocvar_fraglimit;
190                         race_leadlimit = (race_leadlimit >= 0) ? leadlimit_override : autocvar_leadlimit;
191                         race_timelimit = (race_timelimit >= 0) ? timelimit_override : autocvar_timelimit;
192                         fraglimit_override = 0;
193                         leadlimit_override = 0;
194                         timelimit_override = autocvar_g_race_qualifying_timelimit;
195                 }
196                 else
197                 {
198                         g_race_qualifying = 0;
199                 }
200
201                 MUTATOR_ADD(gamemode_race);
202         }
203
204         if(g_cts)
205         {
206                 g_race_qualifying = 1;
207                 fraglimit_override = 0;
208                 leadlimit_override = 0;
209                 independent_players = 1;
210                 MUTATOR_ADD(gamemode_cts);
211         }
212
213         if(g_nexball)
214         {
215                 fraglimit_override = autocvar_g_nexball_goallimit;
216                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
217                 ActivateTeamplay();
218                 have_team_spawns = -1; // request team spawns
219                 MUTATOR_ADD(gamemode_nexball);
220         }
221
222         if(g_keepaway)
223         {
224                 MUTATOR_ADD(gamemode_keepaway);
225         }
226
227         if(g_invasion)
228         {
229                 fraglimit_override = autocvar_g_invasion_point_limit;
230                 if(autocvar_g_invasion_teams >= 2)
231                 {
232                         ActivateTeamplay();
233                         if(autocvar_g_invasion_team_spawns)
234                                 have_team_spawns = -1; // request team spawns
235                 }
236                 MUTATOR_ADD(gamemode_invasion);
237         }
238
239         if(teamplay)
240                 entcs_init();
241
242         cache_mutatormsg = strzone("");
243         cache_lastmutatormsg = strzone("");
244
245         // enforce the server's universal frag/time limits
246         if(!autocvar_g_campaign)
247         {
248                 if(fraglimit_override >= 0)
249                         cvar_set("fraglimit", ftos(fraglimit_override));
250                 if(timelimit_override >= 0)
251                         cvar_set("timelimit", ftos(timelimit_override));
252                 if(leadlimit_override >= 0)
253                         cvar_set("leadlimit", ftos(leadlimit_override));
254                 if(qualifying_override >= 0)
255                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
256         }
257
258         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
259 }
260
261 string GetClientVersionMessage() {
262         string versionmsg;
263         if (self.version_mismatch) {
264                 if(self.version < autocvar_gameversion) {
265                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
266                 } else {
267                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
268                 }
269         } else {
270                 versionmsg = "^2client version and server version are compatible.^8";
271         }
272         return versionmsg;
273 }
274
275 string getwelcomemessage(void)
276 {
277         string s, modifications, motd;
278
279         ret_string = "";
280         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
281         modifications = ret_string;
282
283         if(g_weaponarena)
284         {
285                 if(g_weaponarena_random)
286                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
287                 else
288                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
289         }
290         if(cvar("g_balance_blaster_weaponstart") == 0)
291                 modifications = strcat(modifications, ", No start weapons");
292         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
293                 modifications = strcat(modifications, ", Low gravity");
294         if(g_cloaked && !g_cts)
295                 modifications = strcat(modifications, ", Cloaked");
296         if(g_grappling_hook)
297                 modifications = strcat(modifications, ", Hook");
298         if(g_weapon_stay && !g_cts)
299                 modifications = strcat(modifications, ", Weapons stay");
300         if(g_jetpack)
301                 modifications = strcat(modifications, ", Jet pack");
302         if(autocvar_g_powerups == 0)
303                 modifications = strcat(modifications, ", No powerups");
304         if(autocvar_g_powerups > 0)
305                 modifications = strcat(modifications, ", Powerups");
306         modifications = substring(modifications, 2, strlen(modifications) - 2);
307
308         string versionmessage;
309         versionmessage = GetClientVersionMessage();
310
311         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
312         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
313
314         if(modifications != "")
315                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
316
317         if (g_grappling_hook)
318                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
319
320         if (cvar("g_nades"))
321                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
322
323         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
324         {
325                 if(cache_lastmutatormsg)
326                         strunzone(cache_lastmutatormsg);
327                 if(cache_mutatormsg)
328                         strunzone(cache_mutatormsg);
329                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
330                 cache_mutatormsg = strzone(cache_lastmutatormsg);
331         }
332
333         if (cache_mutatormsg != "") {
334                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
335         }
336
337         motd = autocvar_sv_motd;
338         if (motd != "") {
339                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
340         }
341         return s;
342 }
343
344 void SetPlayerColors(entity pl, float _color)
345 {
346         /*string s;
347         s = ftos(cl);
348         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
349         pl.team = cl + 1;
350         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
351         pl.clientcolors = 16*cl + cl;*/
352
353         float pants, shirt;
354         pants = _color & 0x0F;
355         shirt = _color & 0xF0;
356
357
358         if(teamplay) {
359                 setcolor(pl, 16*pants + pants);
360         } else {
361                 setcolor(pl, shirt + pants);
362         }
363 }
364
365 void SetPlayerTeam(entity pl, float t, float s, float noprint)
366 {
367         float _color;
368
369         if(t == 4)
370                 _color = NUM_TEAM_4 - 1;
371         else if(t == 3)
372                 _color = NUM_TEAM_3 - 1;
373         else if(t == 2)
374                 _color = NUM_TEAM_2 - 1;
375         else
376                 _color = NUM_TEAM_1 - 1;
377
378         SetPlayerColors(pl,_color);
379
380         if(t != s) {
381                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
382
383                 if(!noprint)
384                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
385         }
386
387 }
388
389 // set c1...c4 to show what teams are allowed
390 void CheckAllowedTeams (entity for_whom)
391 {
392         float dm;
393         entity head;
394         string teament_name;
395
396         c1 = c2 = c3 = c4 = -1;
397         cb1 = cb2 = cb3 = cb4 = 0;
398
399         teament_name = string_null;
400         if(g_onslaught)
401         {
402                 // onslaught is special
403                 head = findchain(classname, "onslaught_generator");
404                 while (head)
405                 {
406                         if (head.team == NUM_TEAM_1) c1 = 0;
407                         if (head.team == NUM_TEAM_2) c2 = 0;
408                         if (head.team == NUM_TEAM_3) c3 = 0;
409                         if (head.team == NUM_TEAM_4) c4 = 0;
410                         head = head.chain;
411                 }
412         }
413         else if(g_domination)
414                 teament_name = "dom_team";
415         else if(g_ctf)
416                 teament_name = "ctf_team";
417         else if(g_tdm)
418                 teament_name = "tdm_team";
419         else if(g_nexball)
420                 teament_name = "nexball_team";
421         else if(g_assault)
422                 c1 = c2 = 0; // Assault always has 2 teams
423         else
424         {
425                 // cover anything else by treating it like tdm with no teams spawned
426                 dm = 2;
427
428                 ret_float = dm;
429                 MUTATOR_CALLHOOK(GetTeamCount);
430                 dm = ret_float;
431
432                 if(dm >= 4)
433                         c1 = c2 = c3 = c4 = 0;
434                 else if(dm >= 3)
435                         c1 = c2 = c3 = 0;
436                 else
437                         c1 = c2 = 0;
438         }
439
440         // find out what teams are allowed if necessary
441         if(teament_name)
442         {
443                 head = find(world, classname, teament_name);
444                 while(head)
445                 {
446                         if(!(g_domination && head.netname == ""))
447                         {
448                                 if(head.team == NUM_TEAM_1)
449                                         c1 = 0;
450                                 else if(head.team == NUM_TEAM_2)
451                                         c2 = 0;
452                                 else if(head.team == NUM_TEAM_3)
453                                         c3 = 0;
454                                 else if(head.team == NUM_TEAM_4)
455                                         c4 = 0;
456                         }
457                         head = find(head, classname, teament_name);
458                 }
459         }
460
461         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
462         if(c3==-1 && c4==-1)
463         if(autocvar_bot_vs_human && for_whom)
464         {
465                 if(autocvar_bot_vs_human > 0)
466                 {
467                         // bots are all blue
468                         if(IS_BOT_CLIENT(for_whom))
469                                 c1 = c3 = c4 = -1;
470                         else
471                                 c2 = -1;
472                 }
473                 else
474                 {
475                         // bots are all red
476                         if(IS_BOT_CLIENT(for_whom))
477                                 c2 = c3 = c4 = -1;
478                         else
479                                 c1 = -1;
480                 }
481         }
482
483         // if player has a forced team, ONLY allow that one
484         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
485                 c2 = c3 = c4 = -1;
486         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
487                 c1 = c3 = c4 = -1;
488         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
489                 c1 = c2 = c4 = -1;
490         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
491                 c1 = c2 = c3 = -1;
492 }
493
494 float PlayerValue(entity p)
495 {
496         return 1;
497         // FIXME: it always returns 1...
498 }
499
500 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
501 // teams that are allowed will now have their player counts stored in c1...c4
502 void GetTeamCounts(entity ignore)
503 {
504         entity head;
505         float value, bvalue;
506         // now count how many players are on each team already
507
508         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
509         // also remember the lowest-scoring player
510
511         FOR_EACH_CLIENT(head)
512         {
513                 float t;
514                 if(IS_PLAYER(head) || head.caplayer)
515                         t = head.team;
516                 else if(head.team_forced > 0)
517                         t = head.team_forced; // reserve the spot
518                 else
519                         continue;
520                 if(head != ignore)// && head.netname != "")
521                 {
522                         value = PlayerValue(head);
523                         if(IS_BOT_CLIENT(head))
524                                 bvalue = value;
525                         else
526                                 bvalue = 0;
527                         if(t == NUM_TEAM_1)
528                         {
529                                 if(c1 >= 0)
530                                 {
531                                         c1 = c1 + value;
532                                         cb1 = cb1 + bvalue;
533                                 }
534                         }
535                         if(t == NUM_TEAM_2)
536                         {
537                                 if(c2 >= 0)
538                                 {
539                                         c2 = c2 + value;
540                                         cb2 = cb2 + bvalue;
541                                 }
542                         }
543                         if(t == NUM_TEAM_3)
544                         {
545                                 if(c3 >= 0)
546                                 {
547                                         c3 = c3 + value;
548                                         cb3 = cb3 + bvalue;
549                                 }
550                         }
551                         if(t == NUM_TEAM_4)
552                         {
553                                 if(c4 >= 0)
554                                 {
555                                         c4 = c4 + value;
556                                         cb4 = cb4 + bvalue;
557                                 }
558                         }
559                 }
560         }
561
562         // if the player who has a forced team has not joined yet, reserve the spot
563         if(autocvar_g_campaign)
564         {
565                 switch(autocvar_g_campaign_forceteam)
566                 {
567                         case 1: if(c1 == cb1) ++c1; break;
568                         case 2: if(c2 == cb2) ++c2; break;
569                         case 3: if(c3 == cb3) ++c3; break;
570                         case 4: if(c4 == cb4) ++c4; break;
571                 }
572         }
573 }
574
575 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
576 {
577         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
578         float f;
579         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
580
581         switch(ta)
582         {
583                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
584                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
585                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
586                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
587         }
588         switch(tb)
589         {
590                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
591                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
592                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
593                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
594         }
595
596         // invalid
597         if(ca < 0 || cb < 0)
598                 return false;
599
600         // equal
601         if(ta == tb)
602                 return true;
603
604         if(IS_REAL_CLIENT(e))
605         {
606                 if(bots_would_leave)
607                 {
608                         ca -= cba * 0.999;
609                         cb -= cbb * 0.999;
610                 }
611         }
612
613         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
614         if(ca < 1)
615                 if(cb >= 1)
616                         return true;
617         if(ca >= 1)
618                 if(cb < 1)
619                         return false;
620
621         // first, normalize
622         f = max(ca, cb, 1);
623         ca /= f;
624         cb /= f;
625         f = max(sa, sb, 1);
626         sa /= f;
627         sb /= f;
628
629         // the more we're at the end of the match, the more take scores into account
630         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
631         ca += (sa - ca) * f;
632         cb += (sb - cb) * f;
633
634         return ca <= cb;
635 }
636
637 // returns # of smallest team (1, 2, 3, 4)
638 // NOTE: Assumes CheckAllowedTeams has already been called!
639 float FindSmallestTeam(entity pl, float ignore_pl)
640 {
641         float totalteams, t;
642         totalteams = 0;
643
644         // find out what teams are available
645         //CheckAllowedTeams();
646
647         // make sure there are at least 2 teams to join
648         if(c1 >= 0)
649                 totalteams = totalteams + 1;
650         if(c2 >= 0)
651                 totalteams = totalteams + 1;
652         if(c3 >= 0)
653                 totalteams = totalteams + 1;
654         if(c4 >= 0)
655                 totalteams = totalteams + 1;
656
657         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
658                 totalteams += 1;
659
660         if(totalteams <= 1)
661         {
662                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
663                         return 1; // special case for campaign and player joining
664                 else
665                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
666         }
667
668         // count how many players are in each team
669         if(ignore_pl)
670                 GetTeamCounts(pl);
671         else
672                 GetTeamCounts(world);
673
674         RandomSelection_Init();
675
676         t = 1;
677         if(TeamSmallerEqThanTeam(2, t, pl))
678                 t = 2;
679         if(TeamSmallerEqThanTeam(3, t, pl))
680                 t = 3;
681         if(TeamSmallerEqThanTeam(4, t, pl))
682                 t = 4;
683
684         // now t is the minimum, or A minimum!
685         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
686                 RandomSelection_Add(world, 1, string_null, 1, 1);
687         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
688                 RandomSelection_Add(world, 2, string_null, 1, 1);
689         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
690                 RandomSelection_Add(world, 3, string_null, 1, 1);
691         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
692                 RandomSelection_Add(world, 4, string_null, 1, 1);
693
694         return RandomSelection_chosen_float;
695 }
696
697 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
698 {
699         float smallest, selectedteam;
700
701         // don't join a team if we're not playing a team game
702         if(!teamplay)
703                 return 0;
704
705         // find out what teams are available
706         CheckAllowedTeams(pl);
707
708         // if we don't care what team he ends up on, put him on whatever team he entered as.
709         // if he's not on a valid team, then let other code put him on the smallest team
710         if(!forcebestteam)
711         {
712                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
713                         selectedteam = pl.team;
714                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
715                         selectedteam = pl.team;
716                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
717                         selectedteam = pl.team;
718                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
719                         selectedteam = pl.team;
720                 else
721                         selectedteam = -1;
722
723                 if(selectedteam > 0)
724                 {
725                         if(!only_return_best)
726                         {
727                                 SetPlayerColors(pl, selectedteam - 1);
728
729                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
730                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
731                                 LogTeamchange(pl.playerid, pl.team, 99);
732                         }
733                         return selectedteam;
734                 }
735                 // otherwise end up on the smallest team (handled below)
736         }
737
738         smallest = FindSmallestTeam(pl, true);
739
740         if(!only_return_best && !pl.bot_forced_team)
741         {
742                 TeamchangeFrags(self);
743                 if(smallest == 1)
744                 {
745                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
746                 }
747                 else if(smallest == 2)
748                 {
749                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
750                 }
751                 else if(smallest == 3)
752                 {
753                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
754                 }
755                 else if(smallest == 4)
756                 {
757                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
758                 }
759                 else
760                 {
761                         error("smallest team: invalid team\n");
762                 }
763
764                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
765
766                 if(pl.deadflag == DEAD_NO)
767                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
768         }
769
770         return smallest;
771 }
772
773 //void() ctf_playerchanged;
774 void SV_ChangeTeam(float _color)
775 {
776         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
777
778         // in normal deathmatch we can just apply the color and we're done
779         if(!teamplay) {
780                 SetPlayerColors(self, _color);
781                 return;
782         }
783
784         scolor = self.clientcolors & 0x0F;
785         dcolor = _color & 0x0F;
786
787         if(scolor == NUM_TEAM_1 - 1)
788                 steam = 1;
789         else if(scolor == NUM_TEAM_2 - 1)
790                 steam = 2;
791         else if(scolor == NUM_TEAM_3 - 1)
792                 steam = 3;
793         else // if(scolor == NUM_TEAM_4 - 1)
794                 steam = 4;
795         if(dcolor == NUM_TEAM_1 - 1)
796                 dteam = 1;
797         else if(dcolor == NUM_TEAM_2 - 1)
798                 dteam = 2;
799         else if(dcolor == NUM_TEAM_3 - 1)
800                 dteam = 3;
801         else // if(dcolor == NUM_TEAM_4 - 1)
802                 dteam = 4;
803
804         CheckAllowedTeams(self);
805
806         if(dteam == 1 && c1 < 0) dteam = 4;
807         if(dteam == 4 && c4 < 0) dteam = 3;
808         if(dteam == 3 && c3 < 0) dteam = 2;
809         if(dteam == 2 && c2 < 0) dteam = 1;
810
811         // not changing teams
812         if(scolor == dcolor)
813         {
814                 //bprint("same team change\n");
815                 SetPlayerTeam(self, dteam, steam, true);
816                 return;
817         }
818
819         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
820                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
821                 return; // changing teams is not allowed
822         }
823
824         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
825         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
826         {
827                 GetTeamCounts(self);
828                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
829                 {
830                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
831                         return;
832                 }
833         }
834
835 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
836
837         if(IS_PLAYER(self) && steam != dteam)
838         {
839                 // reduce frags during a team change
840                 TeamchangeFrags(self);
841         }
842
843         SetPlayerTeam(self, dteam, steam, false);
844
845         if(IS_PLAYER(self) && steam != dteam)
846         {
847                 // kill player when changing teams
848                 if(self.deadflag == DEAD_NO)
849                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
850         }
851 }
852
853 void ShufflePlayerOutOfTeam (float source_team)
854 {
855         float smallestteam, smallestteam_count, steam;
856         float lowest_bot_score, lowest_player_score;
857         entity head, lowest_bot, lowest_player, selected;
858
859         smallestteam = 0;
860         smallestteam_count = 999999999;
861
862         if(c1 >= 0 && c1 < smallestteam_count)
863         {
864                 smallestteam = 1;
865                 smallestteam_count = c1;
866         }
867         if(c2 >= 0 && c2 < smallestteam_count)
868         {
869                 smallestteam = 2;
870                 smallestteam_count = c2;
871         }
872         if(c3 >= 0 && c3 < smallestteam_count)
873         {
874                 smallestteam = 3;
875                 smallestteam_count = c3;
876         }
877         if(c4 >= 0 && c4 < smallestteam_count)
878         {
879                 smallestteam = 4;
880                 smallestteam_count = c4;
881         }
882
883         if(!smallestteam)
884         {
885                 bprint("warning: no smallest team\n");
886                 return;
887         }
888
889         if(source_team == 1)
890                 steam = NUM_TEAM_1;
891         else if(source_team == 2)
892                 steam = NUM_TEAM_2;
893         else if(source_team == 3)
894                 steam = NUM_TEAM_3;
895         else // if(source_team == 4)
896                 steam = NUM_TEAM_4;
897
898         lowest_bot = world;
899         lowest_bot_score = 999999999;
900         lowest_player = world;
901         lowest_player_score = 999999999;
902
903         // find the lowest-scoring player & bot of that team
904         FOR_EACH_PLAYER(head)
905         {
906                 if(head.team == steam)
907                 {
908                         if(head.isbot)
909                         {
910                                 if(head.totalfrags < lowest_bot_score)
911                                 {
912                                         lowest_bot = head;
913                                         lowest_bot_score = head.totalfrags;
914                                 }
915                         }
916                         else
917                         {
918                                 if(head.totalfrags < lowest_player_score)
919                                 {
920                                         lowest_player = head;
921                                         lowest_player_score = head.totalfrags;
922                                 }
923                         }
924                 }
925         }
926
927         // prefers to move a bot...
928         if(lowest_bot != world)
929                 selected = lowest_bot;
930         // but it will move a player if it has to
931         else
932                 selected = lowest_player;
933         // don't do anything if it couldn't find anyone
934         if(!selected)
935         {
936                 bprint("warning: couldn't find a player to move from team\n");
937                 return;
938         }
939
940         // smallest team gains a member
941         if(smallestteam == 1)
942         {
943                 c1 = c1 + 1;
944         }
945         else if(smallestteam == 2)
946         {
947                 c2 = c2 + 1;
948         }
949         else if(smallestteam == 3)
950         {
951                 c3 = c3 + 1;
952         }
953         else if(smallestteam == 4)
954         {
955                 c4 = c4 + 1;
956         }
957         else
958         {
959                 bprint("warning: destination team invalid\n");
960                 return;
961         }
962         // source team loses a member
963         if(source_team == 1)
964         {
965                 c1 = c1 + 1;
966         }
967         else if(source_team == 2)
968         {
969                 c2 = c2 + 2;
970         }
971         else if(source_team == 3)
972         {
973                 c3 = c3 + 3;
974         }
975         else if(source_team == 4)
976         {
977                 c4 = c4 + 4;
978         }
979         else
980         {
981                 bprint("warning: source team invalid\n");
982                 return;
983         }
984
985         // move the player to the new team
986         TeamchangeFrags(selected);
987         SetPlayerTeam(selected, smallestteam, source_team, false);
988
989         if(selected.deadflag == DEAD_NO)
990                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
991         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
992 }