qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(cvar("bot_vs_human") && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!cvar("g_balance_teams_force"))
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void nb_init();
  75 void entcs_init();
  76
  77 void LogTeamchange(float player_id, float team_number, float type)
  78 {
  79         if(!cvar("sv_eventlog"))
  80                 return;
  81
  82         if(player_id < 1)
  83                 return;
  84
  85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  86 }
  87
  88 void WriteGameCvars()
  89 {
  90         cvar_set("g_dm", ftos(g_dm));
  91         cvar_set("g_tdm", ftos(g_tdm));
  92         cvar_set("g_domination", ftos(g_domination));
  93         cvar_set("g_ctf", ftos(g_ctf));
  94         cvar_set("g_runematch", ftos(g_runematch));
  95         cvar_set("g_lms", ftos(g_lms));
  96         cvar_set("g_arena", ftos(g_arena));
  97         cvar_set("g_ca", ftos(g_ca));
  98         cvar_set("g_keyhunt", ftos(g_keyhunt));
  99         cvar_set("g_assault", ftos(g_assault));
 100         cvar_set("g_onslaught", ftos(g_onslaught));
 101         cvar_set("g_race", ftos(g_race));
 102         cvar_set("g_nexball", ftos(g_nexball));
 103         cvar_set("g_cts", ftos(g_cts));
 104 }
 105
 106 void ReadGameCvars()
 107 {
 108         float found;
 109         float prev;
 110         float i;
 111
 112         found = 0;
 113         prev = cvar("gamecfg");
 114         for(i = 0; i < 2; ++i)
 115         {
 116                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 117                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 118                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 119                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 120                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 121                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 122                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 123                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 124                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 125                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 126                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 127                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 128                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 129                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 130
 131                 if(found)
 132                         break;
 133
 134                 prev = -1; // second attempt takes place WITHOUT prev set
 135         }
 136
 137         if(!found)
 138                 g_dm = 1;
 139
 140         if(g_dm && cvar("deathmatch_force_teamplay"))
 141         {
 142                 g_dm = 0;
 143                 g_tdm = 1;
 144         }
 145
 146         teams_matter = 0;
 147 }
 148
 149 void default_delayedinit()
 150 {
 151         if(!scores_initialized)
 152                 ScoreRules_generic();
 153 }
 154
 155 void ActivateTeamplay()
 156 {
 157         float teamplay_default;
 158         teamplay_default = cvar("teamplay_default");
 159
 160         if(teamplay_default)
 161                 teamplay = teamplay_default;
 162         else
 163                 teamplay = 3;
 164         cvar_set("teamplay", ftos(teamplay));
 165
 166         teams_matter = 1;
 167 }
 168
 169 void InitGameplayMode()
 170 {
 171         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 172
 173         qualifying_override = -1;
 174
 175         VoteReset();
 176
 177         teams_matter = 0;
 178         cvar_set("teamplay", "0");
 179
 180         // make sure only ONE type is selected
 181         ReadGameCvars();
 182         WriteGameCvars();
 183
 184         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 185         get_mi_min_max(1);
 186         world.mins = mi_min;
 187         world.maxs = mi_max;
 188
 189         MapInfo_LoadMapSettings(mapname);
 190
 191         if not(cvar_value_issafe(world.fog))
 192         {
 193                 print("The current map contains a potentially harmful fog setting, ignored\n");
 194                 world.fog = string_null;
 195         }
 196         if(MapInfo_Map_fog != "")
 197                 if(MapInfo_Map_fog == "none")
 198                         world.fog = string_null;
 199                 else
 200                         world.fog = strzone(MapInfo_Map_fog);
 201         clientstuff = strzone(MapInfo_Map_clientstuff);
 202
 203         MapInfo_ClearTemps();
 204
 205         // in case mapinfo switched the type
 206         ReadGameCvars();
 207
 208         // set both here, gamemode can override it later
 209         timelimit_override = cvar("timelimit_override");
 210         fraglimit_override = cvar("fraglimit_override");
 211         leadlimit_override = cvar("leadlimit_override");
 212
 213         if(g_dm)
 214         {
 215                 game = GAME_DEATHMATCH;
 216                 gamemode_name = "Deathmatch";
 217         }
 218
 219         if(g_tdm)
 220         {
 221                 game = GAME_TEAM_DEATHMATCH;
 222                 gamemode_name = "Team Deathmatch";
 223                 ActivateTeamplay();
 224                 tdm_init();
 225                 if(cvar("g_tdm_team_spawns"))
 226                         have_team_spawns = -1; // request team spawns
 227         }
 228
 229         if(g_domination)
 230         {
 231                 game = GAME_DOMINATION;
 232                 gamemode_name = "Domination";
 233                 ActivateTeamplay();
 234                 fraglimit_override = cvar("g_domination_point_limit");
 235                 leadlimit_override = cvar("g_domination_point_leadlimit");
 236                 dom_init();
 237                 have_team_spawns = -1; // request team spawns
 238         }
 239
 240         if(g_ctf)
 241         {
 242                 game = GAME_CTF;
 243                 gamemode_name = "Capture the Flag";
 244                 ActivateTeamplay();
 245                 if(cvar("g_campaign"))
 246                         g_ctf_win_mode = 2;
 247                 else
 248                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 249                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 250                 if(g_ctf_win_mode == 2)
 251                 {
 252                         fraglimit_override = cvar("g_ctf_capture_limit");
 253                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 254                 }
 255                 else
 256                 {
 257                         fraglimit_override = cvar("capturelimit_override");
 258                         leadlimit_override = cvar("captureleadlimit_override");
 259                 }
 260                 ctf_init();
 261                 have_team_spawns = -1; // request team spawns
 262         }
 263
 264         if(g_runematch)
 265         {
 266                 game = GAME_RUNEMATCH;
 267                 gamemode_name = "Rune Match";
 268                 if(cvar("deathmatch_force_teamplay"))
 269                         ActivateTeamplay();
 270                 fraglimit_override = cvar("g_runematch_point_limit");
 271                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 272                 runematch_init();
 273         }
 274
 275         if(g_lms)
 276         {
 277                 game = GAME_LMS;
 278                 gamemode_name = "Last Man Standing";
 279                 fraglimit_override = cvar("g_lms_lives_override");
 280                 leadlimit_override = 0; // not supported by LMS
 281                 if(fraglimit_override == 0)
 282                         fraglimit_override = -1;
 283                 lms_lowest_lives = 9999;
 284                 lms_next_place = 0;
 285                 ScoreRules_lms();
 286         }
 287
 288         if(g_arena)
 289         {
 290                 game = GAME_ARENA;
 291                 gamemode_name = "Arena";
 292                 fraglimit_override = cvar("g_arena_point_limit");
 293                 leadlimit_override = cvar("g_arena_point_leadlimit");
 294                 maxspawned = cvar("g_arena_maxspawned");
 295                 if(maxspawned < 2)
 296                         maxspawned = 2;
 297                 arena_roundbased = cvar("g_arena_roundbased");
 298         }
 299
 300         if(g_ca)
 301         {
 302                 game = GAME_CA;
 303                 gamemode_name = "Clan Arena";
 304                 ActivateTeamplay();
 305                 fraglimit_override = cvar("g_ca_point_limit");
 306                 leadlimit_override = cvar("g_ca_point_leadlimit");
 307                 precache_sound("ctf/red_capture.wav");
 308                 precache_sound("ctf/blue_capture.wav");
 309         }
 310         if(g_keyhunt)
 311         {
 312                 game = GAME_KEYHUNT;
 313                 gamemode_name = "Key Hunt";
 314                 ActivateTeamplay();
 315                 fraglimit_override = cvar("g_keyhunt_point_limit");
 316                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 317                 MUTATOR_ADD(gamemode_keyhunt);
 318         }
 319
 320         if(g_assault)
 321         {
 322                 game = GAME_ASSAULT;
 323                 gamemode_name = "Assault";
 324                 ActivateTeamplay();
 325                 ScoreRules_assault();
 326                 have_team_spawns = -1; // request team spawns
 327         }
 328
 329         if(g_onslaught)
 330         {
 331                 game = GAME_ONSLAUGHT;
 332                 gamemode_name = "Onslaught";
 333                 ActivateTeamplay();
 334                 have_team_spawns = -1; // request team spawns
 335         }
 336
 337         if(g_race)
 338         {
 339                 game = GAME_RACE;
 340                 gamemode_name = "Race";
 341
 342                 if(cvar("g_race_teams"))
 343                 {
 344                         ActivateTeamplay();
 345                         race_teams = bound(2, cvar("g_race_teams"), 4);
 346                         have_team_spawns = -1; // request team spawns
 347                 }
 348                 else
 349                         race_teams = 0;
 350
 351                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 352                 fraglimit_override = cvar("g_race_laps_limit");
 353                 leadlimit_override = 0; // currently not supported by race
 354         }
 355
 356         if(g_cts)
 357         {
 358                 game = GAME_CTS;
 359                 gamemode_name = "CTS";
 360                 g_race_qualifying = 1;
 361                 fraglimit_override = 0;
 362                 leadlimit_override = 0;
 363         }
 364
 365         if(g_nexball)
 366         {
 367                 game = GAME_NEXBALL;
 368                 gamemode_name = "Nexball";
 369                 fraglimit_override = cvar("g_nexball_goallimit");
 370                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 371                 ActivateTeamplay();
 372                 nb_init();
 373                 have_team_spawns = -1; // request team spawns
 374         }
 375
 376         if(teams_matter)
 377                 entcs_init();
 378
 379         // save it (for the next startup)
 380         cvar_set("gamecfg", ftos(game));
 381
 382         cache_mutatormsg = strzone("");
 383         cache_lastmutatormsg = strzone("");
 384
 385         // enforce the server's universal frag/time limits
 386         if(!cvar("g_campaign"))
 387         {
 388                 if(fraglimit_override >= 0)
 389                         cvar_set("fraglimit", ftos(fraglimit_override));
 390                 if(timelimit_override >= 0)
 391                         cvar_set("timelimit", ftos(timelimit_override));
 392                 if(leadlimit_override >= 0)
 393                         cvar_set("leadlimit", ftos(leadlimit_override));
 394                 if(qualifying_override >= 0)
 395                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 396         }
 397
 398         if(g_race)
 399         {
 400                 // we need to find out the correct value for g_race_qualifying
 401                 if(cvar("g_campaign"))
 402                 {
 403                         g_race_qualifying = 1;
 404                 }
 405                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 406                 {
 407                         g_race_qualifying = 2;
 408                         race_fraglimit = cvar("fraglimit");
 409                         race_leadlimit = cvar("leadlimit");
 410                         race_timelimit = cvar("timelimit");
 411                         cvar_set("fraglimit", "0");
 412                         cvar_set("leadlimit", "0");
 413                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 414                 }
 415                 else
 416                         g_race_qualifying = 0;
 417         }
 418
 419         if(g_race || g_cts)
 420         {
 421                 if(g_race_qualifying)
 422                         independent_players = 1;
 423
 424                 ScoreRules_race();
 425         }
 426
 427         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 428 }
 429
 430 string GetClientVersionMessage() {
 431         local string versionmsg;
 432         if (self.version_mismatch) {
 433                 if(self.version < cvar("gameversion")) {
 434                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 435                 } else {
 436                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 437                 }
 438         } else {
 439                 versionmsg = "^2client version and server version are compatible.^8";
 440         }
 441         return versionmsg;
 442 }
 443
 444
 445 void PrintWelcomeMessage(entity pl)
 446 {
 447         string s, modifications, motd;
 448
 449         if(self.cvar_scr_centertime == 0) return;
 450
 451         if(cvar("g_campaign"))
 452         {
 453                 if(self.classname == "player" && !self.BUTTON_INFO)
 454                         return;
 455         }
 456         else
 457         {
 458                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 459                         return;
 460         }
 461
 462         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 463                 if(self.welcomemessage_time > time) return;
 464                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 465         }
 466
 467         if(cvar("g_campaign"))
 468         {
 469                 centerprint(pl, campaign_message);
 470                 return;
 471         }
 472
 473 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 474         if(!self.BUTTON_INFO)
 475         {
 476                 // TODO get rid of this too
 477                 local string specString;
 478                 specString = NEWLINES;
 479                 //if(time < game_starttime) //also show the countdown when being a spectator
 480                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 481                 //else
 482                 if (timeoutStatus != 0)
 483                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 484                 else
 485                 {
 486                         if(self.classname == "player")
 487                                 return;
 488                         goto normal;
 489                 }
 490                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 491         }
 492
 493 :normal
 494         ret_string = "";
 495         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 496         modifications = ret_string;
 497
 498         if(g_minstagib)
 499                 modifications = strcat(modifications, ", MinstaGib");
 500         if(g_weaponarena)
 501         {
 502                 if(g_weaponarena_random)
 503                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 504                 else
 505                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 506         }
 507         if(cvar("g_start_weapon_laser") == 0)
 508                 modifications = strcat(modifications, ", No start weapons");
 509         if(cvar("sv_gravity") < 800)
 510                 modifications = strcat(modifications, ", Low gravity");
 511         if(g_cloaked)
 512                 modifications = strcat(modifications, ", Cloaked");
 513         if(g_grappling_hook)
 514                 modifications = strcat(modifications, ", Hook");
 515         if(g_midair)
 516                 modifications = strcat(modifications, ", Midair");
 517         if(g_pinata)
 518                 modifications = strcat(modifications, ", Pinata");
 519         if(g_weapon_stay)
 520                 modifications = strcat(modifications, ", Weapons stay");
 521         if(g_bloodloss > 0)
 522                 modifications = strcat(modifications, ", Bloodloss");
 523         if(g_jetpack)
 524                 modifications = strcat(modifications, ", Jet pack");
 525         modifications = substring(modifications, 2, strlen(modifications) - 2);
 526
 527         local string versionmessage;
 528         versionmessage = GetClientVersionMessage();
 529
 530         s = strcat(s, NEWLINES, "This is Xonotic ", cvar_string("g_xonoticversion"), "\n", versionmessage);
 531         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 532
 533         if(modifications != "")
 534                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 535
 536         if(timeoutStatus != 0)
 537                 s = strcat(s, "\n\n", getTimeoutText(1));
 538
 539         if (g_grappling_hook)
 540                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 541
 542         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 543         {
 544                 if(cache_lastmutatormsg)
 545                         strunzone(cache_lastmutatormsg);
 546                 if(cache_mutatormsg)
 547                         strunzone(cache_mutatormsg);
 548                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 549                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 550         }
 551
 552         if (cache_mutatormsg != "") {
 553                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 554         }
 555
 556         motd = cvar_string("sv_motd");
 557         if (motd != "") {
 558                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 559         }
 560         s = strcat(s, "\n");
 561
 562         centerprint(pl, s);
 563 }
 564
 565
 566 void SetPlayerColors(entity pl, float _color)
 567 {
 568         /*string s;
 569         s = ftos(cl);
 570         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 571         pl.team = cl + 1;
 572         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 573         pl.clientcolors = 16*cl + cl;*/
 574
 575         float pants, shirt;
 576         pants = _color & 0x0F;
 577         shirt = _color & 0xF0;
 578
 579
 580         if(teams_matter) {
 581                 setcolor(pl, 16*pants + pants);
 582         } else {
 583                 setcolor(pl, shirt + pants);
 584         }
 585 }
 586
 587 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 588 {
 589         float _color;
 590
 591         if(t == 4)
 592                 _color = COLOR_TEAM4 - 1;
 593         else if(t == 3)
 594                 _color = COLOR_TEAM3 - 1;
 595         else if(t == 2)
 596                 _color = COLOR_TEAM2 - 1;
 597         else
 598                 _color = COLOR_TEAM1 - 1;
 599
 600         SetPlayerColors(pl,_color);
 601
 602         if(t != s) {
 603                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 604
 605                 if(!noprint)
 606                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 607         }
 608
 609 }
 610
 611 // set c1...c4 to show what teams are allowed
 612 void CheckAllowedTeams (entity for_whom)
 613 {
 614         float dm;
 615         entity head;
 616         string teament_name;
 617
 618         c1 = c2 = c3 = c4 = -1;
 619         cb1 = cb2 = cb3 = cb4 = 0;
 620
 621         if(cvar("g_campaign") && for_whom && clienttype(for_whom) == CLIENTTYPE_REAL)
 622         {
 623                 c1 = 0; // only allow RED team for player joining
 624         }
 625         else if(g_onslaught)
 626         {
 627                 // onslaught is special
 628                 head = findchain(classname, "onslaught_generator");
 629                 while (head)
 630                 {
 631                         if (head.team == COLOR_TEAM1) c1 = 0;
 632                         if (head.team == COLOR_TEAM2) c2 = 0;
 633                         if (head.team == COLOR_TEAM3) c3 = 0;
 634                         if (head.team == COLOR_TEAM4) c4 = 0;
 635                         head = head.chain;
 636                 }
 637         }
 638         else if(g_domination)
 639                 teament_name = "dom_team";
 640         else if(g_ctf)
 641                 teament_name = "ctf_team";
 642         else if(g_tdm)
 643                 teament_name = "tdm_team";
 644         else if(g_nexball)
 645                 teament_name = "nexball_team";
 646         else if(g_assault)
 647                 c1 = c2 = 0; // Assault always has 2 teams
 648         else
 649         {
 650                 // cover anything else by treating it like tdm with no teams spawned
 651                 if(g_race)
 652                         dm = race_teams;
 653                 else
 654                         dm = 2;
 655
 656                 ret_float = dm;
 657                 MUTATOR_CALLHOOK(GetTeamCount);
 658                 dm = ret_float;
 659
 660                 if(dm >= 4)
 661                         c1 = c2 = c3 = c4 = 0;
 662                 else if(dm >= 3)
 663                         c1 = c2 = c3 = 0;
 664                 else
 665                         c1 = c2 = 0;
 666         }
 667
 668         // find out what teams are allowed if necessary
 669         if(teament_name)
 670         {
 671                 head = find(world, classname, teament_name);
 672                 while(head)
 673                 {
 674                         if(!(g_domination && head.netname == ""))
 675                         {
 676                                 if(head.team == COLOR_TEAM1)
 677                                         c1 = 0;
 678                                 else if(head.team == COLOR_TEAM2)
 679                                         c2 = 0;
 680                                 else if(head.team == COLOR_TEAM3)
 681                                         c3 = 0;
 682                                 else if(head.team == COLOR_TEAM4)
 683                                         c4 = 0;
 684                         }
 685                         head = find(head, classname, teament_name);
 686                 }
 687         }
 688
 689         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 690         if(c3==-1 && c4==-1)
 691         if(cvar("bot_vs_human") && for_whom)
 692         {
 693                 if(cvar("bot_vs_human") > 0)
 694                 {
 695                         // bots are all blue
 696                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 697                                 c1 = c3 = c4 = -1;
 698                         else
 699                                 c2 = -1;
 700                 }
 701                 else
 702                 {
 703                         // bots are all red
 704                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 705                                 c2 = c3 = c4 = -1;
 706                         else
 707                                 c1 = -1;
 708                 }
 709         }
 710
 711         // if player has a forced team, ONLY allow that one
 712         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 713                 c2 = c3 = c4 = -1;
 714         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 715                 c1 = c3 = c4 = -1;
 716         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 717                 c1 = c2 = c4 = -1;
 718         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 719                 c1 = c2 = c3 = -1;
 720 }
 721
 722 float PlayerValue(entity p)
 723 {
 724         if(IsTeamBalanceForced() == 1)
 725                 return 1;
 726         return 1;
 727         // FIXME: it always returns 1...
 728 }
 729
 730 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 731 // teams that are allowed will now have their player counts stored in c1...c4
 732 void GetTeamCounts(entity ignore)
 733 {
 734         entity head;
 735         float value, bvalue;
 736         // now count how many players are on each team already
 737
 738         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 739         // also remember the lowest-scoring player
 740
 741         FOR_EACH_PLAYER(head)
 742         {
 743                 if(head != ignore)// && head.netname != "")
 744                 {
 745                         value = PlayerValue(head);
 746                         if(clienttype(head) == CLIENTTYPE_BOT)
 747                                 bvalue = value;
 748                         else
 749                                 bvalue = 0;
 750                         if(head.team == COLOR_TEAM1)
 751                         {
 752                                 if(c1 >= 0)
 753                                 {
 754                                         c1 = c1 + value;
 755                                         cb1 = cb1 + bvalue;
 756                                 }
 757                         }
 758                         if(head.team == COLOR_TEAM2)
 759                         {
 760                                 if(c2 >= 0)
 761                                 {
 762                                         c2 = c2 + value;
 763                                         cb2 = cb2 + bvalue;
 764                                 }
 765                         }
 766                         if(head.team == COLOR_TEAM3)
 767                         {
 768                                 if(c3 >= 0)
 769                                 {
 770                                         c3 = c3 + value;
 771                                         cb3 = cb3 + bvalue;
 772                                 }
 773                         }
 774                         if(head.team == COLOR_TEAM4)
 775                         {
 776                                 if(c4 >= 0)
 777                                 {
 778                                         c4 = c4 + value;
 779                                         cb4 = cb4 + bvalue;
 780                                 }
 781                         }
 782                 }
 783         }
 784 }
 785
 786 // returns # of smallest team (1, 2, 3, 4)
 787 // NOTE: Assumes CheckAllowedTeams has already been called!
 788 float FindSmallestTeam(entity pl, float ignore_pl)
 789 {
 790         float totalteams, balance_type, maxc;
 791         totalteams = 0;
 792
 793         // find out what teams are available
 794         //CheckAllowedTeams();
 795
 796         // make sure there are at least 2 teams to join
 797         if(c1 >= 0)
 798                 totalteams = totalteams + 1;
 799         if(c2 >= 0)
 800                 totalteams = totalteams + 1;
 801         if(c3 >= 0)
 802                 totalteams = totalteams + 1;
 803         if(c4 >= 0)
 804                 totalteams = totalteams + 1;
 805
 806         if((cvar("bot_vs_human") || pl.team_forced > 0) && totalteams == 1)
 807                 totalteams += 1;
 808
 809         if(totalteams <= 1)
 810         {
 811                 if(cvar("g_campaign") && pl && clienttype(pl) == CLIENTTYPE_REAL)
 812                         return 1; // special case for campaign and player joining
 813                 else if(g_domination)
 814                         error("Too few teams available for domination\n");
 815                 else if(g_ctf)
 816                         error("Too few teams available for ctf\n");
 817                 else if(g_keyhunt)
 818                         error("Too few teams available for key hunt\n");
 819                 else
 820                         error("Too few teams available for team deathmatch\n");
 821         }
 822
 823         // count how many players are in each team
 824         if(ignore_pl)
 825                 GetTeamCounts(pl);
 826         else
 827                 GetTeamCounts(world);
 828
 829         // c1...c4 now have counts of each team
 830         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 831
 832         // 2 gives priority to what team you're already on, 1 goes in order
 833         // 2 doesn't seem to work though...
 834         balance_type = 1;
 835
 836         if(bots_would_leave)
 837         //if(pl.classname != "player")
 838         if(clienttype(pl) != CLIENTTYPE_BOT)
 839         {
 840                 c1 -= cb1 * 255.0/256.0;
 841                 c2 -= cb2 * 255.0/256.0;
 842                 c3 -= cb3 * 255.0/256.0;
 843                 c4 -= cb4 * 255.0/256.0;
 844         }
 845         maxc = max4(c1, c2, c3, c4);
 846
 847         RandomSelection_Init();
 848         if(balance_type == 1)
 849         {
 850                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 851                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 852                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 853                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 854                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 855         }
 856         else if(balance_type == 2)
 857         {
 858                 // 1: use team count, if equal prefer own team
 859                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 860                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 861                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 862                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 863         }
 864         else if(balance_type == 3)
 865         {
 866                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 867                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 868                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 869                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 870                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 871         }
 872         return RandomSelection_chosen_float;
 873 }
 874
 875 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 876 {
 877         float smallest, selectedteam;
 878
 879         // don't join a team if we're not playing a team game
 880         if(!teams_matter)
 881                 return 0;
 882
 883         // find out what teams are available
 884         CheckAllowedTeams(pl);
 885
 886         // if we want the player in a certain team for campaign, force him there
 887         if(cvar("g_campaign"))
 888         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
 889         {
 890                 switch(cvar("g_campaign_forceteam"))
 891                 {
 892                         case 1:
 893                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
 894                                 LogTeamchange(pl.playerid, pl.team, 2);
 895                                 return COLOR_TEAM1;
 896                         case 2:
 897                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
 898                                 LogTeamchange(pl.playerid, pl.team, 2);
 899                                 return COLOR_TEAM2;
 900                         case 3:
 901                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
 902                                 LogTeamchange(pl.playerid, pl.team, 2);
 903                                 return COLOR_TEAM3;
 904                         case 4:
 905                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
 906                                 LogTeamchange(pl.playerid, pl.team, 2);
 907                                 return COLOR_TEAM4;
 908                         default:
 909                                 break;
 910                 }
 911         }
 912
 913         // if we don't care what team he ends up on, put him on whatever team he entered as.
 914         // if he's not on a valid team, then let other code put him on the smallest team
 915         if(!forcebestteam)
 916         {
 917                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 918                         selectedteam = pl.team;
 919                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 920                         selectedteam = pl.team;
 921                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 922                         selectedteam = pl.team;
 923                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 924                         selectedteam = pl.team;
 925                 else
 926                         selectedteam = -1;
 927
 928                 if(selectedteam > 0)
 929                 {
 930                         if(!only_return_best)
 931                         {
 932                                 SetPlayerColors(pl, selectedteam - 1);
 933
 934                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 935                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 936                                 LogTeamchange(pl.playerid, pl.team, 99);
 937                         }
 938                         return selectedteam;
 939                 }
 940                 // otherwise end up on the smallest team (handled below)
 941         }
 942
 943         smallest = FindSmallestTeam(pl, TRUE);
 944
 945         if(!only_return_best && !pl.bot_forced_team)
 946         {
 947                 TeamchangeFrags(self);
 948                 if(smallest == 1)
 949                 {
 950                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 951                 }
 952                 else if(smallest == 2)
 953                 {
 954                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 955                 }
 956                 else if(smallest == 3)
 957                 {
 958                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 959                 }
 960                 else if(smallest == 4)
 961                 {
 962                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 963                 }
 964                 else
 965                 {
 966                         error("smallest team: invalid team\n");
 967                 }
 968
 969                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 970
 971                 if(pl.deadflag == DEAD_NO)
 972                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 973         }
 974
 975         return smallest;
 976 }
 977
 978 //void() ctf_playerchanged;
 979 void SV_ChangeTeam(float _color)
 980 {
 981         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 982
 983         // in normal deathmatch we can just apply the color and we're done
 984         if(!teams_matter) {
 985                 SetPlayerColors(self, _color);
 986                 return;
 987         }
 988
 989         scolor = self.clientcolors & 0x0F;
 990         dcolor = _color & 0x0F;
 991
 992         if(scolor == COLOR_TEAM1 - 1)
 993                 steam = 1;
 994         else if(scolor == COLOR_TEAM2 - 1)
 995                 steam = 2;
 996         else if(scolor == COLOR_TEAM3 - 1)
 997                 steam = 3;
 998         else // if(scolor == COLOR_TEAM4 - 1)
 999                 steam = 4;
1000         if(dcolor == COLOR_TEAM1 - 1)
1001                 dteam = 1;
1002         else if(dcolor == COLOR_TEAM2 - 1)
1003                 dteam = 2;
1004         else if(dcolor == COLOR_TEAM3 - 1)
1005                 dteam = 3;
1006         else // if(dcolor == COLOR_TEAM4 - 1)
1007                 dteam = 4;
1008
1009         CheckAllowedTeams(self);
1010
1011         if(dteam == 1 && c1 < 0) dteam = 4;
1012         if(dteam == 4 && c4 < 0) dteam = 3;
1013         if(dteam == 3 && c3 < 0) dteam = 2;
1014         if(dteam == 2 && c2 < 0) dteam = 1;
1015
1016         // not changing teams
1017         if(scolor == dcolor)
1018         {
1019                 //bprint("same team change\n");
1020                 SetPlayerTeam(self, dteam, steam, TRUE);
1021                 return;
1022         }
1023
1024         if((cvar("g_campaign")) || (cvar("g_changeteam_banned") && self.wasplayer)) {
1025                 sprint(self, "Team changes not allowed\n");
1026                 return; // changing teams is not allowed
1027         }
1028
1029         if(cvar("g_balance_teams_prevent_imbalance"))
1030         {
1031                 // only allow changing to a smaller or equal size team
1032
1033                 // find out what teams are available
1034                 //CheckAllowedTeams();
1035                 // count how many players on each team
1036                 GetTeamCounts(world);
1037
1038                 // get desired team
1039                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1040                 {
1041                         dcount = c1;
1042                         dbotcount = cb1;
1043                 }
1044                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1045                 {
1046                         dcount = c2;
1047                         dbotcount = cb2;
1048                 }
1049                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1050                 {
1051                         dcount = c3;
1052                         dbotcount = cb3;
1053                 }
1054                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1055                 {
1056                         dcount = c4;
1057                         dbotcount = cb4;
1058                 }
1059                 else
1060                 {
1061                         sprint(self, "Cannot change to an invalid team\n");
1062
1063                         return;
1064                 }
1065
1066                 // get starting team
1067                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1068                         scount = c1;
1069                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1070                         scount = c2;
1071                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1072                         scount = c3;
1073                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1074                         scount = c4;
1075
1076                 if(scount) // started at a valid, nonempty team
1077                 {
1078                         // check if we're trying to change to a larger team that doens't have bots to swap with
1079                         if(dcount >= scount && dbotcount <= 0)
1080                         {
1081                                 sprint(self, "Cannot change to a larger team\n");
1082                                 return; // can't change to a larger team
1083                         }
1084                 }
1085         }
1086
1087 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1088
1089         if(self.classname == "player" && steam != dteam)
1090         {
1091                 // reduce frags during a team change
1092                 TeamchangeFrags(self);
1093         }
1094
1095         SetPlayerTeam(self, dteam, steam, FALSE);
1096
1097         if(self.classname == "player" && steam != dteam)
1098         {
1099                 // kill player when changing teams
1100                 if(self.deadflag == DEAD_NO)
1101                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1102         }
1103         //ctf_playerchanged();
1104 }
1105
1106 void ShufflePlayerOutOfTeam (float source_team)
1107 {
1108         float smallestteam, smallestteam_count, steam;
1109         float lowest_bot_score, lowest_player_score;
1110         entity head, lowest_bot, lowest_player, selected;
1111
1112         smallestteam = 0;
1113         smallestteam_count = 999999999;
1114
1115         if(c1 >= 0 && c1 < smallestteam_count)
1116         {
1117                 smallestteam = 1;
1118                 smallestteam_count = c1;
1119         }
1120         if(c2 >= 0 && c2 < smallestteam_count)
1121         {
1122                 smallestteam = 2;
1123                 smallestteam_count = c2;
1124         }
1125         if(c3 >= 0 && c3 < smallestteam_count)
1126         {
1127                 smallestteam = 3;
1128                 smallestteam_count = c3;
1129         }
1130         if(c4 >= 0 && c4 < smallestteam_count)
1131         {
1132                 smallestteam = 4;
1133                 smallestteam_count = c4;
1134         }
1135
1136         if(!smallestteam)
1137         {
1138                 bprint("warning: no smallest team\n");
1139                 return;
1140         }
1141
1142         if(source_team == 1)
1143                 steam = COLOR_TEAM1;
1144         else if(source_team == 2)
1145                 steam = COLOR_TEAM2;
1146         else if(source_team == 3)
1147                 steam = COLOR_TEAM3;
1148         else if(source_team == 4)
1149                 steam = COLOR_TEAM4;
1150
1151         lowest_bot = world;
1152         lowest_bot_score = 999999999;
1153         lowest_player = world;
1154         lowest_player_score = 999999999;
1155
1156         // find the lowest-scoring player & bot of that team
1157         FOR_EACH_PLAYER(head)
1158         {
1159                 if(head.team == steam)
1160                 {
1161                         if(head.isbot)
1162                         {
1163                                 if(head.totalfrags < lowest_bot_score)
1164                                 {
1165                                         lowest_bot = head;
1166                                         lowest_bot_score = head.totalfrags;
1167                                 }
1168                         }
1169                         else
1170                         {
1171                                 if(head.totalfrags < lowest_player_score)
1172                                 {
1173                                         lowest_player = head;
1174                                         lowest_player_score = head.totalfrags;
1175                                 }
1176                         }
1177                 }
1178         }
1179
1180         // prefers to move a bot...
1181         if(lowest_bot != world)
1182                 selected = lowest_bot;
1183         // but it will move a player if it has to
1184         else
1185                 selected = lowest_player;
1186         // don't do anything if it couldn't find anyone
1187         if(!selected)
1188         {
1189                 bprint("warning: couldn't find a player to move from team\n");
1190                 return;
1191         }
1192
1193         // smallest team gains a member
1194         if(smallestteam == 1)
1195         {
1196                 c1 = c1 + 1;
1197         }
1198         else if(smallestteam == 2)
1199         {
1200                 c2 = c2 + 1;
1201         }
1202         else if(smallestteam == 3)
1203         {
1204                 c3 = c3 + 1;
1205         }
1206         else if(smallestteam == 4)
1207         {
1208                 c4 = c4 + 1;
1209         }
1210         else
1211         {
1212                 bprint("warning: destination team invalid\n");
1213                 return;
1214         }
1215         // source team loses a member
1216         if(source_team == 1)
1217         {
1218                 c1 = c1 + 1;
1219         }
1220         else if(source_team == 2)
1221         {
1222                 c2 = c2 + 2;
1223         }
1224         else if(source_team == 3)
1225         {
1226                 c3 = c3 + 3;
1227         }
1228         else if(source_team == 4)
1229         {
1230                 c4 = c4 + 4;
1231         }
1232         else
1233         {
1234                 bprint("warning: source team invalid\n");
1235                 return;
1236         }
1237
1238         // move the player to the new team
1239         TeamchangeFrags(selected);
1240         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1241
1242         if(selected.deadflag == DEAD_NO)
1243                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1244         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1245 }
1246
1247 void CauseRebalance(float source_team, float howmany_toomany)
1248 {
1249         if(IsTeamBalanceForced() == 1)
1250         {
1251                 bprint("Rebalancing Teams\n");
1252                 ShufflePlayerOutOfTeam(source_team);
1253         }
1254 }
1255
1256 // part of g_balance_teams_force
1257 // occasionally perform an audit of the teams to make
1258 // sure they're more or less balanced in player count.
1259 void AuditTeams()
1260 {
1261         float numplayers, numteams, smallest, toomany;
1262         float balance;
1263         balance = IsTeamBalanceForced();
1264         if(balance == 0)
1265                 return;
1266
1267         if(audit_teams_time > time)
1268                 return;
1269
1270         audit_teams_time = time + 4 + random();
1271
1272 //      bprint("Auditing teams\n");
1273
1274         CheckAllowedTeams(world);
1275         GetTeamCounts(world);
1276
1277
1278         numteams = numplayers = smallest = 0;
1279         if(c1 >= 0)
1280         {
1281                 numteams = numteams + 1;
1282                 numplayers = numplayers + c1;
1283                 smallest = c1;
1284         }
1285         if(c2 >= 0)
1286         {
1287                 numteams = numteams + 1;
1288                 numplayers = numplayers + c2;
1289                 if(c2 < smallest)
1290                         smallest = c2;
1291         }
1292         if(c3 >= 0)
1293         {
1294                 numteams = numteams + 1;
1295                 numplayers = numplayers + c3;
1296                 if(c3 < smallest)
1297                         smallest = c3;
1298         }
1299         if(c4 >= 0)
1300         {
1301                 numteams = numteams + 1;
1302                 numplayers = numplayers + c4;
1303                 if(c4 < smallest)
1304                         smallest = c4;
1305         }
1306
1307         if(numplayers <= 0)
1308                 return; // no players to move around
1309         if(numteams < 2)
1310                 return; // don't bother shuffling if for some reason there aren't any teams
1311
1312         toomany = smallest + 1;
1313
1314         if(c1 && c1 > toomany)
1315                 CauseRebalance(1, c1 - toomany);
1316         if(c2 && c2 > toomany)
1317                 CauseRebalance(2, c2 - toomany);
1318         if(c3 && c3 > toomany)
1319                 CauseRebalance(3, c3 - toomany);
1320         if(c4 && c4 > toomany)
1321                 CauseRebalance(4, c4 - toomany);
1322
1323         // if teams are still unbalanced, balance them further in the next audit,
1324         // which will happen sooner (keep doing rapid audits until things are in order)
1325         audit_teams_time = time + 0.7 + random()*0.3;
1326 }
1327
1328 // code from here on is just to support maps that don't have team entities
1329 void tdm_spawnteam (string teamname, float teamcolor)
1330 {
1331         local entity e;
1332         e = spawn();
1333         e.classname = "tdm_team";
1334         e.netname = teamname;
1335         e.cnt = teamcolor;
1336         e.team = e.cnt + 1;
1337 };
1338
1339 // spawn some default teams if the map is not set up for tdm
1340 void tdm_spawnteams()
1341 {
1342         float numteams;
1343
1344         numteams = cvar("g_tdm_teams_override");
1345         if(numteams < 2)
1346                 numteams = cvar("g_tdm_teams");
1347         numteams = bound(2, numteams, 4);
1348
1349         tdm_spawnteam("Red", COLOR_TEAM1-1);
1350         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1351         if(numteams >= 3)
1352                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1353         if(numteams >= 4)
1354                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1355 };
1356
1357 void tdm_delayedinit()
1358 {
1359         // if no teams are found, spawn defaults
1360         if (find(world, classname, "tdm_team") == world)
1361                 tdm_spawnteams();
1362 };
1363
1364 void tdm_init()
1365 {
1366         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1367 };