6defa736f63cdd09327cedb34e35033ff427d714
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / teamplay.qc
1 #include "teamplay.qh"
2 #include "_all.qh"
3
4 #include "cl_client.qh"
5 #include "race.qh"
6 #include "scores.qh"
7 #include "scores_rules.qh"
8
9 #include "bot/bot.qh"
10
11 #include "command/vote.qh"
12
13 #include "mutators/mutators_include.qh"
14
15 #include "../common/deathtypes.qh"
16 #include "../common/teams.qh"
17
18 void TeamchangeFrags(entity e)
19 {
20         PlayerScore_Clear(e);
21 }
22
23 void LogTeamchange(float player_id, float team_number, float type)
24 {
25         if(!autocvar_sv_eventlog)
26                 return;
27
28         if(player_id < 1)
29                 return;
30
31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
32 }
33
34 void default_delayedinit()
35 {
36         if(!scores_initialized)
37                 ScoreRules_generic();
38 }
39
40 void ActivateTeamplay()
41 {
42         serverflags |= SERVERFLAG_TEAMPLAY;
43         teamplay = 1;
44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
45 }
46
47 void InitGameplayMode()
48 {
49         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
50
51         qualifying_override = -1;
52
53         VoteReset();
54
55         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
56         get_mi_min_max(1);
57         world.mins = mi_min;
58         world.maxs = mi_max;
59
60         MapInfo_LoadMapSettings(mapname);
61         serverflags &= ~SERVERFLAG_TEAMPLAY;
62         teamplay = 0;
63         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
64
65         if (!cvar_value_issafe(world.fog))
66         {
67                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
68                 world.fog = string_null;
69         }
70         if(MapInfo_Map_fog != "")
71                 if(MapInfo_Map_fog == "none")
72                         world.fog = string_null;
73                 else
74                         world.fog = strzone(MapInfo_Map_fog);
75         clientstuff = strzone(MapInfo_Map_clientstuff);
76
77         MapInfo_ClearTemps();
78
79         // set both here, gamemode can override it later
80         timelimit_override = autocvar_timelimit_override;
81         fraglimit_override = autocvar_fraglimit_override;
82         leadlimit_override = autocvar_leadlimit_override;
83         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
84
85         if(g_dm)
86         {
87                 MUTATOR_ADD(gamemode_deathmatch);
88         }
89
90         if(g_tdm)
91         {
92                 ActivateTeamplay();
93                 fraglimit_override = autocvar_g_tdm_point_limit;
94                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
95                 if(autocvar_g_tdm_team_spawns)
96                         have_team_spawns = -1; // request team spawns
97                 MUTATOR_ADD(gamemode_tdm);
98         }
99
100         if(g_domination)
101         {
102                 ActivateTeamplay();
103                 fraglimit_override = autocvar_g_domination_point_limit;
104                 leadlimit_override = autocvar_g_domination_point_leadlimit;
105                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
106                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
107                 have_team_spawns = -1; // request team spawns
108                 MUTATOR_ADD(gamemode_domination);
109         }
110
111         if(g_ctf)
112         {
113                 ActivateTeamplay();
114                 fraglimit_override = autocvar_capturelimit_override;
115                 leadlimit_override = autocvar_captureleadlimit_override;
116                 have_team_spawns = -1; // request team spawns
117                 MUTATOR_ADD(gamemode_ctf);
118         }
119
120         if(g_lms)
121         {
122                 fraglimit_override = autocvar_g_lms_lives_override;
123                 leadlimit_override = 0; // not supported by LMS
124                 if(fraglimit_override == 0)
125                         fraglimit_override = -1;
126                 MUTATOR_ADD(gamemode_lms);
127         }
128
129         if(g_ca)
130         {
131                 ActivateTeamplay();
132                 fraglimit_override = autocvar_g_ca_point_limit;
133                 leadlimit_override = autocvar_g_ca_point_leadlimit;
134                 if(autocvar_g_ca_team_spawns)
135                         have_team_spawns = -1; // request team spawns
136                 MUTATOR_ADD(gamemode_ca);
137         }
138
139         if(g_keyhunt)
140         {
141                 ActivateTeamplay();
142                 fraglimit_override = autocvar_g_keyhunt_point_limit;
143                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
144                 if(autocvar_g_keyhunt_team_spawns)
145                         have_team_spawns = -1; // request team spawns
146                 MUTATOR_ADD(gamemode_keyhunt);
147         }
148
149         if(g_freezetag)
150         {
151                 ActivateTeamplay();
152                 fraglimit_override = autocvar_g_freezetag_point_limit;
153                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
154                 if(autocvar_g_freezetag_team_spawns)
155                         have_team_spawns = -1; // request team spawns
156                 MUTATOR_ADD(gamemode_freezetag);
157         }
158
159         if(g_assault)
160         {
161                 ActivateTeamplay();
162                 have_team_spawns = -1; // request team spawns
163                 MUTATOR_ADD(gamemode_assault);
164         }
165
166         if(g_onslaught)
167         {
168                 ActivateTeamplay();
169                 fraglimit_override = autocvar_g_onslaught_point_limit;
170                 have_team_spawns = -1; // request team spawns
171                 MUTATOR_ADD(gamemode_onslaught);
172         }
173
174         if(g_race)
175         {
176                 if(autocvar_g_race_teams)
177                 {
178                         ActivateTeamplay();
179                         race_teams = bound(2, autocvar_g_race_teams, 4);
180                         have_team_spawns = -1; // request team spawns
181                 }
182                 else
183                         race_teams = 0;
184                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
185                 fraglimit_override = autocvar_g_race_laps_limit;
186                 leadlimit_override = 0; // currently not supported by race
187
188                 // we need to find out the correct value for g_race_qualifying
189                 float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
190
191                 if(autocvar_g_campaign)
192                 {
193                         g_race_qualifying = 1;
194                         independent_players = 1;
195                 }
196                 else if(!autocvar_g_campaign && want_qualifying)
197                 {
198                         g_race_qualifying = 2;
199                         independent_players = 1;
200                         race_fraglimit = (race_fraglimit >= 0) ? fraglimit_override : autocvar_fraglimit;
201                         race_leadlimit = (race_leadlimit >= 0) ? leadlimit_override : autocvar_leadlimit;
202                         race_timelimit = (race_timelimit >= 0) ? timelimit_override : autocvar_timelimit;
203                         fraglimit_override = 0;
204                         leadlimit_override = 0;
205                         timelimit_override = autocvar_g_race_qualifying_timelimit;
206                 }
207                 else
208                 {
209                         g_race_qualifying = 0;
210                 }
211
212                 MUTATOR_ADD(gamemode_race);
213         }
214
215         if(g_cts)
216         {
217                 g_race_qualifying = 1;
218                 fraglimit_override = 0;
219                 leadlimit_override = 0;
220                 independent_players = 1;
221                 MUTATOR_ADD(gamemode_cts);
222         }
223
224         if(g_nexball)
225         {
226                 fraglimit_override = autocvar_g_nexball_goallimit;
227                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
228                 ActivateTeamplay();
229                 have_team_spawns = -1; // request team spawns
230                 MUTATOR_ADD(gamemode_nexball);
231         }
232
233         if(g_keepaway)
234         {
235                 MUTATOR_ADD(gamemode_keepaway);
236         }
237
238         if(g_invasion)
239         {
240                 fraglimit_override = autocvar_g_invasion_point_limit;
241                 if(autocvar_g_invasion_teams >= 2)
242                 {
243                         ActivateTeamplay();
244                         if(autocvar_g_invasion_team_spawns)
245                                 have_team_spawns = -1; // request team spawns
246                 }
247                 MUTATOR_ADD(gamemode_invasion);
248         }
249
250         if(teamplay)
251                 entcs_init();
252
253         cache_mutatormsg = strzone("");
254         cache_lastmutatormsg = strzone("");
255
256         // enforce the server's universal frag/time limits
257         if(!autocvar_g_campaign)
258         {
259                 if(fraglimit_override >= 0)
260                         cvar_set("fraglimit", ftos(fraglimit_override));
261                 if(timelimit_override >= 0)
262                         cvar_set("timelimit", ftos(timelimit_override));
263                 if(leadlimit_override >= 0)
264                         cvar_set("leadlimit", ftos(leadlimit_override));
265                 if(qualifying_override >= 0)
266                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
267         }
268
269         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
270 }
271
272 string GetClientVersionMessage()
273 {SELFPARAM();
274         string versionmsg;
275         if (self.version_mismatch) {
276                 if(self.version < autocvar_gameversion) {
277                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
278                 } else {
279                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
280                 }
281         } else {
282                 versionmsg = "^2client version and server version are compatible.^8";
283         }
284         return versionmsg;
285 }
286
287 string getwelcomemessage(void)
288 {
289         string s, modifications, motd;
290
291         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
292         modifications = ret_string;
293
294         if(g_weaponarena)
295         {
296                 if(g_weaponarena_random)
297                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
298                 else
299                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
300         }
301         else if(cvar("g_balance_blaster_weaponstart") == 0)
302                 modifications = strcat(modifications, ", No start weapons");
303         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
304                 modifications = strcat(modifications, ", Low gravity");
305         if(g_cloaked && !g_cts)
306                 modifications = strcat(modifications, ", Cloaked");
307         if(g_weapon_stay && !g_cts)
308                 modifications = strcat(modifications, ", Weapons stay");
309         if(g_jetpack)
310                 modifications = strcat(modifications, ", Jet pack");
311         if(autocvar_g_powerups == 0)
312                 modifications = strcat(modifications, ", No powerups");
313         if(autocvar_g_powerups > 0)
314                 modifications = strcat(modifications, ", Powerups");
315         modifications = substring(modifications, 2, strlen(modifications) - 2);
316
317         string versionmessage;
318         versionmessage = GetClientVersionMessage();
319
320         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
321         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
322
323         if(modifications != "")
324                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
325
326         if (cvar("g_nades"))
327                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
328
329         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
330         {
331                 if(cache_lastmutatormsg)
332                         strunzone(cache_lastmutatormsg);
333                 if(cache_mutatormsg)
334                         strunzone(cache_mutatormsg);
335                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
336                 cache_mutatormsg = strzone(cache_lastmutatormsg);
337         }
338
339         if (cache_mutatormsg != "") {
340                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
341         }
342
343         string mutator_msg = "";
344         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
345         mutator_msg = ret_string;
346
347         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
348
349         motd = autocvar_sv_motd;
350         if (motd != "") {
351                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
352         }
353         return s;
354 }
355
356 void SetPlayerColors(entity pl, float _color)
357 {
358         /*string s;
359         s = ftos(cl);
360         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
361         pl.team = cl + 1;
362         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
363         pl.clientcolors = 16*cl + cl;*/
364
365         float pants, shirt;
366         pants = _color & 0x0F;
367         shirt = _color & 0xF0;
368
369
370         if(teamplay) {
371                 setcolor(pl, 16*pants + pants);
372         } else {
373                 setcolor(pl, shirt + pants);
374         }
375 }
376
377 void SetPlayerTeam(entity pl, float t, float s, float noprint)
378 {
379         float _color;
380
381         if(t == 4)
382                 _color = NUM_TEAM_4 - 1;
383         else if(t == 3)
384                 _color = NUM_TEAM_3 - 1;
385         else if(t == 2)
386                 _color = NUM_TEAM_2 - 1;
387         else
388                 _color = NUM_TEAM_1 - 1;
389
390         SetPlayerColors(pl,_color);
391
392         if(t != s) {
393                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
394
395                 if(!noprint)
396                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
397         }
398
399 }
400
401 // set c1...c4 to show what teams are allowed
402 void CheckAllowedTeams (entity for_whom)
403 {SELFPARAM();
404         float dm;
405         entity head;
406         string teament_name;
407
408         c1 = c2 = c3 = c4 = -1;
409         cb1 = cb2 = cb3 = cb4 = 0;
410
411         teament_name = string_null;
412         if(g_onslaught)
413         {
414                 // onslaught is special
415                 head = findchain(classname, "onslaught_generator");
416                 while (head)
417                 {
418                         if (head.team == NUM_TEAM_1) c1 = 0;
419                         if (head.team == NUM_TEAM_2) c2 = 0;
420                         if (head.team == NUM_TEAM_3) c3 = 0;
421                         if (head.team == NUM_TEAM_4) c4 = 0;
422                         head = head.chain;
423                 }
424         }
425         else if(g_domination)
426                 teament_name = "dom_team";
427         else if(g_ctf)
428                 teament_name = "ctf_team";
429         else if(g_tdm)
430                 teament_name = "tdm_team";
431         else if(g_nexball)
432                 teament_name = "nexball_team";
433         else if(g_assault)
434                 c1 = c2 = 0; // Assault always has 2 teams
435         else
436         {
437                 // cover anything else by treating it like tdm with no teams spawned
438                 dm = 2;
439
440                 MUTATOR_CALLHOOK(GetTeamCount, dm);
441                 dm = ret_float;
442
443                 if(dm >= 4)
444                         c1 = c2 = c3 = c4 = 0;
445                 else if(dm >= 3)
446                         c1 = c2 = c3 = 0;
447                 else
448                         c1 = c2 = 0;
449         }
450
451         // find out what teams are allowed if necessary
452         if(teament_name)
453         {
454                 head = find(world, classname, teament_name);
455                 while(head)
456                 {
457                         if(!(g_domination && head.netname == ""))
458                         {
459                                 if(head.team == NUM_TEAM_1)
460                                         c1 = 0;
461                                 else if(head.team == NUM_TEAM_2)
462                                         c2 = 0;
463                                 else if(head.team == NUM_TEAM_3)
464                                         c3 = 0;
465                                 else if(head.team == NUM_TEAM_4)
466                                         c4 = 0;
467                         }
468                         head = find(head, classname, teament_name);
469                 }
470         }
471
472         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
473         if(c3==-1 && c4==-1)
474         if(autocvar_bot_vs_human && for_whom)
475         {
476                 if(autocvar_bot_vs_human > 0)
477                 {
478                         // bots are all blue
479                         if(IS_BOT_CLIENT(for_whom))
480                                 c1 = c3 = c4 = -1;
481                         else
482                                 c2 = -1;
483                 }
484                 else
485                 {
486                         // bots are all red
487                         if(IS_BOT_CLIENT(for_whom))
488                                 c2 = c3 = c4 = -1;
489                         else
490                                 c1 = -1;
491                 }
492         }
493
494         // if player has a forced team, ONLY allow that one
495         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
496                 c2 = c3 = c4 = -1;
497         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
498                 c1 = c3 = c4 = -1;
499         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
500                 c1 = c2 = c4 = -1;
501         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
502                 c1 = c2 = c3 = -1;
503 }
504
505 float PlayerValue(entity p)
506 {
507         return 1;
508         // FIXME: it always returns 1...
509 }
510
511 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
512 // teams that are allowed will now have their player counts stored in c1...c4
513 void GetTeamCounts(entity ignore)
514 {
515         entity head;
516         float value, bvalue;
517         // now count how many players are on each team already
518
519         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
520         // also remember the lowest-scoring player
521
522         FOR_EACH_CLIENT(head)
523         {
524                 float t;
525                 if(IS_PLAYER(head) || head.caplayer)
526                         t = head.team;
527                 else if(head.team_forced > 0)
528                         t = head.team_forced; // reserve the spot
529                 else
530                         continue;
531                 if(head != ignore)// && head.netname != "")
532                 {
533                         value = PlayerValue(head);
534                         if(IS_BOT_CLIENT(head))
535                                 bvalue = value;
536                         else
537                                 bvalue = 0;
538                         if(t == NUM_TEAM_1)
539                         {
540                                 if(c1 >= 0)
541                                 {
542                                         c1 = c1 + value;
543                                         cb1 = cb1 + bvalue;
544                                 }
545                         }
546                         if(t == NUM_TEAM_2)
547                         {
548                                 if(c2 >= 0)
549                                 {
550                                         c2 = c2 + value;
551                                         cb2 = cb2 + bvalue;
552                                 }
553                         }
554                         if(t == NUM_TEAM_3)
555                         {
556                                 if(c3 >= 0)
557                                 {
558                                         c3 = c3 + value;
559                                         cb3 = cb3 + bvalue;
560                                 }
561                         }
562                         if(t == NUM_TEAM_4)
563                         {
564                                 if(c4 >= 0)
565                                 {
566                                         c4 = c4 + value;
567                                         cb4 = cb4 + bvalue;
568                                 }
569                         }
570                 }
571         }
572
573         // if the player who has a forced team has not joined yet, reserve the spot
574         if(autocvar_g_campaign)
575         {
576                 switch(autocvar_g_campaign_forceteam)
577                 {
578                         case 1: if(c1 == cb1) ++c1; break;
579                         case 2: if(c2 == cb2) ++c2; break;
580                         case 3: if(c3 == cb3) ++c3; break;
581                         case 4: if(c4 == cb4) ++c4; break;
582                 }
583         }
584 }
585
586 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
587 {
588         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
589         float f;
590         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
591
592         switch(ta)
593         {
594                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
595                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
596                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
597                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
598         }
599         switch(tb)
600         {
601                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
602                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
603                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
604                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
605         }
606
607         // invalid
608         if(ca < 0 || cb < 0)
609                 return false;
610
611         // equal
612         if(ta == tb)
613                 return true;
614
615         if(IS_REAL_CLIENT(e))
616         {
617                 if(bots_would_leave)
618                 {
619                         ca -= cba * 0.999;
620                         cb -= cbb * 0.999;
621                 }
622         }
623
624         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
625         if(ca < 1)
626                 if(cb >= 1)
627                         return true;
628         if(ca >= 1)
629                 if(cb < 1)
630                         return false;
631
632         // first, normalize
633         f = max(ca, cb, 1);
634         ca /= f;
635         cb /= f;
636         f = max(sa, sb, 1);
637         sa /= f;
638         sb /= f;
639
640         // the more we're at the end of the match, the more take scores into account
641         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
642         ca += (sa - ca) * f;
643         cb += (sb - cb) * f;
644
645         return ca <= cb;
646 }
647
648 // returns # of smallest team (1, 2, 3, 4)
649 // NOTE: Assumes CheckAllowedTeams has already been called!
650 float FindSmallestTeam(entity pl, float ignore_pl)
651 {
652         float totalteams, t;
653         totalteams = 0;
654
655         // find out what teams are available
656         //CheckAllowedTeams();
657
658         // make sure there are at least 2 teams to join
659         if(c1 >= 0)
660                 totalteams = totalteams + 1;
661         if(c2 >= 0)
662                 totalteams = totalteams + 1;
663         if(c3 >= 0)
664                 totalteams = totalteams + 1;
665         if(c4 >= 0)
666                 totalteams = totalteams + 1;
667
668         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
669                 totalteams += 1;
670
671         if(totalteams <= 1)
672         {
673                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
674                         return 1; // special case for campaign and player joining
675                 else
676                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
677         }
678
679         // count how many players are in each team
680         if(ignore_pl)
681                 GetTeamCounts(pl);
682         else
683                 GetTeamCounts(world);
684
685         RandomSelection_Init();
686
687         t = 1;
688         if(TeamSmallerEqThanTeam(2, t, pl))
689                 t = 2;
690         if(TeamSmallerEqThanTeam(3, t, pl))
691                 t = 3;
692         if(TeamSmallerEqThanTeam(4, t, pl))
693                 t = 4;
694
695         // now t is the minimum, or A minimum!
696         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
697                 RandomSelection_Add(world, 1, string_null, 1, 1);
698         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
699                 RandomSelection_Add(world, 2, string_null, 1, 1);
700         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
701                 RandomSelection_Add(world, 3, string_null, 1, 1);
702         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
703                 RandomSelection_Add(world, 4, string_null, 1, 1);
704
705         return RandomSelection_chosen_float;
706 }
707
708 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
709 {SELFPARAM();
710         float smallest, selectedteam;
711
712         // don't join a team if we're not playing a team game
713         if(!teamplay)
714                 return 0;
715
716         // find out what teams are available
717         CheckAllowedTeams(pl);
718
719         // if we don't care what team he ends up on, put him on whatever team he entered as.
720         // if he's not on a valid team, then let other code put him on the smallest team
721         if(!forcebestteam)
722         {
723                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
724                         selectedteam = pl.team;
725                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
726                         selectedteam = pl.team;
727                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
728                         selectedteam = pl.team;
729                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
730                         selectedteam = pl.team;
731                 else
732                         selectedteam = -1;
733
734                 if(selectedteam > 0)
735                 {
736                         if(!only_return_best)
737                         {
738                                 SetPlayerColors(pl, selectedteam - 1);
739
740                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
741                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
742                                 LogTeamchange(pl.playerid, pl.team, 99);
743                         }
744                         return selectedteam;
745                 }
746                 // otherwise end up on the smallest team (handled below)
747         }
748
749         smallest = FindSmallestTeam(pl, true);
750
751         if(!only_return_best && !pl.bot_forced_team)
752         {
753                 TeamchangeFrags(self);
754                 if(smallest == 1)
755                 {
756                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
757                 }
758                 else if(smallest == 2)
759                 {
760                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
761                 }
762                 else if(smallest == 3)
763                 {
764                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
765                 }
766                 else if(smallest == 4)
767                 {
768                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
769                 }
770                 else
771                 {
772                         error("smallest team: invalid team\n");
773                 }
774
775                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
776
777                 if(pl.deadflag == DEAD_NO)
778                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
779         }
780
781         return smallest;
782 }
783
784 //void() ctf_playerchanged;
785 void SV_ChangeTeam(float _color)
786 {SELFPARAM();
787         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
788
789         // in normal deathmatch we can just apply the color and we're done
790         if(!teamplay) {
791                 SetPlayerColors(self, _color);
792                 return;
793         }
794
795         scolor = self.clientcolors & 0x0F;
796         dcolor = _color & 0x0F;
797
798         if(scolor == NUM_TEAM_1 - 1)
799                 steam = 1;
800         else if(scolor == NUM_TEAM_2 - 1)
801                 steam = 2;
802         else if(scolor == NUM_TEAM_3 - 1)
803                 steam = 3;
804         else // if(scolor == NUM_TEAM_4 - 1)
805                 steam = 4;
806         if(dcolor == NUM_TEAM_1 - 1)
807                 dteam = 1;
808         else if(dcolor == NUM_TEAM_2 - 1)
809                 dteam = 2;
810         else if(dcolor == NUM_TEAM_3 - 1)
811                 dteam = 3;
812         else // if(dcolor == NUM_TEAM_4 - 1)
813                 dteam = 4;
814
815         CheckAllowedTeams(self);
816
817         if(dteam == 1 && c1 < 0) dteam = 4;
818         if(dteam == 4 && c4 < 0) dteam = 3;
819         if(dteam == 3 && c3 < 0) dteam = 2;
820         if(dteam == 2 && c2 < 0) dteam = 1;
821
822         // not changing teams
823         if(scolor == dcolor)
824         {
825                 //bprint("same team change\n");
826                 SetPlayerTeam(self, dteam, steam, true);
827                 return;
828         }
829
830         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
831                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
832                 return; // changing teams is not allowed
833         }
834
835         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
836         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
837         {
838                 GetTeamCounts(self);
839                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
840                 {
841                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
842                         return;
843                 }
844         }
845
846 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
847
848         if(IS_PLAYER(self) && steam != dteam)
849         {
850                 // reduce frags during a team change
851                 TeamchangeFrags(self);
852         }
853
854         // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
855         if(!IS_CLIENT(self))
856                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_CONNECTING, self.netname);
857
858         SetPlayerTeam(self, dteam, steam, !IS_CLIENT(self));
859
860         if(IS_PLAYER(self) && steam != dteam)
861         {
862                 // kill player when changing teams
863                 if(self.deadflag == DEAD_NO)
864                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
865         }
866 }
867
868 void ShufflePlayerOutOfTeam (float source_team)
869 {
870         float smallestteam, smallestteam_count, steam;
871         float lowest_bot_score, lowest_player_score;
872         entity head, lowest_bot, lowest_player, selected;
873
874         smallestteam = 0;
875         smallestteam_count = 999999999;
876
877         if(c1 >= 0 && c1 < smallestteam_count)
878         {
879                 smallestteam = 1;
880                 smallestteam_count = c1;
881         }
882         if(c2 >= 0 && c2 < smallestteam_count)
883         {
884                 smallestteam = 2;
885                 smallestteam_count = c2;
886         }
887         if(c3 >= 0 && c3 < smallestteam_count)
888         {
889                 smallestteam = 3;
890                 smallestteam_count = c3;
891         }
892         if(c4 >= 0 && c4 < smallestteam_count)
893         {
894                 smallestteam = 4;
895                 smallestteam_count = c4;
896         }
897
898         if(!smallestteam)
899         {
900                 bprint("warning: no smallest team\n");
901                 return;
902         }
903
904         if(source_team == 1)
905                 steam = NUM_TEAM_1;
906         else if(source_team == 2)
907                 steam = NUM_TEAM_2;
908         else if(source_team == 3)
909                 steam = NUM_TEAM_3;
910         else // if(source_team == 4)
911                 steam = NUM_TEAM_4;
912
913         lowest_bot = world;
914         lowest_bot_score = 999999999;
915         lowest_player = world;
916         lowest_player_score = 999999999;
917
918         // find the lowest-scoring player & bot of that team
919         FOR_EACH_PLAYER(head)
920         {
921                 if(head.team == steam)
922                 {
923                         if(head.isbot)
924                         {
925                                 if(head.totalfrags < lowest_bot_score)
926                                 {
927                                         lowest_bot = head;
928                                         lowest_bot_score = head.totalfrags;
929                                 }
930                         }
931                         else
932                         {
933                                 if(head.totalfrags < lowest_player_score)
934                                 {
935                                         lowest_player = head;
936                                         lowest_player_score = head.totalfrags;
937                                 }
938                         }
939                 }
940         }
941
942         // prefers to move a bot...
943         if(lowest_bot != world)
944                 selected = lowest_bot;
945         // but it will move a player if it has to
946         else
947                 selected = lowest_player;
948         // don't do anything if it couldn't find anyone
949         if(!selected)
950         {
951                 bprint("warning: couldn't find a player to move from team\n");
952                 return;
953         }
954
955         // smallest team gains a member
956         if(smallestteam == 1)
957         {
958                 c1 = c1 + 1;
959         }
960         else if(smallestteam == 2)
961         {
962                 c2 = c2 + 1;
963         }
964         else if(smallestteam == 3)
965         {
966                 c3 = c3 + 1;
967         }
968         else if(smallestteam == 4)
969         {
970                 c4 = c4 + 1;
971         }
972         else
973         {
974                 bprint("warning: destination team invalid\n");
975                 return;
976         }
977         // source team loses a member
978         if(source_team == 1)
979         {
980                 c1 = c1 + 1;
981         }
982         else if(source_team == 2)
983         {
984                 c2 = c2 + 2;
985         }
986         else if(source_team == 3)
987         {
988                 c3 = c3 + 3;
989         }
990         else if(source_team == 4)
991         {
992                 c4 = c4 + 4;
993         }
994         else
995         {
996                 bprint("warning: source team invalid\n");
997                 return;
998         }
999
1000         // move the player to the new team
1001         TeamchangeFrags(selected);
1002         SetPlayerTeam(selected, smallestteam, source_team, false);
1003
1004         if(selected.deadflag == DEAD_NO)
1005                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1006         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
1007 }