qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void nb_init();
  75 void entcs_init();
  76
  77 void LogTeamchange(float player_id, float team_number, float type)
  78 {
  79         if(!autocvar_sv_eventlog)
  80                 return;
  81
  82         if(player_id < 1)
  83                 return;
  84
  85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  86 }
  87
  88 void WriteGameCvars()
  89 {
  90         cvar_set("g_dm", ftos(g_dm));
  91         cvar_set("g_tdm", ftos(g_tdm));
  92         cvar_set("g_domination", ftos(g_domination));
  93         cvar_set("g_ctf", ftos(g_ctf));
  94         cvar_set("g_runematch", ftos(g_runematch));
  95         cvar_set("g_lms", ftos(g_lms));
  96         cvar_set("g_arena", ftos(g_arena));
  97         cvar_set("g_ca", ftos(g_ca));
  98         cvar_set("g_keyhunt", ftos(g_keyhunt));
  99         cvar_set("g_assault", ftos(g_assault));
 100         cvar_set("g_onslaught", ftos(g_onslaught));
 101         cvar_set("g_race", ftos(g_race));
 102         cvar_set("g_nexball", ftos(g_nexball));
 103         cvar_set("g_cts", ftos(g_cts));
 104         cvar_set("g_freezetag", ftos(g_freezetag));
 105         cvar_set("g_keepaway", ftos(g_keepaway));
 106 }
 107
 108 void ReadGameCvars()
 109 {
 110         float found;
 111         float prev;
 112         float i;
 113
 114         found = 0;
 115         prev = autocvar_gamecfg;
 116         for(i = 0; i < 2; ++i)
 117         {
 118 //#NO AUTOCVARS START
 119                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 120                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 121                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 122                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 123                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 124                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 125                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 126                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 127                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 128                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 129                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 130                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 131                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 132                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 133                 found += (g_freezetag = (!found && (prev != GAME_FREEZETAG) && cvar("g_freezetag")));
 134                 found += (g_keepaway = (!found && (prev != GAME_KEEPAWAY) && cvar("g_keepaway")));
 135 //#NO AUTOCVARS END
 136
 137                 if(found)
 138                         break;
 139
 140                 prev = -1; // second attempt takes place WITHOUT prev set
 141         }
 142
 143         if(!found)
 144                 g_dm = 1;
 145
 146         if(g_dm && autocvar_deathmatch_force_teamplay)
 147         {
 148                 g_dm = 0;
 149                 g_tdm = 1;
 150         }
 151
 152         teams_matter = 0;
 153         serverflags &~= SERVERFLAG_TEAMPLAY;
 154 }
 155
 156 void default_delayedinit()
 157 {
 158         if(!scores_initialized)
 159                 ScoreRules_generic();
 160 }
 161
 162 void ActivateTeamplay()
 163 {
 164         serverflags |= SERVERFLAG_TEAMPLAY;
 165         teams_matter = 1;
 166 }
 167
 168 void InitGameplayMode()
 169 {
 170         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 171
 172         qualifying_override = -1;
 173
 174         VoteReset();
 175
 176         // make sure only ONE type is selected
 177         ReadGameCvars();
 178         WriteGameCvars();
 179
 180         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 181         get_mi_min_max(1);
 182         world.mins = mi_min;
 183         world.maxs = mi_max;
 184
 185         MapInfo_LoadMapSettings(mapname);
 186
 187         if not(cvar_value_issafe(world.fog))
 188         {
 189                 print("The current map contains a potentially harmful fog setting, ignored\n");
 190                 world.fog = string_null;
 191         }
 192         if(MapInfo_Map_fog != "")
 193                 if(MapInfo_Map_fog == "none")
 194                         world.fog = string_null;
 195                 else
 196                         world.fog = strzone(MapInfo_Map_fog);
 197         clientstuff = strzone(MapInfo_Map_clientstuff);
 198
 199         MapInfo_ClearTemps();
 200
 201         // in case mapinfo switched the type
 202         ReadGameCvars();
 203
 204         // set both here, gamemode can override it later
 205         timelimit_override = autocvar_timelimit_override;
 206         fraglimit_override = autocvar_fraglimit_override;
 207         leadlimit_override = autocvar_leadlimit_override;
 208
 209         if(g_dm)
 210         {
 211                 game = GAME_DEATHMATCH;
 212                 gamemode_name = "Deathmatch";
 213         }
 214
 215         if(g_tdm)
 216         {
 217                 game = GAME_TEAM_DEATHMATCH;
 218                 gamemode_name = "Team Deathmatch";
 219                 ActivateTeamplay();
 220                 tdm_init();
 221                 if(autocvar_g_tdm_team_spawns)
 222                         have_team_spawns = -1; // request team spawns
 223         }
 224
 225         if(g_domination)
 226         {
 227                 game = GAME_DOMINATION;
 228                 gamemode_name = "Domination";
 229                 ActivateTeamplay();
 230                 fraglimit_override = autocvar_g_domination_point_limit;
 231                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 232                 dom_init();
 233                 have_team_spawns = -1; // request team spawns
 234         }
 235
 236         if(g_ctf)
 237         {
 238                 game = GAME_CTF;
 239                 gamemode_name = "Capture the Flag";
 240                 ActivateTeamplay();
 241                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
 242                 if(g_ctf_win_mode == 2)
 243                 {
 244                         fraglimit_override = autocvar_g_ctf_capture_limit;
 245                         leadlimit_override = autocvar_g_ctf_capture_leadlimit;
 246                 }
 247                 else
 248                 {
 249                         fraglimit_override = autocvar_capturelimit_override;
 250                         leadlimit_override = autocvar_captureleadlimit_override;
 251                 }
 252                 ctf_init();
 253                 have_team_spawns = -1; // request team spawns
 254         }
 255
 256         if(g_runematch)
 257         {
 258                 game = GAME_RUNEMATCH;
 259                 gamemode_name = "Rune Match";
 260                 if(autocvar_deathmatch_force_teamplay)
 261                         ActivateTeamplay();
 262                 fraglimit_override = autocvar_g_runematch_point_limit;
 263                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 264                 runematch_init();
 265         }
 266
 267         if(g_lms)
 268         {
 269                 game = GAME_LMS;
 270                 gamemode_name = "Last Man Standing";
 271                 fraglimit_override = autocvar_g_lms_lives_override;
 272                 leadlimit_override = 0; // not supported by LMS
 273                 if(fraglimit_override == 0)
 274                         fraglimit_override = -1;
 275                 lms_lowest_lives = 9999;
 276                 lms_next_place = 0;
 277                 ScoreRules_lms();
 278         }
 279
 280         if(g_arena)
 281         {
 282                 game = GAME_ARENA;
 283                 gamemode_name = "Arena";
 284                 fraglimit_override = autocvar_g_arena_point_limit;
 285                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 286                 maxspawned = autocvar_g_arena_maxspawned;
 287                 if(maxspawned < 2)
 288                         maxspawned = 2;
 289                 arena_roundbased = autocvar_g_arena_roundbased;
 290         }
 291
 292         if(g_ca)
 293         {
 294                 game = GAME_CA;
 295                 gamemode_name = "Clan Arena";
 296                 ActivateTeamplay();
 297                 fraglimit_override = autocvar_g_ca_point_limit;
 298                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 299                 precache_sound("ctf/red_capture.wav");
 300                 precache_sound("ctf/blue_capture.wav");
 301         }
 302         if(g_keyhunt)
 303         {
 304                 game = GAME_KEYHUNT;
 305                 gamemode_name = "Key Hunt";
 306                 ActivateTeamplay();
 307                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 308                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 309                 MUTATOR_ADD(gamemode_keyhunt);
 310         }
 311
 312         if(g_freezetag)
 313         {
 314                 game = GAME_FREEZETAG;
 315                 gamemode_name = "Freeze Tag";
 316                 ActivateTeamplay();
 317                 fraglimit_override = autocvar_g_freezetag_point_limit;
 318                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 319                 MUTATOR_ADD(gamemode_freezetag);
 320         }
 321
 322         if(g_assault)
 323         {
 324                 game = GAME_ASSAULT;
 325                 gamemode_name = "Assault";
 326                 ActivateTeamplay();
 327                 ScoreRules_assault();
 328                 have_team_spawns = -1; // request team spawns
 329         }
 330
 331         if(g_onslaught)
 332         {
 333                 game = GAME_ONSLAUGHT;
 334                 gamemode_name = "Onslaught";
 335                 ActivateTeamplay();
 336                 have_team_spawns = -1; // request team spawns
 337         }
 338
 339         if(g_race)
 340         {
 341                 game = GAME_RACE;
 342                 gamemode_name = "Race";
 343
 344                 if(autocvar_g_race_teams)
 345                 {
 346                         ActivateTeamplay();
 347                         race_teams = bound(2, autocvar_g_race_teams, 4);
 348                         have_team_spawns = -1; // request team spawns
 349                 }
 350                 else
 351                         race_teams = 0;
 352
 353                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 354                 fraglimit_override = autocvar_g_race_laps_limit;
 355                 leadlimit_override = 0; // currently not supported by race
 356         }
 357
 358         if(g_cts)
 359         {
 360                 game = GAME_CTS;
 361                 gamemode_name = "CTS";
 362                 g_race_qualifying = 1;
 363                 fraglimit_override = 0;
 364                 leadlimit_override = 0;
 365         }
 366
 367         if(g_nexball)
 368         {
 369                 game = GAME_NEXBALL;
 370                 gamemode_name = "Nexball";
 371                 fraglimit_override = autocvar_g_nexball_goallimit;
 372                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 373                 ActivateTeamplay();
 374                 nb_init();
 375                 have_team_spawns = -1; // request team spawns
 376         }
 377
 378         if(g_keepaway)
 379         {
 380                 game = GAME_KEEPAWAY;
 381                 gamemode_name = "Keepaway";
 382                 MUTATOR_ADD(gamemode_keepaway);
 383         }
 384
 385         if(teams_matter)
 386                 entcs_init();
 387
 388         // save it (for the next startup)
 389         cvar_set("gamecfg", ftos(game));
 390
 391         cache_mutatormsg = strzone("");
 392         cache_lastmutatormsg = strzone("");
 393
 394         // enforce the server's universal frag/time limits
 395         if(!autocvar_g_campaign)
 396         {
 397                 if(fraglimit_override >= 0)
 398                         cvar_set("fraglimit", ftos(fraglimit_override));
 399                 if(timelimit_override >= 0)
 400                         cvar_set("timelimit", ftos(timelimit_override));
 401                 if(leadlimit_override >= 0)
 402                         cvar_set("leadlimit", ftos(leadlimit_override));
 403                 if(qualifying_override >= 0)
 404                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 405         }
 406
 407         if(g_race)
 408         {
 409                 // we need to find out the correct value for g_race_qualifying
 410                 if(autocvar_g_campaign)
 411                 {
 412                         g_race_qualifying = 1;
 413                 }
 414                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 415                 {
 416                         g_race_qualifying = 2;
 417                         race_fraglimit = autocvar_fraglimit;
 418                         race_leadlimit = autocvar_leadlimit;
 419                         race_timelimit = autocvar_timelimit;
 420                         cvar_set("fraglimit", "0");
 421                         cvar_set("leadlimit", "0");
 422                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 423                 }
 424                 else
 425                         g_race_qualifying = 0;
 426         }
 427
 428         if(g_race || g_cts)
 429         {
 430                 if(g_race_qualifying)
 431                         independent_players = 1;
 432
 433                 ScoreRules_race();
 434         }
 435
 436         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 437 }
 438
 439 string GetClientVersionMessage() {
 440         local string versionmsg;
 441         if (self.version_mismatch) {
 442                 if(self.version < autocvar_gameversion) {
 443                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 444                 } else {
 445                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 446                 }
 447         } else {
 448                 versionmsg = "^2client version and server version are compatible.^8";
 449         }
 450         return versionmsg;
 451 }
 452
 453
 454 void PrintWelcomeMessage(entity pl)
 455 {
 456         string s, modifications, motd;
 457
 458         if(self.cvar_scr_centertime == 0) return;
 459
 460         if(autocvar_g_campaign)
 461         {
 462                 if(self.classname == "player" && !self.BUTTON_INFO)
 463                         return;
 464         }
 465         else
 466         {
 467                 if((time - self.jointime) > autocvar_welcome_message_time && !self.BUTTON_INFO)
 468                         return;
 469         }
 470
 471         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 472                 if(self.welcomemessage_time > time) return;
 473                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 474         }
 475
 476         if(autocvar_g_campaign)
 477         {
 478                 centerprint(pl, campaign_message);
 479                 return;
 480         }
 481
 482 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 483         if(!self.BUTTON_INFO)
 484         {
 485                 // TODO get rid of this too
 486                 local string specString;
 487                 specString = NEWLINES;
 488                 //if(time < game_starttime) //also show the countdown when being a spectator
 489                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 490                 //else
 491                 if (timeoutStatus != 0)
 492                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 493                 else
 494                 {
 495                         if(self.classname == "player")
 496                                 return;
 497                         goto normal;
 498                 }
 499                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 500         }
 501
 502 :normal
 503         ret_string = "";
 504         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 505         modifications = ret_string;
 506
 507         if(g_minstagib)
 508                 modifications = strcat(modifications, ", MinstaGib");
 509         if(g_weaponarena)
 510         {
 511                 if(g_weaponarena_random)
 512                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 513                 else
 514                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 515         }
 516         if(autocvar_g_start_weapon_laser == 0)
 517                 modifications = strcat(modifications, ", No start weapons");
 518         if(autocvar_sv_gravity < 800)
 519                 modifications = strcat(modifications, ", Low gravity");
 520         if(g_cloaked)
 521                 modifications = strcat(modifications, ", Cloaked");
 522         if(g_grappling_hook)
 523                 modifications = strcat(modifications, ", Hook");
 524         if(g_midair)
 525                 modifications = strcat(modifications, ", Midair");
 526         if(g_pinata)
 527                 modifications = strcat(modifications, ", Pinata");
 528         if(g_weapon_stay)
 529                 modifications = strcat(modifications, ", Weapons stay");
 530         if(g_bloodloss > 0)
 531                 modifications = strcat(modifications, ", Bloodloss");
 532         if(g_jetpack)
 533                 modifications = strcat(modifications, ", Jet pack");
 534         modifications = substring(modifications, 2, strlen(modifications) - 2);
 535
 536         local string versionmessage;
 537         versionmessage = GetClientVersionMessage();
 538
 539         s = strcat(s, NEWLINES, "This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 540         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 541
 542         if(modifications != "")
 543                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 544
 545         if(timeoutStatus != 0)
 546                 s = strcat(s, "\n\n", getTimeoutText(1));
 547
 548         if (g_grappling_hook)
 549                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 550
 551         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 552         {
 553                 if(cache_lastmutatormsg)
 554                         strunzone(cache_lastmutatormsg);
 555                 if(cache_mutatormsg)
 556                         strunzone(cache_mutatormsg);
 557                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 558                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 559         }
 560
 561         if (cache_mutatormsg != "") {
 562                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 563         }
 564
 565         motd = autocvar_sv_motd;
 566         if (motd != "") {
 567                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 568         }
 569         s = strcat(s, "\n");
 570
 571         centerprint(pl, s);
 572 }
 573
 574
 575 void SetPlayerColors(entity pl, float _color)
 576 {
 577         /*string s;
 578         s = ftos(cl);
 579         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 580         pl.team = cl + 1;
 581         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 582         pl.clientcolors = 16*cl + cl;*/
 583
 584         float pants, shirt;
 585         pants = _color & 0x0F;
 586         shirt = _color & 0xF0;
 587
 588
 589         if(teams_matter) {
 590                 setcolor(pl, 16*pants + pants);
 591         } else {
 592                 setcolor(pl, shirt + pants);
 593         }
 594 }
 595
 596 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 597 {
 598         float _color;
 599
 600         if(t == 4)
 601                 _color = COLOR_TEAM4 - 1;
 602         else if(t == 3)
 603                 _color = COLOR_TEAM3 - 1;
 604         else if(t == 2)
 605                 _color = COLOR_TEAM2 - 1;
 606         else
 607                 _color = COLOR_TEAM1 - 1;
 608
 609         SetPlayerColors(pl,_color);
 610
 611         if(t != s) {
 612                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 613
 614                 if(!noprint)
 615                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 616         }
 617
 618 }
 619
 620 // set c1...c4 to show what teams are allowed
 621 void CheckAllowedTeams (entity for_whom)
 622 {
 623         float dm;
 624         entity head;
 625         string teament_name;
 626
 627         c1 = c2 = c3 = c4 = -1;
 628         cb1 = cb2 = cb3 = cb4 = 0;
 629
 630         if(g_onslaught)
 631         {
 632                 // onslaught is special
 633                 head = findchain(classname, "onslaught_generator");
 634                 while (head)
 635                 {
 636                         if (head.team == COLOR_TEAM1) c1 = 0;
 637                         if (head.team == COLOR_TEAM2) c2 = 0;
 638                         if (head.team == COLOR_TEAM3) c3 = 0;
 639                         if (head.team == COLOR_TEAM4) c4 = 0;
 640                         head = head.chain;
 641                 }
 642         }
 643         else if(g_domination)
 644                 teament_name = "dom_team";
 645         else if(g_ctf)
 646                 teament_name = "ctf_team";
 647         else if(g_tdm)
 648                 teament_name = "tdm_team";
 649         else if(g_nexball)
 650                 teament_name = "nexball_team";
 651         else if(g_assault)
 652                 c1 = c2 = 0; // Assault always has 2 teams
 653         else
 654         {
 655                 // cover anything else by treating it like tdm with no teams spawned
 656                 if(g_race)
 657                         dm = race_teams;
 658                 else
 659                         dm = 2;
 660
 661                 ret_float = dm;
 662                 MUTATOR_CALLHOOK(GetTeamCount);
 663                 dm = ret_float;
 664
 665                 if(dm >= 4)
 666                         c1 = c2 = c3 = c4 = 0;
 667                 else if(dm >= 3)
 668                         c1 = c2 = c3 = 0;
 669                 else
 670                         c1 = c2 = 0;
 671         }
 672
 673         // find out what teams are allowed if necessary
 674         if(teament_name)
 675         {
 676                 head = find(world, classname, teament_name);
 677                 while(head)
 678                 {
 679                         if(!(g_domination && head.netname == ""))
 680                         {
 681                                 if(head.team == COLOR_TEAM1)
 682                                         c1 = 0;
 683                                 else if(head.team == COLOR_TEAM2)
 684                                         c2 = 0;
 685                                 else if(head.team == COLOR_TEAM3)
 686                                         c3 = 0;
 687                                 else if(head.team == COLOR_TEAM4)
 688                                         c4 = 0;
 689                         }
 690                         head = find(head, classname, teament_name);
 691                 }
 692         }
 693
 694         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 695         if(c3==-1 && c4==-1)
 696         if(autocvar_bot_vs_human && for_whom)
 697         {
 698                 if(autocvar_bot_vs_human > 0)
 699                 {
 700                         // bots are all blue
 701                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 702                                 c1 = c3 = c4 = -1;
 703                         else
 704                                 c2 = -1;
 705                 }
 706                 else
 707                 {
 708                         // bots are all red
 709                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 710                                 c2 = c3 = c4 = -1;
 711                         else
 712                                 c1 = -1;
 713                 }
 714         }
 715
 716         // if player has a forced team, ONLY allow that one
 717         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 718                 c2 = c3 = c4 = -1;
 719         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 720                 c1 = c3 = c4 = -1;
 721         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 722                 c1 = c2 = c4 = -1;
 723         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 724                 c1 = c2 = c3 = -1;
 725 }
 726
 727 float PlayerValue(entity p)
 728 {
 729         if(IsTeamBalanceForced() == 1)
 730                 return 1;
 731         return 1;
 732         // FIXME: it always returns 1...
 733 }
 734
 735 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 736 // teams that are allowed will now have their player counts stored in c1...c4
 737 void GetTeamCounts(entity ignore)
 738 {
 739         entity head;
 740         float value, bvalue;
 741         // now count how many players are on each team already
 742
 743         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 744         // also remember the lowest-scoring player
 745
 746         FOR_EACH_PLAYER(head)
 747         {
 748                 if(head != ignore)// && head.netname != "")
 749                 {
 750                         value = PlayerValue(head);
 751                         if(clienttype(head) == CLIENTTYPE_BOT)
 752                                 bvalue = value;
 753                         else
 754                                 bvalue = 0;
 755                         if(head.team == COLOR_TEAM1)
 756                         {
 757                                 if(c1 >= 0)
 758                                 {
 759                                         c1 = c1 + value;
 760                                         cb1 = cb1 + bvalue;
 761                                 }
 762                         }
 763                         if(head.team == COLOR_TEAM2)
 764                         {
 765                                 if(c2 >= 0)
 766                                 {
 767                                         c2 = c2 + value;
 768                                         cb2 = cb2 + bvalue;
 769                                 }
 770                         }
 771                         if(head.team == COLOR_TEAM3)
 772                         {
 773                                 if(c3 >= 0)
 774                                 {
 775                                         c3 = c3 + value;
 776                                         cb3 = cb3 + bvalue;
 777                                 }
 778                         }
 779                         if(head.team == COLOR_TEAM4)
 780                         {
 781                                 if(c4 >= 0)
 782                                 {
 783                                         c4 = c4 + value;
 784                                         cb4 = cb4 + bvalue;
 785                                 }
 786                         }
 787                 }
 788         }
 789 }
 790
 791 // returns # of smallest team (1, 2, 3, 4)
 792 // NOTE: Assumes CheckAllowedTeams has already been called!
 793 float FindSmallestTeam(entity pl, float ignore_pl)
 794 {
 795         float totalteams, balance_type, maxc;
 796         totalteams = 0;
 797
 798         // find out what teams are available
 799         //CheckAllowedTeams();
 800
 801         // make sure there are at least 2 teams to join
 802         if(c1 >= 0)
 803                 totalteams = totalteams + 1;
 804         if(c2 >= 0)
 805                 totalteams = totalteams + 1;
 806         if(c3 >= 0)
 807                 totalteams = totalteams + 1;
 808         if(c4 >= 0)
 809                 totalteams = totalteams + 1;
 810
 811         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 812                 totalteams += 1;
 813
 814         if(totalteams <= 1)
 815         {
 816                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 817                         return 1; // special case for campaign and player joining
 818                 else if(g_domination)
 819                         error("Too few teams available for domination\n");
 820                 else if(g_ctf)
 821                         error("Too few teams available for ctf\n");
 822                 else if(g_keyhunt)
 823                         error("Too few teams available for key hunt\n");
 824                 else if(g_freezetag)
 825                         error("Too few teams available for freeze tag\n");
 826                 else
 827                         error("Too few teams available for team deathmatch\n");
 828         }
 829
 830         // count how many players are in each team
 831         if(ignore_pl)
 832                 GetTeamCounts(pl);
 833         else
 834                 GetTeamCounts(world);
 835
 836         // c1...c4 now have counts of each team
 837         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 838
 839         // 2 gives priority to what team you're already on, 1 goes in order
 840         // 2 doesn't seem to work though...
 841         balance_type = 1;
 842
 843         if(bots_would_leave)
 844         //if(pl.classname != "player")
 845         if(clienttype(pl) != CLIENTTYPE_BOT)
 846         {
 847                 c1 -= cb1 * 255.0/256.0;
 848                 c2 -= cb2 * 255.0/256.0;
 849                 c3 -= cb3 * 255.0/256.0;
 850                 c4 -= cb4 * 255.0/256.0;
 851         }
 852         maxc = max4(c1, c2, c3, c4);
 853
 854         RandomSelection_Init();
 855         if(balance_type == 1)
 856         {
 857                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 858                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 859                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 860                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 861                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 862         }
 863         else if(balance_type == 2)
 864         {
 865                 // 1: use team count, if equal prefer own team
 866                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 867                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 868                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 869                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 870         }
 871         else if(balance_type == 3)
 872         {
 873                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 874                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 875                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 876                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 877                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 878         }
 879         return RandomSelection_chosen_float;
 880 }
 881
 882 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 883 {
 884         float smallest, selectedteam;
 885
 886         // don't join a team if we're not playing a team game
 887         if(!teams_matter)
 888                 return 0;
 889
 890         // find out what teams are available
 891         CheckAllowedTeams(pl);
 892
 893         // if we want the player in a certain team for campaign, force him there
 894         if(autocvar_g_campaign)
 895         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
 896         {
 897                 switch(autocvar_g_campaign_forceteam)
 898                 {
 899                         case 1:
 900                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
 901                                 LogTeamchange(pl.playerid, pl.team, 2);
 902                                 return COLOR_TEAM1;
 903                         case 2:
 904                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
 905                                 LogTeamchange(pl.playerid, pl.team, 2);
 906                                 return COLOR_TEAM2;
 907                         case 3:
 908                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
 909                                 LogTeamchange(pl.playerid, pl.team, 2);
 910                                 return COLOR_TEAM3;
 911                         case 4:
 912                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
 913                                 LogTeamchange(pl.playerid, pl.team, 2);
 914                                 return COLOR_TEAM4;
 915                         default:
 916                                 break;
 917                 }
 918         }
 919
 920         // if we don't care what team he ends up on, put him on whatever team he entered as.
 921         // if he's not on a valid team, then let other code put him on the smallest team
 922         if(!forcebestteam)
 923         {
 924                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 925                         selectedteam = pl.team;
 926                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 927                         selectedteam = pl.team;
 928                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 929                         selectedteam = pl.team;
 930                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 931                         selectedteam = pl.team;
 932                 else
 933                         selectedteam = -1;
 934
 935                 if(selectedteam > 0)
 936                 {
 937                         if(!only_return_best)
 938                         {
 939                                 SetPlayerColors(pl, selectedteam - 1);
 940
 941                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 942                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 943                                 LogTeamchange(pl.playerid, pl.team, 99);
 944                         }
 945                         return selectedteam;
 946                 }
 947                 // otherwise end up on the smallest team (handled below)
 948         }
 949
 950         smallest = FindSmallestTeam(pl, TRUE);
 951
 952         if(!only_return_best && !pl.bot_forced_team)
 953         {
 954                 TeamchangeFrags(self);
 955                 if(smallest == 1)
 956                 {
 957                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 958                 }
 959                 else if(smallest == 2)
 960                 {
 961                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 962                 }
 963                 else if(smallest == 3)
 964                 {
 965                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 966                 }
 967                 else if(smallest == 4)
 968                 {
 969                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 970                 }
 971                 else
 972                 {
 973                         error("smallest team: invalid team\n");
 974                 }
 975
 976                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 977
 978                 if(pl.deadflag == DEAD_NO)
 979                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 980         }
 981
 982         return smallest;
 983 }
 984
 985 //void() ctf_playerchanged;
 986 void SV_ChangeTeam(float _color)
 987 {
 988         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 989
 990         // in normal deathmatch we can just apply the color and we're done
 991         if(!teams_matter) {
 992                 SetPlayerColors(self, _color);
 993                 return;
 994         }
 995
 996         scolor = self.clientcolors & 0x0F;
 997         dcolor = _color & 0x0F;
 998
 999         if(scolor == COLOR_TEAM1 - 1)
1000                 steam = 1;
1001         else if(scolor == COLOR_TEAM2 - 1)
1002                 steam = 2;
1003         else if(scolor == COLOR_TEAM3 - 1)
1004                 steam = 3;
1005         else // if(scolor == COLOR_TEAM4 - 1)
1006                 steam = 4;
1007         if(dcolor == COLOR_TEAM1 - 1)
1008                 dteam = 1;
1009         else if(dcolor == COLOR_TEAM2 - 1)
1010                 dteam = 2;
1011         else if(dcolor == COLOR_TEAM3 - 1)
1012                 dteam = 3;
1013         else // if(dcolor == COLOR_TEAM4 - 1)
1014                 dteam = 4;
1015
1016         CheckAllowedTeams(self);
1017
1018         if(dteam == 1 && c1 < 0) dteam = 4;
1019         if(dteam == 4 && c4 < 0) dteam = 3;
1020         if(dteam == 3 && c3 < 0) dteam = 2;
1021         if(dteam == 2 && c2 < 0) dteam = 1;
1022
1023         // not changing teams
1024         if(scolor == dcolor)
1025         {
1026                 //bprint("same team change\n");
1027                 SetPlayerTeam(self, dteam, steam, TRUE);
1028                 return;
1029         }
1030
1031         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
1032                 sprint(self, "Team changes not allowed\n");
1033                 return; // changing teams is not allowed
1034         }
1035
1036         if(autocvar_g_balance_teams_prevent_imbalance)
1037         {
1038                 // only allow changing to a smaller or equal size team
1039
1040                 // find out what teams are available
1041                 //CheckAllowedTeams();
1042                 // count how many players on each team
1043                 GetTeamCounts(world);
1044
1045                 // get desired team
1046                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1047                 {
1048                         dcount = c1;
1049                         dbotcount = cb1;
1050                 }
1051                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1052                 {
1053                         dcount = c2;
1054                         dbotcount = cb2;
1055                 }
1056                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1057                 {
1058                         dcount = c3;
1059                         dbotcount = cb3;
1060                 }
1061                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1062                 {
1063                         dcount = c4;
1064                         dbotcount = cb4;
1065                 }
1066                 else
1067                 {
1068                         sprint(self, "Cannot change to an invalid team\n");
1069
1070                         return;
1071                 }
1072
1073                 // get starting team
1074                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1075                         scount = c1;
1076                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1077                         scount = c2;
1078                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1079                         scount = c3;
1080                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1081                         scount = c4;
1082
1083                 if(scount) // started at a valid, nonempty team
1084                 {
1085                         // check if we're trying to change to a larger team that doens't have bots to swap with
1086                         if(dcount >= scount && dbotcount <= 0)
1087                         {
1088                                 sprint(self, "Cannot change to a larger team\n");
1089                                 return; // can't change to a larger team
1090                         }
1091                 }
1092         }
1093
1094 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1095
1096         if(self.classname == "player" && steam != dteam)
1097         {
1098                 // reduce frags during a team change
1099                 TeamchangeFrags(self);
1100         }
1101
1102         SetPlayerTeam(self, dteam, steam, FALSE);
1103
1104         if(self.classname == "player" && steam != dteam)
1105         {
1106                 // kill player when changing teams
1107                 if(self.deadflag == DEAD_NO)
1108                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1109         }
1110         //ctf_playerchanged();
1111 }
1112
1113 void ShufflePlayerOutOfTeam (float source_team)
1114 {
1115         float smallestteam, smallestteam_count, steam;
1116         float lowest_bot_score, lowest_player_score;
1117         entity head, lowest_bot, lowest_player, selected;
1118
1119         smallestteam = 0;
1120         smallestteam_count = 999999999;
1121
1122         if(c1 >= 0 && c1 < smallestteam_count)
1123         {
1124                 smallestteam = 1;
1125                 smallestteam_count = c1;
1126         }
1127         if(c2 >= 0 && c2 < smallestteam_count)
1128         {
1129                 smallestteam = 2;
1130                 smallestteam_count = c2;
1131         }
1132         if(c3 >= 0 && c3 < smallestteam_count)
1133         {
1134                 smallestteam = 3;
1135                 smallestteam_count = c3;
1136         }
1137         if(c4 >= 0 && c4 < smallestteam_count)
1138         {
1139                 smallestteam = 4;
1140                 smallestteam_count = c4;
1141         }
1142
1143         if(!smallestteam)
1144         {
1145                 bprint("warning: no smallest team\n");
1146                 return;
1147         }
1148
1149         if(source_team == 1)
1150                 steam = COLOR_TEAM1;
1151         else if(source_team == 2)
1152                 steam = COLOR_TEAM2;
1153         else if(source_team == 3)
1154                 steam = COLOR_TEAM3;
1155         else if(source_team == 4)
1156                 steam = COLOR_TEAM4;
1157
1158         lowest_bot = world;
1159         lowest_bot_score = 999999999;
1160         lowest_player = world;
1161         lowest_player_score = 999999999;
1162
1163         // find the lowest-scoring player & bot of that team
1164         FOR_EACH_PLAYER(head)
1165         {
1166                 if(head.team == steam)
1167                 {
1168                         if(head.isbot)
1169                         {
1170                                 if(head.totalfrags < lowest_bot_score)
1171                                 {
1172                                         lowest_bot = head;
1173                                         lowest_bot_score = head.totalfrags;
1174                                 }
1175                         }
1176                         else
1177                         {
1178                                 if(head.totalfrags < lowest_player_score)
1179                                 {
1180                                         lowest_player = head;
1181                                         lowest_player_score = head.totalfrags;
1182                                 }
1183                         }
1184                 }
1185         }
1186
1187         // prefers to move a bot...
1188         if(lowest_bot != world)
1189                 selected = lowest_bot;
1190         // but it will move a player if it has to
1191         else
1192                 selected = lowest_player;
1193         // don't do anything if it couldn't find anyone
1194         if(!selected)
1195         {
1196                 bprint("warning: couldn't find a player to move from team\n");
1197                 return;
1198         }
1199
1200         // smallest team gains a member
1201         if(smallestteam == 1)
1202         {
1203                 c1 = c1 + 1;
1204         }
1205         else if(smallestteam == 2)
1206         {
1207                 c2 = c2 + 1;
1208         }
1209         else if(smallestteam == 3)
1210         {
1211                 c3 = c3 + 1;
1212         }
1213         else if(smallestteam == 4)
1214         {
1215                 c4 = c4 + 1;
1216         }
1217         else
1218         {
1219                 bprint("warning: destination team invalid\n");
1220                 return;
1221         }
1222         // source team loses a member
1223         if(source_team == 1)
1224         {
1225                 c1 = c1 + 1;
1226         }
1227         else if(source_team == 2)
1228         {
1229                 c2 = c2 + 2;
1230         }
1231         else if(source_team == 3)
1232         {
1233                 c3 = c3 + 3;
1234         }
1235         else if(source_team == 4)
1236         {
1237                 c4 = c4 + 4;
1238         }
1239         else
1240         {
1241                 bprint("warning: source team invalid\n");
1242                 return;
1243         }
1244
1245         // move the player to the new team
1246         TeamchangeFrags(selected);
1247         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1248
1249         if(selected.deadflag == DEAD_NO)
1250                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1251         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1252 }
1253
1254 void CauseRebalance(float source_team, float howmany_toomany)
1255 {
1256         if(IsTeamBalanceForced() == 1)
1257         {
1258                 bprint("Rebalancing Teams\n");
1259                 ShufflePlayerOutOfTeam(source_team);
1260         }
1261 }
1262
1263 // part of g_balance_teams_force
1264 // occasionally perform an audit of the teams to make
1265 // sure they're more or less balanced in player count.
1266 void AuditTeams()
1267 {
1268         float numplayers, numteams, smallest, toomany;
1269         float balance;
1270         balance = IsTeamBalanceForced();
1271         if(balance == 0)
1272                 return;
1273
1274         if(audit_teams_time > time)
1275                 return;
1276
1277         audit_teams_time = time + 4 + random();
1278
1279 //      bprint("Auditing teams\n");
1280
1281         CheckAllowedTeams(world);
1282         GetTeamCounts(world);
1283
1284
1285         numteams = numplayers = smallest = 0;
1286         if(c1 >= 0)
1287         {
1288                 numteams = numteams + 1;
1289                 numplayers = numplayers + c1;
1290                 smallest = c1;
1291         }
1292         if(c2 >= 0)
1293         {
1294                 numteams = numteams + 1;
1295                 numplayers = numplayers + c2;
1296                 if(c2 < smallest)
1297                         smallest = c2;
1298         }
1299         if(c3 >= 0)
1300         {
1301                 numteams = numteams + 1;
1302                 numplayers = numplayers + c3;
1303                 if(c3 < smallest)
1304                         smallest = c3;
1305         }
1306         if(c4 >= 0)
1307         {
1308                 numteams = numteams + 1;
1309                 numplayers = numplayers + c4;
1310                 if(c4 < smallest)
1311                         smallest = c4;
1312         }
1313
1314         if(numplayers <= 0)
1315                 return; // no players to move around
1316         if(numteams < 2)
1317                 return; // don't bother shuffling if for some reason there aren't any teams
1318
1319         toomany = smallest + 1;
1320
1321         if(c1 && c1 > toomany)
1322                 CauseRebalance(1, c1 - toomany);
1323         if(c2 && c2 > toomany)
1324                 CauseRebalance(2, c2 - toomany);
1325         if(c3 && c3 > toomany)
1326                 CauseRebalance(3, c3 - toomany);
1327         if(c4 && c4 > toomany)
1328                 CauseRebalance(4, c4 - toomany);
1329
1330         // if teams are still unbalanced, balance them further in the next audit,
1331         // which will happen sooner (keep doing rapid audits until things are in order)
1332         audit_teams_time = time + 0.7 + random()*0.3;
1333 }
1334
1335 // code from here on is just to support maps that don't have team entities
1336 void tdm_spawnteam (string teamname, float teamcolor)
1337 {
1338         local entity e;
1339         e = spawn();
1340         e.classname = "tdm_team";
1341         e.netname = teamname;
1342         e.cnt = teamcolor;
1343         e.team = e.cnt + 1;
1344 };
1345
1346 // spawn some default teams if the map is not set up for tdm
1347 void tdm_spawnteams()
1348 {
1349         float numteams;
1350
1351         numteams = autocvar_g_tdm_teams_override;
1352         if(numteams < 2)
1353                 numteams = autocvar_g_tdm_teams;
1354         numteams = bound(2, numteams, 4);
1355
1356         tdm_spawnteam("Red", COLOR_TEAM1-1);
1357         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1358         if(numteams >= 3)
1359                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1360         if(numteams >= 4)
1361                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1362 };
1363
1364 void tdm_delayedinit()
1365 {
1366         // if no teams are found, spawn defaults
1367         if (find(world, classname, "tdm_team") == world)
1368                 tdm_spawnteams();
1369 };
1370
1371 void tdm_init()
1372 {
1373         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1374 };